configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_CPP
  47 AC_PROG_CXX
  48 AC_PROG_OBJC
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AM_PROG_CC_C_O
  53 LT_INIT([disable-static dlopen win32-dll])
  54 AC_SUBST(MKDIR_P)
  55
  56 # allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 # large file support
  60 AC_SYS_LARGEFILE
  61 AC_FUNC_FSEEKO
  62
  63
  64 CFLAGS="-Wall $CFLAGS"
  65 # use '-fno-strict-aliasing', but only if the compiler can take it
  66 AS_IF([gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  67  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  68
  69 # Use Linux interface name unless the OS has a different preference
  70 DEFAULT_INTERFACE="\"eth0\""
  71
  72 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
  73
  74 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  75 native_srcdir=$srcdir
  76
  77 OLD_LDFLAGS="$LDFLAGS"
  78 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
  79
  80 # Check system type
  81 AS_CASE(["$host_os"],
  82   [*darwin* | *rhapsody* | *macosx*],[
  83      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  84      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  85      CFLAGS="-fno-common $CFLAGS"
  86      LDFLAGS="$OLD_LDFLAGS"
  87      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
  88      AC_CHECK_LIB(intl, gettext)
  89      build_target="darwin"
  90      DEFAULT_INTERFACE="\"en0\""
  91      LIBPREFIX=
  92      DLLDIR=lib
  93      UNIXONLY="#"
  94   ],
  95   [linux*],[
  96      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
  97      build_target="linux"
  98      LIBPREFIX=
  99      DLLDIR=lib
 100      UNIXONLY="#"
 101      AC_PATH_XTRA
 102   ],
 103   [*freebsd*],[
 104      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 105      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 106      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 107      build_target="freebsd"
 108      LIBPREFIX=
 109      DLLDIR=lib
 110      UNIXONLY="#"
 111   ],
 112   [*openbsd*],[
 113      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 114      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 115      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 116      build_target="openbsd"
 117      LIBPREFIX=
 118      DLLDIR=lib
 119      UNIXONLY="#"
 120   ],
 121   [*netbsd*],[
 122      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 123      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 124      LIBPREFIX=
 125      DLLDIR=lib
 126      UNIXONLY="#"
 127   ],
 128   [*solaris*],[
 129      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 130      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 131      AC_CHECK_LIB(resolv, res_init)
 132      AC_CHECK_LIB(rt, nanosleep)
 133      build_target="solaris"
 134      LIBPREFIX=
 135      DLLDIR=lib
 136      UNIXONLY="#"
 137   ],
 138   [*arm-linux*],[
 139      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 140      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 141      build_target="linux"
 142      LIBPREFIX=
 143      DLLDIR=lib
 144      UNIXONLY="#"
 145   ],
 146   [*cygwin*],[
 147      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 148      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 149      AC_CHECK_LIB(intl, gettext)
 150      CFLAGS="-mms-bitfields $CFLAGS"
 151      build_target="cygwin"
 152      LIBPREFIX=lib
 153      DLLDIR=bin
 154      AC_PROG_CXX
 155      UNIXONLY=""
 156   ],
 157   [*mingw*],[
 158      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 159      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 160      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 161      AC_CHECK_LIB(intl, gettext)
 162      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 163      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 164      CFLAGS="-mms-bitfields $CFLAGS"
 165      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 166      build_target="mingw"
 167      AC_PROG_CXX
 168      LIBPREFIX=lib
 169      DLLDIR=bin
 170      UNIXONLY=""
 171      funcstocheck=""
 172      native_srcdir=$(cd $srcdir; pwd -W)
 173   ],
 174   [gnu*],[
 175      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 176      build_target="gnu"
 177      UNIXONLY="#"
 178   ],
 179   [
 180      AC_MSG_RESULT(Unrecognised OS $host_os)
 181      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 182      UNIXONLY=""
 183 ])
 184 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 185 AC_SUBST(DEFAULT_INTERFACE)
 186
 187 # Disable TCP-based IPC on systems that support UNIX domain
 188 # sockets in default configuratin:
 189 AC_SUBST(UNIXONLY)
 190
 191
 192 AC_MSG_CHECKING([for build target])
 193 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 194 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 195 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 196 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 197 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 198 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 199 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 200 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 201
 202 AC_MSG_RESULT([$build_target])
 203 AC_SUBST(build_target)
 204 AM_CONDITIONAL([am__fastdepOBJC], false)
 205 AC_UNALIGNED_64_ACCESS
 206
 207 # some other checks for standard libs
 208 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 209 AC_SEARCH_LIBS([memrchr], [],
 210                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 211 AC_SEARCH_LIBS([memset_s], [],
 212                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 213 AC_SEARCH_LIBS([memset_s], [],
 214                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 215 AC_CHECK_LIB(socket, socket)
 216 AC_CHECK_LIB(m, log)
 217 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 218
 219 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 220 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 221
 222 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 223 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 224 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 225 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 226
 227 # autotools' m4 for python has no maximum version!
 228 # python3.4 - python3.7 for tests
 229 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python])
 230 AM_PATH_PYTHON([3.4],, [:])
 231 AC_SUBST([PYTHON])
 232 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 233
 234 # perl
 235 AC_PATH_PROG( PERL, perl, ,
 236               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 237 AC_SUBST([PERL])
 238
 239 # iptables is a soft requirement to run tests
 240 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 241
 242 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 243  [AS_IF([test -x "/sbin/iptables"],
 244    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 245    [AS_IF([test -x "/usr/sbin/iptables"],
 246       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 247
 248 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 249  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 250  [AC_MSG_WARN([warning: 'iptables' not found.])])
 251
 252 # ip6tables is a soft requirement for some features
 253 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 254
 255 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 256   [AS_IF([test -x "/sbin/ip6tables"],
 257      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 258      [AS_IF([test -x "/usr/sbin/ip6tables"],
 259         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 260
 261
 262 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 263   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 264   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 265
 266 # ip is a soft requirement for some features
 267 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 268
 269 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 270  [AS_IF([test -x "/sbin/ip"],
 271    [VAR_IP_BINARY="/sbin/ip"],
 272    [AS_IF([test -x "/usr/sbin/ip"],
 273           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 274
 275 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 276  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 277  [AC_MSG_WARN([warning: 'ip' not found.])])
 278
 279 # locate 'ifconfig'
 280 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 281
 282 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 283 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 284   [AS_IF([test -x "/sbin/ifconfig"],
 285      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 286      [AS_IF([test -x "/usr/sbin/ifconfig"],
 287             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 288
 289 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 290   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 291   [AC_MSG_WARN(['ifconfig' not found.])])
 292
 293
 294 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 295
 296 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 297 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 298       [AS_IF([test -x "/sbin/sysctl"],
 299              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 300              [AS_IF([test -x "/usr/sbin/sysctl"],
 301                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 302 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 303       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 304       [AC_MSG_WARN(['sysctl' not found.])])
 305
 306 # miniupnpc / upnpc binary is a soft runtime requirement
 307 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 308
 309 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 310   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 311   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 312
 313 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 314   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 315      [Define if struct tm has the tm_gmtoff member.])],
 316      ,
 317      [#include <time.h>])
 318
 319 AC_CHECK_DECLS([_stati64])
 320
 321 # 'save' libs; only those libs found so far will be
 322 # linked against _everywhere_.  For the others, we
 323 # will be more selective!
 324 SAVE_LIBS=$LIBS
 325
 326 have_addrinfo_a=0
 327 AC_CHECK_LIB(anl,
 328              getaddrinfo_a,
 329              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 330                                           1,
 331                                           [getaddrinfo_a supported])])
 332 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 333                [test "$have_addrinfo_a" = 1])
 334
 335 # tests only run on Windows
 336 AS_IF([test "x$build_target" = "xmingw"],
 337       [AC_CHECK_LIB(plibc,
 338                     plibc_init,
 339                     [],
 340                     [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 341        AC_CHECK_LIB(gnurx,
 342                     regexec,
 343                     [],
 344                     [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])])
 345
 346 # libgcrypt
 347 gcrypt=0
 348 NEED_LIBGCRYPT_API=1
 349 NEED_LIBGCRYPT_VERSION=1.6.0
 350
 351
 352 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 353 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 354
 355 AS_IF([test $gcrypt = 0],
 356  [
 357   AC_MSG_ERROR([[
 358 ***
 359 *** You need libgcrypt to build this program.
 360 **  This library is for example available at
 361 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 362 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 363 ***  is required.)
 364 ***]])
 365 ])
 366 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 367
 368 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 369
 370
 371
 372 # should the build process be building the documentation?
 373 AC_MSG_CHECKING(whether to build documentation)
 374 AC_ARG_ENABLE([documentation],
 375               [AS_HELP_STRING([--disable-documentation],
 376                               [do not build the documentation])],
 377               [documentation=${enableval}],
 378               [documentation=yes])
 379 AC_MSG_RESULT($documentation)
 380 AS_IF([test "x$documentation" = "xyes"],
 381       [AM_CONDITIONAL([DOCUMENTATION],
 382                       true)
 383        AC_DEFINE([DOCUMENTATION],
 384                  [1],
 385                  [Building the documentation])],
 386       [AM_CONDITIONAL([DOCUMENTATION],
 387                       false)
 388        AC_DEFINE([DOCUMENTATION],
 389                  [0],
 390                  [Not building the documentation])])
 391
 392 # COMMENT: Check wether to transpile texinfo to mdoc.
 393 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 394 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 395 # COMMENT: and makes the configure fail if it is missing.
 396 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 397 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 398 # COMMENT: or nothing was set (this is the default).
 399 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 400 # COMMENT: potential non-existence of the texi2mdoc binary.
 401 # COMMENT: Default return value / setting: no
 402 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 403 AC_ARG_ENABLE([texi2mdoc-generation],
 404               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 405                               [include generated texi2mdoc output in installation])],
 406               [texi2mdoc_generation=${enableval}],
 407               [texi2mdoc_generation=no])
 408 AC_MSG_RESULT($texi2mdoc_generation)
 409 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 410       [AS_IF([test "$texi2mdoc" = 0],
 411              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 412               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your Operating System])
 413               AC_MSG_WARN([ERROR: package manager or from https://mandoc.bsd.lv/texi2mdoc/])],
 414              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 415               AC_DEFINE([TEXI2MDOC_GENERATION],
 416                         [1],
 417                         [Building section 7 mdoc output])])],
 418       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 419                       false)
 420        AC_DEFINE([TEXI2MDOC_GENERATION],
 421                  [0],
 422                  [Not building section 7 mdoc output])])
 423
 424 # should the build process be building only the documentation?
 425 AC_MSG_CHECKING(whether to build only documentation)
 426 AC_ARG_ENABLE([documentation-only],
 427    [AS_HELP_STRING([--enable-documentation-only], [build only the documentation])],
 428    [documentation_only=${enableval}],
 429    [documentation_only=no])
 430 AC_MSG_RESULT($documentation_only)
 431 AS_IF([test "x$documentation_only" = "xyes"],
 432  [
 433   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 434   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 435  ],[
 436   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 437   # TODO: Double negation might be a bit hard to parse for some
 438   # TODO: people reading the output.
 439   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Not building only the documentation])
 440  ])
 441
 442 # should the build process be including the manpages? (default: yes)
 443 AC_MSG_CHECKING(whether to include man pages)
 444 AC_ARG_ENABLE([include-manpages],
 445    [AS_HELP_STRING([--disable-include-manpages], [Do not include the man pages in build and installation])],
 446    [include_manpages=${enableval}],
 447    [include_manpages=yes])
 448 AC_MSG_RESULT($include_manpages)
 449 AS_IF([test "x$include_manpages" = "xyes"],
 450  [
 451   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 452   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 453  ],[
 454   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 455   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 456  ])
 457
 458 # Adam shostack suggests the following for Windows:
 459 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 460 AC_ARG_ENABLE(gcc-hardening,
 461    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 462 [AS_IF([test x$enableval = xyes],[
 463     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 464     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 465     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 466     LDFLAGS="$LDFLAGS -pie"
 467  ])])
 468
 469 # Linker hardening options
 470 # Currently these options are ELF specific - you can't use this with MacOSX
 471 AC_ARG_ENABLE(linker-hardening,
 472   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 473 [AS_IF([test x$enableval = xyes],
 474    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 475
 476
 477 AC_ARG_ENABLE(sanitizer,
 478   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 479 [AS_IF([test x$enableval = xyes],[
 480    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 481  ])])
 482
 483
 484 extra_logging=GNUNET_NO
 485 AC_ARG_ENABLE([logging],
 486    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 487    [AS_IF([test "x$enableval" = "xyes"], [],
 488           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 489           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 490           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 491    ], [])
 492 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 493
 494 # should memory poisoning be enabled?
 495 AC_MSG_CHECKING(whether to poison freed memory)
 496 AC_ARG_ENABLE([poisoning],
 497    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 498    [enable_poisoning=${enableval}],
 499    [
 500      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 501        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 502        [enable_poisoning=no])
 503    ])
 504 AC_MSG_RESULT($enable_poisoning)
 505 AS_IF([test ! "x$enable_poisoning" = "xno"],
 506   [enable_poisoning=1],
 507   [enable_poisoning=0])
 508 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 509
 510 AS_IF([test $build = $target],
 511 [
 512 AC_MSG_CHECKING([for working HMAC])
 513 AC_LANG_PUSH(C)
 514 LIBS="$LIBS $LIBGCRYPT_LIBS"
 515 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 516 AC_RUN_IFELSE(
 517   [AC_LANG_PROGRAM([#include <gcrypt.h>
 518         #include <stdio.h>], [[
 519         gcry_md_hd_t mac;
 520
 521         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 522             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 523             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 524         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 525         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 526             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 527             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 528             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 529             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 530             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 531
 532         if (!gcry_check_version (GCRYPT_VERSION))
 533         {
 534           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 535           return 1;
 536         }
 537
 538         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 539         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 540
 541         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 542         {
 543           fprintf (stderr, "gcry_md_open error\n");
 544           return 2;
 545         }
 546
 547         gcry_md_setkey (mac, key, sizeof (key));
 548         gcry_md_write (mac, data, sizeof (data));
 549
 550         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 551         {
 552           fprintf (stderr, "memcmp error\n");
 553           return 3;
 554         }
 555
 556         gcry_md_close (mac);
 557
 558         return 0;
 559     ]])],
 560   [AC_MSG_RESULT([yes])],
 561   [
 562    RESULT=$?
 563    if test $RESULT = 3
 564    then
 565      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 566    fi
 567    if test $RESULT = 2
 568    then
 569      AC_MSG_FAILURE([HMAC test failed])
 570    fi
 571    if test $RESULT = 1
 572    then
 573      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 574    fi
 575   ],
 576   [AC_MSG_RESULT([cross compiling, test skipped])])
 577 AC_LANG_POP(C)
 578 ])      # $build = $target
 579
 580 # check for bluetooth library
 581 bluetooth=0
 582 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 583 AS_IF([test "$build_target" = "mingw"],
 584  [bluetooth=1])
 585 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 586 AS_IF([test "$bluetooth" = 1],
 587  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 588  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 589
 590 # check for zbar library
 591 zbar=0
 592 AC_MSG_CHECKING(for libzbar)
 593 AC_ARG_WITH(zbar,
 594    [  --with-zbar=PREFIX (base of libzbar installation)],
 595    [AC_MSG_RESULT([$with_zbar])
 596     AS_CASE([$with_zbar],
 597       [no],[],
 598       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 599       [
 600         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 601         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 602         AC_CHECK_HEADERS(zbar.h,
 603           AC_CHECK_LIB([zbar], [zbar_processor_create],
 604             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 605             zbar=1))
 606        ])
 607    ],
 608    [AC_MSG_RESULT([--with-zbar not specified])
 609     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 610 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 611 AS_IF([test "x$zbar" = x1],
 612       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 613       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 614
 615 # check for jansson library
 616 jansson=0
 617 AC_MSG_CHECKING(for libjansson)
 618 AC_ARG_WITH(jansson,
 619    [  --with-jansson=PREFIX (base of libjansson installation)],
 620    [AC_MSG_RESULT([$with_jansson])
 621     AS_CASE([$with_jansson],
 622       [no],[],
 623       [yes],[
 624         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 625       ],[
 626         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 627         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 628         AC_CHECK_HEADERS(jansson.h,
 629           AC_CHECK_LIB([jansson], [json_loads],
 630             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 631             jansson=1))
 632       ])
 633    ],
 634    [AC_MSG_RESULT([--with-jansson not specified])
 635     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 636 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 637 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 638 AS_IF([test "x$jansson" = x1],
 639       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 640       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 641
 642
 643 # check for libpulse(audio) library
 644 pulse=0
 645 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,jansson=1,)
 646 AS_IF([test "$build_target" = "mingw"],
 647       [pulse=0])
 648 AS_IF([test "$pulse" = 1],
 649       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])])
 650
 651 # check for libopus(audio) library
 652 opus=0
 653 CHECK_LIBHEADER(LIBOPUS,
 654                 opus,
 655                 opus_decode_float,
 656                 opus/opus.h,
 657                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 658 AS_IF([test "x$opus" = x1],
 659       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])])
 660
 661 # libogg
 662 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 663         [AC_CHECK_HEADERS([ogg/ogg.h],
 664           AM_CONDITIONAL(HAVE_OGG, true)
 665           ogg=1
 666           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 667           AM_CONDITIONAL(HAVE_OGG, false)
 668           ogg=0
 669           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 670         AM_CONDITIONAL(HAVE_OGG, false)
 671         ogg=0)
 672
 673
 674 PKG_CHECK_MODULES([GLIB],
 675                   [glib-2.0],
 676   [# check for pbc library
 677   pbc=0
 678    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 679    AC_CHECK_HEADER([gabe.h],abe=1)
 680    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 681    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 682    AS_IF([test "x$pbc" = x1],
 683      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 684      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 685    AS_IF([test "x$abe" = x1],
 686     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 687     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 688   [# glib-2 not found
 689    AM_CONDITIONAL(HAVE_PBC, [false])
 690    AM_CONDITIONAL(HAVE_ABE, [false])
 691    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 692
 693 gst=0
 694 PKG_CHECK_MODULES(
 695   [GST],
 696   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 697   [gst=1],
 698   [gst=0])
 699
 700 # Pulse Audio
 701 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 702  AS_IF([test "x$gst" != "x1"],[
 703   conversation_backend=none
 704   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 705   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 706   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 707  ],[
 708    conversation_backend=gst
 709    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 710    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 711    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 712  ])
 713 ],[
 714  conversation_backend=pulse
 715  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 716  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 717  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 718 ])
 719
 720 # libgnurl
 721 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 722
 723 SAVE_CPPFLAGS=$CPPFLAGS
 724 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 725 LIBS="$LIBGNURL $LIBCURL $LIBS"
 726
 727 # libcurl-gnutls
 728 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 729 AS_IF([test "x$curl" = xtrue],[
 730  AC_CHECK_HEADER([curl/curl.h],
 731   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 732   [curl=false])
 733  # need libcurl-gnutls.so, everything else is not acceptable
 734  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 735  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 736 ])
 737
 738 # libcurl and libgnurl should be mutually exclusive
 739 AS_IF([test "$gnurl" = 1],
 740       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 741        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 742        AM_CONDITIONAL(HAVE_LIBCURL, false)
 743        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 744       [AS_IF([test "$curl" = true],
 745              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 746               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 747               AM_CONDITIONAL(HAVE_LIBCURL, true)
 748               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 749              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 750               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 751               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 752               AM_CONDITIONAL(HAVE_LIBCURL, false)
 753               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 754
 755 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 756 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 757
 758 # restore LIBS & CPPFLAGS
 759 LIBS=$SAVE_LIBS
 760 CPPFLAGS=$SAVE_CPPFLAGS
 761
 762 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 763 # GLPK must support glpk_init_env, version >= 4.43
 764 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 765 # GLPK must support atm MLP presolving, version >= 4.32
 766 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 767 AS_IF([test "x$glpk" = xfalse],
 768 [
 769         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 770         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 771 ],[
 772         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 773         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 774 ])
 775
 776
 777 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 778 AS_IF([test x$nss = xfalse],
 779   [
 780         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 781         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 782   ],[
 783         NSS_INCLUDES="
 784         #include <nss.h>
 785         "
 786         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 787                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 788                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 789                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 790                 [$NSS_INCLUDES])
 791 ])
 792
 793
 794
 795 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 796 AC_CHECK_LIB([kvm],[kvm_open])
 797 AC_CHECK_LIB([kstat],[kstat_open])
 798
 799
 800 # should the build process be restricted to the code required
 801 # for GNU Taler wallets?
 802 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 803 AC_ARG_ENABLE([taler-wallet],
 804    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 805    [taler_only=${enableval}],
 806    [taler_only=no])
 807 AC_MSG_RESULT($taler_only)
 808 AS_IF([test "x$taler_only" = "xyes"],
 809 [
 810   AM_CONDITIONAL([TALER_ONLY],true)
 811   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 812 ],[
 813   AM_CONDITIONAL([TALER_ONLY],false)
 814   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 815 ])
 816
 817 # test for libextractor
 818 extractor=0
 819 AC_MSG_CHECKING(for libextractor)
 820 AC_ARG_WITH(extractor,
 821    [  --with-extractor=PREFIX (base of libextractor installation)],
 822    [AC_MSG_RESULT([$with_extractor])
 823     AS_CASE([$with_extractor],
 824       [no],[],
 825       [yes],[
 826         AC_CHECK_HEADERS([extractor.h],
 827           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 828             extractor=1))
 829       ],[
 830         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 831         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 832         AC_CHECK_HEADERS([extractor.h],
 833           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 834             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 835             extractor=1))
 836       ])
 837    ],
 838    [AC_MSG_RESULT([--with-extractor not specified])
 839     AC_CHECK_HEADERS([extractor.h],
 840      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 841       extractor=1))])
 842 # restore LIBS
 843 LIBS=$SAVE_LIBS
 844
 845 AS_IF([test "$extractor" != 1],
 846  [
 847  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 848  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 849  ],[
 850  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 851  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 852  ])
 853
 854
 855 AS_IF([test "$taler_only" != yes],[
 856
 857
 858 # Check for libltdl header (#2999)
 859 ltdl=0
 860 AC_MSG_CHECKING(for libltdl)
 861 AC_ARG_WITH(ltdl,
 862    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 863    [AC_MSG_RESULT([$with_ltdl])
 864     AS_CASE([$with_ltdl],
 865       [no],[],
 866       [yes],[
 867         AC_CHECK_HEADERS(ltdl.h,
 868           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 869             ltdl=1))
 870       ],[
 871         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 872         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 873         AC_CHECK_HEADERS(ltdl.h,
 874           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 875             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 876             ltdl=1))
 877       ])
 878    ],
 879    [AC_MSG_RESULT([--with-ltdl not specified])
 880     AC_CHECK_HEADERS(ltdl.h,
 881      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 882       ltdl=1))])
 883 AS_IF([test x$ltdl = x1],
 884 [
 885  AC_MSG_RESULT([libltdl found])
 886 ],[
 887  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 888 ])
 889 # restore LIBS
 890 LIBS=$SAVE_LIBS
 891
 892 # libidn and libidn2. The ideal goal is this:
 893 # check for libidn2, if it doesn't exist check for libidn
 894 # if both exist, prefer libidn2
 895 # if none exist, fail and message that libidn or libidn2
 896 # is required with a preference for libidn2.
 897 # TODO: What we have right here can probably be improved.
 898 my_with_libidn=1
 899 AC_ARG_WITH(libidn,
 900             AS_HELP_STRING([--with-libidn=pathname],
 901                            [Support IDN (needs libidn)]),
 902             [],
 903             [withval="yes"])
 904 AS_IF([test x_$withval = x_yes],
 905       [AC_CHECK_HEADERS([idna.h],
 906           AC_MSG_NOTICE([Found idna.h]),
 907           AC_CHECK_HEADERS([idn/idna.h],
 908                AC_MSG_NOTICE([Found idn/idna.h]),
 909                my_with_libidn=0))],
 910       [AS_IF([test x_$withval != x_no],
 911              [CFLAGS="$CFLAGS -I$withval/include"
 912               LDFLAGS="$LDFLAGS -L$withval/lib"
 913               AC_CHECK_HEADERS([idna.h],
 914                 AC_MSG_NOTICE([Found idna.h]),
 915                 [AC_MSG_NOTICE([Failed to find idna.h])
 916                  my_with_libidn=0])],
 917              [my_with_libidn=0])])
 918
 919 my_with_libidn2=1
 920 AC_ARG_WITH(libidn2,
 921             AS_HELP_STRING([--with-libidn2=pathname],
 922                            [Support IDN (needs libidn2)]),
 923             [],
 924             [withval="yes"])
 925 AS_IF([test x_$withval = x_yes],
 926       [AC_CHECK_HEADERS([idn2.h],
 927        AC_MSG_NOTICE([Found idn2.h]),
 928        AC_CHECK_HEADERS([idn2/idn2.h],
 929           AC_MSG_NOTICE([Found idn2/idn2.h]),
 930           [AC_MSG_NOTICE([Failed to find idn2.h])
 931            my_with_libidn2=0]))],
 932       [AS_IF([test x_$withval != x_no],
 933              [CFLAGS="$CFLAGS -I$withval/include"
 934               LDFLAGS="$LDFLAGS -L$withval/lib"],
 935              [my_with_libidn2=0])])
 936
 937 AC_MSG_CHECKING([if libidn can be used])
 938 # Check for LIBIDNs
 939 there_can_only_be_one=1
 940
 941 working_libidn1=0
 942 working_libidn2=0
 943 AS_IF([test x$my_with_libidn2 = x1],
 944       [AC_MSG_NOTICE([Checking for libidn2])
 945        AC_CHECK_LIB([idn2],
 946                     [idn2_to_unicode_8z8z],
 947                     [working_libidn2=1
 948                     LIBS="-lidn2 $LIBS"
 949                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 950                                        [1],
 951                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 952                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 953                      MISSING_SEP=", "])])
 954 AM_CONDITIONAL(HAVE_LIBIDN2,
 955                test x$working_libidn2 = x1)
 956 AS_IF([test x$working_libidn2 = x0],
 957       [AS_IF([test x$my_with_libidn = x1],
 958              [AC_MSG_NOTICE([Checking for libidn])
 959               AC_CHECK_LIB([idn],
 960                            [idna_to_ascii_8z],
 961                            [working_libidn1=1
 962                            LIBS="-lidn $LIBS"
 963                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
 964                                               [1],
 965                                               [Define to 1 if you have 'libidn' (-lidn).])],
 966                            [there_can_only_be_one=0])],
 967              [AS_IF([test x$my_with_libidn2 = x1],
 968                     [there_can_only_be_one=0
 969                      AC_MSG_FAILURE([* There can only be one libidn.
 970                                      * Provide either libidn >= 1.13
 971                                      * or
 972                                      * libidn2 to the configure
 973                                      * script via
 974                                      * --with-libidn2
 975                                      * --with-libidn])])])])
 976 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
 977
 978 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
 979       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
 980
 981 AS_IF([test x$there_can_only_be_one = x0],
 982       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
 983
 984 # test for zlib
 985 SAVE_LDFLAGS=$LDFLAGS
 986 SAVE_CPPFLAGS=$CPPFLAGS
 987 AC_ARG_WITH(zlib,
 988             [  --with-zlib[[=DIR]]       use libz in DIR],
 989             [AS_IF([test "$withval" = "no"],
 990                    [AC_MSG_ERROR([GNUnet requires zlib])],
 991                    [test "$withval" != "yes"],
 992                    [Z_DIR=$withval
 993                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
 994                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
 995 AC_CHECK_HEADER(zlib.h,
 996                 [],
 997                 [AC_MSG_ERROR([GNUnet requires zlib])])
 998 AC_CHECK_LIB(z,
 999              compress2,
1000              [AC_DEFINE([HAVE_ZLIB],
1001                         [],
1002                         [Have compression library])
1003               if test "x${Z_DIR}" != "x"; then
1004                       Z_CFLAGS="-I${Z_DIR}/include"
1005                       Z_LIBS="-L${Z_DIR}/lib -lz"
1006               else
1007                       Z_LIBS="-lz"
1008               fi],
1009               [AC_MSG_ERROR([GNUnet requires zlib])])
1010 AC_SUBST(Z_CFLAGS)
1011 AC_SUBST(Z_LIBS)
1012
1013 AS_IF([test "$enable_shared" = "no"],
1014       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1015
1016
1017 # restore LIBS
1018 LIBS=$SAVE_LIBS
1019
1020
1021 # end of taler-only being false
1022 ])
1023
1024
1025 # check for iconv
1026 AM_ICONV
1027
1028 # test for libunistring
1029 gl_LIBUNISTRING
1030 AS_IF([test $HAVE_LIBUNISTRING != yes],
1031       [AC_MSG_ERROR([GNUnet requires libunistring])])
1032
1033 # under emscripten, $gl_libunistring_hexversion is undefined
1034 if test "$taler_only" != yes; then
1035
1036 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1037       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1038 fi
1039 AC_CHECK_HEADERS([unistr.h],
1040                  ,
1041                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1042
1043 # restore LIBS
1044 LIBS=$SAVE_LIBS
1045
1046
1047
1048 # Checks for standard header files.
1049 AC_HEADER_DIRENT
1050 AC_HEADER_STDC
1051
1052 # Check for headers that are ALWAYS required
1053 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1054
1055
1056
1057 # Checks for headers that are only required on some systems or
1058 # opional (and where we do NOT abort if they are not there)
1059 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1060
1061 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1062 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1063 [#ifdef HAVE_SYS_TYPES_H
1064 #include <sys/types.h>
1065 #endif
1066 #ifdef HAVE_NETINET_IN_SYSTM_H
1067 #include <netinet/in_systm.h>
1068 #endif
1069 #ifdef HAVE_NETINET_IN_H
1070 #include <netinet/in.h>
1071 #endif
1072 ])
1073
1074 SAVE_LDFLAGS=$LDFLAGS
1075 SAVE_CPPFLAGS=$CPPFLAGS
1076
1077 # test for sqlite
1078 sqlite=false
1079 AC_MSG_CHECKING(for SQLite)
1080 AC_ARG_WITH(sqlite,
1081   [  --with-sqlite=PFX       base of SQLite installation],
1082   [AC_MSG_RESULT("$with_sqlite")
1083    AS_CASE([$with_sqlite],
1084      [no],[],
1085      [yes],[
1086       AC_CHECK_HEADERS(sqlite3.h,
1087       sqlite=true)],
1088      [
1089     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1090     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1091     AC_CHECK_HEADERS(sqlite3.h,
1092      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1093      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1094      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1095      sqlite=true)
1096     LDFLAGS=$SAVE_LDFLAGS
1097     CPPFLAGS=$SAVE_CPPFLAGS
1098     ])
1099   ],
1100   [AC_MSG_RESULT([--with-sqlite not specified])
1101     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1102 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1103 AC_SUBST(SQLITE_CPPFLAGS)
1104 AC_SUBST(SQLITE_LDFLAGS)
1105
1106 LDFLAGS=$SAVE_LDFLAGS
1107 CPPFLAGS=$SAVE_CPPFLAGS
1108
1109 # test for postgres
1110 postgres=false
1111 # even running the check for postgres breaks emscripten ...
1112 AS_IF([test "$taler_only" != yes],
1113       [AX_LIB_POSTGRESQL([9.5],
1114         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1115          AC_CHECK_HEADERS([libpq-fe.h],
1116          postgres=true)
1117         ],
1118         [AC_MSG_RESULT([no postgres])])])
1119 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1120
1121
1122 LDFLAGS=$SAVE_LDFLAGS
1123 CPPFLAGS=$SAVE_CPPFLAGS
1124
1125 # mysql & windows
1126 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1127 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1128
1129 AS_IF([test "$build_target" = "mingw"]
1130  [CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"])
1131
1132 # test for mysql
1133 mysql=false
1134 mysqlfail=false
1135 SAVE_LDFLAGS=$LDFLAGS
1136 SAVE_CPPFLAGS=$CPPFLAGS
1137 AC_MSG_CHECKING(for mysql)
1138 AC_ARG_WITH(mysql,
1139   [  --with-mysql=PFX        base of MySQL installation],
1140   [AC_MSG_RESULT([$with_mysql])
1141    AS_CASE([$with_mysql],
1142      [no],[],
1143      [yes|""],[
1144       AC_CHECK_HEADERS(mysql/mysql.h,
1145        AC_CHECK_LIB(mysqlclient, mysql_init,
1146        mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1147      ],[
1148       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1149       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1150       AC_CHECK_HEADERS(mysql/mysql.h,
1151        AC_CHECK_LIB(mysqlclient, mysql_init,
1152         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1153         MYSQL_CPPFLAGS="-I$with_mysql/include"
1154
1155         mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1156      ])
1157   ],
1158   [AC_MSG_RESULT([--with-mysql not specified])
1159    if test -d "/usr/lib64/mysql"; then
1160     MYSQL_LIBDIR="/usr/lib64/mysql"
1161    elif test -d "/usr/lib/mysql"; then
1162     MYSQL_LIBDIR="/usr/lib/mysql"
1163    else
1164     MYSQL_LIBDIR="/usr/lib"
1165    fi
1166    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1167    AC_CHECK_LIB(mysqlclient, mysql_init,
1168     [AC_CHECK_HEADERS(mysql/mysql.h,
1169       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1170       mysql=true
1171
1172      , [], [$CYGWIN_MYSQL_MAGIC])])
1173   ])
1174
1175 AC_SUBST(MYSQL_LDFLAGS)
1176 AC_SUBST(MYSQL_CPPFLAGS)
1177
1178 # additional version check for mysql
1179 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1180 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1181  [
1182   AC_MSG_CHECKING(mysql version)
1183   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1184     [[$CYGWIN_MYSQL_MAGIC
1185       #include <mysql/mysql.h>]],
1186     [[
1187       #if (MYSQL_VERSION_ID < 40100)
1188       #error needs at least version >= 4.1
1189       #endif
1190       int main () { return 0; }
1191     ]])
1192     ],mysql=true,mysql=false)
1193   AS_IF([test "$mysql" = "false"],
1194    [
1195     mysqlfail=true
1196     AC_MSG_RESULT([fail, >= 4.1 required])
1197    ],[
1198     AC_MSG_RESULT(ok)
1199    ])
1200 ])
1201 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1202 AM_CONDITIONAL(HAVE_MYSQLE, false)
1203 # restore LIBS
1204 LIBS=$SAVE_LIBS
1205 LDFLAGS=$SAVE_LDFLAGS
1206 CPPFLAGS=$SAVE_CPPFLAGS
1207
1208 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1209 [
1210  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1211 ])
1212
1213 # libmicrohttpd
1214 lmhd=0
1215 AC_MSG_CHECKING([for libmicrohttpd])
1216 AC_ARG_WITH(microhttpd,
1217    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
1218    [AC_MSG_RESULT([$with_microhttpd])
1219     AS_CASE([$with_microhttpd],
1220       [no],[],
1221       [yes|""],[
1222         AC_CHECK_HEADERS([microhttpd.h],
1223           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1224             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1225               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.63])
1226               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1227                 #include "$native_srcdir/src/include/platform.h"
1228                 #include <microhttpd.h>
1229                 #if (MHD_VERSION < 0x0096300)
1230                 #error needs at least version 0.9.63
1231                 #endif
1232                 int main () { return 0; }
1233                ])],
1234                [AC_MSG_RESULT(ok)
1235                 lmhd=1],
1236                [AC_MSG_RESULT(failed)])]),
1237             [],[#include "$native_srcdir/src/include/platform.h"
1238                 #include <microhttpd.h>]),,
1239             [#include "$native_srcdir/src/include/platform.h"])
1240       ],[
1241         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
1242         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
1243         AC_CHECK_HEADERS(microhttpd.h,
1244           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1245             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1246               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
1247               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1248                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1249                 #include "$native_srcdir/src/include/platform.h"
1250                 #include <microhttpd.h>
1251                 #if (MHD_VERSION < 0x0094200)
1252                 #error needs at least version 0.9.42
1253                 #endif
1254                 int main () { return 0; }
1255                ])],
1256                [AC_MSG_RESULT(ok)
1257                 lmhd=1],
1258                [AC_MSG_RESULT(failed)])]),
1259             [],[#include "$native_srcdir/src/include/platform.h"
1260                 #include <microhttpd.h>]),,
1261             [#include "$native_srcdir/src/include/platform.h"])
1262        ])
1263    ],
1264    [AC_MSG_RESULT([--with-microhttpd not specified])
1265     AC_CHECK_HEADERS([microhttpd.h],
1266       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1267         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1268           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1269               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1270                 #include "$native_srcdir/src/include/platform.h"
1271                 #include <microhttpd.h>
1272                 #if (MHD_VERSION < 0x0094200)
1273                 #error needs at least version 0.9.52
1274                 #endif
1275                ])],
1276                [AC_MSG_RESULT(ok)
1277                 lmhd=1],
1278                [AC_MSG_RESULT(failed)])]),
1279         [],[#include "$native_srcdir/src/include/platform.h"
1280             #include <microhttpd.h>]),,
1281        [#include "$native_srcdir/src/include/platform.h"])])
1282 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1283 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1284
1285 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1286
1287 # restore LIBS
1288 LIBS=$SAVE_LIBS
1289
1290 # check for gettext
1291 AM_GNU_GETTEXT([external])
1292 AM_GNU_GETTEXT_VERSION([0.18.1])
1293
1294 # Checks for standard typedefs, structures, and compiler characteristics.
1295 AC_TYPE_PID_T
1296 AC_TYPE_SIZE_T
1297 AC_TYPE_MODE_T
1298 AC_HEADER_TIME
1299 AC_HEADER_STAT
1300 AC_HEADER_STDBOOL
1301 AC_STRUCT_TM
1302
1303 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1304    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1305    ],
1306    [],
1307    [
1308       #include <sys/types.h>
1309       #include <sys/socket.h>
1310       #include <netinet/in.h>
1311    ])
1312
1313 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1314                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1315                             1,
1316                             [Do we have sockaddr_un.sun_len?])],
1317                 [],
1318                 [
1319                 #include <sys/types.h>
1320                 #include <sys/socket.h>
1321                 #include <sys/un.h>
1322                 ])
1323
1324
1325
1326 # Checks for library functions.
1327 AC_FUNC_CLOSEDIR_VOID
1328 AC_FUNC_FORK
1329 AC_PROG_GCC_TRADITIONAL
1330 AC_FUNC_MEMCMP
1331 AC_FUNC_SELECT_ARGTYPES
1332 AC_FUNC_CHOWN
1333
1334 AC_TYPE_SIGNAL
1335 AC_FUNC_STAT
1336 AC_FUNC_STRFTIME
1337 AC_FUNC_VPRINTF
1338 AC_HEADER_SYS_WAIT
1339 AC_TYPE_OFF_T
1340 AC_TYPE_UID_T
1341 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1342
1343 # restore LIBS
1344 LIBS=$SAVE_LIBS
1345
1346 GN_INTLINCL=""
1347 GN_LIBINTL="$LTLIBINTL"
1348 AC_ARG_ENABLE(framework,
1349               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1350               enable_framework_build=$enableval)
1351 AM_CONDITIONAL(WANT_FRAMEWORK,
1352                test x$enable_framework_build = xyes)
1353 AS_IF([test x$enable_framework_build = xyes],
1354       [AC_DEFINE([FRAMEWORK_BUILD],
1355                  1,
1356                  [Build a Mac OS X Framework])
1357       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1358       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1359       AC_LIB_APPENDTOVAR([CPPFLAGS],
1360                          [$GN_INTLINCL])])
1361
1362 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1363 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1364
1365 AC_SUBST(GN_LIB_LDFLAGS)
1366 AC_SUBST(GN_PLUGIN_LDFLAGS)
1367 AC_SUBST(GN_INTLINCL)
1368 AC_SUBST(GN_LIBINTL)
1369
1370 AC_SUBST(CPPFLAGS)
1371 AC_SUBST(LIBS)
1372 AC_SUBST(LDFLAGS)
1373 AC_SUBST(EXT_LIB_PATH)
1374 AC_SUBST(EXT_LIBS)
1375
1376 AC_SUBST(LIBPREFIX)
1377 AC_SUBST(DLLDIR)
1378 AC_SUBST(EXT_LIB_PATH)
1379
1380 DATAROOTDIR=$datarootdir
1381 AC_SUBST(DATAROOTDIR)
1382
1383 # test for sudo
1384 # TODO: do we need to change anything for "doas" on openbsd?
1385 AC_MSG_CHECKING(for sudo)
1386 AC_ARG_WITH(sudo,
1387             [  --with-sudo=PATH       path to sudo binary (or just yes)],
1388             [AC_MSG_RESULT("$with_sudo")
1389              AS_CASE([$with_sudo],
1390                      [no],[SUDO_BINARY=],
1391                      [yes],[SUDO_BINARY=sudo],
1392                      [SUDO_BINARY=$with_sudo])],
1393             [AC_MSG_RESULT([no])])
1394 AC_SUBST(SUDO_BINARY)
1395 AM_CONDITIONAL([HAVE_SUDO],
1396                [test "x$SUDO_BINARY" != "x" -o -w /])
1397
1398
1399 # test for gnunetdns group name
1400 GNUNETDNS_GROUP=gnunetdns
1401 AC_MSG_CHECKING(for gnunetdns group name)
1402 AC_ARG_WITH(gnunetdns,
1403             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1404             [AC_MSG_RESULT("$with_gnunetdns")
1405              AS_CASE([$with_gnunetdns],
1406                      [no],[GNUNETDNS_GROUP=gnunet],
1407                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1408                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1409             [AC_MSG_RESULT([gnunetdns])])
1410 AC_SUBST(GNUNETDNS_GROUP)
1411
1412
1413
1414 # gnutls
1415 gnutls=0
1416 gnutls_dane=0
1417 AC_MSG_CHECKING(for gnutls)
1418 AC_ARG_WITH(gnutls,
1419             [  --with-gnutls=PFX   base of gnutls installation],
1420             [AC_MSG_RESULT([$with_gnutls])
1421              AS_CASE([$with_gnutls],
1422                      [no],[],
1423                      [yes],
1424                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1425                                        AC_CHECK_LIB([gnutls],
1426                                                     [gnutls_priority_set],
1427                                                     gnutls=true))
1428                       AC_CHECK_HEADERS([gnutls/dane.h],
1429                                        AC_CHECK_LIB([gnutls-dane],
1430                                                     [dane_verify_crt_raw],
1431                                                     gnutls_dane=1))],
1432
1433         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1434         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1435         AC_CHECK_HEADERS([gnutls/abstract.h],
1436             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1437               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1438               gnutls=true))
1439         AC_CHECK_HEADERS([gnutls/dane.h],
1440             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1441               gnutls_dane=1))
1442       ])
1443    ],
1444    [AC_MSG_RESULT([--with-gnutls not specified])
1445     AC_CHECK_HEADERS([gnutls/abstract.h],
1446         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1447           gnutls=true))
1448     AC_CHECK_HEADERS([gnutls/dane.h],
1449         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1450                      gnutls_dane=1))
1451    ])
1452 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1453 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1454 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1455 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1456
1457
1458
1459 # Test if we are building for superMUC
1460 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1461 AC_ARG_ENABLE([supermuc],
1462     [AS_HELP_STRING([--enable-supermuc],
1463        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1464     [AS_IF([test "x$enable_supermuc" = "xno"],
1465       [supermuc=0],
1466       [supermuc=1])],
1467     [supermuc=0
1468      enable_supermuc=no])
1469 AC_MSG_RESULT($enable_SUPERMUC)
1470 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1471 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1472
1473 # Check if NSE has to send timestamp information to testbed logger for
1474 # generating histogram of messages received
1475 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1476 AC_ARG_ENABLE([nse-histogram],
1477     [AS_HELP_STRING([--enable-nse-histogram],
1478        [have NSE send timestamp information to testbed logger for generating
1479        histogram of received messages.  NOT useful for production (default is
1480        NO)])],
1481     [AS_IF([test "x$enableval" = "xno"],
1482       [nse_histogram=0],
1483       [nse_histogram=1])],
1484     [nse_histogram=0
1485      enable_nse_histogram=no])
1486 AC_MSG_RESULT($enable_nse_histogram)
1487 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1488 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1489                    [have NSE send timestamp information to testbed logger])
1490
1491 # should 'make check' run tests?
1492 AC_MSG_CHECKING(whether to run tests)
1493 AC_ARG_ENABLE([testruns],
1494    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1495    [enable_tests_run=${enableval}],
1496    [enable_tests_run=yes])
1497 AC_MSG_RESULT($enable_test_run)
1498 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1499
1500
1501 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1502 AC_ARG_ENABLE([benchmark],
1503    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1504    [enable_benchmark=${enableval}],
1505    [enable_benchmark=no])
1506 AC_MSG_RESULT($enable_benchmark)
1507 AS_IF([test "x$enable_benchmark" = "xyes"],
1508       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1509 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1510
1511
1512 # should expensive tests be run?
1513 AC_MSG_CHECKING(whether to run expensive tests)
1514 AC_ARG_ENABLE([expensivetests],
1515    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1516    [enable_expensive=${enableval}],
1517    [enable_expensive=no])
1518 AC_MSG_RESULT($enable_expensive)
1519 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1520
1521 # should ports be open for Java services?
1522 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1523 AC_ARG_ENABLE([javaports],
1524    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1525    [enable_java_ports=${enableval}],
1526    [enable_java_ports=no])
1527 AC_MSG_RESULT($enable_java_ports)
1528 AS_IF([test "x$enable_java_ports" = "xyes"],
1529  [JAVAPORT=""],
1530  [JAVAPORT="$UNIXONLY"])
1531 AC_SUBST(JAVAPORT)
1532
1533 # should benchmarks be run?
1534 AC_MSG_CHECKING(whether to run benchmarks during make check)
1535 AC_ARG_ENABLE([benchmarks],
1536    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1537    [enable_benchmarks=${enableval}],
1538    [enable_benchmarks=no])
1539 AC_MSG_RESULT($enable_benchmarks)
1540 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1541
1542 # should gnunet-testing be compiled
1543 AC_MSG_CHECKING(wether to compile gnunet-testing)
1544 AC_ARG_ENABLE([testing],
1545    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1546    [enable_testing=${enableval}],
1547    [enable_testing=yes])
1548 AC_MSG_RESULT($enable_testing)
1549 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1550
1551 # should experimental code be compiled (code that may not yet compile)?
1552 AC_MSG_CHECKING(whether to compile experimental code)
1553 AC_ARG_ENABLE([experimental],
1554    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1555    [enable_experimental=${enableval}],
1556    [enable_experimental=no])
1557 AC_MSG_RESULT($enable_experimental)
1558 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1559
1560 # should malicious code be compiled (should only be used for testing)?
1561 AC_MSG_CHECKING(whether to compile malicious code)
1562 AC_ARG_ENABLE([malicious],
1563    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1564    [AS_IF([test "x$enableval" = "xno"],
1565      [malicious=0],
1566      [malicious=1])],
1567    [malicious=0
1568     enable_malicious=no])
1569 AC_MSG_RESULT($enable_malicious)
1570 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1571 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1572                    [enable compilation of malicious code])
1573
1574 # should services be started on demand when needed?
1575 # Some services may choose to never start by default
1576 # and it is up to the service/module developer to decide
1577 # by having "START_ON_DEMAND = NO" instead of
1578 # "START_ON_DEMAND = @START_ON_DEMAND@"
1579 # in the service/module's conf.in file.
1580 # See also IMMEDIATE_START for an unconditional immediate start.
1581 START_ON_DEMAND="YES"
1582 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1583 AC_ARG_ENABLE([autostart],
1584    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1585    [enable_autostart=${enableval}
1586     AS_IF([test "x$enable_autostart" = "xno"],
1587       [START_ON_DEMAND="NO"])
1588    ],
1589    [enable_autostart=yes])
1590 AC_MSG_RESULT($enable_autostart)
1591 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1592 AC_SUBST(START_ON_DEMAND)
1593
1594 # should memory statistics be kept (very expensive CPU-wise!)
1595 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1596 AC_ARG_ENABLE([heapstats],
1597    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1598    [enable_heapstats=1],
1599    [enable_heapstats=0])
1600 AC_MSG_RESULT($enable_heapstats)
1601 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1602
1603 # should code be enabled that works around missing OS functionality on Windows?
1604 # used for test cases
1605 if test $build_target = "mingw"
1606 then
1607         workarounds=1
1608
1609 AC_LINK_IFELSE(
1610  [AC_LANG_PROGRAM(
1611   [#include <ws2tcpip.h>
1612   ],[
1613   int s = socket (0, 0, 0);])
1614  ],[
1615   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1616  ],[
1617   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1618  ])
1619
1620 AC_LINK_IFELSE(
1621  [AC_LANG_PROGRAM(
1622   [#include <ws2tcpip.h>
1623   ],[
1624   int s = select (0, NULL, NULL, NULL, NULL);])
1625  ],[
1626   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1627  ],[
1628   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1629  ])
1630
1631 AC_LINK_IFELSE(
1632  [AC_LANG_PROGRAM(
1633   [#include <ws2tcpip.h>
1634   ],[
1635   struct in_addr i;
1636   char *s = inet_ntoa (i);])
1637  ],[
1638   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1639  ],[
1640   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1641  ])
1642
1643 AC_LINK_IFELSE(
1644  [AC_LANG_PROGRAM(
1645   [#include <ws2tcpip.h>
1646   ],[
1647   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1648  ],[
1649   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1650  ],[
1651   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1652  ])
1653
1654 AC_LINK_IFELSE(
1655  [AC_LANG_PROGRAM(
1656   [#include <ws2tcpip.h>
1657   ],[
1658   int s = gethostname (NULL, 0);])
1659  ],[
1660   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1661  ],[
1662   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1663  ])
1664
1665 AC_LINK_IFELSE(
1666  [AC_LANG_PROGRAM(
1667   [#include <ws2tcpip.h>
1668   ],[
1669   void *s = gethostbyname (NULL);])
1670  ],[
1671   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1672  ],[
1673   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1674  ])
1675
1676 AC_LINK_IFELSE(
1677  [AC_LANG_PROGRAM(
1678   [#include <ws2tcpip.h>
1679   ],[
1680   void *s = gethostbyaddr (NULL, 0, 0);])
1681  ],[
1682   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1683  ],[
1684   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1685  ])
1686
1687 AC_LINK_IFELSE(
1688  [AC_LANG_PROGRAM(
1689   [#include <ws2tcpip.h>
1690   ],[
1691   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1692  ],[
1693   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1694  ],[
1695   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],0,[Define this if getaddrinfo() is available])
1696  ])
1697
1698 else
1699   AC_MSG_CHECKING(whether to enable windows workarounds)
1700   AC_ARG_ENABLE([windows_workarounds],
1701      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1702      [enable_workarounds=${enableval}],
1703      [enable_workarounds=no])
1704   AC_MSG_RESULT($enable_workarounds)
1705   AS_IF([test x$enable_windows_workarounds = "xyes"],
1706     [workarounds=1],
1707     [workarounds=0])
1708 fi
1709 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1710
1711
1712 # Check if the __thread storage class for
1713 # thread-local storage is available.
1714 AC_MSG_CHECKING(whether __thread is supported)
1715 AC_LINK_IFELSE(
1716 [AC_LANG_PROGRAM([#include <stdlib.h>
1717                    #undef __thread
1718                    static __thread int a = 1;],
1719                   [exit(a-1);])],
1720  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1721 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1722 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1723       [AC_MSG_RESULT(yes)],
1724       [AC_MSG_RESULT(no)])
1725
1726 # gcov compilation
1727 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1728 AC_ARG_ENABLE([coverage],
1729               AS_HELP_STRING([--enable-coverage],
1730                              [compile the library with code coverage support]),
1731               [use_gcov=${enableval}],
1732               [use_gcov=no])
1733 AC_MSG_RESULT($use_gcov)
1734 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1735
1736
1737 # version info
1738 # TODO: git blame says this predates our switch to git.
1739 # git-svn should be adjusted to simply git, or
1740 # an external script that does the job.
1741 AC_PATH_PROG(svnversioncommand, svnversion)
1742 AC_PATH_PROG(gitcommand, git)
1743 AC_MSG_CHECKING(for source being under a VCS)
1744
1745
1746 # version info
1747 AC_PATH_PROG(gitcommand, git)
1748 AC_MSG_CHECKING(for source being under a VCS)
1749 git_version=
1750 AS_IF([test ! "X$gitcommand" = "X"],
1751 [
1752   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1753 ])
1754 AS_IF([test "X$git_version" = "X"],
1755   [
1756     vcs_name="no"
1757     vcs_version="\"release\""
1758   ],
1759   [
1760     vcs_name="yes, git-svn"
1761     vcs_version="\"git-$git_version\""
1762   ])
1763 AC_MSG_RESULT($vcs_name)
1764
1765 AC_MSG_CHECKING(VCS version)
1766 AC_MSG_RESULT($vcs_version)
1767 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1768
1769 AC_CONFIG_FILES([
1770 Makefile
1771 contrib/Makefile
1772 contrib/hellos/Makefile
1773 contrib/services/Makefile
1774 contrib/services/openrc/Makefile
1775 contrib/services/systemd/Makefile
1776 contrib/scripts/Makefile
1777 contrib/scripts/gnunet-logread/Makefile
1778 doc/Makefile
1779 doc/man/Makefile
1780 doc/doxygen/Makefile
1781 doc/handbook/Makefile
1782 doc/tutorial/Makefile
1783 lint/Makefile
1784 m4/Makefile
1785 po/Makefile.in
1786 src/Makefile
1787 src/arm/Makefile
1788 src/arm/arm.conf
1789 src/ats/Makefile
1790 src/ats/ats.conf
1791 src/ats-tool/Makefile
1792 src/ats-tests/Makefile
1793 src/auction/Makefile
1794 src/block/Makefile
1795 src/cadet/Makefile
1796 src/cadet/cadet.conf
1797 src/core/Makefile
1798 src/core/core.conf
1799 src/consensus/Makefile
1800 src/consensus/consensus.conf
1801 src/conversation/Makefile
1802 src/conversation/conversation.conf
1803 src/curl/Makefile
1804 src/datacache/Makefile
1805 src/datastore/Makefile
1806 src/datastore/datastore.conf
1807 src/dht/Makefile
1808 src/dht/dht.conf
1809 src/dns/Makefile
1810 src/dns/dns.conf
1811 src/exit/Makefile
1812 src/fragmentation/Makefile
1813 src/fs/Makefile
1814 src/fs/fs.conf
1815 src/gns/Makefile
1816 src/gns/gns.conf
1817 src/gns/nss/Makefile
1818 src/gnsrecord/Makefile
1819 src/hello/Makefile
1820 src/identity/Makefile
1821 src/identity/identity.conf
1822 src/credential/Makefile
1823 src/credential/credential.conf
1824 src/include/Makefile
1825 src/integration-tests/Makefile
1826 src/json/Makefile
1827 src/hostlist/Makefile
1828 src/my/Makefile
1829 src/mysql/Makefile
1830 src/namecache/Makefile
1831 src/namecache/namecache.conf
1832 src/namestore/Makefile
1833 src/namestore/namestore.conf
1834 src/nat/Makefile
1835 src/nat/nat.conf
1836 src/nat-auto/Makefile
1837 src/nat-auto/nat-auto.conf
1838 src/nse/Makefile
1839 src/nse/nse.conf
1840 src/nt/Makefile
1841 src/peerinfo/Makefile
1842 src/peerinfo/peerinfo.conf
1843 src/peerinfo-tool/Makefile
1844 src/peerstore/Makefile
1845 src/peerstore/peerstore.conf
1846 src/pq/Makefile
1847 src/pt/Makefile
1848 src/regex/Makefile
1849 src/regex/regex.conf
1850 src/revocation/Makefile
1851 src/revocation/revocation.conf
1852 src/rps/Makefile
1853 src/rps/rps.conf
1854 src/secretsharing/Makefile
1855 src/secretsharing/secretsharing.conf
1856 src/scalarproduct/Makefile
1857 src/scalarproduct/scalarproduct.conf
1858 src/set/Makefile
1859 src/set/set.conf
1860 src/sq/Makefile
1861 src/statistics/Makefile
1862 src/statistics/statistics.conf
1863 src/template/Makefile
1864 src/testbed/Makefile
1865 src/testbed/testbed.conf
1866 src/testbed-logger/Makefile
1867 src/testbed-logger/testbed-logger.conf
1868 src/testing/Makefile
1869 src/topology/Makefile
1870 src/transport/Makefile
1871 src/transport/transport.conf
1872 src/util/Makefile
1873 src/util/resolver.conf
1874 src/vpn/Makefile
1875 src/vpn/vpn.conf
1876 src/zonemaster/Makefile
1877 src/zonemaster/zonemaster.conf
1878 src/rest/Makefile
1879 src/abe/Makefile
1880 src/reclaim-attribute/Makefile
1881 src/reclaim/Makefile
1882 pkgconfig/Makefile
1883 pkgconfig/gnunetarm.pc
1884 pkgconfig/gnunetats.pc
1885 pkgconfig/gnunetblock.pc
1886 pkgconfig/gnunetcadet.pc
1887 pkgconfig/gnunetconsensus.pc
1888 pkgconfig/gnunetconversation.pc
1889 pkgconfig/gnunetcore.pc
1890 pkgconfig/gnunetdatacache.pc
1891 pkgconfig/gnunetdatastore.pc
1892 pkgconfig/gnunetdht.pc
1893 pkgconfig/gnunetdns.pc
1894 pkgconfig/gnunetenv.pc
1895 pkgconfig/gnunetfragmentation.pc
1896 pkgconfig/gnunetfs.pc
1897 pkgconfig/gnunetgns.pc
1898 pkgconfig/gnunethello.pc
1899 pkgconfig/gnunetidentity.pc
1900 pkgconfig/gnunetmicrophone.pc
1901 pkgconfig/gnunetmysql.pc
1902 pkgconfig/gnunetnamestore.pc
1903 pkgconfig/gnunetnat.pc
1904 pkgconfig/gnunetnse.pc
1905 pkgconfig/gnunetpeerinfo.pc
1906 pkgconfig/gnunetpq.pc
1907 pkgconfig/gnunetregex.pc
1908 pkgconfig/gnunetrevocation.pc
1909 pkgconfig/gnunetrps.pc
1910 pkgconfig/gnunetscalarproduct.pc
1911 pkgconfig/gnunetset.pc
1912 pkgconfig/gnunetspeaker.pc
1913 pkgconfig/gnunetstatistics.pc
1914 pkgconfig/gnunettestbed.pc
1915 pkgconfig/gnunettesting.pc
1916 pkgconfig/gnunettransport.pc
1917 pkgconfig/gnunetutil.pc
1918 pkgconfig/gnunetvpn.pc
1919 ])
1920 AC_OUTPUT
1921
1922
1923 # FIXME: `some modules' -> be more specific which exact modules.
1924
1925 # java ports
1926 AS_IF([test "x$enable_java_ports" = "xyes"],
1927       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1928
1929 ####
1930 #### Lasciate ogne speranza, voi ch'intrate
1931 ####
1932 #### This could be moved to the checks above,
1933 #### but for now let's keep it here.
1934 ####
1935
1936 # -- print message regarding enabled experimental features
1937 AS_IF([test "x$enable_experimental" = "xyes"],
1938       [experimental_msg="experimental features enabled"])
1939 # -- OSX Framework
1940 AS_IF([test "$enable_framework_build" = "yes"],
1941       [macosx_framework_msg="yes"],
1942       [macosx_framework_msg="no"])
1943 # -- libidn 2
1944 AS_IF([test "x$working_libidn2" = x1],
1945       [libidn2_msg="libidn2"])
1946 # -- libidn 1
1947 AS_IF([test "x$working_libidn1" = x1],
1948       [libidn1_msg="libidn1"])
1949 # -- texi2mdoc
1950 AS_IF([test "x$texi2mdoc_generation" = x1],
1951       [mdoc_msg="yes"],
1952       [mdoc_msg="no"])
1953 # -- texinfo
1954 AS_IF([test "x$makeinfo" != "x1"],
1955       [texinfo_msg="no"],
1956       [texinfo_msg="yes"])
1957 # -- conversation
1958 AS_IF([test "x$conversation_backend" = "xnone"],
1959       [AS_IF([test "x$pulse" != "x1"],
1960              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1961               libpulse_msg="no"],
1962              [libpulse_msg="yes"])
1963        AS_IF([test "x$opus" != "x1"],
1964              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1965               libopus_msg="no"],
1966              [libopus_msg="yes"])
1967        AS_IF([test "x$gst" != "x1"],
1968              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1969               gstreamer_msg="no"],
1970              [gstreamer_msg="yes"])],
1971       [features_msg="$features_msg conversation"])
1972 # -- interface
1973 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1974 # -- libmicrohttpd
1975 AS_IF([test "x$lmhd" != "x1"],
1976       [libmicrohttpd_msg="no (optional)"],
1977       [libmicrohttpd_msg="yes"])
1978 # -- jansson
1979 AS_IF([test "x$jansson" = "x0"],
1980       [jansson_msg="no (optional)"],
1981       [jansson_msg="yes"])
1982 # -- libextractor
1983 AS_IF([test "$extractor" != 1],
1984       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1985       [libextractor_msg="yes"])
1986 # -- libzbar
1987 AS_IF([test "x$zbar" = "x1"],
1988       [libzbar_msg="yes"
1989        features_msg="$features_msg gnunet-qr"],
1990       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1991        libzbar_msg="no"])
1992 # -- libgnurl
1993 AS_IF([test "$gnurl" = "0"],
1994       [AS_IF([test "x$curl" = "xfalse"],
1995              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1996               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1997               curl_msg="no"],
1998              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1999               curl_msg="yes"])],
2000        [gnurl_msg="yes"])
2001 # -- ifconfig
2002 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2003       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2004        ifconfig_msg="no (optional)"],
2005       [ifconfig_msg="yes"])
2006 # -- upnpc
2007 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2008       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2009        upnpc_msg="no (optional)"],
2010       [upnpc_msg="yes"])
2011 # -- iptables
2012 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2013       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2014        iptables_msg="no (optional)"],
2015       [iptables_msg="yes"])
2016 # -- bluetooth
2017 AS_IF([test "x$bluetooth" = "x0"],
2018       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2019        bluetooth_msg="no (optional)"],
2020       [bluetooth_msg="yes"])
2021 # -- gnutls
2022 AS_IF([test x$gnutls != xtrue],
2023       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2024        gnutls_msg="no"],
2025       [AS_IF([test "x$gnutls_dane" != "x1"],
2026              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2027               gnutls_msg="yes (without DANE support)"],
2028              [gnutls_msg="yes (with DANE support)"])])
2029 # -- databases
2030 AS_IF([test $mysqlfail = true]
2031       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2032 AS_IF([test "$mysql" = true],
2033       [features_msg="$features_msg mysql"
2034        mysql_msg="yes"],
2035       [mysql_msg="no"])
2036 AS_IF([test "$sqlite" = true],
2037       [features_msg="$features_msg sqlite"
2038        sqlite_msg="yes"],
2039       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2040        sqlite_msg="no"])
2041 AS_IF([test "$postgres" = true],
2042       [features_msg="$features_msg postgres"
2043        postgres_msg="yes"],
2044       [postgres_msg="no"])
2045 # -- features
2046 # ---- 1. replace spaces with newlines,
2047 # ---- 2. sort the lines,
2048 # ---- 3. replace the newlines with spaces.
2049 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2050 AC_SUBST(features_msg)
2051
2052
2053 # The summary
2054 # TODO: reduce the length of the last message block ("the message")
2055
2056 AC_MSG_NOTICE([
2057 GNUnet Configuration (incomplete!)
2058
2059 gnunet version:                 ${VERSION}
2060
2061 Host setup:                     ${host}
2062 Install prefix:                 ${prefix}
2063 Compiler:                       ${CC}
2064 CFLAGS:                         ${CFLAGS}
2065 CPPFLAGS:                       ${CPPFLAGS}
2066 LDFLAGS:                        ${LDFLAGS}
2067 LIBS:                           ${LIBS}
2068 Build Target:                   $build_target
2069 Mac OSX framework build:        ${macosx_framework_msg}
2070
2071 Default Interface:              ${interface_msg}
2072
2073 MySQL:                          ${mysql_msg}
2074 PostgreSQL:                     ${postgres_msg}
2075 sqlite3:                        ${sqlite_msg}
2076 gnurl:                          ${gnurl_msg}
2077 curl:                           ${curl_msg}
2078 bluetooth:                      ${bluetooth_msg}
2079 jansson:                        ${jansson_msg}
2080 iptables:                       ${iptables_msg}
2081 ifconfig:                       ${ifconfig_msg}
2082 upnpc:                          ${upnpc_msg}
2083 gnutls:                         ${gnutls_msg}
2084 libzbar:                        ${libzbar_msg}
2085 java:                           ${java_msg}
2086 libmicrohttpd:                  ${libmicrohttpd_msg}
2087 libidn:                         ${libidn1_msg}${libidn2_msg}
2088 libopus:                        ${libopus_msg}
2089 gstreamer:                      ${gstreamer_msg}
2090 libpulse:                       ${libpulse_msg}
2091 libextractor:                   ${libextractor_msg}
2092
2093 texinfo manual:                 ${texinfo_msg}
2094 transpiled mdoc manual:         ${mdoc_msg}
2095
2096 features:                       ${features_msg}
2097 experimental:                   ${experimental_msg}
2098
2099
2100 IMPORTANT:
2101
2102 Please make sure NOW that you have created a user and group 'gnunet'
2103 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2104 type:
2105
2106   addgroup gnunetdns
2107   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2108
2109 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2110 'gnunet'.  Then, you can compile GNUnet with
2111
2112   make
2113
2114 After that, run (if necessary as 'root')
2115
2116   make install
2117
2118 to install everything.
2119
2120 Each GNUnet user should be added to the 'gnunet' group (may
2121 require fresh login to come into effect):
2122
2123   adduser USERNAME gnunet
2124
2125 (run the above command as root once for each of your users, replacing
2126 "USERNAME" with the respective login names).  If you have a global IP
2127 address, no further configuration is required.
2128
2129 For more detailed setup instructions, see https://docs.gnunet.org/
2130
2131 Optionally, download and compile gnunet-gtk to get a GUI for
2132 file-sharing and configuration.  This is particularly recommended
2133 if your network setup is non-trivial, as gnunet-setup can be
2134 used to test in the GUI if your network configuration is working.
2135 gnunet-setup should be run as the "gnunet" user under X.  As it
2136 does very little with the network, running it as "root" is likely
2137 also harmless.  You can also run it as a normal user, but then
2138 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2139 home directory in the end.
2140
2141 Once you have configured your peer, run (as the 'gnunet' user)
2142
2143   gnunet-arm -s
2144
2145 to start the peer.  You can then run the various GNUnet-tools as
2146 your "normal" user (who should only be in the group 'gnunet').
2147 ])