configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.8], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 136      build_target="freebsd"
 137      LIBPREFIX=
 138      DLLDIR=lib
 139      UNIXONLY="#"
 140   ],
 141   [*openbsd*],[
 142      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 143      build_target="openbsd"
 144      use_openbsd_libtool=true
 145      LIBPREFIX=
 146      DLLDIR=lib
 147      UNIXONLY="#"
 148   ],
 149   [*netbsd*],[
 150      build_target="netbsd"
 151      LIBPREFIX=
 152      DLLDIR=lib
 153      UNIXONLY="#"
 154   ],
 155   [*solaris*],[
 156      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 157      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 158      AC_CHECK_LIB(resolv, res_init)
 159      AC_CHECK_LIB(rt, nanosleep)
 160      build_target="solaris"
 161      LIBPREFIX=
 162      DLLDIR=lib
 163      UNIXONLY="#"
 164   ],
 165   [*arm-linux*],[
 166      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 167      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 168      build_target="linux"
 169      LIBPREFIX=
 170      DLLDIR=lib
 171      UNIXONLY="#"
 172   ],
 173   [gnu*],[
 174      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 175      build_target="gnu"
 176      UNIXONLY="#"
 177   ],
 178   [
 179      AC_MSG_RESULT(Unrecognised OS $host_os)
 180      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 181      UNIXONLY=""
 182 ])
 183 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 184 AC_SUBST(DEFAULT_INTERFACE)
 185
 186 # Disable TCP-based IPC on systems that support UNIX domain
 187 # sockets in default configuratin:
 188 AC_SUBST(UNIXONLY)
 189
 190
 191 AC_MSG_CHECKING([for build target])
 192 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 193 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 194 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 195 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 196 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 197 # FIXME: We need a define BSD for some binaries like we
 198 # need define LINUX for some. This does not scale, how
 199 # can we solve this better?
 200 AM_CONDITIONAL(XBSD, test "$build_target" = "netbsd" -o "$build_target" = "freebsd" -o "$build_target" = "openbsd")
 201 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 202 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 203
 204 AC_MSG_RESULT([$build_target])
 205 AC_SUBST(build_target)
 206 AM_CONDITIONAL([am__fastdepOBJC], false)
 207 AC_UNALIGNED_64_ACCESS
 208
 209 # some other checks for standard libs
 210 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 211 AC_SEARCH_LIBS([memrchr], [],
 212                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 213 AC_SEARCH_LIBS([memset_s], [],
 214                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 215 AC_SEARCH_LIBS([memset_s], [],
 216                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 217 AC_CHECK_LIB(socket, socket)
 218 AC_CHECK_LIB(m, log)
 219 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 220
 221 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 222 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 223
 224 AC_CHECK_PROGS(PKG_CONFIG, [pkgconf, pkg-config], false)
 225 AM_CONDITIONAL(HAVE_PKG_CONFIG, test x$PKG_CONFIG != xfalse)
 226
 227 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 228 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 229 AC_MSG_CHECKING(for SSH key)
 230   AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 231   if test -f /tmp/gnunet_test_cosks_ssh_garbage; then
 232      rm -f /tmp/gnunet_test_cosks_ssh_garbage
 233   fi
 234
 235
 236 # autotools' m4 for python has no maximum version!
 237 # python3.4 - python3.8 for tests (3.8 unchecked)
 238 # TODO: document how to override the lowest version
 239 # TODO: found by this.
 240 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 241 AM_PATH_PYTHON([3.4],, [:])
 242 AC_SUBST([PYTHON])
 243 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 244
 245
 246 # perl
 247 AC_PATH_PROG( PERL, perl, ,
 248               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 249 AC_SUBST([PERL])
 250 AS_IF([test -x "$PERL"],
 251   [AC_DEFINE_UNQUOTED([HAVE_PERL], [1], [Path to Perl])],
 252   [AC_DEFINE_UNQUOTED([HAVE_PERL], [0], [Path to Perl])])
 253
 254 # should we install gnunet-logread?
 255 AC_MSG_CHECKING(whether to install gnunet-logread)
 256 AC_ARG_WITH([gnunet-logread],
 257               [AS_HELP_STRING([--with-gnunet-logread],
 258                               [Install gnunet-logread])],
 259               [logread=${withval}],
 260               [logread=no])
 261 AC_MSG_RESULT($logread)
 262 AS_IF([test "x$logread" = "xyes"],
 263       [AM_CONDITIONAL([GNUNET_LOGREAD], true)
 264        AC_DEFINE([GNUNET_LOGREAD],
 265                  [1],
 266                  [Installing gnunet-logread])],
 267       [AM_CONDITIONAL([GNUNET_LOGREAD],
 268                       false)
 269        AC_DEFINE([GNUNET_LOGREAD],
 270                  [0],
 271                  [Not installing gnunet-logread])])
 272
 273 # iptables is a soft requirement to run tests
 274 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 275
 276 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 277  [AS_IF([test -x "/sbin/iptables"],
 278    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 279    [AS_IF([test -x "/usr/sbin/iptables"],
 280       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 281
 282 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 283  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 284  [AC_MSG_WARN([warning: 'iptables' not found.])])
 285
 286 # ip6tables is a soft requirement for some features
 287 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 288
 289 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 290   [AS_IF([test -x "/sbin/ip6tables"],
 291      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 292      [AS_IF([test -x "/usr/sbin/ip6tables"],
 293         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 294
 295
 296 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 297   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 298   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 299
 300 # ip is a soft requirement for some features
 301 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 302
 303 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 304  [AS_IF([test -x "/sbin/ip"],
 305    [VAR_IP_BINARY="/sbin/ip"],
 306    [AS_IF([test -x "/usr/sbin/ip"],
 307           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 308
 309 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 310  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 311  [AC_MSG_WARN([warning: 'ip' not found.])])
 312
 313 # locate 'ifconfig'
 314 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 315
 316 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 317 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 318   [AS_IF([test -x "/sbin/ifconfig"],
 319      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 320      [AS_IF([test -x "/usr/sbin/ifconfig"],
 321             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 322
 323 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 324   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 325   [AC_MSG_WARN(['ifconfig' not found.])])
 326
 327
 328 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 329
 330 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 331 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 332       [AS_IF([test -x "/sbin/sysctl"],
 333              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 334              [AS_IF([test -x "/usr/sbin/sysctl"],
 335                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 336 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 337       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 338       [AC_MSG_WARN(['sysctl' not found.])])
 339
 340 # miniupnpc / upnpc binary is a soft runtime requirement
 341 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 342
 343 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 344   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 345   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 346
 347
 348 # checkbashisms
 349 AC_CHECK_PROGS(CHECKBASHISMS_BINARY, [checkbashisms checkbashisms.pl], false)
 350 AM_CONDITIONAL(HAVE_CHECKBASHISMS, test x$CHECKBASHISMS_BINARY != xfalse)
 351
 352 # uncrustify
 353 # TODO: maybe add flag to pass location
 354 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 355 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 356
 357 # yapf
 358 # TODO: less repetition, add flag to pass name
 359 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 360 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 361
 362
 363 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 364   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 365      [Define if struct tm has the tm_gmtoff member.])],
 366      ,
 367      [#include <time.h>])
 368
 369 # 'save' libs; only those libs found so far will be
 370 # linked against _everywhere_.  For the others, we
 371 # will be more selective!
 372 SAVE_LIBS=$LIBS
 373
 374 have_addrinfo_a=0
 375 AC_CHECK_LIB(anl,
 376              getaddrinfo_a,
 377              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 378                                           1,
 379                                           [getaddrinfo_a supported])])
 380 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 381                [test "$have_addrinfo_a" = 1])
 382
 383 # libgcrypt
 384 gcrypt=0
 385 NEED_LIBGCRYPT_API=1
 386 NEED_LIBGCRYPT_VERSION=1.6.0
 387
 388
 389 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 390 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 391
 392 AS_IF([test $gcrypt = 0],
 393  [
 394   AC_MSG_ERROR([[
 395 ***
 396 *** You need libgcrypt to build this program.
 397 *** This library is for example available at
 398 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 399 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 400 ***  is required.
 401 ***]])
 402 ])
 403 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 404
 405 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 406
 407 AC_CHECK_HEADER([if_tun.h],
 408     [AC_DEFINE([IF_TUN_HDR], ["if_tun.h"], [if_tun.h include path])],
 409     [AC_CHECK_HEADER([linux/if_tun.h],
 410         [AC_DEFINE([IF_TUN_HDR], ["linux/if_tun.h"])],
 411         [AC_CHECK_HEADER([net/if_tun.h],
 412             [AC_DEFINE([IF_TUN_HDR], ["net/if_tun.h"])],
 413             [AC_CHECK_HEADER([net/tun/if_tun.h],
 414                 [AC_DEFINE([IF_TUN_HDR], ["net/tun/if_tun.h"])])])])])
 415
 416
 417 # should the build process be building the documentation?
 418 AC_MSG_CHECKING(whether to build documentation)
 419 AC_ARG_ENABLE([documentation],
 420               [AS_HELP_STRING([--disable-documentation],
 421                               [do not build the documentation])],
 422               [documentation=${enableval}],
 423               [documentation=yes])
 424 AC_MSG_RESULT($documentation)
 425 AS_IF([test "x$documentation" = "xyes"],
 426       [AM_CONDITIONAL([DOCUMENTATION],
 427                       true)
 428        AC_DEFINE([DOCUMENTATION],
 429                  [1],
 430                  [Building the documentation])],
 431       [AM_CONDITIONAL([DOCUMENTATION],
 432                       false)
 433        AC_DEFINE([DOCUMENTATION],
 434                  [0],
 435                  [Not building the documentation])])
 436
 437 # COMMENT: Check whether to transpile texinfo to mdoc.
 438 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 439 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 440 # COMMENT: and makes the configure fail if it is missing.
 441 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 442 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 443 # COMMENT: or nothing was set (this is the default).
 444 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 445 # COMMENT: potential non-existence of the texi2mdoc binary.
 446 # COMMENT: Default return value / setting: no
 447 AC_MSG_CHECKING(whether to include generated texi2mdoc output in installation)
 448 AC_ARG_ENABLE([texi2mdoc-generation],
 449               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 450                               [include generated texi2mdoc output in installation])],
 451               [texi2mdoc_generation=${enableval}],
 452               [texi2mdoc_generation=no])
 453 AC_MSG_RESULT($texi2mdoc_generation)
 454 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 455       [AS_IF([test "$texi2mdoc" = 0],
 456              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 457               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 458               AC_MSG_WARN([ERROR: Operating System package manager or from])
 459               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 460              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 461               AC_DEFINE([TEXI2MDOC_GENERATION],
 462                         [1],
 463                         [Building section 7 mdoc output])])],
 464       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 465                       false)
 466        AC_DEFINE([TEXI2MDOC_GENERATION],
 467                  [0],
 468                  [Not building section 7 mdoc output])])
 469
 470 # test for texi2mdoc (the binary, not the script distributed
 471 # with autogen)
 472 # TODO: refactor this and the check above.
 473 AC_MSG_CHECKING(for texi2mdoc binary)
 474 AC_CHECK_PROGS(TEXI2MDOC_BINARY, [texi2mdoc], false)
 475 AM_CONDITIONAL(HAVE_TEXI2MDOC, test x$TEXI2MDOC_BINARY != xfalse)
 476
 477 # texi2man is a tool which needs to be investigated and
 478 # is probably incompatible to texi2mdoc in invocation.
 479 # Detection at this point only serves as a reminder that
 480 # I will work this into the build-system.
 481 AC_MSG_CHECKING(for texi2man perl script)
 482 AC_CHECK_PROGS(TEXI2MAN_SCRIPT, [texi2man], false)
 483 AM_CONDITIONAL(HAVE_TEXI2MAN, test x$TEXI2MAN_SCRIPT != xfalse)
 484
 485
 486 # test for mandoc
 487 AC_MSG_CHECKING(for mandoc binary)
 488 AC_CHECK_PROGS(MANDOC_BINARY, [mandoc], false)
 489 AM_CONDITIONAL(HAVE_MANDOC, test x$MANDOC_BINARY != xfalse)
 490
 491 # should the build process be building only the documentation?
 492 AC_MSG_CHECKING(whether to build only documentation)
 493 AC_ARG_ENABLE([documentation-only],
 494    [AS_HELP_STRING([--enable-documentation-only],
 495                    [build only the documentation])],
 496    [documentation_only=${enableval}],
 497    [documentation_only=no])
 498 AC_MSG_RESULT($documentation_only)
 499 AS_IF([test "x$documentation_only" = "xyes"],
 500  [
 501   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 502   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 503  ],[
 504   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 505   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 506  ])
 507
 508 # should the build process be including the manpages? (default: yes)
 509 AC_MSG_CHECKING(whether to include man pages)
 510 AC_ARG_ENABLE([include-manpages],
 511    [AS_HELP_STRING([--disable-include-manpages],
 512                    [Do not include the man pages in build and installation])],
 513    [include_manpages=${enableval}],
 514    [include_manpages=yes])
 515 AC_MSG_RESULT($include_manpages)
 516 AS_IF([test "x$include_manpages" = "xyes"],
 517  [
 518   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 519   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 520  ],[
 521   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 522   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 523  ])
 524
 525 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 526 # (not syntax!) to the commandline tools which generate the html. If not,
 527 # texinfo5 switches are used. This comes with no version checks, is
 528 # enabled only at distributors action (ie defaults to "no").
 529 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 530 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 531 AC_ARG_ENABLE([texinfo4],
 532    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 533    [activate_texinfo4=${enableval}],
 534    [activate_texinfo4=no])
 535 AC_MSG_RESULT($activate_texinfo4)
 536 AS_IF([test "x$activate_texinfo4" = "xyes"],
 537  [
 538   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 539   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 540  ],[
 541   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 542   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 543  ])
 544
 545
 546 # Adam shostack suggests the following for Windows:
 547 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 548 AC_ARG_ENABLE(gcc-hardening,
 549    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 550 [AS_IF([test x$enableval = xyes],[
 551     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 552     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 553     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 554     LDFLAGS="$LDFLAGS -pie"
 555  ])])
 556
 557 # Linker hardening options
 558 # Currently these options are ELF specific - you can't use this with MacOSX
 559 AC_ARG_ENABLE(linker-hardening,
 560   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 561 [AS_IF([test x$enableval = xyes],
 562    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 563
 564
 565 AC_ARG_ENABLE(sanitizer,
 566   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 567 [AS_IF([test x$enableval = xyes],[
 568    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 569  ])])
 570
 571
 572 extra_logging=GNUNET_NO
 573 AC_ARG_ENABLE([logging],
 574    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 575    [AS_IF([test "x$enableval" = "xyes"], [],
 576           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 577           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 578           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 579    ], [])
 580 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 581
 582 # should memory poisoning be enabled?
 583 AC_MSG_CHECKING(whether to poison freed memory)
 584 AC_ARG_ENABLE([poisoning],
 585    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 586    [enable_poisoning=${enableval}],
 587    [
 588      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 589        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 590        [enable_poisoning=no])
 591    ])
 592 AC_MSG_RESULT($enable_poisoning)
 593 AS_IF([test ! "x$enable_poisoning" = "xno"],
 594   [enable_poisoning=1],
 595   [enable_poisoning=0])
 596 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 597
 598 AS_IF([test $build = $target],
 599 [
 600 AC_MSG_CHECKING([for working HMAC])
 601 AC_LANG_PUSH(C)
 602 LIBS="$LIBS $LIBGCRYPT_LIBS"
 603 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 604 AC_RUN_IFELSE(
 605   [AC_LANG_PROGRAM([#include <gcrypt.h>
 606         #include <stdio.h>], [[
 607         gcry_md_hd_t mac;
 608
 609         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 610             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 611             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 612         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 613         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 614             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 615             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 616             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 617             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 618             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 619
 620         if (!gcry_check_version (GCRYPT_VERSION))
 621         {
 622           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 623           return 1;
 624         }
 625
 626         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 627         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 628
 629         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 630         {
 631           fprintf (stderr, "gcry_md_open error\n");
 632           return 2;
 633         }
 634
 635         gcry_md_setkey (mac, key, sizeof (key));
 636         gcry_md_write (mac, data, sizeof (data));
 637
 638         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 639         {
 640           fprintf (stderr, "memcmp error\n");
 641           return 3;
 642         }
 643
 644         gcry_md_close (mac);
 645
 646         return 0;
 647     ]])],
 648   [AC_MSG_RESULT([yes])],
 649   [
 650    RESULT=$?
 651    if test $RESULT = 3
 652    then
 653      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 654    fi
 655    if test $RESULT = 2
 656    then
 657      AC_MSG_FAILURE([HMAC test failed])
 658    fi
 659    if test $RESULT = 1
 660    then
 661      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 662    fi
 663   ],
 664   [AC_MSG_RESULT([cross compiling, test skipped])])
 665 AC_LANG_POP(C)
 666 ])      # $build = $target
 667
 668 # check for bluetooth library
 669 bluetooth=0
 670 AC_MSG_CHECKING(for libbluetooth)
 671 AC_ARG_WITH(libbluetooth,
 672     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 673     [AC_MSG_RESULT([$with_libbluetooth])
 674      AS_CASE([$with_libbluetooth],
 675         [no],[],
 676         [yes],[
 677             CHECK_LIBHEADER(BLUETOOTH,
 678                             bluetooth,
 679                             ba2str,
 680                             bluetooth/bluetooth.h,
 681                             bluetooth=1,)
 682         ],[
 683             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 684             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 685             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 686                              AC_CHECK_LIB([bluetooth],
 687                                           [ba2str],
 688                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 689                                           bluetooth=1))
 690         ])
 691     ],
 692     [AC_MSG_RESULT([--with-libbluetooth not specified])
 693      CHECK_LIBHEADER(BLUETOOTH,
 694                      bluetooth,
 695                      ba2str,
 696                      bluetooth/bluetooth.h,
 697                      bluetooth=1,)])
 698 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 699 AS_IF([test "$bluetooth" = 1],
 700       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 701       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 702
 703 # check for zbar library
 704 # NOTE: Do not add checks for: -lSM, -lICE, -lX11, -lXv and -ljpeg
 705 # NOTE: they must be provided by the build environment, not the
 706 # NOTE: build-system of gnunet, as they are 2nd or 3rd level dependencies.
 707 zbar=0
 708 AC_MSG_CHECKING(for libzbar)
 709 AC_ARG_WITH(zbar,
 710    [  --with-zbar=PREFIX (base of libzbar installation)],
 711    [AC_MSG_RESULT([$with_zbar])
 712     AS_CASE([$with_zbar],
 713       [no],[],
 714       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 715       [
 716         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 717         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 718         AC_CHECK_HEADERS(zbar.h,
 719           AC_CHECK_LIB([zbar], [zbar_processor_create],
 720             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 721             zbar=1))
 722        ])
 723    ],
 724    [AC_MSG_RESULT([--with-zbar not specified])
 725     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 726 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 727 AS_IF([test "x$zbar" = x1],
 728       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 729       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 730
 731 # check for jansson library
 732 jansson=0
 733 AC_MSG_CHECKING(for libjansson)
 734 AC_ARG_WITH(jansson,
 735    [  --with-jansson=PREFIX (base of libjansson installation)],
 736    [AC_MSG_RESULT([$with_jansson])
 737     AS_CASE([$with_jansson],
 738       [no],[],
 739       [yes],[
 740         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 741       ],[
 742         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 743         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 744         AC_CHECK_HEADERS(jansson.h,
 745           AC_CHECK_LIB([jansson], [json_loads],
 746             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 747             jansson=1))
 748       ])
 749    ],
 750    [AC_MSG_RESULT([--with-jansson not specified])
 751     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 752 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 753 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 754 AS_IF([test "x$jansson" = x1],
 755       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 756       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 757
 758
 759 # check for libpulse(audio) library
 760 pulse=0
 761 libpulse_msg="no"
 762 AC_MSG_CHECKING(for libpulse)
 763 # TODO: --with-libpulse or --with-pulseaudio? What is more established
 764 # TODO: in this context?
 765 AC_ARG_WITH(libpulse,
 766     [  --with-libpulse=PREFIX (base of libpulse installation)],
 767     [AC_MSG_RESULT([$with_libpulse])
 768      AS_CASE([$with_libpulse],
 769         [no],[],
 770         [yes],[
 771             CHECK_LIBHEADER(LIBPULSE,
 772                             pulse,
 773                             pa_stream_peek,
 774                             pulse/simple.h,
 775                             pulse=1,)
 776         ],[
 777             LDFLAGS="-L$with_libpulse/lib $LDFLAGS"
 778             CPPFLAGS="-I$with_libpulse/include $CPPFLAGS"
 779             AC_CHECK_HEADERS(pulse/simple.h,
 780                              AC_CHECK_LIB([pulse],
 781                                           [pa_stream_peek],
 782                                           EXT_LIB_PATH="-L$with_libpulse/lib $EXT_LIB_PATH"
 783                                           pulse=1))
 784         ])
 785     ],
 786     [AC_MSG_RESULT([--with-libpulse not specified])
 787      CHECK_LIBHEADER(LIBPULSE,
 788                      pulse,
 789                      pa_stream_peek,
 790                      pulse/simple.h,
 791                      pulse=1,)])
 792 AM_CONDITIONAL(HAVE_PULSE, [test "$pulse" = 1])
 793 AS_IF([test x"$pulse" = x1],
 794       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 795        libpulse_msg="yes"],
 796       [AC_DEFINE([HAVE_PULSE],[0],[Lacking libpulse(audio) library])
 797        libpulse_msg="no"])
 798
 799 # check for libopus(audio) library
 800 opus=0
 801 libopus_msg="no"
 802 AC_MSG_CHECKING(for libopus)
 803 AC_ARG_WITH(libopus,
 804     [  --with-libopus=PREFIX (base of libopus installation)],
 805     [AC_MSG_RESULT([$with_libopus])
 806      AS_CASE([$with_libopus],
 807         [no],[],
 808         [yes],[
 809             CHECK_LIBHEADER(LIBOPUS,
 810                             opus,
 811                             opus_decode_float,
 812                             opus/opus.h,
 813                             AC_CHECK_DECL([OPUS_SET_GAIN],
 814                                           [opus=1],
 815                                           [],
 816                                           [[
 817                                           #include <opus/opus.h>
 818                                           ]]))
 819     ],[
 820         LDFLAGS="-L$with_libopus/lib $LDFLAGS"
 821         CPPFLAGS="-I$with_libopus/include $CPPFLAGS"
 822         AC_CHECK_HEADERS(opus/opus.h,
 823                          AC_CHECK_LIB([opus],
 824                                       [OPUS_SET_GAIN],
 825                                       EXT_LIB_PATH="-L$with_libopus/lib $EXT_LIB_PATH"
 826                                       opus=1))
 827       ])
 828     ],
 829     [AC_MSG_RESULT([--with-libopus not specified])
 830      CHECK_LIBHEADER(LIBOPUS,
 831                      opus,
 832                      opus_decode_float,
 833                      opus/opus.h,
 834                      AC_CHECK_DECL([OPUS_SET_GAIN],
 835                                    [opus=1],
 836                                    [],
 837                                    [[
 838                                      #include <opus/opus.h>
 839                                    ]]))])
 840 AM_CONDITIONAL(HAVE_OPUS, [test "$opus" = 1])
 841 AS_IF([test "x$opus" = x1],
 842       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 843        libopus_msg="yes"],
 844       [AC_DEFINE([HAVE_OPUS],[0],[Lacking libopus library])
 845        libopus_msg="no"])
 846
 847 # libogg
 848 AC_MSG_CHECKING(for libogg)
 849 AC_ARG_WITH(libogg,
 850     [  --with-libogg=PREFIX (base of libogg installation)],
 851     [AC_MSG_RESULT([$with_libogg])
 852      AS_CASE([$with_libogg],
 853         [no],[],
 854         [yes],[
 855             CHECK_LIBHEADER(LIBOGG,
 856                             ogg,
 857                             ogg_stream_flush_fill,
 858                             ogg/ogg.h,
 859                             ogg=1,)
 860         ],[
 861             LDFLAGS="-L$with_libogg/lib $LDFLAGS"
 862             CPPFLAGS="-I$with_libogg/include $CPPFLAGS"
 863             AC_CHECK_HEADERS(ogg/ogg.h,
 864                              AC_CHECK_LIB([ogg],
 865                                           [ogg_stream_flush_fill],
 866                                           EXT_LIB_PATH="-L$with_libogg/lib $EXT_LIB_PATH"
 867                                           ogg=1))
 868         ])
 869      ],
 870      [AC_MSG_RESULT([--with-libogg not specified])
 871       CHECK_LIBHEADER(LIBOGG,
 872                       ogg,
 873                       ogg_stream_flush_fill,
 874                       ogg/ogg.h,
 875                       ogg=1,)])
 876 AM_CONDITIONAL(HAVE_OGG, [test "$ogg" = 1])
 877 AS_IF([test x"$ogg" = x1],
 878       [AC_DEFINE([HAVE_OGG],[1],[Have ogg])]
 879       [AC_DEFINE([HAVE_OGG],[0],[Lacking ogg])])
 880
 881
 882 PKG_CHECK_MODULES([GLIB],
 883                   [glib-2.0],
 884   [# check for pbc library
 885   pbc=0
 886    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 887    AC_CHECK_HEADER([gabe.h],abe=1)
 888    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 889    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 890    AS_IF([test "x$pbc" = x1],
 891      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 892      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 893    AS_IF([test "x$abe" = x1],
 894     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 895     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 896   [# glib-2 not found
 897    AM_CONDITIONAL(HAVE_PBC, [false])
 898    AM_CONDITIONAL(HAVE_ABE, [false])
 899    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 900
 901
 902 gst=0
 903 gstreamer_msg="no"
 904 AC_MSG_CHECKING(for gstreamer)
 905 PKG_CHECK_MODULES(
 906   [GST],
 907   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 908   [gst=1
 909    gstreamer_msg="yes"],
 910   [gst=0])
 911
 912 # conversation
 913 AC_MSG_CHECKING(conversation feature set to build)
 914 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 915  AS_IF([test "x$gst" != "x1"],[
 916   conversation_backend=none
 917   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 918   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 919   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 920  ],[
 921    conversation_backend=gst
 922    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 923    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 924    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 925  ])
 926 ],[
 927  conversation_backend=pulse
 928  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 929  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 930  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 931 ])
 932
 933 AS_IF([test "x$conversation_backend" = "xnone"],
 934       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 935       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 936
 937 # libgnurl
 938 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 939
 940 SAVE_CPPFLAGS=$CPPFLAGS
 941 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 942 LIBS="$LIBGNURL $LIBCURL $LIBS"
 943
 944 # libcurl-gnutls
 945 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 946 AS_IF([test "x$curl" = xtrue],[
 947  AC_CHECK_HEADER([curl/curl.h],
 948   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 949   [curl=false])
 950  # need libcurl-gnutls.so, everything else is not acceptable
 951  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 952  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 953 ])
 954
 955 # libcurl and libgnurl should be mutually exclusive
 956 AS_IF([test "$gnurl" = 1],
 957       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 958        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 959        AM_CONDITIONAL(HAVE_LIBCURL, false)
 960        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 961       [AS_IF([test "$curl" = true],
 962              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 963               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 964               AM_CONDITIONAL(HAVE_LIBCURL, true)
 965               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 966              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 967               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 968               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 969               AM_CONDITIONAL(HAVE_LIBCURL, false)
 970               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 971
 972 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 973 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 974
 975 # restore LIBS & CPPFLAGS
 976 LIBS=$SAVE_LIBS
 977 CPPFLAGS=$SAVE_CPPFLAGS
 978
 979
 980 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 981 AS_IF([test x$nss = xfalse],
 982   [
 983         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 984         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 985   ],[
 986         NSS_INCLUDES="
 987         #include <nss.h>
 988         "
 989         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 990                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 991                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 992                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 993                 [$NSS_INCLUDES])
 994 ])
 995
 996
 997
 998 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 999 AC_CHECK_LIB([kvm],[kvm_open])
1000 AC_CHECK_LIB([kstat],[kstat_open])
1001
1002
1003 # should the build process be restricted to the code required
1004 # for GNU Taler wallets?
1005 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
1006 AC_ARG_ENABLE([taler-wallet],
1007    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
1008    [taler_only=${enableval}],
1009    [taler_only=no])
1010 AC_MSG_RESULT($taler_only)
1011 AS_IF([test "x$taler_only" = "xyes"],
1012 [
1013   AM_CONDITIONAL([TALER_ONLY],true)
1014   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
1015 ],[
1016   AM_CONDITIONAL([TALER_ONLY],false)
1017   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
1018 ])
1019
1020 # test for libextractor
1021 extractor=0
1022 AC_MSG_CHECKING(for libextractor)
1023 AC_ARG_WITH(extractor,
1024    [  --with-extractor=PREFIX (base of libextractor installation)],
1025    [AC_MSG_RESULT([$with_extractor])
1026     AS_CASE([$with_extractor],
1027       [no],[],
1028       [yes],[
1029         AC_CHECK_HEADERS([extractor.h],
1030           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1031             extractor=1))
1032       ],[
1033         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
1034         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
1035         AC_CHECK_HEADERS([extractor.h],
1036           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1037             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
1038             extractor=1))
1039       ])
1040    ],
1041    [AC_MSG_RESULT([--with-extractor not specified])
1042     AC_CHECK_HEADERS([extractor.h],
1043      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1044       extractor=1))])
1045 # restore LIBS
1046 LIBS=$SAVE_LIBS
1047
1048 AS_IF([test "$extractor" != 1],
1049  [
1050  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
1051  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
1052  ],[
1053  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
1054  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
1055  ])
1056
1057
1058 AS_IF([test "$taler_only" != yes],[
1059
1060
1061 # Check for libltdl header (#2999)
1062 ltdl=0
1063 AC_MSG_CHECKING(for libltdl)
1064 AC_ARG_WITH(ltdl,
1065    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
1066    [AC_MSG_RESULT([$with_ltdl])
1067     AS_CASE([$with_ltdl],
1068       [no],[],
1069       [yes],[
1070         AC_CHECK_HEADERS(ltdl.h,
1071           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1072             ltdl=1))
1073       ],[
1074         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
1075         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
1076         AC_CHECK_HEADERS(ltdl.h,
1077           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1078             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
1079             ltdl=1))
1080       ])
1081    ],
1082    [AC_MSG_RESULT([--with-ltdl not specified])
1083     AC_CHECK_HEADERS(ltdl.h,
1084      AC_CHECK_LIB([ltdl], [lt_dlopenext],
1085       ltdl=1))])
1086 AS_IF([test x$ltdl = x1],
1087 [
1088  AC_MSG_RESULT([libltdl found])
1089 ],[
1090  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool).])
1091 ])
1092 # restore LIBS
1093 LIBS=$SAVE_LIBS
1094
1095 # libidn and libidn2. The ideal goal is this:
1096 # check for libidn2, if it doesn't exist check for libidn
1097 # if both exist, prefer libidn2
1098 # if none exist, fail and message that libidn or libidn2
1099 # is required with a preference for libidn2.
1100 # TODO: What we have right here can probably be improved.
1101 AC_MSG_CHECKING(for idn or idn2)
1102
1103 AC_MSG_CHECKING(for idn)
1104 my_with_libidn=1
1105 AC_ARG_WITH(libidn,
1106             AS_HELP_STRING([--with-libidn=pathname],
1107                            [Support IDN (needs libidn)]),
1108             [],
1109             [withval="yes"])
1110 AS_IF([test x_$withval = x_yes],
1111       [AC_CHECK_HEADERS([idna.h],
1112                         AC_MSG_NOTICE([Found idna.h]),
1113                         AC_CHECK_HEADERS([idn/idna.h],
1114                                          AC_MSG_NOTICE([Found idn/idna.h]),
1115                                          my_with_libidn=0))],
1116       [AS_IF([test x_$withval != x_no],
1117              [CFLAGS="$CFLAGS -I$withval/include"
1118               LDFLAGS="$LDFLAGS -L$withval/lib"
1119               AC_CHECK_HEADERS([idna.h],
1120                                AC_MSG_NOTICE([Found idna.h]),
1121                                    [AC_MSG_NOTICE([Failed to find idna.h])
1122                                my_with_libidn=0])],
1123              [my_with_libidn=0])])
1124
1125 AC_MSG_CHECKING(for idn2)
1126 my_with_libidn2=1
1127 AC_ARG_WITH(libidn2,
1128             AS_HELP_STRING([--with-libidn2=pathname],
1129                            [Support IDN (needs libidn2)]),
1130             [],
1131             [withval="yes"])
1132 AS_IF([test x_$withval = x_yes],
1133       [AC_CHECK_HEADERS([idn2.h],
1134                         AC_MSG_NOTICE([Found idn2.h]),
1135                         AC_CHECK_HEADERS([idn2/idn2.h],
1136                                          AC_MSG_NOTICE([Found idn2/idn2.h]),
1137                                          [AC_MSG_NOTICE([Failed to find idn2.h])
1138                                          my_with_libidn2=0]))],
1139       [AS_IF([test x_$withval != x_no],
1140              [CFLAGS="$CFLAGS -I$withval/include"
1141               LDFLAGS="$LDFLAGS -L$withval/lib"],
1142                   [my_with_libidn2=0])])
1143
1144 AC_MSG_CHECKING([if libidn can be used])
1145 # Check for LIBIDNs
1146 there_can_only_be_one=1
1147
1148 working_libidn1=0
1149 working_libidn2=0
1150 AS_IF([test x$my_with_libidn2 = x1],
1151       [AC_MSG_NOTICE([Checking for libidn2])
1152        AC_CHECK_LIB([idn2],
1153                     [idn2_to_unicode_8z8z],
1154                     [working_libidn2=1
1155                     LIBS="-lidn2 $LIBS"
1156                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1157                                        [1],
1158                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1159                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1160                      MISSING_SEP=", "])])
1161 AM_CONDITIONAL(HAVE_LIBIDN2, test x$working_libidn2 = x1)
1162 AS_IF([test x$working_libidn2 = x0],
1163       [AS_IF([test x$my_with_libidn = x1],
1164              [AC_MSG_NOTICE([Checking for libidn])
1165               AC_CHECK_LIB([idn],
1166                            [idna_to_ascii_8z],
1167                            [working_libidn1=1
1168                            LIBS="-lidn $LIBS"
1169                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1170                                               [1],
1171                                               [Define to 1 if you have 'libidn' (-lidn).])],
1172                            [there_can_only_be_one=0])],
1173              [AS_IF([test x$my_with_libidn2 = x1],
1174                     [there_can_only_be_one=0
1175                      AC_MSG_FAILURE([* There can only be one libidn.
1176                                      * Provide either libidn >= 1.13
1177                                      * or
1178                                      * libidn2 to the configure
1179                                      * script via
1180                                      * --with-libidn2
1181                                      * --with-libidn])])])])
1182 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1183
1184 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1185       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1186
1187 AS_IF([test x$there_can_only_be_one = x0],
1188       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1189
1190 # test for zlib
1191 SAVE_LDFLAGS=$LDFLAGS
1192 SAVE_CPPFLAGS=$CPPFLAGS
1193 AC_ARG_WITH(zlib,
1194             [  --with-zlib[[=DIR]]       use libz in DIR],
1195             [AS_IF([test "$withval" = "no"],
1196                    [AC_MSG_ERROR([GNUnet requires zlib])],
1197                    [test "$withval" != "yes"],
1198                    [Z_DIR=$withval
1199                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1200                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1201 AC_CHECK_HEADER(zlib.h,
1202                 [],
1203                 [AC_MSG_ERROR([GNUnet requires zlib])])
1204 AC_CHECK_LIB(z,
1205              compress2,
1206              [AC_DEFINE([HAVE_ZLIB],
1207                         [],
1208                         [Have compression library])
1209               if test "x${Z_DIR}" != "x"; then
1210                       Z_CFLAGS="-I${Z_DIR}/include"
1211                       Z_LIBS="-L${Z_DIR}/lib -lz"
1212               else
1213                       Z_LIBS="-lz"
1214               fi],
1215               [AC_MSG_ERROR([GNUnet requires zlib])])
1216 AC_SUBST(Z_CFLAGS)
1217 AC_SUBST(Z_LIBS)
1218
1219 AS_IF([test "$enable_shared" = "no"],
1220       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1221
1222
1223 # restore LIBS
1224 LIBS=$SAVE_LIBS
1225
1226
1227 # end of taler-only being false
1228 ])
1229
1230
1231 # check for iconv
1232 AM_ICONV
1233
1234 # test for libunistring
1235 gl_LIBUNISTRING
1236 AS_IF([test $HAVE_LIBUNISTRING != yes],
1237       [AC_MSG_ERROR([GNUnet requires libunistring])])
1238
1239 # under emscripten, $gl_libunistring_hexversion is undefined
1240 if test "$taler_only" != yes; then
1241
1242 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1243       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1244 fi
1245 AC_CHECK_HEADERS([unistr.h],
1246                  ,
1247                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1248
1249 # restore LIBS
1250 LIBS=$SAVE_LIBS
1251
1252
1253
1254 # Checks for standard header files.
1255 AC_HEADER_DIRENT
1256 AC_HEADER_STDC
1257
1258 # Check for headers that are ALWAYS required
1259 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1260
1261
1262
1263 # Checks for headers that are only required on some systems or
1264 # opional (and where we do NOT abort if they are not there)
1265 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1266
1267 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1268 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1269 [#ifdef HAVE_SYS_TYPES_H
1270 #include <sys/types.h>
1271 #endif
1272 #ifdef HAVE_NETINET_IN_SYSTM_H
1273 #include <netinet/in_systm.h>
1274 #endif
1275 #ifdef HAVE_NETINET_IN_H
1276 #include <netinet/in.h>
1277 #endif
1278 ])
1279
1280 SAVE_LDFLAGS=$LDFLAGS
1281 SAVE_CPPFLAGS=$CPPFLAGS
1282
1283 # test for sqlite
1284 sqlite=false
1285 AC_MSG_CHECKING(for SQLite)
1286 AC_ARG_WITH(sqlite,
1287   [  --with-sqlite=PFX       base of SQLite installation],
1288   [AC_MSG_RESULT("$with_sqlite")
1289    AS_CASE([$with_sqlite],
1290      [no],[],
1291      [yes],[
1292       AC_CHECK_HEADERS(sqlite3.h,
1293       sqlite=true)],
1294      [
1295     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1296     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1297     AC_CHECK_HEADERS(sqlite3.h,
1298      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1299      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1300      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1301      sqlite=true)
1302     LDFLAGS=$SAVE_LDFLAGS
1303     CPPFLAGS=$SAVE_CPPFLAGS
1304     ])
1305   ],
1306   [AC_MSG_RESULT([--with-sqlite not specified])
1307     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1308 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1309 AC_SUBST(SQLITE_CPPFLAGS)
1310 AC_SUBST(SQLITE_LDFLAGS)
1311
1312 LDFLAGS=$SAVE_LDFLAGS
1313 CPPFLAGS=$SAVE_CPPFLAGS
1314
1315 # test for postgres:
1316 postgres=false
1317 # even running the check for postgres breaks emscripten
1318 AS_IF([test "$taler_only" != yes],
1319       [AX_LIB_POSTGRESQL([9.5],
1320         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1321          AC_CHECK_HEADERS([libpq-fe.h],
1322          postgres=true)
1323         ],
1324         [AC_MSG_RESULT([no postgres])])])
1325
1326 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1327 AS_IF([test "x$postgres" = xtrue],
1328       [AC_DEFINE([HAVE_POSTGRESQL],[1],[Have PostgreSQL])],
1329       [AC_DEFINE([HAVE_POSTGRESQL],[0],[Lacking PostgreSQL])])
1330
1331 LDFLAGS=$SAVE_LDFLAGS
1332 CPPFLAGS=$SAVE_CPPFLAGS
1333
1334 # mysql & windows
1335 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1336 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1337
1338 # test for mysql
1339 mysql=false
1340 mysqlfail=false
1341 SAVE_LDFLAGS=$LDFLAGS
1342 SAVE_CPPFLAGS=$CPPFLAGS
1343 AC_MSG_CHECKING(for mysql)
1344 AC_ARG_WITH(mysql,
1345   [  --with-mysql=PFX        base of MySQL installation],
1346   [AC_MSG_RESULT([$with_mysql])
1347    AS_CASE([$with_mysql],
1348      [no],[],
1349      [yes|""],[
1350       AC_CHECK_HEADERS(mysql/mysql.h,
1351        AC_CHECK_LIB(mysqlclient, mysql_init,
1352        mysql=true), [], [])
1353      ],[
1354       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1355       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1356       AC_CHECK_HEADERS(mysql/mysql.h,
1357        AC_CHECK_LIB(mysqlclient, mysql_init,
1358         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1359         MYSQL_CPPFLAGS="-I$with_mysql/include"
1360
1361         mysql=true), [], [])
1362      ])
1363   ],
1364   [AC_MSG_RESULT([--with-mysql not specified])
1365    if test -d "/usr/lib64/mysql"; then
1366     MYSQL_LIBDIR="/usr/lib64/mysql"
1367    elif test -d "/usr/lib/mysql"; then
1368     MYSQL_LIBDIR="/usr/lib/mysql"
1369    else
1370     MYSQL_LIBDIR="/usr/lib"
1371    fi
1372    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1373    AC_CHECK_LIB(mysqlclient, mysql_init,
1374     [AC_CHECK_HEADERS(mysql/mysql.h,
1375       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1376       mysql=true
1377
1378      , [], [])])
1379   ])
1380
1381 AC_SUBST(MYSQL_LDFLAGS)
1382 AC_SUBST(MYSQL_CPPFLAGS)
1383
1384 # additional version check for mysql
1385 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1386 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1387  [
1388   AC_MSG_CHECKING(mysql version)
1389   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1390     [[
1391       #include <mysql/mysql.h>]],
1392     [[
1393       #if (MYSQL_VERSION_ID < 40100)
1394       #error needs at least version >= 4.1
1395       #endif
1396       int main () { return 0; }
1397     ]])
1398     ],mysql=true,mysql=false)
1399   AS_IF([test "$mysql" = "false"],
1400    [
1401     mysqlfail=true
1402     AC_MSG_RESULT([fail, >= 4.1 required])
1403    ],[
1404     AC_MSG_RESULT(ok)
1405    ])
1406 ])
1407 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1408 AM_CONDITIONAL(HAVE_MYSQLE, false)
1409 # restore LIBS
1410 LIBS=$SAVE_LIBS
1411 LDFLAGS=$SAVE_LDFLAGS
1412 CPPFLAGS=$SAVE_CPPFLAGS
1413
1414 # TODO: should this test for "or" not "and"?
1415 # TODO: Add postgres?
1416 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1417 [
1418  AC_MSG_ERROR([GNUnet requires SQLite or MySQL / MariaDB.])
1419 ])
1420
1421 # libmicrohttpd
1422 lmhd=0
1423 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1424 AC_ARG_WITH(microhttpd,
1425    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1426        [base of libmicrohttpd installation])],
1427    [],
1428    [with_microhttpd=check])
1429 AS_CASE([$with_microhttpd],
1430    [no], [],
1431    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1432    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1433        [lmhd=1],
1434        [AC_MSG_WARN([Building without libmicrohttpd])])],
1435    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1436     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1437     export PKG_CONFIG_PATH
1438     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1439     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1440 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1441 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1442
1443 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1444
1445 # restore LIBS
1446 LIBS=$SAVE_LIBS
1447
1448 # check for gettext
1449 AM_GNU_GETTEXT([external])
1450 AM_GNU_GETTEXT_VERSION([0.18.1])
1451
1452 # Checks for standard typedefs, structures, and compiler characteristics.
1453 AC_TYPE_PID_T
1454 AC_TYPE_SIZE_T
1455 AC_TYPE_MODE_T
1456 AC_HEADER_TIME
1457 AC_HEADER_STAT
1458 AC_HEADER_STDBOOL
1459 AC_STRUCT_TM
1460
1461 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1462    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1463    ],
1464    [],
1465    [
1466       #include <sys/types.h>
1467       #include <sys/socket.h>
1468       #include <netinet/in.h>
1469    ])
1470
1471 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1472                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1473                             1,
1474                             [Do we have sockaddr_un.sun_len?])],
1475                 [],
1476                 [
1477                 #include <sys/types.h>
1478                 #include <sys/socket.h>
1479                 #include <sys/un.h>
1480                 ])
1481
1482
1483
1484 # Checks for library functions.
1485 AC_FUNC_CLOSEDIR_VOID
1486 AC_FUNC_FORK
1487 AC_PROG_GCC_TRADITIONAL
1488 AC_FUNC_MEMCMP
1489 AC_FUNC_SELECT_ARGTYPES
1490 AC_FUNC_CHOWN
1491
1492 AC_TYPE_SIGNAL
1493 AC_FUNC_STAT
1494 AC_FUNC_STRFTIME
1495 AC_FUNC_VPRINTF
1496 AC_HEADER_SYS_WAIT
1497 AC_TYPE_OFF_T
1498 AC_TYPE_UID_T
1499 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1500
1501 # restore LIBS
1502 LIBS=$SAVE_LIBS
1503
1504 GN_INTLINCL=""
1505 GN_LIBINTL="$LTLIBINTL"
1506 AC_ARG_ENABLE(framework,
1507               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1508               enable_framework_build=$enableval)
1509 AM_CONDITIONAL(WANT_FRAMEWORK,
1510                test x$enable_framework_build = xyes)
1511 AS_IF([test x$enable_framework_build = xyes],
1512       [AC_DEFINE([FRAMEWORK_BUILD],
1513                  1,
1514                  [Build a Mac OS X Framework])
1515       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1516       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1517       AC_LIB_APPENDTOVAR([CPPFLAGS],
1518                          [$GN_INTLINCL])])
1519
1520 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1521 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1522
1523 AC_SUBST(GN_LIB_LDFLAGS)
1524 AC_SUBST(GN_PLUGIN_LDFLAGS)
1525 AC_SUBST(GN_INTLINCL)
1526 AC_SUBST(GN_LIBINTL)
1527
1528 AC_SUBST(CPPFLAGS)
1529 AC_SUBST(LIBS)
1530 AC_SUBST(LDFLAGS)
1531 AC_SUBST(EXT_LIB_PATH)
1532 AC_SUBST(EXT_LIBS)
1533
1534 AC_SUBST(LIBPREFIX)
1535 AC_SUBST(DLLDIR)
1536 AC_SUBST(EXT_LIB_PATH)
1537
1538 DATAROOTDIR=$datarootdir
1539 AC_SUBST(DATAROOTDIR)
1540
1541 # test for sudo
1542 AC_MSG_CHECKING(for sudo)
1543 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1544 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1545 AC_ARG_WITH(sudo,
1546            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1547            [AC_MSG_RESULT("$with_sudo")
1548             AS_CASE([$with_sudo],
1549                     [no],[SUDO_BINARY=],
1550                     [yes],[SUDO_BINARY=sudo],
1551                     [SUDO_BINARY=$with_sudo])],
1552            [AC_MSG_RESULT([no])])
1553 AC_SUBST(SUDO_BINARY)
1554 AM_CONDITIONAL([HAVE_SUDO],
1555               [test "x$SUDO_BINARY" != "x" -o -w /])
1556
1557 # test for doas
1558 AC_MSG_CHECKING(for doas)
1559 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1560 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1561
1562 # test for gnunetdns group name
1563 GNUNETDNS_GROUP=gnunetdns
1564 AC_MSG_CHECKING(for gnunetdns group name)
1565 AC_ARG_WITH(gnunetdns,
1566             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1567             [AC_MSG_RESULT("$with_gnunetdns")
1568              AS_CASE([$with_gnunetdns],
1569                      [no],[GNUNETDNS_GROUP=gnunet],
1570                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1571                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1572             [AC_MSG_RESULT([gnunetdns])])
1573 AC_SUBST(GNUNETDNS_GROUP)
1574
1575
1576
1577 # gnutls
1578 gnutls=0
1579 gnutls_dane=0
1580 AC_MSG_CHECKING(for gnutls)
1581 AC_ARG_WITH(gnutls,
1582             [  --with-gnutls=PFX   base of gnutls installation],
1583             [AC_MSG_RESULT([$with_gnutls])
1584              AS_CASE([$with_gnutls],
1585                      [no],[],
1586                      [yes],
1587                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1588                                        AC_CHECK_LIB([gnutls],
1589                                                     [gnutls_priority_set],
1590                                                     gnutls=true))
1591                       AC_CHECK_HEADERS([gnutls/dane.h],
1592                                        AC_CHECK_LIB([gnutls-dane],
1593                                                     [dane_verify_crt_raw],
1594                                                     gnutls_dane=1))],
1595
1596         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1597         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1598         AC_CHECK_HEADERS([gnutls/abstract.h],
1599             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1600               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1601               gnutls=true))
1602         AC_CHECK_HEADERS([gnutls/dane.h],
1603             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1604               gnutls_dane=1))
1605       ])
1606    ],
1607    [AC_MSG_RESULT([--with-gnutls not specified])
1608     AC_CHECK_HEADERS([gnutls/abstract.h],
1609         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1610           gnutls=true))
1611     AC_CHECK_HEADERS([gnutls/dane.h],
1612         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1613                      gnutls_dane=1))
1614    ])
1615 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1616 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1617 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1618 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1619
1620
1621
1622 # Test if we are building for superMUC
1623 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1624 AC_ARG_ENABLE([supermuc],
1625     [AS_HELP_STRING([--enable-supermuc],
1626        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1627     [AS_IF([test "x$enable_supermuc" = "xno"],
1628       [supermuc=0],
1629       [supermuc=1])],
1630     [supermuc=0
1631      enable_supermuc=no])
1632 AC_MSG_RESULT($enable_SUPERMUC)
1633 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1634 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1635
1636 # Check if NSE has to send timestamp information to testbed logger for
1637 # generating histogram of messages received
1638 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1639 AC_ARG_ENABLE([nse-histogram],
1640     [AS_HELP_STRING([--enable-nse-histogram],
1641        [have NSE send timestamp information to testbed logger for generating
1642        histogram of received messages.  NOT useful for production (default is
1643        NO)])],
1644     [AS_IF([test "x$enableval" = "xno"],
1645       [nse_histogram=0],
1646       [nse_histogram=1])],
1647     [nse_histogram=0
1648      enable_nse_histogram=no])
1649 AC_MSG_RESULT($enable_nse_histogram)
1650 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1651 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1652                    [have NSE send timestamp information to testbed logger])
1653
1654 # should 'make check' run tests?
1655 AC_MSG_CHECKING(whether to run tests)
1656 AC_ARG_ENABLE([testruns],
1657    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1658    [enable_tests_run=${enableval}],
1659    [enable_tests_run=yes])
1660 AC_MSG_RESULT($enable_test_run)
1661 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1662
1663
1664 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1665 AC_ARG_ENABLE([benchmark],
1666    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1667    [enable_benchmark=${enableval}],
1668    [enable_benchmark=no])
1669 AC_MSG_RESULT($enable_benchmark)
1670 AS_IF([test "x$enable_benchmark" = "xyes"],
1671       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1672 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1673
1674
1675 # should expensive tests be run?
1676 AC_MSG_CHECKING(whether to run expensive tests)
1677 AC_ARG_ENABLE([expensivetests],
1678    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1679    [enable_expensive=${enableval}],
1680    [enable_expensive=no])
1681 AC_MSG_RESULT($enable_expensive)
1682 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1683
1684 # should ports be open for Java services?
1685 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1686 AC_ARG_ENABLE([javaports],
1687    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1688    [enable_java_ports=${enableval}],
1689    [enable_java_ports=no])
1690 AC_MSG_RESULT($enable_java_ports)
1691 AS_IF([test "x$enable_java_ports" = "xyes"],
1692  [JAVAPORT=""],
1693  [JAVAPORT="$UNIXONLY"])
1694 AC_SUBST(JAVAPORT)
1695
1696 # should benchmarks be run?
1697 AC_MSG_CHECKING(whether to run benchmarks during make check)
1698 AC_ARG_ENABLE([benchmarks],
1699    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1700    [enable_benchmarks=${enableval}],
1701    [enable_benchmarks=no])
1702 AC_MSG_RESULT($enable_benchmarks)
1703 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1704
1705 # should gnunet-testing be compiled
1706 AC_MSG_CHECKING(whether to compile gnunet-testing)
1707 AC_ARG_ENABLE([testing],
1708    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1709    [enable_testing=${enableval}],
1710    [enable_testing=yes])
1711 AC_MSG_RESULT($enable_testing)
1712 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1713
1714 # should experimental code be compiled (code that may not yet compile)?
1715 AC_MSG_CHECKING(whether to compile experimental code)
1716 AC_ARG_ENABLE([experimental],
1717    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1718    [enable_experimental=${enableval}],
1719    [enable_experimental=no])
1720 AC_MSG_RESULT($enable_experimental)
1721 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1722
1723 # should malicious code be compiled (should only be used for testing)?
1724 AC_MSG_CHECKING(whether to compile malicious code)
1725 AC_ARG_ENABLE([malicious],
1726    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1727    [AS_IF([test "x$enableval" = "xno"],
1728      [malicious=0],
1729      [malicious=1])],
1730    [malicious=0
1731     enable_malicious=no])
1732 AC_MSG_RESULT($enable_malicious)
1733 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1734 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1735                    [enable compilation of malicious code])
1736
1737 # should services be started on demand when needed?
1738 # Some services may choose to never start by default
1739 # and it is up to the service/module developer to decide
1740 # by having "START_ON_DEMAND = NO" instead of
1741 # "START_ON_DEMAND = @START_ON_DEMAND@"
1742 # in the service/module's conf.in file.
1743 # See also IMMEDIATE_START for an unconditional immediate start.
1744 START_ON_DEMAND="YES"
1745 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1746 AC_ARG_ENABLE([autostart],
1747    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1748    [enable_autostart=${enableval}
1749     AS_IF([test "x$enable_autostart" = "xno"],
1750       [START_ON_DEMAND="NO"])
1751    ],
1752    [enable_autostart=yes])
1753 AC_MSG_RESULT($enable_autostart)
1754 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1755 AC_SUBST(START_ON_DEMAND)
1756
1757 # should memory statistics be kept (very expensive CPU-wise!)
1758 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1759 AC_ARG_ENABLE([heapstats],
1760    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1761    [enable_heapstats=1],
1762    [enable_heapstats=0])
1763 AC_MSG_RESULT($enable_heapstats)
1764 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1765
1766
1767 # Check if the __thread storage class for
1768 # thread-local storage is available.
1769 AC_MSG_CHECKING(whether __thread is supported)
1770 AC_LINK_IFELSE(
1771 [AC_LANG_PROGRAM([#include <stdlib.h>
1772                    #undef __thread
1773                    static __thread int a = 1;],
1774                   [exit(a-1);])],
1775  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1776 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1777 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1778       [AC_MSG_RESULT(yes)],
1779       [AC_MSG_RESULT(no)])
1780
1781 # gcov compilation
1782 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1783 AC_ARG_ENABLE([coverage],
1784               AS_HELP_STRING([--enable-coverage],
1785                              [compile the library with code coverage support]),
1786               [use_gcov=${enableval}],
1787               [use_gcov=no])
1788 AC_MSG_RESULT($use_gcov)
1789 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1790
1791
1792 # version info
1793 # TODO: git blame says this predates our switch to git.
1794 # git-svn should be adjusted to simply git, or
1795 # an external script that does the job.
1796 AC_PATH_PROG(svnversioncommand, svnversion)
1797 AC_PATH_PROG(gitcommand, git)
1798 AC_MSG_CHECKING(for source being under a VCS)
1799
1800
1801 # version info
1802 AC_PATH_PROG(gitcommand, git)
1803 AC_MSG_CHECKING(for source being under a VCS)
1804 git_version=
1805 AS_IF([test ! "X$gitcommand" = "X"],
1806 [
1807   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1808 ])
1809 AS_IF([test "X$git_version" = "X"],
1810   [
1811     vcs_name="no"
1812     vcs_version="\"release\""
1813   ],
1814   [
1815     vcs_name="yes, git-svn"
1816     vcs_version="\"git-$git_version\""
1817   ])
1818 AC_MSG_RESULT($vcs_name)
1819
1820 AC_MSG_CHECKING(VCS version)
1821 AC_MSG_RESULT($vcs_version)
1822 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1823
1824 AC_CONFIG_FILES([
1825 Makefile
1826 contrib/Makefile
1827 contrib/hellos/Makefile
1828 contrib/services/Makefile
1829 contrib/services/openrc/Makefile
1830 contrib/services/systemd/Makefile
1831 contrib/scripts/Makefile
1832 contrib/scripts/gnunet-logread/Makefile
1833 doc/Makefile
1834 doc/man/Makefile
1835 doc/doxygen/Makefile
1836 doc/handbook/Makefile
1837 doc/tutorial/Makefile
1838 m4/Makefile
1839 po/Makefile.in
1840 src/Makefile
1841 src/arm/Makefile
1842 src/arm/arm.conf
1843 src/ats/Makefile
1844 src/ats/ats.conf
1845 src/ats-tool/Makefile
1846 src/ats-tests/Makefile
1847 src/auction/Makefile
1848 src/block/Makefile
1849 src/cadet/Makefile
1850 src/cadet/cadet.conf
1851 src/core/Makefile
1852 src/core/core.conf
1853 src/consensus/Makefile
1854 src/consensus/consensus.conf
1855 src/conversation/Makefile
1856 src/conversation/conversation.conf
1857 src/curl/Makefile
1858 src/datacache/Makefile
1859 src/datastore/Makefile
1860 src/datastore/datastore.conf
1861 src/dht/Makefile
1862 src/dht/dht.conf
1863 src/dns/Makefile
1864 src/dns/dns.conf
1865 src/exit/Makefile
1866 src/fragmentation/Makefile
1867 src/fs/Makefile
1868 src/fs/fs.conf
1869 src/gns/Makefile
1870 src/gns/gns.conf
1871 src/gns/nss/Makefile
1872 src/gnsrecord/Makefile
1873 src/hello/Makefile
1874 src/identity/Makefile
1875 src/identity/identity.conf
1876 src/abd/Makefile
1877 src/abd/abd.conf
1878 src/include/Makefile
1879 src/integration-tests/Makefile
1880 src/json/Makefile
1881 src/hostlist/Makefile
1882 src/my/Makefile
1883 src/mysql/Makefile
1884 src/namecache/Makefile
1885 src/namecache/namecache.conf
1886 src/namestore/Makefile
1887 src/namestore/namestore.conf
1888 src/nat/Makefile
1889 src/nat/nat.conf
1890 src/nat-auto/Makefile
1891 src/nat-auto/nat-auto.conf
1892 src/nse/Makefile
1893 src/nse/nse.conf
1894 src/nt/Makefile
1895 src/peerinfo/Makefile
1896 src/peerinfo/peerinfo.conf
1897 src/peerinfo-tool/Makefile
1898 src/peerstore/Makefile
1899 src/peerstore/peerstore.conf
1900 src/pq/Makefile
1901 src/pt/Makefile
1902 src/regex/Makefile
1903 src/regex/regex.conf
1904 src/revocation/Makefile
1905 src/revocation/revocation.conf
1906 src/rps/Makefile
1907 src/rps/rps.conf
1908 src/secretsharing/Makefile
1909 src/secretsharing/secretsharing.conf
1910 src/scalarproduct/Makefile
1911 src/scalarproduct/scalarproduct.conf
1912 src/set/Makefile
1913 src/set/set.conf
1914 src/sq/Makefile
1915 src/statistics/Makefile
1916 src/statistics/statistics.conf
1917 src/template/Makefile
1918 src/testbed/Makefile
1919 src/testbed/testbed.conf
1920 src/testbed-logger/Makefile
1921 src/testbed-logger/testbed-logger.conf
1922 src/testing/Makefile
1923 src/topology/Makefile
1924 src/transport/Makefile
1925 src/transport/transport.conf
1926 src/util/Makefile
1927 src/util/resolver.conf
1928 src/vpn/Makefile
1929 src/vpn/vpn.conf
1930 src/zonemaster/Makefile
1931 src/zonemaster/zonemaster.conf
1932 src/rest/Makefile
1933 src/abe/Makefile
1934 src/reclaim-attribute/Makefile
1935 src/reclaim/Makefile
1936 pkgconfig/Makefile
1937 pkgconfig/gnunetarm.pc
1938 pkgconfig/gnunetats.pc
1939 pkgconfig/gnunetblock.pc
1940 pkgconfig/gnunetcadet.pc
1941 pkgconfig/gnunetconsensus.pc
1942 pkgconfig/gnunetconversation.pc
1943 pkgconfig/gnunetcore.pc
1944 pkgconfig/gnunetdatacache.pc
1945 pkgconfig/gnunetdatastore.pc
1946 pkgconfig/gnunetdht.pc
1947 pkgconfig/gnunetdns.pc
1948 pkgconfig/gnunetenv.pc
1949 pkgconfig/gnunetfragmentation.pc
1950 pkgconfig/gnunetfs.pc
1951 pkgconfig/gnunetgns.pc
1952 pkgconfig/gnunethello.pc
1953 pkgconfig/gnunetidentity.pc
1954 pkgconfig/gnunetmicrophone.pc
1955 pkgconfig/gnunetmysql.pc
1956 pkgconfig/gnunetnamestore.pc
1957 pkgconfig/gnunetnat.pc
1958 pkgconfig/gnunetnse.pc
1959 pkgconfig/gnunetpeerinfo.pc
1960 pkgconfig/gnunetpq.pc
1961 pkgconfig/gnunetregex.pc
1962 pkgconfig/gnunetrevocation.pc
1963 pkgconfig/gnunetrps.pc
1964 pkgconfig/gnunetscalarproduct.pc
1965 pkgconfig/gnunetset.pc
1966 pkgconfig/gnunetspeaker.pc
1967 pkgconfig/gnunetstatistics.pc
1968 pkgconfig/gnunettestbed.pc
1969 pkgconfig/gnunettesting.pc
1970 pkgconfig/gnunettransport.pc
1971 pkgconfig/gnunetutil.pc
1972 pkgconfig/gnunetvpn.pc
1973 ])
1974 AC_OUTPUT
1975
1976
1977 # FIXME: `some modules' -> be more specific which exact modules.
1978
1979 # java ports
1980 AS_IF([test "x$enable_java_ports" = "xyes"],
1981       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1982
1983 ####
1984 #### Lasciate ogne speranza, voi ch'intrate
1985 ####
1986 #### This could be moved to the checks above,
1987 #### but for now let's keep it here.
1988 ####
1989
1990 # TODO: We use "WARNING" too often, we need to clarify what
1991 # TODO: constitutes a WARNING, an ERROR, and a NOTICE, and
1992 # TODO: other message levels.
1993
1994 # -- print message regarding enabled experimental features
1995 AS_IF([test "x$enable_experimental" = "xyes"],
1996       [experimental_msg="experimental features enabled"])
1997 # -- OSX Framework
1998 AS_IF([test "$enable_framework_build" = "yes"],
1999       [macosx_framework_msg="yes"],
2000       [macosx_framework_msg="no"])
2001 # -- libidn 2
2002 AS_IF([test "x$working_libidn2" = x1],
2003       [libidn2_msg="libidn2"])
2004 # -- libidn 1
2005 AS_IF([test "x$working_libidn1" = x1],
2006       [libidn1_msg="libidn1"])
2007 # -- texi2mdoc-generation
2008 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
2009       [mdocml_msg="yes"],
2010       [mdocml_msg="no"])
2011 # -- texi2mdoc
2012 AS_IF([test "x$TEXI2MDOC_BINARY" = "false"],
2013       [AC_MSG_NOTICE([WARNING: optional texi2mdoc binary not found])
2014        texi2mdoc_msg="no (optional)"],
2015       [texi2mdoc_msg="yes"])
2016 # -- mandoc
2017 AS_IF([test "x$MANDOC_BINARY" = "false"],
2018       [AC_MSG_NOTICE([WARNING: optional mandoc binary not found])
2019        mandoc_msg="no"],
2020       [mandoc_msg="yes"])
2021 # -- texinfo
2022 AS_IF([test "x$makeinfo" != "x1"],
2023       [texinfo_msg="no"],
2024       [texinfo_msg="yes"])
2025 # -- conversation
2026 AS_IF([test "x$conversation_backend" = "xnone"],
2027       [AS_IF([test "x$pulse" != "x1"],
2028              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found (required to build conversation against it).])
2029               libpulse_msg="no"],
2030              [libpulse_msg="yes"])
2031        AS_IF([test "x$opus" != "x1"],
2032              [AC_MSG_NOTICE([WARNING: libopus not found (conversation)])
2033               libopus_msg="no"],
2034              [libopus_msg="yes"])
2035        AS_IF([test "x$gst" != "x1"],
2036              [AC_MSG_NOTICE([WARNING: GStreamer not found (required to build conversation against it).])
2037               gstreamer_msg="no"],
2038              [gstreamer_msg="yes"])],
2039       [features_msg="$features_msg conversation"])
2040 # -- interface
2041 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2042 # -- libmicrohttpd
2043 AS_IF([test "x$lmhd" != "x1"],
2044       [libmicrohttpd_msg="no (optional)"],
2045       [libmicrohttpd_msg="yes"])
2046 # -- jansson
2047 AS_IF([test "x$jansson" = "x0"],
2048       [jansson_msg="no (optional)"],
2049       [jansson_msg="yes"])
2050 # -- libextractor
2051 AS_IF([test "$extractor" != 1],
2052       [AC_MSG_WARN([WARNING: libextractor not found, but various file-sharing functions require it])],
2053       [libextractor_msg="yes"])
2054 # -- libzbar
2055 AS_IF([test "x$zbar" = "x1"],
2056       [libzbar_msg="yes"
2057        features_msg="$features_msg gnunet-qr"],
2058       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
2059        libzbar_msg="no"])
2060 # -- libgnurl
2061 AS_IF([test "$gnurl" = "0"],
2062       [AS_IF([test "x$curl" = "xfalse"],
2063              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
2064               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2065               curl_msg="no"],
2066              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
2067               curl_msg="yes"])],
2068        [gnurl_msg="yes"])
2069 # -- ifconfig
2070 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2071       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2072        ifconfig_msg="no (optional)"],
2073       [ifconfig_msg="yes"])
2074 # -- upnpc
2075 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2076       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2077        upnpc_msg="no (optional)"],
2078       [upnpc_msg="yes"])
2079 # -- iptables
2080 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2081       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2082        iptables_msg="no (optional)"],
2083       [iptables_msg="yes"])
2084 # -- bluetooth
2085 AS_IF([test "x$bluetooth" = "x0"],
2086       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2087        bluetooth_msg="no (optional)"],
2088       [bluetooth_msg="yes"])
2089 # -- gnutls
2090 AS_IF([test x$gnutls != xtrue],
2091       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2092        gnutls_msg="no"],
2093       [AS_IF([test "x$gnutls_dane" != "x1"],
2094              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2095               gnutls_msg="yes (without DANE support)"],
2096              [gnutls_msg="yes (with DANE support)"])])
2097 # -- databases
2098 # TODO: this always returns true, the check might
2099 # TODO: not be working as intended (for msqlfail).
2100 AS_IF([test x$mysqlfail = "true"]
2101       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2102 AS_IF([test "$mysql" = true],
2103       [features_msg="$features_msg mysql"
2104        mysql_msg="yes"],
2105       [mysql_msg="no"])
2106 AS_IF([test "$sqlite" = true],
2107       [features_msg="$features_msg sqlite"
2108        sqlite_msg="yes"],
2109       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2110        sqlite_msg="no"])
2111 AS_IF([test "$postgres" = true],
2112       [features_msg="$features_msg postgres"
2113        postgres_msg="yes"],
2114       [postgres_msg="no"])
2115 # -- features
2116 # ---- 1. replace spaces with newlines,
2117 # ---- 2. sort the lines,
2118 # ---- 3. replace the newlines with spaces.
2119 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2120 AC_SUBST(features_msg)
2121
2122
2123 # The summary
2124 # TODO: reduce the length of the last message block, following "IMPORTANT".
2125
2126 AC_MSG_NOTICE([
2127 GNUnet Configuration
2128
2129 gnunet version:                 ${VERSION}
2130
2131 Host setup:                     ${host}
2132 Install prefix:                 ${prefix}
2133 Compiler:                       ${CC}
2134 CFLAGS:                         ${CFLAGS}
2135 CPPFLAGS:                       ${CPPFLAGS}
2136 LDFLAGS:                        ${LDFLAGS}
2137 LIBS:                           ${LIBS}
2138 Build Target:                   $build_target
2139 Mac OSX framework build:        ${macosx_framework_msg}
2140
2141 Default Interface:              ${interface_msg}
2142
2143 MySQL:                          ${mysql_msg}
2144 PostgreSQL:                     ${postgres_msg}
2145 sqlite3:                        ${sqlite_msg}
2146 gnurl:                          ${gnurl_msg}
2147 curl:                           ${curl_msg}
2148 bluetooth:                      ${bluetooth_msg}
2149 jansson:                        ${jansson_msg}
2150 iptables:                       ${iptables_msg}
2151 ifconfig:                       ${ifconfig_msg}
2152 upnpc:                          ${upnpc_msg}
2153 gnutls:                         ${gnutls_msg}
2154 libzbar:                        ${libzbar_msg}
2155 java:                           ${java_msg}
2156 libmicrohttpd:                  ${libmicrohttpd_msg}
2157 libidn:                         ${libidn1_msg}${libidn2_msg}
2158 libopus:                        ${libopus_msg}
2159 gstreamer:                      ${gstreamer_msg}
2160 libpulse:                       ${libpulse_msg}
2161 libextractor:                   ${libextractor_msg}
2162 texi2mdoc:                      ${texi2mdoc_msg}
2163 mandoc:                         ${mandoc_msg}
2164
2165 texinfo manual:                 ${texinfo_msg}
2166 transpiled mdocml manual:       ${mdocml_msg}
2167
2168 features:                       ${features_msg}
2169 experimental:                   ${experimental_msg}
2170
2171
2172 IMPORTANT:
2173
2174 Please make sure NOW that you have created a user and group 'gnunet'
2175 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2176 type:
2177
2178   addgroup gnunetdns
2179   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2180
2181 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2182 'gnunet'.  Then, you can compile GNUnet with
2183
2184   make
2185
2186 After that, run (if necessary as 'root')
2187
2188   make install
2189
2190 to install everything.
2191
2192 Each GNUnet user should be added to the 'gnunet' group (may
2193 require fresh login to come into effect):
2194
2195   adduser USERNAME gnunet
2196
2197 (run the above command as root once for each of your users, replacing
2198 "USERNAME" with the respective login names).  If you have a global IP
2199 address, no further configuration is required.
2200
2201 For more detailed setup instructions, see https://docs.gnunet.org/
2202
2203 Optionally, download and compile gnunet-gtk to get a GUI for
2204 file-sharing and configuration.  This is particularly recommended
2205 if your network setup is non-trivial, as gnunet-setup can be
2206 used to test in the GUI if your network configuration is working.
2207 gnunet-setup should be run as the "gnunet" user under X.  As it
2208 does very little with the network, running it as "root" is likely
2209 also harmless.  You can also run it as a normal user, but then
2210 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2211 home directory in the end.
2212
2213 Once you have configured your peer, run (as the 'gnunet' user)
2214
2215   gnunet-arm -s
2216
2217 to start the peer.  You can then run the various GNUnet-tools as
2218 your "normal" user (who should only be in the group 'gnunet').
2219 ])