configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen win32-dll])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 136      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 137      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 138      build_target="freebsd"
 139      LIBPREFIX=
 140      DLLDIR=lib
 141      UNIXONLY="#"
 142   ],
 143   [*openbsd*],[
 144      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 145      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 146      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 147      build_target="openbsd"
 148      LIBPREFIX=
 149      DLLDIR=lib
 150      UNIXONLY="#"
 151   ],
 152   [*netbsd*],[
 153      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 154      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 155      build_target="netbsd"
 156      LIBPREFIX=
 157      DLLDIR=lib
 158      UNIXONLY="#"
 159   ],
 160   [*solaris*],[
 161      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 162      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 163      AC_CHECK_LIB(resolv, res_init)
 164      AC_CHECK_LIB(rt, nanosleep)
 165      build_target="solaris"
 166      LIBPREFIX=
 167      DLLDIR=lib
 168      UNIXONLY="#"
 169   ],
 170   [*arm-linux*],[
 171      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 172      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 173      build_target="linux"
 174      LIBPREFIX=
 175      DLLDIR=lib
 176      UNIXONLY="#"
 177   ],
 178   [gnu*],[
 179      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 180      build_target="gnu"
 181      UNIXONLY="#"
 182   ],
 183   [
 184      AC_MSG_RESULT(Unrecognised OS $host_os)
 185      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 186      UNIXONLY=""
 187 ])
 188 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 189 AC_SUBST(DEFAULT_INTERFACE)
 190
 191 # Disable TCP-based IPC on systems that support UNIX domain
 192 # sockets in default configuratin:
 193 AC_SUBST(UNIXONLY)
 194
 195
 196 AC_MSG_CHECKING([for build target])
 197 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 198 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 199 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 226 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 227 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 228 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 229
 230 # autotools' m4 for python has no maximum version!
 231 # python3.4 - python3.8 for tests (3.8 unchecked)
 232 # TODO: document how to override the lowest version
 233 # TODO: found by this.
 234 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 235 AM_PATH_PYTHON([3.4],, [:])
 236 AC_SUBST([PYTHON])
 237 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 238
 239 # perl
 240 AC_PATH_PROG( PERL, perl, ,
 241               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 242 AC_SUBST([PERL])
 243
 244 # iptables is a soft requirement to run tests
 245 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 246
 247 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 248  [AS_IF([test -x "/sbin/iptables"],
 249    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 250    [AS_IF([test -x "/usr/sbin/iptables"],
 251       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 252
 253 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 254  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 255  [AC_MSG_WARN([warning: 'iptables' not found.])])
 256
 257 # ip6tables is a soft requirement for some features
 258 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 259
 260 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 261   [AS_IF([test -x "/sbin/ip6tables"],
 262      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 263      [AS_IF([test -x "/usr/sbin/ip6tables"],
 264         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 265
 266
 267 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 268   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 269   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 270
 271 # ip is a soft requirement for some features
 272 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 273
 274 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 275  [AS_IF([test -x "/sbin/ip"],
 276    [VAR_IP_BINARY="/sbin/ip"],
 277    [AS_IF([test -x "/usr/sbin/ip"],
 278           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 279
 280 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 281  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 282  [AC_MSG_WARN([warning: 'ip' not found.])])
 283
 284 # locate 'ifconfig'
 285 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 286
 287 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 288 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 289   [AS_IF([test -x "/sbin/ifconfig"],
 290      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 291      [AS_IF([test -x "/usr/sbin/ifconfig"],
 292             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 293
 294 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 295   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 296   [AC_MSG_WARN(['ifconfig' not found.])])
 297
 298
 299 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 300
 301 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 302 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 303       [AS_IF([test -x "/sbin/sysctl"],
 304              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 305              [AS_IF([test -x "/usr/sbin/sysctl"],
 306                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 307 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 308       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 309       [AC_MSG_WARN(['sysctl' not found.])])
 310
 311 # miniupnpc / upnpc binary is a soft runtime requirement
 312 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 313
 314 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 315   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 316   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 317
 318
 319 # uncrustify
 320 # TODO: maybe add flag to pass location
 321 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 322 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 323
 324 # yapf
 325 # TODO: less repetition, add flag to pass name
 326 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 327 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 328
 329
 330 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 331   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 332      [Define if struct tm has the tm_gmtoff member.])],
 333      ,
 334      [#include <time.h>])
 335
 336 # 'save' libs; only those libs found so far will be
 337 # linked against _everywhere_.  For the others, we
 338 # will be more selective!
 339 SAVE_LIBS=$LIBS
 340
 341 have_addrinfo_a=0
 342 AC_CHECK_LIB(anl,
 343              getaddrinfo_a,
 344              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 345                                           1,
 346                                           [getaddrinfo_a supported])])
 347 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 348                [test "$have_addrinfo_a" = 1])
 349
 350 # libgcrypt
 351 gcrypt=0
 352 NEED_LIBGCRYPT_API=1
 353 NEED_LIBGCRYPT_VERSION=1.6.0
 354
 355
 356 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 357 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 358
 359 AS_IF([test $gcrypt = 0],
 360  [
 361   AC_MSG_ERROR([[
 362 ***
 363 *** You need libgcrypt to build this program.
 364 *** This library is for example available at
 365 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 366 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 367 ***  is required.
 368 ***]])
 369 ])
 370 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 371
 372 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 373
 374
 375
 376 # should the build process be building the documentation?
 377 AC_MSG_CHECKING(whether to build documentation)
 378 AC_ARG_ENABLE([documentation],
 379               [AS_HELP_STRING([--disable-documentation],
 380                               [do not build the documentation])],
 381               [documentation=${enableval}],
 382               [documentation=yes])
 383 AC_MSG_RESULT($documentation)
 384 AS_IF([test "x$documentation" = "xyes"],
 385       [AM_CONDITIONAL([DOCUMENTATION],
 386                       true)
 387        AC_DEFINE([DOCUMENTATION],
 388                  [1],
 389                  [Building the documentation])],
 390       [AM_CONDITIONAL([DOCUMENTATION],
 391                       false)
 392        AC_DEFINE([DOCUMENTATION],
 393                  [0],
 394                  [Not building the documentation])])
 395
 396 # COMMENT: Check wether to transpile texinfo to mdoc.
 397 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 398 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 399 # COMMENT: and makes the configure fail if it is missing.
 400 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 401 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 402 # COMMENT: or nothing was set (this is the default).
 403 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 404 # COMMENT: potential non-existence of the texi2mdoc binary.
 405 # COMMENT: Default return value / setting: no
 406 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 407 AC_ARG_ENABLE([texi2mdoc-generation],
 408               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 409                               [include generated texi2mdoc output in installation])],
 410               [texi2mdoc_generation=${enableval}],
 411               [texi2mdoc_generation=no])
 412 AC_MSG_RESULT($texi2mdoc_generation)
 413 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 414       [AS_IF([test "$texi2mdoc" = 0],
 415              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 416               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 417               AC_MSG_WARN([ERROR: Operating System package manager or from])
 418               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 419              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 420               AC_DEFINE([TEXI2MDOC_GENERATION],
 421                         [1],
 422                         [Building section 7 mdoc output])])],
 423       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 424                       false)
 425        AC_DEFINE([TEXI2MDOC_GENERATION],
 426                  [0],
 427                  [Not building section 7 mdoc output])])
 428
 429 # should the build process be building only the documentation?
 430 AC_MSG_CHECKING(whether to build only documentation)
 431 AC_ARG_ENABLE([documentation-only],
 432    [AS_HELP_STRING([--enable-documentation-only],
 433                    [build only the documentation])],
 434    [documentation_only=${enableval}],
 435    [documentation_only=no])
 436 AC_MSG_RESULT($documentation_only)
 437 AS_IF([test "x$documentation_only" = "xyes"],
 438  [
 439   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 440   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 441  ],[
 442   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 443   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 444  ])
 445
 446 # should the build process be including the manpages? (default: yes)
 447 AC_MSG_CHECKING(whether to include man pages)
 448 AC_ARG_ENABLE([include-manpages],
 449    [AS_HELP_STRING([--disable-include-manpages],
 450                    [Do not include the man pages in build and installation])],
 451    [include_manpages=${enableval}],
 452    [include_manpages=yes])
 453 AC_MSG_RESULT($include_manpages)
 454 AS_IF([test "x$include_manpages" = "xyes"],
 455  [
 456   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 457   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 458  ],[
 459   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 460   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 461  ])
 462
 463 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 464 # (not syntax!) to the commandline tools which generate the html. If not,
 465 # texinfo5 switches are used. This comes with no version checks, is
 466 # enabled only at distributors action (ie defaults to "no").
 467 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 468 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 469 AC_ARG_ENABLE([texinfo4],
 470    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 471    [activate_texinfo4=${enableval}],
 472    [activate_texinfo4=no])
 473 AC_MSG_RESULT($activate_texinfo4)
 474 AS_IF([test "x$activate_texinfo4" = "xyes"],
 475  [
 476   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 477   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 478  ],[
 479   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 480   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 481  ])
 482
 483
 484 # Adam shostack suggests the following for Windows:
 485 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 486 AC_ARG_ENABLE(gcc-hardening,
 487    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 488 [AS_IF([test x$enableval = xyes],[
 489     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 490     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 491     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 492     LDFLAGS="$LDFLAGS -pie"
 493  ])])
 494
 495 # Linker hardening options
 496 # Currently these options are ELF specific - you can't use this with MacOSX
 497 AC_ARG_ENABLE(linker-hardening,
 498   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 499 [AS_IF([test x$enableval = xyes],
 500    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 501
 502
 503 AC_ARG_ENABLE(sanitizer,
 504   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 505 [AS_IF([test x$enableval = xyes],[
 506    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 507  ])])
 508
 509
 510 extra_logging=GNUNET_NO
 511 AC_ARG_ENABLE([logging],
 512    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 513    [AS_IF([test "x$enableval" = "xyes"], [],
 514           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 515           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 516           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 517    ], [])
 518 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 519
 520 # should memory poisoning be enabled?
 521 AC_MSG_CHECKING(whether to poison freed memory)
 522 AC_ARG_ENABLE([poisoning],
 523    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 524    [enable_poisoning=${enableval}],
 525    [
 526      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 527        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 528        [enable_poisoning=no])
 529    ])
 530 AC_MSG_RESULT($enable_poisoning)
 531 AS_IF([test ! "x$enable_poisoning" = "xno"],
 532   [enable_poisoning=1],
 533   [enable_poisoning=0])
 534 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 535
 536 AS_IF([test $build = $target],
 537 [
 538 AC_MSG_CHECKING([for working HMAC])
 539 AC_LANG_PUSH(C)
 540 LIBS="$LIBS $LIBGCRYPT_LIBS"
 541 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 542 AC_RUN_IFELSE(
 543   [AC_LANG_PROGRAM([#include <gcrypt.h>
 544         #include <stdio.h>], [[
 545         gcry_md_hd_t mac;
 546
 547         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 548             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 549             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 550         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 551         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 552             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 553             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 554             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 555             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 556             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 557
 558         if (!gcry_check_version (GCRYPT_VERSION))
 559         {
 560           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 561           return 1;
 562         }
 563
 564         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 565         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 566
 567         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 568         {
 569           fprintf (stderr, "gcry_md_open error\n");
 570           return 2;
 571         }
 572
 573         gcry_md_setkey (mac, key, sizeof (key));
 574         gcry_md_write (mac, data, sizeof (data));
 575
 576         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 577         {
 578           fprintf (stderr, "memcmp error\n");
 579           return 3;
 580         }
 581
 582         gcry_md_close (mac);
 583
 584         return 0;
 585     ]])],
 586   [AC_MSG_RESULT([yes])],
 587   [
 588    RESULT=$?
 589    if test $RESULT = 3
 590    then
 591      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 592    fi
 593    if test $RESULT = 2
 594    then
 595      AC_MSG_FAILURE([HMAC test failed])
 596    fi
 597    if test $RESULT = 1
 598    then
 599      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 600    fi
 601   ],
 602   [AC_MSG_RESULT([cross compiling, test skipped])])
 603 AC_LANG_POP(C)
 604 ])      # $build = $target
 605
 606 # check for bluetooth library
 607 bluetooth=0
 608 AC_MSG_CHECKING(for libbluetooth)
 609 AC_ARG_WITH(libbluetooth,
 610     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 611     [AC_MSG_RESULT([$with_libbluetooth])
 612      AS_CASE([$with_libbluetooth],
 613         [no],[],
 614         [yes],[
 615             CHECK_LIBHEADER(BLUETOOTH,
 616                             bluetooth,
 617                             ba2str,
 618                             bluetooth/bluetooth.h,
 619                             bluetooth=1,)
 620         ],[
 621             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 622             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 623             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 624                              AC_CHECK_LIB([bluetooth],
 625                                           [ba2str],
 626                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 627                                           bluetooth=1))
 628         ])
 629     ],
 630     [AC_MSG_RESULT([--with-libbluetooth not specified])
 631      CHECK_LIBHEADER(BLUETOOTH,
 632                      bluetooth,
 633                      ba2str,
 634                      bluetooth/bluetooth.h,
 635                      bluetooth=1,)])
 636 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 637 AS_IF([test "$bluetooth" = 1],
 638       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 639       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 640
 641 # check for zbar library
 642 zbar=0
 643 AC_MSG_CHECKING(for libzbar)
 644 AC_ARG_WITH(zbar,
 645    [  --with-zbar=PREFIX (base of libzbar installation)],
 646    [AC_MSG_RESULT([$with_zbar])
 647     AS_CASE([$with_zbar],
 648       [no],[],
 649       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 650       [
 651         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 652         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 653         AC_CHECK_HEADERS(zbar.h,
 654           AC_CHECK_LIB([zbar], [zbar_processor_create],
 655             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 656             zbar=1))
 657        ])
 658    ],
 659    [AC_MSG_RESULT([--with-zbar not specified])
 660     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 661 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 662 AS_IF([test "x$zbar" = x1],
 663       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 664       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 665
 666 # check for jansson library
 667 jansson=0
 668 AC_MSG_CHECKING(for libjansson)
 669 AC_ARG_WITH(jansson,
 670    [  --with-jansson=PREFIX (base of libjansson installation)],
 671    [AC_MSG_RESULT([$with_jansson])
 672     AS_CASE([$with_jansson],
 673       [no],[],
 674       [yes],[
 675         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 676       ],[
 677         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 678         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 679         AC_CHECK_HEADERS(jansson.h,
 680           AC_CHECK_LIB([jansson], [json_loads],
 681             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 682             jansson=1))
 683       ])
 684    ],
 685    [AC_MSG_RESULT([--with-jansson not specified])
 686     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 687 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 688 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 689 AS_IF([test "x$jansson" = x1],
 690       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 691       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 692
 693
 694 # check for libpulse(audio) library
 695 pulse=0
 696 libpulse_msg="no"
 697 AC_MSG_CHECKING(for libpulse)
 698 # TODO: --with-libpulse or --with-pulseaudio? What is more established
 699 # TODO: in this context?
 700 AC_ARG_WITH(libpulse,
 701     [  --with-libpulse=PREFIX (base of libpulse installation)],
 702     [AC_MSG_RESULT([$with_libpulse])
 703      AS_CASE([$with_libpulse],
 704         [no],[],
 705         [yes],[
 706             CHECK_LIBHEADER(LIBPULSE,
 707                             pulse,
 708                             pa_stream_peek,
 709                             pulse/simple.h,
 710                             pulse=1,)
 711         ],[
 712             LDFLAGS="-L$with_libpulse/lib $LDFLAGS"
 713             CPPFLAGS="-I$with_libpulse/include $CPPFLAGS"
 714             AC_CHECK_HEADERS(pulse/simple.h,
 715                              AC_CHECK_LIB([pulse],
 716                                           [pa_stream_peek],
 717                                           EXT_LIB_PATH="-L$with_libpulse/lib $EXT_LIB_PATH"
 718                                           pulse=1))
 719         ])
 720     ],
 721     [AC_MSG_RESULT([--with-libpulse not specified])
 722      CHECK_LIBHEADER(LIBPULSE,
 723                      pulse,
 724                      pa_stream_peek,
 725                      pulse/simple.h,
 726                      pulse=1,)])
 727 AM_CONDITIONAL(HAVE_PULSE, [test "$pulse" = 1])
 728 AS_IF([test x"$pulse" = x1],
 729       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 730        libpulse_msg="yes"],
 731       [AC_DEFINE([HAVE_PULSE],[0],[Lacking libpulse(audio) library])
 732        libpulse_msg="no"])
 733
 734 # check for libopus(audio) library
 735 opus=0
 736 libopus_msg="no"
 737 AC_MSG_CHECKING(for libopus)
 738 AC_ARG_WITH(libopus,
 739     [  --with-libopus=PREFIX (base of libopus installation)],
 740     [AC_MSG_RESULT([$with_libopus])
 741      AS_CASE([$with_libopus],
 742         [no],[],
 743         [yes],[
 744             CHECK_LIBHEADER(LIBOPUS,
 745                             opus,
 746                             opus_decode_float,
 747                             opus/opus.h,
 748                             AC_CHECK_DECL([OPUS_SET_GAIN],
 749                                           [opus=1],
 750                                           [],
 751                                           [[
 752                                           #include <opus/opus.h>
 753                                           ]]))
 754     ],[
 755         LDFLAGS="-L$with_libopus/lib $LDFLAGS"
 756         CPPFLAGS="-I$with_libopus/include $CPPFLAGS"
 757         AC_CHECK_HEADERS(opus/opus.h,
 758                          AC_CHECK_LIB([opus],
 759                                       [OPUS_SET_GAIN],
 760                                       EXT_LIB_PATH="-L$with_libopus/lib $EXT_LIB_PATH"
 761                                       opus=1))
 762       ])
 763     ],
 764     [AC_MSG_RESULT([--with-libopus not specified])
 765      CHECK_LIBHEADER(LIBOPUS,
 766                      opus,
 767                      opus_decode_float,
 768                      opus/opus.h,
 769                      AC_CHECK_DECL([OPUS_SET_GAIN],
 770                                    [opus=1],
 771                                    [],
 772                                    [[
 773                                      #include <opus/opus.h>
 774                                    ]]))])
 775 AM_CONDITIONAL(HAVE_OPUS, [test "$opus" = 1])
 776 AS_IF([test "x$opus" = x1],
 777       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 778        libopus_msg="yes"],
 779       [AC_DEFINE([HAVE_OPUS],[0],[Lacking libopus library])
 780        libopus_msg="no"])
 781
 782 # libogg
 783 AC_MSG_CHECKING(for libogg)
 784 AC_ARG_WITH(libogg,
 785     [  --with-libogg=PREFIX (base of libogg installation)],
 786     [AC_MSG_RESULT([$with_libogg])
 787      AS_CASE([$with_libogg],
 788         [no],[],
 789         [yes],[
 790             CHECK_LIBHEADER(LIBOGG,
 791                             ogg,
 792                             ogg_stream_flush_fill,
 793                             ogg/ogg.h,
 794                             ogg=1,)
 795         ],[
 796             LDFLAGS="-L$with_libogg/lib $LDFLAGS"
 797             CPPFLAGS="-I$with_libogg/include $CPPFLAGS"
 798             AC_CHECK_HEADERS(ogg/ogg.h,
 799                              AC_CHECK_LIB([ogg],
 800                                           [ogg_stream_flush_fill],
 801                                           EXT_LIB_PATH="-L$with_libogg/lib $EXT_LIB_PATH"
 802                                           ogg=1))
 803         ])
 804      ],
 805      [AC_MSG_RESULT([--with-libogg not specified])
 806       CHECK_LIBHEADER(LIBOGG,
 807                       ogg,
 808                       ogg_stream_flush_fill,
 809                       ogg/ogg.h,
 810                       ogg=1,)])
 811 AM_CONDITIONAL(HAVE_OGG, [test "$ogg" = 1])
 812 AS_IF([test x"$ogg" = x1],
 813       [AC_DEFINE([HAVE_OGG],[1],[Have ogg])]
 814       [AC_DEFINE([HAVE_OGG],[0],[Lacking ogg])])
 815
 816
 817 PKG_CHECK_MODULES([GLIB],
 818                   [glib-2.0],
 819   [# check for pbc library
 820   pbc=0
 821    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 822    AC_CHECK_HEADER([gabe.h],abe=1)
 823    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 824    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 825    AS_IF([test "x$pbc" = x1],
 826      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 827      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 828    AS_IF([test "x$abe" = x1],
 829     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 830     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 831   [# glib-2 not found
 832    AM_CONDITIONAL(HAVE_PBC, [false])
 833    AM_CONDITIONAL(HAVE_ABE, [false])
 834    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 835
 836
 837 gst=0
 838 gstreamer_msg="no"
 839 AC_MSG_CHECKING(for gstreamer)
 840 PKG_CHECK_MODULES(
 841   [GST],
 842   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 843   [gst=1
 844    gstreamer_msg="yes"],
 845   [gst=0])
 846
 847 # conversation
 848 AC_MSG_CHECKING(conversation feature set to build)
 849 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 850  AS_IF([test "x$gst" != "x1"],[
 851   conversation_backend=none
 852   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 853   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 854   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 855  ],[
 856    conversation_backend=gst
 857    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 858    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 859    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 860  ])
 861 ],[
 862  conversation_backend=pulse
 863  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 864  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 865  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 866 ])
 867
 868 AS_IF([test "x$conversation_backend" = "xnone"],
 869       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 870       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 871
 872 # libgnurl
 873 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 874
 875 SAVE_CPPFLAGS=$CPPFLAGS
 876 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 877 LIBS="$LIBGNURL $LIBCURL $LIBS"
 878
 879 # libcurl-gnutls
 880 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 881 AS_IF([test "x$curl" = xtrue],[
 882  AC_CHECK_HEADER([curl/curl.h],
 883   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 884   [curl=false])
 885  # need libcurl-gnutls.so, everything else is not acceptable
 886  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 887  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 888 ])
 889
 890 # libcurl and libgnurl should be mutually exclusive
 891 AS_IF([test "$gnurl" = 1],
 892       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 893        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 894        AM_CONDITIONAL(HAVE_LIBCURL, false)
 895        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 896       [AS_IF([test "$curl" = true],
 897              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 898               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 899               AM_CONDITIONAL(HAVE_LIBCURL, true)
 900               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 901              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 902               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 903               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 904               AM_CONDITIONAL(HAVE_LIBCURL, false)
 905               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 906
 907 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 908 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 909
 910 # restore LIBS & CPPFLAGS
 911 LIBS=$SAVE_LIBS
 912 CPPFLAGS=$SAVE_CPPFLAGS
 913
 914
 915 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 916 AS_IF([test x$nss = xfalse],
 917   [
 918         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 919         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 920   ],[
 921         NSS_INCLUDES="
 922         #include <nss.h>
 923         "
 924         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 925                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 926                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 927                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 928                 [$NSS_INCLUDES])
 929 ])
 930
 931
 932
 933 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 934 AC_CHECK_LIB([kvm],[kvm_open])
 935 AC_CHECK_LIB([kstat],[kstat_open])
 936
 937
 938 # should the build process be restricted to the code required
 939 # for GNU Taler wallets?
 940 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 941 AC_ARG_ENABLE([taler-wallet],
 942    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 943    [taler_only=${enableval}],
 944    [taler_only=no])
 945 AC_MSG_RESULT($taler_only)
 946 AS_IF([test "x$taler_only" = "xyes"],
 947 [
 948   AM_CONDITIONAL([TALER_ONLY],true)
 949   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 950 ],[
 951   AM_CONDITIONAL([TALER_ONLY],false)
 952   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 953 ])
 954
 955 # test for libextractor
 956 extractor=0
 957 AC_MSG_CHECKING(for libextractor)
 958 AC_ARG_WITH(extractor,
 959    [  --with-extractor=PREFIX (base of libextractor installation)],
 960    [AC_MSG_RESULT([$with_extractor])
 961     AS_CASE([$with_extractor],
 962       [no],[],
 963       [yes],[
 964         AC_CHECK_HEADERS([extractor.h],
 965           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 966             extractor=1))
 967       ],[
 968         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 969         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 970         AC_CHECK_HEADERS([extractor.h],
 971           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 972             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 973             extractor=1))
 974       ])
 975    ],
 976    [AC_MSG_RESULT([--with-extractor not specified])
 977     AC_CHECK_HEADERS([extractor.h],
 978      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 979       extractor=1))])
 980 # restore LIBS
 981 LIBS=$SAVE_LIBS
 982
 983 AS_IF([test "$extractor" != 1],
 984  [
 985  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 986  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 987  ],[
 988  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 989  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 990  ])
 991
 992
 993 AS_IF([test "$taler_only" != yes],[
 994
 995
 996 # Check for libltdl header (#2999)
 997 ltdl=0
 998 AC_MSG_CHECKING(for libltdl)
 999 AC_ARG_WITH(ltdl,
1000    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
1001    [AC_MSG_RESULT([$with_ltdl])
1002     AS_CASE([$with_ltdl],
1003       [no],[],
1004       [yes],[
1005         AC_CHECK_HEADERS(ltdl.h,
1006           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1007             ltdl=1))
1008       ],[
1009         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
1010         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
1011         AC_CHECK_HEADERS(ltdl.h,
1012           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1013             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
1014             ltdl=1))
1015       ])
1016    ],
1017    [AC_MSG_RESULT([--with-ltdl not specified])
1018     AC_CHECK_HEADERS(ltdl.h,
1019      AC_CHECK_LIB([ltdl], [lt_dlopenext],
1020       ltdl=1))])
1021 AS_IF([test x$ltdl = x1],
1022 [
1023  AC_MSG_RESULT([libltdl found])
1024 ],[
1025  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
1026 ])
1027 # restore LIBS
1028 LIBS=$SAVE_LIBS
1029
1030 # libidn and libidn2. The ideal goal is this:
1031 # check for libidn2, if it doesn't exist check for libidn
1032 # if both exist, prefer libidn2
1033 # if none exist, fail and message that libidn or libidn2
1034 # is required with a preference for libidn2.
1035 # TODO: What we have right here can probably be improved.
1036 AC_MSG_CHECKING(for idn or idn2)
1037
1038 AC_MSG_CHECKING(for idn)
1039 my_with_libidn=1
1040 AC_ARG_WITH(libidn,
1041             AS_HELP_STRING([--with-libidn=pathname],
1042                            [Support IDN (needs libidn)]),
1043             [],
1044             [withval="yes"])
1045 AS_IF([test x_$withval = x_yes],
1046       [AC_CHECK_HEADERS([idna.h],
1047                         AC_MSG_NOTICE([Found idna.h]),
1048                         AC_CHECK_HEADERS([idn/idna.h],
1049                                          AC_MSG_NOTICE([Found idn/idna.h]),
1050                                          my_with_libidn=0))],
1051       [AS_IF([test x_$withval != x_no],
1052              [CFLAGS="$CFLAGS -I$withval/include"
1053               LDFLAGS="$LDFLAGS -L$withval/lib"
1054               AC_CHECK_HEADERS([idna.h],
1055                                AC_MSG_NOTICE([Found idna.h]),
1056                                    [AC_MSG_NOTICE([Failed to find idna.h])
1057                                my_with_libidn=0])],
1058              [my_with_libidn=0])])
1059
1060 AC_MSG_CHECKING(for idn2)
1061 my_with_libidn2=1
1062 AC_ARG_WITH(libidn2,
1063             AS_HELP_STRING([--with-libidn2=pathname],
1064                            [Support IDN (needs libidn2)]),
1065             [],
1066             [withval="yes"])
1067 AS_IF([test x_$withval = x_yes],
1068       [AC_CHECK_HEADERS([idn2.h],
1069                         AC_MSG_NOTICE([Found idn2.h]),
1070                         AC_CHECK_HEADERS([idn2/idn2.h],
1071                                          AC_MSG_NOTICE([Found idn2/idn2.h]),
1072                                          [AC_MSG_NOTICE([Failed to find idn2.h])
1073                                          my_with_libidn2=0]))],
1074       [AS_IF([test x_$withval != x_no],
1075              [CFLAGS="$CFLAGS -I$withval/include"
1076               LDFLAGS="$LDFLAGS -L$withval/lib"],
1077                   [my_with_libidn2=0])])
1078
1079 AC_MSG_CHECKING([if libidn can be used])
1080 # Check for LIBIDNs
1081 there_can_only_be_one=1
1082
1083 working_libidn1=0
1084 working_libidn2=0
1085 AS_IF([test x$my_with_libidn2 = x1],
1086       [AC_MSG_NOTICE([Checking for libidn2])
1087        AC_CHECK_LIB([idn2],
1088                     [idn2_to_unicode_8z8z],
1089                     [working_libidn2=1
1090                     LIBS="-lidn2 $LIBS"
1091                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1092                                        [1],
1093                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1094                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1095                      MISSING_SEP=", "])])
1096 AM_CONDITIONAL(HAVE_LIBIDN2,
1097                test x$working_libidn2 = x1)
1098 AS_IF([test x$working_libidn2 = x0],
1099       [AS_IF([test x$my_with_libidn = x1],
1100              [AC_MSG_NOTICE([Checking for libidn])
1101               AC_CHECK_LIB([idn],
1102                            [idna_to_ascii_8z],
1103                            [working_libidn1=1
1104                            LIBS="-lidn $LIBS"
1105                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1106                                               [1],
1107                                               [Define to 1 if you have 'libidn' (-lidn).])],
1108                            [there_can_only_be_one=0])],
1109              [AS_IF([test x$my_with_libidn2 = x1],
1110                     [there_can_only_be_one=0
1111                      AC_MSG_FAILURE([* There can only be one libidn.
1112                                      * Provide either libidn >= 1.13
1113                                      * or
1114                                      * libidn2 to the configure
1115                                      * script via
1116                                      * --with-libidn2
1117                                      * --with-libidn])])])])
1118 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1119
1120 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1121       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1122
1123 AS_IF([test x$there_can_only_be_one = x0],
1124       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1125
1126 # test for zlib
1127 SAVE_LDFLAGS=$LDFLAGS
1128 SAVE_CPPFLAGS=$CPPFLAGS
1129 AC_ARG_WITH(zlib,
1130             [  --with-zlib[[=DIR]]       use libz in DIR],
1131             [AS_IF([test "$withval" = "no"],
1132                    [AC_MSG_ERROR([GNUnet requires zlib])],
1133                    [test "$withval" != "yes"],
1134                    [Z_DIR=$withval
1135                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1136                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1137 AC_CHECK_HEADER(zlib.h,
1138                 [],
1139                 [AC_MSG_ERROR([GNUnet requires zlib])])
1140 AC_CHECK_LIB(z,
1141              compress2,
1142              [AC_DEFINE([HAVE_ZLIB],
1143                         [],
1144                         [Have compression library])
1145               if test "x${Z_DIR}" != "x"; then
1146                       Z_CFLAGS="-I${Z_DIR}/include"
1147                       Z_LIBS="-L${Z_DIR}/lib -lz"
1148               else
1149                       Z_LIBS="-lz"
1150               fi],
1151               [AC_MSG_ERROR([GNUnet requires zlib])])
1152 AC_SUBST(Z_CFLAGS)
1153 AC_SUBST(Z_LIBS)
1154
1155 AS_IF([test "$enable_shared" = "no"],
1156       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1157
1158
1159 # restore LIBS
1160 LIBS=$SAVE_LIBS
1161
1162
1163 # end of taler-only being false
1164 ])
1165
1166
1167 # check for iconv
1168 AM_ICONV
1169
1170 # test for libunistring
1171 gl_LIBUNISTRING
1172 AS_IF([test $HAVE_LIBUNISTRING != yes],
1173       [AC_MSG_ERROR([GNUnet requires libunistring])])
1174
1175 # under emscripten, $gl_libunistring_hexversion is undefined
1176 if test "$taler_only" != yes; then
1177
1178 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1179       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1180 fi
1181 AC_CHECK_HEADERS([unistr.h],
1182                  ,
1183                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1184
1185 # restore LIBS
1186 LIBS=$SAVE_LIBS
1187
1188
1189
1190 # Checks for standard header files.
1191 AC_HEADER_DIRENT
1192 AC_HEADER_STDC
1193
1194 # Check for headers that are ALWAYS required
1195 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1196
1197
1198
1199 # Checks for headers that are only required on some systems or
1200 # opional (and where we do NOT abort if they are not there)
1201 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1202
1203 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1204 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1205 [#ifdef HAVE_SYS_TYPES_H
1206 #include <sys/types.h>
1207 #endif
1208 #ifdef HAVE_NETINET_IN_SYSTM_H
1209 #include <netinet/in_systm.h>
1210 #endif
1211 #ifdef HAVE_NETINET_IN_H
1212 #include <netinet/in.h>
1213 #endif
1214 ])
1215
1216 SAVE_LDFLAGS=$LDFLAGS
1217 SAVE_CPPFLAGS=$CPPFLAGS
1218
1219 # test for sqlite
1220 sqlite=false
1221 AC_MSG_CHECKING(for SQLite)
1222 AC_ARG_WITH(sqlite,
1223   [  --with-sqlite=PFX       base of SQLite installation],
1224   [AC_MSG_RESULT("$with_sqlite")
1225    AS_CASE([$with_sqlite],
1226      [no],[],
1227      [yes],[
1228       AC_CHECK_HEADERS(sqlite3.h,
1229       sqlite=true)],
1230      [
1231     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1232     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1233     AC_CHECK_HEADERS(sqlite3.h,
1234      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1235      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1236      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1237      sqlite=true)
1238     LDFLAGS=$SAVE_LDFLAGS
1239     CPPFLAGS=$SAVE_CPPFLAGS
1240     ])
1241   ],
1242   [AC_MSG_RESULT([--with-sqlite not specified])
1243     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1244 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1245 AC_SUBST(SQLITE_CPPFLAGS)
1246 AC_SUBST(SQLITE_LDFLAGS)
1247
1248 LDFLAGS=$SAVE_LDFLAGS
1249 CPPFLAGS=$SAVE_CPPFLAGS
1250
1251 # test for postgres
1252 postgres=false
1253 # even running the check for postgres breaks emscripten ...
1254 AS_IF([test "$taler_only" != yes],
1255       [AX_LIB_POSTGRESQL([9.5],
1256         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1257          AC_CHECK_HEADERS([libpq-fe.h],
1258          postgres=true)
1259         ],
1260         [AC_MSG_RESULT([no postgres])])])
1261 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1262
1263
1264 LDFLAGS=$SAVE_LDFLAGS
1265 CPPFLAGS=$SAVE_CPPFLAGS
1266
1267 # mysql & windows
1268 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1269 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1270
1271 # test for mysql
1272 mysql=false
1273 mysqlfail=false
1274 SAVE_LDFLAGS=$LDFLAGS
1275 SAVE_CPPFLAGS=$CPPFLAGS
1276 AC_MSG_CHECKING(for mysql)
1277 AC_ARG_WITH(mysql,
1278   [  --with-mysql=PFX        base of MySQL installation],
1279   [AC_MSG_RESULT([$with_mysql])
1280    AS_CASE([$with_mysql],
1281      [no],[],
1282      [yes|""],[
1283       AC_CHECK_HEADERS(mysql/mysql.h,
1284        AC_CHECK_LIB(mysqlclient, mysql_init,
1285        mysql=true), [], [])
1286      ],[
1287       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1288       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1289       AC_CHECK_HEADERS(mysql/mysql.h,
1290        AC_CHECK_LIB(mysqlclient, mysql_init,
1291         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1292         MYSQL_CPPFLAGS="-I$with_mysql/include"
1293
1294         mysql=true), [], [])
1295      ])
1296   ],
1297   [AC_MSG_RESULT([--with-mysql not specified])
1298    if test -d "/usr/lib64/mysql"; then
1299     MYSQL_LIBDIR="/usr/lib64/mysql"
1300    elif test -d "/usr/lib/mysql"; then
1301     MYSQL_LIBDIR="/usr/lib/mysql"
1302    else
1303     MYSQL_LIBDIR="/usr/lib"
1304    fi
1305    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1306    AC_CHECK_LIB(mysqlclient, mysql_init,
1307     [AC_CHECK_HEADERS(mysql/mysql.h,
1308       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1309       mysql=true
1310
1311      , [], [])])
1312   ])
1313
1314 AC_SUBST(MYSQL_LDFLAGS)
1315 AC_SUBST(MYSQL_CPPFLAGS)
1316
1317 # additional version check for mysql
1318 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1319 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1320  [
1321   AC_MSG_CHECKING(mysql version)
1322   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1323     [[
1324       #include <mysql/mysql.h>]],
1325     [[
1326       #if (MYSQL_VERSION_ID < 40100)
1327       #error needs at least version >= 4.1
1328       #endif
1329       int main () { return 0; }
1330     ]])
1331     ],mysql=true,mysql=false)
1332   AS_IF([test "$mysql" = "false"],
1333    [
1334     mysqlfail=true
1335     AC_MSG_RESULT([fail, >= 4.1 required])
1336    ],[
1337     AC_MSG_RESULT(ok)
1338    ])
1339 ])
1340 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1341 AM_CONDITIONAL(HAVE_MYSQLE, false)
1342 # restore LIBS
1343 LIBS=$SAVE_LIBS
1344 LDFLAGS=$SAVE_LDFLAGS
1345 CPPFLAGS=$SAVE_CPPFLAGS
1346
1347 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1348 [
1349  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1350 ])
1351
1352 # libmicrohttpd
1353 lmhd=0
1354 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1355 AC_ARG_WITH(microhttpd,
1356    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1357        [base of libmicrohttpd installation])],
1358    [],
1359    [with_microhttpd=check])
1360 AS_CASE([$with_microhttpd],
1361    [no], [],
1362    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1363    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1364        [lmhd=1],
1365        [AC_MSG_WARN([Building without libmicrohttpd])])],
1366    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1367     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1368     export PKG_CONFIG_PATH
1369     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1370     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1371 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1372 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1373
1374 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1375
1376 # restore LIBS
1377 LIBS=$SAVE_LIBS
1378
1379 # check for gettext
1380 AM_GNU_GETTEXT([external])
1381 AM_GNU_GETTEXT_VERSION([0.18.1])
1382
1383 # Checks for standard typedefs, structures, and compiler characteristics.
1384 AC_TYPE_PID_T
1385 AC_TYPE_SIZE_T
1386 AC_TYPE_MODE_T
1387 AC_HEADER_TIME
1388 AC_HEADER_STAT
1389 AC_HEADER_STDBOOL
1390 AC_STRUCT_TM
1391
1392 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1393    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1394    ],
1395    [],
1396    [
1397       #include <sys/types.h>
1398       #include <sys/socket.h>
1399       #include <netinet/in.h>
1400    ])
1401
1402 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1403                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1404                             1,
1405                             [Do we have sockaddr_un.sun_len?])],
1406                 [],
1407                 [
1408                 #include <sys/types.h>
1409                 #include <sys/socket.h>
1410                 #include <sys/un.h>
1411                 ])
1412
1413
1414
1415 # Checks for library functions.
1416 AC_FUNC_CLOSEDIR_VOID
1417 AC_FUNC_FORK
1418 AC_PROG_GCC_TRADITIONAL
1419 AC_FUNC_MEMCMP
1420 AC_FUNC_SELECT_ARGTYPES
1421 AC_FUNC_CHOWN
1422
1423 AC_TYPE_SIGNAL
1424 AC_FUNC_STAT
1425 AC_FUNC_STRFTIME
1426 AC_FUNC_VPRINTF
1427 AC_HEADER_SYS_WAIT
1428 AC_TYPE_OFF_T
1429 AC_TYPE_UID_T
1430 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1431
1432 # restore LIBS
1433 LIBS=$SAVE_LIBS
1434
1435 GN_INTLINCL=""
1436 GN_LIBINTL="$LTLIBINTL"
1437 AC_ARG_ENABLE(framework,
1438               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1439               enable_framework_build=$enableval)
1440 AM_CONDITIONAL(WANT_FRAMEWORK,
1441                test x$enable_framework_build = xyes)
1442 AS_IF([test x$enable_framework_build = xyes],
1443       [AC_DEFINE([FRAMEWORK_BUILD],
1444                  1,
1445                  [Build a Mac OS X Framework])
1446       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1447       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1448       AC_LIB_APPENDTOVAR([CPPFLAGS],
1449                          [$GN_INTLINCL])])
1450
1451 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1452 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1453
1454 AC_SUBST(GN_LIB_LDFLAGS)
1455 AC_SUBST(GN_PLUGIN_LDFLAGS)
1456 AC_SUBST(GN_INTLINCL)
1457 AC_SUBST(GN_LIBINTL)
1458
1459 AC_SUBST(CPPFLAGS)
1460 AC_SUBST(LIBS)
1461 AC_SUBST(LDFLAGS)
1462 AC_SUBST(EXT_LIB_PATH)
1463 AC_SUBST(EXT_LIBS)
1464
1465 AC_SUBST(LIBPREFIX)
1466 AC_SUBST(DLLDIR)
1467 AC_SUBST(EXT_LIB_PATH)
1468
1469 DATAROOTDIR=$datarootdir
1470 AC_SUBST(DATAROOTDIR)
1471
1472 # test for sudo
1473 AC_MSG_CHECKING(for sudo)
1474 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1475 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1476 AC_ARG_WITH(sudo,
1477            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1478            [AC_MSG_RESULT("$with_sudo")
1479             AS_CASE([$with_sudo],
1480                     [no],[SUDO_BINARY=],
1481                     [yes],[SUDO_BINARY=sudo],
1482                     [SUDO_BINARY=$with_sudo])],
1483            [AC_MSG_RESULT([no])])
1484 AC_SUBST(SUDO_BINARY)
1485 AM_CONDITIONAL([HAVE_SUDO],
1486               [test "x$SUDO_BINARY" != "x" -o -w /])
1487
1488 # test for doas
1489 AC_MSG_CHECKING(for doas)
1490 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1491 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1492
1493 # test for gnunetdns group name
1494 GNUNETDNS_GROUP=gnunetdns
1495 AC_MSG_CHECKING(for gnunetdns group name)
1496 AC_ARG_WITH(gnunetdns,
1497             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1498             [AC_MSG_RESULT("$with_gnunetdns")
1499              AS_CASE([$with_gnunetdns],
1500                      [no],[GNUNETDNS_GROUP=gnunet],
1501                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1502                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1503             [AC_MSG_RESULT([gnunetdns])])
1504 AC_SUBST(GNUNETDNS_GROUP)
1505
1506
1507
1508 # gnutls
1509 gnutls=0
1510 gnutls_dane=0
1511 AC_MSG_CHECKING(for gnutls)
1512 AC_ARG_WITH(gnutls,
1513             [  --with-gnutls=PFX   base of gnutls installation],
1514             [AC_MSG_RESULT([$with_gnutls])
1515              AS_CASE([$with_gnutls],
1516                      [no],[],
1517                      [yes],
1518                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1519                                        AC_CHECK_LIB([gnutls],
1520                                                     [gnutls_priority_set],
1521                                                     gnutls=true))
1522                       AC_CHECK_HEADERS([gnutls/dane.h],
1523                                        AC_CHECK_LIB([gnutls-dane],
1524                                                     [dane_verify_crt_raw],
1525                                                     gnutls_dane=1))],
1526
1527         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1528         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1529         AC_CHECK_HEADERS([gnutls/abstract.h],
1530             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1531               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1532               gnutls=true))
1533         AC_CHECK_HEADERS([gnutls/dane.h],
1534             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1535               gnutls_dane=1))
1536       ])
1537    ],
1538    [AC_MSG_RESULT([--with-gnutls not specified])
1539     AC_CHECK_HEADERS([gnutls/abstract.h],
1540         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1541           gnutls=true))
1542     AC_CHECK_HEADERS([gnutls/dane.h],
1543         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1544                      gnutls_dane=1))
1545    ])
1546 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1547 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1548 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1549 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1550
1551
1552
1553 # Test if we are building for superMUC
1554 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1555 AC_ARG_ENABLE([supermuc],
1556     [AS_HELP_STRING([--enable-supermuc],
1557        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1558     [AS_IF([test "x$enable_supermuc" = "xno"],
1559       [supermuc=0],
1560       [supermuc=1])],
1561     [supermuc=0
1562      enable_supermuc=no])
1563 AC_MSG_RESULT($enable_SUPERMUC)
1564 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1565 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1566
1567 # Check if NSE has to send timestamp information to testbed logger for
1568 # generating histogram of messages received
1569 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1570 AC_ARG_ENABLE([nse-histogram],
1571     [AS_HELP_STRING([--enable-nse-histogram],
1572        [have NSE send timestamp information to testbed logger for generating
1573        histogram of received messages.  NOT useful for production (default is
1574        NO)])],
1575     [AS_IF([test "x$enableval" = "xno"],
1576       [nse_histogram=0],
1577       [nse_histogram=1])],
1578     [nse_histogram=0
1579      enable_nse_histogram=no])
1580 AC_MSG_RESULT($enable_nse_histogram)
1581 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1582 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1583                    [have NSE send timestamp information to testbed logger])
1584
1585 # should 'make check' run tests?
1586 AC_MSG_CHECKING(whether to run tests)
1587 AC_ARG_ENABLE([testruns],
1588    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1589    [enable_tests_run=${enableval}],
1590    [enable_tests_run=yes])
1591 AC_MSG_RESULT($enable_test_run)
1592 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1593
1594
1595 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1596 AC_ARG_ENABLE([benchmark],
1597    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1598    [enable_benchmark=${enableval}],
1599    [enable_benchmark=no])
1600 AC_MSG_RESULT($enable_benchmark)
1601 AS_IF([test "x$enable_benchmark" = "xyes"],
1602       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1603 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1604
1605
1606 # should expensive tests be run?
1607 AC_MSG_CHECKING(whether to run expensive tests)
1608 AC_ARG_ENABLE([expensivetests],
1609    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1610    [enable_expensive=${enableval}],
1611    [enable_expensive=no])
1612 AC_MSG_RESULT($enable_expensive)
1613 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1614
1615 # should ports be open for Java services?
1616 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1617 AC_ARG_ENABLE([javaports],
1618    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1619    [enable_java_ports=${enableval}],
1620    [enable_java_ports=no])
1621 AC_MSG_RESULT($enable_java_ports)
1622 AS_IF([test "x$enable_java_ports" = "xyes"],
1623  [JAVAPORT=""],
1624  [JAVAPORT="$UNIXONLY"])
1625 AC_SUBST(JAVAPORT)
1626
1627 # should benchmarks be run?
1628 AC_MSG_CHECKING(whether to run benchmarks during make check)
1629 AC_ARG_ENABLE([benchmarks],
1630    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1631    [enable_benchmarks=${enableval}],
1632    [enable_benchmarks=no])
1633 AC_MSG_RESULT($enable_benchmarks)
1634 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1635
1636 # should gnunet-testing be compiled
1637 AC_MSG_CHECKING(wether to compile gnunet-testing)
1638 AC_ARG_ENABLE([testing],
1639    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1640    [enable_testing=${enableval}],
1641    [enable_testing=yes])
1642 AC_MSG_RESULT($enable_testing)
1643 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1644
1645 # should experimental code be compiled (code that may not yet compile)?
1646 AC_MSG_CHECKING(whether to compile experimental code)
1647 AC_ARG_ENABLE([experimental],
1648    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1649    [enable_experimental=${enableval}],
1650    [enable_experimental=no])
1651 AC_MSG_RESULT($enable_experimental)
1652 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1653
1654 # should malicious code be compiled (should only be used for testing)?
1655 AC_MSG_CHECKING(whether to compile malicious code)
1656 AC_ARG_ENABLE([malicious],
1657    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1658    [AS_IF([test "x$enableval" = "xno"],
1659      [malicious=0],
1660      [malicious=1])],
1661    [malicious=0
1662     enable_malicious=no])
1663 AC_MSG_RESULT($enable_malicious)
1664 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1665 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1666                    [enable compilation of malicious code])
1667
1668 # should services be started on demand when needed?
1669 # Some services may choose to never start by default
1670 # and it is up to the service/module developer to decide
1671 # by having "START_ON_DEMAND = NO" instead of
1672 # "START_ON_DEMAND = @START_ON_DEMAND@"
1673 # in the service/module's conf.in file.
1674 # See also IMMEDIATE_START for an unconditional immediate start.
1675 START_ON_DEMAND="YES"
1676 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1677 AC_ARG_ENABLE([autostart],
1678    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1679    [enable_autostart=${enableval}
1680     AS_IF([test "x$enable_autostart" = "xno"],
1681       [START_ON_DEMAND="NO"])
1682    ],
1683    [enable_autostart=yes])
1684 AC_MSG_RESULT($enable_autostart)
1685 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1686 AC_SUBST(START_ON_DEMAND)
1687
1688 # should memory statistics be kept (very expensive CPU-wise!)
1689 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1690 AC_ARG_ENABLE([heapstats],
1691    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1692    [enable_heapstats=1],
1693    [enable_heapstats=0])
1694 AC_MSG_RESULT($enable_heapstats)
1695 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1696
1697
1698 # Check if the __thread storage class for
1699 # thread-local storage is available.
1700 AC_MSG_CHECKING(whether __thread is supported)
1701 AC_LINK_IFELSE(
1702 [AC_LANG_PROGRAM([#include <stdlib.h>
1703                    #undef __thread
1704                    static __thread int a = 1;],
1705                   [exit(a-1);])],
1706  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1707 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1708 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1709       [AC_MSG_RESULT(yes)],
1710       [AC_MSG_RESULT(no)])
1711
1712 # gcov compilation
1713 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1714 AC_ARG_ENABLE([coverage],
1715               AS_HELP_STRING([--enable-coverage],
1716                              [compile the library with code coverage support]),
1717               [use_gcov=${enableval}],
1718               [use_gcov=no])
1719 AC_MSG_RESULT($use_gcov)
1720 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1721
1722
1723 # version info
1724 # TODO: git blame says this predates our switch to git.
1725 # git-svn should be adjusted to simply git, or
1726 # an external script that does the job.
1727 AC_PATH_PROG(svnversioncommand, svnversion)
1728 AC_PATH_PROG(gitcommand, git)
1729 AC_MSG_CHECKING(for source being under a VCS)
1730
1731
1732 # version info
1733 AC_PATH_PROG(gitcommand, git)
1734 AC_MSG_CHECKING(for source being under a VCS)
1735 git_version=
1736 AS_IF([test ! "X$gitcommand" = "X"],
1737 [
1738   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1739 ])
1740 AS_IF([test "X$git_version" = "X"],
1741   [
1742     vcs_name="no"
1743     vcs_version="\"release\""
1744   ],
1745   [
1746     vcs_name="yes, git-svn"
1747     vcs_version="\"git-$git_version\""
1748   ])
1749 AC_MSG_RESULT($vcs_name)
1750
1751 AC_MSG_CHECKING(VCS version)
1752 AC_MSG_RESULT($vcs_version)
1753 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1754
1755 AC_CONFIG_FILES([
1756 Makefile
1757 contrib/Makefile
1758 contrib/hellos/Makefile
1759 contrib/services/Makefile
1760 contrib/services/openrc/Makefile
1761 contrib/services/systemd/Makefile
1762 contrib/scripts/Makefile
1763 contrib/scripts/gnunet-logread/Makefile
1764 doc/Makefile
1765 doc/man/Makefile
1766 doc/doxygen/Makefile
1767 doc/handbook/Makefile
1768 doc/tutorial/Makefile
1769 lint/Makefile
1770 m4/Makefile
1771 po/Makefile.in
1772 src/Makefile
1773 src/arm/Makefile
1774 src/arm/arm.conf
1775 src/ats/Makefile
1776 src/ats/ats.conf
1777 src/ats-tool/Makefile
1778 src/ats-tests/Makefile
1779 src/auction/Makefile
1780 src/block/Makefile
1781 src/cadet/Makefile
1782 src/cadet/cadet.conf
1783 src/core/Makefile
1784 src/core/core.conf
1785 src/consensus/Makefile
1786 src/consensus/consensus.conf
1787 src/conversation/Makefile
1788 src/conversation/conversation.conf
1789 src/curl/Makefile
1790 src/datacache/Makefile
1791 src/datastore/Makefile
1792 src/datastore/datastore.conf
1793 src/dht/Makefile
1794 src/dht/dht.conf
1795 src/dns/Makefile
1796 src/dns/dns.conf
1797 src/exit/Makefile
1798 src/fragmentation/Makefile
1799 src/fs/Makefile
1800 src/fs/fs.conf
1801 src/gns/Makefile
1802 src/gns/gns.conf
1803 src/gns/nss/Makefile
1804 src/gnsrecord/Makefile
1805 src/hello/Makefile
1806 src/identity/Makefile
1807 src/identity/identity.conf
1808 src/abd/Makefile
1809 src/abd/abd.conf
1810 src/include/Makefile
1811 src/integration-tests/Makefile
1812 src/json/Makefile
1813 src/hostlist/Makefile
1814 src/my/Makefile
1815 src/mysql/Makefile
1816 src/namecache/Makefile
1817 src/namecache/namecache.conf
1818 src/namestore/Makefile
1819 src/namestore/namestore.conf
1820 src/nat/Makefile
1821 src/nat/nat.conf
1822 src/nat-auto/Makefile
1823 src/nat-auto/nat-auto.conf
1824 src/nse/Makefile
1825 src/nse/nse.conf
1826 src/nt/Makefile
1827 src/peerinfo/Makefile
1828 src/peerinfo/peerinfo.conf
1829 src/peerinfo-tool/Makefile
1830 src/peerstore/Makefile
1831 src/peerstore/peerstore.conf
1832 src/pq/Makefile
1833 src/pt/Makefile
1834 src/regex/Makefile
1835 src/regex/regex.conf
1836 src/revocation/Makefile
1837 src/revocation/revocation.conf
1838 src/rps/Makefile
1839 src/rps/rps.conf
1840 src/secretsharing/Makefile
1841 src/secretsharing/secretsharing.conf
1842 src/scalarproduct/Makefile
1843 src/scalarproduct/scalarproduct.conf
1844 src/set/Makefile
1845 src/set/set.conf
1846 src/sq/Makefile
1847 src/statistics/Makefile
1848 src/statistics/statistics.conf
1849 src/template/Makefile
1850 src/testbed/Makefile
1851 src/testbed/testbed.conf
1852 src/testbed-logger/Makefile
1853 src/testbed-logger/testbed-logger.conf
1854 src/testing/Makefile
1855 src/topology/Makefile
1856 src/transport/Makefile
1857 src/transport/transport.conf
1858 src/util/Makefile
1859 src/util/resolver.conf
1860 src/vpn/Makefile
1861 src/vpn/vpn.conf
1862 src/zonemaster/Makefile
1863 src/zonemaster/zonemaster.conf
1864 src/rest/Makefile
1865 src/abe/Makefile
1866 src/reclaim-attribute/Makefile
1867 src/reclaim/Makefile
1868 pkgconfig/Makefile
1869 pkgconfig/gnunetarm.pc
1870 pkgconfig/gnunetats.pc
1871 pkgconfig/gnunetblock.pc
1872 pkgconfig/gnunetcadet.pc
1873 pkgconfig/gnunetconsensus.pc
1874 pkgconfig/gnunetconversation.pc
1875 pkgconfig/gnunetcore.pc
1876 pkgconfig/gnunetdatacache.pc
1877 pkgconfig/gnunetdatastore.pc
1878 pkgconfig/gnunetdht.pc
1879 pkgconfig/gnunetdns.pc
1880 pkgconfig/gnunetenv.pc
1881 pkgconfig/gnunetfragmentation.pc
1882 pkgconfig/gnunetfs.pc
1883 pkgconfig/gnunetgns.pc
1884 pkgconfig/gnunethello.pc
1885 pkgconfig/gnunetidentity.pc
1886 pkgconfig/gnunetmicrophone.pc
1887 pkgconfig/gnunetmysql.pc
1888 pkgconfig/gnunetnamestore.pc
1889 pkgconfig/gnunetnat.pc
1890 pkgconfig/gnunetnse.pc
1891 pkgconfig/gnunetpeerinfo.pc
1892 pkgconfig/gnunetpq.pc
1893 pkgconfig/gnunetregex.pc
1894 pkgconfig/gnunetrevocation.pc
1895 pkgconfig/gnunetrps.pc
1896 pkgconfig/gnunetscalarproduct.pc
1897 pkgconfig/gnunetset.pc
1898 pkgconfig/gnunetspeaker.pc
1899 pkgconfig/gnunetstatistics.pc
1900 pkgconfig/gnunettestbed.pc
1901 pkgconfig/gnunettesting.pc
1902 pkgconfig/gnunettransport.pc
1903 pkgconfig/gnunetutil.pc
1904 pkgconfig/gnunetvpn.pc
1905 ])
1906 AC_OUTPUT
1907
1908
1909 # FIXME: `some modules' -> be more specific which exact modules.
1910
1911 # java ports
1912 AS_IF([test "x$enable_java_ports" = "xyes"],
1913       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1914
1915 ####
1916 #### Lasciate ogne speranza, voi ch'intrate
1917 ####
1918 #### This could be moved to the checks above,
1919 #### but for now let's keep it here.
1920 ####
1921
1922 # -- print message regarding enabled experimental features
1923 AS_IF([test "x$enable_experimental" = "xyes"],
1924       [experimental_msg="experimental features enabled"])
1925 # -- OSX Framework
1926 AS_IF([test "$enable_framework_build" = "yes"],
1927       [macosx_framework_msg="yes"],
1928       [macosx_framework_msg="no"])
1929 # -- libidn 2
1930 AS_IF([test "x$working_libidn2" = x1],
1931       [libidn2_msg="libidn2"])
1932 # -- libidn 1
1933 AS_IF([test "x$working_libidn1" = x1],
1934       [libidn1_msg="libidn1"])
1935 # -- texi2mdoc
1936 AS_IF([test "x$texi2mdoc_generation" = x1],
1937       [mdoc_msg="yes"],
1938       [mdoc_msg="no"])
1939 # -- texinfo
1940 AS_IF([test "x$makeinfo" != "x1"],
1941       [texinfo_msg="no"],
1942       [texinfo_msg="yes"])
1943 # -- conversation
1944 AS_IF([test "x$conversation_backend" = "xnone"],
1945       [AS_IF([test "x$pulse" != "x1"],
1946              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1947               libpulse_msg="no"],
1948              [libpulse_msg="yes"])
1949        AS_IF([test "x$opus" != "x1"],
1950              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1951               libopus_msg="no"],
1952              [libopus_msg="yes"])
1953        AS_IF([test "x$gst" != "x1"],
1954              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1955               gstreamer_msg="no"],
1956              [gstreamer_msg="yes"])],
1957       [features_msg="$features_msg conversation"])
1958 # -- interface
1959 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1960 # -- libmicrohttpd
1961 AS_IF([test "x$lmhd" != "x1"],
1962       [libmicrohttpd_msg="no (optional)"],
1963       [libmicrohttpd_msg="yes"])
1964 # -- jansson
1965 AS_IF([test "x$jansson" = "x0"],
1966       [jansson_msg="no (optional)"],
1967       [jansson_msg="yes"])
1968 # -- libextractor
1969 AS_IF([test "$extractor" != 1],
1970       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1971       [libextractor_msg="yes"])
1972 # -- libzbar
1973 AS_IF([test "x$zbar" = "x1"],
1974       [libzbar_msg="yes"
1975        features_msg="$features_msg gnunet-qr"],
1976       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1977        libzbar_msg="no"])
1978 # -- libgnurl
1979 AS_IF([test "$gnurl" = "0"],
1980       [AS_IF([test "x$curl" = "xfalse"],
1981              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1982               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1983               curl_msg="no"],
1984              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1985               curl_msg="yes"])],
1986        [gnurl_msg="yes"])
1987 # -- ifconfig
1988 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
1989       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
1990        ifconfig_msg="no (optional)"],
1991       [ifconfig_msg="yes"])
1992 # -- upnpc
1993 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
1994       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
1995        upnpc_msg="no (optional)"],
1996       [upnpc_msg="yes"])
1997 # -- iptables
1998 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
1999       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2000        iptables_msg="no (optional)"],
2001       [iptables_msg="yes"])
2002 # -- bluetooth
2003 AS_IF([test "x$bluetooth" = "x0"],
2004       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2005        bluetooth_msg="no (optional)"],
2006       [bluetooth_msg="yes"])
2007 # -- gnutls
2008 AS_IF([test x$gnutls != xtrue],
2009       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2010        gnutls_msg="no"],
2011       [AS_IF([test "x$gnutls_dane" != "x1"],
2012              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2013               gnutls_msg="yes (without DANE support)"],
2014              [gnutls_msg="yes (with DANE support)"])])
2015 # -- databases
2016 AS_IF([test $mysqlfail = true]
2017       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2018 AS_IF([test "$mysql" = true],
2019       [features_msg="$features_msg mysql"
2020        mysql_msg="yes"],
2021       [mysql_msg="no"])
2022 AS_IF([test "$sqlite" = true],
2023       [features_msg="$features_msg sqlite"
2024        sqlite_msg="yes"],
2025       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2026        sqlite_msg="no"])
2027 AS_IF([test "$postgres" = true],
2028       [features_msg="$features_msg postgres"
2029        postgres_msg="yes"],
2030       [postgres_msg="no"])
2031 # -- features
2032 # ---- 1. replace spaces with newlines,
2033 # ---- 2. sort the lines,
2034 # ---- 3. replace the newlines with spaces.
2035 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2036 AC_SUBST(features_msg)
2037
2038
2039 # The summary
2040 # TODO: reduce the length of the last message block ("the message")
2041
2042 AC_MSG_NOTICE([
2043 GNUnet Configuration
2044
2045 gnunet version:                 ${VERSION}
2046
2047 Host setup:                     ${host}
2048 Install prefix:                 ${prefix}
2049 Compiler:                       ${CC}
2050 CFLAGS:                         ${CFLAGS}
2051 CPPFLAGS:                       ${CPPFLAGS}
2052 LDFLAGS:                        ${LDFLAGS}
2053 LIBS:                           ${LIBS}
2054 Build Target:                   $build_target
2055 Mac OSX framework build:        ${macosx_framework_msg}
2056
2057 Default Interface:              ${interface_msg}
2058
2059 MySQL:                          ${mysql_msg}
2060 PostgreSQL:                     ${postgres_msg}
2061 sqlite3:                        ${sqlite_msg}
2062 gnurl:                          ${gnurl_msg}
2063 curl:                           ${curl_msg}
2064 bluetooth:                      ${bluetooth_msg}
2065 jansson:                        ${jansson_msg}
2066 iptables:                       ${iptables_msg}
2067 ifconfig:                       ${ifconfig_msg}
2068 upnpc:                          ${upnpc_msg}
2069 gnutls:                         ${gnutls_msg}
2070 libzbar:                        ${libzbar_msg}
2071 java:                           ${java_msg}
2072 libmicrohttpd:                  ${libmicrohttpd_msg}
2073 libidn:                         ${libidn1_msg}${libidn2_msg}
2074 libopus:                        ${libopus_msg}
2075 gstreamer:                      ${gstreamer_msg}
2076 libpulse:                       ${libpulse_msg}
2077 libextractor:                   ${libextractor_msg}
2078
2079 texinfo manual:                 ${texinfo_msg}
2080 transpiled mdoc manual:         ${mdoc_msg}
2081
2082 features:                       ${features_msg}
2083 experimental:                   ${experimental_msg}
2084
2085
2086 IMPORTANT:
2087
2088 Please make sure NOW that you have created a user and group 'gnunet'
2089 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2090 type:
2091
2092   addgroup gnunetdns
2093   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2094
2095 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2096 'gnunet'.  Then, you can compile GNUnet with
2097
2098   make
2099
2100 After that, run (if necessary as 'root')
2101
2102   make install
2103
2104 to install everything.
2105
2106 Each GNUnet user should be added to the 'gnunet' group (may
2107 require fresh login to come into effect):
2108
2109   adduser USERNAME gnunet
2110
2111 (run the above command as root once for each of your users, replacing
2112 "USERNAME" with the respective login names).  If you have a global IP
2113 address, no further configuration is required.
2114
2115 For more detailed setup instructions, see https://docs.gnunet.org/
2116
2117 Optionally, download and compile gnunet-gtk to get a GUI for
2118 file-sharing and configuration.  This is particularly recommended
2119 if your network setup is non-trivial, as gnunet-setup can be
2120 used to test in the GUI if your network configuration is working.
2121 gnunet-setup should be run as the "gnunet" user under X.  As it
2122 does very little with the network, running it as "root" is likely
2123 also harmless.  You can also run it as a normal user, but then
2124 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2125 home directory in the end.
2126
2127 Once you have configured your peer, run (as the 'gnunet' user)
2128
2129   gnunet-arm -s
2130
2131 to start the peer.  You can then run the various GNUnet-tools as
2132 your "normal" user (who should only be in the group 'gnunet').
2133 ])