configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_CPP
  47 AC_PROG_CXX
  48 AC_PROG_OBJC
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AM_PROG_CC_C_O
  53 LT_INIT([disable-static dlopen win32-dll])
  54 AC_SUBST(MKDIR_P)
  55
  56 # allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 # large file support
  60 AC_SYS_LARGEFILE
  61 AC_FUNC_FSEEKO
  62
  63
  64 CFLAGS="-Wall $CFLAGS"
  65 # use '-fno-strict-aliasing', but only if the compiler can take it
  66 AS_IF([gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  67  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  68
  69 # A helper which allows us to check cflags if compiler
  70 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  71   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  72     [ac_save_CFLAGS="$CFLAGS"
  73      CFLAGS="$CFLAGS $1"
  74      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  76        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  77      CFLAGS="$ac_save_CFLAGS"
  78     ])
  79
  80   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  81     [$2], [$3])
  82 ])
  83
  84 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  85 CC_CHECK_CFLAGS_SILENT([-Wno-address-of-packed-member],
  86                       [CFLAGS="-Wno-address-of-packed-member $CFLAGS"])
  87
  88 # Use Linux interface name unless the OS has a different preference
  89 DEFAULT_INTERFACE="\"eth0\""
  90
  91 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
  92
  93 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  94 native_srcdir=$srcdir
  95
  96 OLD_LDFLAGS="$LDFLAGS"
  97 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
  98
  99 # Check system type
 100 AS_CASE(["$host_os"],
 101   [*darwin* | *rhapsody* | *macosx*],[
 102      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 103      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 104      CFLAGS="-fno-common $CFLAGS"
 105      LDFLAGS="$OLD_LDFLAGS"
 106      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 107      AC_CHECK_LIB(intl, gettext)
 108      build_target="darwin"
 109      DEFAULT_INTERFACE="\"en0\""
 110      LIBPREFIX=
 111      DLLDIR=lib
 112      UNIXONLY="#"
 113   ],
 114   [linux*],[
 115      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 116      build_target="linux"
 117      LIBPREFIX=
 118      DLLDIR=lib
 119      UNIXONLY="#"
 120      AC_PATH_XTRA
 121   ],
 122   [*freebsd*],[
 123      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 124      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 125      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 126      build_target="freebsd"
 127      LIBPREFIX=
 128      DLLDIR=lib
 129      UNIXONLY="#"
 130   ],
 131   [*openbsd*],[
 132      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 133      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 134      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 135      build_target="openbsd"
 136      LIBPREFIX=
 137      DLLDIR=lib
 138      UNIXONLY="#"
 139   ],
 140   [*netbsd*],[
 141      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 142      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 143      LIBPREFIX=
 144      DLLDIR=lib
 145      UNIXONLY="#"
 146   ],
 147   [*solaris*],[
 148      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 149      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 150      AC_CHECK_LIB(resolv, res_init)
 151      AC_CHECK_LIB(rt, nanosleep)
 152      build_target="solaris"
 153      LIBPREFIX=
 154      DLLDIR=lib
 155      UNIXONLY="#"
 156   ],
 157   [*arm-linux*],[
 158      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 159      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 160      build_target="linux"
 161      LIBPREFIX=
 162      DLLDIR=lib
 163      UNIXONLY="#"
 164   ],
 165   [*cygwin*],[
 166      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 167      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 168      AC_CHECK_LIB(intl, gettext)
 169      CFLAGS="-mms-bitfields $CFLAGS"
 170      build_target="cygwin"
 171      LIBPREFIX=lib
 172      DLLDIR=bin
 173      AC_PROG_CXX
 174      UNIXONLY=""
 175   ],
 176   [*mingw*],[
 177      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 178      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 179      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 180      AC_CHECK_LIB(intl, gettext)
 181      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 182      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 183      CFLAGS="-mms-bitfields $CFLAGS"
 184      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 185      build_target="mingw"
 186      AC_PROG_CXX
 187      LIBPREFIX=lib
 188      DLLDIR=bin
 189      UNIXONLY=""
 190      funcstocheck=""
 191      native_srcdir=$(cd $srcdir; pwd -W)
 192   ],
 193   [gnu*],[
 194      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 195      build_target="gnu"
 196      UNIXONLY="#"
 197   ],
 198   [
 199      AC_MSG_RESULT(Unrecognised OS $host_os)
 200      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 201      UNIXONLY=""
 202 ])
 203 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 204 AC_SUBST(DEFAULT_INTERFACE)
 205
 206 # Disable TCP-based IPC on systems that support UNIX domain
 207 # sockets in default configuratin:
 208 AC_SUBST(UNIXONLY)
 209
 210
 211 AC_MSG_CHECKING([for build target])
 212 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 213 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 214 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 215 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 216 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 217 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 218 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 219 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 220
 221 AC_MSG_RESULT([$build_target])
 222 AC_SUBST(build_target)
 223 AM_CONDITIONAL([am__fastdepOBJC], false)
 224 AC_UNALIGNED_64_ACCESS
 225
 226 # some other checks for standard libs
 227 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 228 AC_SEARCH_LIBS([memrchr], [],
 229                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 230 AC_SEARCH_LIBS([memset_s], [],
 231                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 232 AC_SEARCH_LIBS([memset_s], [],
 233                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 234 AC_CHECK_LIB(socket, socket)
 235 AC_CHECK_LIB(m, log)
 236 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 237
 238 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 239 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 240
 241 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 242 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 243 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 244 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 245
 246 # autotools' m4 for python has no maximum version!
 247 # python3.4 - python3.7 for tests
 248 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python])
 249 AM_PATH_PYTHON([3.4],, [:])
 250 AC_SUBST([PYTHON])
 251 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 252
 253 # perl
 254 AC_PATH_PROG( PERL, perl, ,
 255               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 256 AC_SUBST([PERL])
 257
 258 # iptables is a soft requirement to run tests
 259 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 260
 261 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 262  [AS_IF([test -x "/sbin/iptables"],
 263    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 264    [AS_IF([test -x "/usr/sbin/iptables"],
 265       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 266
 267 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 268  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 269  [AC_MSG_WARN([warning: 'iptables' not found.])])
 270
 271 # ip6tables is a soft requirement for some features
 272 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 273
 274 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 275   [AS_IF([test -x "/sbin/ip6tables"],
 276      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 277      [AS_IF([test -x "/usr/sbin/ip6tables"],
 278         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 279
 280
 281 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 282   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 283   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 284
 285 # ip is a soft requirement for some features
 286 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 287
 288 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 289  [AS_IF([test -x "/sbin/ip"],
 290    [VAR_IP_BINARY="/sbin/ip"],
 291    [AS_IF([test -x "/usr/sbin/ip"],
 292           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 293
 294 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 295  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 296  [AC_MSG_WARN([warning: 'ip' not found.])])
 297
 298 # locate 'ifconfig'
 299 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 300
 301 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 302 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 303   [AS_IF([test -x "/sbin/ifconfig"],
 304      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 305      [AS_IF([test -x "/usr/sbin/ifconfig"],
 306             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 307
 308 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 309   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 310   [AC_MSG_WARN(['ifconfig' not found.])])
 311
 312
 313 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 314
 315 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 316 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 317       [AS_IF([test -x "/sbin/sysctl"],
 318              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 319              [AS_IF([test -x "/usr/sbin/sysctl"],
 320                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 321 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 322       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 323       [AC_MSG_WARN(['sysctl' not found.])])
 324
 325 # miniupnpc / upnpc binary is a soft runtime requirement
 326 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 327
 328 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 329   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 330   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 331
 332 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 333   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 334      [Define if struct tm has the tm_gmtoff member.])],
 335      ,
 336      [#include <time.h>])
 337
 338 AC_CHECK_DECLS([_stati64])
 339
 340 # 'save' libs; only those libs found so far will be
 341 # linked against _everywhere_.  For the others, we
 342 # will be more selective!
 343 SAVE_LIBS=$LIBS
 344
 345 have_addrinfo_a=0
 346 AC_CHECK_LIB(anl,
 347              getaddrinfo_a,
 348              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 349                                           1,
 350                                           [getaddrinfo_a supported])])
 351 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 352                [test "$have_addrinfo_a" = 1])
 353
 354 # tests only run on Windows
 355 AS_IF([test "x$build_target" = "xmingw"],
 356       [AC_CHECK_LIB(plibc,
 357                     plibc_init,
 358                     [],
 359                     [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 360        AC_CHECK_LIB(gnurx,
 361                     regexec,
 362                     [],
 363                     [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])])
 364
 365 # libgcrypt
 366 gcrypt=0
 367 NEED_LIBGCRYPT_API=1
 368 NEED_LIBGCRYPT_VERSION=1.6.0
 369
 370
 371 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 372 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 373
 374 AS_IF([test $gcrypt = 0],
 375  [
 376   AC_MSG_ERROR([[
 377 ***
 378 *** You need libgcrypt to build this program.
 379 **  This library is for example available at
 380 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 381 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 382 ***  is required.)
 383 ***]])
 384 ])
 385 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 386
 387 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 388
 389
 390
 391 # should the build process be building the documentation?
 392 AC_MSG_CHECKING(whether to build documentation)
 393 AC_ARG_ENABLE([documentation],
 394               [AS_HELP_STRING([--disable-documentation],
 395                               [do not build the documentation])],
 396               [documentation=${enableval}],
 397               [documentation=yes])
 398 AC_MSG_RESULT($documentation)
 399 AS_IF([test "x$documentation" = "xyes"],
 400       [AM_CONDITIONAL([DOCUMENTATION],
 401                       true)
 402        AC_DEFINE([DOCUMENTATION],
 403                  [1],
 404                  [Building the documentation])],
 405       [AM_CONDITIONAL([DOCUMENTATION],
 406                       false)
 407        AC_DEFINE([DOCUMENTATION],
 408                  [0],
 409                  [Not building the documentation])])
 410
 411 # COMMENT: Check wether to transpile texinfo to mdoc.
 412 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 413 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 414 # COMMENT: and makes the configure fail if it is missing.
 415 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 416 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 417 # COMMENT: or nothing was set (this is the default).
 418 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 419 # COMMENT: potential non-existence of the texi2mdoc binary.
 420 # COMMENT: Default return value / setting: no
 421 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 422 AC_ARG_ENABLE([texi2mdoc-generation],
 423               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 424                               [include generated texi2mdoc output in installation])],
 425               [texi2mdoc_generation=${enableval}],
 426               [texi2mdoc_generation=no])
 427 AC_MSG_RESULT($texi2mdoc_generation)
 428 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 429       [AS_IF([test "$texi2mdoc" = 0],
 430              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 431               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your Operating System])
 432               AC_MSG_WARN([ERROR: package manager or from https://mandoc.bsd.lv/texi2mdoc/])],
 433              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 434               AC_DEFINE([TEXI2MDOC_GENERATION],
 435                         [1],
 436                         [Building section 7 mdoc output])])],
 437       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 438                       false)
 439        AC_DEFINE([TEXI2MDOC_GENERATION],
 440                  [0],
 441                  [Not building section 7 mdoc output])])
 442
 443 # should the build process be building only the documentation?
 444 AC_MSG_CHECKING(whether to build only documentation)
 445 AC_ARG_ENABLE([documentation-only],
 446    [AS_HELP_STRING([--enable-documentation-only], [build only the documentation])],
 447    [documentation_only=${enableval}],
 448    [documentation_only=no])
 449 AC_MSG_RESULT($documentation_only)
 450 AS_IF([test "x$documentation_only" = "xyes"],
 451  [
 452   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 453   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 454  ],[
 455   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 456   # TODO: Double negation might be a bit hard to parse for some
 457   # TODO: people reading the output.
 458   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Not building only the documentation])
 459  ])
 460
 461 # should the build process be including the manpages? (default: yes)
 462 AC_MSG_CHECKING(whether to include man pages)
 463 AC_ARG_ENABLE([include-manpages],
 464    [AS_HELP_STRING([--disable-include-manpages], [Do not include the man pages in build and installation])],
 465    [include_manpages=${enableval}],
 466    [include_manpages=yes])
 467 AC_MSG_RESULT($include_manpages)
 468 AS_IF([test "x$include_manpages" = "xyes"],
 469  [
 470   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 471   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 472  ],[
 473   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 474   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 475  ])
 476
 477 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 478 # (not syntax!) to the commandline tools which generate the html. If not,
 479 # texinfo5 switches are used. This comes with no version checks, is
 480 # enabled only at distributors action (ie defaults to "no").
 481 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 482 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 483 AC_ARG_ENABLE([texinfo4],
 484    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 485    [activate_texinfo4=${enableval}],
 486    [activate_texinfo4=no])
 487 AC_MSG_RESULT($activate_texinfo4)
 488 AS_IF([test "x$activate_texinfo4" = "xyes"],
 489  [
 490   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 491   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 492  ],[
 493   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 494   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 495  ])
 496
 497
 498 # Adam shostack suggests the following for Windows:
 499 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 500 AC_ARG_ENABLE(gcc-hardening,
 501    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 502 [AS_IF([test x$enableval = xyes],[
 503     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 504     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 505     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 506     LDFLAGS="$LDFLAGS -pie"
 507  ])])
 508
 509 # Linker hardening options
 510 # Currently these options are ELF specific - you can't use this with MacOSX
 511 AC_ARG_ENABLE(linker-hardening,
 512   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 513 [AS_IF([test x$enableval = xyes],
 514    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 515
 516
 517 AC_ARG_ENABLE(sanitizer,
 518   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 519 [AS_IF([test x$enableval = xyes],[
 520    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 521  ])])
 522
 523
 524 extra_logging=GNUNET_NO
 525 AC_ARG_ENABLE([logging],
 526    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 527    [AS_IF([test "x$enableval" = "xyes"], [],
 528           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 529           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 530           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 531    ], [])
 532 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 533
 534 # should memory poisoning be enabled?
 535 AC_MSG_CHECKING(whether to poison freed memory)
 536 AC_ARG_ENABLE([poisoning],
 537    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 538    [enable_poisoning=${enableval}],
 539    [
 540      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 541        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 542        [enable_poisoning=no])
 543    ])
 544 AC_MSG_RESULT($enable_poisoning)
 545 AS_IF([test ! "x$enable_poisoning" = "xno"],
 546   [enable_poisoning=1],
 547   [enable_poisoning=0])
 548 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 549
 550 AS_IF([test $build = $target],
 551 [
 552 AC_MSG_CHECKING([for working HMAC])
 553 AC_LANG_PUSH(C)
 554 LIBS="$LIBS $LIBGCRYPT_LIBS"
 555 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 556 AC_RUN_IFELSE(
 557   [AC_LANG_PROGRAM([#include <gcrypt.h>
 558         #include <stdio.h>], [[
 559         gcry_md_hd_t mac;
 560
 561         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 562             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 563             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 564         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 565         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 566             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 567             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 568             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 569             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 570             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 571
 572         if (!gcry_check_version (GCRYPT_VERSION))
 573         {
 574           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 575           return 1;
 576         }
 577
 578         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 579         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 580
 581         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 582         {
 583           fprintf (stderr, "gcry_md_open error\n");
 584           return 2;
 585         }
 586
 587         gcry_md_setkey (mac, key, sizeof (key));
 588         gcry_md_write (mac, data, sizeof (data));
 589
 590         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 591         {
 592           fprintf (stderr, "memcmp error\n");
 593           return 3;
 594         }
 595
 596         gcry_md_close (mac);
 597
 598         return 0;
 599     ]])],
 600   [AC_MSG_RESULT([yes])],
 601   [
 602    RESULT=$?
 603    if test $RESULT = 3
 604    then
 605      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 606    fi
 607    if test $RESULT = 2
 608    then
 609      AC_MSG_FAILURE([HMAC test failed])
 610    fi
 611    if test $RESULT = 1
 612    then
 613      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 614    fi
 615   ],
 616   [AC_MSG_RESULT([cross compiling, test skipped])])
 617 AC_LANG_POP(C)
 618 ])      # $build = $target
 619
 620 # check for bluetooth library
 621 bluetooth=0
 622 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 623 AS_IF([test "$build_target" = "mingw"],
 624  [bluetooth=1])
 625 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 626 AS_IF([test "$bluetooth" = 1],
 627  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 628  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 629
 630 # check for zbar library
 631 zbar=0
 632 AC_MSG_CHECKING(for libzbar)
 633 AC_ARG_WITH(zbar,
 634    [  --with-zbar=PREFIX (base of libzbar installation)],
 635    [AC_MSG_RESULT([$with_zbar])
 636     AS_CASE([$with_zbar],
 637       [no],[],
 638       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 639       [
 640         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 641         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 642         AC_CHECK_HEADERS(zbar.h,
 643           AC_CHECK_LIB([zbar], [zbar_processor_create],
 644             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 645             zbar=1))
 646        ])
 647    ],
 648    [AC_MSG_RESULT([--with-zbar not specified])
 649     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 650 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 651 AS_IF([test "x$zbar" = x1],
 652       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 653       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 654
 655 # check for jansson library
 656 jansson=0
 657 AC_MSG_CHECKING(for libjansson)
 658 AC_ARG_WITH(jansson,
 659    [  --with-jansson=PREFIX (base of libjansson installation)],
 660    [AC_MSG_RESULT([$with_jansson])
 661     AS_CASE([$with_jansson],
 662       [no],[],
 663       [yes],[
 664         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 665       ],[
 666         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 667         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 668         AC_CHECK_HEADERS(jansson.h,
 669           AC_CHECK_LIB([jansson], [json_loads],
 670             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 671             jansson=1))
 672       ])
 673    ],
 674    [AC_MSG_RESULT([--with-jansson not specified])
 675     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 676 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 677 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 678 AS_IF([test "x$jansson" = x1],
 679       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 680       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 681
 682
 683 # check for libpulse(audio) library
 684 pulse=0
 685 libpulse_msg="no"
 686 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 687 AS_IF([test "$build_target" = "mingw"],
 688       [pulse=0])
 689 AS_IF([test "$pulse" = 1],
 690       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 691        libpulse_msg="yes"])
 692
 693 # check for libopus(audio) library
 694 opus=0
 695 libopus_msg="no"
 696 CHECK_LIBHEADER(LIBOPUS,
 697                 opus,
 698                 opus_decode_float,
 699                 opus/opus.h,
 700                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 701 AS_IF([test "x$opus" = x1],
 702       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 703        libopus_msg="yes"])
 704
 705 # libogg
 706 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 707         [AC_CHECK_HEADERS([ogg/ogg.h],
 708           AM_CONDITIONAL(HAVE_OGG, true)
 709           ogg=1
 710           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 711           AM_CONDITIONAL(HAVE_OGG, false)
 712           ogg=0
 713           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 714         AM_CONDITIONAL(HAVE_OGG, false)
 715         ogg=0)
 716
 717
 718 PKG_CHECK_MODULES([GLIB],
 719                   [glib-2.0],
 720   [# check for pbc library
 721   pbc=0
 722    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 723    AC_CHECK_HEADER([gabe.h],abe=1)
 724    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 725    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 726    AS_IF([test "x$pbc" = x1],
 727      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 728      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 729    AS_IF([test "x$abe" = x1],
 730     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 731     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 732   [# glib-2 not found
 733    AM_CONDITIONAL(HAVE_PBC, [false])
 734    AM_CONDITIONAL(HAVE_ABE, [false])
 735    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 736
 737 gst=0
 738 gstreamer_msg="no"
 739 PKG_CHECK_MODULES(
 740   [GST],
 741   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 742   [gst=1
 743    gstreamer_msg="yes"],
 744   [gst=0])
 745
 746 # Pulse Audio
 747 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 748  AS_IF([test "x$gst" != "x1"],[
 749   conversation_backend=none
 750   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 751   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 752   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 753  ],[
 754    conversation_backend=gst
 755    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 756    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 757    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 758  ])
 759 ],[
 760  conversation_backend=pulse
 761  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 762  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 763  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 764 ])
 765
 766 # libgnurl
 767 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 768
 769 SAVE_CPPFLAGS=$CPPFLAGS
 770 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 771 LIBS="$LIBGNURL $LIBCURL $LIBS"
 772
 773 # libcurl-gnutls
 774 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 775 AS_IF([test "x$curl" = xtrue],[
 776  AC_CHECK_HEADER([curl/curl.h],
 777   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 778   [curl=false])
 779  # need libcurl-gnutls.so, everything else is not acceptable
 780  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 781  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 782 ])
 783
 784 # libcurl and libgnurl should be mutually exclusive
 785 AS_IF([test "$gnurl" = 1],
 786       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 787        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 788        AM_CONDITIONAL(HAVE_LIBCURL, false)
 789        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 790       [AS_IF([test "$curl" = true],
 791              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 792               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 793               AM_CONDITIONAL(HAVE_LIBCURL, true)
 794               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 795              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 796               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 797               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 798               AM_CONDITIONAL(HAVE_LIBCURL, false)
 799               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 800
 801 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 802 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 803
 804 # restore LIBS & CPPFLAGS
 805 LIBS=$SAVE_LIBS
 806 CPPFLAGS=$SAVE_CPPFLAGS
 807
 808 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 809 # GLPK must support glpk_init_env, version >= 4.43
 810 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 811 # GLPK must support atm MLP presolving, version >= 4.32
 812 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 813 AS_IF([test "x$glpk" = xfalse],
 814 [
 815         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 816         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 817 ],[
 818         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 819         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 820 ])
 821
 822
 823 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 824 AS_IF([test x$nss = xfalse],
 825   [
 826         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 827         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 828   ],[
 829         NSS_INCLUDES="
 830         #include <nss.h>
 831         "
 832         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 833                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 834                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 835                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 836                 [$NSS_INCLUDES])
 837 ])
 838
 839
 840
 841 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 842 AC_CHECK_LIB([kvm],[kvm_open])
 843 AC_CHECK_LIB([kstat],[kstat_open])
 844
 845
 846 # should the build process be restricted to the code required
 847 # for GNU Taler wallets?
 848 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 849 AC_ARG_ENABLE([taler-wallet],
 850    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 851    [taler_only=${enableval}],
 852    [taler_only=no])
 853 AC_MSG_RESULT($taler_only)
 854 AS_IF([test "x$taler_only" = "xyes"],
 855 [
 856   AM_CONDITIONAL([TALER_ONLY],true)
 857   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 858 ],[
 859   AM_CONDITIONAL([TALER_ONLY],false)
 860   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 861 ])
 862
 863 # test for libextractor
 864 extractor=0
 865 AC_MSG_CHECKING(for libextractor)
 866 AC_ARG_WITH(extractor,
 867    [  --with-extractor=PREFIX (base of libextractor installation)],
 868    [AC_MSG_RESULT([$with_extractor])
 869     AS_CASE([$with_extractor],
 870       [no],[],
 871       [yes],[
 872         AC_CHECK_HEADERS([extractor.h],
 873           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 874             extractor=1))
 875       ],[
 876         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 877         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 878         AC_CHECK_HEADERS([extractor.h],
 879           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 880             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 881             extractor=1))
 882       ])
 883    ],
 884    [AC_MSG_RESULT([--with-extractor not specified])
 885     AC_CHECK_HEADERS([extractor.h],
 886      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 887       extractor=1))])
 888 # restore LIBS
 889 LIBS=$SAVE_LIBS
 890
 891 AS_IF([test "$extractor" != 1],
 892  [
 893  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 894  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 895  ],[
 896  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 897  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 898  ])
 899
 900
 901 AS_IF([test "$taler_only" != yes],[
 902
 903
 904 # Check for libltdl header (#2999)
 905 ltdl=0
 906 AC_MSG_CHECKING(for libltdl)
 907 AC_ARG_WITH(ltdl,
 908    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 909    [AC_MSG_RESULT([$with_ltdl])
 910     AS_CASE([$with_ltdl],
 911       [no],[],
 912       [yes],[
 913         AC_CHECK_HEADERS(ltdl.h,
 914           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 915             ltdl=1))
 916       ],[
 917         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 918         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 919         AC_CHECK_HEADERS(ltdl.h,
 920           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 921             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 922             ltdl=1))
 923       ])
 924    ],
 925    [AC_MSG_RESULT([--with-ltdl not specified])
 926     AC_CHECK_HEADERS(ltdl.h,
 927      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 928       ltdl=1))])
 929 AS_IF([test x$ltdl = x1],
 930 [
 931  AC_MSG_RESULT([libltdl found])
 932 ],[
 933  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 934 ])
 935 # restore LIBS
 936 LIBS=$SAVE_LIBS
 937
 938 # libidn and libidn2. The ideal goal is this:
 939 # check for libidn2, if it doesn't exist check for libidn
 940 # if both exist, prefer libidn2
 941 # if none exist, fail and message that libidn or libidn2
 942 # is required with a preference for libidn2.
 943 # TODO: What we have right here can probably be improved.
 944 my_with_libidn=1
 945 AC_ARG_WITH(libidn,
 946             AS_HELP_STRING([--with-libidn=pathname],
 947                            [Support IDN (needs libidn)]),
 948             [],
 949             [withval="yes"])
 950 AS_IF([test x_$withval = x_yes],
 951       [AC_CHECK_HEADERS([idna.h],
 952           AC_MSG_NOTICE([Found idna.h]),
 953           AC_CHECK_HEADERS([idn/idna.h],
 954                AC_MSG_NOTICE([Found idn/idna.h]),
 955                my_with_libidn=0))],
 956       [AS_IF([test x_$withval != x_no],
 957              [CFLAGS="$CFLAGS -I$withval/include"
 958               LDFLAGS="$LDFLAGS -L$withval/lib"
 959               AC_CHECK_HEADERS([idna.h],
 960                 AC_MSG_NOTICE([Found idna.h]),
 961                 [AC_MSG_NOTICE([Failed to find idna.h])
 962                  my_with_libidn=0])],
 963              [my_with_libidn=0])])
 964
 965 my_with_libidn2=1
 966 AC_ARG_WITH(libidn2,
 967             AS_HELP_STRING([--with-libidn2=pathname],
 968                            [Support IDN (needs libidn2)]),
 969             [],
 970             [withval="yes"])
 971 AS_IF([test x_$withval = x_yes],
 972       [AC_CHECK_HEADERS([idn2.h],
 973        AC_MSG_NOTICE([Found idn2.h]),
 974        AC_CHECK_HEADERS([idn2/idn2.h],
 975           AC_MSG_NOTICE([Found idn2/idn2.h]),
 976           [AC_MSG_NOTICE([Failed to find idn2.h])
 977            my_with_libidn2=0]))],
 978       [AS_IF([test x_$withval != x_no],
 979              [CFLAGS="$CFLAGS -I$withval/include"
 980               LDFLAGS="$LDFLAGS -L$withval/lib"],
 981              [my_with_libidn2=0])])
 982
 983 AC_MSG_CHECKING([if libidn can be used])
 984 # Check for LIBIDNs
 985 there_can_only_be_one=1
 986
 987 working_libidn1=0
 988 working_libidn2=0
 989 AS_IF([test x$my_with_libidn2 = x1],
 990       [AC_MSG_NOTICE([Checking for libidn2])
 991        AC_CHECK_LIB([idn2],
 992                     [idn2_to_unicode_8z8z],
 993                     [working_libidn2=1
 994                     LIBS="-lidn2 $LIBS"
 995                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 996                                        [1],
 997                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 998                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 999                      MISSING_SEP=", "])])
1000 AM_CONDITIONAL(HAVE_LIBIDN2,
1001                test x$working_libidn2 = x1)
1002 AS_IF([test x$working_libidn2 = x0],
1003       [AS_IF([test x$my_with_libidn = x1],
1004              [AC_MSG_NOTICE([Checking for libidn])
1005               AC_CHECK_LIB([idn],
1006                            [idna_to_ascii_8z],
1007                            [working_libidn1=1
1008                            LIBS="-lidn $LIBS"
1009                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1010                                               [1],
1011                                               [Define to 1 if you have 'libidn' (-lidn).])],
1012                            [there_can_only_be_one=0])],
1013              [AS_IF([test x$my_with_libidn2 = x1],
1014                     [there_can_only_be_one=0
1015                      AC_MSG_FAILURE([* There can only be one libidn.
1016                                      * Provide either libidn >= 1.13
1017                                      * or
1018                                      * libidn2 to the configure
1019                                      * script via
1020                                      * --with-libidn2
1021                                      * --with-libidn])])])])
1022 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1023
1024 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1025       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1026
1027 AS_IF([test x$there_can_only_be_one = x0],
1028       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1029
1030 # test for zlib
1031 SAVE_LDFLAGS=$LDFLAGS
1032 SAVE_CPPFLAGS=$CPPFLAGS
1033 AC_ARG_WITH(zlib,
1034             [  --with-zlib[[=DIR]]       use libz in DIR],
1035             [AS_IF([test "$withval" = "no"],
1036                    [AC_MSG_ERROR([GNUnet requires zlib])],
1037                    [test "$withval" != "yes"],
1038                    [Z_DIR=$withval
1039                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1040                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1041 AC_CHECK_HEADER(zlib.h,
1042                 [],
1043                 [AC_MSG_ERROR([GNUnet requires zlib])])
1044 AC_CHECK_LIB(z,
1045              compress2,
1046              [AC_DEFINE([HAVE_ZLIB],
1047                         [],
1048                         [Have compression library])
1049               if test "x${Z_DIR}" != "x"; then
1050                       Z_CFLAGS="-I${Z_DIR}/include"
1051                       Z_LIBS="-L${Z_DIR}/lib -lz"
1052               else
1053                       Z_LIBS="-lz"
1054               fi],
1055               [AC_MSG_ERROR([GNUnet requires zlib])])
1056 AC_SUBST(Z_CFLAGS)
1057 AC_SUBST(Z_LIBS)
1058
1059 AS_IF([test "$enable_shared" = "no"],
1060       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1061
1062
1063 # restore LIBS
1064 LIBS=$SAVE_LIBS
1065
1066
1067 # end of taler-only being false
1068 ])
1069
1070
1071 # check for iconv
1072 AM_ICONV
1073
1074 # test for libunistring
1075 gl_LIBUNISTRING
1076 AS_IF([test $HAVE_LIBUNISTRING != yes],
1077       [AC_MSG_ERROR([GNUnet requires libunistring])])
1078
1079 # under emscripten, $gl_libunistring_hexversion is undefined
1080 if test "$taler_only" != yes; then
1081
1082 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1083       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1084 fi
1085 AC_CHECK_HEADERS([unistr.h],
1086                  ,
1087                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1088
1089 # restore LIBS
1090 LIBS=$SAVE_LIBS
1091
1092
1093
1094 # Checks for standard header files.
1095 AC_HEADER_DIRENT
1096 AC_HEADER_STDC
1097
1098 # Check for headers that are ALWAYS required
1099 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1100
1101
1102
1103 # Checks for headers that are only required on some systems or
1104 # opional (and where we do NOT abort if they are not there)
1105 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1106
1107 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1108 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1109 [#ifdef HAVE_SYS_TYPES_H
1110 #include <sys/types.h>
1111 #endif
1112 #ifdef HAVE_NETINET_IN_SYSTM_H
1113 #include <netinet/in_systm.h>
1114 #endif
1115 #ifdef HAVE_NETINET_IN_H
1116 #include <netinet/in.h>
1117 #endif
1118 ])
1119
1120 SAVE_LDFLAGS=$LDFLAGS
1121 SAVE_CPPFLAGS=$CPPFLAGS
1122
1123 # test for sqlite
1124 sqlite=false
1125 AC_MSG_CHECKING(for SQLite)
1126 AC_ARG_WITH(sqlite,
1127   [  --with-sqlite=PFX       base of SQLite installation],
1128   [AC_MSG_RESULT("$with_sqlite")
1129    AS_CASE([$with_sqlite],
1130      [no],[],
1131      [yes],[
1132       AC_CHECK_HEADERS(sqlite3.h,
1133       sqlite=true)],
1134      [
1135     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1136     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1137     AC_CHECK_HEADERS(sqlite3.h,
1138      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1139      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1140      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1141      sqlite=true)
1142     LDFLAGS=$SAVE_LDFLAGS
1143     CPPFLAGS=$SAVE_CPPFLAGS
1144     ])
1145   ],
1146   [AC_MSG_RESULT([--with-sqlite not specified])
1147     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1148 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1149 AC_SUBST(SQLITE_CPPFLAGS)
1150 AC_SUBST(SQLITE_LDFLAGS)
1151
1152 LDFLAGS=$SAVE_LDFLAGS
1153 CPPFLAGS=$SAVE_CPPFLAGS
1154
1155 # test for postgres
1156 postgres=false
1157 # even running the check for postgres breaks emscripten ...
1158 AS_IF([test "$taler_only" != yes],
1159       [AX_LIB_POSTGRESQL([9.5],
1160         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1161          AC_CHECK_HEADERS([libpq-fe.h],
1162          postgres=true)
1163         ],
1164         [AC_MSG_RESULT([no postgres])])])
1165 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1166
1167
1168 LDFLAGS=$SAVE_LDFLAGS
1169 CPPFLAGS=$SAVE_CPPFLAGS
1170
1171 # mysql & windows
1172 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1173 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1174
1175 AS_IF([test "$build_target" = "mingw"]
1176  [CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"])
1177
1178 # test for mysql
1179 mysql=false
1180 mysqlfail=false
1181 SAVE_LDFLAGS=$LDFLAGS
1182 SAVE_CPPFLAGS=$CPPFLAGS
1183 AC_MSG_CHECKING(for mysql)
1184 AC_ARG_WITH(mysql,
1185   [  --with-mysql=PFX        base of MySQL installation],
1186   [AC_MSG_RESULT([$with_mysql])
1187    AS_CASE([$with_mysql],
1188      [no],[],
1189      [yes|""],[
1190       AC_CHECK_HEADERS(mysql/mysql.h,
1191        AC_CHECK_LIB(mysqlclient, mysql_init,
1192        mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1193      ],[
1194       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1195       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1196       AC_CHECK_HEADERS(mysql/mysql.h,
1197        AC_CHECK_LIB(mysqlclient, mysql_init,
1198         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1199         MYSQL_CPPFLAGS="-I$with_mysql/include"
1200
1201         mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
1202      ])
1203   ],
1204   [AC_MSG_RESULT([--with-mysql not specified])
1205    if test -d "/usr/lib64/mysql"; then
1206     MYSQL_LIBDIR="/usr/lib64/mysql"
1207    elif test -d "/usr/lib/mysql"; then
1208     MYSQL_LIBDIR="/usr/lib/mysql"
1209    else
1210     MYSQL_LIBDIR="/usr/lib"
1211    fi
1212    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1213    AC_CHECK_LIB(mysqlclient, mysql_init,
1214     [AC_CHECK_HEADERS(mysql/mysql.h,
1215       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1216       mysql=true
1217
1218      , [], [$CYGWIN_MYSQL_MAGIC])])
1219   ])
1220
1221 AC_SUBST(MYSQL_LDFLAGS)
1222 AC_SUBST(MYSQL_CPPFLAGS)
1223
1224 # additional version check for mysql
1225 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1226 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1227  [
1228   AC_MSG_CHECKING(mysql version)
1229   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1230     [[$CYGWIN_MYSQL_MAGIC
1231       #include <mysql/mysql.h>]],
1232     [[
1233       #if (MYSQL_VERSION_ID < 40100)
1234       #error needs at least version >= 4.1
1235       #endif
1236       int main () { return 0; }
1237     ]])
1238     ],mysql=true,mysql=false)
1239   AS_IF([test "$mysql" = "false"],
1240    [
1241     mysqlfail=true
1242     AC_MSG_RESULT([fail, >= 4.1 required])
1243    ],[
1244     AC_MSG_RESULT(ok)
1245    ])
1246 ])
1247 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1248 AM_CONDITIONAL(HAVE_MYSQLE, false)
1249 # restore LIBS
1250 LIBS=$SAVE_LIBS
1251 LDFLAGS=$SAVE_LDFLAGS
1252 CPPFLAGS=$SAVE_CPPFLAGS
1253
1254 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1255 [
1256  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1257 ])
1258
1259 # libmicrohttpd
1260 lmhd=0
1261 AC_MSG_CHECKING([for libmicrohttpd])
1262 AC_ARG_WITH(microhttpd,
1263    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
1264    [AC_MSG_RESULT([$with_microhttpd])
1265     AS_CASE([$with_microhttpd],
1266       [no],[],
1267       [yes|""],[
1268         AC_CHECK_HEADERS([microhttpd.h],
1269           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1270             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1271               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.63])
1272               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1273                 #include "$native_srcdir/src/include/platform.h"
1274                 #include <microhttpd.h>
1275                 #if (MHD_VERSION < 0x0096300)
1276                 #error needs at least version 0.9.63
1277                 #endif
1278                 int main () { return 0; }
1279                ])],
1280                [AC_MSG_RESULT(ok)
1281                 lmhd=1],
1282                [AC_MSG_RESULT(failed)])]),
1283             [],[#include "$native_srcdir/src/include/platform.h"
1284                 #include <microhttpd.h>]),,
1285             [#include "$native_srcdir/src/include/platform.h"])
1286       ],[
1287         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
1288         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
1289         AC_CHECK_HEADERS(microhttpd.h,
1290           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1291             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1292               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
1293               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1294                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1295                 #include "$native_srcdir/src/include/platform.h"
1296                 #include <microhttpd.h>
1297                 #if (MHD_VERSION < 0x0094200)
1298                 #error needs at least version 0.9.42
1299                 #endif
1300                 int main () { return 0; }
1301                ])],
1302                [AC_MSG_RESULT(ok)
1303                 lmhd=1],
1304                [AC_MSG_RESULT(failed)])]),
1305             [],[#include "$native_srcdir/src/include/platform.h"
1306                 #include <microhttpd.h>]),,
1307             [#include "$native_srcdir/src/include/platform.h"])
1308        ])
1309    ],
1310    [AC_MSG_RESULT([--with-microhttpd not specified])
1311     AC_CHECK_HEADERS([microhttpd.h],
1312       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1313         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1314           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.52])
1315               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1316                 #include "$native_srcdir/src/include/platform.h"
1317                 #include <microhttpd.h>
1318                 #if (MHD_VERSION < 0x0094200)
1319                 #error needs at least version 0.9.52
1320                 #endif
1321                ])],
1322                [AC_MSG_RESULT(ok)
1323                 lmhd=1],
1324                [AC_MSG_RESULT(failed)])]),
1325         [],[#include "$native_srcdir/src/include/platform.h"
1326             #include <microhttpd.h>]),,
1327        [#include "$native_srcdir/src/include/platform.h"])])
1328 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1329 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1330
1331 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1332
1333 # restore LIBS
1334 LIBS=$SAVE_LIBS
1335
1336 # check for gettext
1337 AM_GNU_GETTEXT([external])
1338 AM_GNU_GETTEXT_VERSION([0.18.1])
1339
1340 # Checks for standard typedefs, structures, and compiler characteristics.
1341 AC_TYPE_PID_T
1342 AC_TYPE_SIZE_T
1343 AC_TYPE_MODE_T
1344 AC_HEADER_TIME
1345 AC_HEADER_STAT
1346 AC_HEADER_STDBOOL
1347 AC_STRUCT_TM
1348
1349 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1350    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1351    ],
1352    [],
1353    [
1354       #include <sys/types.h>
1355       #include <sys/socket.h>
1356       #include <netinet/in.h>
1357    ])
1358
1359 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1360                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1361                             1,
1362                             [Do we have sockaddr_un.sun_len?])],
1363                 [],
1364                 [
1365                 #include <sys/types.h>
1366                 #include <sys/socket.h>
1367                 #include <sys/un.h>
1368                 ])
1369
1370
1371
1372 # Checks for library functions.
1373 AC_FUNC_CLOSEDIR_VOID
1374 AC_FUNC_FORK
1375 AC_PROG_GCC_TRADITIONAL
1376 AC_FUNC_MEMCMP
1377 AC_FUNC_SELECT_ARGTYPES
1378 AC_FUNC_CHOWN
1379
1380 AC_TYPE_SIGNAL
1381 AC_FUNC_STAT
1382 AC_FUNC_STRFTIME
1383 AC_FUNC_VPRINTF
1384 AC_HEADER_SYS_WAIT
1385 AC_TYPE_OFF_T
1386 AC_TYPE_UID_T
1387 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1388
1389 # restore LIBS
1390 LIBS=$SAVE_LIBS
1391
1392 GN_INTLINCL=""
1393 GN_LIBINTL="$LTLIBINTL"
1394 AC_ARG_ENABLE(framework,
1395               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1396               enable_framework_build=$enableval)
1397 AM_CONDITIONAL(WANT_FRAMEWORK,
1398                test x$enable_framework_build = xyes)
1399 AS_IF([test x$enable_framework_build = xyes],
1400       [AC_DEFINE([FRAMEWORK_BUILD],
1401                  1,
1402                  [Build a Mac OS X Framework])
1403       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1404       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1405       AC_LIB_APPENDTOVAR([CPPFLAGS],
1406                          [$GN_INTLINCL])])
1407
1408 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1409 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1410
1411 AC_SUBST(GN_LIB_LDFLAGS)
1412 AC_SUBST(GN_PLUGIN_LDFLAGS)
1413 AC_SUBST(GN_INTLINCL)
1414 AC_SUBST(GN_LIBINTL)
1415
1416 AC_SUBST(CPPFLAGS)
1417 AC_SUBST(LIBS)
1418 AC_SUBST(LDFLAGS)
1419 AC_SUBST(EXT_LIB_PATH)
1420 AC_SUBST(EXT_LIBS)
1421
1422 AC_SUBST(LIBPREFIX)
1423 AC_SUBST(DLLDIR)
1424 AC_SUBST(EXT_LIB_PATH)
1425
1426 DATAROOTDIR=$datarootdir
1427 AC_SUBST(DATAROOTDIR)
1428
1429 # test for sudo
1430 # TODO: do we need to change anything for "doas" on openbsd?
1431 AC_MSG_CHECKING(for sudo)
1432 AC_ARG_WITH(sudo,
1433             [  --with-sudo=PATH       path to sudo binary (or just yes)],
1434             [AC_MSG_RESULT("$with_sudo")
1435              AS_CASE([$with_sudo],
1436                      [no],[SUDO_BINARY=],
1437                      [yes],[SUDO_BINARY=sudo],
1438                      [SUDO_BINARY=$with_sudo])],
1439             [AC_MSG_RESULT([no])])
1440 AC_SUBST(SUDO_BINARY)
1441 AM_CONDITIONAL([HAVE_SUDO],
1442                [test "x$SUDO_BINARY" != "x" -o -w /])
1443
1444
1445 # test for gnunetdns group name
1446 GNUNETDNS_GROUP=gnunetdns
1447 AC_MSG_CHECKING(for gnunetdns group name)
1448 AC_ARG_WITH(gnunetdns,
1449             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1450             [AC_MSG_RESULT("$with_gnunetdns")
1451              AS_CASE([$with_gnunetdns],
1452                      [no],[GNUNETDNS_GROUP=gnunet],
1453                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1454                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1455             [AC_MSG_RESULT([gnunetdns])])
1456 AC_SUBST(GNUNETDNS_GROUP)
1457
1458
1459
1460 # gnutls
1461 gnutls=0
1462 gnutls_dane=0
1463 AC_MSG_CHECKING(for gnutls)
1464 AC_ARG_WITH(gnutls,
1465             [  --with-gnutls=PFX   base of gnutls installation],
1466             [AC_MSG_RESULT([$with_gnutls])
1467              AS_CASE([$with_gnutls],
1468                      [no],[],
1469                      [yes],
1470                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1471                                        AC_CHECK_LIB([gnutls],
1472                                                     [gnutls_priority_set],
1473                                                     gnutls=true))
1474                       AC_CHECK_HEADERS([gnutls/dane.h],
1475                                        AC_CHECK_LIB([gnutls-dane],
1476                                                     [dane_verify_crt_raw],
1477                                                     gnutls_dane=1))],
1478
1479         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1480         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1481         AC_CHECK_HEADERS([gnutls/abstract.h],
1482             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1483               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1484               gnutls=true))
1485         AC_CHECK_HEADERS([gnutls/dane.h],
1486             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1487               gnutls_dane=1))
1488       ])
1489    ],
1490    [AC_MSG_RESULT([--with-gnutls not specified])
1491     AC_CHECK_HEADERS([gnutls/abstract.h],
1492         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1493           gnutls=true))
1494     AC_CHECK_HEADERS([gnutls/dane.h],
1495         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1496                      gnutls_dane=1))
1497    ])
1498 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1499 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1500 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1501 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1502
1503
1504
1505 # Test if we are building for superMUC
1506 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1507 AC_ARG_ENABLE([supermuc],
1508     [AS_HELP_STRING([--enable-supermuc],
1509        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1510     [AS_IF([test "x$enable_supermuc" = "xno"],
1511       [supermuc=0],
1512       [supermuc=1])],
1513     [supermuc=0
1514      enable_supermuc=no])
1515 AC_MSG_RESULT($enable_SUPERMUC)
1516 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1517 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1518
1519 # Check if NSE has to send timestamp information to testbed logger for
1520 # generating histogram of messages received
1521 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1522 AC_ARG_ENABLE([nse-histogram],
1523     [AS_HELP_STRING([--enable-nse-histogram],
1524        [have NSE send timestamp information to testbed logger for generating
1525        histogram of received messages.  NOT useful for production (default is
1526        NO)])],
1527     [AS_IF([test "x$enableval" = "xno"],
1528       [nse_histogram=0],
1529       [nse_histogram=1])],
1530     [nse_histogram=0
1531      enable_nse_histogram=no])
1532 AC_MSG_RESULT($enable_nse_histogram)
1533 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1534 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1535                    [have NSE send timestamp information to testbed logger])
1536
1537 # should 'make check' run tests?
1538 AC_MSG_CHECKING(whether to run tests)
1539 AC_ARG_ENABLE([testruns],
1540    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1541    [enable_tests_run=${enableval}],
1542    [enable_tests_run=yes])
1543 AC_MSG_RESULT($enable_test_run)
1544 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1545
1546
1547 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1548 AC_ARG_ENABLE([benchmark],
1549    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1550    [enable_benchmark=${enableval}],
1551    [enable_benchmark=no])
1552 AC_MSG_RESULT($enable_benchmark)
1553 AS_IF([test "x$enable_benchmark" = "xyes"],
1554       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1555 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1556
1557
1558 # should expensive tests be run?
1559 AC_MSG_CHECKING(whether to run expensive tests)
1560 AC_ARG_ENABLE([expensivetests],
1561    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1562    [enable_expensive=${enableval}],
1563    [enable_expensive=no])
1564 AC_MSG_RESULT($enable_expensive)
1565 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1566
1567 # should ports be open for Java services?
1568 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1569 AC_ARG_ENABLE([javaports],
1570    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1571    [enable_java_ports=${enableval}],
1572    [enable_java_ports=no])
1573 AC_MSG_RESULT($enable_java_ports)
1574 AS_IF([test "x$enable_java_ports" = "xyes"],
1575  [JAVAPORT=""],
1576  [JAVAPORT="$UNIXONLY"])
1577 AC_SUBST(JAVAPORT)
1578
1579 # should benchmarks be run?
1580 AC_MSG_CHECKING(whether to run benchmarks during make check)
1581 AC_ARG_ENABLE([benchmarks],
1582    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1583    [enable_benchmarks=${enableval}],
1584    [enable_benchmarks=no])
1585 AC_MSG_RESULT($enable_benchmarks)
1586 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1587
1588 # should gnunet-testing be compiled
1589 AC_MSG_CHECKING(wether to compile gnunet-testing)
1590 AC_ARG_ENABLE([testing],
1591    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1592    [enable_testing=${enableval}],
1593    [enable_testing=yes])
1594 AC_MSG_RESULT($enable_testing)
1595 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1596
1597 # should experimental code be compiled (code that may not yet compile)?
1598 AC_MSG_CHECKING(whether to compile experimental code)
1599 AC_ARG_ENABLE([experimental],
1600    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1601    [enable_experimental=${enableval}],
1602    [enable_experimental=no])
1603 AC_MSG_RESULT($enable_experimental)
1604 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1605
1606 # should malicious code be compiled (should only be used for testing)?
1607 AC_MSG_CHECKING(whether to compile malicious code)
1608 AC_ARG_ENABLE([malicious],
1609    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1610    [AS_IF([test "x$enableval" = "xno"],
1611      [malicious=0],
1612      [malicious=1])],
1613    [malicious=0
1614     enable_malicious=no])
1615 AC_MSG_RESULT($enable_malicious)
1616 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1617 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1618                    [enable compilation of malicious code])
1619
1620 # should services be started on demand when needed?
1621 # Some services may choose to never start by default
1622 # and it is up to the service/module developer to decide
1623 # by having "START_ON_DEMAND = NO" instead of
1624 # "START_ON_DEMAND = @START_ON_DEMAND@"
1625 # in the service/module's conf.in file.
1626 # See also IMMEDIATE_START for an unconditional immediate start.
1627 START_ON_DEMAND="YES"
1628 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1629 AC_ARG_ENABLE([autostart],
1630    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1631    [enable_autostart=${enableval}
1632     AS_IF([test "x$enable_autostart" = "xno"],
1633       [START_ON_DEMAND="NO"])
1634    ],
1635    [enable_autostart=yes])
1636 AC_MSG_RESULT($enable_autostart)
1637 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1638 AC_SUBST(START_ON_DEMAND)
1639
1640 # should memory statistics be kept (very expensive CPU-wise!)
1641 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1642 AC_ARG_ENABLE([heapstats],
1643    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1644    [enable_heapstats=1],
1645    [enable_heapstats=0])
1646 AC_MSG_RESULT($enable_heapstats)
1647 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1648
1649 # should code be enabled that works around missing OS functionality on Windows?
1650 # used for test cases
1651 if test $build_target = "mingw"
1652 then
1653         workarounds=1
1654
1655 AC_LINK_IFELSE(
1656  [AC_LANG_PROGRAM(
1657   [#include <ws2tcpip.h>
1658   ],[
1659   int s = socket (0, 0, 0);])
1660  ],[
1661   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1662  ],[
1663   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1664  ])
1665
1666 AC_LINK_IFELSE(
1667  [AC_LANG_PROGRAM(
1668   [#include <ws2tcpip.h>
1669   ],[
1670   int s = select (0, NULL, NULL, NULL, NULL);])
1671  ],[
1672   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1673  ],[
1674   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1675  ])
1676
1677 AC_LINK_IFELSE(
1678  [AC_LANG_PROGRAM(
1679   [#include <ws2tcpip.h>
1680   ],[
1681   struct in_addr i;
1682   char *s = inet_ntoa (i);])
1683  ],[
1684   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1685  ],[
1686   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1687  ])
1688
1689 AC_LINK_IFELSE(
1690  [AC_LANG_PROGRAM(
1691   [#include <ws2tcpip.h>
1692   ],[
1693   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1694  ],[
1695   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1696  ],[
1697   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1698  ])
1699
1700 AC_LINK_IFELSE(
1701  [AC_LANG_PROGRAM(
1702   [#include <ws2tcpip.h>
1703   ],[
1704   int s = gethostname (NULL, 0);])
1705  ],[
1706   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1707  ],[
1708   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1709  ])
1710
1711 AC_LINK_IFELSE(
1712  [AC_LANG_PROGRAM(
1713   [#include <ws2tcpip.h>
1714   ],[
1715   void *s = gethostbyname (NULL);])
1716  ],[
1717   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1718  ],[
1719   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1720  ])
1721
1722 AC_LINK_IFELSE(
1723  [AC_LANG_PROGRAM(
1724   [#include <ws2tcpip.h>
1725   ],[
1726   void *s = gethostbyaddr (NULL, 0, 0);])
1727  ],[
1728   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1729  ],[
1730   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1731  ])
1732
1733 AC_LINK_IFELSE(
1734  [AC_LANG_PROGRAM(
1735   [#include <ws2tcpip.h>
1736   ],[
1737   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1738  ],[
1739   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1740  ],[
1741   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],0,[Define this if getaddrinfo() is available])
1742  ])
1743
1744 else
1745   AC_MSG_CHECKING(whether to enable windows workarounds)
1746   AC_ARG_ENABLE([windows_workarounds],
1747      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1748      [enable_workarounds=${enableval}],
1749      [enable_workarounds=no])
1750   AC_MSG_RESULT($enable_workarounds)
1751   AS_IF([test x$enable_windows_workarounds = "xyes"],
1752     [workarounds=1],
1753     [workarounds=0])
1754 fi
1755 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1756
1757
1758 # Check if the __thread storage class for
1759 # thread-local storage is available.
1760 AC_MSG_CHECKING(whether __thread is supported)
1761 AC_LINK_IFELSE(
1762 [AC_LANG_PROGRAM([#include <stdlib.h>
1763                    #undef __thread
1764                    static __thread int a = 1;],
1765                   [exit(a-1);])],
1766  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1767 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1768 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1769       [AC_MSG_RESULT(yes)],
1770       [AC_MSG_RESULT(no)])
1771
1772 # gcov compilation
1773 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1774 AC_ARG_ENABLE([coverage],
1775               AS_HELP_STRING([--enable-coverage],
1776                              [compile the library with code coverage support]),
1777               [use_gcov=${enableval}],
1778               [use_gcov=no])
1779 AC_MSG_RESULT($use_gcov)
1780 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1781
1782
1783 # version info
1784 # TODO: git blame says this predates our switch to git.
1785 # git-svn should be adjusted to simply git, or
1786 # an external script that does the job.
1787 AC_PATH_PROG(svnversioncommand, svnversion)
1788 AC_PATH_PROG(gitcommand, git)
1789 AC_MSG_CHECKING(for source being under a VCS)
1790
1791
1792 # version info
1793 AC_PATH_PROG(gitcommand, git)
1794 AC_MSG_CHECKING(for source being under a VCS)
1795 git_version=
1796 AS_IF([test ! "X$gitcommand" = "X"],
1797 [
1798   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1799 ])
1800 AS_IF([test "X$git_version" = "X"],
1801   [
1802     vcs_name="no"
1803     vcs_version="\"release\""
1804   ],
1805   [
1806     vcs_name="yes, git-svn"
1807     vcs_version="\"git-$git_version\""
1808   ])
1809 AC_MSG_RESULT($vcs_name)
1810
1811 AC_MSG_CHECKING(VCS version)
1812 AC_MSG_RESULT($vcs_version)
1813 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1814
1815 AC_CONFIG_FILES([
1816 Makefile
1817 contrib/Makefile
1818 contrib/hellos/Makefile
1819 contrib/services/Makefile
1820 contrib/services/openrc/Makefile
1821 contrib/services/systemd/Makefile
1822 contrib/scripts/Makefile
1823 contrib/scripts/gnunet-logread/Makefile
1824 doc/Makefile
1825 doc/man/Makefile
1826 doc/doxygen/Makefile
1827 doc/handbook/Makefile
1828 doc/tutorial/Makefile
1829 lint/Makefile
1830 m4/Makefile
1831 po/Makefile.in
1832 src/Makefile
1833 src/arm/Makefile
1834 src/arm/arm.conf
1835 src/ats/Makefile
1836 src/ats/ats.conf
1837 src/ats-tool/Makefile
1838 src/ats-tests/Makefile
1839 src/auction/Makefile
1840 src/block/Makefile
1841 src/cadet/Makefile
1842 src/cadet/cadet.conf
1843 src/core/Makefile
1844 src/core/core.conf
1845 src/consensus/Makefile
1846 src/consensus/consensus.conf
1847 src/conversation/Makefile
1848 src/conversation/conversation.conf
1849 src/curl/Makefile
1850 src/datacache/Makefile
1851 src/datastore/Makefile
1852 src/datastore/datastore.conf
1853 src/dht/Makefile
1854 src/dht/dht.conf
1855 src/dns/Makefile
1856 src/dns/dns.conf
1857 src/exit/Makefile
1858 src/fragmentation/Makefile
1859 src/fs/Makefile
1860 src/fs/fs.conf
1861 src/gns/Makefile
1862 src/gns/gns.conf
1863 src/gns/nss/Makefile
1864 src/gnsrecord/Makefile
1865 src/hello/Makefile
1866 src/identity/Makefile
1867 src/identity/identity.conf
1868 src/credential/Makefile
1869 src/credential/credential.conf
1870 src/include/Makefile
1871 src/integration-tests/Makefile
1872 src/json/Makefile
1873 src/hostlist/Makefile
1874 src/my/Makefile
1875 src/mysql/Makefile
1876 src/namecache/Makefile
1877 src/namecache/namecache.conf
1878 src/namestore/Makefile
1879 src/namestore/namestore.conf
1880 src/nat/Makefile
1881 src/nat/nat.conf
1882 src/nat-auto/Makefile
1883 src/nat-auto/nat-auto.conf
1884 src/nse/Makefile
1885 src/nse/nse.conf
1886 src/nt/Makefile
1887 src/peerinfo/Makefile
1888 src/peerinfo/peerinfo.conf
1889 src/peerinfo-tool/Makefile
1890 src/peerstore/Makefile
1891 src/peerstore/peerstore.conf
1892 src/pq/Makefile
1893 src/pt/Makefile
1894 src/regex/Makefile
1895 src/regex/regex.conf
1896 src/revocation/Makefile
1897 src/revocation/revocation.conf
1898 src/rps/Makefile
1899 src/rps/rps.conf
1900 src/secretsharing/Makefile
1901 src/secretsharing/secretsharing.conf
1902 src/scalarproduct/Makefile
1903 src/scalarproduct/scalarproduct.conf
1904 src/set/Makefile
1905 src/set/set.conf
1906 src/sq/Makefile
1907 src/statistics/Makefile
1908 src/statistics/statistics.conf
1909 src/template/Makefile
1910 src/testbed/Makefile
1911 src/testbed/testbed.conf
1912 src/testbed-logger/Makefile
1913 src/testbed-logger/testbed-logger.conf
1914 src/testing/Makefile
1915 src/topology/Makefile
1916 src/transport/Makefile
1917 src/transport/transport.conf
1918 src/util/Makefile
1919 src/util/resolver.conf
1920 src/vpn/Makefile
1921 src/vpn/vpn.conf
1922 src/zonemaster/Makefile
1923 src/zonemaster/zonemaster.conf
1924 src/rest/Makefile
1925 src/abe/Makefile
1926 src/reclaim-attribute/Makefile
1927 src/reclaim/Makefile
1928 pkgconfig/Makefile
1929 pkgconfig/gnunetarm.pc
1930 pkgconfig/gnunetats.pc
1931 pkgconfig/gnunetblock.pc
1932 pkgconfig/gnunetcadet.pc
1933 pkgconfig/gnunetconsensus.pc
1934 pkgconfig/gnunetconversation.pc
1935 pkgconfig/gnunetcore.pc
1936 pkgconfig/gnunetdatacache.pc
1937 pkgconfig/gnunetdatastore.pc
1938 pkgconfig/gnunetdht.pc
1939 pkgconfig/gnunetdns.pc
1940 pkgconfig/gnunetenv.pc
1941 pkgconfig/gnunetfragmentation.pc
1942 pkgconfig/gnunetfs.pc
1943 pkgconfig/gnunetgns.pc
1944 pkgconfig/gnunethello.pc
1945 pkgconfig/gnunetidentity.pc
1946 pkgconfig/gnunetmicrophone.pc
1947 pkgconfig/gnunetmysql.pc
1948 pkgconfig/gnunetnamestore.pc
1949 pkgconfig/gnunetnat.pc
1950 pkgconfig/gnunetnse.pc
1951 pkgconfig/gnunetpeerinfo.pc
1952 pkgconfig/gnunetpq.pc
1953 pkgconfig/gnunetregex.pc
1954 pkgconfig/gnunetrevocation.pc
1955 pkgconfig/gnunetrps.pc
1956 pkgconfig/gnunetscalarproduct.pc
1957 pkgconfig/gnunetset.pc
1958 pkgconfig/gnunetspeaker.pc
1959 pkgconfig/gnunetstatistics.pc
1960 pkgconfig/gnunettestbed.pc
1961 pkgconfig/gnunettesting.pc
1962 pkgconfig/gnunettransport.pc
1963 pkgconfig/gnunetutil.pc
1964 pkgconfig/gnunetvpn.pc
1965 ])
1966 AC_OUTPUT
1967
1968
1969 # FIXME: `some modules' -> be more specific which exact modules.
1970
1971 # java ports
1972 AS_IF([test "x$enable_java_ports" = "xyes"],
1973       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1974
1975 ####
1976 #### Lasciate ogne speranza, voi ch'intrate
1977 ####
1978 #### This could be moved to the checks above,
1979 #### but for now let's keep it here.
1980 ####
1981
1982 # -- print message regarding enabled experimental features
1983 AS_IF([test "x$enable_experimental" = "xyes"],
1984       [experimental_msg="experimental features enabled"])
1985 # -- OSX Framework
1986 AS_IF([test "$enable_framework_build" = "yes"],
1987       [macosx_framework_msg="yes"],
1988       [macosx_framework_msg="no"])
1989 # -- libidn 2
1990 AS_IF([test "x$working_libidn2" = x1],
1991       [libidn2_msg="libidn2"])
1992 # -- libidn 1
1993 AS_IF([test "x$working_libidn1" = x1],
1994       [libidn1_msg="libidn1"])
1995 # -- texi2mdoc
1996 AS_IF([test "x$texi2mdoc_generation" = x1],
1997       [mdoc_msg="yes"],
1998       [mdoc_msg="no"])
1999 # -- texinfo
2000 AS_IF([test "x$makeinfo" != "x1"],
2001       [texinfo_msg="no"],
2002       [texinfo_msg="yes"])
2003 # -- conversation
2004 AS_IF([test "x$conversation_backend" = "xnone"],
2005       [AS_IF([test "x$pulse" != "x1"],
2006              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
2007               libpulse_msg="no"],
2008              [libpulse_msg="yes"])
2009        AS_IF([test "x$opus" != "x1"],
2010              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
2011               libopus_msg="no"],
2012              [libopus_msg="yes"])
2013        AS_IF([test "x$gst" != "x1"],
2014              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
2015               gstreamer_msg="no"],
2016              [gstreamer_msg="yes"])],
2017       [features_msg="$features_msg conversation"])
2018 # -- interface
2019 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2020 # -- libmicrohttpd
2021 AS_IF([test "x$lmhd" != "x1"],
2022       [libmicrohttpd_msg="no (optional)"],
2023       [libmicrohttpd_msg="yes"])
2024 # -- jansson
2025 AS_IF([test "x$jansson" = "x0"],
2026       [jansson_msg="no (optional)"],
2027       [jansson_msg="yes"])
2028 # -- libextractor
2029 AS_IF([test "$extractor" != 1],
2030       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
2031       [libextractor_msg="yes"])
2032 # -- libzbar
2033 AS_IF([test "x$zbar" = "x1"],
2034       [libzbar_msg="yes"
2035        features_msg="$features_msg gnunet-qr"],
2036       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
2037        libzbar_msg="no"])
2038 # -- libgnurl
2039 AS_IF([test "$gnurl" = "0"],
2040       [AS_IF([test "x$curl" = "xfalse"],
2041              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
2042               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2043               curl_msg="no"],
2044              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
2045               curl_msg="yes"])],
2046        [gnurl_msg="yes"])
2047 # -- ifconfig
2048 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2049       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2050        ifconfig_msg="no (optional)"],
2051       [ifconfig_msg="yes"])
2052 # -- upnpc
2053 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2054       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2055        upnpc_msg="no (optional)"],
2056       [upnpc_msg="yes"])
2057 # -- iptables
2058 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2059       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2060        iptables_msg="no (optional)"],
2061       [iptables_msg="yes"])
2062 # -- bluetooth
2063 AS_IF([test "x$bluetooth" = "x0"],
2064       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2065        bluetooth_msg="no (optional)"],
2066       [bluetooth_msg="yes"])
2067 # -- gnutls
2068 AS_IF([test x$gnutls != xtrue],
2069       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2070        gnutls_msg="no"],
2071       [AS_IF([test "x$gnutls_dane" != "x1"],
2072              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2073               gnutls_msg="yes (without DANE support)"],
2074              [gnutls_msg="yes (with DANE support)"])])
2075 # -- databases
2076 AS_IF([test $mysqlfail = true]
2077       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2078 AS_IF([test "$mysql" = true],
2079       [features_msg="$features_msg mysql"
2080        mysql_msg="yes"],
2081       [mysql_msg="no"])
2082 AS_IF([test "$sqlite" = true],
2083       [features_msg="$features_msg sqlite"
2084        sqlite_msg="yes"],
2085       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2086        sqlite_msg="no"])
2087 AS_IF([test "$postgres" = true],
2088       [features_msg="$features_msg postgres"
2089        postgres_msg="yes"],
2090       [postgres_msg="no"])
2091 # -- features
2092 # ---- 1. replace spaces with newlines,
2093 # ---- 2. sort the lines,
2094 # ---- 3. replace the newlines with spaces.
2095 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2096 AC_SUBST(features_msg)
2097
2098
2099 # The summary
2100 # TODO: reduce the length of the last message block ("the message")
2101
2102 AC_MSG_NOTICE([
2103 GNUnet Configuration (incomplete!)
2104
2105 gnunet version:                 ${VERSION}
2106
2107 Host setup:                     ${host}
2108 Install prefix:                 ${prefix}
2109 Compiler:                       ${CC}
2110 CFLAGS:                         ${CFLAGS}
2111 CPPFLAGS:                       ${CPPFLAGS}
2112 LDFLAGS:                        ${LDFLAGS}
2113 LIBS:                           ${LIBS}
2114 Build Target:                   $build_target
2115 Mac OSX framework build:        ${macosx_framework_msg}
2116
2117 Default Interface:              ${interface_msg}
2118
2119 MySQL:                          ${mysql_msg}
2120 PostgreSQL:                     ${postgres_msg}
2121 sqlite3:                        ${sqlite_msg}
2122 gnurl:                          ${gnurl_msg}
2123 curl:                           ${curl_msg}
2124 bluetooth:                      ${bluetooth_msg}
2125 jansson:                        ${jansson_msg}
2126 iptables:                       ${iptables_msg}
2127 ifconfig:                       ${ifconfig_msg}
2128 upnpc:                          ${upnpc_msg}
2129 gnutls:                         ${gnutls_msg}
2130 libzbar:                        ${libzbar_msg}
2131 java:                           ${java_msg}
2132 libmicrohttpd:                  ${libmicrohttpd_msg}
2133 libidn:                         ${libidn1_msg}${libidn2_msg}
2134 libopus:                        ${libopus_msg}
2135 gstreamer:                      ${gstreamer_msg}
2136 libpulse:                       ${libpulse_msg}
2137 libextractor:                   ${libextractor_msg}
2138
2139 texinfo manual:                 ${texinfo_msg}
2140 transpiled mdoc manual:         ${mdoc_msg}
2141
2142 features:                       ${features_msg}
2143 experimental:                   ${experimental_msg}
2144
2145
2146 IMPORTANT:
2147
2148 Please make sure NOW that you have created a user and group 'gnunet'
2149 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2150 type:
2151
2152   addgroup gnunetdns
2153   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2154
2155 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2156 'gnunet'.  Then, you can compile GNUnet with
2157
2158   make
2159
2160 After that, run (if necessary as 'root')
2161
2162   make install
2163
2164 to install everything.
2165
2166 Each GNUnet user should be added to the 'gnunet' group (may
2167 require fresh login to come into effect):
2168
2169   adduser USERNAME gnunet
2170
2171 (run the above command as root once for each of your users, replacing
2172 "USERNAME" with the respective login names).  If you have a global IP
2173 address, no further configuration is required.
2174
2175 For more detailed setup instructions, see https://docs.gnunet.org/
2176
2177 Optionally, download and compile gnunet-gtk to get a GUI for
2178 file-sharing and configuration.  This is particularly recommended
2179 if your network setup is non-trivial, as gnunet-setup can be
2180 used to test in the GUI if your network configuration is working.
2181 gnunet-setup should be run as the "gnunet" user under X.  As it
2182 does very little with the network, running it as "root" is likely
2183 also harmless.  You can also run it as a normal user, but then
2184 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2185 home directory in the end.
2186
2187 Once you have configured your peer, run (as the 'gnunet' user)
2188
2189   gnunet-arm -s
2190
2191 to start the peer.  You can then run the various GNUnet-tools as
2192 your "normal" user (who should only be in the group 'gnunet').
2193 ])