configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_CPP
  47 AC_PROG_CXX
  48 AC_PROG_OBJC
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AM_PROG_CC_C_O
  53 LT_INIT([disable-static dlopen win32-dll])
  54 AC_SUBST(MKDIR_P)
  55
  56 # allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 # large file support
  60 AC_SYS_LARGEFILE
  61 AC_FUNC_FSEEKO
  62
  63
  64 CFLAGS="-Wall $CFLAGS"
  65 # use '-fno-strict-aliasing', but only if the compiler can take it
  66 AS_IF([gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  67  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  68
  69 # A helper which allows us to check cflags if compiler
  70 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  71   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  72     [ac_save_CFLAGS="$CFLAGS"
  73      CFLAGS="$CFLAGS $1"
  74      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  76        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  77      CFLAGS="$ac_save_CFLAGS"
  78     ])
  79
  80   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  81     [$2], [$3])
  82 ])
  83
  84 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  85 CC_CHECK_CFLAGS_SILENT([-Wno-address-of-packed-member],
  86                       [CFLAGS="-Wno-address-of-packed-member $CFLAGS"])
  87
  88 # Use Linux interface name unless the OS has a different preference
  89 DEFAULT_INTERFACE="\"eth0\""
  90
  91 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
  92
  93 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  94 native_srcdir=$srcdir
  95
  96 OLD_LDFLAGS="$LDFLAGS"
  97 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
  98
  99 # Check system type
 100 AS_CASE(["$host_os"],
 101   [*darwin* | *rhapsody* | *macosx*],[
 102      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 103      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 104      CFLAGS="-fno-common $CFLAGS"
 105      LDFLAGS="$OLD_LDFLAGS"
 106      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 107      AC_CHECK_LIB(intl, gettext)
 108      build_target="darwin"
 109      DEFAULT_INTERFACE="\"en0\""
 110      LIBPREFIX=
 111      DLLDIR=lib
 112      UNIXONLY="#"
 113   ],
 114   [linux*],[
 115      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 116      build_target="linux"
 117      LIBPREFIX=
 118      DLLDIR=lib
 119      UNIXONLY="#"
 120      AC_PATH_XTRA
 121   ],
 122   [*freebsd*],[
 123      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 124      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 125      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 126      build_target="freebsd"
 127      LIBPREFIX=
 128      DLLDIR=lib
 129      UNIXONLY="#"
 130   ],
 131   [*openbsd*],[
 132      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 133      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 134      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 135      build_target="openbsd"
 136      LIBPREFIX=
 137      DLLDIR=lib
 138      UNIXONLY="#"
 139   ],
 140   [*netbsd*],[
 141      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 142      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 143      LIBPREFIX=
 144      DLLDIR=lib
 145      UNIXONLY="#"
 146   ],
 147   [*solaris*],[
 148      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 149      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 150      AC_CHECK_LIB(resolv, res_init)
 151      AC_CHECK_LIB(rt, nanosleep)
 152      build_target="solaris"
 153      LIBPREFIX=
 154      DLLDIR=lib
 155      UNIXONLY="#"
 156   ],
 157   [*arm-linux*],[
 158      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 159      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 160      build_target="linux"
 161      LIBPREFIX=
 162      DLLDIR=lib
 163      UNIXONLY="#"
 164   ],
 165   [*cygwin*],[
 166      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 167      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 168      AC_CHECK_LIB(intl, gettext)
 169      CFLAGS="-mms-bitfields $CFLAGS"
 170      build_target="cygwin"
 171      LIBPREFIX=lib
 172      DLLDIR=bin
 173      AC_PROG_CXX
 174      UNIXONLY=""
 175   ],
 176   [*mingw*],[
 177      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 178      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 179      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 180      AC_CHECK_LIB(intl, gettext)
 181      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 182      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 183      CFLAGS="-mms-bitfields $CFLAGS"
 184      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 185      build_target="mingw"
 186      AC_PROG_CXX
 187      LIBPREFIX=lib
 188      DLLDIR=bin
 189      UNIXONLY=""
 190      funcstocheck=""
 191      native_srcdir=$(cd $srcdir; pwd -W)
 192   ],
 193   [gnu*],[
 194      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 195      build_target="gnu"
 196      UNIXONLY="#"
 197   ],
 198   [
 199      AC_MSG_RESULT(Unrecognised OS $host_os)
 200      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 201      UNIXONLY=""
 202 ])
 203 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 204 AC_SUBST(DEFAULT_INTERFACE)
 205
 206 # Disable TCP-based IPC on systems that support UNIX domain
 207 # sockets in default configuratin:
 208 AC_SUBST(UNIXONLY)
 209
 210
 211 AC_MSG_CHECKING([for build target])
 212 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 213 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 214 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 215 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 216 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 217 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 218 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 219 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 220
 221 AC_MSG_RESULT([$build_target])
 222 AC_SUBST(build_target)
 223 AM_CONDITIONAL([am__fastdepOBJC], false)
 224 AC_UNALIGNED_64_ACCESS
 225
 226 # some other checks for standard libs
 227 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 228 AC_SEARCH_LIBS([memrchr], [],
 229                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 230 AC_SEARCH_LIBS([memset_s], [],
 231                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 232 AC_SEARCH_LIBS([memset_s], [],
 233                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 234 AC_CHECK_LIB(socket, socket)
 235 AC_CHECK_LIB(m, log)
 236 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 237
 238 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 239 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 240
 241 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 242 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 243 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 244 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 245
 246 # autotools' m4 for python has no maximum version!
 247 # python3.4 - python3.7 for tests
 248 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python])
 249 AM_PATH_PYTHON([3.4],, [:])
 250 AC_SUBST([PYTHON])
 251 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 252
 253 # perl
 254 AC_PATH_PROG( PERL, perl, ,
 255               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 256 AC_SUBST([PERL])
 257
 258 # iptables is a soft requirement to run tests
 259 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 260
 261 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 262  [AS_IF([test -x "/sbin/iptables"],
 263    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 264    [AS_IF([test -x "/usr/sbin/iptables"],
 265       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 266
 267 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 268  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 269  [AC_MSG_WARN([warning: 'iptables' not found.])])
 270
 271 # ip6tables is a soft requirement for some features
 272 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 273
 274 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 275   [AS_IF([test -x "/sbin/ip6tables"],
 276      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 277      [AS_IF([test -x "/usr/sbin/ip6tables"],
 278         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 279
 280
 281 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 282   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 283   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 284
 285 # ip is a soft requirement for some features
 286 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 287
 288 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 289  [AS_IF([test -x "/sbin/ip"],
 290    [VAR_IP_BINARY="/sbin/ip"],
 291    [AS_IF([test -x "/usr/sbin/ip"],
 292           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 293
 294 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 295  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 296  [AC_MSG_WARN([warning: 'ip' not found.])])
 297
 298 # locate 'ifconfig'
 299 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 300
 301 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 302 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 303   [AS_IF([test -x "/sbin/ifconfig"],
 304      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 305      [AS_IF([test -x "/usr/sbin/ifconfig"],
 306             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 307
 308 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 309   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 310   [AC_MSG_WARN(['ifconfig' not found.])])
 311
 312
 313 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 314
 315 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 316 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 317       [AS_IF([test -x "/sbin/sysctl"],
 318              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 319              [AS_IF([test -x "/usr/sbin/sysctl"],
 320                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 321 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 322       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 323       [AC_MSG_WARN(['sysctl' not found.])])
 324
 325 # miniupnpc / upnpc binary is a soft runtime requirement
 326 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 327
 328 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 329   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 330   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 331
 332 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 333   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 334      [Define if struct tm has the tm_gmtoff member.])],
 335      ,
 336      [#include <time.h>])
 337
 338 AC_CHECK_DECLS([_stati64])
 339
 340 # 'save' libs; only those libs found so far will be
 341 # linked against _everywhere_.  For the others, we
 342 # will be more selective!
 343 SAVE_LIBS=$LIBS
 344
 345 have_addrinfo_a=0
 346 AC_CHECK_LIB(anl,
 347              getaddrinfo_a,
 348              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 349                                           1,
 350                                           [getaddrinfo_a supported])])
 351 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 352                [test "$have_addrinfo_a" = 1])
 353
 354 # tests only run on Windows
 355 AS_IF([test "x$build_target" = "xmingw"],
 356       [AC_CHECK_LIB(plibc,
 357                     plibc_init,
 358                     [],
 359                     [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 360        AC_CHECK_LIB(gnurx,
 361                     regexec,
 362                     [],
 363                     [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])])
 364
 365 # libgcrypt
 366 gcrypt=0
 367 NEED_LIBGCRYPT_API=1
 368 NEED_LIBGCRYPT_VERSION=1.6.0
 369
 370
 371 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 372 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 373
 374 AS_IF([test $gcrypt = 0],
 375  [
 376   AC_MSG_ERROR([[
 377 ***
 378 *** You need libgcrypt to build this program.
 379 **  This library is for example available at
 380 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 381 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 382 ***  is required.)
 383 ***]])
 384 ])
 385 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 386
 387 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 388
 389
 390
 391 # should the build process be building the documentation?
 392 AC_MSG_CHECKING(whether to build documentation)
 393 AC_ARG_ENABLE([documentation],
 394               [AS_HELP_STRING([--disable-documentation],
 395                               [do not build the documentation])],
 396               [documentation=${enableval}],
 397               [documentation=yes])
 398 AC_MSG_RESULT($documentation)
 399 AS_IF([test "x$documentation" = "xyes"],
 400       [AM_CONDITIONAL([DOCUMENTATION],
 401                       true)
 402        AC_DEFINE([DOCUMENTATION],
 403                  [1],
 404                  [Building the documentation])],
 405       [AM_CONDITIONAL([DOCUMENTATION],
 406                       false)
 407        AC_DEFINE([DOCUMENTATION],
 408                  [0],
 409                  [Not building the documentation])])
 410
 411 # COMMENT: Check wether to transpile texinfo to mdoc.
 412 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 413 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 414 # COMMENT: and makes the configure fail if it is missing.
 415 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 416 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 417 # COMMENT: or nothing was set (this is the default).
 418 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 419 # COMMENT: potential non-existence of the texi2mdoc binary.
 420 # COMMENT: Default return value / setting: no
 421 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 422 AC_ARG_ENABLE([texi2mdoc-generation],
 423               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 424                               [include generated texi2mdoc output in installation])],
 425               [texi2mdoc_generation=${enableval}],
 426               [texi2mdoc_generation=no])
 427 AC_MSG_RESULT($texi2mdoc_generation)
 428 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 429       [AS_IF([test "$texi2mdoc" = 0],
 430              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 431               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your Operating System])
 432               AC_MSG_WARN([ERROR: package manager or from https://mandoc.bsd.lv/texi2mdoc/])],
 433              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 434               AC_DEFINE([TEXI2MDOC_GENERATION],
 435                         [1],
 436                         [Building section 7 mdoc output])])],
 437       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 438                       false)
 439        AC_DEFINE([TEXI2MDOC_GENERATION],
 440                  [0],
 441                  [Not building section 7 mdoc output])])
 442
 443 # should the build process be building only the documentation?
 444 AC_MSG_CHECKING(whether to build only documentation)
 445 AC_ARG_ENABLE([documentation-only],
 446    [AS_HELP_STRING([--enable-documentation-only], [build only the documentation])],
 447    [documentation_only=${enableval}],
 448    [documentation_only=no])
 449 AC_MSG_RESULT($documentation_only)
 450 AS_IF([test "x$documentation_only" = "xyes"],
 451  [
 452   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 453   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 454  ],[
 455   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 456   # TODO: Double negation might be a bit hard to parse for some
 457   # TODO: people reading the output.
 458   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Not building only the documentation])
 459  ])
 460
 461 # should the build process be including the manpages? (default: yes)
 462 AC_MSG_CHECKING(whether to include man pages)
 463 AC_ARG_ENABLE([include-manpages],
 464    [AS_HELP_STRING([--disable-include-manpages], [Do not include the man pages in build and installation])],
 465    [include_manpages=${enableval}],
 466    [include_manpages=yes])
 467 AC_MSG_RESULT($include_manpages)
 468 AS_IF([test "x$include_manpages" = "xyes"],
 469  [
 470   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 471   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 472  ],[
 473   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 474   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 475  ])
 476
 477 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 478 # (not syntax!) to the commandline tools which generate the html. If not,
 479 # texinfo5 switches are used. This comes with no version checks, is
 480 # enabled only at distributors action (ie defaults to "no").
 481 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 482 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 483 AC_ARG_ENABLE([texinfo4],
 484    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 485    [activate_texinfo4=${enableval}],
 486    [activate_texinfo4=no])
 487 AC_MSG_RESULT($activate_texinfo4)
 488 AS_IF([test "x$activate_texinfo4" = "xyes"],
 489  [
 490   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 491   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 492  ],[
 493   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 494   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 495  ])
 496
 497
 498 # Adam shostack suggests the following for Windows:
 499 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 500 AC_ARG_ENABLE(gcc-hardening,
 501    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 502 [AS_IF([test x$enableval = xyes],[
 503     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 504     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 505     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 506     LDFLAGS="$LDFLAGS -pie"
 507  ])])
 508
 509 # Linker hardening options
 510 # Currently these options are ELF specific - you can't use this with MacOSX
 511 AC_ARG_ENABLE(linker-hardening,
 512   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 513 [AS_IF([test x$enableval = xyes],
 514    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 515
 516
 517 AC_ARG_ENABLE(sanitizer,
 518   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 519 [AS_IF([test x$enableval = xyes],[
 520    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 521  ])])
 522
 523
 524 extra_logging=GNUNET_NO
 525 AC_ARG_ENABLE([logging],
 526    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 527    [AS_IF([test "x$enableval" = "xyes"], [],
 528           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 529           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 530           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 531    ], [])
 532 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 533
 534 # should memory poisoning be enabled?
 535 AC_MSG_CHECKING(whether to poison freed memory)
 536 AC_ARG_ENABLE([poisoning],
 537    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 538    [enable_poisoning=${enableval}],
 539    [
 540      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 541        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 542        [enable_poisoning=no])
 543    ])
 544 AC_MSG_RESULT($enable_poisoning)
 545 AS_IF([test ! "x$enable_poisoning" = "xno"],
 546   [enable_poisoning=1],
 547   [enable_poisoning=0])
 548 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 549
 550 AS_IF([test $build = $target],
 551 [
 552 AC_MSG_CHECKING([for working HMAC])
 553 AC_LANG_PUSH(C)
 554 LIBS="$LIBS $LIBGCRYPT_LIBS"
 555 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 556 AC_RUN_IFELSE(
 557   [AC_LANG_PROGRAM([#include <gcrypt.h>
 558         #include <stdio.h>], [[
 559         gcry_md_hd_t mac;
 560
 561         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 562             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 563             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 564         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 565         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 566             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 567             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 568             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 569             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 570             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 571
 572         if (!gcry_check_version (GCRYPT_VERSION))
 573         {
 574           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 575           return 1;
 576         }
 577
 578         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 579         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 580
 581         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 582         {
 583           fprintf (stderr, "gcry_md_open error\n");
 584           return 2;
 585         }
 586
 587         gcry_md_setkey (mac, key, sizeof (key));
 588         gcry_md_write (mac, data, sizeof (data));
 589
 590         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 591         {
 592           fprintf (stderr, "memcmp error\n");
 593           return 3;
 594         }
 595
 596         gcry_md_close (mac);
 597
 598         return 0;
 599     ]])],
 600   [AC_MSG_RESULT([yes])],
 601   [
 602    RESULT=$?
 603    if test $RESULT = 3
 604    then
 605      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 606    fi
 607    if test $RESULT = 2
 608    then
 609      AC_MSG_FAILURE([HMAC test failed])
 610    fi
 611    if test $RESULT = 1
 612    then
 613      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 614    fi
 615   ],
 616   [AC_MSG_RESULT([cross compiling, test skipped])])
 617 AC_LANG_POP(C)
 618 ])      # $build = $target
 619
 620 # check for bluetooth library
 621 bluetooth=0
 622 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 623 AS_IF([test "$build_target" = "mingw"],
 624  [bluetooth=1])
 625 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 626 AS_IF([test "$bluetooth" = 1],
 627  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 628  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 629
 630 # check for zbar library
 631 zbar=0
 632 AC_MSG_CHECKING(for libzbar)
 633 AC_ARG_WITH(zbar,
 634    [  --with-zbar=PREFIX (base of libzbar installation)],
 635    [AC_MSG_RESULT([$with_zbar])
 636     AS_CASE([$with_zbar],
 637       [no],[],
 638       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 639       [
 640         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 641         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 642         AC_CHECK_HEADERS(zbar.h,
 643           AC_CHECK_LIB([zbar], [zbar_processor_create],
 644             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 645             zbar=1))
 646        ])
 647    ],
 648    [AC_MSG_RESULT([--with-zbar not specified])
 649     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 650 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 651 AS_IF([test "x$zbar" = x1],
 652       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 653       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 654
 655 # check for jansson library
 656 jansson=0
 657 AC_MSG_CHECKING(for libjansson)
 658 AC_ARG_WITH(jansson,
 659    [  --with-jansson=PREFIX (base of libjansson installation)],
 660    [AC_MSG_RESULT([$with_jansson])
 661     AS_CASE([$with_jansson],
 662       [no],[],
 663       [yes],[
 664         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 665       ],[
 666         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 667         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 668         AC_CHECK_HEADERS(jansson.h,
 669           AC_CHECK_LIB([jansson], [json_loads],
 670             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 671             jansson=1))
 672       ])
 673    ],
 674    [AC_MSG_RESULT([--with-jansson not specified])
 675     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 676 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 677 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 678 AS_IF([test "x$jansson" = x1],
 679       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 680       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 681
 682
 683 # check for libpulse(audio) library
 684 pulse=0
 685 libpulse_msg="no"
 686 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 687 AS_IF([test "$build_target" = "mingw"],
 688       [pulse=0])
 689 AS_IF([test "$pulse" = 1],
 690       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 691        libpulse_msg="yes"])
 692
 693 # check for libopus(audio) library
 694 opus=0
 695 libopus_msg="no"
 696 CHECK_LIBHEADER(LIBOPUS,
 697                 opus,
 698                 opus_decode_float,
 699                 opus/opus.h,
 700                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 701 AS_IF([test "x$opus" = x1],
 702       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 703        libopus_msg="yes"])
 704
 705 # libogg
 706 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 707         [AC_CHECK_HEADERS([ogg/ogg.h],
 708           AM_CONDITIONAL(HAVE_OGG, true)
 709           ogg=1
 710           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 711           AM_CONDITIONAL(HAVE_OGG, false)
 712           ogg=0
 713           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 714         AM_CONDITIONAL(HAVE_OGG, false)
 715         ogg=0)
 716
 717
 718 PKG_CHECK_MODULES([GLIB],
 719                   [glib-2.0],
 720   [# check for pbc library
 721   pbc=0
 722    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 723    AC_CHECK_HEADER([gabe.h],abe=1)
 724    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 725    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 726    AS_IF([test "x$pbc" = x1],
 727      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 728      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 729    AS_IF([test "x$abe" = x1],
 730     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 731     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 732   [# glib-2 not found
 733    AM_CONDITIONAL(HAVE_PBC, [false])
 734    AM_CONDITIONAL(HAVE_ABE, [false])
 735    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 736
 737 gst=0
 738 gstreamer_msg="no"
 739 PKG_CHECK_MODULES(
 740   [GST],
 741   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 742   [gst=1
 743    gstreamer_msg="yes"],
 744   [gst=0])
 745
 746 # Pulse Audio
 747 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 748  AS_IF([test "x$gst" != "x1"],[
 749   conversation_backend=none
 750   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 751   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 752   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 753  ],[
 754    conversation_backend=gst
 755    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 756    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 757    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 758  ])
 759 ],[
 760  conversation_backend=pulse
 761  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 762  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 763  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 764 ])
 765
 766 AS_IF([test "x$conversation_backend" = "xnone"],
 767       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 768       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 769
 770 # libgnurl
 771 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 772
 773 SAVE_CPPFLAGS=$CPPFLAGS
 774 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 775 LIBS="$LIBGNURL $LIBCURL $LIBS"
 776
 777 # libcurl-gnutls
 778 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 779 AS_IF([test "x$curl" = xtrue],[
 780  AC_CHECK_HEADER([curl/curl.h],
 781   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 782   [curl=false])
 783  # need libcurl-gnutls.so, everything else is not acceptable
 784  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 785  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 786 ])
 787
 788 # libcurl and libgnurl should be mutually exclusive
 789 AS_IF([test "$gnurl" = 1],
 790       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 791        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 792        AM_CONDITIONAL(HAVE_LIBCURL, false)
 793        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 794       [AS_IF([test "$curl" = true],
 795              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 796               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 797               AM_CONDITIONAL(HAVE_LIBCURL, true)
 798               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 799              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 800               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 801               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 802               AM_CONDITIONAL(HAVE_LIBCURL, false)
 803               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 804
 805 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 806 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 807
 808 # restore LIBS & CPPFLAGS
 809 LIBS=$SAVE_LIBS
 810 CPPFLAGS=$SAVE_CPPFLAGS
 811
 812 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 813 # GLPK must support glpk_init_env, version >= 4.43
 814 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 815 # GLPK must support atm MLP presolving, version >= 4.32
 816 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 817 AS_IF([test "x$glpk" = xfalse],
 818 [
 819         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 820         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 821 ],[
 822         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 823         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 824 ])
 825
 826
 827 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 828 AS_IF([test x$nss = xfalse],
 829   [
 830         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 831         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 832   ],[
 833         NSS_INCLUDES="
 834         #include <nss.h>
 835         "
 836         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 837                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 838                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 839                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 840                 [$NSS_INCLUDES])
 841 ])
 842
 843
 844
 845 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 846 AC_CHECK_LIB([kvm],[kvm_open])
 847 AC_CHECK_LIB([kstat],[kstat_open])
 848
 849
 850 # should the build process be restricted to the code required
 851 # for GNU Taler wallets?
 852 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 853 AC_ARG_ENABLE([taler-wallet],
 854    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 855    [taler_only=${enableval}],
 856    [taler_only=no])
 857 AC_MSG_RESULT($taler_only)
 858 AS_IF([test "x$taler_only" = "xyes"],
 859 [
 860   AM_CONDITIONAL([TALER_ONLY],true)
 861   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 862 ],[
 863   AM_CONDITIONAL([TALER_ONLY],false)
 864   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 865 ])
 866
 867 # test for libextractor
 868 extractor=0
 869 AC_MSG_CHECKING(for libextractor)
 870 AC_ARG_WITH(extractor,
 871    [  --with-extractor=PREFIX (base of libextractor installation)],
 872    [AC_MSG_RESULT([$with_extractor])
 873     AS_CASE([$with_extractor],
 874       [no],[],
 875       [yes],[
 876         AC_CHECK_HEADERS([extractor.h],
 877           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 878             extractor=1))
 879       ],[
 880         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 881         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 882         AC_CHECK_HEADERS([extractor.h],
 883           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 884             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 885             extractor=1))
 886       ])
 887    ],
 888    [AC_MSG_RESULT([--with-extractor not specified])
 889     AC_CHECK_HEADERS([extractor.h],
 890      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 891       extractor=1))])
 892 # restore LIBS
 893 LIBS=$SAVE_LIBS
 894
 895 AS_IF([test "$extractor" != 1],
 896  [
 897  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 898  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 899  ],[
 900  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 901  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 902  ])
 903
 904
 905 AS_IF([test "$taler_only" != yes],[
 906
 907
 908 # Check for libltdl header (#2999)
 909 ltdl=0
 910 AC_MSG_CHECKING(for libltdl)
 911 AC_ARG_WITH(ltdl,
 912    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 913    [AC_MSG_RESULT([$with_ltdl])
 914     AS_CASE([$with_ltdl],
 915       [no],[],
 916       [yes],[
 917         AC_CHECK_HEADERS(ltdl.h,
 918           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 919             ltdl=1))
 920       ],[
 921         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 922         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 923         AC_CHECK_HEADERS(ltdl.h,
 924           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 925             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 926             ltdl=1))
 927       ])
 928    ],
 929    [AC_MSG_RESULT([--with-ltdl not specified])
 930     AC_CHECK_HEADERS(ltdl.h,
 931      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 932       ltdl=1))])
 933 AS_IF([test x$ltdl = x1],
 934 [
 935  AC_MSG_RESULT([libltdl found])
 936 ],[
 937  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 938 ])
 939 # restore LIBS
 940 LIBS=$SAVE_LIBS
 941
 942 # libidn and libidn2. The ideal goal is this:
 943 # check for libidn2, if it doesn't exist check for libidn
 944 # if both exist, prefer libidn2
 945 # if none exist, fail and message that libidn or libidn2
 946 # is required with a preference for libidn2.
 947 # TODO: What we have right here can probably be improved.
 948 my_with_libidn=1
 949 AC_ARG_WITH(libidn,
 950             AS_HELP_STRING([--with-libidn=pathname],
 951                            [Support IDN (needs libidn)]),
 952             [],
 953             [withval="yes"])
 954 AS_IF([test x_$withval = x_yes],
 955       [AC_CHECK_HEADERS([idna.h],
 956           AC_MSG_NOTICE([Found idna.h]),
 957           AC_CHECK_HEADERS([idn/idna.h],
 958                AC_MSG_NOTICE([Found idn/idna.h]),
 959                my_with_libidn=0))],
 960       [AS_IF([test x_$withval != x_no],
 961              [CFLAGS="$CFLAGS -I$withval/include"
 962               LDFLAGS="$LDFLAGS -L$withval/lib"
 963               AC_CHECK_HEADERS([idna.h],
 964                 AC_MSG_NOTICE([Found idna.h]),
 965                 [AC_MSG_NOTICE([Failed to find idna.h])
 966                  my_with_libidn=0])],
 967              [my_with_libidn=0])])
 968
 969 my_with_libidn2=1
 970 AC_ARG_WITH(libidn2,
 971             AS_HELP_STRING([--with-libidn2=pathname],
 972                            [Support IDN (needs libidn2)]),
 973             [],
 974             [withval="yes"])
 975 AS_IF([test x_$withval = x_yes],
 976       [AC_CHECK_HEADERS([idn2.h],
 977        AC_MSG_NOTICE([Found idn2.h]),
 978        AC_CHECK_HEADERS([idn2/idn2.h],
 979           AC_MSG_NOTICE([Found idn2/idn2.h]),
 980           [AC_MSG_NOTICE([Failed to find idn2.h])
 981            my_with_libidn2=0]))],
 982       [AS_IF([test x_$withval != x_no],
 983              [CFLAGS="$CFLAGS -I$withval/include"
 984               LDFLAGS="$LDFLAGS -L$withval/lib"],
 985              [my_with_libidn2=0])])
 986
 987 AC_MSG_CHECKING([if libidn can be used])
 988 # Check for LIBIDNs
 989 there_can_only_be_one=1
 990
 991 working_libidn1=0
 992 working_libidn2=0
 993 AS_IF([test x$my_with_libidn2 = x1],
 994       [AC_MSG_NOTICE([Checking for libidn2])
 995        AC_CHECK_LIB([idn2],
 996                     [idn2_to_unicode_8z8z],
 997                     [working_libidn2=1
 998                     LIBS="-lidn2 $LIBS"
 999                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1000                                        [1],
1001                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1002                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1003                      MISSING_SEP=", "])])
1004 AM_CONDITIONAL(HAVE_LIBIDN2,
1005                test x$working_libidn2 = x1)
1006 AS_IF([test x$working_libidn2 = x0],
1007       [AS_IF([test x$my_with_libidn = x1],
1008              [AC_MSG_NOTICE([Checking for libidn])
1009               AC_CHECK_LIB([idn],
1010                            [idna_to_ascii_8z],
1011                            [working_libidn1=1
1012                            LIBS="-lidn $LIBS"
1013                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1014                                               [1],
1015                                               [Define to 1 if you have 'libidn' (-lidn).])],
1016                            [there_can_only_be_one=0])],
1017              [AS_IF([test x$my_with_libidn2 = x1],
1018                     [there_can_only_be_one=0
1019                      AC_MSG_FAILURE([* There can only be one libidn.
1020                                      * Provide either libidn >= 1.13
1021                                      * or
1022                                      * libidn2 to the configure
1023                                      * script via
1024                                      * --with-libidn2
1025                                      * --with-libidn])])])])
1026 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1027
1028 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1029       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1030
1031 AS_IF([test x$there_can_only_be_one = x0],
1032       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1033
1034 # test for zlib
1035 SAVE_LDFLAGS=$LDFLAGS
1036 SAVE_CPPFLAGS=$CPPFLAGS
1037 AC_ARG_WITH(zlib,
1038             [  --with-zlib[[=DIR]]       use libz in DIR],
1039             [AS_IF([test "$withval" = "no"],
1040                    [AC_MSG_ERROR([GNUnet requires zlib])],
1041                    [test "$withval" != "yes"],
1042                    [Z_DIR=$withval
1043                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1044                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1045 AC_CHECK_HEADER(zlib.h,
1046                 [],
1047                 [AC_MSG_ERROR([GNUnet requires zlib])])
1048 AC_CHECK_LIB(z,
1049              compress2,
1050              [AC_DEFINE([HAVE_ZLIB],
1051                         [],
1052                         [Have compression library])
1053               if test "x${Z_DIR}" != "x"; then
1054                       Z_CFLAGS="-I${Z_DIR}/include"
1055                       Z_LIBS="-L${Z_DIR}/lib -lz"
1056               else
1057                       Z_LIBS="-lz"
1058               fi],
1059               [AC_MSG_ERROR([GNUnet requires zlib])])
1060 AC_SUBST(Z_CFLAGS)
1061 AC_SUBST(Z_LIBS)
1062
1063 AS_IF([test "$enable_shared" = "no"],
1064       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1065
1066
1067 # restore LIBS
1068 LIBS=$SAVE_LIBS
1069
1070
1071 # end of taler-only being false
1072 ])
1073
1074
1075 # check for iconv
1076 AM_ICONV
1077
1078 # test for libunistring
1079 gl_LIBUNISTRING
1080 AS_IF([test $HAVE_LIBUNISTRING != yes],
1081       [AC_MSG_ERROR([GNUnet requires libunistring])])
1082
1083 # under emscripten, $gl_libunistring_hexversion is undefined
1084 if test "$taler_only" != yes; then
1085
1086 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1087       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1088 fi
1089 AC_CHECK_HEADERS([unistr.h],
1090                  ,
1091                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1092
1093 # restore LIBS
1094 LIBS=$SAVE_LIBS
1095
1096
1097
1098 # Checks for standard header files.
1099 AC_HEADER_DIRENT
1100 AC_HEADER_STDC
1101
1102 # Check for headers that are ALWAYS required
1103 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1104
1105
1106
1107 # Checks for headers that are only required on some systems or
1108 # opional (and where we do NOT abort if they are not there)
1109 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1110
1111 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1112 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1113 [#ifdef HAVE_SYS_TYPES_H
1114 #include <sys/types.h>
1115 #endif
1116 #ifdef HAVE_NETINET_IN_SYSTM_H
1117 #include <netinet/in_systm.h>
1118 #endif
1119 #ifdef HAVE_NETINET_IN_H
1120 #include <netinet/in.h>
1121 #endif
1122 ])
1123
1124 SAVE_LDFLAGS=$LDFLAGS
1125 SAVE_CPPFLAGS=$CPPFLAGS
1126
1127 # test for sqlite
1128 sqlite=false
1129 AC_MSG_CHECKING(for SQLite)
1130 AC_ARG_WITH(sqlite,
1131   [  --with-sqlite=PFX       base of SQLite installation],
1132   [AC_MSG_RESULT("$with_sqlite")
1133    AS_CASE([$with_sqlite],
1134      [no],[],
1135      [yes],[
1136       AC_CHECK_HEADERS(sqlite3.h,
1137       sqlite=true)],
1138      [
1139     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1140     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1141     AC_CHECK_HEADERS(sqlite3.h,
1142      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1143      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1144      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1145      sqlite=true)
1146     LDFLAGS=$SAVE_LDFLAGS
1147     CPPFLAGS=$SAVE_CPPFLAGS
1148     ])
1149   ],
1150   [AC_MSG_RESULT([--with-sqlite not specified])
1151     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1152 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1153 AC_SUBST(SQLITE_CPPFLAGS)
1154 AC_SUBST(SQLITE_LDFLAGS)
1155
1156 LDFLAGS=$SAVE_LDFLAGS
1157 CPPFLAGS=$SAVE_CPPFLAGS
1158
1159 # test for postgres
1160 postgres=false
1161 # even running the check for postgres breaks emscripten ...
1162 AS_IF([test "$taler_only" != yes],
1163       [AX_LIB_POSTGRESQL([9.5],
1164         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1165          AC_CHECK_HEADERS([libpq-fe.h],
1166          postgres=true)
1167         ],
1168         [AC_MSG_RESULT([no postgres])])])
1169 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1170
1171
1172 LDFLAGS=$SAVE_LDFLAGS
1173 CPPFLAGS=$SAVE_CPPFLAGS
1174
1175 # mysql & windows
1176 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1177 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1178
1179 AS_IF([test "$build_target" = "mingw"]
1180  [CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"])
1181
1182 # test for mysql
1183 mysql=false
1184 mysqlfail=false
1185 SAVE_LDFLAGS=$LDFLAGS
1186 SAVE_CPPFLAGS=$CPPFLAGS
1187 AC_MSG_CHECKING(for mysql)
1188 AC_ARG_WITH(mysql,
1189   [  --with-mysql=PFX        base of MySQL installation],
1190   [AC_MSG_RESULT([$with_mysql])
1191    AS_CASE([$with_mysql],
1192      [no],[],
1193      [yes|""],[
1194       AC_CHECK_HEADERS(mysql/mysql.h,
1195        AC_CHECK_LIB(mysqlclient, mysql_init,
1196        mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1197      ],[
1198       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1199       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1200       AC_CHECK_HEADERS(mysql/mysql.h,
1201        AC_CHECK_LIB(mysqlclient, mysql_init,
1202         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1203         MYSQL_CPPFLAGS="-I$with_mysql/include"
1204
1205         mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1206      ])
1207   ],
1208   [AC_MSG_RESULT([--with-mysql not specified])
1209    if test -d "/usr/lib64/mysql"; then
1210     MYSQL_LIBDIR="/usr/lib64/mysql"
1211    elif test -d "/usr/lib/mysql"; then
1212     MYSQL_LIBDIR="/usr/lib/mysql"
1213    else
1214     MYSQL_LIBDIR="/usr/lib"
1215    fi
1216    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1217    AC_CHECK_LIB(mysqlclient, mysql_init,
1218     [AC_CHECK_HEADERS(mysql/mysql.h,
1219       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1220       mysql=true
1221
1222      , [], [$CYGWIN_MYSQL_MAGIC])])
1223   ])
1224
1225 AC_SUBST(MYSQL_LDFLAGS)
1226 AC_SUBST(MYSQL_CPPFLAGS)
1227
1228 # additional version check for mysql
1229 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1230 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1231  [
1232   AC_MSG_CHECKING(mysql version)
1233   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1234     [[$CYGWIN_MYSQL_MAGIC
1235       #include <mysql/mysql.h>]],
1236     [[
1237       #if (MYSQL_VERSION_ID < 40100)
1238       #error needs at least version >= 4.1
1239       #endif
1240       int main () { return 0; }
1241     ]])
1242     ],mysql=true,mysql=false)
1243   AS_IF([test "$mysql" = "false"],
1244    [
1245     mysqlfail=true
1246     AC_MSG_RESULT([fail, >= 4.1 required])
1247    ],[
1248     AC_MSG_RESULT(ok)
1249    ])
1250 ])
1251 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1252 AM_CONDITIONAL(HAVE_MYSQLE, false)
1253 # restore LIBS
1254 LIBS=$SAVE_LIBS
1255 LDFLAGS=$SAVE_LDFLAGS
1256 CPPFLAGS=$SAVE_CPPFLAGS
1257
1258 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1259 [
1260  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1261 ])
1262
1263 # libmicrohttpd
1264 lmhd=0
1265 AC_MSG_CHECKING([for libmicrohttpd])
1266 AC_ARG_WITH(microhttpd,
1267    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
1268    [AC_MSG_RESULT([$with_microhttpd])
1269     AS_CASE([$with_microhttpd],
1270       [no],[],
1271       [yes|""],[
1272         AC_CHECK_HEADERS([microhttpd.h],
1273           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1274             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1275               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.63])
1276               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1277                 #include "$native_srcdir/src/include/platform.h"
1278                 #include <microhttpd.h>
1279                 #if (MHD_VERSION < 0x0096300)
1280                 #error needs at least version 0.9.63
1281                 #endif
1282                 int main () { return 0; }
1283                ])],
1284                [AC_MSG_RESULT(ok)
1285                 lmhd=1],
1286                [AC_MSG_RESULT(failed)])]),
1287             [],[#include "$native_srcdir/src/include/platform.h"
1288                 #include <microhttpd.h>]),,
1289             [#include "$native_srcdir/src/include/platform.h"])
1290       ],[
1291         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
1292         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
1293         AC_CHECK_HEADERS(microhttpd.h,
1294           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1295             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1296               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
1297               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1298                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1299                 #include "$native_srcdir/src/include/platform.h"
1300                 #include <microhttpd.h>
1301                 #if (MHD_VERSION < 0x0094200)
1302                 #error needs at least version 0.9.42
1303                 #endif
1304                 int main () { return 0; }
1305                ])],
1306                [AC_MSG_RESULT(ok)
1307                 lmhd=1],
1308                [AC_MSG_RESULT(failed)])]),
1309             [],[#include "$native_srcdir/src/include/platform.h"
1310                 #include <microhttpd.h>]),,
1311             [#include "$native_srcdir/src/include/platform.h"])
1312        ])
1313    ],
1314    [AC_MSG_RESULT([--with-microhttpd not specified])
1315     AC_CHECK_HEADERS([microhttpd.h],
1316       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1317         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1318           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1319               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1320                 #include "$native_srcdir/src/include/platform.h"
1321                 #include <microhttpd.h>
1322                 #if (MHD_VERSION < 0x0094200)
1323                 #error needs at least version 0.9.52
1324                 #endif
1325                ])],
1326                [AC_MSG_RESULT(ok)
1327                 lmhd=1],
1328                [AC_MSG_RESULT(failed)])]),
1329         [],[#include "$native_srcdir/src/include/platform.h"
1330             #include <microhttpd.h>]),,
1331        [#include "$native_srcdir/src/include/platform.h"])])
1332 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1333 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1334
1335 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1336
1337 # restore LIBS
1338 LIBS=$SAVE_LIBS
1339
1340 # check for gettext
1341 AM_GNU_GETTEXT([external])
1342 AM_GNU_GETTEXT_VERSION([0.18.1])
1343
1344 # Checks for standard typedefs, structures, and compiler characteristics.
1345 AC_TYPE_PID_T
1346 AC_TYPE_SIZE_T
1347 AC_TYPE_MODE_T
1348 AC_HEADER_TIME
1349 AC_HEADER_STAT
1350 AC_HEADER_STDBOOL
1351 AC_STRUCT_TM
1352
1353 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1354    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1355    ],
1356    [],
1357    [
1358       #include <sys/types.h>
1359       #include <sys/socket.h>
1360       #include <netinet/in.h>
1361    ])
1362
1363 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1364                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1365                             1,
1366                             [Do we have sockaddr_un.sun_len?])],
1367                 [],
1368                 [
1369                 #include <sys/types.h>
1370                 #include <sys/socket.h>
1371                 #include <sys/un.h>
1372                 ])
1373
1374
1375
1376 # Checks for library functions.
1377 AC_FUNC_CLOSEDIR_VOID
1378 AC_FUNC_FORK
1379 AC_PROG_GCC_TRADITIONAL
1380 AC_FUNC_MEMCMP
1381 AC_FUNC_SELECT_ARGTYPES
1382 AC_FUNC_CHOWN
1383
1384 AC_TYPE_SIGNAL
1385 AC_FUNC_STAT
1386 AC_FUNC_STRFTIME
1387 AC_FUNC_VPRINTF
1388 AC_HEADER_SYS_WAIT
1389 AC_TYPE_OFF_T
1390 AC_TYPE_UID_T
1391 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1392
1393 # restore LIBS
1394 LIBS=$SAVE_LIBS
1395
1396 GN_INTLINCL=""
1397 GN_LIBINTL="$LTLIBINTL"
1398 AC_ARG_ENABLE(framework,
1399               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1400               enable_framework_build=$enableval)
1401 AM_CONDITIONAL(WANT_FRAMEWORK,
1402                test x$enable_framework_build = xyes)
1403 AS_IF([test x$enable_framework_build = xyes],
1404       [AC_DEFINE([FRAMEWORK_BUILD],
1405                  1,
1406                  [Build a Mac OS X Framework])
1407       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1408       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1409       AC_LIB_APPENDTOVAR([CPPFLAGS],
1410                          [$GN_INTLINCL])])
1411
1412 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1413 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1414
1415 AC_SUBST(GN_LIB_LDFLAGS)
1416 AC_SUBST(GN_PLUGIN_LDFLAGS)
1417 AC_SUBST(GN_INTLINCL)
1418 AC_SUBST(GN_LIBINTL)
1419
1420 AC_SUBST(CPPFLAGS)
1421 AC_SUBST(LIBS)
1422 AC_SUBST(LDFLAGS)
1423 AC_SUBST(EXT_LIB_PATH)
1424 AC_SUBST(EXT_LIBS)
1425
1426 AC_SUBST(LIBPREFIX)
1427 AC_SUBST(DLLDIR)
1428 AC_SUBST(EXT_LIB_PATH)
1429
1430 DATAROOTDIR=$datarootdir
1431 AC_SUBST(DATAROOTDIR)
1432
1433 # test for sudo
1434 # TODO: do we need to change anything for "doas" on openbsd?
1435 AC_MSG_CHECKING(for sudo)
1436 AC_ARG_WITH(sudo,
1437             [  --with-sudo=PATH       path to sudo binary (or just yes)],
1438             [AC_MSG_RESULT("$with_sudo")
1439              AS_CASE([$with_sudo],
1440                      [no],[SUDO_BINARY=],
1441                      [yes],[SUDO_BINARY=sudo],
1442                      [SUDO_BINARY=$with_sudo])],
1443             [AC_MSG_RESULT([no])])
1444 AC_SUBST(SUDO_BINARY)
1445 AM_CONDITIONAL([HAVE_SUDO],
1446                [test "x$SUDO_BINARY" != "x" -o -w /])
1447
1448
1449 # test for gnunetdns group name
1450 GNUNETDNS_GROUP=gnunetdns
1451 AC_MSG_CHECKING(for gnunetdns group name)
1452 AC_ARG_WITH(gnunetdns,
1453             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1454             [AC_MSG_RESULT("$with_gnunetdns")
1455              AS_CASE([$with_gnunetdns],
1456                      [no],[GNUNETDNS_GROUP=gnunet],
1457                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1458                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1459             [AC_MSG_RESULT([gnunetdns])])
1460 AC_SUBST(GNUNETDNS_GROUP)
1461
1462
1463
1464 # gnutls
1465 gnutls=0
1466 gnutls_dane=0
1467 AC_MSG_CHECKING(for gnutls)
1468 AC_ARG_WITH(gnutls,
1469             [  --with-gnutls=PFX   base of gnutls installation],
1470             [AC_MSG_RESULT([$with_gnutls])
1471              AS_CASE([$with_gnutls],
1472                      [no],[],
1473                      [yes],
1474                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1475                                        AC_CHECK_LIB([gnutls],
1476                                                     [gnutls_priority_set],
1477                                                     gnutls=true))
1478                       AC_CHECK_HEADERS([gnutls/dane.h],
1479                                        AC_CHECK_LIB([gnutls-dane],
1480                                                     [dane_verify_crt_raw],
1481                                                     gnutls_dane=1))],
1482
1483         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1484         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1485         AC_CHECK_HEADERS([gnutls/abstract.h],
1486             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1487               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1488               gnutls=true))
1489         AC_CHECK_HEADERS([gnutls/dane.h],
1490             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1491               gnutls_dane=1))
1492       ])
1493    ],
1494    [AC_MSG_RESULT([--with-gnutls not specified])
1495     AC_CHECK_HEADERS([gnutls/abstract.h],
1496         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1497           gnutls=true))
1498     AC_CHECK_HEADERS([gnutls/dane.h],
1499         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1500                      gnutls_dane=1))
1501    ])
1502 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1503 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1504 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1505 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1506
1507
1508
1509 # Test if we are building for superMUC
1510 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1511 AC_ARG_ENABLE([supermuc],
1512     [AS_HELP_STRING([--enable-supermuc],
1513        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1514     [AS_IF([test "x$enable_supermuc" = "xno"],
1515       [supermuc=0],
1516       [supermuc=1])],
1517     [supermuc=0
1518      enable_supermuc=no])
1519 AC_MSG_RESULT($enable_SUPERMUC)
1520 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1521 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1522
1523 # Check if NSE has to send timestamp information to testbed logger for
1524 # generating histogram of messages received
1525 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1526 AC_ARG_ENABLE([nse-histogram],
1527     [AS_HELP_STRING([--enable-nse-histogram],
1528        [have NSE send timestamp information to testbed logger for generating
1529        histogram of received messages.  NOT useful for production (default is
1530        NO)])],
1531     [AS_IF([test "x$enableval" = "xno"],
1532       [nse_histogram=0],
1533       [nse_histogram=1])],
1534     [nse_histogram=0
1535      enable_nse_histogram=no])
1536 AC_MSG_RESULT($enable_nse_histogram)
1537 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1538 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1539                    [have NSE send timestamp information to testbed logger])
1540
1541 # should 'make check' run tests?
1542 AC_MSG_CHECKING(whether to run tests)
1543 AC_ARG_ENABLE([testruns],
1544    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1545    [enable_tests_run=${enableval}],
1546    [enable_tests_run=yes])
1547 AC_MSG_RESULT($enable_test_run)
1548 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1549
1550
1551 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1552 AC_ARG_ENABLE([benchmark],
1553    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1554    [enable_benchmark=${enableval}],
1555    [enable_benchmark=no])
1556 AC_MSG_RESULT($enable_benchmark)
1557 AS_IF([test "x$enable_benchmark" = "xyes"],
1558       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1559 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1560
1561
1562 # should expensive tests be run?
1563 AC_MSG_CHECKING(whether to run expensive tests)
1564 AC_ARG_ENABLE([expensivetests],
1565    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1566    [enable_expensive=${enableval}],
1567    [enable_expensive=no])
1568 AC_MSG_RESULT($enable_expensive)
1569 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1570
1571 # should ports be open for Java services?
1572 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1573 AC_ARG_ENABLE([javaports],
1574    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1575    [enable_java_ports=${enableval}],
1576    [enable_java_ports=no])
1577 AC_MSG_RESULT($enable_java_ports)
1578 AS_IF([test "x$enable_java_ports" = "xyes"],
1579  [JAVAPORT=""],
1580  [JAVAPORT="$UNIXONLY"])
1581 AC_SUBST(JAVAPORT)
1582
1583 # should benchmarks be run?
1584 AC_MSG_CHECKING(whether to run benchmarks during make check)
1585 AC_ARG_ENABLE([benchmarks],
1586    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1587    [enable_benchmarks=${enableval}],
1588    [enable_benchmarks=no])
1589 AC_MSG_RESULT($enable_benchmarks)
1590 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1591
1592 # should gnunet-testing be compiled
1593 AC_MSG_CHECKING(wether to compile gnunet-testing)
1594 AC_ARG_ENABLE([testing],
1595    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1596    [enable_testing=${enableval}],
1597    [enable_testing=yes])
1598 AC_MSG_RESULT($enable_testing)
1599 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1600
1601 # should experimental code be compiled (code that may not yet compile)?
1602 AC_MSG_CHECKING(whether to compile experimental code)
1603 AC_ARG_ENABLE([experimental],
1604    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1605    [enable_experimental=${enableval}],
1606    [enable_experimental=no])
1607 AC_MSG_RESULT($enable_experimental)
1608 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1609
1610 # should malicious code be compiled (should only be used for testing)?
1611 AC_MSG_CHECKING(whether to compile malicious code)
1612 AC_ARG_ENABLE([malicious],
1613    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1614    [AS_IF([test "x$enableval" = "xno"],
1615      [malicious=0],
1616      [malicious=1])],
1617    [malicious=0
1618     enable_malicious=no])
1619 AC_MSG_RESULT($enable_malicious)
1620 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1621 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1622                    [enable compilation of malicious code])
1623
1624 # should services be started on demand when needed?
1625 # Some services may choose to never start by default
1626 # and it is up to the service/module developer to decide
1627 # by having "START_ON_DEMAND = NO" instead of
1628 # "START_ON_DEMAND = @START_ON_DEMAND@"
1629 # in the service/module's conf.in file.
1630 # See also IMMEDIATE_START for an unconditional immediate start.
1631 START_ON_DEMAND="YES"
1632 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1633 AC_ARG_ENABLE([autostart],
1634    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1635    [enable_autostart=${enableval}
1636     AS_IF([test "x$enable_autostart" = "xno"],
1637       [START_ON_DEMAND="NO"])
1638    ],
1639    [enable_autostart=yes])
1640 AC_MSG_RESULT($enable_autostart)
1641 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1642 AC_SUBST(START_ON_DEMAND)
1643
1644 # should memory statistics be kept (very expensive CPU-wise!)
1645 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1646 AC_ARG_ENABLE([heapstats],
1647    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1648    [enable_heapstats=1],
1649    [enable_heapstats=0])
1650 AC_MSG_RESULT($enable_heapstats)
1651 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1652
1653 # should code be enabled that works around missing OS functionality on Windows?
1654 # used for test cases
1655 if test $build_target = "mingw"
1656 then
1657         workarounds=1
1658
1659 AC_LINK_IFELSE(
1660  [AC_LANG_PROGRAM(
1661   [#include <ws2tcpip.h>
1662   ],[
1663   int s = socket (0, 0, 0);])
1664  ],[
1665   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1666  ],[
1667   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1668  ])
1669
1670 AC_LINK_IFELSE(
1671  [AC_LANG_PROGRAM(
1672   [#include <ws2tcpip.h>
1673   ],[
1674   int s = select (0, NULL, NULL, NULL, NULL);])
1675  ],[
1676   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1677  ],[
1678   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1679  ])
1680
1681 AC_LINK_IFELSE(
1682  [AC_LANG_PROGRAM(
1683   [#include <ws2tcpip.h>
1684   ],[
1685   struct in_addr i;
1686   char *s = inet_ntoa (i);])
1687  ],[
1688   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1689  ],[
1690   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1691  ])
1692
1693 AC_LINK_IFELSE(
1694  [AC_LANG_PROGRAM(
1695   [#include <ws2tcpip.h>
1696   ],[
1697   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1698  ],[
1699   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1700  ],[
1701   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1702  ])
1703
1704 AC_LINK_IFELSE(
1705  [AC_LANG_PROGRAM(
1706   [#include <ws2tcpip.h>
1707   ],[
1708   int s = gethostname (NULL, 0);])
1709  ],[
1710   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1711  ],[
1712   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1713  ])
1714
1715 AC_LINK_IFELSE(
1716  [AC_LANG_PROGRAM(
1717   [#include <ws2tcpip.h>
1718   ],[
1719   void *s = gethostbyname (NULL);])
1720  ],[
1721   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1722  ],[
1723   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1724  ])
1725
1726 AC_LINK_IFELSE(
1727  [AC_LANG_PROGRAM(
1728   [#include <ws2tcpip.h>
1729   ],[
1730   void *s = gethostbyaddr (NULL, 0, 0);])
1731  ],[
1732   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1733  ],[
1734   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1735  ])
1736
1737 AC_LINK_IFELSE(
1738  [AC_LANG_PROGRAM(
1739   [#include <ws2tcpip.h>
1740   ],[
1741   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1742  ],[
1743   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1744  ],[
1745   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],0,[Define this if getaddrinfo() is available])
1746  ])
1747
1748 else
1749   AC_MSG_CHECKING(whether to enable windows workarounds)
1750   AC_ARG_ENABLE([windows_workarounds],
1751      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1752      [enable_workarounds=${enableval}],
1753      [enable_workarounds=no])
1754   AC_MSG_RESULT($enable_workarounds)
1755   AS_IF([test x$enable_windows_workarounds = "xyes"],
1756     [workarounds=1],
1757     [workarounds=0])
1758 fi
1759 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1760
1761
1762 # Check if the __thread storage class for
1763 # thread-local storage is available.
1764 AC_MSG_CHECKING(whether __thread is supported)
1765 AC_LINK_IFELSE(
1766 [AC_LANG_PROGRAM([#include <stdlib.h>
1767                    #undef __thread
1768                    static __thread int a = 1;],
1769                   [exit(a-1);])],
1770  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1771 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1772 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1773       [AC_MSG_RESULT(yes)],
1774       [AC_MSG_RESULT(no)])
1775
1776 # gcov compilation
1777 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1778 AC_ARG_ENABLE([coverage],
1779               AS_HELP_STRING([--enable-coverage],
1780                              [compile the library with code coverage support]),
1781               [use_gcov=${enableval}],
1782               [use_gcov=no])
1783 AC_MSG_RESULT($use_gcov)
1784 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1785
1786
1787 # version info
1788 # TODO: git blame says this predates our switch to git.
1789 # git-svn should be adjusted to simply git, or
1790 # an external script that does the job.
1791 AC_PATH_PROG(svnversioncommand, svnversion)
1792 AC_PATH_PROG(gitcommand, git)
1793 AC_MSG_CHECKING(for source being under a VCS)
1794
1795
1796 # version info
1797 AC_PATH_PROG(gitcommand, git)
1798 AC_MSG_CHECKING(for source being under a VCS)
1799 git_version=
1800 AS_IF([test ! "X$gitcommand" = "X"],
1801 [
1802   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1803 ])
1804 AS_IF([test "X$git_version" = "X"],
1805   [
1806     vcs_name="no"
1807     vcs_version="\"release\""
1808   ],
1809   [
1810     vcs_name="yes, git-svn"
1811     vcs_version="\"git-$git_version\""
1812   ])
1813 AC_MSG_RESULT($vcs_name)
1814
1815 AC_MSG_CHECKING(VCS version)
1816 AC_MSG_RESULT($vcs_version)
1817 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1818
1819 AC_CONFIG_FILES([
1820 Makefile
1821 contrib/Makefile
1822 contrib/hellos/Makefile
1823 contrib/services/Makefile
1824 contrib/services/openrc/Makefile
1825 contrib/services/systemd/Makefile
1826 contrib/scripts/Makefile
1827 contrib/scripts/gnunet-logread/Makefile
1828 doc/Makefile
1829 doc/man/Makefile
1830 doc/doxygen/Makefile
1831 doc/handbook/Makefile
1832 doc/tutorial/Makefile
1833 lint/Makefile
1834 m4/Makefile
1835 po/Makefile.in
1836 src/Makefile
1837 src/arm/Makefile
1838 src/arm/arm.conf
1839 src/ats/Makefile
1840 src/ats/ats.conf
1841 src/ats-tool/Makefile
1842 src/ats-tests/Makefile
1843 src/auction/Makefile
1844 src/block/Makefile
1845 src/cadet/Makefile
1846 src/cadet/cadet.conf
1847 src/core/Makefile
1848 src/core/core.conf
1849 src/consensus/Makefile
1850 src/consensus/consensus.conf
1851 src/conversation/Makefile
1852 src/conversation/conversation.conf
1853 src/curl/Makefile
1854 src/datacache/Makefile
1855 src/datastore/Makefile
1856 src/datastore/datastore.conf
1857 src/dht/Makefile
1858 src/dht/dht.conf
1859 src/dns/Makefile
1860 src/dns/dns.conf
1861 src/exit/Makefile
1862 src/fragmentation/Makefile
1863 src/fs/Makefile
1864 src/fs/fs.conf
1865 src/gns/Makefile
1866 src/gns/gns.conf
1867 src/gns/nss/Makefile
1868 src/gnsrecord/Makefile
1869 src/hello/Makefile
1870 src/identity/Makefile
1871 src/identity/identity.conf
1872 src/credential/Makefile
1873 src/credential/credential.conf
1874 src/include/Makefile
1875 src/integration-tests/Makefile
1876 src/json/Makefile
1877 src/hostlist/Makefile
1878 src/my/Makefile
1879 src/mysql/Makefile
1880 src/namecache/Makefile
1881 src/namecache/namecache.conf
1882 src/namestore/Makefile
1883 src/namestore/namestore.conf
1884 src/nat/Makefile
1885 src/nat/nat.conf
1886 src/nat-auto/Makefile
1887 src/nat-auto/nat-auto.conf
1888 src/nse/Makefile
1889 src/nse/nse.conf
1890 src/nt/Makefile
1891 src/peerinfo/Makefile
1892 src/peerinfo/peerinfo.conf
1893 src/peerinfo-tool/Makefile
1894 src/peerstore/Makefile
1895 src/peerstore/peerstore.conf
1896 src/pq/Makefile
1897 src/pt/Makefile
1898 src/regex/Makefile
1899 src/regex/regex.conf
1900 src/revocation/Makefile
1901 src/revocation/revocation.conf
1902 src/rps/Makefile
1903 src/rps/rps.conf
1904 src/secretsharing/Makefile
1905 src/secretsharing/secretsharing.conf
1906 src/scalarproduct/Makefile
1907 src/scalarproduct/scalarproduct.conf
1908 src/set/Makefile
1909 src/set/set.conf
1910 src/sq/Makefile
1911 src/statistics/Makefile
1912 src/statistics/statistics.conf
1913 src/template/Makefile
1914 src/testbed/Makefile
1915 src/testbed/testbed.conf
1916 src/testbed-logger/Makefile
1917 src/testbed-logger/testbed-logger.conf
1918 src/testing/Makefile
1919 src/topology/Makefile
1920 src/transport/Makefile
1921 src/transport/transport.conf
1922 src/util/Makefile
1923 src/util/resolver.conf
1924 src/vpn/Makefile
1925 src/vpn/vpn.conf
1926 src/zonemaster/Makefile
1927 src/zonemaster/zonemaster.conf
1928 src/rest/Makefile
1929 src/abe/Makefile
1930 src/reclaim-attribute/Makefile
1931 src/reclaim/Makefile
1932 pkgconfig/Makefile
1933 pkgconfig/gnunetarm.pc
1934 pkgconfig/gnunetats.pc
1935 pkgconfig/gnunetblock.pc
1936 pkgconfig/gnunetcadet.pc
1937 pkgconfig/gnunetconsensus.pc
1938 pkgconfig/gnunetconversation.pc
1939 pkgconfig/gnunetcore.pc
1940 pkgconfig/gnunetdatacache.pc
1941 pkgconfig/gnunetdatastore.pc
1942 pkgconfig/gnunetdht.pc
1943 pkgconfig/gnunetdns.pc
1944 pkgconfig/gnunetenv.pc
1945 pkgconfig/gnunetfragmentation.pc
1946 pkgconfig/gnunetfs.pc
1947 pkgconfig/gnunetgns.pc
1948 pkgconfig/gnunethello.pc
1949 pkgconfig/gnunetidentity.pc
1950 pkgconfig/gnunetmicrophone.pc
1951 pkgconfig/gnunetmysql.pc
1952 pkgconfig/gnunetnamestore.pc
1953 pkgconfig/gnunetnat.pc
1954 pkgconfig/gnunetnse.pc
1955 pkgconfig/gnunetpeerinfo.pc
1956 pkgconfig/gnunetpq.pc
1957 pkgconfig/gnunetregex.pc
1958 pkgconfig/gnunetrevocation.pc
1959 pkgconfig/gnunetrps.pc
1960 pkgconfig/gnunetscalarproduct.pc
1961 pkgconfig/gnunetset.pc
1962 pkgconfig/gnunetspeaker.pc
1963 pkgconfig/gnunetstatistics.pc
1964 pkgconfig/gnunettestbed.pc
1965 pkgconfig/gnunettesting.pc
1966 pkgconfig/gnunettransport.pc
1967 pkgconfig/gnunetutil.pc
1968 pkgconfig/gnunetvpn.pc
1969 ])
1970 AC_OUTPUT
1971
1972
1973 # FIXME: `some modules' -> be more specific which exact modules.
1974
1975 # java ports
1976 AS_IF([test "x$enable_java_ports" = "xyes"],
1977       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1978
1979 ####
1980 #### Lasciate ogne speranza, voi ch'intrate
1981 ####
1982 #### This could be moved to the checks above,
1983 #### but for now let's keep it here.
1984 ####
1985
1986 # -- print message regarding enabled experimental features
1987 AS_IF([test "x$enable_experimental" = "xyes"],
1988       [experimental_msg="experimental features enabled"])
1989 # -- OSX Framework
1990 AS_IF([test "$enable_framework_build" = "yes"],
1991       [macosx_framework_msg="yes"],
1992       [macosx_framework_msg="no"])
1993 # -- libidn 2
1994 AS_IF([test "x$working_libidn2" = x1],
1995       [libidn2_msg="libidn2"])
1996 # -- libidn 1
1997 AS_IF([test "x$working_libidn1" = x1],
1998       [libidn1_msg="libidn1"])
1999 # -- texi2mdoc
2000 AS_IF([test "x$texi2mdoc_generation" = x1],
2001       [mdoc_msg="yes"],
2002       [mdoc_msg="no"])
2003 # -- texinfo
2004 AS_IF([test "x$makeinfo" != "x1"],
2005       [texinfo_msg="no"],
2006       [texinfo_msg="yes"])
2007 # -- conversation
2008 AS_IF([test "x$conversation_backend" = "xnone"],
2009       [AS_IF([test "x$pulse" != "x1"],
2010              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
2011               libpulse_msg="no"],
2012              [libpulse_msg="yes"])
2013        AS_IF([test "x$opus" != "x1"],
2014              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
2015               libopus_msg="no"],
2016              [libopus_msg="yes"])
2017        AS_IF([test "x$gst" != "x1"],
2018              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
2019               gstreamer_msg="no"],
2020              [gstreamer_msg="yes"])],
2021       [features_msg="$features_msg conversation"])
2022 # -- interface
2023 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2024 # -- libmicrohttpd
2025 AS_IF([test "x$lmhd" != "x1"],
2026       [libmicrohttpd_msg="no (optional)"],
2027       [libmicrohttpd_msg="yes"])
2028 # -- jansson
2029 AS_IF([test "x$jansson" = "x0"],
2030       [jansson_msg="no (optional)"],
2031       [jansson_msg="yes"])
2032 # -- libextractor
2033 AS_IF([test "$extractor" != 1],
2034       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
2035       [libextractor_msg="yes"])
2036 # -- libzbar
2037 AS_IF([test "x$zbar" = "x1"],
2038       [libzbar_msg="yes"
2039        features_msg="$features_msg gnunet-qr"],
2040       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
2041        libzbar_msg="no"])
2042 # -- libgnurl
2043 AS_IF([test "$gnurl" = "0"],
2044       [AS_IF([test "x$curl" = "xfalse"],
2045              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
2046               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2047               curl_msg="no"],
2048              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
2049               curl_msg="yes"])],
2050        [gnurl_msg="yes"])
2051 # -- ifconfig
2052 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2053       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2054        ifconfig_msg="no (optional)"],
2055       [ifconfig_msg="yes"])
2056 # -- upnpc
2057 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2058       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2059        upnpc_msg="no (optional)"],
2060       [upnpc_msg="yes"])
2061 # -- iptables
2062 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2063       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2064        iptables_msg="no (optional)"],
2065       [iptables_msg="yes"])
2066 # -- bluetooth
2067 AS_IF([test "x$bluetooth" = "x0"],
2068       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2069        bluetooth_msg="no (optional)"],
2070       [bluetooth_msg="yes"])
2071 # -- gnutls
2072 AS_IF([test x$gnutls != xtrue],
2073       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2074        gnutls_msg="no"],
2075       [AS_IF([test "x$gnutls_dane" != "x1"],
2076              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2077               gnutls_msg="yes (without DANE support)"],
2078              [gnutls_msg="yes (with DANE support)"])])
2079 # -- databases
2080 AS_IF([test $mysqlfail = true]
2081       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2082 AS_IF([test "$mysql" = true],
2083       [features_msg="$features_msg mysql"
2084        mysql_msg="yes"],
2085       [mysql_msg="no"])
2086 AS_IF([test "$sqlite" = true],
2087       [features_msg="$features_msg sqlite"
2088        sqlite_msg="yes"],
2089       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2090        sqlite_msg="no"])
2091 AS_IF([test "$postgres" = true],
2092       [features_msg="$features_msg postgres"
2093        postgres_msg="yes"],
2094       [postgres_msg="no"])
2095 # -- features
2096 # ---- 1. replace spaces with newlines,
2097 # ---- 2. sort the lines,
2098 # ---- 3. replace the newlines with spaces.
2099 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2100 AC_SUBST(features_msg)
2101
2102
2103 # The summary
2104 # TODO: reduce the length of the last message block ("the message")
2105
2106 AC_MSG_NOTICE([
2107 GNUnet Configuration (incomplete!)
2108
2109 gnunet version:                 ${VERSION}
2110
2111 Host setup:                     ${host}
2112 Install prefix:                 ${prefix}
2113 Compiler:                       ${CC}
2114 CFLAGS:                         ${CFLAGS}
2115 CPPFLAGS:                       ${CPPFLAGS}
2116 LDFLAGS:                        ${LDFLAGS}
2117 LIBS:                           ${LIBS}
2118 Build Target:                   $build_target
2119 Mac OSX framework build:        ${macosx_framework_msg}
2120
2121 Default Interface:              ${interface_msg}
2122
2123 MySQL:                          ${mysql_msg}
2124 PostgreSQL:                     ${postgres_msg}
2125 sqlite3:                        ${sqlite_msg}
2126 gnurl:                          ${gnurl_msg}
2127 curl:                           ${curl_msg}
2128 bluetooth:                      ${bluetooth_msg}
2129 jansson:                        ${jansson_msg}
2130 iptables:                       ${iptables_msg}
2131 ifconfig:                       ${ifconfig_msg}
2132 upnpc:                          ${upnpc_msg}
2133 gnutls:                         ${gnutls_msg}
2134 libzbar:                        ${libzbar_msg}
2135 java:                           ${java_msg}
2136 libmicrohttpd:                  ${libmicrohttpd_msg}
2137 libidn:                         ${libidn1_msg}${libidn2_msg}
2138 libopus:                        ${libopus_msg}
2139 gstreamer:                      ${gstreamer_msg}
2140 libpulse:                       ${libpulse_msg}
2141 libextractor:                   ${libextractor_msg}
2142
2143 texinfo manual:                 ${texinfo_msg}
2144 transpiled mdoc manual:         ${mdoc_msg}
2145
2146 features:                       ${features_msg}
2147 experimental:                   ${experimental_msg}
2148
2149
2150 IMPORTANT:
2151
2152 Please make sure NOW that you have created a user and group 'gnunet'
2153 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2154 type:
2155
2156   addgroup gnunetdns
2157   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2158
2159 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2160 'gnunet'.  Then, you can compile GNUnet with
2161
2162   make
2163
2164 After that, run (if necessary as 'root')
2165
2166   make install
2167
2168 to install everything.
2169
2170 Each GNUnet user should be added to the 'gnunet' group (may
2171 require fresh login to come into effect):
2172
2173   adduser USERNAME gnunet
2174
2175 (run the above command as root once for each of your users, replacing
2176 "USERNAME" with the respective login names).  If you have a global IP
2177 address, no further configuration is required.
2178
2179 For more detailed setup instructions, see https://docs.gnunet.org/
2180
2181 Optionally, download and compile gnunet-gtk to get a GUI for
2182 file-sharing and configuration.  This is particularly recommended
2183 if your network setup is non-trivial, as gnunet-setup can be
2184 used to test in the GUI if your network configuration is working.
2185 gnunet-setup should be run as the "gnunet" user under X.  As it
2186 does very little with the network, running it as "root" is likely
2187 also harmless.  You can also run it as a normal user, but then
2188 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2189 home directory in the end.
2190
2191 Once you have configured your peer, run (as the 'gnunet' user)
2192
2193   gnunet-arm -s
2194
2195 to start the peer.  You can then run the various GNUnet-tools as
2196 your "normal" user (who should only be in the group 'gnunet').
2197 ])