configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.8], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 136      build_target="freebsd"
 137      LIBPREFIX=
 138      DLLDIR=lib
 139      UNIXONLY="#"
 140   ],
 141   [*openbsd*],[
 142      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 143      build_target="openbsd"
 144      use_openbsd_libtool=true
 145      LIBPREFIX=
 146      DLLDIR=lib
 147      UNIXONLY="#"
 148   ],
 149   [*netbsd*],[
 150      build_target="netbsd"
 151      LIBPREFIX=
 152      DLLDIR=lib
 153      UNIXONLY="#"
 154   ],
 155   [*solaris*],[
 156      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 157      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 158      AC_CHECK_LIB(resolv, res_init)
 159      AC_CHECK_LIB(rt, nanosleep)
 160      build_target="solaris"
 161      LIBPREFIX=
 162      DLLDIR=lib
 163      UNIXONLY="#"
 164   ],
 165   [*arm-linux*],[
 166      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 167      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 168      build_target="linux"
 169      LIBPREFIX=
 170      DLLDIR=lib
 171      UNIXONLY="#"
 172   ],
 173   [gnu*],[
 174      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 175      build_target="gnu"
 176      UNIXONLY="#"
 177   ],
 178   [
 179      AC_MSG_RESULT(Unrecognised OS $host_os)
 180      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 181      UNIXONLY=""
 182 ])
 183 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 184 AC_SUBST(DEFAULT_INTERFACE)
 185
 186 # Disable TCP-based IPC on systems that support UNIX domain
 187 # sockets in default configuratin:
 188 AC_SUBST(UNIXONLY)
 189
 190
 191 AC_MSG_CHECKING([for build target])
 192 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 193 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 194 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 195 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 196 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 197 # FIXME: We need a define BSD for some binaries like we
 198 # need define LINUX for some. This does not scale, how
 199 # can we solve this better?
 200 AM_CONDITIONAL(XBSD, test "$build_target" = "netbsd" -o "$build_target" = "freebsd" -o "$build_target" = "openbsd")
 201 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 202 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 203
 204 AC_MSG_RESULT([$build_target])
 205 AC_SUBST(build_target)
 206 AM_CONDITIONAL([am__fastdepOBJC], false)
 207 AC_UNALIGNED_64_ACCESS
 208
 209 # some other checks for standard libs
 210 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 211 AC_SEARCH_LIBS([memrchr], [],
 212                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 213 AC_SEARCH_LIBS([memset_s], [],
 214                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 215 AC_SEARCH_LIBS([memset_s], [],
 216                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 217 AC_CHECK_LIB(socket, socket)
 218 AC_CHECK_LIB(m, log)
 219 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 220
 221 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 222 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 223
 224 AC_CHECK_PROGS(PKG_CONFIG, [pkgconf, pkg-config], false)
 225 AM_CONDITIONAL(HAVE_PKG_CONFIG, test x$PKG_CONFIG != xfalse)
 226
 227 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 228 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 229 AC_MSG_CHECKING(for SSH key)
 230   AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 231   if test -f /tmp/gnunet_test_cosks_ssh_garbage; then
 232      rm -f /tmp/gnunet_test_cosks_ssh_garbage
 233   fi
 234
 235
 236 # autotools' m4 for python has no maximum version!
 237 # python3.4 - python3.8 for tests (3.8 unchecked)
 238 # TODO: document how to override the lowest version
 239 # TODO: found by this.
 240 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 241 AM_PATH_PYTHON([3.4],, [:])
 242 AC_SUBST([PYTHON])
 243 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 244
 245
 246 # perl
 247 AC_PATH_PROG( PERL, perl, ,
 248               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 249 AC_SUBST([PERL])
 250 AS_IF([test -x "$PERL"],
 251   [AC_DEFINE_UNQUOTED([HAVE_PERL], [1], [Path to Perl])],
 252   [AC_DEFINE_UNQUOTED([HAVE_PERL], [0], [Path to Perl])])
 253
 254 # awk
 255 AC_PATH_PROGS( AWK_BINARY, [awk gawk], ,$PATH:/usr/bin/:/usr/local/bin )
 256 AC_SUBST([AWK_BINARY])
 257 AS_IF([test -x "$AWK_BINARY"],
 258   [AC_DEFINE_UNQUOTED([HAVE_AWK], [1], [Path to awk])],
 259   [AC_DEFINE_UNQUOTED([HAVE_AWK], [0], [Path to awk])])
 260
 261 # should we install gnunet-logread?
 262 AC_MSG_CHECKING(whether to install gnunet-logread)
 263 AC_ARG_WITH([gnunet-logread],
 264               [AS_HELP_STRING([--with-gnunet-logread],
 265                               [Install gnunet-logread])],
 266               [logread=${withval}],
 267               [logread=no])
 268 AC_MSG_RESULT($logread)
 269 AS_IF([test "x$logread" = "xyes"],
 270       [AM_CONDITIONAL([GNUNET_LOGREAD], true)
 271        AC_DEFINE([GNUNET_LOGREAD],
 272                  [1],
 273                  [Installing gnunet-logread])],
 274       [AM_CONDITIONAL([GNUNET_LOGREAD],
 275                       false)
 276        AC_DEFINE([GNUNET_LOGREAD],
 277                  [0],
 278                  [Not installing gnunet-logread])])
 279
 280 # iptables is a soft requirement to run tests
 281 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 282
 283 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 284  [AS_IF([test -x "/sbin/iptables"],
 285    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 286    [AS_IF([test -x "/usr/sbin/iptables"],
 287       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 288
 289 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 290  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 291  [AC_MSG_WARN([warning: 'iptables' not found.])])
 292
 293 # ip6tables is a soft requirement for some features
 294 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 295
 296 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 297   [AS_IF([test -x "/sbin/ip6tables"],
 298      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 299      [AS_IF([test -x "/usr/sbin/ip6tables"],
 300         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 301
 302
 303 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 304   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 305   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 306
 307 # ip is a soft requirement for some features
 308 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 309
 310 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 311  [AS_IF([test -x "/sbin/ip"],
 312    [VAR_IP_BINARY="/sbin/ip"],
 313    [AS_IF([test -x "/usr/sbin/ip"],
 314           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 315
 316 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 317  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 318  [AC_MSG_WARN([warning: 'ip' not found.])])
 319
 320 # locate 'ifconfig'
 321 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 322
 323 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 324 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 325   [AS_IF([test -x "/sbin/ifconfig"],
 326      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 327      [AS_IF([test -x "/usr/sbin/ifconfig"],
 328             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 329
 330 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 331   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 332   [AC_MSG_WARN(['ifconfig' not found.])])
 333
 334
 335 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 336
 337 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 338 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 339       [AS_IF([test -x "/sbin/sysctl"],
 340              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 341              [AS_IF([test -x "/usr/sbin/sysctl"],
 342                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 343 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 344       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 345       [AC_MSG_WARN(['sysctl' not found.])])
 346
 347 # miniupnpc / upnpc binary is a soft runtime requirement
 348 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 349
 350 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 351   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 352   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 353
 354
 355 # checkbashisms
 356 AC_CHECK_PROGS(CHECKBASHISMS_BINARY, [checkbashisms checkbashisms.pl], false)
 357 AM_CONDITIONAL(HAVE_CHECKBASHISMS, test x$CHECKBASHISMS_BINARY != xfalse)
 358
 359 # uncrustify
 360 # TODO: maybe add flag to pass location
 361 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 362 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 363
 364 # yapf
 365 # TODO: less repetition, add flag to pass name
 366 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 367 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 368
 369
 370 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 371   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 372      [Define if struct tm has the tm_gmtoff member.])],
 373      ,
 374      [#include <time.h>])
 375
 376 # 'save' libs; only those libs found so far will be
 377 # linked against _everywhere_.  For the others, we
 378 # will be more selective!
 379 SAVE_LIBS=$LIBS
 380
 381 have_addrinfo_a=0
 382 AC_CHECK_LIB(anl,
 383              getaddrinfo_a,
 384              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 385                                           1,
 386                                           [getaddrinfo_a supported])])
 387 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 388                [test "$have_addrinfo_a" = 1])
 389
 390 # libgcrypt
 391 gcrypt=0
 392 NEED_LIBGCRYPT_API=1
 393 NEED_LIBGCRYPT_VERSION=1.6.0
 394
 395
 396 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 397 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 398
 399 AS_IF([test $gcrypt = 0],
 400  [
 401   AC_MSG_ERROR([[
 402 ***
 403 *** You need libgcrypt to build this program.
 404 *** This library is for example available at
 405 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 406 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 407 ***  is required.
 408 ***]])
 409 ])
 410 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 411
 412 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 413
 414 AC_CHECK_HEADER([if_tun.h],
 415     [AC_DEFINE([IF_TUN_HDR], ["if_tun.h"], [if_tun.h include path])],
 416     [AC_CHECK_HEADER([linux/if_tun.h],
 417         [AC_DEFINE([IF_TUN_HDR], ["linux/if_tun.h"])],
 418         [AC_CHECK_HEADER([net/if_tun.h],
 419             [AC_DEFINE([IF_TUN_HDR], ["net/if_tun.h"])],
 420             [AC_CHECK_HEADER([net/tun/if_tun.h],
 421                 [AC_DEFINE([IF_TUN_HDR], ["net/tun/if_tun.h"])])])])])
 422
 423
 424 # should the build process be building the documentation?
 425 AC_MSG_CHECKING(whether to build documentation)
 426 AC_ARG_ENABLE([documentation],
 427               [AS_HELP_STRING([--disable-documentation],
 428                               [do not build the documentation])],
 429               [documentation=${enableval}],
 430               [documentation=yes])
 431 AC_MSG_RESULT($documentation)
 432 AS_IF([test "x$documentation" = "xyes"],
 433       [AM_CONDITIONAL([DOCUMENTATION],
 434                       true)
 435        AC_DEFINE([DOCUMENTATION],
 436                  [1],
 437                  [Building the documentation])],
 438       [AM_CONDITIONAL([DOCUMENTATION],
 439                       false)
 440        AC_DEFINE([DOCUMENTATION],
 441                  [0],
 442                  [Not building the documentation])])
 443
 444 # COMMENT: Check whether to transpile texinfo to mdoc.
 445 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 446 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 447 # COMMENT: and makes the configure fail if it is missing.
 448 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 449 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 450 # COMMENT: or nothing was set (this is the default).
 451 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 452 # COMMENT: potential non-existence of the texi2mdoc binary.
 453 # COMMENT: Default return value / setting: no
 454 AC_MSG_CHECKING(whether to include generated texi2mdoc output in installation)
 455 AC_ARG_ENABLE([texi2mdoc-generation],
 456               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 457                               [include generated texi2mdoc output in installation])],
 458               [texi2mdoc_generation=${enableval}],
 459               [texi2mdoc_generation=no])
 460 AC_MSG_RESULT($texi2mdoc_generation)
 461 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 462       [AS_IF([test "$texi2mdoc" = 0],
 463              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 464               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 465               AC_MSG_WARN([ERROR: Operating System package manager or from])
 466               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 467              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 468               AC_DEFINE([TEXI2MDOC_GENERATION],
 469                         [1],
 470                         [Building section 7 mdoc output])])],
 471       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 472                       false)
 473        AC_DEFINE([TEXI2MDOC_GENERATION],
 474                  [0],
 475                  [Not building section 7 mdoc output])])
 476
 477 # test for texi2mdoc (the binary, not the script distributed
 478 # with autogen)
 479 # TODO: refactor this and the check above.
 480 AC_MSG_CHECKING(for texi2mdoc binary)
 481 AC_CHECK_PROGS(TEXI2MDOC_BINARY, [texi2mdoc], false)
 482 AM_CONDITIONAL(HAVE_TEXI2MDOC, test x$TEXI2MDOC_BINARY != xfalse)
 483
 484 # texi2man is a tool which needs to be investigated and
 485 # is probably incompatible to texi2mdoc in invocation.
 486 # Detection at this point only serves as a reminder that
 487 # I will work this into the build-system.
 488 AC_MSG_CHECKING(for texi2man perl script)
 489 AC_CHECK_PROGS(TEXI2MAN_SCRIPT, [texi2man], false)
 490 AM_CONDITIONAL(HAVE_TEXI2MAN, test x$TEXI2MAN_SCRIPT != xfalse)
 491
 492
 493 # test for mandoc
 494 AC_MSG_CHECKING(for mandoc binary)
 495 AC_CHECK_PROGS(MANDOC_BINARY, [mandoc], false)
 496 AM_CONDITIONAL(HAVE_MANDOC, test x$MANDOC_BINARY != xfalse)
 497
 498 # should the build process be building only the documentation?
 499 AC_MSG_CHECKING(whether to build only documentation)
 500 AC_ARG_ENABLE([documentation-only],
 501    [AS_HELP_STRING([--enable-documentation-only],
 502                    [build only the documentation])],
 503    [documentation_only=${enableval}],
 504    [documentation_only=no])
 505 AC_MSG_RESULT($documentation_only)
 506 AS_IF([test "x$documentation_only" = "xyes"],
 507  [
 508   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 509   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 510  ],[
 511   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 512   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 513  ])
 514
 515 # should the build process be including the manpages? (default: yes)
 516 AC_MSG_CHECKING(whether to include man pages)
 517 AC_ARG_ENABLE([include-manpages],
 518    [AS_HELP_STRING([--disable-include-manpages],
 519                    [Do not include the man pages in build and installation])],
 520    [include_manpages=${enableval}],
 521    [include_manpages=yes])
 522 AC_MSG_RESULT($include_manpages)
 523 AS_IF([test "x$include_manpages" = "xyes"],
 524  [
 525   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 526   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 527  ],[
 528   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 529   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 530  ])
 531
 532 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 533 # (not syntax!) to the commandline tools which generate the html. If not,
 534 # texinfo5 switches are used. This comes with no version checks, is
 535 # enabled only at distributors action (ie defaults to "no").
 536 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 537 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 538 AC_ARG_ENABLE([texinfo4],
 539    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 540    [activate_texinfo4=${enableval}],
 541    [activate_texinfo4=no])
 542 AC_MSG_RESULT($activate_texinfo4)
 543 AS_IF([test "x$activate_texinfo4" = "xyes"],
 544  [
 545   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 546   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 547  ],[
 548   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 549   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 550  ])
 551
 552
 553 # Adam shostack suggests the following for Windows:
 554 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 555 AC_ARG_ENABLE(gcc-hardening,
 556    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 557 [AS_IF([test x$enableval = xyes],[
 558     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 559     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 560     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 561     LDFLAGS="$LDFLAGS -pie"
 562  ])])
 563
 564 # Linker hardening options
 565 # Currently these options are ELF specific - you can't use this with MacOSX
 566 AC_ARG_ENABLE(linker-hardening,
 567   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 568 [AS_IF([test x$enableval = xyes],
 569    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 570
 571
 572 AC_ARG_ENABLE(sanitizer,
 573   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 574 [AS_IF([test x$enableval = xyes],[
 575    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 576  ])])
 577
 578
 579 extra_logging=GNUNET_NO
 580 AC_ARG_ENABLE([logging],
 581    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 582    [AS_IF([test "x$enableval" = "xyes"], [],
 583           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 584           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 585           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 586    ], [])
 587 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 588
 589 # should memory poisoning be enabled?
 590 AC_MSG_CHECKING(whether to poison freed memory)
 591 AC_ARG_ENABLE([poisoning],
 592    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 593    [enable_poisoning=${enableval}],
 594    [
 595      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 596        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 597        [enable_poisoning=no])
 598    ])
 599 AC_MSG_RESULT($enable_poisoning)
 600 AS_IF([test ! "x$enable_poisoning" = "xno"],
 601   [enable_poisoning=1],
 602   [enable_poisoning=0])
 603 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 604
 605 AS_IF([test $build = $target],
 606 [
 607 AC_MSG_CHECKING([for working HMAC])
 608 AC_LANG_PUSH(C)
 609 LIBS="$LIBS $LIBGCRYPT_LIBS"
 610 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 611 AC_RUN_IFELSE(
 612   [AC_LANG_PROGRAM([#include <gcrypt.h>
 613         #include <stdio.h>], [[
 614         gcry_md_hd_t mac;
 615
 616         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 617             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 618             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 619         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 620         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 621             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 622             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 623             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 624             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 625             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 626
 627         if (!gcry_check_version (GCRYPT_VERSION))
 628         {
 629           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 630           return 1;
 631         }
 632
 633         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 634         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 635
 636         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 637         {
 638           fprintf (stderr, "gcry_md_open error\n");
 639           return 2;
 640         }
 641
 642         gcry_md_setkey (mac, key, sizeof (key));
 643         gcry_md_write (mac, data, sizeof (data));
 644
 645         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 646         {
 647           fprintf (stderr, "memcmp error\n");
 648           return 3;
 649         }
 650
 651         gcry_md_close (mac);
 652
 653         return 0;
 654     ]])],
 655   [AC_MSG_RESULT([yes])],
 656   [
 657    RESULT=$?
 658    if test $RESULT = 3
 659    then
 660      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 661    fi
 662    if test $RESULT = 2
 663    then
 664      AC_MSG_FAILURE([HMAC test failed])
 665    fi
 666    if test $RESULT = 1
 667    then
 668      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 669    fi
 670   ],
 671   [AC_MSG_RESULT([cross compiling, test skipped])])
 672 AC_LANG_POP(C)
 673 ])      # $build = $target
 674
 675 # check for bluetooth library
 676 bluetooth=0
 677 AC_MSG_CHECKING(for libbluetooth)
 678 AC_ARG_WITH(libbluetooth,
 679     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 680     [AC_MSG_RESULT([$with_libbluetooth])
 681      AS_CASE([$with_libbluetooth],
 682         [no],[],
 683         [yes],[
 684             CHECK_LIBHEADER(BLUETOOTH,
 685                             bluetooth,
 686                             ba2str,
 687                             bluetooth/bluetooth.h,
 688                             bluetooth=1,)
 689         ],[
 690             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 691             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 692             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 693                              AC_CHECK_LIB([bluetooth],
 694                                           [ba2str],
 695                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 696                                           bluetooth=1))
 697         ])
 698     ],
 699     [AC_MSG_RESULT([--with-libbluetooth not specified])
 700      CHECK_LIBHEADER(BLUETOOTH,
 701                      bluetooth,
 702                      ba2str,
 703                      bluetooth/bluetooth.h,
 704                      bluetooth=1,)])
 705 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 706 AS_IF([test "$bluetooth" = 1],
 707       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 708       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 709
 710 # check for zbar library
 711 # NOTE: Do not add checks for: -lSM, -lICE, -lX11, -lXv and -ljpeg
 712 # NOTE: they must be provided by the build environment, not the
 713 # NOTE: build-system of gnunet, as they are 2nd or 3rd level dependencies.
 714 zbar=0
 715 AC_MSG_CHECKING(for libzbar)
 716 AC_ARG_WITH(zbar,
 717    [  --with-zbar=PREFIX (base of libzbar installation)],
 718    [AC_MSG_RESULT([$with_zbar])
 719     AS_CASE([$with_zbar],
 720       [no],[],
 721       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 722       [
 723         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 724         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 725         AC_CHECK_HEADERS(zbar.h,
 726           AC_CHECK_LIB([zbar], [zbar_processor_create],
 727             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 728             zbar=1))
 729        ])
 730    ],
 731    [AC_MSG_RESULT([--with-zbar not specified])
 732     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 733 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 734 AS_IF([test "x$zbar" = x1],
 735       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 736       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 737
 738 # check for jansson library
 739 jansson=0
 740 AC_MSG_CHECKING(for libjansson)
 741 AC_ARG_WITH(jansson,
 742    [  --with-jansson=PREFIX (base of libjansson installation)],
 743    [AC_MSG_RESULT([$with_jansson])
 744     AS_CASE([$with_jansson],
 745       [no],[],
 746       [yes],[
 747         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 748       ],[
 749         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 750         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 751         AC_CHECK_HEADERS(jansson.h,
 752           AC_CHECK_LIB([jansson], [json_loads],
 753             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 754             jansson=1))
 755       ])
 756    ],
 757    [AC_MSG_RESULT([--with-jansson not specified])
 758     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 759 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 760 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 761 AS_IF([test "x$jansson" = x1],
 762       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 763       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 764
 765
 766 # check for libpulse(audio) library
 767 pulse=0
 768 libpulse_msg="no"
 769 AC_MSG_CHECKING(for libpulse)
 770 # TODO: --with-libpulse or --with-pulseaudio? What is more established
 771 # TODO: in this context?
 772 AC_ARG_WITH(libpulse,
 773     [  --with-libpulse=PREFIX (base of libpulse installation)],
 774     [AC_MSG_RESULT([$with_libpulse])
 775      AS_CASE([$with_libpulse],
 776         [no],[],
 777         [yes],[
 778             CHECK_LIBHEADER(LIBPULSE,
 779                             pulse,
 780                             pa_stream_peek,
 781                             pulse/simple.h,
 782                             pulse=1,)
 783         ],[
 784             LDFLAGS="-L$with_libpulse/lib $LDFLAGS"
 785             CPPFLAGS="-I$with_libpulse/include $CPPFLAGS"
 786             AC_CHECK_HEADERS(pulse/simple.h,
 787                              AC_CHECK_LIB([pulse],
 788                                           [pa_stream_peek],
 789                                           EXT_LIB_PATH="-L$with_libpulse/lib $EXT_LIB_PATH"
 790                                           pulse=1))
 791         ])
 792     ],
 793     [AC_MSG_RESULT([--with-libpulse not specified])
 794      CHECK_LIBHEADER(LIBPULSE,
 795                      pulse,
 796                      pa_stream_peek,
 797                      pulse/simple.h,
 798                      pulse=1,)])
 799 AM_CONDITIONAL(HAVE_PULSE, [test "$pulse" = 1])
 800 AS_IF([test x"$pulse" = x1],
 801       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 802        libpulse_msg="yes"],
 803       [AC_DEFINE([HAVE_PULSE],[0],[Lacking libpulse(audio) library])
 804        libpulse_msg="no"])
 805
 806 # check for libopus(audio) library
 807 opus=0
 808 libopus_msg="no"
 809 AC_MSG_CHECKING(for libopus)
 810 AC_ARG_WITH(libopus,
 811     [  --with-libopus=PREFIX (base of libopus installation)],
 812     [AC_MSG_RESULT([$with_libopus])
 813      AS_CASE([$with_libopus],
 814         [no],[],
 815         [yes],[
 816             CHECK_LIBHEADER(LIBOPUS,
 817                             opus,
 818                             opus_decode_float,
 819                             opus/opus.h,
 820                             AC_CHECK_DECL([OPUS_SET_GAIN],
 821                                           [opus=1],
 822                                           [],
 823                                           [[
 824                                           #include <opus/opus.h>
 825                                           ]]))
 826     ],[
 827         LDFLAGS="-L$with_libopus/lib $LDFLAGS"
 828         CPPFLAGS="-I$with_libopus/include $CPPFLAGS"
 829         AC_CHECK_HEADERS(opus/opus.h,
 830                          AC_CHECK_LIB([opus],
 831                                       [OPUS_SET_GAIN],
 832                                       EXT_LIB_PATH="-L$with_libopus/lib $EXT_LIB_PATH"
 833                                       opus=1))
 834       ])
 835     ],
 836     [AC_MSG_RESULT([--with-libopus not specified])
 837      CHECK_LIBHEADER(LIBOPUS,
 838                      opus,
 839                      opus_decode_float,
 840                      opus/opus.h,
 841                      AC_CHECK_DECL([OPUS_SET_GAIN],
 842                                    [opus=1],
 843                                    [],
 844                                    [[
 845                                      #include <opus/opus.h>
 846                                    ]]))])
 847 AM_CONDITIONAL(HAVE_OPUS, [test "$opus" = 1])
 848 AS_IF([test "x$opus" = x1],
 849       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 850        libopus_msg="yes"],
 851       [AC_DEFINE([HAVE_OPUS],[0],[Lacking libopus library])
 852        libopus_msg="no"])
 853
 854 # libogg
 855 AC_MSG_CHECKING(for libogg)
 856 AC_ARG_WITH(libogg,
 857     [  --with-libogg=PREFIX (base of libogg installation)],
 858     [AC_MSG_RESULT([$with_libogg])
 859      AS_CASE([$with_libogg],
 860         [no],[],
 861         [yes],[
 862             CHECK_LIBHEADER(LIBOGG,
 863                             ogg,
 864                             ogg_stream_flush_fill,
 865                             ogg/ogg.h,
 866                             ogg=1,)
 867         ],[
 868             LDFLAGS="-L$with_libogg/lib $LDFLAGS"
 869             CPPFLAGS="-I$with_libogg/include $CPPFLAGS"
 870             AC_CHECK_HEADERS(ogg/ogg.h,
 871                              AC_CHECK_LIB([ogg],
 872                                           [ogg_stream_flush_fill],
 873                                           EXT_LIB_PATH="-L$with_libogg/lib $EXT_LIB_PATH"
 874                                           ogg=1))
 875         ])
 876      ],
 877      [AC_MSG_RESULT([--with-libogg not specified])
 878       CHECK_LIBHEADER(LIBOGG,
 879                       ogg,
 880                       ogg_stream_flush_fill,
 881                       ogg/ogg.h,
 882                       ogg=1,)])
 883 AM_CONDITIONAL(HAVE_OGG, [test "$ogg" = 1])
 884 AS_IF([test x"$ogg" = x1],
 885       [AC_DEFINE([HAVE_OGG],[1],[Have ogg])]
 886       [AC_DEFINE([HAVE_OGG],[0],[Lacking ogg])])
 887
 888
 889 PKG_CHECK_MODULES([GLIB],
 890                   [glib-2.0],
 891   [# check for pbc library
 892   pbc=0
 893    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 894    AC_CHECK_HEADER([gabe.h],abe=1)
 895    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 896    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 897    AS_IF([test "x$pbc" = x1],
 898      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 899      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 900    AS_IF([test "x$abe" = x1],
 901     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 902     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 903   [# glib-2 not found
 904    AM_CONDITIONAL(HAVE_PBC, [false])
 905    AM_CONDITIONAL(HAVE_ABE, [false])
 906    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 907
 908
 909 gst=0
 910 gstreamer_msg="no"
 911 AC_MSG_CHECKING(for gstreamer)
 912 PKG_CHECK_MODULES(
 913   [GST],
 914   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 915   [gst=1
 916    gstreamer_msg="yes"],
 917   [gst=0])
 918
 919 # conversation
 920 AC_MSG_CHECKING(conversation feature set to build)
 921 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 922  AS_IF([test "x$gst" != "x1"],[
 923   conversation_backend=none
 924   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 925   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 926   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 927  ],[
 928    conversation_backend=gst
 929    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 930    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 931    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 932  ])
 933 ],[
 934  conversation_backend=pulse
 935  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 936  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 937  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 938 ])
 939
 940 AS_IF([test "x$conversation_backend" = "xnone"],
 941       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 942       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 943
 944 # libgnurl
 945 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 946
 947 SAVE_CPPFLAGS=$CPPFLAGS
 948 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 949 LIBS="$LIBGNURL $LIBCURL $LIBS"
 950
 951 # libcurl-gnutls
 952 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 953 AS_IF([test "x$curl" = xtrue],[
 954  AC_CHECK_HEADER([curl/curl.h],
 955   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 956   [curl=false])
 957  # need libcurl-gnutls.so, everything else is not acceptable
 958  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 959  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 960 ])
 961
 962 # libcurl and libgnurl should be mutually exclusive
 963 AS_IF([test "$gnurl" = 1],
 964       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 965        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 966        AM_CONDITIONAL(HAVE_LIBCURL, false)
 967        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 968       [AS_IF([test "$curl" = true],
 969              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 970               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 971               AM_CONDITIONAL(HAVE_LIBCURL, true)
 972               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 973              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 974               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 975               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 976               AM_CONDITIONAL(HAVE_LIBCURL, false)
 977               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 978
 979 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 980 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 981
 982 # restore LIBS & CPPFLAGS
 983 LIBS=$SAVE_LIBS
 984 CPPFLAGS=$SAVE_CPPFLAGS
 985
 986
 987 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 988 AS_IF([test x$nss = xfalse],
 989   [
 990         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 991         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 992   ],[
 993         NSS_INCLUDES="
 994         #include <nss.h>
 995         "
 996         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 997                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 998                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 999                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
1000                 [$NSS_INCLUDES])
1001 ])
1002
1003
1004
1005 # test for kvm and kstat (for CPU stats under BSD/Solaris)
1006 AC_CHECK_LIB([kvm],[kvm_open])
1007 AC_CHECK_LIB([kstat],[kstat_open])
1008
1009
1010 # should the build process be restricted to the code required
1011 # for GNU Taler wallets?
1012 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
1013 AC_ARG_ENABLE([taler-wallet],
1014    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
1015    [taler_only=${enableval}],
1016    [taler_only=no])
1017 AC_MSG_RESULT($taler_only)
1018 AS_IF([test "x$taler_only" = "xyes"],
1019 [
1020   AM_CONDITIONAL([TALER_ONLY],true)
1021   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
1022 ],[
1023   AM_CONDITIONAL([TALER_ONLY],false)
1024   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
1025 ])
1026
1027 # test for libextractor
1028 extractor=0
1029 AC_MSG_CHECKING(for libextractor)
1030 AC_ARG_WITH(extractor,
1031    [  --with-extractor=PREFIX (base of libextractor installation)],
1032    [AC_MSG_RESULT([$with_extractor])
1033     AS_CASE([$with_extractor],
1034       [no],[],
1035       [yes],[
1036         AC_CHECK_HEADERS([extractor.h],
1037           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1038             extractor=1))
1039       ],[
1040         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
1041         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
1042         AC_CHECK_HEADERS([extractor.h],
1043           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1044             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
1045             extractor=1))
1046       ])
1047    ],
1048    [AC_MSG_RESULT([--with-extractor not specified])
1049     AC_CHECK_HEADERS([extractor.h],
1050      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1051       extractor=1))])
1052 # restore LIBS
1053 LIBS=$SAVE_LIBS
1054
1055 AS_IF([test "$extractor" != 1],
1056  [
1057  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
1058  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
1059  ],[
1060  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
1061  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
1062  ])
1063
1064
1065 AS_IF([test "$taler_only" != yes],[
1066
1067
1068 # Check for libltdl header (#2999)
1069 ltdl=0
1070 AC_MSG_CHECKING(for libltdl)
1071 AC_ARG_WITH(ltdl,
1072    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
1073    [AC_MSG_RESULT([$with_ltdl])
1074     AS_CASE([$with_ltdl],
1075       [no],[],
1076       [yes],[
1077         AC_CHECK_HEADERS(ltdl.h,
1078           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1079             ltdl=1))
1080       ],[
1081         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
1082         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
1083         AC_CHECK_HEADERS(ltdl.h,
1084           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1085             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
1086             ltdl=1))
1087       ])
1088    ],
1089    [AC_MSG_RESULT([--with-ltdl not specified])
1090     AC_CHECK_HEADERS(ltdl.h,
1091      AC_CHECK_LIB([ltdl], [lt_dlopenext],
1092       ltdl=1))])
1093 AS_IF([test x$ltdl = x1],
1094 [
1095  AC_MSG_RESULT([libltdl found])
1096 ],[
1097  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool).])
1098 ])
1099 # restore LIBS
1100 LIBS=$SAVE_LIBS
1101
1102 # libidn and libidn2. The ideal goal is this:
1103 # check for libidn2, if it doesn't exist check for libidn
1104 # if both exist, prefer libidn2
1105 # if none exist, fail and message that libidn or libidn2
1106 # is required with a preference for libidn2.
1107 # TODO: What we have right here can probably be improved.
1108 AC_MSG_CHECKING(for idn or idn2)
1109
1110 AC_MSG_CHECKING(for idn)
1111 my_with_libidn=1
1112 AC_ARG_WITH(libidn,
1113             AS_HELP_STRING([--with-libidn=pathname],
1114                            [Support IDN (needs libidn)]),
1115             [],
1116             [withval="yes"])
1117 AS_IF([test x_$withval = x_yes],
1118       [AC_CHECK_HEADERS([idna.h],
1119                         AC_MSG_NOTICE([Found idna.h]),
1120                         AC_CHECK_HEADERS([idn/idna.h],
1121                                          AC_MSG_NOTICE([Found idn/idna.h]),
1122                                          my_with_libidn=0))],
1123       [AS_IF([test x_$withval != x_no],
1124              [CFLAGS="$CFLAGS -I$withval/include"
1125               LDFLAGS="$LDFLAGS -L$withval/lib"
1126               AC_CHECK_HEADERS([idna.h],
1127                                AC_MSG_NOTICE([Found idna.h]),
1128                                    [AC_MSG_NOTICE([Failed to find idna.h])
1129                                my_with_libidn=0])],
1130              [my_with_libidn=0])])
1131
1132 AC_MSG_CHECKING(for idn2)
1133 my_with_libidn2=1
1134 AC_ARG_WITH(libidn2,
1135             AS_HELP_STRING([--with-libidn2=pathname],
1136                            [Support IDN (needs libidn2)]),
1137             [],
1138             [withval="yes"])
1139 AS_IF([test x_$withval = x_yes],
1140       [AC_CHECK_HEADERS([idn2.h],
1141                         AC_MSG_NOTICE([Found idn2.h]),
1142                         AC_CHECK_HEADERS([idn2/idn2.h],
1143                                          AC_MSG_NOTICE([Found idn2/idn2.h]),
1144                                          [AC_MSG_NOTICE([Failed to find idn2.h])
1145                                          my_with_libidn2=0]))],
1146       [AS_IF([test x_$withval != x_no],
1147              [CFLAGS="$CFLAGS -I$withval/include"
1148               LDFLAGS="$LDFLAGS -L$withval/lib"],
1149                   [my_with_libidn2=0])])
1150
1151 AC_MSG_CHECKING([if libidn can be used])
1152 # Check for LIBIDNs
1153 there_can_only_be_one=1
1154
1155 working_libidn1=0
1156 working_libidn2=0
1157 AS_IF([test x$my_with_libidn2 = x1],
1158       [AC_MSG_NOTICE([Checking for libidn2])
1159        AC_CHECK_LIB([idn2],
1160                     [idn2_to_unicode_8z8z],
1161                     [working_libidn2=1
1162                     LIBS="-lidn2 $LIBS"
1163                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1164                                        [1],
1165                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1166                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1167                      MISSING_SEP=", "])])
1168 AM_CONDITIONAL(HAVE_LIBIDN2, test x$working_libidn2 = x1)
1169 AS_IF([test x$working_libidn2 = x0],
1170       [AS_IF([test x$my_with_libidn = x1],
1171              [AC_MSG_NOTICE([Checking for libidn])
1172               AC_CHECK_LIB([idn],
1173                            [idna_to_ascii_8z],
1174                            [working_libidn1=1
1175                            LIBS="-lidn $LIBS"
1176                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1177                                               [1],
1178                                               [Define to 1 if you have 'libidn' (-lidn).])],
1179                            [there_can_only_be_one=0])],
1180              [AS_IF([test x$my_with_libidn2 = x1],
1181                     [there_can_only_be_one=0
1182                      AC_MSG_FAILURE([* There can only be one libidn.
1183                                      * Provide either libidn >= 1.13
1184                                      * or
1185                                      * libidn2 to the configure
1186                                      * script via
1187                                      * --with-libidn2
1188                                      * --with-libidn])])])])
1189 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1190
1191 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1192       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1193
1194 AS_IF([test x$there_can_only_be_one = x0],
1195       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1196
1197 # test for zlib
1198 SAVE_LDFLAGS=$LDFLAGS
1199 SAVE_CPPFLAGS=$CPPFLAGS
1200 AC_ARG_WITH(zlib,
1201             [  --with-zlib[[=DIR]]       use libz in DIR],
1202             [AS_IF([test "$withval" = "no"],
1203                    [AC_MSG_ERROR([GNUnet requires zlib])],
1204                    [test "$withval" != "yes"],
1205                    [Z_DIR=$withval
1206                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1207                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1208 AC_CHECK_HEADER(zlib.h,
1209                 [],
1210                 [AC_MSG_ERROR([GNUnet requires zlib])])
1211 AC_CHECK_LIB(z,
1212              compress2,
1213              [AC_DEFINE([HAVE_ZLIB],
1214                         [],
1215                         [Have compression library])
1216               if test "x${Z_DIR}" != "x"; then
1217                       Z_CFLAGS="-I${Z_DIR}/include"
1218                       Z_LIBS="-L${Z_DIR}/lib -lz"
1219               else
1220                       Z_LIBS="-lz"
1221               fi],
1222               [AC_MSG_ERROR([GNUnet requires zlib])])
1223 AC_SUBST(Z_CFLAGS)
1224 AC_SUBST(Z_LIBS)
1225
1226 AS_IF([test "$enable_shared" = "no"],
1227       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1228
1229
1230 # restore LIBS
1231 LIBS=$SAVE_LIBS
1232
1233
1234 # end of taler-only being false
1235 ])
1236
1237
1238 # check for iconv
1239 AM_ICONV
1240
1241 # test for libunistring
1242 gl_LIBUNISTRING
1243 AS_IF([test $HAVE_LIBUNISTRING != yes],
1244       [AC_MSG_ERROR([GNUnet requires libunistring])])
1245
1246 # under emscripten, $gl_libunistring_hexversion is undefined
1247 if test "$taler_only" != yes; then
1248
1249 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1250       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1251 fi
1252 AC_CHECK_HEADERS([unistr.h],
1253                  ,
1254                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1255
1256 # restore LIBS
1257 LIBS=$SAVE_LIBS
1258
1259
1260
1261 # Checks for standard header files.
1262 AC_HEADER_DIRENT
1263 AC_HEADER_STDC
1264
1265 # Check for headers that are ALWAYS required
1266 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1267
1268
1269
1270 # Checks for headers that are only required on some systems or
1271 # opional (and where we do NOT abort if they are not there)
1272 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1273
1274 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1275 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1276 [#ifdef HAVE_SYS_TYPES_H
1277 #include <sys/types.h>
1278 #endif
1279 #ifdef HAVE_NETINET_IN_SYSTM_H
1280 #include <netinet/in_systm.h>
1281 #endif
1282 #ifdef HAVE_NETINET_IN_H
1283 #include <netinet/in.h>
1284 #endif
1285 ])
1286
1287 SAVE_LDFLAGS=$LDFLAGS
1288 SAVE_CPPFLAGS=$CPPFLAGS
1289
1290 # test for sqlite
1291 sqlite=false
1292 AC_MSG_CHECKING(for SQLite)
1293 AC_ARG_WITH(sqlite,
1294   [  --with-sqlite=PFX       base of SQLite installation],
1295   [AC_MSG_RESULT("$with_sqlite")
1296    AS_CASE([$with_sqlite],
1297      [no],[],
1298      [yes],[
1299       AC_CHECK_HEADERS(sqlite3.h,
1300       sqlite=true)],
1301      [
1302     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1303     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1304     AC_CHECK_HEADERS(sqlite3.h,
1305      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1306      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1307      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1308      sqlite=true)
1309     LDFLAGS=$SAVE_LDFLAGS
1310     CPPFLAGS=$SAVE_CPPFLAGS
1311     ])
1312   ],
1313   [AC_MSG_RESULT([--with-sqlite not specified])
1314     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1315 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1316 AC_SUBST(SQLITE_CPPFLAGS)
1317 AC_SUBST(SQLITE_LDFLAGS)
1318
1319 LDFLAGS=$SAVE_LDFLAGS
1320 CPPFLAGS=$SAVE_CPPFLAGS
1321
1322 # test for postgres:
1323 postgres=false
1324 # even running the check for postgres breaks emscripten
1325 AS_IF([test "$taler_only" != yes],
1326       [AX_LIB_POSTGRESQL([9.5],
1327         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1328          AC_CHECK_HEADERS([libpq-fe.h],
1329          postgres=true)
1330         ],
1331         [AC_MSG_RESULT([no postgres])])])
1332
1333 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1334 AS_IF([test "x$postgres" = xtrue],
1335       [AC_DEFINE([HAVE_POSTGRESQL],[1],[Have PostgreSQL])],
1336       [AC_DEFINE([HAVE_POSTGRESQL],[0],[Lacking PostgreSQL])])
1337
1338 LDFLAGS=$SAVE_LDFLAGS
1339 CPPFLAGS=$SAVE_CPPFLAGS
1340
1341 # mysql & windows
1342 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1343 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1344
1345 # test for mysql
1346 mysql=false
1347 mysqlfail=false
1348 SAVE_LDFLAGS=$LDFLAGS
1349 SAVE_CPPFLAGS=$CPPFLAGS
1350 AC_MSG_CHECKING(for mysql)
1351 AC_ARG_WITH(mysql,
1352   [  --with-mysql=PFX        base of MySQL installation],
1353   [AC_MSG_RESULT([$with_mysql])
1354    AS_CASE([$with_mysql],
1355      [no],[],
1356      [yes|""],[
1357       AC_CHECK_HEADERS(mysql/mysql.h,
1358        AC_CHECK_LIB(mysqlclient, mysql_init,
1359        mysql=true), [], [])
1360      ],[
1361       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1362       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1363       AC_CHECK_HEADERS(mysql/mysql.h,
1364        AC_CHECK_LIB(mysqlclient, mysql_init,
1365         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1366         MYSQL_CPPFLAGS="-I$with_mysql/include"
1367
1368         mysql=true), [], [])
1369      ])
1370   ],
1371   [AC_MSG_RESULT([--with-mysql not specified])
1372    if test -d "/usr/lib64/mysql"; then
1373     MYSQL_LIBDIR="/usr/lib64/mysql"
1374    elif test -d "/usr/lib/mysql"; then
1375     MYSQL_LIBDIR="/usr/lib/mysql"
1376    else
1377     MYSQL_LIBDIR="/usr/lib"
1378    fi
1379    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1380    AC_CHECK_LIB(mysqlclient, mysql_init,
1381     [AC_CHECK_HEADERS(mysql/mysql.h,
1382       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1383       mysql=true
1384
1385      , [], [])])
1386   ])
1387
1388 AC_SUBST(MYSQL_LDFLAGS)
1389 AC_SUBST(MYSQL_CPPFLAGS)
1390
1391 # additional version check for mysql
1392 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1393 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1394  [
1395   AC_MSG_CHECKING(mysql version)
1396   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1397     [[
1398       #include <mysql/mysql.h>]],
1399     [[
1400       #if (MYSQL_VERSION_ID < 40100)
1401       #error needs at least version >= 4.1
1402       #endif
1403       int main () { return 0; }
1404     ]])
1405     ],mysql=true,mysql=false)
1406   AS_IF([test "$mysql" = "false"],
1407    [
1408     mysqlfail=true
1409     AC_MSG_RESULT([fail, >= 4.1 required])
1410    ],[
1411     AC_MSG_RESULT(ok)
1412    ])
1413 ])
1414 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1415 AM_CONDITIONAL(HAVE_MYSQLE, false)
1416 # restore LIBS
1417 LIBS=$SAVE_LIBS
1418 LDFLAGS=$SAVE_LDFLAGS
1419 CPPFLAGS=$SAVE_CPPFLAGS
1420
1421 # TODO: should this test for "or" not "and"?
1422 # TODO: Add postgres?
1423 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1424 [
1425  AC_MSG_ERROR([GNUnet requires SQLite or MySQL / MariaDB.])
1426 ])
1427
1428 # libmicrohttpd
1429 lmhd=0
1430 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1431 AC_ARG_WITH(microhttpd,
1432    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1433        [base of libmicrohttpd installation])],
1434    [],
1435    [with_microhttpd=check])
1436 AS_CASE([$with_microhttpd],
1437    [no], [],
1438    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1439    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1440        [lmhd=1],
1441        [AC_MSG_WARN([Building without libmicrohttpd])])],
1442    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1443     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1444     export PKG_CONFIG_PATH
1445     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1446     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1447 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1448 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1449
1450 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1451
1452 # restore LIBS
1453 LIBS=$SAVE_LIBS
1454
1455 # check for gettext
1456 AM_GNU_GETTEXT([external])
1457 AM_GNU_GETTEXT_VERSION([0.18.1])
1458
1459 # Checks for standard typedefs, structures, and compiler characteristics.
1460 AC_TYPE_PID_T
1461 AC_TYPE_SIZE_T
1462 AC_TYPE_MODE_T
1463 AC_HEADER_TIME
1464 AC_HEADER_STAT
1465 AC_HEADER_STDBOOL
1466 AC_STRUCT_TM
1467
1468 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1469    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1470    ],
1471    [],
1472    [
1473       #include <sys/types.h>
1474       #include <sys/socket.h>
1475       #include <netinet/in.h>
1476    ])
1477
1478 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1479                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1480                             1,
1481                             [Do we have sockaddr_un.sun_len?])],
1482                 [],
1483                 [
1484                 #include <sys/types.h>
1485                 #include <sys/socket.h>
1486                 #include <sys/un.h>
1487                 ])
1488
1489
1490
1491 # Checks for library functions.
1492 AC_FUNC_CLOSEDIR_VOID
1493 AC_FUNC_FORK
1494 AC_PROG_GCC_TRADITIONAL
1495 AC_FUNC_MEMCMP
1496 AC_FUNC_SELECT_ARGTYPES
1497 AC_FUNC_CHOWN
1498
1499 AC_TYPE_SIGNAL
1500 AC_FUNC_STAT
1501 AC_FUNC_STRFTIME
1502 AC_FUNC_VPRINTF
1503 AC_HEADER_SYS_WAIT
1504 AC_TYPE_OFF_T
1505 AC_TYPE_UID_T
1506 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1507
1508 # restore LIBS
1509 LIBS=$SAVE_LIBS
1510
1511 GN_INTLINCL=""
1512 GN_LIBINTL="$LTLIBINTL"
1513 AC_ARG_ENABLE(framework,
1514               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1515               enable_framework_build=$enableval)
1516 AM_CONDITIONAL(WANT_FRAMEWORK,
1517                test x$enable_framework_build = xyes)
1518 AS_IF([test x$enable_framework_build = xyes],
1519       [AC_DEFINE([FRAMEWORK_BUILD],
1520                  1,
1521                  [Build a Mac OS X Framework])
1522       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1523       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1524       AC_LIB_APPENDTOVAR([CPPFLAGS],
1525                          [$GN_INTLINCL])])
1526
1527 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1528 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1529
1530 AC_SUBST(GN_LIB_LDFLAGS)
1531 AC_SUBST(GN_PLUGIN_LDFLAGS)
1532 AC_SUBST(GN_INTLINCL)
1533 AC_SUBST(GN_LIBINTL)
1534
1535 AC_SUBST(CPPFLAGS)
1536 AC_SUBST(LIBS)
1537 AC_SUBST(LDFLAGS)
1538 AC_SUBST(EXT_LIB_PATH)
1539 AC_SUBST(EXT_LIBS)
1540
1541 AC_SUBST(LIBPREFIX)
1542 AC_SUBST(DLLDIR)
1543 AC_SUBST(EXT_LIB_PATH)
1544
1545 DATAROOTDIR=$datarootdir
1546 AC_SUBST(DATAROOTDIR)
1547
1548 # test for sudo
1549 AC_MSG_CHECKING(for sudo)
1550 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1551 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1552 AC_ARG_WITH(sudo,
1553            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1554            [AC_MSG_RESULT("$with_sudo")
1555             AS_CASE([$with_sudo],
1556                     [no],[SUDO_BINARY=],
1557                     [yes],[SUDO_BINARY=sudo],
1558                     [SUDO_BINARY=$with_sudo])],
1559            [AC_MSG_RESULT([no])])
1560 AC_SUBST(SUDO_BINARY)
1561 AM_CONDITIONAL([HAVE_SUDO],
1562               [test "x$SUDO_BINARY" != "x" -o -w /])
1563
1564 # test for doas
1565 AC_MSG_CHECKING(for doas)
1566 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1567 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1568
1569 # test for gnunetdns group name
1570 GNUNETDNS_GROUP=gnunetdns
1571 AC_MSG_CHECKING(for gnunetdns group name)
1572 AC_ARG_WITH(gnunetdns,
1573             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1574             [AC_MSG_RESULT("$with_gnunetdns")
1575              AS_CASE([$with_gnunetdns],
1576                      [no],[GNUNETDNS_GROUP=gnunet],
1577                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1578                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1579             [AC_MSG_RESULT([gnunetdns])])
1580 AC_SUBST(GNUNETDNS_GROUP)
1581
1582
1583
1584 # gnutls
1585 gnutls=0
1586 gnutls_dane=0
1587 AC_MSG_CHECKING(for gnutls)
1588 AC_ARG_WITH(gnutls,
1589             [  --with-gnutls=PFX   base of gnutls installation],
1590             [AC_MSG_RESULT([$with_gnutls])
1591              AS_CASE([$with_gnutls],
1592                      [no],[],
1593                      [yes],
1594                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1595                                        AC_CHECK_LIB([gnutls],
1596                                                     [gnutls_priority_set],
1597                                                     gnutls=true))
1598                       AC_CHECK_HEADERS([gnutls/dane.h],
1599                                        AC_CHECK_LIB([gnutls-dane],
1600                                                     [dane_verify_crt_raw],
1601                                                     gnutls_dane=1))],
1602
1603         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1604         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1605         AC_CHECK_HEADERS([gnutls/abstract.h],
1606             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1607               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1608               gnutls=true))
1609         AC_CHECK_HEADERS([gnutls/dane.h],
1610             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1611               gnutls_dane=1))
1612       ])
1613    ],
1614    [AC_MSG_RESULT([--with-gnutls not specified])
1615     AC_CHECK_HEADERS([gnutls/abstract.h],
1616         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1617           gnutls=true))
1618     AC_CHECK_HEADERS([gnutls/dane.h],
1619         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1620                      gnutls_dane=1))
1621    ])
1622 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1623 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1624 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1625 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1626
1627
1628
1629 # Test if we are building for superMUC
1630 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1631 AC_ARG_ENABLE([supermuc],
1632     [AS_HELP_STRING([--enable-supermuc],
1633        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1634     [AS_IF([test "x$enable_supermuc" = "xno"],
1635       [supermuc=0],
1636       [supermuc=1])],
1637     [supermuc=0
1638      enable_supermuc=no])
1639 AC_MSG_RESULT($enable_SUPERMUC)
1640 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1641 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1642
1643 # Check if NSE has to send timestamp information to testbed logger for
1644 # generating histogram of messages received
1645 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1646 AC_ARG_ENABLE([nse-histogram],
1647     [AS_HELP_STRING([--enable-nse-histogram],
1648        [have NSE send timestamp information to testbed logger for generating
1649        histogram of received messages.  NOT useful for production (default is
1650        NO)])],
1651     [AS_IF([test "x$enableval" = "xno"],
1652       [nse_histogram=0],
1653       [nse_histogram=1])],
1654     [nse_histogram=0
1655      enable_nse_histogram=no])
1656 AC_MSG_RESULT($enable_nse_histogram)
1657 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1658 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1659                    [have NSE send timestamp information to testbed logger])
1660
1661 # should 'make check' run tests?
1662 AC_MSG_CHECKING(whether to run tests)
1663 AC_ARG_ENABLE([testruns],
1664    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1665    [enable_tests_run=${enableval}],
1666    [enable_tests_run=yes])
1667 AC_MSG_RESULT($enable_test_run)
1668 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1669
1670
1671 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1672 AC_ARG_ENABLE([benchmark],
1673    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1674    [enable_benchmark=${enableval}],
1675    [enable_benchmark=no])
1676 AC_MSG_RESULT($enable_benchmark)
1677 AS_IF([test "x$enable_benchmark" = "xyes"],
1678       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1679 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1680
1681
1682 # should expensive tests be run?
1683 AC_MSG_CHECKING(whether to run expensive tests)
1684 AC_ARG_ENABLE([expensivetests],
1685    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1686    [enable_expensive=${enableval}],
1687    [enable_expensive=no])
1688 AC_MSG_RESULT($enable_expensive)
1689 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1690
1691 # should ports be open for Java services?
1692 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1693 AC_ARG_ENABLE([javaports],
1694    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1695    [enable_java_ports=${enableval}],
1696    [enable_java_ports=no])
1697 AC_MSG_RESULT($enable_java_ports)
1698 AS_IF([test "x$enable_java_ports" = "xyes"],
1699  [JAVAPORT=""],
1700  [JAVAPORT="$UNIXONLY"])
1701 AC_SUBST(JAVAPORT)
1702
1703 # should benchmarks be run?
1704 AC_MSG_CHECKING(whether to run benchmarks during make check)
1705 AC_ARG_ENABLE([benchmarks],
1706    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1707    [enable_benchmarks=${enableval}],
1708    [enable_benchmarks=no])
1709 AC_MSG_RESULT($enable_benchmarks)
1710 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1711
1712 # should gnunet-testing be compiled
1713 AC_MSG_CHECKING(whether to compile gnunet-testing)
1714 AC_ARG_ENABLE([testing],
1715    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1716    [enable_testing=${enableval}],
1717    [enable_testing=yes])
1718 AC_MSG_RESULT($enable_testing)
1719 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1720
1721 # should experimental code be compiled (code that may not yet compile)?
1722 AC_MSG_CHECKING(whether to compile experimental code)
1723 AC_ARG_ENABLE([experimental],
1724    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1725    [enable_experimental=${enableval}],
1726    [enable_experimental=no])
1727 AC_MSG_RESULT($enable_experimental)
1728 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1729
1730 # should malicious code be compiled (should only be used for testing)?
1731 AC_MSG_CHECKING(whether to compile malicious code)
1732 AC_ARG_ENABLE([malicious],
1733    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1734    [AS_IF([test "x$enableval" = "xno"],
1735      [malicious=0],
1736      [malicious=1])],
1737    [malicious=0
1738     enable_malicious=no])
1739 AC_MSG_RESULT($enable_malicious)
1740 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1741 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1742                    [enable compilation of malicious code])
1743
1744 # should services be started on demand when needed?
1745 # Some services may choose to never start by default
1746 # and it is up to the service/module developer to decide
1747 # by having "START_ON_DEMAND = NO" instead of
1748 # "START_ON_DEMAND = @START_ON_DEMAND@"
1749 # in the service/module's conf.in file.
1750 # See also IMMEDIATE_START for an unconditional immediate start.
1751 START_ON_DEMAND="YES"
1752 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1753 AC_ARG_ENABLE([autostart],
1754    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1755    [enable_autostart=${enableval}
1756     AS_IF([test "x$enable_autostart" = "xno"],
1757       [START_ON_DEMAND="NO"])
1758    ],
1759    [enable_autostart=yes])
1760 AC_MSG_RESULT($enable_autostart)
1761 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1762 AC_SUBST(START_ON_DEMAND)
1763
1764 # should memory statistics be kept (very expensive CPU-wise!)
1765 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1766 AC_ARG_ENABLE([heapstats],
1767    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1768    [enable_heapstats=1],
1769    [enable_heapstats=0])
1770 AC_MSG_RESULT($enable_heapstats)
1771 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1772
1773
1774 # Check if the __thread storage class for
1775 # thread-local storage is available.
1776 AC_MSG_CHECKING(whether __thread is supported)
1777 AC_LINK_IFELSE(
1778 [AC_LANG_PROGRAM([#include <stdlib.h>
1779                    #undef __thread
1780                    static __thread int a = 1;],
1781                   [exit(a-1);])],
1782  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1783 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1784 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1785       [AC_MSG_RESULT(yes)],
1786       [AC_MSG_RESULT(no)])
1787
1788 # gcov compilation
1789 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1790 AC_ARG_ENABLE([coverage],
1791               AS_HELP_STRING([--enable-coverage],
1792                              [compile the library with code coverage support]),
1793               [use_gcov=${enableval}],
1794               [use_gcov=no])
1795 AC_MSG_RESULT($use_gcov)
1796 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1797
1798
1799 # version info
1800 # TODO: git blame says this predates our switch to git.
1801 # git-svn should be adjusted to simply git, or
1802 # an external script that does the job.
1803 AC_PATH_PROG(svnversioncommand, svnversion)
1804 AC_PATH_PROG(gitcommand, git)
1805 AC_MSG_CHECKING(for source being under a VCS)
1806
1807
1808 # version info
1809 AC_PATH_PROG(gitcommand, git)
1810 AC_MSG_CHECKING(for source being under a VCS)
1811 git_version=
1812 AS_IF([test ! "X$gitcommand" = "X"],
1813 [
1814   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1815 ])
1816 AS_IF([test "X$git_version" = "X"],
1817   [
1818     vcs_name="no"
1819     vcs_version="\"release\""
1820   ],
1821   [
1822     vcs_name="yes, git-svn"
1823     vcs_version="\"git-$git_version\""
1824   ])
1825 AC_MSG_RESULT($vcs_name)
1826
1827 AC_MSG_CHECKING(VCS version)
1828 AC_MSG_RESULT($vcs_version)
1829 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1830
1831 AC_CONFIG_FILES([
1832 Makefile
1833 contrib/Makefile
1834 contrib/hellos/Makefile
1835 contrib/services/Makefile
1836 contrib/services/openrc/Makefile
1837 contrib/services/systemd/Makefile
1838 contrib/scripts/Makefile
1839 contrib/scripts/gnunet-logread/Makefile
1840 doc/Makefile
1841 doc/man/Makefile
1842 doc/doxygen/Makefile
1843 doc/handbook/Makefile
1844 doc/tutorial/Makefile
1845 m4/Makefile
1846 po/Makefile.in
1847 src/Makefile
1848 src/arm/Makefile
1849 src/arm/arm.conf
1850 src/ats/Makefile
1851 src/ats/ats.conf
1852 src/ats-tool/Makefile
1853 src/ats-tests/Makefile
1854 src/auction/Makefile
1855 src/block/Makefile
1856 src/cadet/Makefile
1857 src/cadet/cadet.conf
1858 src/core/Makefile
1859 src/core/core.conf
1860 src/consensus/Makefile
1861 src/consensus/consensus.conf
1862 src/conversation/Makefile
1863 src/conversation/conversation.conf
1864 src/curl/Makefile
1865 src/datacache/Makefile
1866 src/datastore/Makefile
1867 src/datastore/datastore.conf
1868 src/dht/Makefile
1869 src/dht/dht.conf
1870 src/dns/Makefile
1871 src/dns/dns.conf
1872 src/exit/Makefile
1873 src/fragmentation/Makefile
1874 src/fs/Makefile
1875 src/fs/fs.conf
1876 src/gns/Makefile
1877 src/gns/gns.conf
1878 src/gns/nss/Makefile
1879 src/gnsrecord/Makefile
1880 src/hello/Makefile
1881 src/identity/Makefile
1882 src/identity/identity.conf
1883 src/abd/Makefile
1884 src/abd/abd.conf
1885 src/include/Makefile
1886 src/integration-tests/Makefile
1887 src/json/Makefile
1888 src/hostlist/Makefile
1889 src/my/Makefile
1890 src/mysql/Makefile
1891 src/namecache/Makefile
1892 src/namecache/namecache.conf
1893 src/namestore/Makefile
1894 src/namestore/namestore.conf
1895 src/nat/Makefile
1896 src/nat/nat.conf
1897 src/nat-auto/Makefile
1898 src/nat-auto/nat-auto.conf
1899 src/nse/Makefile
1900 src/nse/nse.conf
1901 src/nt/Makefile
1902 src/peerinfo/Makefile
1903 src/peerinfo/peerinfo.conf
1904 src/peerinfo-tool/Makefile
1905 src/peerstore/Makefile
1906 src/peerstore/peerstore.conf
1907 src/pq/Makefile
1908 src/pt/Makefile
1909 src/regex/Makefile
1910 src/regex/regex.conf
1911 src/revocation/Makefile
1912 src/revocation/revocation.conf
1913 src/rps/Makefile
1914 src/rps/rps.conf
1915 src/secretsharing/Makefile
1916 src/secretsharing/secretsharing.conf
1917 src/scalarproduct/Makefile
1918 src/scalarproduct/scalarproduct.conf
1919 src/set/Makefile
1920 src/set/set.conf
1921 src/sq/Makefile
1922 src/statistics/Makefile
1923 src/statistics/statistics.conf
1924 src/template/Makefile
1925 src/testbed/Makefile
1926 src/testbed/testbed.conf
1927 src/testbed-logger/Makefile
1928 src/testbed-logger/testbed-logger.conf
1929 src/testing/Makefile
1930 src/topology/Makefile
1931 src/transport/Makefile
1932 src/transport/transport.conf
1933 src/util/Makefile
1934 src/util/resolver.conf
1935 src/vpn/Makefile
1936 src/vpn/vpn.conf
1937 src/zonemaster/Makefile
1938 src/zonemaster/zonemaster.conf
1939 src/rest/Makefile
1940 src/abe/Makefile
1941 src/reclaim-attribute/Makefile
1942 src/reclaim/Makefile
1943 pkgconfig/Makefile
1944 pkgconfig/gnunetarm.pc
1945 pkgconfig/gnunetats.pc
1946 pkgconfig/gnunetblock.pc
1947 pkgconfig/gnunetcadet.pc
1948 pkgconfig/gnunetconsensus.pc
1949 pkgconfig/gnunetconversation.pc
1950 pkgconfig/gnunetcore.pc
1951 pkgconfig/gnunetdatacache.pc
1952 pkgconfig/gnunetdatastore.pc
1953 pkgconfig/gnunetdht.pc
1954 pkgconfig/gnunetdns.pc
1955 pkgconfig/gnunetenv.pc
1956 pkgconfig/gnunetfragmentation.pc
1957 pkgconfig/gnunetfs.pc
1958 pkgconfig/gnunetgns.pc
1959 pkgconfig/gnunethello.pc
1960 pkgconfig/gnunetidentity.pc
1961 pkgconfig/gnunetmicrophone.pc
1962 pkgconfig/gnunetmysql.pc
1963 pkgconfig/gnunetnamestore.pc
1964 pkgconfig/gnunetnat.pc
1965 pkgconfig/gnunetnse.pc
1966 pkgconfig/gnunetpeerinfo.pc
1967 pkgconfig/gnunetpq.pc
1968 pkgconfig/gnunetregex.pc
1969 pkgconfig/gnunetrevocation.pc
1970 pkgconfig/gnunetrps.pc
1971 pkgconfig/gnunetscalarproduct.pc
1972 pkgconfig/gnunetset.pc
1973 pkgconfig/gnunetspeaker.pc
1974 pkgconfig/gnunetstatistics.pc
1975 pkgconfig/gnunettestbed.pc
1976 pkgconfig/gnunettesting.pc
1977 pkgconfig/gnunettransport.pc
1978 pkgconfig/gnunetutil.pc
1979 pkgconfig/gnunetvpn.pc
1980 ])
1981 AC_OUTPUT
1982
1983
1984 # FIXME: `some modules' -> be more specific which exact modules.
1985
1986 # java ports
1987 AS_IF([test "x$enable_java_ports" = "xyes"],
1988       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1989
1990 ####
1991 #### Lasciate ogne speranza, voi ch'intrate
1992 ####
1993 #### This could be moved to the checks above,
1994 #### but for now let's keep it here.
1995 ####
1996
1997 # TODO: We use "WARNING" too often, we need to clarify what
1998 # TODO: constitutes a WARNING, an ERROR, and a NOTICE, and
1999 # TODO: other message levels.
2000
2001 # -- print message regarding enabled experimental features
2002 AS_IF([test "x$enable_experimental" = "xyes"],
2003       [experimental_msg="experimental features enabled"])
2004 # -- OSX Framework
2005 AS_IF([test "$enable_framework_build" = "yes"],
2006       [macosx_framework_msg="yes"],
2007       [macosx_framework_msg="no"])
2008 # -- libidn 2
2009 AS_IF([test "x$working_libidn2" = x1],
2010       [libidn2_msg="libidn2"])
2011 # -- libidn 1
2012 AS_IF([test "x$working_libidn1" = x1],
2013       [libidn1_msg="libidn1"])
2014 # -- texi2mdoc-generation
2015 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
2016       [mdocml_msg="yes"],
2017       [mdocml_msg="no"])
2018 # -- texi2mdoc
2019 AS_IF([test "x$TEXI2MDOC_BINARY" = "false"],
2020       [AC_MSG_NOTICE([WARNING: optional texi2mdoc binary not found])
2021        texi2mdoc_msg="no (optional)"],
2022       [texi2mdoc_msg="yes"])
2023 # -- mandoc
2024 AS_IF([test "x$MANDOC_BINARY" = "false"],
2025       [AC_MSG_NOTICE([WARNING: optional mandoc binary not found])
2026        mandoc_msg="no"],
2027       [mandoc_msg="yes"])
2028 # -- texinfo
2029 AS_IF([test "x$makeinfo" != "x1"],
2030       [texinfo_msg="no"],
2031       [texinfo_msg="yes"])
2032 # -- conversation
2033 AS_IF([test "x$conversation_backend" = "xnone"],
2034       [AS_IF([test "x$pulse" != "x1"],
2035              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found (required to build conversation against it).])
2036               libpulse_msg="no"],
2037              [libpulse_msg="yes"])
2038        AS_IF([test "x$opus" != "x1"],
2039              [AC_MSG_NOTICE([WARNING: libopus not found (conversation)])
2040               libopus_msg="no"],
2041              [libopus_msg="yes"])
2042        AS_IF([test "x$gst" != "x1"],
2043              [AC_MSG_NOTICE([WARNING: GStreamer not found (required to build conversation against it).])
2044               gstreamer_msg="no"],
2045              [gstreamer_msg="yes"])],
2046       [features_msg="$features_msg conversation"])
2047 # -- interface
2048 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2049 # -- libmicrohttpd
2050 AS_IF([test "x$lmhd" != "x1"],
2051       [libmicrohttpd_msg="no (optional)"],
2052       [libmicrohttpd_msg="yes"])
2053 # -- jansson
2054 AS_IF([test "x$jansson" = "x0"],
2055       [jansson_msg="no (optional)"],
2056       [jansson_msg="yes"])
2057 # -- libextractor
2058 AS_IF([test "$extractor" != 1],
2059       [AC_MSG_WARN([WARNING: libextractor not found, but various file-sharing functions require it])],
2060       [libextractor_msg="yes"])
2061 # -- libzbar
2062 AS_IF([test "x$zbar" = "x1"],
2063       [libzbar_msg="yes"
2064        features_msg="$features_msg gnunet-qr"],
2065       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
2066        libzbar_msg="no"])
2067 # -- libgnurl
2068 AS_IF([test "$gnurl" = "0"],
2069       [AS_IF([test "x$curl" = "xfalse"],
2070              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
2071               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2072               curl_msg="no"],
2073              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
2074               curl_msg="yes"])],
2075        [gnurl_msg="yes"])
2076 # -- ifconfig
2077 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2078       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2079        ifconfig_msg="no (optional)"],
2080       [ifconfig_msg="yes"])
2081 # -- upnpc
2082 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2083       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2084        upnpc_msg="no (optional)"],
2085       [upnpc_msg="yes"])
2086 # -- iptables
2087 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2088       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2089        iptables_msg="no (optional)"],
2090       [iptables_msg="yes"])
2091 # -- bluetooth
2092 AS_IF([test "x$bluetooth" = "x0"],
2093       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2094        bluetooth_msg="no (optional)"],
2095       [bluetooth_msg="yes"])
2096 # -- gnutls
2097 AS_IF([test x$gnutls != xtrue],
2098       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2099        gnutls_msg="no"],
2100       [AS_IF([test "x$gnutls_dane" != "x1"],
2101              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2102               gnutls_msg="yes (without DANE support)"],
2103              [gnutls_msg="yes (with DANE support)"])])
2104 # -- databases
2105 # TODO: this always returns true, the check might
2106 # TODO: not be working as intended (for msqlfail).
2107 AS_IF([test x$mysqlfail = "true"]
2108       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2109 AS_IF([test "$mysql" = true],
2110       [features_msg="$features_msg mysql"
2111        mysql_msg="yes"],
2112       [mysql_msg="no"])
2113 AS_IF([test "$sqlite" = true],
2114       [features_msg="$features_msg sqlite"
2115        sqlite_msg="yes"],
2116       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2117        sqlite_msg="no"])
2118 AS_IF([test "$postgres" = true],
2119       [features_msg="$features_msg postgres"
2120        postgres_msg="yes"],
2121       [postgres_msg="no"])
2122 # -- features
2123 # ---- 1. replace spaces with newlines,
2124 # ---- 2. sort the lines,
2125 # ---- 3. replace the newlines with spaces.
2126 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2127 AC_SUBST(features_msg)
2128
2129
2130 # The summary
2131 # TODO: reduce the length of the last message block, following "IMPORTANT".
2132
2133 AC_MSG_NOTICE([
2134 GNUnet Configuration
2135
2136 gnunet version:                 ${VERSION}
2137
2138 Host setup:                     ${host}
2139 Install prefix:                 ${prefix}
2140 Compiler:                       ${CC}
2141 CFLAGS:                         ${CFLAGS}
2142 CPPFLAGS:                       ${CPPFLAGS}
2143 LDFLAGS:                        ${LDFLAGS}
2144 LIBS:                           ${LIBS}
2145 Build Target:                   $build_target
2146 Mac OSX framework build:        ${macosx_framework_msg}
2147
2148 Default Interface:              ${interface_msg}
2149
2150 MySQL:                          ${mysql_msg}
2151 PostgreSQL:                     ${postgres_msg}
2152 sqlite3:                        ${sqlite_msg}
2153 gnurl:                          ${gnurl_msg}
2154 curl:                           ${curl_msg}
2155 bluetooth:                      ${bluetooth_msg}
2156 jansson:                        ${jansson_msg}
2157 iptables:                       ${iptables_msg}
2158 ifconfig:                       ${ifconfig_msg}
2159 upnpc:                          ${upnpc_msg}
2160 gnutls:                         ${gnutls_msg}
2161 libzbar:                        ${libzbar_msg}
2162 java:                           ${java_msg}
2163 libmicrohttpd:                  ${libmicrohttpd_msg}
2164 libidn:                         ${libidn1_msg}${libidn2_msg}
2165 libopus:                        ${libopus_msg}
2166 gstreamer:                      ${gstreamer_msg}
2167 libpulse:                       ${libpulse_msg}
2168 libextractor:                   ${libextractor_msg}
2169 texi2mdoc:                      ${texi2mdoc_msg}
2170 mandoc:                         ${mandoc_msg}
2171
2172 texinfo manual:                 ${texinfo_msg}
2173 transpiled mdocml manual:       ${mdocml_msg}
2174
2175 features:                       ${features_msg}
2176 experimental:                   ${experimental_msg}
2177
2178
2179 IMPORTANT:
2180
2181 Please make sure NOW that you have created a user and group 'gnunet'
2182 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2183 type:
2184
2185   addgroup gnunetdns
2186   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2187
2188 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2189 'gnunet'.  Then, you can compile GNUnet with
2190
2191   make
2192
2193 After that, run (if necessary as 'root')
2194
2195   make install
2196
2197 to install everything.
2198
2199 Each GNUnet user should be added to the 'gnunet' group (may
2200 require fresh login to come into effect):
2201
2202   adduser USERNAME gnunet
2203
2204 (run the above command as root once for each of your users, replacing
2205 "USERNAME" with the respective login names).  If you have a global IP
2206 address, no further configuration is required.
2207
2208 For more detailed setup instructions, see https://docs.gnunet.org/
2209
2210 Optionally, download and compile gnunet-gtk to get a GUI for
2211 file-sharing and configuration.  This is particularly recommended
2212 if your network setup is non-trivial, as gnunet-setup can be
2213 used to test in the GUI if your network configuration is working.
2214 gnunet-setup should be run as the "gnunet" user under X.  As it
2215 does very little with the network, running it as "root" is likely
2216 also harmless.  You can also run it as a normal user, but then
2217 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2218 home directory in the end.
2219
2220 Once you have configured your peer, run (as the 'gnunet' user)
2221
2222   gnunet-arm -s
2223
2224 to start the peer.  You can then run the various GNUnet-tools as
2225 your "normal" user (who should only be in the group 'gnunet').
2226 ])