configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_CPP
  47 AC_PROG_CXX
  48 AC_PROG_OBJC
  49 AC_PROG_INSTALL
  50 AC_PROG_LN_S
  51 AC_PROG_MAKE_SET
  52 AM_PROG_CC_C_O
  53 LT_INIT([disable-static dlopen win32-dll])
  54 AC_SUBST(MKDIR_P)
  55
  56 # allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 # large file support
  60 AC_SYS_LARGEFILE
  61 AC_FUNC_FSEEKO
  62
  63
  64 CFLAGS="-Wall $CFLAGS"
  65 # use '-fno-strict-aliasing', but only if the compiler can take it
  66 AS_IF([gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  67  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  68
  69 # A helper which allows us to check cflags if compiler
  70 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  71   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  72     [ac_save_CFLAGS="$CFLAGS"
  73      CFLAGS="$CFLAGS $1 -Werror"
  74      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  76        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  77      CFLAGS="$ac_save_CFLAGS"
  78     ])
  79
  80   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  81     [$2], [$3])
  82 ])
  83
  84
  85 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  86 # Check for CFLAG and appends them to CFLAGS if supported
  87 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  88   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  89     AS_TR_SH([cc_cv_cflags_-W$1]),
  90     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  91   )
  92
  93   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  94     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  95 ])
  96
  97
  98 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  99 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
 100
 101 # Use Linux interface name unless the OS has a different preference
 102 DEFAULT_INTERFACE="\"eth0\""
 103
 104 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 105
 106 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 107 native_srcdir=$srcdir
 108
 109 OLD_LDFLAGS="$LDFLAGS"
 110 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 111
 112 # Check system type
 113 AS_CASE(["$host_os"],
 114   [*darwin* | *rhapsody* | *macosx*],[
 115      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 116      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 117      CFLAGS="-fno-common $CFLAGS"
 118      LDFLAGS="$OLD_LDFLAGS"
 119      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 120      AC_CHECK_LIB(intl, gettext)
 121      build_target="darwin"
 122      DEFAULT_INTERFACE="\"en0\""
 123      LIBPREFIX=
 124      DLLDIR=lib
 125      UNIXONLY="#"
 126   ],
 127   [linux*],[
 128      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 129      build_target="linux"
 130      LIBPREFIX=
 131      DLLDIR=lib
 132      UNIXONLY="#"
 133      AC_PATH_XTRA
 134   ],
 135   [*freebsd*],[
 136      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 137      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 138      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 139      build_target="freebsd"
 140      LIBPREFIX=
 141      DLLDIR=lib
 142      UNIXONLY="#"
 143   ],
 144   [*openbsd*],[
 145      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 146      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 147      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 148      build_target="openbsd"
 149      LIBPREFIX=
 150      DLLDIR=lib
 151      UNIXONLY="#"
 152   ],
 153   [*netbsd*],[
 154      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 155      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 156      build_target="netbsd"
 157      LIBPREFIX=
 158      DLLDIR=lib
 159      UNIXONLY="#"
 160   ],
 161   [*solaris*],[
 162      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 163      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 164      AC_CHECK_LIB(resolv, res_init)
 165      AC_CHECK_LIB(rt, nanosleep)
 166      build_target="solaris"
 167      LIBPREFIX=
 168      DLLDIR=lib
 169      UNIXONLY="#"
 170   ],
 171   [*arm-linux*],[
 172      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 173      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 174      build_target="linux"
 175      LIBPREFIX=
 176      DLLDIR=lib
 177      UNIXONLY="#"
 178   ],
 179   [gnu*],[
 180      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 181      build_target="gnu"
 182      UNIXONLY="#"
 183   ],
 184   [
 185      AC_MSG_RESULT(Unrecognised OS $host_os)
 186      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 187      UNIXONLY=""
 188 ])
 189 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 190 AC_SUBST(DEFAULT_INTERFACE)
 191
 192 # Disable TCP-based IPC on systems that support UNIX domain
 193 # sockets in default configuratin:
 194 AC_SUBST(UNIXONLY)
 195
 196
 197 AC_MSG_CHECKING([for build target])
 198 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 199 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 226 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 227 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 228 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 229
 230 # autotools' m4 for python has no maximum version!
 231 # python3.4 - python3.7 for tests
 232 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python])
 233 AM_PATH_PYTHON([3.4],, [:])
 234 AC_SUBST([PYTHON])
 235 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 236
 237 # perl
 238 AC_PATH_PROG( PERL, perl, ,
 239               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 240 AC_SUBST([PERL])
 241
 242 # iptables is a soft requirement to run tests
 243 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 244
 245 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 246  [AS_IF([test -x "/sbin/iptables"],
 247    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 248    [AS_IF([test -x "/usr/sbin/iptables"],
 249       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 250
 251 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 252  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 253  [AC_MSG_WARN([warning: 'iptables' not found.])])
 254
 255 # ip6tables is a soft requirement for some features
 256 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 257
 258 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 259   [AS_IF([test -x "/sbin/ip6tables"],
 260      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 261      [AS_IF([test -x "/usr/sbin/ip6tables"],
 262         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 263
 264
 265 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 266   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 267   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 268
 269 # ip is a soft requirement for some features
 270 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 271
 272 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 273  [AS_IF([test -x "/sbin/ip"],
 274    [VAR_IP_BINARY="/sbin/ip"],
 275    [AS_IF([test -x "/usr/sbin/ip"],
 276           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 277
 278 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 279  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 280  [AC_MSG_WARN([warning: 'ip' not found.])])
 281
 282 # locate 'ifconfig'
 283 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 284
 285 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 286 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 287   [AS_IF([test -x "/sbin/ifconfig"],
 288      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 289      [AS_IF([test -x "/usr/sbin/ifconfig"],
 290             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 291
 292 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 293   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 294   [AC_MSG_WARN(['ifconfig' not found.])])
 295
 296
 297 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 298
 299 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 300 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 301       [AS_IF([test -x "/sbin/sysctl"],
 302              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 303              [AS_IF([test -x "/usr/sbin/sysctl"],
 304                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 305 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 306       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 307       [AC_MSG_WARN(['sysctl' not found.])])
 308
 309 # miniupnpc / upnpc binary is a soft runtime requirement
 310 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 311
 312 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 313   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 314   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 315
 316 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 317   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 318      [Define if struct tm has the tm_gmtoff member.])],
 319      ,
 320      [#include <time.h>])
 321
 322 AC_CHECK_DECLS([_stati64])
 323
 324 # 'save' libs; only those libs found so far will be
 325 # linked against _everywhere_.  For the others, we
 326 # will be more selective!
 327 SAVE_LIBS=$LIBS
 328
 329 have_addrinfo_a=0
 330 AC_CHECK_LIB(anl,
 331              getaddrinfo_a,
 332              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 333                                           1,
 334                                           [getaddrinfo_a supported])])
 335 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 336                [test "$have_addrinfo_a" = 1])
 337
 338 # libgcrypt
 339 gcrypt=0
 340 NEED_LIBGCRYPT_API=1
 341 NEED_LIBGCRYPT_VERSION=1.6.0
 342
 343
 344 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 345 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 346
 347 AS_IF([test $gcrypt = 0],
 348  [
 349   AC_MSG_ERROR([[
 350 ***
 351 *** You need libgcrypt to build this program.
 352 **  This library is for example available at
 353 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 354 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 355 ***  is required.)
 356 ***]])
 357 ])
 358 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 359
 360 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 361
 362
 363
 364 # should the build process be building the documentation?
 365 AC_MSG_CHECKING(whether to build documentation)
 366 AC_ARG_ENABLE([documentation],
 367               [AS_HELP_STRING([--disable-documentation],
 368                               [do not build the documentation])],
 369               [documentation=${enableval}],
 370               [documentation=yes])
 371 AC_MSG_RESULT($documentation)
 372 AS_IF([test "x$documentation" = "xyes"],
 373       [AM_CONDITIONAL([DOCUMENTATION],
 374                       true)
 375        AC_DEFINE([DOCUMENTATION],
 376                  [1],
 377                  [Building the documentation])],
 378       [AM_CONDITIONAL([DOCUMENTATION],
 379                       false)
 380        AC_DEFINE([DOCUMENTATION],
 381                  [0],
 382                  [Not building the documentation])])
 383
 384 # COMMENT: Check wether to transpile texinfo to mdoc.
 385 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 386 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 387 # COMMENT: and makes the configure fail if it is missing.
 388 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 389 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 390 # COMMENT: or nothing was set (this is the default).
 391 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 392 # COMMENT: potential non-existence of the texi2mdoc binary.
 393 # COMMENT: Default return value / setting: no
 394 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 395 AC_ARG_ENABLE([texi2mdoc-generation],
 396               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 397                               [include generated texi2mdoc output in installation])],
 398               [texi2mdoc_generation=${enableval}],
 399               [texi2mdoc_generation=no])
 400 AC_MSG_RESULT($texi2mdoc_generation)
 401 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 402       [AS_IF([test "$texi2mdoc" = 0],
 403              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 404               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your Operating System])
 405               AC_MSG_WARN([ERROR: package manager or from https://mandoc.bsd.lv/texi2mdoc/])],
 406              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 407               AC_DEFINE([TEXI2MDOC_GENERATION],
 408                         [1],
 409                         [Building section 7 mdoc output])])],
 410       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 411                       false)
 412        AC_DEFINE([TEXI2MDOC_GENERATION],
 413                  [0],
 414                  [Not building section 7 mdoc output])])
 415
 416 # should the build process be building only the documentation?
 417 AC_MSG_CHECKING(whether to build only documentation)
 418 AC_ARG_ENABLE([documentation-only],
 419    [AS_HELP_STRING([--enable-documentation-only], [build only the documentation])],
 420    [documentation_only=${enableval}],
 421    [documentation_only=no])
 422 AC_MSG_RESULT($documentation_only)
 423 AS_IF([test "x$documentation_only" = "xyes"],
 424  [
 425   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 426   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 427  ],[
 428   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 429   # TODO: Double negation might be a bit hard to parse for some
 430   # TODO: people reading the output.
 431   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Not building only the documentation])
 432  ])
 433
 434 # should the build process be including the manpages? (default: yes)
 435 AC_MSG_CHECKING(whether to include man pages)
 436 AC_ARG_ENABLE([include-manpages],
 437    [AS_HELP_STRING([--disable-include-manpages], [Do not include the man pages in build and installation])],
 438    [include_manpages=${enableval}],
 439    [include_manpages=yes])
 440 AC_MSG_RESULT($include_manpages)
 441 AS_IF([test "x$include_manpages" = "xyes"],
 442  [
 443   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 444   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 445  ],[
 446   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 447   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 448  ])
 449
 450 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 451 # (not syntax!) to the commandline tools which generate the html. If not,
 452 # texinfo5 switches are used. This comes with no version checks, is
 453 # enabled only at distributors action (ie defaults to "no").
 454 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 455 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 456 AC_ARG_ENABLE([texinfo4],
 457    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 458    [activate_texinfo4=${enableval}],
 459    [activate_texinfo4=no])
 460 AC_MSG_RESULT($activate_texinfo4)
 461 AS_IF([test "x$activate_texinfo4" = "xyes"],
 462  [
 463   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 464   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 465  ],[
 466   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 467   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 468  ])
 469
 470
 471 # Adam shostack suggests the following for Windows:
 472 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 473 AC_ARG_ENABLE(gcc-hardening,
 474    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 475 [AS_IF([test x$enableval = xyes],[
 476     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 477     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 478     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 479     LDFLAGS="$LDFLAGS -pie"
 480  ])])
 481
 482 # Linker hardening options
 483 # Currently these options are ELF specific - you can't use this with MacOSX
 484 AC_ARG_ENABLE(linker-hardening,
 485   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 486 [AS_IF([test x$enableval = xyes],
 487    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 488
 489
 490 AC_ARG_ENABLE(sanitizer,
 491   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 492 [AS_IF([test x$enableval = xyes],[
 493    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 494  ])])
 495
 496
 497 extra_logging=GNUNET_NO
 498 AC_ARG_ENABLE([logging],
 499    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 500    [AS_IF([test "x$enableval" = "xyes"], [],
 501           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 502           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 503           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 504    ], [])
 505 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 506
 507 # should memory poisoning be enabled?
 508 AC_MSG_CHECKING(whether to poison freed memory)
 509 AC_ARG_ENABLE([poisoning],
 510    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 511    [enable_poisoning=${enableval}],
 512    [
 513      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 514        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 515        [enable_poisoning=no])
 516    ])
 517 AC_MSG_RESULT($enable_poisoning)
 518 AS_IF([test ! "x$enable_poisoning" = "xno"],
 519   [enable_poisoning=1],
 520   [enable_poisoning=0])
 521 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 522
 523 AS_IF([test $build = $target],
 524 [
 525 AC_MSG_CHECKING([for working HMAC])
 526 AC_LANG_PUSH(C)
 527 LIBS="$LIBS $LIBGCRYPT_LIBS"
 528 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 529 AC_RUN_IFELSE(
 530   [AC_LANG_PROGRAM([#include <gcrypt.h>
 531         #include <stdio.h>], [[
 532         gcry_md_hd_t mac;
 533
 534         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 535             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 536             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 537         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 538         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 539             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 540             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 541             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 542             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 543             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 544
 545         if (!gcry_check_version (GCRYPT_VERSION))
 546         {
 547           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 548           return 1;
 549         }
 550
 551         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 552         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 553
 554         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 555         {
 556           fprintf (stderr, "gcry_md_open error\n");
 557           return 2;
 558         }
 559
 560         gcry_md_setkey (mac, key, sizeof (key));
 561         gcry_md_write (mac, data, sizeof (data));
 562
 563         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 564         {
 565           fprintf (stderr, "memcmp error\n");
 566           return 3;
 567         }
 568
 569         gcry_md_close (mac);
 570
 571         return 0;
 572     ]])],
 573   [AC_MSG_RESULT([yes])],
 574   [
 575    RESULT=$?
 576    if test $RESULT = 3
 577    then
 578      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 579    fi
 580    if test $RESULT = 2
 581    then
 582      AC_MSG_FAILURE([HMAC test failed])
 583    fi
 584    if test $RESULT = 1
 585    then
 586      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 587    fi
 588   ],
 589   [AC_MSG_RESULT([cross compiling, test skipped])])
 590 AC_LANG_POP(C)
 591 ])      # $build = $target
 592
 593 # check for bluetooth library
 594 bluetooth=0
 595 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 596 AS_IF([test "$build_target" = "mingw"],
 597  [bluetooth=1])
 598 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 599 AS_IF([test "$bluetooth" = 1],
 600  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 601  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 602
 603 # check for zbar library
 604 zbar=0
 605 AC_MSG_CHECKING(for libzbar)
 606 AC_ARG_WITH(zbar,
 607    [  --with-zbar=PREFIX (base of libzbar installation)],
 608    [AC_MSG_RESULT([$with_zbar])
 609     AS_CASE([$with_zbar],
 610       [no],[],
 611       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 612       [
 613         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 614         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 615         AC_CHECK_HEADERS(zbar.h,
 616           AC_CHECK_LIB([zbar], [zbar_processor_create],
 617             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 618             zbar=1))
 619        ])
 620    ],
 621    [AC_MSG_RESULT([--with-zbar not specified])
 622     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 623 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 624 AS_IF([test "x$zbar" = x1],
 625       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 626       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 627
 628 # check for jansson library
 629 jansson=0
 630 AC_MSG_CHECKING(for libjansson)
 631 AC_ARG_WITH(jansson,
 632    [  --with-jansson=PREFIX (base of libjansson installation)],
 633    [AC_MSG_RESULT([$with_jansson])
 634     AS_CASE([$with_jansson],
 635       [no],[],
 636       [yes],[
 637         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 638       ],[
 639         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 640         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 641         AC_CHECK_HEADERS(jansson.h,
 642           AC_CHECK_LIB([jansson], [json_loads],
 643             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 644             jansson=1))
 645       ])
 646    ],
 647    [AC_MSG_RESULT([--with-jansson not specified])
 648     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 649 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 650 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 651 AS_IF([test "x$jansson" = x1],
 652       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 653       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 654
 655
 656 # check for libpulse(audio) library
 657 pulse=0
 658 libpulse_msg="no"
 659 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 660 AS_IF([test "$build_target" = "mingw"],
 661       [pulse=0])
 662 AS_IF([test "$pulse" = 1],
 663       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 664        libpulse_msg="yes"])
 665
 666 # check for libopus(audio) library
 667 opus=0
 668 libopus_msg="no"
 669 CHECK_LIBHEADER(LIBOPUS,
 670                 opus,
 671                 opus_decode_float,
 672                 opus/opus.h,
 673                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 674 AS_IF([test "x$opus" = x1],
 675       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 676        libopus_msg="yes"])
 677
 678 # libogg
 679 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 680         [AC_CHECK_HEADERS([ogg/ogg.h],
 681           AM_CONDITIONAL(HAVE_OGG, true)
 682           ogg=1
 683           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 684           AM_CONDITIONAL(HAVE_OGG, false)
 685           ogg=0
 686           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 687         AM_CONDITIONAL(HAVE_OGG, false)
 688         ogg=0)
 689
 690
 691 PKG_CHECK_MODULES([GLIB],
 692                   [glib-2.0],
 693   [# check for pbc library
 694   pbc=0
 695    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 696    AC_CHECK_HEADER([gabe.h],abe=1)
 697    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 698    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 699    AS_IF([test "x$pbc" = x1],
 700      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 701      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 702    AS_IF([test "x$abe" = x1],
 703     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 704     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 705   [# glib-2 not found
 706    AM_CONDITIONAL(HAVE_PBC, [false])
 707    AM_CONDITIONAL(HAVE_ABE, [false])
 708    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 709
 710 gst=0
 711 gstreamer_msg="no"
 712 PKG_CHECK_MODULES(
 713   [GST],
 714   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 715   [gst=1
 716    gstreamer_msg="yes"],
 717   [gst=0])
 718
 719 # Pulse Audio
 720 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 721  AS_IF([test "x$gst" != "x1"],[
 722   conversation_backend=none
 723   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 724   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 725   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 726  ],[
 727    conversation_backend=gst
 728    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 729    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 730    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 731  ])
 732 ],[
 733  conversation_backend=pulse
 734  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 735  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 736  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 737 ])
 738
 739 AS_IF([test "x$conversation_backend" = "xnone"],
 740       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 741       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 742
 743 # libgnurl
 744 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 745
 746 SAVE_CPPFLAGS=$CPPFLAGS
 747 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 748 LIBS="$LIBGNURL $LIBCURL $LIBS"
 749
 750 # libcurl-gnutls
 751 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 752 AS_IF([test "x$curl" = xtrue],[
 753  AC_CHECK_HEADER([curl/curl.h],
 754   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 755   [curl=false])
 756  # need libcurl-gnutls.so, everything else is not acceptable
 757  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 758  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 759 ])
 760
 761 # libcurl and libgnurl should be mutually exclusive
 762 AS_IF([test "$gnurl" = 1],
 763       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 764        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 765        AM_CONDITIONAL(HAVE_LIBCURL, false)
 766        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 767       [AS_IF([test "$curl" = true],
 768              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 769               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 770               AM_CONDITIONAL(HAVE_LIBCURL, true)
 771               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 772              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 773               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 774               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 775               AM_CONDITIONAL(HAVE_LIBCURL, false)
 776               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 777
 778 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 779 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 780
 781 # restore LIBS & CPPFLAGS
 782 LIBS=$SAVE_LIBS
 783 CPPFLAGS=$SAVE_CPPFLAGS
 784
 785 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 786 # GLPK must support glpk_init_env, version >= 4.43
 787 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 788 # GLPK must support atm MLP presolving, version >= 4.32
 789 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 790 AS_IF([test "x$glpk" = xfalse],
 791 [
 792         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 793         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 794 ],[
 795         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 796         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 797 ])
 798
 799
 800 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 801 AS_IF([test x$nss = xfalse],
 802   [
 803         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 804         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 805   ],[
 806         NSS_INCLUDES="
 807         #include <nss.h>
 808         "
 809         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 810                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 811                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 812                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 813                 [$NSS_INCLUDES])
 814 ])
 815
 816
 817
 818 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 819 AC_CHECK_LIB([kvm],[kvm_open])
 820 AC_CHECK_LIB([kstat],[kstat_open])
 821
 822
 823 # should the build process be restricted to the code required
 824 # for GNU Taler wallets?
 825 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 826 AC_ARG_ENABLE([taler-wallet],
 827    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 828    [taler_only=${enableval}],
 829    [taler_only=no])
 830 AC_MSG_RESULT($taler_only)
 831 AS_IF([test "x$taler_only" = "xyes"],
 832 [
 833   AM_CONDITIONAL([TALER_ONLY],true)
 834   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 835 ],[
 836   AM_CONDITIONAL([TALER_ONLY],false)
 837   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 838 ])
 839
 840 # test for libextractor
 841 extractor=0
 842 AC_MSG_CHECKING(for libextractor)
 843 AC_ARG_WITH(extractor,
 844    [  --with-extractor=PREFIX (base of libextractor installation)],
 845    [AC_MSG_RESULT([$with_extractor])
 846     AS_CASE([$with_extractor],
 847       [no],[],
 848       [yes],[
 849         AC_CHECK_HEADERS([extractor.h],
 850           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 851             extractor=1))
 852       ],[
 853         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 854         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 855         AC_CHECK_HEADERS([extractor.h],
 856           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 857             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 858             extractor=1))
 859       ])
 860    ],
 861    [AC_MSG_RESULT([--with-extractor not specified])
 862     AC_CHECK_HEADERS([extractor.h],
 863      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 864       extractor=1))])
 865 # restore LIBS
 866 LIBS=$SAVE_LIBS
 867
 868 AS_IF([test "$extractor" != 1],
 869  [
 870  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 871  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 872  ],[
 873  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 874  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 875  ])
 876
 877
 878 AS_IF([test "$taler_only" != yes],[
 879
 880
 881 # Check for libltdl header (#2999)
 882 ltdl=0
 883 AC_MSG_CHECKING(for libltdl)
 884 AC_ARG_WITH(ltdl,
 885    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 886    [AC_MSG_RESULT([$with_ltdl])
 887     AS_CASE([$with_ltdl],
 888       [no],[],
 889       [yes],[
 890         AC_CHECK_HEADERS(ltdl.h,
 891           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 892             ltdl=1))
 893       ],[
 894         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 895         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 896         AC_CHECK_HEADERS(ltdl.h,
 897           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 898             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 899             ltdl=1))
 900       ])
 901    ],
 902    [AC_MSG_RESULT([--with-ltdl not specified])
 903     AC_CHECK_HEADERS(ltdl.h,
 904      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 905       ltdl=1))])
 906 AS_IF([test x$ltdl = x1],
 907 [
 908  AC_MSG_RESULT([libltdl found])
 909 ],[
 910  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 911 ])
 912 # restore LIBS
 913 LIBS=$SAVE_LIBS
 914
 915 # libidn and libidn2. The ideal goal is this:
 916 # check for libidn2, if it doesn't exist check for libidn
 917 # if both exist, prefer libidn2
 918 # if none exist, fail and message that libidn or libidn2
 919 # is required with a preference for libidn2.
 920 # TODO: What we have right here can probably be improved.
 921 my_with_libidn=1
 922 AC_ARG_WITH(libidn,
 923             AS_HELP_STRING([--with-libidn=pathname],
 924                            [Support IDN (needs libidn)]),
 925             [],
 926             [withval="yes"])
 927 AS_IF([test x_$withval = x_yes],
 928       [AC_CHECK_HEADERS([idna.h],
 929           AC_MSG_NOTICE([Found idna.h]),
 930           AC_CHECK_HEADERS([idn/idna.h],
 931                AC_MSG_NOTICE([Found idn/idna.h]),
 932                my_with_libidn=0))],
 933       [AS_IF([test x_$withval != x_no],
 934              [CFLAGS="$CFLAGS -I$withval/include"
 935               LDFLAGS="$LDFLAGS -L$withval/lib"
 936               AC_CHECK_HEADERS([idna.h],
 937                 AC_MSG_NOTICE([Found idna.h]),
 938                 [AC_MSG_NOTICE([Failed to find idna.h])
 939                  my_with_libidn=0])],
 940              [my_with_libidn=0])])
 941
 942 my_with_libidn2=1
 943 AC_ARG_WITH(libidn2,
 944             AS_HELP_STRING([--with-libidn2=pathname],
 945                            [Support IDN (needs libidn2)]),
 946             [],
 947             [withval="yes"])
 948 AS_IF([test x_$withval = x_yes],
 949       [AC_CHECK_HEADERS([idn2.h],
 950        AC_MSG_NOTICE([Found idn2.h]),
 951        AC_CHECK_HEADERS([idn2/idn2.h],
 952           AC_MSG_NOTICE([Found idn2/idn2.h]),
 953           [AC_MSG_NOTICE([Failed to find idn2.h])
 954            my_with_libidn2=0]))],
 955       [AS_IF([test x_$withval != x_no],
 956              [CFLAGS="$CFLAGS -I$withval/include"
 957               LDFLAGS="$LDFLAGS -L$withval/lib"],
 958              [my_with_libidn2=0])])
 959
 960 AC_MSG_CHECKING([if libidn can be used])
 961 # Check for LIBIDNs
 962 there_can_only_be_one=1
 963
 964 working_libidn1=0
 965 working_libidn2=0
 966 AS_IF([test x$my_with_libidn2 = x1],
 967       [AC_MSG_NOTICE([Checking for libidn2])
 968        AC_CHECK_LIB([idn2],
 969                     [idn2_to_unicode_8z8z],
 970                     [working_libidn2=1
 971                     LIBS="-lidn2 $LIBS"
 972                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 973                                        [1],
 974                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 975                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 976                      MISSING_SEP=", "])])
 977 AM_CONDITIONAL(HAVE_LIBIDN2,
 978                test x$working_libidn2 = x1)
 979 AS_IF([test x$working_libidn2 = x0],
 980       [AS_IF([test x$my_with_libidn = x1],
 981              [AC_MSG_NOTICE([Checking for libidn])
 982               AC_CHECK_LIB([idn],
 983                            [idna_to_ascii_8z],
 984                            [working_libidn1=1
 985                            LIBS="-lidn $LIBS"
 986                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
 987                                               [1],
 988                                               [Define to 1 if you have 'libidn' (-lidn).])],
 989                            [there_can_only_be_one=0])],
 990              [AS_IF([test x$my_with_libidn2 = x1],
 991                     [there_can_only_be_one=0
 992                      AC_MSG_FAILURE([* There can only be one libidn.
 993                                      * Provide either libidn >= 1.13
 994                                      * or
 995                                      * libidn2 to the configure
 996                                      * script via
 997                                      * --with-libidn2
 998                                      * --with-libidn])])])])
 999 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1000
1001 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1002       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1003
1004 AS_IF([test x$there_can_only_be_one = x0],
1005       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1006
1007 # test for zlib
1008 SAVE_LDFLAGS=$LDFLAGS
1009 SAVE_CPPFLAGS=$CPPFLAGS
1010 AC_ARG_WITH(zlib,
1011             [  --with-zlib[[=DIR]]       use libz in DIR],
1012             [AS_IF([test "$withval" = "no"],
1013                    [AC_MSG_ERROR([GNUnet requires zlib])],
1014                    [test "$withval" != "yes"],
1015                    [Z_DIR=$withval
1016                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1017                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1018 AC_CHECK_HEADER(zlib.h,
1019                 [],
1020                 [AC_MSG_ERROR([GNUnet requires zlib])])
1021 AC_CHECK_LIB(z,
1022              compress2,
1023              [AC_DEFINE([HAVE_ZLIB],
1024                         [],
1025                         [Have compression library])
1026               if test "x${Z_DIR}" != "x"; then
1027                       Z_CFLAGS="-I${Z_DIR}/include"
1028                       Z_LIBS="-L${Z_DIR}/lib -lz"
1029               else
1030                       Z_LIBS="-lz"
1031               fi],
1032               [AC_MSG_ERROR([GNUnet requires zlib])])
1033 AC_SUBST(Z_CFLAGS)
1034 AC_SUBST(Z_LIBS)
1035
1036 AS_IF([test "$enable_shared" = "no"],
1037       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1038
1039
1040 # restore LIBS
1041 LIBS=$SAVE_LIBS
1042
1043
1044 # end of taler-only being false
1045 ])
1046
1047
1048 # check for iconv
1049 AM_ICONV
1050
1051 # test for libunistring
1052 gl_LIBUNISTRING
1053 AS_IF([test $HAVE_LIBUNISTRING != yes],
1054       [AC_MSG_ERROR([GNUnet requires libunistring])])
1055
1056 # under emscripten, $gl_libunistring_hexversion is undefined
1057 if test "$taler_only" != yes; then
1058
1059 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1060       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1061 fi
1062 AC_CHECK_HEADERS([unistr.h],
1063                  ,
1064                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1065
1066 # restore LIBS
1067 LIBS=$SAVE_LIBS
1068
1069
1070
1071 # Checks for standard header files.
1072 AC_HEADER_DIRENT
1073 AC_HEADER_STDC
1074
1075 # Check for headers that are ALWAYS required
1076 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1077
1078
1079
1080 # Checks for headers that are only required on some systems or
1081 # opional (and where we do NOT abort if they are not there)
1082 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1083
1084 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1085 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1086 [#ifdef HAVE_SYS_TYPES_H
1087 #include <sys/types.h>
1088 #endif
1089 #ifdef HAVE_NETINET_IN_SYSTM_H
1090 #include <netinet/in_systm.h>
1091 #endif
1092 #ifdef HAVE_NETINET_IN_H
1093 #include <netinet/in.h>
1094 #endif
1095 ])
1096
1097 SAVE_LDFLAGS=$LDFLAGS
1098 SAVE_CPPFLAGS=$CPPFLAGS
1099
1100 # test for sqlite
1101 sqlite=false
1102 AC_MSG_CHECKING(for SQLite)
1103 AC_ARG_WITH(sqlite,
1104   [  --with-sqlite=PFX       base of SQLite installation],
1105   [AC_MSG_RESULT("$with_sqlite")
1106    AS_CASE([$with_sqlite],
1107      [no],[],
1108      [yes],[
1109       AC_CHECK_HEADERS(sqlite3.h,
1110       sqlite=true)],
1111      [
1112     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1113     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1114     AC_CHECK_HEADERS(sqlite3.h,
1115      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1116      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1117      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1118      sqlite=true)
1119     LDFLAGS=$SAVE_LDFLAGS
1120     CPPFLAGS=$SAVE_CPPFLAGS
1121     ])
1122   ],
1123   [AC_MSG_RESULT([--with-sqlite not specified])
1124     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1125 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1126 AC_SUBST(SQLITE_CPPFLAGS)
1127 AC_SUBST(SQLITE_LDFLAGS)
1128
1129 LDFLAGS=$SAVE_LDFLAGS
1130 CPPFLAGS=$SAVE_CPPFLAGS
1131
1132 # test for postgres
1133 postgres=false
1134 # even running the check for postgres breaks emscripten ...
1135 AS_IF([test "$taler_only" != yes],
1136       [AX_LIB_POSTGRESQL([9.5],
1137         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1138          AC_CHECK_HEADERS([libpq-fe.h],
1139          postgres=true)
1140         ],
1141         [AC_MSG_RESULT([no postgres])])])
1142 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1143
1144
1145 LDFLAGS=$SAVE_LDFLAGS
1146 CPPFLAGS=$SAVE_CPPFLAGS
1147
1148 # mysql & windows
1149 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1150 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1151
1152 # test for mysql
1153 mysql=false
1154 mysqlfail=false
1155 SAVE_LDFLAGS=$LDFLAGS
1156 SAVE_CPPFLAGS=$CPPFLAGS
1157 AC_MSG_CHECKING(for mysql)
1158 AC_ARG_WITH(mysql,
1159   [  --with-mysql=PFX        base of MySQL installation],
1160   [AC_MSG_RESULT([$with_mysql])
1161    AS_CASE([$with_mysql],
1162      [no],[],
1163      [yes|""],[
1164       AC_CHECK_HEADERS(mysql/mysql.h,
1165        AC_CHECK_LIB(mysqlclient, mysql_init,
1166        mysql=true), [], [])
1167      ],[
1168       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1169       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1170       AC_CHECK_HEADERS(mysql/mysql.h,
1171        AC_CHECK_LIB(mysqlclient, mysql_init,
1172         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1173         MYSQL_CPPFLAGS="-I$with_mysql/include"
1174
1175         mysql=true), [], [])
1176      ])
1177   ],
1178   [AC_MSG_RESULT([--with-mysql not specified])
1179    if test -d "/usr/lib64/mysql"; then
1180     MYSQL_LIBDIR="/usr/lib64/mysql"
1181    elif test -d "/usr/lib/mysql"; then
1182     MYSQL_LIBDIR="/usr/lib/mysql"
1183    else
1184     MYSQL_LIBDIR="/usr/lib"
1185    fi
1186    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1187    AC_CHECK_LIB(mysqlclient, mysql_init,
1188     [AC_CHECK_HEADERS(mysql/mysql.h,
1189       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1190       mysql=true
1191
1192      , [], [])])
1193   ])
1194
1195 AC_SUBST(MYSQL_LDFLAGS)
1196 AC_SUBST(MYSQL_CPPFLAGS)
1197
1198 # additional version check for mysql
1199 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1200 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1201  [
1202   AC_MSG_CHECKING(mysql version)
1203   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1204     [[
1205       #include <mysql/mysql.h>]],
1206     [[
1207       #if (MYSQL_VERSION_ID < 40100)
1208       #error needs at least version >= 4.1
1209       #endif
1210       int main () { return 0; }
1211     ]])
1212     ],mysql=true,mysql=false)
1213   AS_IF([test "$mysql" = "false"],
1214    [
1215     mysqlfail=true
1216     AC_MSG_RESULT([fail, >= 4.1 required])
1217    ],[
1218     AC_MSG_RESULT(ok)
1219    ])
1220 ])
1221 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1222 AM_CONDITIONAL(HAVE_MYSQLE, false)
1223 # restore LIBS
1224 LIBS=$SAVE_LIBS
1225 LDFLAGS=$SAVE_LDFLAGS
1226 CPPFLAGS=$SAVE_CPPFLAGS
1227
1228 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1229 [
1230  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1231 ])
1232
1233 # libmicrohttpd
1234 lmhd=0
1235 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1236 AC_ARG_WITH(microhttpd,
1237    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1238        [base of libmicrohttpd installation])],
1239    [],
1240    [with_microhttpd=check])
1241 AS_CASE([$with_microhttpd],
1242    [no], [],
1243    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1244    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1245        [lmhd=1],
1246        [AC_MSG_WARN([Building without libmicrohttpd])])],
1247    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1248     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1249     export PKG_CONFIG_PATH
1250     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1251     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1252 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1253 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1254
1255 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1256
1257 # restore LIBS
1258 LIBS=$SAVE_LIBS
1259
1260 # check for gettext
1261 AM_GNU_GETTEXT([external])
1262 AM_GNU_GETTEXT_VERSION([0.18.1])
1263
1264 # Checks for standard typedefs, structures, and compiler characteristics.
1265 AC_TYPE_PID_T
1266 AC_TYPE_SIZE_T
1267 AC_TYPE_MODE_T
1268 AC_HEADER_TIME
1269 AC_HEADER_STAT
1270 AC_HEADER_STDBOOL
1271 AC_STRUCT_TM
1272
1273 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1274    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1275    ],
1276    [],
1277    [
1278       #include <sys/types.h>
1279       #include <sys/socket.h>
1280       #include <netinet/in.h>
1281    ])
1282
1283 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1284                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1285                             1,
1286                             [Do we have sockaddr_un.sun_len?])],
1287                 [],
1288                 [
1289                 #include <sys/types.h>
1290                 #include <sys/socket.h>
1291                 #include <sys/un.h>
1292                 ])
1293
1294
1295
1296 # Checks for library functions.
1297 AC_FUNC_CLOSEDIR_VOID
1298 AC_FUNC_FORK
1299 AC_PROG_GCC_TRADITIONAL
1300 AC_FUNC_MEMCMP
1301 AC_FUNC_SELECT_ARGTYPES
1302 AC_FUNC_CHOWN
1303
1304 AC_TYPE_SIGNAL
1305 AC_FUNC_STAT
1306 AC_FUNC_STRFTIME
1307 AC_FUNC_VPRINTF
1308 AC_HEADER_SYS_WAIT
1309 AC_TYPE_OFF_T
1310 AC_TYPE_UID_T
1311 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1312
1313 # restore LIBS
1314 LIBS=$SAVE_LIBS
1315
1316 GN_INTLINCL=""
1317 GN_LIBINTL="$LTLIBINTL"
1318 AC_ARG_ENABLE(framework,
1319               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1320               enable_framework_build=$enableval)
1321 AM_CONDITIONAL(WANT_FRAMEWORK,
1322                test x$enable_framework_build = xyes)
1323 AS_IF([test x$enable_framework_build = xyes],
1324       [AC_DEFINE([FRAMEWORK_BUILD],
1325                  1,
1326                  [Build a Mac OS X Framework])
1327       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1328       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1329       AC_LIB_APPENDTOVAR([CPPFLAGS],
1330                          [$GN_INTLINCL])])
1331
1332 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1333 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1334
1335 AC_SUBST(GN_LIB_LDFLAGS)
1336 AC_SUBST(GN_PLUGIN_LDFLAGS)
1337 AC_SUBST(GN_INTLINCL)
1338 AC_SUBST(GN_LIBINTL)
1339
1340 AC_SUBST(CPPFLAGS)
1341 AC_SUBST(LIBS)
1342 AC_SUBST(LDFLAGS)
1343 AC_SUBST(EXT_LIB_PATH)
1344 AC_SUBST(EXT_LIBS)
1345
1346 AC_SUBST(LIBPREFIX)
1347 AC_SUBST(DLLDIR)
1348 AC_SUBST(EXT_LIB_PATH)
1349
1350 DATAROOTDIR=$datarootdir
1351 AC_SUBST(DATAROOTDIR)
1352
1353 # test for sudo
1354 # TODO: do we need to change anything for "doas" on openbsd?
1355 AC_MSG_CHECKING(for sudo)
1356 AC_ARG_WITH(sudo,
1357             [  --with-sudo=PATH       path to sudo binary (or just yes)],
1358             [AC_MSG_RESULT("$with_sudo")
1359              AS_CASE([$with_sudo],
1360                      [no],[SUDO_BINARY=],
1361                      [yes],[SUDO_BINARY=sudo],
1362                      [SUDO_BINARY=$with_sudo])],
1363             [AC_MSG_RESULT([no])])
1364 AC_SUBST(SUDO_BINARY)
1365 AM_CONDITIONAL([HAVE_SUDO],
1366                [test "x$SUDO_BINARY" != "x" -o -w /])
1367
1368
1369 # test for gnunetdns group name
1370 GNUNETDNS_GROUP=gnunetdns
1371 AC_MSG_CHECKING(for gnunetdns group name)
1372 AC_ARG_WITH(gnunetdns,
1373             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1374             [AC_MSG_RESULT("$with_gnunetdns")
1375              AS_CASE([$with_gnunetdns],
1376                      [no],[GNUNETDNS_GROUP=gnunet],
1377                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1378                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1379             [AC_MSG_RESULT([gnunetdns])])
1380 AC_SUBST(GNUNETDNS_GROUP)
1381
1382
1383
1384 # gnutls
1385 gnutls=0
1386 gnutls_dane=0
1387 AC_MSG_CHECKING(for gnutls)
1388 AC_ARG_WITH(gnutls,
1389             [  --with-gnutls=PFX   base of gnutls installation],
1390             [AC_MSG_RESULT([$with_gnutls])
1391              AS_CASE([$with_gnutls],
1392                      [no],[],
1393                      [yes],
1394                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1395                                        AC_CHECK_LIB([gnutls],
1396                                                     [gnutls_priority_set],
1397                                                     gnutls=true))
1398                       AC_CHECK_HEADERS([gnutls/dane.h],
1399                                        AC_CHECK_LIB([gnutls-dane],
1400                                                     [dane_verify_crt_raw],
1401                                                     gnutls_dane=1))],
1402
1403         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1404         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1405         AC_CHECK_HEADERS([gnutls/abstract.h],
1406             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1407               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1408               gnutls=true))
1409         AC_CHECK_HEADERS([gnutls/dane.h],
1410             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1411               gnutls_dane=1))
1412       ])
1413    ],
1414    [AC_MSG_RESULT([--with-gnutls not specified])
1415     AC_CHECK_HEADERS([gnutls/abstract.h],
1416         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1417           gnutls=true))
1418     AC_CHECK_HEADERS([gnutls/dane.h],
1419         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1420                      gnutls_dane=1))
1421    ])
1422 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1423 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1424 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1425 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1426
1427
1428
1429 # Test if we are building for superMUC
1430 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1431 AC_ARG_ENABLE([supermuc],
1432     [AS_HELP_STRING([--enable-supermuc],
1433        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1434     [AS_IF([test "x$enable_supermuc" = "xno"],
1435       [supermuc=0],
1436       [supermuc=1])],
1437     [supermuc=0
1438      enable_supermuc=no])
1439 AC_MSG_RESULT($enable_SUPERMUC)
1440 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1441 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1442
1443 # Check if NSE has to send timestamp information to testbed logger for
1444 # generating histogram of messages received
1445 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1446 AC_ARG_ENABLE([nse-histogram],
1447     [AS_HELP_STRING([--enable-nse-histogram],
1448        [have NSE send timestamp information to testbed logger for generating
1449        histogram of received messages.  NOT useful for production (default is
1450        NO)])],
1451     [AS_IF([test "x$enableval" = "xno"],
1452       [nse_histogram=0],
1453       [nse_histogram=1])],
1454     [nse_histogram=0
1455      enable_nse_histogram=no])
1456 AC_MSG_RESULT($enable_nse_histogram)
1457 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1458 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1459                    [have NSE send timestamp information to testbed logger])
1460
1461 # should 'make check' run tests?
1462 AC_MSG_CHECKING(whether to run tests)
1463 AC_ARG_ENABLE([testruns],
1464    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1465    [enable_tests_run=${enableval}],
1466    [enable_tests_run=yes])
1467 AC_MSG_RESULT($enable_test_run)
1468 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1469
1470
1471 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1472 AC_ARG_ENABLE([benchmark],
1473    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1474    [enable_benchmark=${enableval}],
1475    [enable_benchmark=no])
1476 AC_MSG_RESULT($enable_benchmark)
1477 AS_IF([test "x$enable_benchmark" = "xyes"],
1478       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1479 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1480
1481
1482 # should expensive tests be run?
1483 AC_MSG_CHECKING(whether to run expensive tests)
1484 AC_ARG_ENABLE([expensivetests],
1485    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1486    [enable_expensive=${enableval}],
1487    [enable_expensive=no])
1488 AC_MSG_RESULT($enable_expensive)
1489 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1490
1491 # should ports be open for Java services?
1492 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1493 AC_ARG_ENABLE([javaports],
1494    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1495    [enable_java_ports=${enableval}],
1496    [enable_java_ports=no])
1497 AC_MSG_RESULT($enable_java_ports)
1498 AS_IF([test "x$enable_java_ports" = "xyes"],
1499  [JAVAPORT=""],
1500  [JAVAPORT="$UNIXONLY"])
1501 AC_SUBST(JAVAPORT)
1502
1503 # should benchmarks be run?
1504 AC_MSG_CHECKING(whether to run benchmarks during make check)
1505 AC_ARG_ENABLE([benchmarks],
1506    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1507    [enable_benchmarks=${enableval}],
1508    [enable_benchmarks=no])
1509 AC_MSG_RESULT($enable_benchmarks)
1510 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1511
1512 # should gnunet-testing be compiled
1513 AC_MSG_CHECKING(wether to compile gnunet-testing)
1514 AC_ARG_ENABLE([testing],
1515    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1516    [enable_testing=${enableval}],
1517    [enable_testing=yes])
1518 AC_MSG_RESULT($enable_testing)
1519 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1520
1521 # should experimental code be compiled (code that may not yet compile)?
1522 AC_MSG_CHECKING(whether to compile experimental code)
1523 AC_ARG_ENABLE([experimental],
1524    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1525    [enable_experimental=${enableval}],
1526    [enable_experimental=no])
1527 AC_MSG_RESULT($enable_experimental)
1528 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1529
1530 # should malicious code be compiled (should only be used for testing)?
1531 AC_MSG_CHECKING(whether to compile malicious code)
1532 AC_ARG_ENABLE([malicious],
1533    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1534    [AS_IF([test "x$enableval" = "xno"],
1535      [malicious=0],
1536      [malicious=1])],
1537    [malicious=0
1538     enable_malicious=no])
1539 AC_MSG_RESULT($enable_malicious)
1540 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1541 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1542                    [enable compilation of malicious code])
1543
1544 # should services be started on demand when needed?
1545 # Some services may choose to never start by default
1546 # and it is up to the service/module developer to decide
1547 # by having "START_ON_DEMAND = NO" instead of
1548 # "START_ON_DEMAND = @START_ON_DEMAND@"
1549 # in the service/module's conf.in file.
1550 # See also IMMEDIATE_START for an unconditional immediate start.
1551 START_ON_DEMAND="YES"
1552 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1553 AC_ARG_ENABLE([autostart],
1554    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1555    [enable_autostart=${enableval}
1556     AS_IF([test "x$enable_autostart" = "xno"],
1557       [START_ON_DEMAND="NO"])
1558    ],
1559    [enable_autostart=yes])
1560 AC_MSG_RESULT($enable_autostart)
1561 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1562 AC_SUBST(START_ON_DEMAND)
1563
1564 # should memory statistics be kept (very expensive CPU-wise!)
1565 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1566 AC_ARG_ENABLE([heapstats],
1567    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1568    [enable_heapstats=1],
1569    [enable_heapstats=0])
1570 AC_MSG_RESULT($enable_heapstats)
1571 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1572
1573
1574 # Check if the __thread storage class for
1575 # thread-local storage is available.
1576 AC_MSG_CHECKING(whether __thread is supported)
1577 AC_LINK_IFELSE(
1578 [AC_LANG_PROGRAM([#include <stdlib.h>
1579                    #undef __thread
1580                    static __thread int a = 1;],
1581                   [exit(a-1);])],
1582  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1583 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1584 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1585       [AC_MSG_RESULT(yes)],
1586       [AC_MSG_RESULT(no)])
1587
1588 # gcov compilation
1589 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1590 AC_ARG_ENABLE([coverage],
1591               AS_HELP_STRING([--enable-coverage],
1592                              [compile the library with code coverage support]),
1593               [use_gcov=${enableval}],
1594               [use_gcov=no])
1595 AC_MSG_RESULT($use_gcov)
1596 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1597
1598
1599 # version info
1600 # TODO: git blame says this predates our switch to git.
1601 # git-svn should be adjusted to simply git, or
1602 # an external script that does the job.
1603 AC_PATH_PROG(svnversioncommand, svnversion)
1604 AC_PATH_PROG(gitcommand, git)
1605 AC_MSG_CHECKING(for source being under a VCS)
1606
1607
1608 # version info
1609 AC_PATH_PROG(gitcommand, git)
1610 AC_MSG_CHECKING(for source being under a VCS)
1611 git_version=
1612 AS_IF([test ! "X$gitcommand" = "X"],
1613 [
1614   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1615 ])
1616 AS_IF([test "X$git_version" = "X"],
1617   [
1618     vcs_name="no"
1619     vcs_version="\"release\""
1620   ],
1621   [
1622     vcs_name="yes, git-svn"
1623     vcs_version="\"git-$git_version\""
1624   ])
1625 AC_MSG_RESULT($vcs_name)
1626
1627 AC_MSG_CHECKING(VCS version)
1628 AC_MSG_RESULT($vcs_version)
1629 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1630
1631 AC_CONFIG_FILES([
1632 Makefile
1633 contrib/Makefile
1634 contrib/hellos/Makefile
1635 contrib/services/Makefile
1636 contrib/services/openrc/Makefile
1637 contrib/services/systemd/Makefile
1638 contrib/scripts/Makefile
1639 contrib/scripts/gnunet-logread/Makefile
1640 doc/Makefile
1641 doc/man/Makefile
1642 doc/doxygen/Makefile
1643 doc/handbook/Makefile
1644 doc/tutorial/Makefile
1645 lint/Makefile
1646 m4/Makefile
1647 po/Makefile.in
1648 src/Makefile
1649 src/arm/Makefile
1650 src/arm/arm.conf
1651 src/ats/Makefile
1652 src/ats/ats.conf
1653 src/ats-tool/Makefile
1654 src/ats-tests/Makefile
1655 src/auction/Makefile
1656 src/block/Makefile
1657 src/cadet/Makefile
1658 src/cadet/cadet.conf
1659 src/core/Makefile
1660 src/core/core.conf
1661 src/consensus/Makefile
1662 src/consensus/consensus.conf
1663 src/conversation/Makefile
1664 src/conversation/conversation.conf
1665 src/curl/Makefile
1666 src/datacache/Makefile
1667 src/datastore/Makefile
1668 src/datastore/datastore.conf
1669 src/dht/Makefile
1670 src/dht/dht.conf
1671 src/dns/Makefile
1672 src/dns/dns.conf
1673 src/exit/Makefile
1674 src/fragmentation/Makefile
1675 src/fs/Makefile
1676 src/fs/fs.conf
1677 src/gns/Makefile
1678 src/gns/gns.conf
1679 src/gns/nss/Makefile
1680 src/gnsrecord/Makefile
1681 src/hello/Makefile
1682 src/identity/Makefile
1683 src/identity/identity.conf
1684 src/credential/Makefile
1685 src/credential/credential.conf
1686 src/include/Makefile
1687 src/integration-tests/Makefile
1688 src/json/Makefile
1689 src/hostlist/Makefile
1690 src/my/Makefile
1691 src/mysql/Makefile
1692 src/namecache/Makefile
1693 src/namecache/namecache.conf
1694 src/namestore/Makefile
1695 src/namestore/namestore.conf
1696 src/nat/Makefile
1697 src/nat/nat.conf
1698 src/nat-auto/Makefile
1699 src/nat-auto/nat-auto.conf
1700 src/nse/Makefile
1701 src/nse/nse.conf
1702 src/nt/Makefile
1703 src/peerinfo/Makefile
1704 src/peerinfo/peerinfo.conf
1705 src/peerinfo-tool/Makefile
1706 src/peerstore/Makefile
1707 src/peerstore/peerstore.conf
1708 src/pq/Makefile
1709 src/pt/Makefile
1710 src/regex/Makefile
1711 src/regex/regex.conf
1712 src/revocation/Makefile
1713 src/revocation/revocation.conf
1714 src/rps/Makefile
1715 src/rps/rps.conf
1716 src/secretsharing/Makefile
1717 src/secretsharing/secretsharing.conf
1718 src/scalarproduct/Makefile
1719 src/scalarproduct/scalarproduct.conf
1720 src/set/Makefile
1721 src/set/set.conf
1722 src/sq/Makefile
1723 src/statistics/Makefile
1724 src/statistics/statistics.conf
1725 src/template/Makefile
1726 src/testbed/Makefile
1727 src/testbed/testbed.conf
1728 src/testbed-logger/Makefile
1729 src/testbed-logger/testbed-logger.conf
1730 src/testing/Makefile
1731 src/topology/Makefile
1732 src/transport/Makefile
1733 src/transport/transport.conf
1734 src/util/Makefile
1735 src/util/resolver.conf
1736 src/vpn/Makefile
1737 src/vpn/vpn.conf
1738 src/zonemaster/Makefile
1739 src/zonemaster/zonemaster.conf
1740 src/rest/Makefile
1741 src/abe/Makefile
1742 src/reclaim-attribute/Makefile
1743 src/reclaim/Makefile
1744 pkgconfig/Makefile
1745 pkgconfig/gnunetarm.pc
1746 pkgconfig/gnunetats.pc
1747 pkgconfig/gnunetblock.pc
1748 pkgconfig/gnunetcadet.pc
1749 pkgconfig/gnunetconsensus.pc
1750 pkgconfig/gnunetconversation.pc
1751 pkgconfig/gnunetcore.pc
1752 pkgconfig/gnunetdatacache.pc
1753 pkgconfig/gnunetdatastore.pc
1754 pkgconfig/gnunetdht.pc
1755 pkgconfig/gnunetdns.pc
1756 pkgconfig/gnunetenv.pc
1757 pkgconfig/gnunetfragmentation.pc
1758 pkgconfig/gnunetfs.pc
1759 pkgconfig/gnunetgns.pc
1760 pkgconfig/gnunethello.pc
1761 pkgconfig/gnunetidentity.pc
1762 pkgconfig/gnunetmicrophone.pc
1763 pkgconfig/gnunetmysql.pc
1764 pkgconfig/gnunetnamestore.pc
1765 pkgconfig/gnunetnat.pc
1766 pkgconfig/gnunetnse.pc
1767 pkgconfig/gnunetpeerinfo.pc
1768 pkgconfig/gnunetpq.pc
1769 pkgconfig/gnunetregex.pc
1770 pkgconfig/gnunetrevocation.pc
1771 pkgconfig/gnunetrps.pc
1772 pkgconfig/gnunetscalarproduct.pc
1773 pkgconfig/gnunetset.pc
1774 pkgconfig/gnunetspeaker.pc
1775 pkgconfig/gnunetstatistics.pc
1776 pkgconfig/gnunettestbed.pc
1777 pkgconfig/gnunettesting.pc
1778 pkgconfig/gnunettransport.pc
1779 pkgconfig/gnunetutil.pc
1780 pkgconfig/gnunetvpn.pc
1781 ])
1782 AC_OUTPUT
1783
1784
1785 # FIXME: `some modules' -> be more specific which exact modules.
1786
1787 # java ports
1788 AS_IF([test "x$enable_java_ports" = "xyes"],
1789       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1790
1791 ####
1792 #### Lasciate ogne speranza, voi ch'intrate
1793 ####
1794 #### This could be moved to the checks above,
1795 #### but for now let's keep it here.
1796 ####
1797
1798 # -- print message regarding enabled experimental features
1799 AS_IF([test "x$enable_experimental" = "xyes"],
1800       [experimental_msg="experimental features enabled"])
1801 # -- OSX Framework
1802 AS_IF([test "$enable_framework_build" = "yes"],
1803       [macosx_framework_msg="yes"],
1804       [macosx_framework_msg="no"])
1805 # -- libidn 2
1806 AS_IF([test "x$working_libidn2" = x1],
1807       [libidn2_msg="libidn2"])
1808 # -- libidn 1
1809 AS_IF([test "x$working_libidn1" = x1],
1810       [libidn1_msg="libidn1"])
1811 # -- texi2mdoc
1812 AS_IF([test "x$texi2mdoc_generation" = x1],
1813       [mdoc_msg="yes"],
1814       [mdoc_msg="no"])
1815 # -- texinfo
1816 AS_IF([test "x$makeinfo" != "x1"],
1817       [texinfo_msg="no"],
1818       [texinfo_msg="yes"])
1819 # -- conversation
1820 AS_IF([test "x$conversation_backend" = "xnone"],
1821       [AS_IF([test "x$pulse" != "x1"],
1822              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1823               libpulse_msg="no"],
1824              [libpulse_msg="yes"])
1825        AS_IF([test "x$opus" != "x1"],
1826              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1827               libopus_msg="no"],
1828              [libopus_msg="yes"])
1829        AS_IF([test "x$gst" != "x1"],
1830              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1831               gstreamer_msg="no"],
1832              [gstreamer_msg="yes"])],
1833       [features_msg="$features_msg conversation"])
1834 # -- interface
1835 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1836 # -- libmicrohttpd
1837 AS_IF([test "x$lmhd" != "x1"],
1838       [libmicrohttpd_msg="no (optional)"],
1839       [libmicrohttpd_msg="yes"])
1840 # -- jansson
1841 AS_IF([test "x$jansson" = "x0"],
1842       [jansson_msg="no (optional)"],
1843       [jansson_msg="yes"])
1844 # -- libextractor
1845 AS_IF([test "$extractor" != 1],
1846       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1847       [libextractor_msg="yes"])
1848 # -- libzbar
1849 AS_IF([test "x$zbar" = "x1"],
1850       [libzbar_msg="yes"
1851        features_msg="$features_msg gnunet-qr"],
1852       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1853        libzbar_msg="no"])
1854 # -- libgnurl
1855 AS_IF([test "$gnurl" = "0"],
1856       [AS_IF([test "x$curl" = "xfalse"],
1857              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1858               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1859               curl_msg="no"],
1860              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1861               curl_msg="yes"])],
1862        [gnurl_msg="yes"])
1863 # -- ifconfig
1864 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
1865       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
1866        ifconfig_msg="no (optional)"],
1867       [ifconfig_msg="yes"])
1868 # -- upnpc
1869 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
1870       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
1871        upnpc_msg="no (optional)"],
1872       [upnpc_msg="yes"])
1873 # -- iptables
1874 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
1875       [AC_MSG_NOTICE([WARNING: optional iptables not found])
1876        iptables_msg="no (optional)"],
1877       [iptables_msg="yes"])
1878 # -- bluetooth
1879 AS_IF([test "x$bluetooth" = "x0"],
1880       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
1881        bluetooth_msg="no (optional)"],
1882       [bluetooth_msg="yes"])
1883 # -- gnutls
1884 AS_IF([test x$gnutls != xtrue],
1885       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
1886        gnutls_msg="no"],
1887       [AS_IF([test "x$gnutls_dane" != "x1"],
1888              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
1889               gnutls_msg="yes (without DANE support)"],
1890              [gnutls_msg="yes (with DANE support)"])])
1891 # -- databases
1892 AS_IF([test $mysqlfail = true]
1893       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
1894 AS_IF([test "$mysql" = true],
1895       [features_msg="$features_msg mysql"
1896        mysql_msg="yes"],
1897       [mysql_msg="no"])
1898 AS_IF([test "$sqlite" = true],
1899       [features_msg="$features_msg sqlite"
1900        sqlite_msg="yes"],
1901       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1902        sqlite_msg="no"])
1903 AS_IF([test "$postgres" = true],
1904       [features_msg="$features_msg postgres"
1905        postgres_msg="yes"],
1906       [postgres_msg="no"])
1907 # -- features
1908 # ---- 1. replace spaces with newlines,
1909 # ---- 2. sort the lines,
1910 # ---- 3. replace the newlines with spaces.
1911 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
1912 AC_SUBST(features_msg)
1913
1914
1915 # The summary
1916 # TODO: reduce the length of the last message block ("the message")
1917
1918 AC_MSG_NOTICE([
1919 GNUnet Configuration (incomplete!)
1920
1921 gnunet version:                 ${VERSION}
1922
1923 Host setup:                     ${host}
1924 Install prefix:                 ${prefix}
1925 Compiler:                       ${CC}
1926 CFLAGS:                         ${CFLAGS}
1927 CPPFLAGS:                       ${CPPFLAGS}
1928 LDFLAGS:                        ${LDFLAGS}
1929 LIBS:                           ${LIBS}
1930 Build Target:                   $build_target
1931 Mac OSX framework build:        ${macosx_framework_msg}
1932
1933 Default Interface:              ${interface_msg}
1934
1935 MySQL:                          ${mysql_msg}
1936 PostgreSQL:                     ${postgres_msg}
1937 sqlite3:                        ${sqlite_msg}
1938 gnurl:                          ${gnurl_msg}
1939 curl:                           ${curl_msg}
1940 bluetooth:                      ${bluetooth_msg}
1941 jansson:                        ${jansson_msg}
1942 iptables:                       ${iptables_msg}
1943 ifconfig:                       ${ifconfig_msg}
1944 upnpc:                          ${upnpc_msg}
1945 gnutls:                         ${gnutls_msg}
1946 libzbar:                        ${libzbar_msg}
1947 java:                           ${java_msg}
1948 libmicrohttpd:                  ${libmicrohttpd_msg}
1949 libidn:                         ${libidn1_msg}${libidn2_msg}
1950 libopus:                        ${libopus_msg}
1951 gstreamer:                      ${gstreamer_msg}
1952 libpulse:                       ${libpulse_msg}
1953 libextractor:                   ${libextractor_msg}
1954
1955 texinfo manual:                 ${texinfo_msg}
1956 transpiled mdoc manual:         ${mdoc_msg}
1957
1958 features:                       ${features_msg}
1959 experimental:                   ${experimental_msg}
1960
1961
1962 IMPORTANT:
1963
1964 Please make sure NOW that you have created a user and group 'gnunet'
1965 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
1966 type:
1967
1968   addgroup gnunetdns
1969   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1970
1971 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1972 'gnunet'.  Then, you can compile GNUnet with
1973
1974   make
1975
1976 After that, run (if necessary as 'root')
1977
1978   make install
1979
1980 to install everything.
1981
1982 Each GNUnet user should be added to the 'gnunet' group (may
1983 require fresh login to come into effect):
1984
1985   adduser USERNAME gnunet
1986
1987 (run the above command as root once for each of your users, replacing
1988 "USERNAME" with the respective login names).  If you have a global IP
1989 address, no further configuration is required.
1990
1991 For more detailed setup instructions, see https://docs.gnunet.org/
1992
1993 Optionally, download and compile gnunet-gtk to get a GUI for
1994 file-sharing and configuration.  This is particularly recommended
1995 if your network setup is non-trivial, as gnunet-setup can be
1996 used to test in the GUI if your network configuration is working.
1997 gnunet-setup should be run as the "gnunet" user under X.  As it
1998 does very little with the network, running it as "root" is likely
1999 also harmless.  You can also run it as a normal user, but then
2000 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2001 home directory in the end.
2002
2003 Once you have configured your peer, run (as the 'gnunet' user)
2004
2005   gnunet-arm -s
2006
2007 to start the peer.  You can then run the various GNUnet-tools as
2008 your "normal" user (who should only be in the group 'gnunet').
2009 ])