configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen win32-dll])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 136      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 137      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 138      build_target="freebsd"
 139      LIBPREFIX=
 140      DLLDIR=lib
 141      UNIXONLY="#"
 142   ],
 143   [*openbsd*],[
 144      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 145      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 146      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 147      build_target="openbsd"
 148      LIBPREFIX=
 149      DLLDIR=lib
 150      UNIXONLY="#"
 151   ],
 152   [*netbsd*],[
 153      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 154      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 155      build_target="netbsd"
 156      LIBPREFIX=
 157      DLLDIR=lib
 158      UNIXONLY="#"
 159   ],
 160   [*solaris*],[
 161      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 162      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 163      AC_CHECK_LIB(resolv, res_init)
 164      AC_CHECK_LIB(rt, nanosleep)
 165      build_target="solaris"
 166      LIBPREFIX=
 167      DLLDIR=lib
 168      UNIXONLY="#"
 169   ],
 170   [*arm-linux*],[
 171      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 172      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 173      build_target="linux"
 174      LIBPREFIX=
 175      DLLDIR=lib
 176      UNIXONLY="#"
 177   ],
 178   [gnu*],[
 179      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 180      build_target="gnu"
 181      UNIXONLY="#"
 182   ],
 183   [
 184      AC_MSG_RESULT(Unrecognised OS $host_os)
 185      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 186      UNIXONLY=""
 187 ])
 188 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 189 AC_SUBST(DEFAULT_INTERFACE)
 190
 191 # Disable TCP-based IPC on systems that support UNIX domain
 192 # sockets in default configuratin:
 193 AC_SUBST(UNIXONLY)
 194
 195
 196 AC_MSG_CHECKING([for build target])
 197 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 198 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 199 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 226 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 227 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 228 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 229
 230 # autotools' m4 for python has no maximum version!
 231 # python3.4 - python3.8 for tests (3.8 unchecked)
 232 # TODO: document how to override the lowest version
 233 # TODO: found by this.
 234 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 235 AM_PATH_PYTHON([3.4],, [:])
 236 AC_SUBST([PYTHON])
 237 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 238
 239 # perl
 240 AC_PATH_PROG( PERL, perl, ,
 241               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 242 AC_SUBST([PERL])
 243
 244 # iptables is a soft requirement to run tests
 245 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 246
 247 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 248  [AS_IF([test -x "/sbin/iptables"],
 249    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 250    [AS_IF([test -x "/usr/sbin/iptables"],
 251       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 252
 253 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 254  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 255  [AC_MSG_WARN([warning: 'iptables' not found.])])
 256
 257 # ip6tables is a soft requirement for some features
 258 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 259
 260 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 261   [AS_IF([test -x "/sbin/ip6tables"],
 262      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 263      [AS_IF([test -x "/usr/sbin/ip6tables"],
 264         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 265
 266
 267 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 268   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 269   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 270
 271 # ip is a soft requirement for some features
 272 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 273
 274 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 275  [AS_IF([test -x "/sbin/ip"],
 276    [VAR_IP_BINARY="/sbin/ip"],
 277    [AS_IF([test -x "/usr/sbin/ip"],
 278           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 279
 280 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 281  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 282  [AC_MSG_WARN([warning: 'ip' not found.])])
 283
 284 # locate 'ifconfig'
 285 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 286
 287 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 288 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 289   [AS_IF([test -x "/sbin/ifconfig"],
 290      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 291      [AS_IF([test -x "/usr/sbin/ifconfig"],
 292             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 293
 294 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 295   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 296   [AC_MSG_WARN(['ifconfig' not found.])])
 297
 298
 299 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 300
 301 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 302 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 303       [AS_IF([test -x "/sbin/sysctl"],
 304              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 305              [AS_IF([test -x "/usr/sbin/sysctl"],
 306                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 307 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 308       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 309       [AC_MSG_WARN(['sysctl' not found.])])
 310
 311 # miniupnpc / upnpc binary is a soft runtime requirement
 312 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 313
 314 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 315   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 316   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 317
 318
 319 # uncrustify
 320 # TODO: maybe add flag to pass location
 321 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 322 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 323
 324 # yapf
 325 # TODO: less repetition, add flag to pass name
 326 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 327 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 328
 329
 330 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 331   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 332      [Define if struct tm has the tm_gmtoff member.])],
 333      ,
 334      [#include <time.h>])
 335
 336 # 'save' libs; only those libs found so far will be
 337 # linked against _everywhere_.  For the others, we
 338 # will be more selective!
 339 SAVE_LIBS=$LIBS
 340
 341 have_addrinfo_a=0
 342 AC_CHECK_LIB(anl,
 343              getaddrinfo_a,
 344              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 345                                           1,
 346                                           [getaddrinfo_a supported])])
 347 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 348                [test "$have_addrinfo_a" = 1])
 349
 350 # libgcrypt
 351 gcrypt=0
 352 NEED_LIBGCRYPT_API=1
 353 NEED_LIBGCRYPT_VERSION=1.6.0
 354
 355
 356 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 357 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 358
 359 AS_IF([test $gcrypt = 0],
 360  [
 361   AC_MSG_ERROR([[
 362 ***
 363 *** You need libgcrypt to build this program.
 364 *** This library is for example available at
 365 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 366 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 367 ***  is required.
 368 ***]])
 369 ])
 370 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 371
 372 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 373
 374
 375
 376 # should the build process be building the documentation?
 377 AC_MSG_CHECKING(whether to build documentation)
 378 AC_ARG_ENABLE([documentation],
 379               [AS_HELP_STRING([--disable-documentation],
 380                               [do not build the documentation])],
 381               [documentation=${enableval}],
 382               [documentation=yes])
 383 AC_MSG_RESULT($documentation)
 384 AS_IF([test "x$documentation" = "xyes"],
 385       [AM_CONDITIONAL([DOCUMENTATION],
 386                       true)
 387        AC_DEFINE([DOCUMENTATION],
 388                  [1],
 389                  [Building the documentation])],
 390       [AM_CONDITIONAL([DOCUMENTATION],
 391                       false)
 392        AC_DEFINE([DOCUMENTATION],
 393                  [0],
 394                  [Not building the documentation])])
 395
 396 # COMMENT: Check wether to transpile texinfo to mdoc.
 397 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 398 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 399 # COMMENT: and makes the configure fail if it is missing.
 400 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 401 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 402 # COMMENT: or nothing was set (this is the default).
 403 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 404 # COMMENT: potential non-existence of the texi2mdoc binary.
 405 # COMMENT: Default return value / setting: no
 406 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 407 AC_ARG_ENABLE([texi2mdoc-generation],
 408               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 409                               [include generated texi2mdoc output in installation])],
 410               [texi2mdoc_generation=${enableval}],
 411               [texi2mdoc_generation=no])
 412 AC_MSG_RESULT($texi2mdoc_generation)
 413 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 414       [AS_IF([test "$texi2mdoc" = 0],
 415              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 416               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 417               AC_MSG_WARN([ERROR: Operating System package manager or from])
 418               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 419              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 420               AC_DEFINE([TEXI2MDOC_GENERATION],
 421                         [1],
 422                         [Building section 7 mdoc output])])],
 423       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 424                       false)
 425        AC_DEFINE([TEXI2MDOC_GENERATION],
 426                  [0],
 427                  [Not building section 7 mdoc output])])
 428
 429 # should the build process be building only the documentation?
 430 AC_MSG_CHECKING(whether to build only documentation)
 431 AC_ARG_ENABLE([documentation-only],
 432    [AS_HELP_STRING([--enable-documentation-only],
 433                    [build only the documentation])],
 434    [documentation_only=${enableval}],
 435    [documentation_only=no])
 436 AC_MSG_RESULT($documentation_only)
 437 AS_IF([test "x$documentation_only" = "xyes"],
 438  [
 439   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 440   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 441  ],[
 442   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 443   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 444  ])
 445
 446 # should the build process be including the manpages? (default: yes)
 447 AC_MSG_CHECKING(whether to include man pages)
 448 AC_ARG_ENABLE([include-manpages],
 449    [AS_HELP_STRING([--disable-include-manpages],
 450                    [Do not include the man pages in build and installation])],
 451    [include_manpages=${enableval}],
 452    [include_manpages=yes])
 453 AC_MSG_RESULT($include_manpages)
 454 AS_IF([test "x$include_manpages" = "xyes"],
 455  [
 456   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 457   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 458  ],[
 459   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 460   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 461  ])
 462
 463 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 464 # (not syntax!) to the commandline tools which generate the html. If not,
 465 # texinfo5 switches are used. This comes with no version checks, is
 466 # enabled only at distributors action (ie defaults to "no").
 467 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 468 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 469 AC_ARG_ENABLE([texinfo4],
 470    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 471    [activate_texinfo4=${enableval}],
 472    [activate_texinfo4=no])
 473 AC_MSG_RESULT($activate_texinfo4)
 474 AS_IF([test "x$activate_texinfo4" = "xyes"],
 475  [
 476   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 477   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 478  ],[
 479   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 480   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 481  ])
 482
 483
 484 # Adam shostack suggests the following for Windows:
 485 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 486 AC_ARG_ENABLE(gcc-hardening,
 487    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 488 [AS_IF([test x$enableval = xyes],[
 489     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 490     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 491     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 492     LDFLAGS="$LDFLAGS -pie"
 493  ])])
 494
 495 # Linker hardening options
 496 # Currently these options are ELF specific - you can't use this with MacOSX
 497 AC_ARG_ENABLE(linker-hardening,
 498   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 499 [AS_IF([test x$enableval = xyes],
 500    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 501
 502
 503 AC_ARG_ENABLE(sanitizer,
 504   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 505 [AS_IF([test x$enableval = xyes],[
 506    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 507  ])])
 508
 509
 510 extra_logging=GNUNET_NO
 511 AC_ARG_ENABLE([logging],
 512    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 513    [AS_IF([test "x$enableval" = "xyes"], [],
 514           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 515           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 516           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 517    ], [])
 518 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 519
 520 # should memory poisoning be enabled?
 521 AC_MSG_CHECKING(whether to poison freed memory)
 522 AC_ARG_ENABLE([poisoning],
 523    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 524    [enable_poisoning=${enableval}],
 525    [
 526      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 527        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 528        [enable_poisoning=no])
 529    ])
 530 AC_MSG_RESULT($enable_poisoning)
 531 AS_IF([test ! "x$enable_poisoning" = "xno"],
 532   [enable_poisoning=1],
 533   [enable_poisoning=0])
 534 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 535
 536 AS_IF([test $build = $target],
 537 [
 538 AC_MSG_CHECKING([for working HMAC])
 539 AC_LANG_PUSH(C)
 540 LIBS="$LIBS $LIBGCRYPT_LIBS"
 541 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 542 AC_RUN_IFELSE(
 543   [AC_LANG_PROGRAM([#include <gcrypt.h>
 544         #include <stdio.h>], [[
 545         gcry_md_hd_t mac;
 546
 547         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 548             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 549             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 550         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 551         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 552             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 553             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 554             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 555             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 556             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 557
 558         if (!gcry_check_version (GCRYPT_VERSION))
 559         {
 560           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 561           return 1;
 562         }
 563
 564         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 565         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 566
 567         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 568         {
 569           fprintf (stderr, "gcry_md_open error\n");
 570           return 2;
 571         }
 572
 573         gcry_md_setkey (mac, key, sizeof (key));
 574         gcry_md_write (mac, data, sizeof (data));
 575
 576         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 577         {
 578           fprintf (stderr, "memcmp error\n");
 579           return 3;
 580         }
 581
 582         gcry_md_close (mac);
 583
 584         return 0;
 585     ]])],
 586   [AC_MSG_RESULT([yes])],
 587   [
 588    RESULT=$?
 589    if test $RESULT = 3
 590    then
 591      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 592    fi
 593    if test $RESULT = 2
 594    then
 595      AC_MSG_FAILURE([HMAC test failed])
 596    fi
 597    if test $RESULT = 1
 598    then
 599      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 600    fi
 601   ],
 602   [AC_MSG_RESULT([cross compiling, test skipped])])
 603 AC_LANG_POP(C)
 604 ])      # $build = $target
 605
 606 # check for bluetooth library
 607 bluetooth=0
 608 AC_MSG_CHECKING(for libbluetooth)
 609 AC_ARG_WITH(libbluetooth,
 610     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 611     [AC_MSG_RESULT([$with_libbluetooth])
 612      AS_CASE([$with_libbluetooth],
 613         [no],[],
 614         [yes],[
 615             CHECK_LIBHEADER(BLUETOOTH,
 616                             bluetooth,
 617                             ba2str,
 618                             bluetooth/bluetooth.h,
 619                             bluetooth=1,)
 620         ],[
 621             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 622             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 623             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 624                              AC_CHECK_LIB([bluetooth],
 625                                           [ba2str],
 626                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 627                                           bluetooth=1))
 628         ])
 629     ],
 630     [AC_MSG_RESULT([--with-libbluetooth not specified])
 631      CHECK_LIBHEADER(BLUETOOTH,
 632                      bluetooth,
 633                      ba2str,
 634                      bluetooth/bluetooth.h,
 635                      bluetooth=1,)])
 636 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 637 AS_IF([test "$bluetooth" = 1],
 638       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 639       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 640
 641 # check for zbar library
 642 zbar=0
 643 AC_MSG_CHECKING(for libzbar)
 644 AC_ARG_WITH(zbar,
 645    [  --with-zbar=PREFIX (base of libzbar installation)],
 646    [AC_MSG_RESULT([$with_zbar])
 647     AS_CASE([$with_zbar],
 648       [no],[],
 649       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 650       [
 651         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 652         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 653         AC_CHECK_HEADERS(zbar.h,
 654           AC_CHECK_LIB([zbar], [zbar_processor_create],
 655             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 656             zbar=1))
 657        ])
 658    ],
 659    [AC_MSG_RESULT([--with-zbar not specified])
 660     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 661 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 662 AS_IF([test "x$zbar" = x1],
 663       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 664       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 665
 666 # check for jansson library
 667 jansson=0
 668 AC_MSG_CHECKING(for libjansson)
 669 AC_ARG_WITH(jansson,
 670    [  --with-jansson=PREFIX (base of libjansson installation)],
 671    [AC_MSG_RESULT([$with_jansson])
 672     AS_CASE([$with_jansson],
 673       [no],[],
 674       [yes],[
 675         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 676       ],[
 677         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 678         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 679         AC_CHECK_HEADERS(jansson.h,
 680           AC_CHECK_LIB([jansson], [json_loads],
 681             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 682             jansson=1))
 683       ])
 684    ],
 685    [AC_MSG_RESULT([--with-jansson not specified])
 686     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 687 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 688 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 689 AS_IF([test "x$jansson" = x1],
 690       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 691       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 692
 693
 694 # check for libpulse(audio) library
 695 pulse=0
 696 libpulse_msg="no"
 697 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 698 AS_IF([test "$pulse" = 1],
 699       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 700        libpulse_msg="yes"])
 701
 702 # check for libopus(audio) library
 703 opus=0
 704 libopus_msg="no"
 705 CHECK_LIBHEADER(LIBOPUS,
 706                 opus,
 707                 opus_decode_float,
 708                 opus/opus.h,
 709                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 710 AS_IF([test "x$opus" = x1],
 711       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 712        libopus_msg="yes"])
 713
 714 # libogg
 715 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 716         [AC_CHECK_HEADERS([ogg/ogg.h],
 717           AM_CONDITIONAL(HAVE_OGG, true)
 718           ogg=1
 719           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 720           AM_CONDITIONAL(HAVE_OGG, false)
 721           ogg=0
 722           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 723         AM_CONDITIONAL(HAVE_OGG, false)
 724         ogg=0)
 725
 726
 727 PKG_CHECK_MODULES([GLIB],
 728                   [glib-2.0],
 729   [# check for pbc library
 730   pbc=0
 731    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 732    AC_CHECK_HEADER([gabe.h],abe=1)
 733    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 734    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 735    AS_IF([test "x$pbc" = x1],
 736      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 737      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 738    AS_IF([test "x$abe" = x1],
 739     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 740     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 741   [# glib-2 not found
 742    AM_CONDITIONAL(HAVE_PBC, [false])
 743    AM_CONDITIONAL(HAVE_ABE, [false])
 744    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 745
 746 gst=0
 747 gstreamer_msg="no"
 748 PKG_CHECK_MODULES(
 749   [GST],
 750   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 751   [gst=1
 752    gstreamer_msg="yes"],
 753   [gst=0])
 754
 755 # Pulse Audio
 756 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 757  AS_IF([test "x$gst" != "x1"],[
 758   conversation_backend=none
 759   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 760   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 761   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 762  ],[
 763    conversation_backend=gst
 764    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 765    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 766    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 767  ])
 768 ],[
 769  conversation_backend=pulse
 770  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 771  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 772  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 773 ])
 774
 775 AS_IF([test "x$conversation_backend" = "xnone"],
 776       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 777       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 778
 779 # libgnurl
 780 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 781
 782 SAVE_CPPFLAGS=$CPPFLAGS
 783 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 784 LIBS="$LIBGNURL $LIBCURL $LIBS"
 785
 786 # libcurl-gnutls
 787 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 788 AS_IF([test "x$curl" = xtrue],[
 789  AC_CHECK_HEADER([curl/curl.h],
 790   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 791   [curl=false])
 792  # need libcurl-gnutls.so, everything else is not acceptable
 793  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 794  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 795 ])
 796
 797 # libcurl and libgnurl should be mutually exclusive
 798 AS_IF([test "$gnurl" = 1],
 799       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 800        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 801        AM_CONDITIONAL(HAVE_LIBCURL, false)
 802        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 803       [AS_IF([test "$curl" = true],
 804              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 805               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 806               AM_CONDITIONAL(HAVE_LIBCURL, true)
 807               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 808              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 809               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 810               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 811               AM_CONDITIONAL(HAVE_LIBCURL, false)
 812               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 813
 814 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 815 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 816
 817 # restore LIBS & CPPFLAGS
 818 LIBS=$SAVE_LIBS
 819 CPPFLAGS=$SAVE_CPPFLAGS
 820
 821
 822 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 823 AS_IF([test x$nss = xfalse],
 824   [
 825         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 826         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 827   ],[
 828         NSS_INCLUDES="
 829         #include <nss.h>
 830         "
 831         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 832                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 833                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 834                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 835                 [$NSS_INCLUDES])
 836 ])
 837
 838
 839
 840 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 841 AC_CHECK_LIB([kvm],[kvm_open])
 842 AC_CHECK_LIB([kstat],[kstat_open])
 843
 844
 845 # should the build process be restricted to the code required
 846 # for GNU Taler wallets?
 847 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 848 AC_ARG_ENABLE([taler-wallet],
 849    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 850    [taler_only=${enableval}],
 851    [taler_only=no])
 852 AC_MSG_RESULT($taler_only)
 853 AS_IF([test "x$taler_only" = "xyes"],
 854 [
 855   AM_CONDITIONAL([TALER_ONLY],true)
 856   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 857 ],[
 858   AM_CONDITIONAL([TALER_ONLY],false)
 859   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 860 ])
 861
 862 # test for libextractor
 863 extractor=0
 864 AC_MSG_CHECKING(for libextractor)
 865 AC_ARG_WITH(extractor,
 866    [  --with-extractor=PREFIX (base of libextractor installation)],
 867    [AC_MSG_RESULT([$with_extractor])
 868     AS_CASE([$with_extractor],
 869       [no],[],
 870       [yes],[
 871         AC_CHECK_HEADERS([extractor.h],
 872           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 873             extractor=1))
 874       ],[
 875         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 876         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 877         AC_CHECK_HEADERS([extractor.h],
 878           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 879             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 880             extractor=1))
 881       ])
 882    ],
 883    [AC_MSG_RESULT([--with-extractor not specified])
 884     AC_CHECK_HEADERS([extractor.h],
 885      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 886       extractor=1))])
 887 # restore LIBS
 888 LIBS=$SAVE_LIBS
 889
 890 AS_IF([test "$extractor" != 1],
 891  [
 892  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 893  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 894  ],[
 895  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 896  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 897  ])
 898
 899
 900 AS_IF([test "$taler_only" != yes],[
 901
 902
 903 # Check for libltdl header (#2999)
 904 ltdl=0
 905 AC_MSG_CHECKING(for libltdl)
 906 AC_ARG_WITH(ltdl,
 907    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 908    [AC_MSG_RESULT([$with_ltdl])
 909     AS_CASE([$with_ltdl],
 910       [no],[],
 911       [yes],[
 912         AC_CHECK_HEADERS(ltdl.h,
 913           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 914             ltdl=1))
 915       ],[
 916         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 917         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 918         AC_CHECK_HEADERS(ltdl.h,
 919           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 920             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 921             ltdl=1))
 922       ])
 923    ],
 924    [AC_MSG_RESULT([--with-ltdl not specified])
 925     AC_CHECK_HEADERS(ltdl.h,
 926      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 927       ltdl=1))])
 928 AS_IF([test x$ltdl = x1],
 929 [
 930  AC_MSG_RESULT([libltdl found])
 931 ],[
 932  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 933 ])
 934 # restore LIBS
 935 LIBS=$SAVE_LIBS
 936
 937 # libidn and libidn2. The ideal goal is this:
 938 # check for libidn2, if it doesn't exist check for libidn
 939 # if both exist, prefer libidn2
 940 # if none exist, fail and message that libidn or libidn2
 941 # is required with a preference for libidn2.
 942 # TODO: What we have right here can probably be improved.
 943 my_with_libidn=1
 944 AC_ARG_WITH(libidn,
 945             AS_HELP_STRING([--with-libidn=pathname],
 946                            [Support IDN (needs libidn)]),
 947             [],
 948             [withval="yes"])
 949 AS_IF([test x_$withval = x_yes],
 950       [AC_CHECK_HEADERS([idna.h],
 951           AC_MSG_NOTICE([Found idna.h]),
 952           AC_CHECK_HEADERS([idn/idna.h],
 953                AC_MSG_NOTICE([Found idn/idna.h]),
 954                my_with_libidn=0))],
 955       [AS_IF([test x_$withval != x_no],
 956              [CFLAGS="$CFLAGS -I$withval/include"
 957               LDFLAGS="$LDFLAGS -L$withval/lib"
 958               AC_CHECK_HEADERS([idna.h],
 959                 AC_MSG_NOTICE([Found idna.h]),
 960                 [AC_MSG_NOTICE([Failed to find idna.h])
 961                  my_with_libidn=0])],
 962              [my_with_libidn=0])])
 963
 964 my_with_libidn2=1
 965 AC_ARG_WITH(libidn2,
 966             AS_HELP_STRING([--with-libidn2=pathname],
 967                            [Support IDN (needs libidn2)]),
 968             [],
 969             [withval="yes"])
 970 AS_IF([test x_$withval = x_yes],
 971       [AC_CHECK_HEADERS([idn2.h],
 972        AC_MSG_NOTICE([Found idn2.h]),
 973        AC_CHECK_HEADERS([idn2/idn2.h],
 974           AC_MSG_NOTICE([Found idn2/idn2.h]),
 975           [AC_MSG_NOTICE([Failed to find idn2.h])
 976            my_with_libidn2=0]))],
 977       [AS_IF([test x_$withval != x_no],
 978              [CFLAGS="$CFLAGS -I$withval/include"
 979               LDFLAGS="$LDFLAGS -L$withval/lib"],
 980              [my_with_libidn2=0])])
 981
 982 AC_MSG_CHECKING([if libidn can be used])
 983 # Check for LIBIDNs
 984 there_can_only_be_one=1
 985
 986 working_libidn1=0
 987 working_libidn2=0
 988 AS_IF([test x$my_with_libidn2 = x1],
 989       [AC_MSG_NOTICE([Checking for libidn2])
 990        AC_CHECK_LIB([idn2],
 991                     [idn2_to_unicode_8z8z],
 992                     [working_libidn2=1
 993                     LIBS="-lidn2 $LIBS"
 994                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 995                                        [1],
 996                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 997                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 998                      MISSING_SEP=", "])])
 999 AM_CONDITIONAL(HAVE_LIBIDN2,
1000                test x$working_libidn2 = x1)
1001 AS_IF([test x$working_libidn2 = x0],
1002       [AS_IF([test x$my_with_libidn = x1],
1003              [AC_MSG_NOTICE([Checking for libidn])
1004               AC_CHECK_LIB([idn],
1005                            [idna_to_ascii_8z],
1006                            [working_libidn1=1
1007                            LIBS="-lidn $LIBS"
1008                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1009                                               [1],
1010                                               [Define to 1 if you have 'libidn' (-lidn).])],
1011                            [there_can_only_be_one=0])],
1012              [AS_IF([test x$my_with_libidn2 = x1],
1013                     [there_can_only_be_one=0
1014                      AC_MSG_FAILURE([* There can only be one libidn.
1015                                      * Provide either libidn >= 1.13
1016                                      * or
1017                                      * libidn2 to the configure
1018                                      * script via
1019                                      * --with-libidn2
1020                                      * --with-libidn])])])])
1021 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1022
1023 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1024       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1025
1026 AS_IF([test x$there_can_only_be_one = x0],
1027       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1028
1029 # test for zlib
1030 SAVE_LDFLAGS=$LDFLAGS
1031 SAVE_CPPFLAGS=$CPPFLAGS
1032 AC_ARG_WITH(zlib,
1033             [  --with-zlib[[=DIR]]       use libz in DIR],
1034             [AS_IF([test "$withval" = "no"],
1035                    [AC_MSG_ERROR([GNUnet requires zlib])],
1036                    [test "$withval" != "yes"],
1037                    [Z_DIR=$withval
1038                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1039                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1040 AC_CHECK_HEADER(zlib.h,
1041                 [],
1042                 [AC_MSG_ERROR([GNUnet requires zlib])])
1043 AC_CHECK_LIB(z,
1044              compress2,
1045              [AC_DEFINE([HAVE_ZLIB],
1046                         [],
1047                         [Have compression library])
1048               if test "x${Z_DIR}" != "x"; then
1049                       Z_CFLAGS="-I${Z_DIR}/include"
1050                       Z_LIBS="-L${Z_DIR}/lib -lz"
1051               else
1052                       Z_LIBS="-lz"
1053               fi],
1054               [AC_MSG_ERROR([GNUnet requires zlib])])
1055 AC_SUBST(Z_CFLAGS)
1056 AC_SUBST(Z_LIBS)
1057
1058 AS_IF([test "$enable_shared" = "no"],
1059       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1060
1061
1062 # restore LIBS
1063 LIBS=$SAVE_LIBS
1064
1065
1066 # end of taler-only being false
1067 ])
1068
1069
1070 # check for iconv
1071 AM_ICONV
1072
1073 # test for libunistring
1074 gl_LIBUNISTRING
1075 AS_IF([test $HAVE_LIBUNISTRING != yes],
1076       [AC_MSG_ERROR([GNUnet requires libunistring])])
1077
1078 # under emscripten, $gl_libunistring_hexversion is undefined
1079 if test "$taler_only" != yes; then
1080
1081 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1082       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1083 fi
1084 AC_CHECK_HEADERS([unistr.h],
1085                  ,
1086                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1087
1088 # restore LIBS
1089 LIBS=$SAVE_LIBS
1090
1091
1092
1093 # Checks for standard header files.
1094 AC_HEADER_DIRENT
1095 AC_HEADER_STDC
1096
1097 # Check for headers that are ALWAYS required
1098 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1099
1100
1101
1102 # Checks for headers that are only required on some systems or
1103 # opional (and where we do NOT abort if they are not there)
1104 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1105
1106 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1107 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1108 [#ifdef HAVE_SYS_TYPES_H
1109 #include <sys/types.h>
1110 #endif
1111 #ifdef HAVE_NETINET_IN_SYSTM_H
1112 #include <netinet/in_systm.h>
1113 #endif
1114 #ifdef HAVE_NETINET_IN_H
1115 #include <netinet/in.h>
1116 #endif
1117 ])
1118
1119 SAVE_LDFLAGS=$LDFLAGS
1120 SAVE_CPPFLAGS=$CPPFLAGS
1121
1122 # test for sqlite
1123 sqlite=false
1124 AC_MSG_CHECKING(for SQLite)
1125 AC_ARG_WITH(sqlite,
1126   [  --with-sqlite=PFX       base of SQLite installation],
1127   [AC_MSG_RESULT("$with_sqlite")
1128    AS_CASE([$with_sqlite],
1129      [no],[],
1130      [yes],[
1131       AC_CHECK_HEADERS(sqlite3.h,
1132       sqlite=true)],
1133      [
1134     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1135     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1136     AC_CHECK_HEADERS(sqlite3.h,
1137      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1138      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1139      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1140      sqlite=true)
1141     LDFLAGS=$SAVE_LDFLAGS
1142     CPPFLAGS=$SAVE_CPPFLAGS
1143     ])
1144   ],
1145   [AC_MSG_RESULT([--with-sqlite not specified])
1146     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1147 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1148 AC_SUBST(SQLITE_CPPFLAGS)
1149 AC_SUBST(SQLITE_LDFLAGS)
1150
1151 LDFLAGS=$SAVE_LDFLAGS
1152 CPPFLAGS=$SAVE_CPPFLAGS
1153
1154 # test for postgres
1155 postgres=false
1156 # even running the check for postgres breaks emscripten ...
1157 AS_IF([test "$taler_only" != yes],
1158       [AX_LIB_POSTGRESQL([9.5],
1159         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1160          AC_CHECK_HEADERS([libpq-fe.h],
1161          postgres=true)
1162         ],
1163         [AC_MSG_RESULT([no postgres])])])
1164 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1165
1166
1167 LDFLAGS=$SAVE_LDFLAGS
1168 CPPFLAGS=$SAVE_CPPFLAGS
1169
1170 # mysql & windows
1171 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1172 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1173
1174 # test for mysql
1175 mysql=false
1176 mysqlfail=false
1177 SAVE_LDFLAGS=$LDFLAGS
1178 SAVE_CPPFLAGS=$CPPFLAGS
1179 AC_MSG_CHECKING(for mysql)
1180 AC_ARG_WITH(mysql,
1181   [  --with-mysql=PFX        base of MySQL installation],
1182   [AC_MSG_RESULT([$with_mysql])
1183    AS_CASE([$with_mysql],
1184      [no],[],
1185      [yes|""],[
1186       AC_CHECK_HEADERS(mysql/mysql.h,
1187        AC_CHECK_LIB(mysqlclient, mysql_init,
1188        mysql=true), [], [])
1189      ],[
1190       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1191       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1192       AC_CHECK_HEADERS(mysql/mysql.h,
1193        AC_CHECK_LIB(mysqlclient, mysql_init,
1194         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1195         MYSQL_CPPFLAGS="-I$with_mysql/include"
1196
1197         mysql=true), [], [])
1198      ])
1199   ],
1200   [AC_MSG_RESULT([--with-mysql not specified])
1201    if test -d "/usr/lib64/mysql"; then
1202     MYSQL_LIBDIR="/usr/lib64/mysql"
1203    elif test -d "/usr/lib/mysql"; then
1204     MYSQL_LIBDIR="/usr/lib/mysql"
1205    else
1206     MYSQL_LIBDIR="/usr/lib"
1207    fi
1208    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1209    AC_CHECK_LIB(mysqlclient, mysql_init,
1210     [AC_CHECK_HEADERS(mysql/mysql.h,
1211       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1212       mysql=true
1213
1214      , [], [])])
1215   ])
1216
1217 AC_SUBST(MYSQL_LDFLAGS)
1218 AC_SUBST(MYSQL_CPPFLAGS)
1219
1220 # additional version check for mysql
1221 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1222 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1223  [
1224   AC_MSG_CHECKING(mysql version)
1225   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1226     [[
1227       #include <mysql/mysql.h>]],
1228     [[
1229       #if (MYSQL_VERSION_ID < 40100)
1230       #error needs at least version >= 4.1
1231       #endif
1232       int main () { return 0; }
1233     ]])
1234     ],mysql=true,mysql=false)
1235   AS_IF([test "$mysql" = "false"],
1236    [
1237     mysqlfail=true
1238     AC_MSG_RESULT([fail, >= 4.1 required])
1239    ],[
1240     AC_MSG_RESULT(ok)
1241    ])
1242 ])
1243 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1244 AM_CONDITIONAL(HAVE_MYSQLE, false)
1245 # restore LIBS
1246 LIBS=$SAVE_LIBS
1247 LDFLAGS=$SAVE_LDFLAGS
1248 CPPFLAGS=$SAVE_CPPFLAGS
1249
1250 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1251 [
1252  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1253 ])
1254
1255 # libmicrohttpd
1256 lmhd=0
1257 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1258 AC_ARG_WITH(microhttpd,
1259    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1260        [base of libmicrohttpd installation])],
1261    [],
1262    [with_microhttpd=check])
1263 AS_CASE([$with_microhttpd],
1264    [no], [],
1265    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1266    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1267        [lmhd=1],
1268        [AC_MSG_WARN([Building without libmicrohttpd])])],
1269    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1270     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1271     export PKG_CONFIG_PATH
1272     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1273     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1274 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1275 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1276
1277 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1278
1279 # restore LIBS
1280 LIBS=$SAVE_LIBS
1281
1282 # check for gettext
1283 AM_GNU_GETTEXT([external])
1284 AM_GNU_GETTEXT_VERSION([0.18.1])
1285
1286 # Checks for standard typedefs, structures, and compiler characteristics.
1287 AC_TYPE_PID_T
1288 AC_TYPE_SIZE_T
1289 AC_TYPE_MODE_T
1290 AC_HEADER_TIME
1291 AC_HEADER_STAT
1292 AC_HEADER_STDBOOL
1293 AC_STRUCT_TM
1294
1295 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1296    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1297    ],
1298    [],
1299    [
1300       #include <sys/types.h>
1301       #include <sys/socket.h>
1302       #include <netinet/in.h>
1303    ])
1304
1305 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1306                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1307                             1,
1308                             [Do we have sockaddr_un.sun_len?])],
1309                 [],
1310                 [
1311                 #include <sys/types.h>
1312                 #include <sys/socket.h>
1313                 #include <sys/un.h>
1314                 ])
1315
1316
1317
1318 # Checks for library functions.
1319 AC_FUNC_CLOSEDIR_VOID
1320 AC_FUNC_FORK
1321 AC_PROG_GCC_TRADITIONAL
1322 AC_FUNC_MEMCMP
1323 AC_FUNC_SELECT_ARGTYPES
1324 AC_FUNC_CHOWN
1325
1326 AC_TYPE_SIGNAL
1327 AC_FUNC_STAT
1328 AC_FUNC_STRFTIME
1329 AC_FUNC_VPRINTF
1330 AC_HEADER_SYS_WAIT
1331 AC_TYPE_OFF_T
1332 AC_TYPE_UID_T
1333 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1334
1335 # restore LIBS
1336 LIBS=$SAVE_LIBS
1337
1338 GN_INTLINCL=""
1339 GN_LIBINTL="$LTLIBINTL"
1340 AC_ARG_ENABLE(framework,
1341               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1342               enable_framework_build=$enableval)
1343 AM_CONDITIONAL(WANT_FRAMEWORK,
1344                test x$enable_framework_build = xyes)
1345 AS_IF([test x$enable_framework_build = xyes],
1346       [AC_DEFINE([FRAMEWORK_BUILD],
1347                  1,
1348                  [Build a Mac OS X Framework])
1349       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1350       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1351       AC_LIB_APPENDTOVAR([CPPFLAGS],
1352                          [$GN_INTLINCL])])
1353
1354 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1355 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1356
1357 AC_SUBST(GN_LIB_LDFLAGS)
1358 AC_SUBST(GN_PLUGIN_LDFLAGS)
1359 AC_SUBST(GN_INTLINCL)
1360 AC_SUBST(GN_LIBINTL)
1361
1362 AC_SUBST(CPPFLAGS)
1363 AC_SUBST(LIBS)
1364 AC_SUBST(LDFLAGS)
1365 AC_SUBST(EXT_LIB_PATH)
1366 AC_SUBST(EXT_LIBS)
1367
1368 AC_SUBST(LIBPREFIX)
1369 AC_SUBST(DLLDIR)
1370 AC_SUBST(EXT_LIB_PATH)
1371
1372 DATAROOTDIR=$datarootdir
1373 AC_SUBST(DATAROOTDIR)
1374
1375 # test for sudo
1376 AC_MSG_CHECKING(for sudo)
1377 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1378 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1379 AC_ARG_WITH(sudo,
1380            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1381            [AC_MSG_RESULT("$with_sudo")
1382             AS_CASE([$with_sudo],
1383                     [no],[SUDO_BINARY=],
1384                     [yes],[SUDO_BINARY=sudo],
1385                     [SUDO_BINARY=$with_sudo])],
1386            [AC_MSG_RESULT([no])])
1387 AC_SUBST(SUDO_BINARY)
1388 AM_CONDITIONAL([HAVE_SUDO],
1389               [test "x$SUDO_BINARY" != "x" -o -w /])
1390
1391 # test for doas
1392 AC_MSG_CHECKING(for doas)
1393 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1394 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1395
1396 # test for gnunetdns group name
1397 GNUNETDNS_GROUP=gnunetdns
1398 AC_MSG_CHECKING(for gnunetdns group name)
1399 AC_ARG_WITH(gnunetdns,
1400             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1401             [AC_MSG_RESULT("$with_gnunetdns")
1402              AS_CASE([$with_gnunetdns],
1403                      [no],[GNUNETDNS_GROUP=gnunet],
1404                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1405                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1406             [AC_MSG_RESULT([gnunetdns])])
1407 AC_SUBST(GNUNETDNS_GROUP)
1408
1409
1410
1411 # gnutls
1412 gnutls=0
1413 gnutls_dane=0
1414 AC_MSG_CHECKING(for gnutls)
1415 AC_ARG_WITH(gnutls,
1416             [  --with-gnutls=PFX   base of gnutls installation],
1417             [AC_MSG_RESULT([$with_gnutls])
1418              AS_CASE([$with_gnutls],
1419                      [no],[],
1420                      [yes],
1421                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1422                                        AC_CHECK_LIB([gnutls],
1423                                                     [gnutls_priority_set],
1424                                                     gnutls=true))
1425                       AC_CHECK_HEADERS([gnutls/dane.h],
1426                                        AC_CHECK_LIB([gnutls-dane],
1427                                                     [dane_verify_crt_raw],
1428                                                     gnutls_dane=1))],
1429
1430         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1431         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1432         AC_CHECK_HEADERS([gnutls/abstract.h],
1433             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1434               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1435               gnutls=true))
1436         AC_CHECK_HEADERS([gnutls/dane.h],
1437             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1438               gnutls_dane=1))
1439       ])
1440    ],
1441    [AC_MSG_RESULT([--with-gnutls not specified])
1442     AC_CHECK_HEADERS([gnutls/abstract.h],
1443         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1444           gnutls=true))
1445     AC_CHECK_HEADERS([gnutls/dane.h],
1446         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1447                      gnutls_dane=1))
1448    ])
1449 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1450 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1451 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1452 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1453
1454
1455
1456 # Test if we are building for superMUC
1457 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1458 AC_ARG_ENABLE([supermuc],
1459     [AS_HELP_STRING([--enable-supermuc],
1460        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1461     [AS_IF([test "x$enable_supermuc" = "xno"],
1462       [supermuc=0],
1463       [supermuc=1])],
1464     [supermuc=0
1465      enable_supermuc=no])
1466 AC_MSG_RESULT($enable_SUPERMUC)
1467 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1468 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1469
1470 # Check if NSE has to send timestamp information to testbed logger for
1471 # generating histogram of messages received
1472 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1473 AC_ARG_ENABLE([nse-histogram],
1474     [AS_HELP_STRING([--enable-nse-histogram],
1475        [have NSE send timestamp information to testbed logger for generating
1476        histogram of received messages.  NOT useful for production (default is
1477        NO)])],
1478     [AS_IF([test "x$enableval" = "xno"],
1479       [nse_histogram=0],
1480       [nse_histogram=1])],
1481     [nse_histogram=0
1482      enable_nse_histogram=no])
1483 AC_MSG_RESULT($enable_nse_histogram)
1484 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1485 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1486                    [have NSE send timestamp information to testbed logger])
1487
1488 # should 'make check' run tests?
1489 AC_MSG_CHECKING(whether to run tests)
1490 AC_ARG_ENABLE([testruns],
1491    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1492    [enable_tests_run=${enableval}],
1493    [enable_tests_run=yes])
1494 AC_MSG_RESULT($enable_test_run)
1495 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1496
1497
1498 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1499 AC_ARG_ENABLE([benchmark],
1500    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1501    [enable_benchmark=${enableval}],
1502    [enable_benchmark=no])
1503 AC_MSG_RESULT($enable_benchmark)
1504 AS_IF([test "x$enable_benchmark" = "xyes"],
1505       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1506 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1507
1508
1509 # should expensive tests be run?
1510 AC_MSG_CHECKING(whether to run expensive tests)
1511 AC_ARG_ENABLE([expensivetests],
1512    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1513    [enable_expensive=${enableval}],
1514    [enable_expensive=no])
1515 AC_MSG_RESULT($enable_expensive)
1516 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1517
1518 # should ports be open for Java services?
1519 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1520 AC_ARG_ENABLE([javaports],
1521    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1522    [enable_java_ports=${enableval}],
1523    [enable_java_ports=no])
1524 AC_MSG_RESULT($enable_java_ports)
1525 AS_IF([test "x$enable_java_ports" = "xyes"],
1526  [JAVAPORT=""],
1527  [JAVAPORT="$UNIXONLY"])
1528 AC_SUBST(JAVAPORT)
1529
1530 # should benchmarks be run?
1531 AC_MSG_CHECKING(whether to run benchmarks during make check)
1532 AC_ARG_ENABLE([benchmarks],
1533    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1534    [enable_benchmarks=${enableval}],
1535    [enable_benchmarks=no])
1536 AC_MSG_RESULT($enable_benchmarks)
1537 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1538
1539 # should gnunet-testing be compiled
1540 AC_MSG_CHECKING(wether to compile gnunet-testing)
1541 AC_ARG_ENABLE([testing],
1542    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1543    [enable_testing=${enableval}],
1544    [enable_testing=yes])
1545 AC_MSG_RESULT($enable_testing)
1546 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1547
1548 # should experimental code be compiled (code that may not yet compile)?
1549 AC_MSG_CHECKING(whether to compile experimental code)
1550 AC_ARG_ENABLE([experimental],
1551    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1552    [enable_experimental=${enableval}],
1553    [enable_experimental=no])
1554 AC_MSG_RESULT($enable_experimental)
1555 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1556
1557 # should malicious code be compiled (should only be used for testing)?
1558 AC_MSG_CHECKING(whether to compile malicious code)
1559 AC_ARG_ENABLE([malicious],
1560    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1561    [AS_IF([test "x$enableval" = "xno"],
1562      [malicious=0],
1563      [malicious=1])],
1564    [malicious=0
1565     enable_malicious=no])
1566 AC_MSG_RESULT($enable_malicious)
1567 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1568 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1569                    [enable compilation of malicious code])
1570
1571 # should services be started on demand when needed?
1572 # Some services may choose to never start by default
1573 # and it is up to the service/module developer to decide
1574 # by having "START_ON_DEMAND = NO" instead of
1575 # "START_ON_DEMAND = @START_ON_DEMAND@"
1576 # in the service/module's conf.in file.
1577 # See also IMMEDIATE_START for an unconditional immediate start.
1578 START_ON_DEMAND="YES"
1579 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1580 AC_ARG_ENABLE([autostart],
1581    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1582    [enable_autostart=${enableval}
1583     AS_IF([test "x$enable_autostart" = "xno"],
1584       [START_ON_DEMAND="NO"])
1585    ],
1586    [enable_autostart=yes])
1587 AC_MSG_RESULT($enable_autostart)
1588 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1589 AC_SUBST(START_ON_DEMAND)
1590
1591 # should memory statistics be kept (very expensive CPU-wise!)
1592 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1593 AC_ARG_ENABLE([heapstats],
1594    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1595    [enable_heapstats=1],
1596    [enable_heapstats=0])
1597 AC_MSG_RESULT($enable_heapstats)
1598 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1599
1600
1601 # Check if the __thread storage class for
1602 # thread-local storage is available.
1603 AC_MSG_CHECKING(whether __thread is supported)
1604 AC_LINK_IFELSE(
1605 [AC_LANG_PROGRAM([#include <stdlib.h>
1606                    #undef __thread
1607                    static __thread int a = 1;],
1608                   [exit(a-1);])],
1609  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1610 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1611 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1612       [AC_MSG_RESULT(yes)],
1613       [AC_MSG_RESULT(no)])
1614
1615 # gcov compilation
1616 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1617 AC_ARG_ENABLE([coverage],
1618               AS_HELP_STRING([--enable-coverage],
1619                              [compile the library with code coverage support]),
1620               [use_gcov=${enableval}],
1621               [use_gcov=no])
1622 AC_MSG_RESULT($use_gcov)
1623 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1624
1625
1626 # version info
1627 # TODO: git blame says this predates our switch to git.
1628 # git-svn should be adjusted to simply git, or
1629 # an external script that does the job.
1630 AC_PATH_PROG(svnversioncommand, svnversion)
1631 AC_PATH_PROG(gitcommand, git)
1632 AC_MSG_CHECKING(for source being under a VCS)
1633
1634
1635 # version info
1636 AC_PATH_PROG(gitcommand, git)
1637 AC_MSG_CHECKING(for source being under a VCS)
1638 git_version=
1639 AS_IF([test ! "X$gitcommand" = "X"],
1640 [
1641   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1642 ])
1643 AS_IF([test "X$git_version" = "X"],
1644   [
1645     vcs_name="no"
1646     vcs_version="\"release\""
1647   ],
1648   [
1649     vcs_name="yes, git-svn"
1650     vcs_version="\"git-$git_version\""
1651   ])
1652 AC_MSG_RESULT($vcs_name)
1653
1654 AC_MSG_CHECKING(VCS version)
1655 AC_MSG_RESULT($vcs_version)
1656 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1657
1658 AC_CONFIG_FILES([
1659 Makefile
1660 contrib/Makefile
1661 contrib/hellos/Makefile
1662 contrib/services/Makefile
1663 contrib/services/openrc/Makefile
1664 contrib/services/systemd/Makefile
1665 contrib/scripts/Makefile
1666 contrib/scripts/gnunet-logread/Makefile
1667 doc/Makefile
1668 doc/man/Makefile
1669 doc/doxygen/Makefile
1670 doc/handbook/Makefile
1671 doc/tutorial/Makefile
1672 lint/Makefile
1673 m4/Makefile
1674 po/Makefile.in
1675 src/Makefile
1676 src/arm/Makefile
1677 src/arm/arm.conf
1678 src/ats/Makefile
1679 src/ats/ats.conf
1680 src/ats-tool/Makefile
1681 src/ats-tests/Makefile
1682 src/auction/Makefile
1683 src/block/Makefile
1684 src/cadet/Makefile
1685 src/cadet/cadet.conf
1686 src/core/Makefile
1687 src/core/core.conf
1688 src/consensus/Makefile
1689 src/consensus/consensus.conf
1690 src/conversation/Makefile
1691 src/conversation/conversation.conf
1692 src/curl/Makefile
1693 src/datacache/Makefile
1694 src/datastore/Makefile
1695 src/datastore/datastore.conf
1696 src/dht/Makefile
1697 src/dht/dht.conf
1698 src/dns/Makefile
1699 src/dns/dns.conf
1700 src/exit/Makefile
1701 src/fragmentation/Makefile
1702 src/fs/Makefile
1703 src/fs/fs.conf
1704 src/gns/Makefile
1705 src/gns/gns.conf
1706 src/gns/nss/Makefile
1707 src/gnsrecord/Makefile
1708 src/hello/Makefile
1709 src/identity/Makefile
1710 src/identity/identity.conf
1711 src/abd/Makefile
1712 src/abd/abd.conf
1713 src/include/Makefile
1714 src/integration-tests/Makefile
1715 src/json/Makefile
1716 src/hostlist/Makefile
1717 src/my/Makefile
1718 src/mysql/Makefile
1719 src/namecache/Makefile
1720 src/namecache/namecache.conf
1721 src/namestore/Makefile
1722 src/namestore/namestore.conf
1723 src/nat/Makefile
1724 src/nat/nat.conf
1725 src/nat-auto/Makefile
1726 src/nat-auto/nat-auto.conf
1727 src/nse/Makefile
1728 src/nse/nse.conf
1729 src/nt/Makefile
1730 src/peerinfo/Makefile
1731 src/peerinfo/peerinfo.conf
1732 src/peerinfo-tool/Makefile
1733 src/peerstore/Makefile
1734 src/peerstore/peerstore.conf
1735 src/pq/Makefile
1736 src/pt/Makefile
1737 src/regex/Makefile
1738 src/regex/regex.conf
1739 src/revocation/Makefile
1740 src/revocation/revocation.conf
1741 src/rps/Makefile
1742 src/rps/rps.conf
1743 src/secretsharing/Makefile
1744 src/secretsharing/secretsharing.conf
1745 src/scalarproduct/Makefile
1746 src/scalarproduct/scalarproduct.conf
1747 src/set/Makefile
1748 src/set/set.conf
1749 src/sq/Makefile
1750 src/statistics/Makefile
1751 src/statistics/statistics.conf
1752 src/template/Makefile
1753 src/testbed/Makefile
1754 src/testbed/testbed.conf
1755 src/testbed-logger/Makefile
1756 src/testbed-logger/testbed-logger.conf
1757 src/testing/Makefile
1758 src/topology/Makefile
1759 src/transport/Makefile
1760 src/transport/transport.conf
1761 src/util/Makefile
1762 src/util/resolver.conf
1763 src/vpn/Makefile
1764 src/vpn/vpn.conf
1765 src/zonemaster/Makefile
1766 src/zonemaster/zonemaster.conf
1767 src/rest/Makefile
1768 src/abe/Makefile
1769 src/reclaim-attribute/Makefile
1770 src/reclaim/Makefile
1771 pkgconfig/Makefile
1772 pkgconfig/gnunetarm.pc
1773 pkgconfig/gnunetats.pc
1774 pkgconfig/gnunetblock.pc
1775 pkgconfig/gnunetcadet.pc
1776 pkgconfig/gnunetconsensus.pc
1777 pkgconfig/gnunetconversation.pc
1778 pkgconfig/gnunetcore.pc
1779 pkgconfig/gnunetdatacache.pc
1780 pkgconfig/gnunetdatastore.pc
1781 pkgconfig/gnunetdht.pc
1782 pkgconfig/gnunetdns.pc
1783 pkgconfig/gnunetenv.pc
1784 pkgconfig/gnunetfragmentation.pc
1785 pkgconfig/gnunetfs.pc
1786 pkgconfig/gnunetgns.pc
1787 pkgconfig/gnunethello.pc
1788 pkgconfig/gnunetidentity.pc
1789 pkgconfig/gnunetmicrophone.pc
1790 pkgconfig/gnunetmysql.pc
1791 pkgconfig/gnunetnamestore.pc
1792 pkgconfig/gnunetnat.pc
1793 pkgconfig/gnunetnse.pc
1794 pkgconfig/gnunetpeerinfo.pc
1795 pkgconfig/gnunetpq.pc
1796 pkgconfig/gnunetregex.pc
1797 pkgconfig/gnunetrevocation.pc
1798 pkgconfig/gnunetrps.pc
1799 pkgconfig/gnunetscalarproduct.pc
1800 pkgconfig/gnunetset.pc
1801 pkgconfig/gnunetspeaker.pc
1802 pkgconfig/gnunetstatistics.pc
1803 pkgconfig/gnunettestbed.pc
1804 pkgconfig/gnunettesting.pc
1805 pkgconfig/gnunettransport.pc
1806 pkgconfig/gnunetutil.pc
1807 pkgconfig/gnunetvpn.pc
1808 ])
1809 AC_OUTPUT
1810
1811
1812 # FIXME: `some modules' -> be more specific which exact modules.
1813
1814 # java ports
1815 AS_IF([test "x$enable_java_ports" = "xyes"],
1816       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1817
1818 ####
1819 #### Lasciate ogne speranza, voi ch'intrate
1820 ####
1821 #### This could be moved to the checks above,
1822 #### but for now let's keep it here.
1823 ####
1824
1825 # -- print message regarding enabled experimental features
1826 AS_IF([test "x$enable_experimental" = "xyes"],
1827       [experimental_msg="experimental features enabled"])
1828 # -- OSX Framework
1829 AS_IF([test "$enable_framework_build" = "yes"],
1830       [macosx_framework_msg="yes"],
1831       [macosx_framework_msg="no"])
1832 # -- libidn 2
1833 AS_IF([test "x$working_libidn2" = x1],
1834       [libidn2_msg="libidn2"])
1835 # -- libidn 1
1836 AS_IF([test "x$working_libidn1" = x1],
1837       [libidn1_msg="libidn1"])
1838 # -- texi2mdoc
1839 AS_IF([test "x$texi2mdoc_generation" = x1],
1840       [mdoc_msg="yes"],
1841       [mdoc_msg="no"])
1842 # -- texinfo
1843 AS_IF([test "x$makeinfo" != "x1"],
1844       [texinfo_msg="no"],
1845       [texinfo_msg="yes"])
1846 # -- conversation
1847 AS_IF([test "x$conversation_backend" = "xnone"],
1848       [AS_IF([test "x$pulse" != "x1"],
1849              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1850               libpulse_msg="no"],
1851              [libpulse_msg="yes"])
1852        AS_IF([test "x$opus" != "x1"],
1853              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1854               libopus_msg="no"],
1855              [libopus_msg="yes"])
1856        AS_IF([test "x$gst" != "x1"],
1857              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1858               gstreamer_msg="no"],
1859              [gstreamer_msg="yes"])],
1860       [features_msg="$features_msg conversation"])
1861 # -- interface
1862 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1863 # -- libmicrohttpd
1864 AS_IF([test "x$lmhd" != "x1"],
1865       [libmicrohttpd_msg="no (optional)"],
1866       [libmicrohttpd_msg="yes"])
1867 # -- jansson
1868 AS_IF([test "x$jansson" = "x0"],
1869       [jansson_msg="no (optional)"],
1870       [jansson_msg="yes"])
1871 # -- libextractor
1872 AS_IF([test "$extractor" != 1],
1873       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1874       [libextractor_msg="yes"])
1875 # -- libzbar
1876 AS_IF([test "x$zbar" = "x1"],
1877       [libzbar_msg="yes"
1878        features_msg="$features_msg gnunet-qr"],
1879       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1880        libzbar_msg="no"])
1881 # -- libgnurl
1882 AS_IF([test "$gnurl" = "0"],
1883       [AS_IF([test "x$curl" = "xfalse"],
1884              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1885               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1886               curl_msg="no"],
1887              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1888               curl_msg="yes"])],
1889        [gnurl_msg="yes"])
1890 # -- ifconfig
1891 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
1892       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
1893        ifconfig_msg="no (optional)"],
1894       [ifconfig_msg="yes"])
1895 # -- upnpc
1896 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
1897       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
1898        upnpc_msg="no (optional)"],
1899       [upnpc_msg="yes"])
1900 # -- iptables
1901 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
1902       [AC_MSG_NOTICE([WARNING: optional iptables not found])
1903        iptables_msg="no (optional)"],
1904       [iptables_msg="yes"])
1905 # -- bluetooth
1906 AS_IF([test "x$bluetooth" = "x0"],
1907       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
1908        bluetooth_msg="no (optional)"],
1909       [bluetooth_msg="yes"])
1910 # -- gnutls
1911 AS_IF([test x$gnutls != xtrue],
1912       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
1913        gnutls_msg="no"],
1914       [AS_IF([test "x$gnutls_dane" != "x1"],
1915              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
1916               gnutls_msg="yes (without DANE support)"],
1917              [gnutls_msg="yes (with DANE support)"])])
1918 # -- databases
1919 AS_IF([test $mysqlfail = true]
1920       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
1921 AS_IF([test "$mysql" = true],
1922       [features_msg="$features_msg mysql"
1923        mysql_msg="yes"],
1924       [mysql_msg="no"])
1925 AS_IF([test "$sqlite" = true],
1926       [features_msg="$features_msg sqlite"
1927        sqlite_msg="yes"],
1928       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1929        sqlite_msg="no"])
1930 AS_IF([test "$postgres" = true],
1931       [features_msg="$features_msg postgres"
1932        postgres_msg="yes"],
1933       [postgres_msg="no"])
1934 # -- features
1935 # ---- 1. replace spaces with newlines,
1936 # ---- 2. sort the lines,
1937 # ---- 3. replace the newlines with spaces.
1938 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
1939 AC_SUBST(features_msg)
1940
1941
1942 # The summary
1943 # TODO: reduce the length of the last message block ("the message")
1944
1945 AC_MSG_NOTICE([
1946 GNUnet Configuration
1947
1948 gnunet version:                 ${VERSION}
1949
1950 Host setup:                     ${host}
1951 Install prefix:                 ${prefix}
1952 Compiler:                       ${CC}
1953 CFLAGS:                         ${CFLAGS}
1954 CPPFLAGS:                       ${CPPFLAGS}
1955 LDFLAGS:                        ${LDFLAGS}
1956 LIBS:                           ${LIBS}
1957 Build Target:                   $build_target
1958 Mac OSX framework build:        ${macosx_framework_msg}
1959
1960 Default Interface:              ${interface_msg}
1961
1962 MySQL:                          ${mysql_msg}
1963 PostgreSQL:                     ${postgres_msg}
1964 sqlite3:                        ${sqlite_msg}
1965 gnurl:                          ${gnurl_msg}
1966 curl:                           ${curl_msg}
1967 bluetooth:                      ${bluetooth_msg}
1968 jansson:                        ${jansson_msg}
1969 iptables:                       ${iptables_msg}
1970 ifconfig:                       ${ifconfig_msg}
1971 upnpc:                          ${upnpc_msg}
1972 gnutls:                         ${gnutls_msg}
1973 libzbar:                        ${libzbar_msg}
1974 java:                           ${java_msg}
1975 libmicrohttpd:                  ${libmicrohttpd_msg}
1976 libidn:                         ${libidn1_msg}${libidn2_msg}
1977 libopus:                        ${libopus_msg}
1978 gstreamer:                      ${gstreamer_msg}
1979 libpulse:                       ${libpulse_msg}
1980 libextractor:                   ${libextractor_msg}
1981
1982 texinfo manual:                 ${texinfo_msg}
1983 transpiled mdoc manual:         ${mdoc_msg}
1984
1985 features:                       ${features_msg}
1986 experimental:                   ${experimental_msg}
1987
1988
1989 IMPORTANT:
1990
1991 Please make sure NOW that you have created a user and group 'gnunet'
1992 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
1993 type:
1994
1995   addgroup gnunetdns
1996   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1997
1998 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1999 'gnunet'.  Then, you can compile GNUnet with
2000
2001   make
2002
2003 After that, run (if necessary as 'root')
2004
2005   make install
2006
2007 to install everything.
2008
2009 Each GNUnet user should be added to the 'gnunet' group (may
2010 require fresh login to come into effect):
2011
2012   adduser USERNAME gnunet
2013
2014 (run the above command as root once for each of your users, replacing
2015 "USERNAME" with the respective login names).  If you have a global IP
2016 address, no further configuration is required.
2017
2018 For more detailed setup instructions, see https://docs.gnunet.org/
2019
2020 Optionally, download and compile gnunet-gtk to get a GUI for
2021 file-sharing and configuration.  This is particularly recommended
2022 if your network setup is non-trivial, as gnunet-setup can be
2023 used to test in the GUI if your network configuration is working.
2024 gnunet-setup should be run as the "gnunet" user under X.  As it
2025 does very little with the network, running it as "root" is likely
2026 also harmless.  You can also run it as a normal user, but then
2027 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2028 home directory in the end.
2029
2030 Once you have configured your peer, run (as the 'gnunet' user)
2031
2032   gnunet-arm -s
2033
2034 to start the peer.  You can then run the various GNUnet-tools as
2035 your "normal" user (who should only be in the group 'gnunet').
2036 ])