configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen win32-dll])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 136      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 137      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 138      build_target="freebsd"
 139      LIBPREFIX=
 140      DLLDIR=lib
 141      UNIXONLY="#"
 142   ],
 143   [*openbsd*],[
 144      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 145      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 146      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 147      build_target="openbsd"
 148      LIBPREFIX=
 149      DLLDIR=lib
 150      UNIXONLY="#"
 151   ],
 152   [*netbsd*],[
 153      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 154      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 155      build_target="netbsd"
 156      LIBPREFIX=
 157      DLLDIR=lib
 158      UNIXONLY="#"
 159   ],
 160   [*solaris*],[
 161      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 162      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 163      AC_CHECK_LIB(resolv, res_init)
 164      AC_CHECK_LIB(rt, nanosleep)
 165      build_target="solaris"
 166      LIBPREFIX=
 167      DLLDIR=lib
 168      UNIXONLY="#"
 169   ],
 170   [*arm-linux*],[
 171      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 172      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 173      build_target="linux"
 174      LIBPREFIX=
 175      DLLDIR=lib
 176      UNIXONLY="#"
 177   ],
 178   [gnu*],[
 179      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 180      build_target="gnu"
 181      UNIXONLY="#"
 182   ],
 183   [
 184      AC_MSG_RESULT(Unrecognised OS $host_os)
 185      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 186      UNIXONLY=""
 187 ])
 188 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 189 AC_SUBST(DEFAULT_INTERFACE)
 190
 191 # Disable TCP-based IPC on systems that support UNIX domain
 192 # sockets in default configuratin:
 193 AC_SUBST(UNIXONLY)
 194
 195
 196 AC_MSG_CHECKING([for build target])
 197 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 198 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 199 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 226 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 227 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 228 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 229
 230 # autotools' m4 for python has no maximum version!
 231 # python3.4 - python3.7 for tests
 232 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python])
 233 AM_PATH_PYTHON([3.4],, [:])
 234 AC_SUBST([PYTHON])
 235 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 236
 237 # perl
 238 AC_PATH_PROG( PERL, perl, ,
 239               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 240 AC_SUBST([PERL])
 241
 242 # iptables is a soft requirement to run tests
 243 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 244
 245 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 246  [AS_IF([test -x "/sbin/iptables"],
 247    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 248    [AS_IF([test -x "/usr/sbin/iptables"],
 249       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 250
 251 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 252  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 253  [AC_MSG_WARN([warning: 'iptables' not found.])])
 254
 255 # ip6tables is a soft requirement for some features
 256 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 257
 258 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 259   [AS_IF([test -x "/sbin/ip6tables"],
 260      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 261      [AS_IF([test -x "/usr/sbin/ip6tables"],
 262         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 263
 264
 265 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 266   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 267   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 268
 269 # ip is a soft requirement for some features
 270 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 271
 272 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 273  [AS_IF([test -x "/sbin/ip"],
 274    [VAR_IP_BINARY="/sbin/ip"],
 275    [AS_IF([test -x "/usr/sbin/ip"],
 276           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 277
 278 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 279  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 280  [AC_MSG_WARN([warning: 'ip' not found.])])
 281
 282 # locate 'ifconfig'
 283 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 284
 285 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 286 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 287   [AS_IF([test -x "/sbin/ifconfig"],
 288      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 289      [AS_IF([test -x "/usr/sbin/ifconfig"],
 290             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 291
 292 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 293   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 294   [AC_MSG_WARN(['ifconfig' not found.])])
 295
 296
 297 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 298
 299 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 300 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 301       [AS_IF([test -x "/sbin/sysctl"],
 302              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 303              [AS_IF([test -x "/usr/sbin/sysctl"],
 304                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 305 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 306       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 307       [AC_MSG_WARN(['sysctl' not found.])])
 308
 309 # miniupnpc / upnpc binary is a soft runtime requirement
 310 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 311
 312 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 313   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 314   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 315
 316
 317 # uncrustify
 318 # TODO: maybe add flag to pass location
 319 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 320 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 321
 322 # yapf
 323 # TODO: less repetition, add flag to pass name
 324 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 325 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 326
 327
 328 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 329   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 330      [Define if struct tm has the tm_gmtoff member.])],
 331      ,
 332      [#include <time.h>])
 333
 334 # 'save' libs; only those libs found so far will be
 335 # linked against _everywhere_.  For the others, we
 336 # will be more selective!
 337 SAVE_LIBS=$LIBS
 338
 339 have_addrinfo_a=0
 340 AC_CHECK_LIB(anl,
 341              getaddrinfo_a,
 342              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 343                                           1,
 344                                           [getaddrinfo_a supported])])
 345 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 346                [test "$have_addrinfo_a" = 1])
 347
 348 # libgcrypt
 349 gcrypt=0
 350 NEED_LIBGCRYPT_API=1
 351 NEED_LIBGCRYPT_VERSION=1.6.0
 352
 353
 354 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 355 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 356
 357 AS_IF([test $gcrypt = 0],
 358  [
 359   AC_MSG_ERROR([[
 360 ***
 361 *** You need libgcrypt to build this program.
 362 **  This library is for example available at
 363 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 364 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 365 ***  is required.)
 366 ***]])
 367 ])
 368 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 369
 370 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 371
 372
 373
 374 # should the build process be building the documentation?
 375 AC_MSG_CHECKING(whether to build documentation)
 376 AC_ARG_ENABLE([documentation],
 377               [AS_HELP_STRING([--disable-documentation],
 378                               [do not build the documentation])],
 379               [documentation=${enableval}],
 380               [documentation=yes])
 381 AC_MSG_RESULT($documentation)
 382 AS_IF([test "x$documentation" = "xyes"],
 383       [AM_CONDITIONAL([DOCUMENTATION],
 384                       true)
 385        AC_DEFINE([DOCUMENTATION],
 386                  [1],
 387                  [Building the documentation])],
 388       [AM_CONDITIONAL([DOCUMENTATION],
 389                       false)
 390        AC_DEFINE([DOCUMENTATION],
 391                  [0],
 392                  [Not building the documentation])])
 393
 394 # COMMENT: Check wether to transpile texinfo to mdoc.
 395 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 396 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 397 # COMMENT: and makes the configure fail if it is missing.
 398 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 399 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 400 # COMMENT: or nothing was set (this is the default).
 401 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 402 # COMMENT: potential non-existence of the texi2mdoc binary.
 403 # COMMENT: Default return value / setting: no
 404 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 405 AC_ARG_ENABLE([texi2mdoc-generation],
 406               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 407                               [include generated texi2mdoc output in installation])],
 408               [texi2mdoc_generation=${enableval}],
 409               [texi2mdoc_generation=no])
 410 AC_MSG_RESULT($texi2mdoc_generation)
 411 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 412       [AS_IF([test "$texi2mdoc" = 0],
 413              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 414               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your Operating System])
 415               AC_MSG_WARN([ERROR: package manager or from https://mandoc.bsd.lv/texi2mdoc/])],
 416              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 417               AC_DEFINE([TEXI2MDOC_GENERATION],
 418                         [1],
 419                         [Building section 7 mdoc output])])],
 420       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 421                       false)
 422        AC_DEFINE([TEXI2MDOC_GENERATION],
 423                  [0],
 424                  [Not building section 7 mdoc output])])
 425
 426 # should the build process be building only the documentation?
 427 AC_MSG_CHECKING(whether to build only documentation)
 428 AC_ARG_ENABLE([documentation-only],
 429    [AS_HELP_STRING([--enable-documentation-only], [build only the documentation])],
 430    [documentation_only=${enableval}],
 431    [documentation_only=no])
 432 AC_MSG_RESULT($documentation_only)
 433 AS_IF([test "x$documentation_only" = "xyes"],
 434  [
 435   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 436   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 437  ],[
 438   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 439   # TODO: Double negation might be a bit hard to parse for some
 440   # TODO: people reading the output.
 441   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Not building only the documentation])
 442  ])
 443
 444 # should the build process be including the manpages? (default: yes)
 445 AC_MSG_CHECKING(whether to include man pages)
 446 AC_ARG_ENABLE([include-manpages],
 447    [AS_HELP_STRING([--disable-include-manpages], [Do not include the man pages in build and installation])],
 448    [include_manpages=${enableval}],
 449    [include_manpages=yes])
 450 AC_MSG_RESULT($include_manpages)
 451 AS_IF([test "x$include_manpages" = "xyes"],
 452  [
 453   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 454   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 455  ],[
 456   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 457   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 458  ])
 459
 460 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 461 # (not syntax!) to the commandline tools which generate the html. If not,
 462 # texinfo5 switches are used. This comes with no version checks, is
 463 # enabled only at distributors action (ie defaults to "no").
 464 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 465 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 466 AC_ARG_ENABLE([texinfo4],
 467    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 468    [activate_texinfo4=${enableval}],
 469    [activate_texinfo4=no])
 470 AC_MSG_RESULT($activate_texinfo4)
 471 AS_IF([test "x$activate_texinfo4" = "xyes"],
 472  [
 473   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 474   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 475  ],[
 476   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 477   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 478  ])
 479
 480
 481 # Adam shostack suggests the following for Windows:
 482 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 483 AC_ARG_ENABLE(gcc-hardening,
 484    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 485 [AS_IF([test x$enableval = xyes],[
 486     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 487     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 488     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 489     LDFLAGS="$LDFLAGS -pie"
 490  ])])
 491
 492 # Linker hardening options
 493 # Currently these options are ELF specific - you can't use this with MacOSX
 494 AC_ARG_ENABLE(linker-hardening,
 495   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 496 [AS_IF([test x$enableval = xyes],
 497    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 498
 499
 500 AC_ARG_ENABLE(sanitizer,
 501   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 502 [AS_IF([test x$enableval = xyes],[
 503    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 504  ])])
 505
 506
 507 extra_logging=GNUNET_NO
 508 AC_ARG_ENABLE([logging],
 509    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 510    [AS_IF([test "x$enableval" = "xyes"], [],
 511           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 512           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 513           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 514    ], [])
 515 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 516
 517 # should memory poisoning be enabled?
 518 AC_MSG_CHECKING(whether to poison freed memory)
 519 AC_ARG_ENABLE([poisoning],
 520    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 521    [enable_poisoning=${enableval}],
 522    [
 523      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 524        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 525        [enable_poisoning=no])
 526    ])
 527 AC_MSG_RESULT($enable_poisoning)
 528 AS_IF([test ! "x$enable_poisoning" = "xno"],
 529   [enable_poisoning=1],
 530   [enable_poisoning=0])
 531 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 532
 533 AS_IF([test $build = $target],
 534 [
 535 AC_MSG_CHECKING([for working HMAC])
 536 AC_LANG_PUSH(C)
 537 LIBS="$LIBS $LIBGCRYPT_LIBS"
 538 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 539 AC_RUN_IFELSE(
 540   [AC_LANG_PROGRAM([#include <gcrypt.h>
 541         #include <stdio.h>], [[
 542         gcry_md_hd_t mac;
 543
 544         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 545             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 546             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 547         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 548         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 549             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 550             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 551             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 552             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 553             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 554
 555         if (!gcry_check_version (GCRYPT_VERSION))
 556         {
 557           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 558           return 1;
 559         }
 560
 561         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 562         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 563
 564         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 565         {
 566           fprintf (stderr, "gcry_md_open error\n");
 567           return 2;
 568         }
 569
 570         gcry_md_setkey (mac, key, sizeof (key));
 571         gcry_md_write (mac, data, sizeof (data));
 572
 573         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 574         {
 575           fprintf (stderr, "memcmp error\n");
 576           return 3;
 577         }
 578
 579         gcry_md_close (mac);
 580
 581         return 0;
 582     ]])],
 583   [AC_MSG_RESULT([yes])],
 584   [
 585    RESULT=$?
 586    if test $RESULT = 3
 587    then
 588      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 589    fi
 590    if test $RESULT = 2
 591    then
 592      AC_MSG_FAILURE([HMAC test failed])
 593    fi
 594    if test $RESULT = 1
 595    then
 596      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 597    fi
 598   ],
 599   [AC_MSG_RESULT([cross compiling, test skipped])])
 600 AC_LANG_POP(C)
 601 ])      # $build = $target
 602
 603 # check for bluetooth library
 604 bluetooth=0
 605 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 606 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 607 AS_IF([test "$bluetooth" = 1],
 608  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 609  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 610
 611 # check for zbar library
 612 zbar=0
 613 AC_MSG_CHECKING(for libzbar)
 614 AC_ARG_WITH(zbar,
 615    [  --with-zbar=PREFIX (base of libzbar installation)],
 616    [AC_MSG_RESULT([$with_zbar])
 617     AS_CASE([$with_zbar],
 618       [no],[],
 619       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 620       [
 621         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 622         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 623         AC_CHECK_HEADERS(zbar.h,
 624           AC_CHECK_LIB([zbar], [zbar_processor_create],
 625             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 626             zbar=1))
 627        ])
 628    ],
 629    [AC_MSG_RESULT([--with-zbar not specified])
 630     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 631 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 632 AS_IF([test "x$zbar" = x1],
 633       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 634       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 635
 636 # check for jansson library
 637 jansson=0
 638 AC_MSG_CHECKING(for libjansson)
 639 AC_ARG_WITH(jansson,
 640    [  --with-jansson=PREFIX (base of libjansson installation)],
 641    [AC_MSG_RESULT([$with_jansson])
 642     AS_CASE([$with_jansson],
 643       [no],[],
 644       [yes],[
 645         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 646       ],[
 647         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 648         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 649         AC_CHECK_HEADERS(jansson.h,
 650           AC_CHECK_LIB([jansson], [json_loads],
 651             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 652             jansson=1))
 653       ])
 654    ],
 655    [AC_MSG_RESULT([--with-jansson not specified])
 656     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 657 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 658 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 659 AS_IF([test "x$jansson" = x1],
 660       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 661       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 662
 663
 664 # check for libpulse(audio) library
 665 pulse=0
 666 libpulse_msg="no"
 667 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 668 AS_IF([test "$pulse" = 1],
 669       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 670        libpulse_msg="yes"])
 671
 672 # check for libopus(audio) library
 673 opus=0
 674 libopus_msg="no"
 675 CHECK_LIBHEADER(LIBOPUS,
 676                 opus,
 677                 opus_decode_float,
 678                 opus/opus.h,
 679                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 680 AS_IF([test "x$opus" = x1],
 681       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 682        libopus_msg="yes"])
 683
 684 # libogg
 685 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 686         [AC_CHECK_HEADERS([ogg/ogg.h],
 687           AM_CONDITIONAL(HAVE_OGG, true)
 688           ogg=1
 689           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 690           AM_CONDITIONAL(HAVE_OGG, false)
 691           ogg=0
 692           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 693         AM_CONDITIONAL(HAVE_OGG, false)
 694         ogg=0)
 695
 696
 697 PKG_CHECK_MODULES([GLIB],
 698                   [glib-2.0],
 699   [# check for pbc library
 700   pbc=0
 701    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 702    AC_CHECK_HEADER([gabe.h],abe=1)
 703    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 704    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 705    AS_IF([test "x$pbc" = x1],
 706      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 707      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 708    AS_IF([test "x$abe" = x1],
 709     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 710     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 711   [# glib-2 not found
 712    AM_CONDITIONAL(HAVE_PBC, [false])
 713    AM_CONDITIONAL(HAVE_ABE, [false])
 714    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 715
 716 gst=0
 717 gstreamer_msg="no"
 718 PKG_CHECK_MODULES(
 719   [GST],
 720   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 721   [gst=1
 722    gstreamer_msg="yes"],
 723   [gst=0])
 724
 725 # Pulse Audio
 726 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 727  AS_IF([test "x$gst" != "x1"],[
 728   conversation_backend=none
 729   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 730   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 731   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 732  ],[
 733    conversation_backend=gst
 734    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 735    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 736    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 737  ])
 738 ],[
 739  conversation_backend=pulse
 740  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 741  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 742  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 743 ])
 744
 745 AS_IF([test "x$conversation_backend" = "xnone"],
 746       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 747       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 748
 749 # libgnurl
 750 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 751
 752 SAVE_CPPFLAGS=$CPPFLAGS
 753 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 754 LIBS="$LIBGNURL $LIBCURL $LIBS"
 755
 756 # libcurl-gnutls
 757 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 758 AS_IF([test "x$curl" = xtrue],[
 759  AC_CHECK_HEADER([curl/curl.h],
 760   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 761   [curl=false])
 762  # need libcurl-gnutls.so, everything else is not acceptable
 763  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 764  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 765 ])
 766
 767 # libcurl and libgnurl should be mutually exclusive
 768 AS_IF([test "$gnurl" = 1],
 769       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 770        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 771        AM_CONDITIONAL(HAVE_LIBCURL, false)
 772        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 773       [AS_IF([test "$curl" = true],
 774              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 775               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 776               AM_CONDITIONAL(HAVE_LIBCURL, true)
 777               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 778              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 779               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 780               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 781               AM_CONDITIONAL(HAVE_LIBCURL, false)
 782               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 783
 784 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 785 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 786
 787 # restore LIBS & CPPFLAGS
 788 LIBS=$SAVE_LIBS
 789 CPPFLAGS=$SAVE_CPPFLAGS
 790
 791 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 792 # GLPK must support glpk_init_env, version >= 4.43
 793 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 794 # GLPK must support atm MLP presolving, version >= 4.32
 795 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 796 AS_IF([test "x$glpk" = xfalse],
 797 [
 798         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 799         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 800 ],[
 801         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 802         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 803 ])
 804
 805
 806 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 807 AS_IF([test x$nss = xfalse],
 808   [
 809         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 810         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 811   ],[
 812         NSS_INCLUDES="
 813         #include <nss.h>
 814         "
 815         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 816                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 817                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 818                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 819                 [$NSS_INCLUDES])
 820 ])
 821
 822
 823
 824 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 825 AC_CHECK_LIB([kvm],[kvm_open])
 826 AC_CHECK_LIB([kstat],[kstat_open])
 827
 828
 829 # should the build process be restricted to the code required
 830 # for GNU Taler wallets?
 831 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 832 AC_ARG_ENABLE([taler-wallet],
 833    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 834    [taler_only=${enableval}],
 835    [taler_only=no])
 836 AC_MSG_RESULT($taler_only)
 837 AS_IF([test "x$taler_only" = "xyes"],
 838 [
 839   AM_CONDITIONAL([TALER_ONLY],true)
 840   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 841 ],[
 842   AM_CONDITIONAL([TALER_ONLY],false)
 843   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 844 ])
 845
 846 # test for libextractor
 847 extractor=0
 848 AC_MSG_CHECKING(for libextractor)
 849 AC_ARG_WITH(extractor,
 850    [  --with-extractor=PREFIX (base of libextractor installation)],
 851    [AC_MSG_RESULT([$with_extractor])
 852     AS_CASE([$with_extractor],
 853       [no],[],
 854       [yes],[
 855         AC_CHECK_HEADERS([extractor.h],
 856           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 857             extractor=1))
 858       ],[
 859         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 860         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 861         AC_CHECK_HEADERS([extractor.h],
 862           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 863             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 864             extractor=1))
 865       ])
 866    ],
 867    [AC_MSG_RESULT([--with-extractor not specified])
 868     AC_CHECK_HEADERS([extractor.h],
 869      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 870       extractor=1))])
 871 # restore LIBS
 872 LIBS=$SAVE_LIBS
 873
 874 AS_IF([test "$extractor" != 1],
 875  [
 876  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 877  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 878  ],[
 879  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 880  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 881  ])
 882
 883
 884 AS_IF([test "$taler_only" != yes],[
 885
 886
 887 # Check for libltdl header (#2999)
 888 ltdl=0
 889 AC_MSG_CHECKING(for libltdl)
 890 AC_ARG_WITH(ltdl,
 891    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 892    [AC_MSG_RESULT([$with_ltdl])
 893     AS_CASE([$with_ltdl],
 894       [no],[],
 895       [yes],[
 896         AC_CHECK_HEADERS(ltdl.h,
 897           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 898             ltdl=1))
 899       ],[
 900         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 901         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 902         AC_CHECK_HEADERS(ltdl.h,
 903           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 904             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 905             ltdl=1))
 906       ])
 907    ],
 908    [AC_MSG_RESULT([--with-ltdl not specified])
 909     AC_CHECK_HEADERS(ltdl.h,
 910      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 911       ltdl=1))])
 912 AS_IF([test x$ltdl = x1],
 913 [
 914  AC_MSG_RESULT([libltdl found])
 915 ],[
 916  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 917 ])
 918 # restore LIBS
 919 LIBS=$SAVE_LIBS
 920
 921 # libidn and libidn2. The ideal goal is this:
 922 # check for libidn2, if it doesn't exist check for libidn
 923 # if both exist, prefer libidn2
 924 # if none exist, fail and message that libidn or libidn2
 925 # is required with a preference for libidn2.
 926 # TODO: What we have right here can probably be improved.
 927 my_with_libidn=1
 928 AC_ARG_WITH(libidn,
 929             AS_HELP_STRING([--with-libidn=pathname],
 930                            [Support IDN (needs libidn)]),
 931             [],
 932             [withval="yes"])
 933 AS_IF([test x_$withval = x_yes],
 934       [AC_CHECK_HEADERS([idna.h],
 935           AC_MSG_NOTICE([Found idna.h]),
 936           AC_CHECK_HEADERS([idn/idna.h],
 937                AC_MSG_NOTICE([Found idn/idna.h]),
 938                my_with_libidn=0))],
 939       [AS_IF([test x_$withval != x_no],
 940              [CFLAGS="$CFLAGS -I$withval/include"
 941               LDFLAGS="$LDFLAGS -L$withval/lib"
 942               AC_CHECK_HEADERS([idna.h],
 943                 AC_MSG_NOTICE([Found idna.h]),
 944                 [AC_MSG_NOTICE([Failed to find idna.h])
 945                  my_with_libidn=0])],
 946              [my_with_libidn=0])])
 947
 948 my_with_libidn2=1
 949 AC_ARG_WITH(libidn2,
 950             AS_HELP_STRING([--with-libidn2=pathname],
 951                            [Support IDN (needs libidn2)]),
 952             [],
 953             [withval="yes"])
 954 AS_IF([test x_$withval = x_yes],
 955       [AC_CHECK_HEADERS([idn2.h],
 956        AC_MSG_NOTICE([Found idn2.h]),
 957        AC_CHECK_HEADERS([idn2/idn2.h],
 958           AC_MSG_NOTICE([Found idn2/idn2.h]),
 959           [AC_MSG_NOTICE([Failed to find idn2.h])
 960            my_with_libidn2=0]))],
 961       [AS_IF([test x_$withval != x_no],
 962              [CFLAGS="$CFLAGS -I$withval/include"
 963               LDFLAGS="$LDFLAGS -L$withval/lib"],
 964              [my_with_libidn2=0])])
 965
 966 AC_MSG_CHECKING([if libidn can be used])
 967 # Check for LIBIDNs
 968 there_can_only_be_one=1
 969
 970 working_libidn1=0
 971 working_libidn2=0
 972 AS_IF([test x$my_with_libidn2 = x1],
 973       [AC_MSG_NOTICE([Checking for libidn2])
 974        AC_CHECK_LIB([idn2],
 975                     [idn2_to_unicode_8z8z],
 976                     [working_libidn2=1
 977                     LIBS="-lidn2 $LIBS"
 978                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 979                                        [1],
 980                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 981                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 982                      MISSING_SEP=", "])])
 983 AM_CONDITIONAL(HAVE_LIBIDN2,
 984                test x$working_libidn2 = x1)
 985 AS_IF([test x$working_libidn2 = x0],
 986       [AS_IF([test x$my_with_libidn = x1],
 987              [AC_MSG_NOTICE([Checking for libidn])
 988               AC_CHECK_LIB([idn],
 989                            [idna_to_ascii_8z],
 990                            [working_libidn1=1
 991                            LIBS="-lidn $LIBS"
 992                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
 993                                               [1],
 994                                               [Define to 1 if you have 'libidn' (-lidn).])],
 995                            [there_can_only_be_one=0])],
 996              [AS_IF([test x$my_with_libidn2 = x1],
 997                     [there_can_only_be_one=0
 998                      AC_MSG_FAILURE([* There can only be one libidn.
 999                                      * Provide either libidn >= 1.13
1000                                      * or
1001                                      * libidn2 to the configure
1002                                      * script via
1003                                      * --with-libidn2
1004                                      * --with-libidn])])])])
1005 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1006
1007 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1008       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1009
1010 AS_IF([test x$there_can_only_be_one = x0],
1011       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1012
1013 # test for zlib
1014 SAVE_LDFLAGS=$LDFLAGS
1015 SAVE_CPPFLAGS=$CPPFLAGS
1016 AC_ARG_WITH(zlib,
1017             [  --with-zlib[[=DIR]]       use libz in DIR],
1018             [AS_IF([test "$withval" = "no"],
1019                    [AC_MSG_ERROR([GNUnet requires zlib])],
1020                    [test "$withval" != "yes"],
1021                    [Z_DIR=$withval
1022                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1023                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1024 AC_CHECK_HEADER(zlib.h,
1025                 [],
1026                 [AC_MSG_ERROR([GNUnet requires zlib])])
1027 AC_CHECK_LIB(z,
1028              compress2,
1029              [AC_DEFINE([HAVE_ZLIB],
1030                         [],
1031                         [Have compression library])
1032               if test "x${Z_DIR}" != "x"; then
1033                       Z_CFLAGS="-I${Z_DIR}/include"
1034                       Z_LIBS="-L${Z_DIR}/lib -lz"
1035               else
1036                       Z_LIBS="-lz"
1037               fi],
1038               [AC_MSG_ERROR([GNUnet requires zlib])])
1039 AC_SUBST(Z_CFLAGS)
1040 AC_SUBST(Z_LIBS)
1041
1042 AS_IF([test "$enable_shared" = "no"],
1043       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1044
1045
1046 # restore LIBS
1047 LIBS=$SAVE_LIBS
1048
1049
1050 # end of taler-only being false
1051 ])
1052
1053
1054 # check for iconv
1055 AM_ICONV
1056
1057 # test for libunistring
1058 gl_LIBUNISTRING
1059 AS_IF([test $HAVE_LIBUNISTRING != yes],
1060       [AC_MSG_ERROR([GNUnet requires libunistring])])
1061
1062 # under emscripten, $gl_libunistring_hexversion is undefined
1063 if test "$taler_only" != yes; then
1064
1065 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1066       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1067 fi
1068 AC_CHECK_HEADERS([unistr.h],
1069                  ,
1070                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1071
1072 # restore LIBS
1073 LIBS=$SAVE_LIBS
1074
1075
1076
1077 # Checks for standard header files.
1078 AC_HEADER_DIRENT
1079 AC_HEADER_STDC
1080
1081 # Check for headers that are ALWAYS required
1082 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1083
1084
1085
1086 # Checks for headers that are only required on some systems or
1087 # opional (and where we do NOT abort if they are not there)
1088 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1089
1090 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1091 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1092 [#ifdef HAVE_SYS_TYPES_H
1093 #include <sys/types.h>
1094 #endif
1095 #ifdef HAVE_NETINET_IN_SYSTM_H
1096 #include <netinet/in_systm.h>
1097 #endif
1098 #ifdef HAVE_NETINET_IN_H
1099 #include <netinet/in.h>
1100 #endif
1101 ])
1102
1103 SAVE_LDFLAGS=$LDFLAGS
1104 SAVE_CPPFLAGS=$CPPFLAGS
1105
1106 # test for sqlite
1107 sqlite=false
1108 AC_MSG_CHECKING(for SQLite)
1109 AC_ARG_WITH(sqlite,
1110   [  --with-sqlite=PFX       base of SQLite installation],
1111   [AC_MSG_RESULT("$with_sqlite")
1112    AS_CASE([$with_sqlite],
1113      [no],[],
1114      [yes],[
1115       AC_CHECK_HEADERS(sqlite3.h,
1116       sqlite=true)],
1117      [
1118     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1119     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1120     AC_CHECK_HEADERS(sqlite3.h,
1121      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1122      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1123      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1124      sqlite=true)
1125     LDFLAGS=$SAVE_LDFLAGS
1126     CPPFLAGS=$SAVE_CPPFLAGS
1127     ])
1128   ],
1129   [AC_MSG_RESULT([--with-sqlite not specified])
1130     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1131 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1132 AC_SUBST(SQLITE_CPPFLAGS)
1133 AC_SUBST(SQLITE_LDFLAGS)
1134
1135 LDFLAGS=$SAVE_LDFLAGS
1136 CPPFLAGS=$SAVE_CPPFLAGS
1137
1138 # test for postgres
1139 postgres=false
1140 # even running the check for postgres breaks emscripten ...
1141 AS_IF([test "$taler_only" != yes],
1142       [AX_LIB_POSTGRESQL([9.5],
1143         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1144          AC_CHECK_HEADERS([libpq-fe.h],
1145          postgres=true)
1146         ],
1147         [AC_MSG_RESULT([no postgres])])])
1148 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1149
1150
1151 LDFLAGS=$SAVE_LDFLAGS
1152 CPPFLAGS=$SAVE_CPPFLAGS
1153
1154 # mysql & windows
1155 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1156 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1157
1158 # test for mysql
1159 mysql=false
1160 mysqlfail=false
1161 SAVE_LDFLAGS=$LDFLAGS
1162 SAVE_CPPFLAGS=$CPPFLAGS
1163 AC_MSG_CHECKING(for mysql)
1164 AC_ARG_WITH(mysql,
1165   [  --with-mysql=PFX        base of MySQL installation],
1166   [AC_MSG_RESULT([$with_mysql])
1167    AS_CASE([$with_mysql],
1168      [no],[],
1169      [yes|""],[
1170       AC_CHECK_HEADERS(mysql/mysql.h,
1171        AC_CHECK_LIB(mysqlclient, mysql_init,
1172        mysql=true), [], [])
1173      ],[
1174       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1175       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1176       AC_CHECK_HEADERS(mysql/mysql.h,
1177        AC_CHECK_LIB(mysqlclient, mysql_init,
1178         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1179         MYSQL_CPPFLAGS="-I$with_mysql/include"
1180
1181         mysql=true), [], [])
1182      ])
1183   ],
1184   [AC_MSG_RESULT([--with-mysql not specified])
1185    if test -d "/usr/lib64/mysql"; then
1186     MYSQL_LIBDIR="/usr/lib64/mysql"
1187    elif test -d "/usr/lib/mysql"; then
1188     MYSQL_LIBDIR="/usr/lib/mysql"
1189    else
1190     MYSQL_LIBDIR="/usr/lib"
1191    fi
1192    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1193    AC_CHECK_LIB(mysqlclient, mysql_init,
1194     [AC_CHECK_HEADERS(mysql/mysql.h,
1195       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1196       mysql=true
1197
1198      , [], [])])
1199   ])
1200
1201 AC_SUBST(MYSQL_LDFLAGS)
1202 AC_SUBST(MYSQL_CPPFLAGS)
1203
1204 # additional version check for mysql
1205 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1206 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1207  [
1208   AC_MSG_CHECKING(mysql version)
1209   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1210     [[
1211       #include <mysql/mysql.h>]],
1212     [[
1213       #if (MYSQL_VERSION_ID < 40100)
1214       #error needs at least version >= 4.1
1215       #endif
1216       int main () { return 0; }
1217     ]])
1218     ],mysql=true,mysql=false)
1219   AS_IF([test "$mysql" = "false"],
1220    [
1221     mysqlfail=true
1222     AC_MSG_RESULT([fail, >= 4.1 required])
1223    ],[
1224     AC_MSG_RESULT(ok)
1225    ])
1226 ])
1227 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1228 AM_CONDITIONAL(HAVE_MYSQLE, false)
1229 # restore LIBS
1230 LIBS=$SAVE_LIBS
1231 LDFLAGS=$SAVE_LDFLAGS
1232 CPPFLAGS=$SAVE_CPPFLAGS
1233
1234 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1235 [
1236  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1237 ])
1238
1239 # libmicrohttpd
1240 lmhd=0
1241 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1242 AC_ARG_WITH(microhttpd,
1243    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1244        [base of libmicrohttpd installation])],
1245    [],
1246    [with_microhttpd=check])
1247 AS_CASE([$with_microhttpd],
1248    [no], [],
1249    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1250    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1251        [lmhd=1],
1252        [AC_MSG_WARN([Building without libmicrohttpd])])],
1253    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1254     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1255     export PKG_CONFIG_PATH
1256     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1257     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1258 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1259 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1260
1261 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1262
1263 # restore LIBS
1264 LIBS=$SAVE_LIBS
1265
1266 # check for gettext
1267 AM_GNU_GETTEXT([external])
1268 AM_GNU_GETTEXT_VERSION([0.18.1])
1269
1270 # Checks for standard typedefs, structures, and compiler characteristics.
1271 AC_TYPE_PID_T
1272 AC_TYPE_SIZE_T
1273 AC_TYPE_MODE_T
1274 AC_HEADER_TIME
1275 AC_HEADER_STAT
1276 AC_HEADER_STDBOOL
1277 AC_STRUCT_TM
1278
1279 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1280    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1281    ],
1282    [],
1283    [
1284       #include <sys/types.h>
1285       #include <sys/socket.h>
1286       #include <netinet/in.h>
1287    ])
1288
1289 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1290                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1291                             1,
1292                             [Do we have sockaddr_un.sun_len?])],
1293                 [],
1294                 [
1295                 #include <sys/types.h>
1296                 #include <sys/socket.h>
1297                 #include <sys/un.h>
1298                 ])
1299
1300
1301
1302 # Checks for library functions.
1303 AC_FUNC_CLOSEDIR_VOID
1304 AC_FUNC_FORK
1305 AC_PROG_GCC_TRADITIONAL
1306 AC_FUNC_MEMCMP
1307 AC_FUNC_SELECT_ARGTYPES
1308 AC_FUNC_CHOWN
1309
1310 AC_TYPE_SIGNAL
1311 AC_FUNC_STAT
1312 AC_FUNC_STRFTIME
1313 AC_FUNC_VPRINTF
1314 AC_HEADER_SYS_WAIT
1315 AC_TYPE_OFF_T
1316 AC_TYPE_UID_T
1317 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1318
1319 # restore LIBS
1320 LIBS=$SAVE_LIBS
1321
1322 GN_INTLINCL=""
1323 GN_LIBINTL="$LTLIBINTL"
1324 AC_ARG_ENABLE(framework,
1325               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1326               enable_framework_build=$enableval)
1327 AM_CONDITIONAL(WANT_FRAMEWORK,
1328                test x$enable_framework_build = xyes)
1329 AS_IF([test x$enable_framework_build = xyes],
1330       [AC_DEFINE([FRAMEWORK_BUILD],
1331                  1,
1332                  [Build a Mac OS X Framework])
1333       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1334       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1335       AC_LIB_APPENDTOVAR([CPPFLAGS],
1336                          [$GN_INTLINCL])])
1337
1338 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1339 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1340
1341 AC_SUBST(GN_LIB_LDFLAGS)
1342 AC_SUBST(GN_PLUGIN_LDFLAGS)
1343 AC_SUBST(GN_INTLINCL)
1344 AC_SUBST(GN_LIBINTL)
1345
1346 AC_SUBST(CPPFLAGS)
1347 AC_SUBST(LIBS)
1348 AC_SUBST(LDFLAGS)
1349 AC_SUBST(EXT_LIB_PATH)
1350 AC_SUBST(EXT_LIBS)
1351
1352 AC_SUBST(LIBPREFIX)
1353 AC_SUBST(DLLDIR)
1354 AC_SUBST(EXT_LIB_PATH)
1355
1356 DATAROOTDIR=$datarootdir
1357 AC_SUBST(DATAROOTDIR)
1358
1359 # test for sudo
1360 AC_MSG_CHECKING(for sudo)
1361 AC_ARG_WITH(sudo,
1362             [  --with-sudo=PATH       path to sudo binary (or just yes)],
1363             [AC_MSG_RESULT("$with_sudo")
1364              AS_CASE([$with_sudo],
1365                      [no],[SUDO_BINARY=],
1366                      [yes],[SUDO_BINARY=sudo],
1367                      [SUDO_BINARY=$with_sudo])],
1368             [AC_MSG_RESULT([no])])
1369 AC_SUBST(SUDO_BINARY)
1370 AM_CONDITIONAL([HAVE_SUDO],
1371                [test "x$SUDO_BINARY" != "x" -o -w /])
1372
1373 # test for doas
1374 AC_MSG_CHECKING(for doas)
1375 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1376 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1377
1378 # test for gnunetdns group name
1379 GNUNETDNS_GROUP=gnunetdns
1380 AC_MSG_CHECKING(for gnunetdns group name)
1381 AC_ARG_WITH(gnunetdns,
1382             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1383             [AC_MSG_RESULT("$with_gnunetdns")
1384              AS_CASE([$with_gnunetdns],
1385                      [no],[GNUNETDNS_GROUP=gnunet],
1386                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1387                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1388             [AC_MSG_RESULT([gnunetdns])])
1389 AC_SUBST(GNUNETDNS_GROUP)
1390
1391
1392
1393 # gnutls
1394 gnutls=0
1395 gnutls_dane=0
1396 AC_MSG_CHECKING(for gnutls)
1397 AC_ARG_WITH(gnutls,
1398             [  --with-gnutls=PFX   base of gnutls installation],
1399             [AC_MSG_RESULT([$with_gnutls])
1400              AS_CASE([$with_gnutls],
1401                      [no],[],
1402                      [yes],
1403                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1404                                        AC_CHECK_LIB([gnutls],
1405                                                     [gnutls_priority_set],
1406                                                     gnutls=true))
1407                       AC_CHECK_HEADERS([gnutls/dane.h],
1408                                        AC_CHECK_LIB([gnutls-dane],
1409                                                     [dane_verify_crt_raw],
1410                                                     gnutls_dane=1))],
1411
1412         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1413         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1414         AC_CHECK_HEADERS([gnutls/abstract.h],
1415             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1416               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1417               gnutls=true))
1418         AC_CHECK_HEADERS([gnutls/dane.h],
1419             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1420               gnutls_dane=1))
1421       ])
1422    ],
1423    [AC_MSG_RESULT([--with-gnutls not specified])
1424     AC_CHECK_HEADERS([gnutls/abstract.h],
1425         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1426           gnutls=true))
1427     AC_CHECK_HEADERS([gnutls/dane.h],
1428         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1429                      gnutls_dane=1))
1430    ])
1431 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1432 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1433 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1434 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1435
1436
1437
1438 # Test if we are building for superMUC
1439 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1440 AC_ARG_ENABLE([supermuc],
1441     [AS_HELP_STRING([--enable-supermuc],
1442        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1443     [AS_IF([test "x$enable_supermuc" = "xno"],
1444       [supermuc=0],
1445       [supermuc=1])],
1446     [supermuc=0
1447      enable_supermuc=no])
1448 AC_MSG_RESULT($enable_SUPERMUC)
1449 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1450 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1451
1452 # Check if NSE has to send timestamp information to testbed logger for
1453 # generating histogram of messages received
1454 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1455 AC_ARG_ENABLE([nse-histogram],
1456     [AS_HELP_STRING([--enable-nse-histogram],
1457        [have NSE send timestamp information to testbed logger for generating
1458        histogram of received messages.  NOT useful for production (default is
1459        NO)])],
1460     [AS_IF([test "x$enableval" = "xno"],
1461       [nse_histogram=0],
1462       [nse_histogram=1])],
1463     [nse_histogram=0
1464      enable_nse_histogram=no])
1465 AC_MSG_RESULT($enable_nse_histogram)
1466 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1467 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1468                    [have NSE send timestamp information to testbed logger])
1469
1470 # should 'make check' run tests?
1471 AC_MSG_CHECKING(whether to run tests)
1472 AC_ARG_ENABLE([testruns],
1473    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1474    [enable_tests_run=${enableval}],
1475    [enable_tests_run=yes])
1476 AC_MSG_RESULT($enable_test_run)
1477 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1478
1479
1480 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1481 AC_ARG_ENABLE([benchmark],
1482    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1483    [enable_benchmark=${enableval}],
1484    [enable_benchmark=no])
1485 AC_MSG_RESULT($enable_benchmark)
1486 AS_IF([test "x$enable_benchmark" = "xyes"],
1487       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1488 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1489
1490
1491 # should expensive tests be run?
1492 AC_MSG_CHECKING(whether to run expensive tests)
1493 AC_ARG_ENABLE([expensivetests],
1494    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1495    [enable_expensive=${enableval}],
1496    [enable_expensive=no])
1497 AC_MSG_RESULT($enable_expensive)
1498 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1499
1500 # should ports be open for Java services?
1501 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1502 AC_ARG_ENABLE([javaports],
1503    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1504    [enable_java_ports=${enableval}],
1505    [enable_java_ports=no])
1506 AC_MSG_RESULT($enable_java_ports)
1507 AS_IF([test "x$enable_java_ports" = "xyes"],
1508  [JAVAPORT=""],
1509  [JAVAPORT="$UNIXONLY"])
1510 AC_SUBST(JAVAPORT)
1511
1512 # should benchmarks be run?
1513 AC_MSG_CHECKING(whether to run benchmarks during make check)
1514 AC_ARG_ENABLE([benchmarks],
1515    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1516    [enable_benchmarks=${enableval}],
1517    [enable_benchmarks=no])
1518 AC_MSG_RESULT($enable_benchmarks)
1519 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1520
1521 # should gnunet-testing be compiled
1522 AC_MSG_CHECKING(wether to compile gnunet-testing)
1523 AC_ARG_ENABLE([testing],
1524    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1525    [enable_testing=${enableval}],
1526    [enable_testing=yes])
1527 AC_MSG_RESULT($enable_testing)
1528 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1529
1530 # should experimental code be compiled (code that may not yet compile)?
1531 AC_MSG_CHECKING(whether to compile experimental code)
1532 AC_ARG_ENABLE([experimental],
1533    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1534    [enable_experimental=${enableval}],
1535    [enable_experimental=no])
1536 AC_MSG_RESULT($enable_experimental)
1537 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1538
1539 # should malicious code be compiled (should only be used for testing)?
1540 AC_MSG_CHECKING(whether to compile malicious code)
1541 AC_ARG_ENABLE([malicious],
1542    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1543    [AS_IF([test "x$enableval" = "xno"],
1544      [malicious=0],
1545      [malicious=1])],
1546    [malicious=0
1547     enable_malicious=no])
1548 AC_MSG_RESULT($enable_malicious)
1549 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1550 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1551                    [enable compilation of malicious code])
1552
1553 # should services be started on demand when needed?
1554 # Some services may choose to never start by default
1555 # and it is up to the service/module developer to decide
1556 # by having "START_ON_DEMAND = NO" instead of
1557 # "START_ON_DEMAND = @START_ON_DEMAND@"
1558 # in the service/module's conf.in file.
1559 # See also IMMEDIATE_START for an unconditional immediate start.
1560 START_ON_DEMAND="YES"
1561 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1562 AC_ARG_ENABLE([autostart],
1563    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1564    [enable_autostart=${enableval}
1565     AS_IF([test "x$enable_autostart" = "xno"],
1566       [START_ON_DEMAND="NO"])
1567    ],
1568    [enable_autostart=yes])
1569 AC_MSG_RESULT($enable_autostart)
1570 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1571 AC_SUBST(START_ON_DEMAND)
1572
1573 # should memory statistics be kept (very expensive CPU-wise!)
1574 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1575 AC_ARG_ENABLE([heapstats],
1576    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1577    [enable_heapstats=1],
1578    [enable_heapstats=0])
1579 AC_MSG_RESULT($enable_heapstats)
1580 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1581
1582
1583 # Check if the __thread storage class for
1584 # thread-local storage is available.
1585 AC_MSG_CHECKING(whether __thread is supported)
1586 AC_LINK_IFELSE(
1587 [AC_LANG_PROGRAM([#include <stdlib.h>
1588                    #undef __thread
1589                    static __thread int a = 1;],
1590                   [exit(a-1);])],
1591  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1592 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1593 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1594       [AC_MSG_RESULT(yes)],
1595       [AC_MSG_RESULT(no)])
1596
1597 # gcov compilation
1598 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1599 AC_ARG_ENABLE([coverage],
1600               AS_HELP_STRING([--enable-coverage],
1601                              [compile the library with code coverage support]),
1602               [use_gcov=${enableval}],
1603               [use_gcov=no])
1604 AC_MSG_RESULT($use_gcov)
1605 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1606
1607
1608 # version info
1609 # TODO: git blame says this predates our switch to git.
1610 # git-svn should be adjusted to simply git, or
1611 # an external script that does the job.
1612 AC_PATH_PROG(svnversioncommand, svnversion)
1613 AC_PATH_PROG(gitcommand, git)
1614 AC_MSG_CHECKING(for source being under a VCS)
1615
1616
1617 # version info
1618 AC_PATH_PROG(gitcommand, git)
1619 AC_MSG_CHECKING(for source being under a VCS)
1620 git_version=
1621 AS_IF([test ! "X$gitcommand" = "X"],
1622 [
1623   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1624 ])
1625 AS_IF([test "X$git_version" = "X"],
1626   [
1627     vcs_name="no"
1628     vcs_version="\"release\""
1629   ],
1630   [
1631     vcs_name="yes, git-svn"
1632     vcs_version="\"git-$git_version\""
1633   ])
1634 AC_MSG_RESULT($vcs_name)
1635
1636 AC_MSG_CHECKING(VCS version)
1637 AC_MSG_RESULT($vcs_version)
1638 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1639
1640 AC_CONFIG_FILES([
1641 Makefile
1642 contrib/Makefile
1643 contrib/hellos/Makefile
1644 contrib/services/Makefile
1645 contrib/services/openrc/Makefile
1646 contrib/services/systemd/Makefile
1647 contrib/scripts/Makefile
1648 contrib/scripts/gnunet-logread/Makefile
1649 doc/Makefile
1650 doc/man/Makefile
1651 doc/doxygen/Makefile
1652 doc/handbook/Makefile
1653 doc/tutorial/Makefile
1654 lint/Makefile
1655 m4/Makefile
1656 po/Makefile.in
1657 src/Makefile
1658 src/arm/Makefile
1659 src/arm/arm.conf
1660 src/ats/Makefile
1661 src/ats/ats.conf
1662 src/ats-tool/Makefile
1663 src/ats-tests/Makefile
1664 src/auction/Makefile
1665 src/block/Makefile
1666 src/cadet/Makefile
1667 src/cadet/cadet.conf
1668 src/core/Makefile
1669 src/core/core.conf
1670 src/consensus/Makefile
1671 src/consensus/consensus.conf
1672 src/conversation/Makefile
1673 src/conversation/conversation.conf
1674 src/curl/Makefile
1675 src/datacache/Makefile
1676 src/datastore/Makefile
1677 src/datastore/datastore.conf
1678 src/dht/Makefile
1679 src/dht/dht.conf
1680 src/dns/Makefile
1681 src/dns/dns.conf
1682 src/exit/Makefile
1683 src/fragmentation/Makefile
1684 src/fs/Makefile
1685 src/fs/fs.conf
1686 src/gns/Makefile
1687 src/gns/gns.conf
1688 src/gns/nss/Makefile
1689 src/gnsrecord/Makefile
1690 src/hello/Makefile
1691 src/identity/Makefile
1692 src/identity/identity.conf
1693 src/abd/Makefile
1694 src/abd/abd.conf
1695 src/include/Makefile
1696 src/integration-tests/Makefile
1697 src/json/Makefile
1698 src/hostlist/Makefile
1699 src/my/Makefile
1700 src/mysql/Makefile
1701 src/namecache/Makefile
1702 src/namecache/namecache.conf
1703 src/namestore/Makefile
1704 src/namestore/namestore.conf
1705 src/nat/Makefile
1706 src/nat/nat.conf
1707 src/nat-auto/Makefile
1708 src/nat-auto/nat-auto.conf
1709 src/nse/Makefile
1710 src/nse/nse.conf
1711 src/nt/Makefile
1712 src/peerinfo/Makefile
1713 src/peerinfo/peerinfo.conf
1714 src/peerinfo-tool/Makefile
1715 src/peerstore/Makefile
1716 src/peerstore/peerstore.conf
1717 src/pq/Makefile
1718 src/pt/Makefile
1719 src/regex/Makefile
1720 src/regex/regex.conf
1721 src/revocation/Makefile
1722 src/revocation/revocation.conf
1723 src/rps/Makefile
1724 src/rps/rps.conf
1725 src/secretsharing/Makefile
1726 src/secretsharing/secretsharing.conf
1727 src/scalarproduct/Makefile
1728 src/scalarproduct/scalarproduct.conf
1729 src/set/Makefile
1730 src/set/set.conf
1731 src/sq/Makefile
1732 src/statistics/Makefile
1733 src/statistics/statistics.conf
1734 src/template/Makefile
1735 src/testbed/Makefile
1736 src/testbed/testbed.conf
1737 src/testbed-logger/Makefile
1738 src/testbed-logger/testbed-logger.conf
1739 src/testing/Makefile
1740 src/topology/Makefile
1741 src/transport/Makefile
1742 src/transport/transport.conf
1743 src/util/Makefile
1744 src/util/resolver.conf
1745 src/vpn/Makefile
1746 src/vpn/vpn.conf
1747 src/zonemaster/Makefile
1748 src/zonemaster/zonemaster.conf
1749 src/rest/Makefile
1750 src/abe/Makefile
1751 src/reclaim-attribute/Makefile
1752 src/reclaim/Makefile
1753 pkgconfig/Makefile
1754 pkgconfig/gnunetarm.pc
1755 pkgconfig/gnunetats.pc
1756 pkgconfig/gnunetblock.pc
1757 pkgconfig/gnunetcadet.pc
1758 pkgconfig/gnunetconsensus.pc
1759 pkgconfig/gnunetconversation.pc
1760 pkgconfig/gnunetcore.pc
1761 pkgconfig/gnunetdatacache.pc
1762 pkgconfig/gnunetdatastore.pc
1763 pkgconfig/gnunetdht.pc
1764 pkgconfig/gnunetdns.pc
1765 pkgconfig/gnunetenv.pc
1766 pkgconfig/gnunetfragmentation.pc
1767 pkgconfig/gnunetfs.pc
1768 pkgconfig/gnunetgns.pc
1769 pkgconfig/gnunethello.pc
1770 pkgconfig/gnunetidentity.pc
1771 pkgconfig/gnunetmicrophone.pc
1772 pkgconfig/gnunetmysql.pc
1773 pkgconfig/gnunetnamestore.pc
1774 pkgconfig/gnunetnat.pc
1775 pkgconfig/gnunetnse.pc
1776 pkgconfig/gnunetpeerinfo.pc
1777 pkgconfig/gnunetpq.pc
1778 pkgconfig/gnunetregex.pc
1779 pkgconfig/gnunetrevocation.pc
1780 pkgconfig/gnunetrps.pc
1781 pkgconfig/gnunetscalarproduct.pc
1782 pkgconfig/gnunetset.pc
1783 pkgconfig/gnunetspeaker.pc
1784 pkgconfig/gnunetstatistics.pc
1785 pkgconfig/gnunettestbed.pc
1786 pkgconfig/gnunettesting.pc
1787 pkgconfig/gnunettransport.pc
1788 pkgconfig/gnunetutil.pc
1789 pkgconfig/gnunetvpn.pc
1790 ])
1791 AC_OUTPUT
1792
1793
1794 # FIXME: `some modules' -> be more specific which exact modules.
1795
1796 # java ports
1797 AS_IF([test "x$enable_java_ports" = "xyes"],
1798       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1799
1800 ####
1801 #### Lasciate ogne speranza, voi ch'intrate
1802 ####
1803 #### This could be moved to the checks above,
1804 #### but for now let's keep it here.
1805 ####
1806
1807 # -- print message regarding enabled experimental features
1808 AS_IF([test "x$enable_experimental" = "xyes"],
1809       [experimental_msg="experimental features enabled"])
1810 # -- OSX Framework
1811 AS_IF([test "$enable_framework_build" = "yes"],
1812       [macosx_framework_msg="yes"],
1813       [macosx_framework_msg="no"])
1814 # -- libidn 2
1815 AS_IF([test "x$working_libidn2" = x1],
1816       [libidn2_msg="libidn2"])
1817 # -- libidn 1
1818 AS_IF([test "x$working_libidn1" = x1],
1819       [libidn1_msg="libidn1"])
1820 # -- texi2mdoc
1821 AS_IF([test "x$texi2mdoc_generation" = x1],
1822       [mdoc_msg="yes"],
1823       [mdoc_msg="no"])
1824 # -- texinfo
1825 AS_IF([test "x$makeinfo" != "x1"],
1826       [texinfo_msg="no"],
1827       [texinfo_msg="yes"])
1828 # -- conversation
1829 AS_IF([test "x$conversation_backend" = "xnone"],
1830       [AS_IF([test "x$pulse" != "x1"],
1831              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1832               libpulse_msg="no"],
1833              [libpulse_msg="yes"])
1834        AS_IF([test "x$opus" != "x1"],
1835              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1836               libopus_msg="no"],
1837              [libopus_msg="yes"])
1838        AS_IF([test "x$gst" != "x1"],
1839              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1840               gstreamer_msg="no"],
1841              [gstreamer_msg="yes"])],
1842       [features_msg="$features_msg conversation"])
1843 # -- interface
1844 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1845 # -- libmicrohttpd
1846 AS_IF([test "x$lmhd" != "x1"],
1847       [libmicrohttpd_msg="no (optional)"],
1848       [libmicrohttpd_msg="yes"])
1849 # -- jansson
1850 AS_IF([test "x$jansson" = "x0"],
1851       [jansson_msg="no (optional)"],
1852       [jansson_msg="yes"])
1853 # -- libextractor
1854 AS_IF([test "$extractor" != 1],
1855       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1856       [libextractor_msg="yes"])
1857 # -- libzbar
1858 AS_IF([test "x$zbar" = "x1"],
1859       [libzbar_msg="yes"
1860        features_msg="$features_msg gnunet-qr"],
1861       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1862        libzbar_msg="no"])
1863 # -- libgnurl
1864 AS_IF([test "$gnurl" = "0"],
1865       [AS_IF([test "x$curl" = "xfalse"],
1866              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1867               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1868               curl_msg="no"],
1869              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1870               curl_msg="yes"])],
1871        [gnurl_msg="yes"])
1872 # -- ifconfig
1873 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
1874       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
1875        ifconfig_msg="no (optional)"],
1876       [ifconfig_msg="yes"])
1877 # -- upnpc
1878 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
1879       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
1880        upnpc_msg="no (optional)"],
1881       [upnpc_msg="yes"])
1882 # -- iptables
1883 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
1884       [AC_MSG_NOTICE([WARNING: optional iptables not found])
1885        iptables_msg="no (optional)"],
1886       [iptables_msg="yes"])
1887 # -- bluetooth
1888 AS_IF([test "x$bluetooth" = "x0"],
1889       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
1890        bluetooth_msg="no (optional)"],
1891       [bluetooth_msg="yes"])
1892 # -- gnutls
1893 AS_IF([test x$gnutls != xtrue],
1894       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
1895        gnutls_msg="no"],
1896       [AS_IF([test "x$gnutls_dane" != "x1"],
1897              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
1898               gnutls_msg="yes (without DANE support)"],
1899              [gnutls_msg="yes (with DANE support)"])])
1900 # -- databases
1901 AS_IF([test $mysqlfail = true]
1902       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
1903 AS_IF([test "$mysql" = true],
1904       [features_msg="$features_msg mysql"
1905        mysql_msg="yes"],
1906       [mysql_msg="no"])
1907 AS_IF([test "$sqlite" = true],
1908       [features_msg="$features_msg sqlite"
1909        sqlite_msg="yes"],
1910       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1911        sqlite_msg="no"])
1912 AS_IF([test "$postgres" = true],
1913       [features_msg="$features_msg postgres"
1914        postgres_msg="yes"],
1915       [postgres_msg="no"])
1916 # -- features
1917 # ---- 1. replace spaces with newlines,
1918 # ---- 2. sort the lines,
1919 # ---- 3. replace the newlines with spaces.
1920 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
1921 AC_SUBST(features_msg)
1922
1923
1924 # The summary
1925 # TODO: reduce the length of the last message block ("the message")
1926
1927 AC_MSG_NOTICE([
1928 GNUnet Configuration
1929
1930 gnunet version:                 ${VERSION}
1931
1932 Host setup:                     ${host}
1933 Install prefix:                 ${prefix}
1934 Compiler:                       ${CC}
1935 CFLAGS:                         ${CFLAGS}
1936 CPPFLAGS:                       ${CPPFLAGS}
1937 LDFLAGS:                        ${LDFLAGS}
1938 LIBS:                           ${LIBS}
1939 Build Target:                   $build_target
1940 Mac OSX framework build:        ${macosx_framework_msg}
1941
1942 Default Interface:              ${interface_msg}
1943
1944 MySQL:                          ${mysql_msg}
1945 PostgreSQL:                     ${postgres_msg}
1946 sqlite3:                        ${sqlite_msg}
1947 gnurl:                          ${gnurl_msg}
1948 curl:                           ${curl_msg}
1949 bluetooth:                      ${bluetooth_msg}
1950 jansson:                        ${jansson_msg}
1951 iptables:                       ${iptables_msg}
1952 ifconfig:                       ${ifconfig_msg}
1953 upnpc:                          ${upnpc_msg}
1954 gnutls:                         ${gnutls_msg}
1955 libzbar:                        ${libzbar_msg}
1956 java:                           ${java_msg}
1957 libmicrohttpd:                  ${libmicrohttpd_msg}
1958 libidn:                         ${libidn1_msg}${libidn2_msg}
1959 libopus:                        ${libopus_msg}
1960 gstreamer:                      ${gstreamer_msg}
1961 libpulse:                       ${libpulse_msg}
1962 libextractor:                   ${libextractor_msg}
1963
1964 texinfo manual:                 ${texinfo_msg}
1965 transpiled mdoc manual:         ${mdoc_msg}
1966
1967 features:                       ${features_msg}
1968 experimental:                   ${experimental_msg}
1969
1970
1971 IMPORTANT:
1972
1973 Please make sure NOW that you have created a user and group 'gnunet'
1974 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
1975 type:
1976
1977   addgroup gnunetdns
1978   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1979
1980 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1981 'gnunet'.  Then, you can compile GNUnet with
1982
1983   make
1984
1985 After that, run (if necessary as 'root')
1986
1987   make install
1988
1989 to install everything.
1990
1991 Each GNUnet user should be added to the 'gnunet' group (may
1992 require fresh login to come into effect):
1993
1994   adduser USERNAME gnunet
1995
1996 (run the above command as root once for each of your users, replacing
1997 "USERNAME" with the respective login names).  If you have a global IP
1998 address, no further configuration is required.
1999
2000 For more detailed setup instructions, see https://docs.gnunet.org/
2001
2002 Optionally, download and compile gnunet-gtk to get a GUI for
2003 file-sharing and configuration.  This is particularly recommended
2004 if your network setup is non-trivial, as gnunet-setup can be
2005 used to test in the GUI if your network configuration is working.
2006 gnunet-setup should be run as the "gnunet" user under X.  As it
2007 does very little with the network, running it as "root" is likely
2008 also harmless.  You can also run it as a normal user, but then
2009 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2010 home directory in the end.
2011
2012 Once you have configured your peer, run (as the 'gnunet' user)
2013
2014   gnunet-arm -s
2015
2016 to start the peer.  You can then run the various GNUnet-tools as
2017 your "normal" user (who should only be in the group 'gnunet').
2018 ])