configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.8], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen win32-dll])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 136      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 137      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 138      build_target="freebsd"
 139      LIBPREFIX=
 140      DLLDIR=lib
 141      UNIXONLY="#"
 142   ],
 143   [*openbsd*],[
 144      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 145      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 146      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 147      build_target="openbsd"
 148      LIBPREFIX=
 149      DLLDIR=lib
 150      UNIXONLY="#"
 151   ],
 152   [*netbsd*],[
 153      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 154      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 155      build_target="netbsd"
 156      LIBPREFIX=
 157      DLLDIR=lib
 158      UNIXONLY="#"
 159   ],
 160   [*solaris*],[
 161      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 162      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 163      AC_CHECK_LIB(resolv, res_init)
 164      AC_CHECK_LIB(rt, nanosleep)
 165      build_target="solaris"
 166      LIBPREFIX=
 167      DLLDIR=lib
 168      UNIXONLY="#"
 169   ],
 170   [*arm-linux*],[
 171      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 172      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 173      build_target="linux"
 174      LIBPREFIX=
 175      DLLDIR=lib
 176      UNIXONLY="#"
 177   ],
 178   [gnu*],[
 179      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 180      build_target="gnu"
 181      UNIXONLY="#"
 182   ],
 183   [
 184      AC_MSG_RESULT(Unrecognised OS $host_os)
 185      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 186      UNIXONLY=""
 187 ])
 188 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 189 AC_SUBST(DEFAULT_INTERFACE)
 190
 191 # Disable TCP-based IPC on systems that support UNIX domain
 192 # sockets in default configuratin:
 193 AC_SUBST(UNIXONLY)
 194
 195
 196 AC_MSG_CHECKING([for build target])
 197 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 198 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 199 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROGS(PKG_CONFIG, [pkgconf, pkg-config], false)
 226 AM_CONDITIONAL(HAVE_PKG_CONFIG, test x$PKG_CONFIG != xfalse)
 227
 228 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 229 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 230 AC_MSG_CHECKING(for SSH key)
 231   AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 232   if test -f /tmp/gnunet_test_cosks_ssh_garbage; then
 233      rm -f /tmp/gnunet_test_cosks_ssh_garbage
 234   fi
 235
 236
 237 # autotools' m4 for python has no maximum version!
 238 # python3.4 - python3.8 for tests (3.8 unchecked)
 239 # TODO: document how to override the lowest version
 240 # TODO: found by this.
 241 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 242 AM_PATH_PYTHON([3.4],, [:])
 243 AC_SUBST([PYTHON])
 244 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 245
 246 # perl
 247 AC_PATH_PROG( PERL, perl, ,
 248               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 249 AC_SUBST([PERL])
 250
 251 # iptables is a soft requirement to run tests
 252 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 253
 254 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 255  [AS_IF([test -x "/sbin/iptables"],
 256    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 257    [AS_IF([test -x "/usr/sbin/iptables"],
 258       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 259
 260 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 261  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 262  [AC_MSG_WARN([warning: 'iptables' not found.])])
 263
 264 # ip6tables is a soft requirement for some features
 265 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 266
 267 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 268   [AS_IF([test -x "/sbin/ip6tables"],
 269      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 270      [AS_IF([test -x "/usr/sbin/ip6tables"],
 271         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 272
 273
 274 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 275   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 276   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 277
 278 # ip is a soft requirement for some features
 279 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 280
 281 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 282  [AS_IF([test -x "/sbin/ip"],
 283    [VAR_IP_BINARY="/sbin/ip"],
 284    [AS_IF([test -x "/usr/sbin/ip"],
 285           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 286
 287 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 288  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 289  [AC_MSG_WARN([warning: 'ip' not found.])])
 290
 291 # locate 'ifconfig'
 292 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 293
 294 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 295 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 296   [AS_IF([test -x "/sbin/ifconfig"],
 297      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 298      [AS_IF([test -x "/usr/sbin/ifconfig"],
 299             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 300
 301 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 302   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 303   [AC_MSG_WARN(['ifconfig' not found.])])
 304
 305
 306 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 307
 308 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 309 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 310       [AS_IF([test -x "/sbin/sysctl"],
 311              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 312              [AS_IF([test -x "/usr/sbin/sysctl"],
 313                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 314 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 315       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 316       [AC_MSG_WARN(['sysctl' not found.])])
 317
 318 # miniupnpc / upnpc binary is a soft runtime requirement
 319 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 320
 321 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 322   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 323   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 324
 325
 326 # checkbashisms
 327 AC_CHECK_PROGS(CHECKBASHISMS_BINARY, [checkbashisms checkbashisms.pl], false)
 328 AM_CONDITIONAL(HAVE_CHECKBASHISMS, test x$CHECKBASHISMS_BINARY != xfalse)
 329
 330 # uncrustify
 331 # TODO: maybe add flag to pass location
 332 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 333 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 334
 335 # yapf
 336 # TODO: less repetition, add flag to pass name
 337 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 338 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 339
 340
 341 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 342   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 343      [Define if struct tm has the tm_gmtoff member.])],
 344      ,
 345      [#include <time.h>])
 346
 347 # 'save' libs; only those libs found so far will be
 348 # linked against _everywhere_.  For the others, we
 349 # will be more selective!
 350 SAVE_LIBS=$LIBS
 351
 352 have_addrinfo_a=0
 353 AC_CHECK_LIB(anl,
 354              getaddrinfo_a,
 355              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 356                                           1,
 357                                           [getaddrinfo_a supported])])
 358 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 359                [test "$have_addrinfo_a" = 1])
 360
 361 # libgcrypt
 362 gcrypt=0
 363 NEED_LIBGCRYPT_API=1
 364 NEED_LIBGCRYPT_VERSION=1.6.0
 365
 366
 367 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 368 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 369
 370 AS_IF([test $gcrypt = 0],
 371  [
 372   AC_MSG_ERROR([[
 373 ***
 374 *** You need libgcrypt to build this program.
 375 *** This library is for example available at
 376 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 377 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 378 ***  is required.
 379 ***]])
 380 ])
 381 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 382
 383 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 384
 385
 386
 387 # should the build process be building the documentation?
 388 AC_MSG_CHECKING(whether to build documentation)
 389 AC_ARG_ENABLE([documentation],
 390               [AS_HELP_STRING([--disable-documentation],
 391                               [do not build the documentation])],
 392               [documentation=${enableval}],
 393               [documentation=yes])
 394 AC_MSG_RESULT($documentation)
 395 AS_IF([test "x$documentation" = "xyes"],
 396       [AM_CONDITIONAL([DOCUMENTATION],
 397                       true)
 398        AC_DEFINE([DOCUMENTATION],
 399                  [1],
 400                  [Building the documentation])],
 401       [AM_CONDITIONAL([DOCUMENTATION],
 402                       false)
 403        AC_DEFINE([DOCUMENTATION],
 404                  [0],
 405                  [Not building the documentation])])
 406
 407 # COMMENT: Check wether to transpile texinfo to mdoc.
 408 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 409 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 410 # COMMENT: and makes the configure fail if it is missing.
 411 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 412 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 413 # COMMENT: or nothing was set (this is the default).
 414 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 415 # COMMENT: potential non-existence of the texi2mdoc binary.
 416 # COMMENT: Default return value / setting: no
 417 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 418 AC_ARG_ENABLE([texi2mdoc-generation],
 419               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 420                               [include generated texi2mdoc output in installation])],
 421               [texi2mdoc_generation=${enableval}],
 422               [texi2mdoc_generation=no])
 423 AC_MSG_RESULT($texi2mdoc_generation)
 424 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 425       [AS_IF([test "$texi2mdoc" = 0],
 426              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 427               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 428               AC_MSG_WARN([ERROR: Operating System package manager or from])
 429               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 430              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 431               AC_DEFINE([TEXI2MDOC_GENERATION],
 432                         [1],
 433                         [Building section 7 mdoc output])])],
 434       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 435                       false)
 436        AC_DEFINE([TEXI2MDOC_GENERATION],
 437                  [0],
 438                  [Not building section 7 mdoc output])])
 439
 440 # test for texi2mdoc (the binary, not the script distributed
 441 # with autogen)
 442 # TODO: refactor this and the check above.
 443 AC_MSG_CHECKING(for texi2mdoc binary)
 444 AC_CHECK_PROGS(TEXI2MDOC_BINARY, [texi2mdoc], false)
 445 AM_CONDITIONAL(HAVE_TEXI2MDOC, test x$TEXI2MDOC_BINARY != xfalse)
 446
 447 # texi2man is a tool which needs to be investigated and
 448 # is probably incompatible to texi2mdoc in invocation.
 449 # Detection at this point only serves as a reminder that
 450 # I will work this into the build-system.
 451 AC_MSG_CHECKING(for texi2man perl script)
 452 AC_CHECK_PROGS(TEXI2MAN_SCRIPT, [texi2man], false)
 453 AM_CONDITIONAL(HAVE_TEXI2MAN, test x$TEXI2MAN_SCRIPT != xfalse)
 454
 455
 456 # test for mandoc
 457 AC_MSG_CHECKING(for mandoc binary)
 458 AC_CHECK_PROGS(MANDOC_BINARY, [mandoc], false)
 459 AM_CONDITIONAL(HAVE_MANDOC, test x$MANDOC_BINARY != xfalse)
 460
 461 # should the build process be building only the documentation?
 462 AC_MSG_CHECKING(whether to build only documentation)
 463 AC_ARG_ENABLE([documentation-only],
 464    [AS_HELP_STRING([--enable-documentation-only],
 465                    [build only the documentation])],
 466    [documentation_only=${enableval}],
 467    [documentation_only=no])
 468 AC_MSG_RESULT($documentation_only)
 469 AS_IF([test "x$documentation_only" = "xyes"],
 470  [
 471   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 472   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 473  ],[
 474   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 475   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 476  ])
 477
 478 # should the build process be including the manpages? (default: yes)
 479 AC_MSG_CHECKING(whether to include man pages)
 480 AC_ARG_ENABLE([include-manpages],
 481    [AS_HELP_STRING([--disable-include-manpages],
 482                    [Do not include the man pages in build and installation])],
 483    [include_manpages=${enableval}],
 484    [include_manpages=yes])
 485 AC_MSG_RESULT($include_manpages)
 486 AS_IF([test "x$include_manpages" = "xyes"],
 487  [
 488   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 489   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 490  ],[
 491   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 492   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 493  ])
 494
 495 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 496 # (not syntax!) to the commandline tools which generate the html. If not,
 497 # texinfo5 switches are used. This comes with no version checks, is
 498 # enabled only at distributors action (ie defaults to "no").
 499 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 500 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 501 AC_ARG_ENABLE([texinfo4],
 502    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 503    [activate_texinfo4=${enableval}],
 504    [activate_texinfo4=no])
 505 AC_MSG_RESULT($activate_texinfo4)
 506 AS_IF([test "x$activate_texinfo4" = "xyes"],
 507  [
 508   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 509   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 510  ],[
 511   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 512   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 513  ])
 514
 515
 516 # Adam shostack suggests the following for Windows:
 517 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 518 AC_ARG_ENABLE(gcc-hardening,
 519    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 520 [AS_IF([test x$enableval = xyes],[
 521     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 522     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 523     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 524     LDFLAGS="$LDFLAGS -pie"
 525  ])])
 526
 527 # Linker hardening options
 528 # Currently these options are ELF specific - you can't use this with MacOSX
 529 AC_ARG_ENABLE(linker-hardening,
 530   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 531 [AS_IF([test x$enableval = xyes],
 532    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 533
 534
 535 AC_ARG_ENABLE(sanitizer,
 536   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 537 [AS_IF([test x$enableval = xyes],[
 538    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 539  ])])
 540
 541
 542 extra_logging=GNUNET_NO
 543 AC_ARG_ENABLE([logging],
 544    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 545    [AS_IF([test "x$enableval" = "xyes"], [],
 546           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 547           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 548           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 549    ], [])
 550 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 551
 552 # should memory poisoning be enabled?
 553 AC_MSG_CHECKING(whether to poison freed memory)
 554 AC_ARG_ENABLE([poisoning],
 555    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 556    [enable_poisoning=${enableval}],
 557    [
 558      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 559        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 560        [enable_poisoning=no])
 561    ])
 562 AC_MSG_RESULT($enable_poisoning)
 563 AS_IF([test ! "x$enable_poisoning" = "xno"],
 564   [enable_poisoning=1],
 565   [enable_poisoning=0])
 566 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 567
 568 AS_IF([test $build = $target],
 569 [
 570 AC_MSG_CHECKING([for working HMAC])
 571 AC_LANG_PUSH(C)
 572 LIBS="$LIBS $LIBGCRYPT_LIBS"
 573 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 574 AC_RUN_IFELSE(
 575   [AC_LANG_PROGRAM([#include <gcrypt.h>
 576         #include <stdio.h>], [[
 577         gcry_md_hd_t mac;
 578
 579         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 580             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 581             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 582         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 583         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 584             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 585             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 586             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 587             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 588             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 589
 590         if (!gcry_check_version (GCRYPT_VERSION))
 591         {
 592           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 593           return 1;
 594         }
 595
 596         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 597         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 598
 599         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 600         {
 601           fprintf (stderr, "gcry_md_open error\n");
 602           return 2;
 603         }
 604
 605         gcry_md_setkey (mac, key, sizeof (key));
 606         gcry_md_write (mac, data, sizeof (data));
 607
 608         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 609         {
 610           fprintf (stderr, "memcmp error\n");
 611           return 3;
 612         }
 613
 614         gcry_md_close (mac);
 615
 616         return 0;
 617     ]])],
 618   [AC_MSG_RESULT([yes])],
 619   [
 620    RESULT=$?
 621    if test $RESULT = 3
 622    then
 623      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 624    fi
 625    if test $RESULT = 2
 626    then
 627      AC_MSG_FAILURE([HMAC test failed])
 628    fi
 629    if test $RESULT = 1
 630    then
 631      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 632    fi
 633   ],
 634   [AC_MSG_RESULT([cross compiling, test skipped])])
 635 AC_LANG_POP(C)
 636 ])      # $build = $target
 637
 638 # check for bluetooth library
 639 bluetooth=0
 640 AC_MSG_CHECKING(for libbluetooth)
 641 AC_ARG_WITH(libbluetooth,
 642     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 643     [AC_MSG_RESULT([$with_libbluetooth])
 644      AS_CASE([$with_libbluetooth],
 645         [no],[],
 646         [yes],[
 647             CHECK_LIBHEADER(BLUETOOTH,
 648                             bluetooth,
 649                             ba2str,
 650                             bluetooth/bluetooth.h,
 651                             bluetooth=1,)
 652         ],[
 653             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 654             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 655             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 656                              AC_CHECK_LIB([bluetooth],
 657                                           [ba2str],
 658                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 659                                           bluetooth=1))
 660         ])
 661     ],
 662     [AC_MSG_RESULT([--with-libbluetooth not specified])
 663      CHECK_LIBHEADER(BLUETOOTH,
 664                      bluetooth,
 665                      ba2str,
 666                      bluetooth/bluetooth.h,
 667                      bluetooth=1,)])
 668 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 669 AS_IF([test "$bluetooth" = 1],
 670       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 671       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 672
 673 # check for zbar library
 674 # TODO: Add checks for: -lSM, -lICE, -lX11, -lXv and -ljpeg
 675 # TODO: if zbar exists.
 676 zbar=0
 677 AC_MSG_CHECKING(for libzbar)
 678 AC_ARG_WITH(zbar,
 679    [  --with-zbar=PREFIX (base of libzbar installation)],
 680    [AC_MSG_RESULT([$with_zbar])
 681     AS_CASE([$with_zbar],
 682       [no],[],
 683       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 684       [
 685         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 686         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 687         AC_CHECK_HEADERS(zbar.h,
 688           AC_CHECK_LIB([zbar], [zbar_processor_create],
 689             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 690             zbar=1))
 691        ])
 692    ],
 693    [AC_MSG_RESULT([--with-zbar not specified])
 694     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 695 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 696 AS_IF([test "x$zbar" = x1],
 697       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 698       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 699
 700 # check for jansson library
 701 jansson=0
 702 AC_MSG_CHECKING(for libjansson)
 703 AC_ARG_WITH(jansson,
 704    [  --with-jansson=PREFIX (base of libjansson installation)],
 705    [AC_MSG_RESULT([$with_jansson])
 706     AS_CASE([$with_jansson],
 707       [no],[],
 708       [yes],[
 709         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 710       ],[
 711         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 712         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 713         AC_CHECK_HEADERS(jansson.h,
 714           AC_CHECK_LIB([jansson], [json_loads],
 715             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 716             jansson=1))
 717       ])
 718    ],
 719    [AC_MSG_RESULT([--with-jansson not specified])
 720     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 721 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 722 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 723 AS_IF([test "x$jansson" = x1],
 724       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 725       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 726
 727
 728 # check for libpulse(audio) library
 729 pulse=0
 730 libpulse_msg="no"
 731 AC_MSG_CHECKING(for libpulse)
 732 # TODO: --with-libpulse or --with-pulseaudio? What is more established
 733 # TODO: in this context?
 734 AC_ARG_WITH(libpulse,
 735     [  --with-libpulse=PREFIX (base of libpulse installation)],
 736     [AC_MSG_RESULT([$with_libpulse])
 737      AS_CASE([$with_libpulse],
 738         [no],[],
 739         [yes],[
 740             CHECK_LIBHEADER(LIBPULSE,
 741                             pulse,
 742                             pa_stream_peek,
 743                             pulse/simple.h,
 744                             pulse=1,)
 745         ],[
 746             LDFLAGS="-L$with_libpulse/lib $LDFLAGS"
 747             CPPFLAGS="-I$with_libpulse/include $CPPFLAGS"
 748             AC_CHECK_HEADERS(pulse/simple.h,
 749                              AC_CHECK_LIB([pulse],
 750                                           [pa_stream_peek],
 751                                           EXT_LIB_PATH="-L$with_libpulse/lib $EXT_LIB_PATH"
 752                                           pulse=1))
 753         ])
 754     ],
 755     [AC_MSG_RESULT([--with-libpulse not specified])
 756      CHECK_LIBHEADER(LIBPULSE,
 757                      pulse,
 758                      pa_stream_peek,
 759                      pulse/simple.h,
 760                      pulse=1,)])
 761 AM_CONDITIONAL(HAVE_PULSE, [test "$pulse" = 1])
 762 AS_IF([test x"$pulse" = x1],
 763       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 764        libpulse_msg="yes"],
 765       [AC_DEFINE([HAVE_PULSE],[0],[Lacking libpulse(audio) library])
 766        libpulse_msg="no"])
 767
 768 # check for libopus(audio) library
 769 opus=0
 770 libopus_msg="no"
 771 AC_MSG_CHECKING(for libopus)
 772 AC_ARG_WITH(libopus,
 773     [  --with-libopus=PREFIX (base of libopus installation)],
 774     [AC_MSG_RESULT([$with_libopus])
 775      AS_CASE([$with_libopus],
 776         [no],[],
 777         [yes],[
 778             CHECK_LIBHEADER(LIBOPUS,
 779                             opus,
 780                             opus_decode_float,
 781                             opus/opus.h,
 782                             AC_CHECK_DECL([OPUS_SET_GAIN],
 783                                           [opus=1],
 784                                           [],
 785                                           [[
 786                                           #include <opus/opus.h>
 787                                           ]]))
 788     ],[
 789         LDFLAGS="-L$with_libopus/lib $LDFLAGS"
 790         CPPFLAGS="-I$with_libopus/include $CPPFLAGS"
 791         AC_CHECK_HEADERS(opus/opus.h,
 792                          AC_CHECK_LIB([opus],
 793                                       [OPUS_SET_GAIN],
 794                                       EXT_LIB_PATH="-L$with_libopus/lib $EXT_LIB_PATH"
 795                                       opus=1))
 796       ])
 797     ],
 798     [AC_MSG_RESULT([--with-libopus not specified])
 799      CHECK_LIBHEADER(LIBOPUS,
 800                      opus,
 801                      opus_decode_float,
 802                      opus/opus.h,
 803                      AC_CHECK_DECL([OPUS_SET_GAIN],
 804                                    [opus=1],
 805                                    [],
 806                                    [[
 807                                      #include <opus/opus.h>
 808                                    ]]))])
 809 AM_CONDITIONAL(HAVE_OPUS, [test "$opus" = 1])
 810 AS_IF([test "x$opus" = x1],
 811       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 812        libopus_msg="yes"],
 813       [AC_DEFINE([HAVE_OPUS],[0],[Lacking libopus library])
 814        libopus_msg="no"])
 815
 816 # libogg
 817 AC_MSG_CHECKING(for libogg)
 818 AC_ARG_WITH(libogg,
 819     [  --with-libogg=PREFIX (base of libogg installation)],
 820     [AC_MSG_RESULT([$with_libogg])
 821      AS_CASE([$with_libogg],
 822         [no],[],
 823         [yes],[
 824             CHECK_LIBHEADER(LIBOGG,
 825                             ogg,
 826                             ogg_stream_flush_fill,
 827                             ogg/ogg.h,
 828                             ogg=1,)
 829         ],[
 830             LDFLAGS="-L$with_libogg/lib $LDFLAGS"
 831             CPPFLAGS="-I$with_libogg/include $CPPFLAGS"
 832             AC_CHECK_HEADERS(ogg/ogg.h,
 833                              AC_CHECK_LIB([ogg],
 834                                           [ogg_stream_flush_fill],
 835                                           EXT_LIB_PATH="-L$with_libogg/lib $EXT_LIB_PATH"
 836                                           ogg=1))
 837         ])
 838      ],
 839      [AC_MSG_RESULT([--with-libogg not specified])
 840       CHECK_LIBHEADER(LIBOGG,
 841                       ogg,
 842                       ogg_stream_flush_fill,
 843                       ogg/ogg.h,
 844                       ogg=1,)])
 845 AM_CONDITIONAL(HAVE_OGG, [test "$ogg" = 1])
 846 AS_IF([test x"$ogg" = x1],
 847       [AC_DEFINE([HAVE_OGG],[1],[Have ogg])]
 848       [AC_DEFINE([HAVE_OGG],[0],[Lacking ogg])])
 849
 850
 851 PKG_CHECK_MODULES([GLIB],
 852                   [glib-2.0],
 853   [# check for pbc library
 854   pbc=0
 855    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 856    AC_CHECK_HEADER([gabe.h],abe=1)
 857    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 858    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 859    AS_IF([test "x$pbc" = x1],
 860      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 861      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 862    AS_IF([test "x$abe" = x1],
 863     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 864     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 865   [# glib-2 not found
 866    AM_CONDITIONAL(HAVE_PBC, [false])
 867    AM_CONDITIONAL(HAVE_ABE, [false])
 868    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 869
 870
 871 gst=0
 872 gstreamer_msg="no"
 873 AC_MSG_CHECKING(for gstreamer)
 874 PKG_CHECK_MODULES(
 875   [GST],
 876   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 877   [gst=1
 878    gstreamer_msg="yes"],
 879   [gst=0])
 880
 881 # conversation
 882 AC_MSG_CHECKING(conversation feature set to build)
 883 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 884  AS_IF([test "x$gst" != "x1"],[
 885   conversation_backend=none
 886   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 887   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 888   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 889  ],[
 890    conversation_backend=gst
 891    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 892    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 893    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 894  ])
 895 ],[
 896  conversation_backend=pulse
 897  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 898  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 899  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 900 ])
 901
 902 AS_IF([test "x$conversation_backend" = "xnone"],
 903       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 904       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 905
 906 # libgnurl
 907 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 908
 909 SAVE_CPPFLAGS=$CPPFLAGS
 910 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 911 LIBS="$LIBGNURL $LIBCURL $LIBS"
 912
 913 # libcurl-gnutls
 914 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 915 AS_IF([test "x$curl" = xtrue],[
 916  AC_CHECK_HEADER([curl/curl.h],
 917   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 918   [curl=false])
 919  # need libcurl-gnutls.so, everything else is not acceptable
 920  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 921  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 922 ])
 923
 924 # libcurl and libgnurl should be mutually exclusive
 925 AS_IF([test "$gnurl" = 1],
 926       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 927        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 928        AM_CONDITIONAL(HAVE_LIBCURL, false)
 929        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 930       [AS_IF([test "$curl" = true],
 931              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 932               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 933               AM_CONDITIONAL(HAVE_LIBCURL, true)
 934               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 935              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 936               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 937               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 938               AM_CONDITIONAL(HAVE_LIBCURL, false)
 939               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 940
 941 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 942 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 943
 944 # restore LIBS & CPPFLAGS
 945 LIBS=$SAVE_LIBS
 946 CPPFLAGS=$SAVE_CPPFLAGS
 947
 948
 949 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 950 AS_IF([test x$nss = xfalse],
 951   [
 952         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 953         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 954   ],[
 955         NSS_INCLUDES="
 956         #include <nss.h>
 957         "
 958         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 959                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 960                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 961                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 962                 [$NSS_INCLUDES])
 963 ])
 964
 965
 966
 967 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 968 AC_CHECK_LIB([kvm],[kvm_open])
 969 AC_CHECK_LIB([kstat],[kstat_open])
 970
 971
 972 # should the build process be restricted to the code required
 973 # for GNU Taler wallets?
 974 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 975 AC_ARG_ENABLE([taler-wallet],
 976    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 977    [taler_only=${enableval}],
 978    [taler_only=no])
 979 AC_MSG_RESULT($taler_only)
 980 AS_IF([test "x$taler_only" = "xyes"],
 981 [
 982   AM_CONDITIONAL([TALER_ONLY],true)
 983   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 984 ],[
 985   AM_CONDITIONAL([TALER_ONLY],false)
 986   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 987 ])
 988
 989 # test for libextractor
 990 extractor=0
 991 AC_MSG_CHECKING(for libextractor)
 992 AC_ARG_WITH(extractor,
 993    [  --with-extractor=PREFIX (base of libextractor installation)],
 994    [AC_MSG_RESULT([$with_extractor])
 995     AS_CASE([$with_extractor],
 996       [no],[],
 997       [yes],[
 998         AC_CHECK_HEADERS([extractor.h],
 999           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1000             extractor=1))
1001       ],[
1002         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
1003         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
1004         AC_CHECK_HEADERS([extractor.h],
1005           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1006             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
1007             extractor=1))
1008       ])
1009    ],
1010    [AC_MSG_RESULT([--with-extractor not specified])
1011     AC_CHECK_HEADERS([extractor.h],
1012      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1013       extractor=1))])
1014 # restore LIBS
1015 LIBS=$SAVE_LIBS
1016
1017 AS_IF([test "$extractor" != 1],
1018  [
1019  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
1020  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
1021  ],[
1022  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
1023  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
1024  ])
1025
1026
1027 AS_IF([test "$taler_only" != yes],[
1028
1029
1030 # Check for libltdl header (#2999)
1031 ltdl=0
1032 AC_MSG_CHECKING(for libltdl)
1033 AC_ARG_WITH(ltdl,
1034    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
1035    [AC_MSG_RESULT([$with_ltdl])
1036     AS_CASE([$with_ltdl],
1037       [no],[],
1038       [yes],[
1039         AC_CHECK_HEADERS(ltdl.h,
1040           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1041             ltdl=1))
1042       ],[
1043         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
1044         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
1045         AC_CHECK_HEADERS(ltdl.h,
1046           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1047             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
1048             ltdl=1))
1049       ])
1050    ],
1051    [AC_MSG_RESULT([--with-ltdl not specified])
1052     AC_CHECK_HEADERS(ltdl.h,
1053      AC_CHECK_LIB([ltdl], [lt_dlopenext],
1054       ltdl=1))])
1055 AS_IF([test x$ltdl = x1],
1056 [
1057  AC_MSG_RESULT([libltdl found])
1058 ],[
1059  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool).])
1060 ])
1061 # restore LIBS
1062 LIBS=$SAVE_LIBS
1063
1064 # libidn and libidn2. The ideal goal is this:
1065 # check for libidn2, if it doesn't exist check for libidn
1066 # if both exist, prefer libidn2
1067 # if none exist, fail and message that libidn or libidn2
1068 # is required with a preference for libidn2.
1069 # TODO: What we have right here can probably be improved.
1070 AC_MSG_CHECKING(for idn or idn2)
1071
1072 AC_MSG_CHECKING(for idn)
1073 my_with_libidn=1
1074 AC_ARG_WITH(libidn,
1075             AS_HELP_STRING([--with-libidn=pathname],
1076                            [Support IDN (needs libidn)]),
1077             [],
1078             [withval="yes"])
1079 AS_IF([test x_$withval = x_yes],
1080       [AC_CHECK_HEADERS([idna.h],
1081                         AC_MSG_NOTICE([Found idna.h]),
1082                         AC_CHECK_HEADERS([idn/idna.h],
1083                                          AC_MSG_NOTICE([Found idn/idna.h]),
1084                                          my_with_libidn=0))],
1085       [AS_IF([test x_$withval != x_no],
1086              [CFLAGS="$CFLAGS -I$withval/include"
1087               LDFLAGS="$LDFLAGS -L$withval/lib"
1088               AC_CHECK_HEADERS([idna.h],
1089                                AC_MSG_NOTICE([Found idna.h]),
1090                                    [AC_MSG_NOTICE([Failed to find idna.h])
1091                                my_with_libidn=0])],
1092              [my_with_libidn=0])])
1093
1094 AC_MSG_CHECKING(for idn2)
1095 my_with_libidn2=1
1096 AC_ARG_WITH(libidn2,
1097             AS_HELP_STRING([--with-libidn2=pathname],
1098                            [Support IDN (needs libidn2)]),
1099             [],
1100             [withval="yes"])
1101 AS_IF([test x_$withval = x_yes],
1102       [AC_CHECK_HEADERS([idn2.h],
1103                         AC_MSG_NOTICE([Found idn2.h]),
1104                         AC_CHECK_HEADERS([idn2/idn2.h],
1105                                          AC_MSG_NOTICE([Found idn2/idn2.h]),
1106                                          [AC_MSG_NOTICE([Failed to find idn2.h])
1107                                          my_with_libidn2=0]))],
1108       [AS_IF([test x_$withval != x_no],
1109              [CFLAGS="$CFLAGS -I$withval/include"
1110               LDFLAGS="$LDFLAGS -L$withval/lib"],
1111                   [my_with_libidn2=0])])
1112
1113 AC_MSG_CHECKING([if libidn can be used])
1114 # Check for LIBIDNs
1115 there_can_only_be_one=1
1116
1117 working_libidn1=0
1118 working_libidn2=0
1119 AS_IF([test x$my_with_libidn2 = x1],
1120       [AC_MSG_NOTICE([Checking for libidn2])
1121        AC_CHECK_LIB([idn2],
1122                     [idn2_to_unicode_8z8z],
1123                     [working_libidn2=1
1124                     LIBS="-lidn2 $LIBS"
1125                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1126                                        [1],
1127                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1128                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1129                      MISSING_SEP=", "])])
1130 AM_CONDITIONAL(HAVE_LIBIDN2, test x$working_libidn2 = x1)
1131 AS_IF([test x$working_libidn2 = x0],
1132       [AS_IF([test x$my_with_libidn = x1],
1133              [AC_MSG_NOTICE([Checking for libidn])
1134               AC_CHECK_LIB([idn],
1135                            [idna_to_ascii_8z],
1136                            [working_libidn1=1
1137                            LIBS="-lidn $LIBS"
1138                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1139                                               [1],
1140                                               [Define to 1 if you have 'libidn' (-lidn).])],
1141                            [there_can_only_be_one=0])],
1142              [AS_IF([test x$my_with_libidn2 = x1],
1143                     [there_can_only_be_one=0
1144                      AC_MSG_FAILURE([* There can only be one libidn.
1145                                      * Provide either libidn >= 1.13
1146                                      * or
1147                                      * libidn2 to the configure
1148                                      * script via
1149                                      * --with-libidn2
1150                                      * --with-libidn])])])])
1151 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1152
1153 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1154       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1155
1156 AS_IF([test x$there_can_only_be_one = x0],
1157       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1158
1159 # test for zlib
1160 SAVE_LDFLAGS=$LDFLAGS
1161 SAVE_CPPFLAGS=$CPPFLAGS
1162 AC_ARG_WITH(zlib,
1163             [  --with-zlib[[=DIR]]       use libz in DIR],
1164             [AS_IF([test "$withval" = "no"],
1165                    [AC_MSG_ERROR([GNUnet requires zlib])],
1166                    [test "$withval" != "yes"],
1167                    [Z_DIR=$withval
1168                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1169                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1170 AC_CHECK_HEADER(zlib.h,
1171                 [],
1172                 [AC_MSG_ERROR([GNUnet requires zlib])])
1173 AC_CHECK_LIB(z,
1174              compress2,
1175              [AC_DEFINE([HAVE_ZLIB],
1176                         [],
1177                         [Have compression library])
1178               if test "x${Z_DIR}" != "x"; then
1179                       Z_CFLAGS="-I${Z_DIR}/include"
1180                       Z_LIBS="-L${Z_DIR}/lib -lz"
1181               else
1182                       Z_LIBS="-lz"
1183               fi],
1184               [AC_MSG_ERROR([GNUnet requires zlib])])
1185 AC_SUBST(Z_CFLAGS)
1186 AC_SUBST(Z_LIBS)
1187
1188 AS_IF([test "$enable_shared" = "no"],
1189       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1190
1191
1192 # restore LIBS
1193 LIBS=$SAVE_LIBS
1194
1195
1196 # end of taler-only being false
1197 ])
1198
1199
1200 # check for iconv
1201 AM_ICONV
1202
1203 # test for libunistring
1204 gl_LIBUNISTRING
1205 AS_IF([test $HAVE_LIBUNISTRING != yes],
1206       [AC_MSG_ERROR([GNUnet requires libunistring])])
1207
1208 # under emscripten, $gl_libunistring_hexversion is undefined
1209 if test "$taler_only" != yes; then
1210
1211 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1212       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1213 fi
1214 AC_CHECK_HEADERS([unistr.h],
1215                  ,
1216                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1217
1218 # restore LIBS
1219 LIBS=$SAVE_LIBS
1220
1221
1222
1223 # Checks for standard header files.
1224 AC_HEADER_DIRENT
1225 AC_HEADER_STDC
1226
1227 # Check for headers that are ALWAYS required
1228 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1229
1230
1231
1232 # Checks for headers that are only required on some systems or
1233 # opional (and where we do NOT abort if they are not there)
1234 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1235
1236 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1237 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1238 [#ifdef HAVE_SYS_TYPES_H
1239 #include <sys/types.h>
1240 #endif
1241 #ifdef HAVE_NETINET_IN_SYSTM_H
1242 #include <netinet/in_systm.h>
1243 #endif
1244 #ifdef HAVE_NETINET_IN_H
1245 #include <netinet/in.h>
1246 #endif
1247 ])
1248
1249 SAVE_LDFLAGS=$LDFLAGS
1250 SAVE_CPPFLAGS=$CPPFLAGS
1251
1252 # test for sqlite
1253 sqlite=false
1254 AC_MSG_CHECKING(for SQLite)
1255 AC_ARG_WITH(sqlite,
1256   [  --with-sqlite=PFX       base of SQLite installation],
1257   [AC_MSG_RESULT("$with_sqlite")
1258    AS_CASE([$with_sqlite],
1259      [no],[],
1260      [yes],[
1261       AC_CHECK_HEADERS(sqlite3.h,
1262       sqlite=true)],
1263      [
1264     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1265     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1266     AC_CHECK_HEADERS(sqlite3.h,
1267      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1268      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1269      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1270      sqlite=true)
1271     LDFLAGS=$SAVE_LDFLAGS
1272     CPPFLAGS=$SAVE_CPPFLAGS
1273     ])
1274   ],
1275   [AC_MSG_RESULT([--with-sqlite not specified])
1276     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1277 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1278 AC_SUBST(SQLITE_CPPFLAGS)
1279 AC_SUBST(SQLITE_LDFLAGS)
1280
1281 LDFLAGS=$SAVE_LDFLAGS
1282 CPPFLAGS=$SAVE_CPPFLAGS
1283
1284 # test for postgres:
1285 postgres=false
1286 # even running the check for postgres breaks emscripten
1287 AS_IF([test "$taler_only" != yes],
1288       [AX_LIB_POSTGRESQL([9.5],
1289         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1290          AC_CHECK_HEADERS([libpq-fe.h],
1291          postgres=true)
1292         ],
1293         [AC_MSG_RESULT([no postgres])])])
1294
1295 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1296 AS_IF([test "x$postgres" = xtrue],
1297       [AC_DEFINE([HAVE_POSTGRESQL],[1],[Have PostgreSQL])],
1298       [AC_DEFINE([HAVE_POSTGRESQL],[0],[Lacking PostgreSQL])])
1299
1300 LDFLAGS=$SAVE_LDFLAGS
1301 CPPFLAGS=$SAVE_CPPFLAGS
1302
1303 # mysql & windows
1304 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1305 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1306
1307 # test for mysql
1308 mysql=false
1309 mysqlfail=false
1310 SAVE_LDFLAGS=$LDFLAGS
1311 SAVE_CPPFLAGS=$CPPFLAGS
1312 AC_MSG_CHECKING(for mysql)
1313 AC_ARG_WITH(mysql,
1314   [  --with-mysql=PFX        base of MySQL installation],
1315   [AC_MSG_RESULT([$with_mysql])
1316    AS_CASE([$with_mysql],
1317      [no],[],
1318      [yes|""],[
1319       AC_CHECK_HEADERS(mysql/mysql.h,
1320        AC_CHECK_LIB(mysqlclient, mysql_init,
1321        mysql=true), [], [])
1322      ],[
1323       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1324       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1325       AC_CHECK_HEADERS(mysql/mysql.h,
1326        AC_CHECK_LIB(mysqlclient, mysql_init,
1327         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1328         MYSQL_CPPFLAGS="-I$with_mysql/include"
1329
1330         mysql=true), [], [])
1331      ])
1332   ],
1333   [AC_MSG_RESULT([--with-mysql not specified])
1334    if test -d "/usr/lib64/mysql"; then
1335     MYSQL_LIBDIR="/usr/lib64/mysql"
1336    elif test -d "/usr/lib/mysql"; then
1337     MYSQL_LIBDIR="/usr/lib/mysql"
1338    else
1339     MYSQL_LIBDIR="/usr/lib"
1340    fi
1341    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1342    AC_CHECK_LIB(mysqlclient, mysql_init,
1343     [AC_CHECK_HEADERS(mysql/mysql.h,
1344       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1345       mysql=true
1346
1347      , [], [])])
1348   ])
1349
1350 AC_SUBST(MYSQL_LDFLAGS)
1351 AC_SUBST(MYSQL_CPPFLAGS)
1352
1353 # additional version check for mysql
1354 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1355 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1356  [
1357   AC_MSG_CHECKING(mysql version)
1358   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1359     [[
1360       #include <mysql/mysql.h>]],
1361     [[
1362       #if (MYSQL_VERSION_ID < 40100)
1363       #error needs at least version >= 4.1
1364       #endif
1365       int main () { return 0; }
1366     ]])
1367     ],mysql=true,mysql=false)
1368   AS_IF([test "$mysql" = "false"],
1369    [
1370     mysqlfail=true
1371     AC_MSG_RESULT([fail, >= 4.1 required])
1372    ],[
1373     AC_MSG_RESULT(ok)
1374    ])
1375 ])
1376 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1377 AM_CONDITIONAL(HAVE_MYSQLE, false)
1378 # restore LIBS
1379 LIBS=$SAVE_LIBS
1380 LDFLAGS=$SAVE_LDFLAGS
1381 CPPFLAGS=$SAVE_CPPFLAGS
1382
1383 # TODO: should this test for "or" not "and"?
1384 # TODO: Add postgres?
1385 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1386 [
1387  AC_MSG_ERROR([GNUnet requires SQLite or MySQL / MariaDB.])
1388 ])
1389
1390 # libmicrohttpd
1391 lmhd=0
1392 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1393 AC_ARG_WITH(microhttpd,
1394    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1395        [base of libmicrohttpd installation])],
1396    [],
1397    [with_microhttpd=check])
1398 AS_CASE([$with_microhttpd],
1399    [no], [],
1400    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1401    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1402        [lmhd=1],
1403        [AC_MSG_WARN([Building without libmicrohttpd])])],
1404    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1405     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1406     export PKG_CONFIG_PATH
1407     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1408     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1409 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1410 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1411
1412 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1413
1414 # restore LIBS
1415 LIBS=$SAVE_LIBS
1416
1417 # check for gettext
1418 AM_GNU_GETTEXT([external])
1419 AM_GNU_GETTEXT_VERSION([0.18.1])
1420
1421 # Checks for standard typedefs, structures, and compiler characteristics.
1422 AC_TYPE_PID_T
1423 AC_TYPE_SIZE_T
1424 AC_TYPE_MODE_T
1425 AC_HEADER_TIME
1426 AC_HEADER_STAT
1427 AC_HEADER_STDBOOL
1428 AC_STRUCT_TM
1429
1430 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1431    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1432    ],
1433    [],
1434    [
1435       #include <sys/types.h>
1436       #include <sys/socket.h>
1437       #include <netinet/in.h>
1438    ])
1439
1440 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1441                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1442                             1,
1443                             [Do we have sockaddr_un.sun_len?])],
1444                 [],
1445                 [
1446                 #include <sys/types.h>
1447                 #include <sys/socket.h>
1448                 #include <sys/un.h>
1449                 ])
1450
1451
1452
1453 # Checks for library functions.
1454 AC_FUNC_CLOSEDIR_VOID
1455 AC_FUNC_FORK
1456 AC_PROG_GCC_TRADITIONAL
1457 AC_FUNC_MEMCMP
1458 AC_FUNC_SELECT_ARGTYPES
1459 AC_FUNC_CHOWN
1460
1461 AC_TYPE_SIGNAL
1462 AC_FUNC_STAT
1463 AC_FUNC_STRFTIME
1464 AC_FUNC_VPRINTF
1465 AC_HEADER_SYS_WAIT
1466 AC_TYPE_OFF_T
1467 AC_TYPE_UID_T
1468 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1469
1470 # restore LIBS
1471 LIBS=$SAVE_LIBS
1472
1473 GN_INTLINCL=""
1474 GN_LIBINTL="$LTLIBINTL"
1475 AC_ARG_ENABLE(framework,
1476               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1477               enable_framework_build=$enableval)
1478 AM_CONDITIONAL(WANT_FRAMEWORK,
1479                test x$enable_framework_build = xyes)
1480 AS_IF([test x$enable_framework_build = xyes],
1481       [AC_DEFINE([FRAMEWORK_BUILD],
1482                  1,
1483                  [Build a Mac OS X Framework])
1484       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1485       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1486       AC_LIB_APPENDTOVAR([CPPFLAGS],
1487                          [$GN_INTLINCL])])
1488
1489 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1490 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1491
1492 AC_SUBST(GN_LIB_LDFLAGS)
1493 AC_SUBST(GN_PLUGIN_LDFLAGS)
1494 AC_SUBST(GN_INTLINCL)
1495 AC_SUBST(GN_LIBINTL)
1496
1497 AC_SUBST(CPPFLAGS)
1498 AC_SUBST(LIBS)
1499 AC_SUBST(LDFLAGS)
1500 AC_SUBST(EXT_LIB_PATH)
1501 AC_SUBST(EXT_LIBS)
1502
1503 AC_SUBST(LIBPREFIX)
1504 AC_SUBST(DLLDIR)
1505 AC_SUBST(EXT_LIB_PATH)
1506
1507 DATAROOTDIR=$datarootdir
1508 AC_SUBST(DATAROOTDIR)
1509
1510 # test for sudo
1511 AC_MSG_CHECKING(for sudo)
1512 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1513 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1514 AC_ARG_WITH(sudo,
1515            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1516            [AC_MSG_RESULT("$with_sudo")
1517             AS_CASE([$with_sudo],
1518                     [no],[SUDO_BINARY=],
1519                     [yes],[SUDO_BINARY=sudo],
1520                     [SUDO_BINARY=$with_sudo])],
1521            [AC_MSG_RESULT([no])])
1522 AC_SUBST(SUDO_BINARY)
1523 AM_CONDITIONAL([HAVE_SUDO],
1524               [test "x$SUDO_BINARY" != "x" -o -w /])
1525
1526 # test for doas
1527 AC_MSG_CHECKING(for doas)
1528 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1529 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1530
1531 # test for gnunetdns group name
1532 GNUNETDNS_GROUP=gnunetdns
1533 AC_MSG_CHECKING(for gnunetdns group name)
1534 AC_ARG_WITH(gnunetdns,
1535             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1536             [AC_MSG_RESULT("$with_gnunetdns")
1537              AS_CASE([$with_gnunetdns],
1538                      [no],[GNUNETDNS_GROUP=gnunet],
1539                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1540                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1541             [AC_MSG_RESULT([gnunetdns])])
1542 AC_SUBST(GNUNETDNS_GROUP)
1543
1544
1545
1546 # gnutls
1547 gnutls=0
1548 gnutls_dane=0
1549 AC_MSG_CHECKING(for gnutls)
1550 AC_ARG_WITH(gnutls,
1551             [  --with-gnutls=PFX   base of gnutls installation],
1552             [AC_MSG_RESULT([$with_gnutls])
1553              AS_CASE([$with_gnutls],
1554                      [no],[],
1555                      [yes],
1556                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1557                                        AC_CHECK_LIB([gnutls],
1558                                                     [gnutls_priority_set],
1559                                                     gnutls=true))
1560                       AC_CHECK_HEADERS([gnutls/dane.h],
1561                                        AC_CHECK_LIB([gnutls-dane],
1562                                                     [dane_verify_crt_raw],
1563                                                     gnutls_dane=1))],
1564
1565         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1566         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1567         AC_CHECK_HEADERS([gnutls/abstract.h],
1568             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1569               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1570               gnutls=true))
1571         AC_CHECK_HEADERS([gnutls/dane.h],
1572             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1573               gnutls_dane=1))
1574       ])
1575    ],
1576    [AC_MSG_RESULT([--with-gnutls not specified])
1577     AC_CHECK_HEADERS([gnutls/abstract.h],
1578         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1579           gnutls=true))
1580     AC_CHECK_HEADERS([gnutls/dane.h],
1581         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1582                      gnutls_dane=1))
1583    ])
1584 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1585 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1586 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1587 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1588
1589
1590
1591 # Test if we are building for superMUC
1592 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1593 AC_ARG_ENABLE([supermuc],
1594     [AS_HELP_STRING([--enable-supermuc],
1595        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1596     [AS_IF([test "x$enable_supermuc" = "xno"],
1597       [supermuc=0],
1598       [supermuc=1])],
1599     [supermuc=0
1600      enable_supermuc=no])
1601 AC_MSG_RESULT($enable_SUPERMUC)
1602 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1603 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1604
1605 # Check if NSE has to send timestamp information to testbed logger for
1606 # generating histogram of messages received
1607 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1608 AC_ARG_ENABLE([nse-histogram],
1609     [AS_HELP_STRING([--enable-nse-histogram],
1610        [have NSE send timestamp information to testbed logger for generating
1611        histogram of received messages.  NOT useful for production (default is
1612        NO)])],
1613     [AS_IF([test "x$enableval" = "xno"],
1614       [nse_histogram=0],
1615       [nse_histogram=1])],
1616     [nse_histogram=0
1617      enable_nse_histogram=no])
1618 AC_MSG_RESULT($enable_nse_histogram)
1619 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1620 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1621                    [have NSE send timestamp information to testbed logger])
1622
1623 # should 'make check' run tests?
1624 AC_MSG_CHECKING(whether to run tests)
1625 AC_ARG_ENABLE([testruns],
1626    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1627    [enable_tests_run=${enableval}],
1628    [enable_tests_run=yes])
1629 AC_MSG_RESULT($enable_test_run)
1630 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1631
1632
1633 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1634 AC_ARG_ENABLE([benchmark],
1635    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1636    [enable_benchmark=${enableval}],
1637    [enable_benchmark=no])
1638 AC_MSG_RESULT($enable_benchmark)
1639 AS_IF([test "x$enable_benchmark" = "xyes"],
1640       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1641 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1642
1643
1644 # should expensive tests be run?
1645 AC_MSG_CHECKING(whether to run expensive tests)
1646 AC_ARG_ENABLE([expensivetests],
1647    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1648    [enable_expensive=${enableval}],
1649    [enable_expensive=no])
1650 AC_MSG_RESULT($enable_expensive)
1651 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1652
1653 # should ports be open for Java services?
1654 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1655 AC_ARG_ENABLE([javaports],
1656    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1657    [enable_java_ports=${enableval}],
1658    [enable_java_ports=no])
1659 AC_MSG_RESULT($enable_java_ports)
1660 AS_IF([test "x$enable_java_ports" = "xyes"],
1661  [JAVAPORT=""],
1662  [JAVAPORT="$UNIXONLY"])
1663 AC_SUBST(JAVAPORT)
1664
1665 # should benchmarks be run?
1666 AC_MSG_CHECKING(whether to run benchmarks during make check)
1667 AC_ARG_ENABLE([benchmarks],
1668    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1669    [enable_benchmarks=${enableval}],
1670    [enable_benchmarks=no])
1671 AC_MSG_RESULT($enable_benchmarks)
1672 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1673
1674 # should gnunet-testing be compiled
1675 AC_MSG_CHECKING(wether to compile gnunet-testing)
1676 AC_ARG_ENABLE([testing],
1677    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1678    [enable_testing=${enableval}],
1679    [enable_testing=yes])
1680 AC_MSG_RESULT($enable_testing)
1681 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1682
1683 # should experimental code be compiled (code that may not yet compile)?
1684 AC_MSG_CHECKING(whether to compile experimental code)
1685 AC_ARG_ENABLE([experimental],
1686    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1687    [enable_experimental=${enableval}],
1688    [enable_experimental=no])
1689 AC_MSG_RESULT($enable_experimental)
1690 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1691
1692 # should malicious code be compiled (should only be used for testing)?
1693 AC_MSG_CHECKING(whether to compile malicious code)
1694 AC_ARG_ENABLE([malicious],
1695    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1696    [AS_IF([test "x$enableval" = "xno"],
1697      [malicious=0],
1698      [malicious=1])],
1699    [malicious=0
1700     enable_malicious=no])
1701 AC_MSG_RESULT($enable_malicious)
1702 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1703 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1704                    [enable compilation of malicious code])
1705
1706 # should services be started on demand when needed?
1707 # Some services may choose to never start by default
1708 # and it is up to the service/module developer to decide
1709 # by having "START_ON_DEMAND = NO" instead of
1710 # "START_ON_DEMAND = @START_ON_DEMAND@"
1711 # in the service/module's conf.in file.
1712 # See also IMMEDIATE_START for an unconditional immediate start.
1713 START_ON_DEMAND="YES"
1714 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1715 AC_ARG_ENABLE([autostart],
1716    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1717    [enable_autostart=${enableval}
1718     AS_IF([test "x$enable_autostart" = "xno"],
1719       [START_ON_DEMAND="NO"])
1720    ],
1721    [enable_autostart=yes])
1722 AC_MSG_RESULT($enable_autostart)
1723 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1724 AC_SUBST(START_ON_DEMAND)
1725
1726 # should memory statistics be kept (very expensive CPU-wise!)
1727 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1728 AC_ARG_ENABLE([heapstats],
1729    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1730    [enable_heapstats=1],
1731    [enable_heapstats=0])
1732 AC_MSG_RESULT($enable_heapstats)
1733 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1734
1735
1736 # Check if the __thread storage class for
1737 # thread-local storage is available.
1738 AC_MSG_CHECKING(whether __thread is supported)
1739 AC_LINK_IFELSE(
1740 [AC_LANG_PROGRAM([#include <stdlib.h>
1741                    #undef __thread
1742                    static __thread int a = 1;],
1743                   [exit(a-1);])],
1744  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1745 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1746 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1747       [AC_MSG_RESULT(yes)],
1748       [AC_MSG_RESULT(no)])
1749
1750 # gcov compilation
1751 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1752 AC_ARG_ENABLE([coverage],
1753               AS_HELP_STRING([--enable-coverage],
1754                              [compile the library with code coverage support]),
1755               [use_gcov=${enableval}],
1756               [use_gcov=no])
1757 AC_MSG_RESULT($use_gcov)
1758 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1759
1760
1761 # version info
1762 # TODO: git blame says this predates our switch to git.
1763 # git-svn should be adjusted to simply git, or
1764 # an external script that does the job.
1765 AC_PATH_PROG(svnversioncommand, svnversion)
1766 AC_PATH_PROG(gitcommand, git)
1767 AC_MSG_CHECKING(for source being under a VCS)
1768
1769
1770 # version info
1771 AC_PATH_PROG(gitcommand, git)
1772 AC_MSG_CHECKING(for source being under a VCS)
1773 git_version=
1774 AS_IF([test ! "X$gitcommand" = "X"],
1775 [
1776   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1777 ])
1778 AS_IF([test "X$git_version" = "X"],
1779   [
1780     vcs_name="no"
1781     vcs_version="\"release\""
1782   ],
1783   [
1784     vcs_name="yes, git-svn"
1785     vcs_version="\"git-$git_version\""
1786   ])
1787 AC_MSG_RESULT($vcs_name)
1788
1789 AC_MSG_CHECKING(VCS version)
1790 AC_MSG_RESULT($vcs_version)
1791 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1792
1793 AC_CONFIG_FILES([
1794 Makefile
1795 contrib/Makefile
1796 contrib/hellos/Makefile
1797 contrib/services/Makefile
1798 contrib/services/openrc/Makefile
1799 contrib/services/systemd/Makefile
1800 contrib/scripts/Makefile
1801 contrib/scripts/gnunet-logread/Makefile
1802 doc/Makefile
1803 doc/man/Makefile
1804 doc/doxygen/Makefile
1805 doc/handbook/Makefile
1806 doc/tutorial/Makefile
1807 m4/Makefile
1808 po/Makefile.in
1809 src/Makefile
1810 src/arm/Makefile
1811 src/arm/arm.conf
1812 src/ats/Makefile
1813 src/ats/ats.conf
1814 src/ats-tool/Makefile
1815 src/ats-tests/Makefile
1816 src/auction/Makefile
1817 src/block/Makefile
1818 src/cadet/Makefile
1819 src/cadet/cadet.conf
1820 src/core/Makefile
1821 src/core/core.conf
1822 src/consensus/Makefile
1823 src/consensus/consensus.conf
1824 src/conversation/Makefile
1825 src/conversation/conversation.conf
1826 src/curl/Makefile
1827 src/datacache/Makefile
1828 src/datastore/Makefile
1829 src/datastore/datastore.conf
1830 src/dht/Makefile
1831 src/dht/dht.conf
1832 src/dns/Makefile
1833 src/dns/dns.conf
1834 src/exit/Makefile
1835 src/fragmentation/Makefile
1836 src/fs/Makefile
1837 src/fs/fs.conf
1838 src/gns/Makefile
1839 src/gns/gns.conf
1840 src/gns/nss/Makefile
1841 src/gnsrecord/Makefile
1842 src/hello/Makefile
1843 src/identity/Makefile
1844 src/identity/identity.conf
1845 src/abd/Makefile
1846 src/abd/abd.conf
1847 src/include/Makefile
1848 src/integration-tests/Makefile
1849 src/json/Makefile
1850 src/hostlist/Makefile
1851 src/my/Makefile
1852 src/mysql/Makefile
1853 src/namecache/Makefile
1854 src/namecache/namecache.conf
1855 src/namestore/Makefile
1856 src/namestore/namestore.conf
1857 src/nat/Makefile
1858 src/nat/nat.conf
1859 src/nat-auto/Makefile
1860 src/nat-auto/nat-auto.conf
1861 src/nse/Makefile
1862 src/nse/nse.conf
1863 src/nt/Makefile
1864 src/peerinfo/Makefile
1865 src/peerinfo/peerinfo.conf
1866 src/peerinfo-tool/Makefile
1867 src/peerstore/Makefile
1868 src/peerstore/peerstore.conf
1869 src/pq/Makefile
1870 src/pt/Makefile
1871 src/regex/Makefile
1872 src/regex/regex.conf
1873 src/revocation/Makefile
1874 src/revocation/revocation.conf
1875 src/rps/Makefile
1876 src/rps/rps.conf
1877 src/secretsharing/Makefile
1878 src/secretsharing/secretsharing.conf
1879 src/scalarproduct/Makefile
1880 src/scalarproduct/scalarproduct.conf
1881 src/set/Makefile
1882 src/set/set.conf
1883 src/sq/Makefile
1884 src/statistics/Makefile
1885 src/statistics/statistics.conf
1886 src/template/Makefile
1887 src/testbed/Makefile
1888 src/testbed/testbed.conf
1889 src/testbed-logger/Makefile
1890 src/testbed-logger/testbed-logger.conf
1891 src/testing/Makefile
1892 src/topology/Makefile
1893 src/transport/Makefile
1894 src/transport/transport.conf
1895 src/util/Makefile
1896 src/util/resolver.conf
1897 src/vpn/Makefile
1898 src/vpn/vpn.conf
1899 src/zonemaster/Makefile
1900 src/zonemaster/zonemaster.conf
1901 src/rest/Makefile
1902 src/abe/Makefile
1903 src/reclaim-attribute/Makefile
1904 src/reclaim/Makefile
1905 pkgconfig/Makefile
1906 pkgconfig/gnunetarm.pc
1907 pkgconfig/gnunetats.pc
1908 pkgconfig/gnunetblock.pc
1909 pkgconfig/gnunetcadet.pc
1910 pkgconfig/gnunetconsensus.pc
1911 pkgconfig/gnunetconversation.pc
1912 pkgconfig/gnunetcore.pc
1913 pkgconfig/gnunetdatacache.pc
1914 pkgconfig/gnunetdatastore.pc
1915 pkgconfig/gnunetdht.pc
1916 pkgconfig/gnunetdns.pc
1917 pkgconfig/gnunetenv.pc
1918 pkgconfig/gnunetfragmentation.pc
1919 pkgconfig/gnunetfs.pc
1920 pkgconfig/gnunetgns.pc
1921 pkgconfig/gnunethello.pc
1922 pkgconfig/gnunetidentity.pc
1923 pkgconfig/gnunetmicrophone.pc
1924 pkgconfig/gnunetmysql.pc
1925 pkgconfig/gnunetnamestore.pc
1926 pkgconfig/gnunetnat.pc
1927 pkgconfig/gnunetnse.pc
1928 pkgconfig/gnunetpeerinfo.pc
1929 pkgconfig/gnunetpq.pc
1930 pkgconfig/gnunetregex.pc
1931 pkgconfig/gnunetrevocation.pc
1932 pkgconfig/gnunetrps.pc
1933 pkgconfig/gnunetscalarproduct.pc
1934 pkgconfig/gnunetset.pc
1935 pkgconfig/gnunetspeaker.pc
1936 pkgconfig/gnunetstatistics.pc
1937 pkgconfig/gnunettestbed.pc
1938 pkgconfig/gnunettesting.pc
1939 pkgconfig/gnunettransport.pc
1940 pkgconfig/gnunetutil.pc
1941 pkgconfig/gnunetvpn.pc
1942 ])
1943 AC_OUTPUT
1944
1945
1946 # FIXME: `some modules' -> be more specific which exact modules.
1947
1948 # java ports
1949 AS_IF([test "x$enable_java_ports" = "xyes"],
1950       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1951
1952 ####
1953 #### Lasciate ogne speranza, voi ch'intrate
1954 ####
1955 #### This could be moved to the checks above,
1956 #### but for now let's keep it here.
1957 ####
1958
1959 # TODO: We use "WARNING" too often, we need to clarify what
1960 # TODO: constitutes a WARNING, an ERROR, and a NOTICE, and
1961 # TODO: other message levels.
1962
1963 # -- print message regarding enabled experimental features
1964 AS_IF([test "x$enable_experimental" = "xyes"],
1965       [experimental_msg="experimental features enabled"])
1966 # -- OSX Framework
1967 AS_IF([test "$enable_framework_build" = "yes"],
1968       [macosx_framework_msg="yes"],
1969       [macosx_framework_msg="no"])
1970 # -- libidn 2
1971 AS_IF([test "x$working_libidn2" = x1],
1972       [libidn2_msg="libidn2"])
1973 # -- libidn 1
1974 AS_IF([test "x$working_libidn1" = x1],
1975       [libidn1_msg="libidn1"])
1976 # -- texi2mdoc-generation
1977 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
1978       [mdocml_msg="yes"],
1979       [mdocml_msg="no"])
1980 # -- texi2mdoc
1981 AS_IF([test "x$TEXI2MDOC_BINARY" = "false"],
1982       [AC_MSG_NOTICE([WARNING: optional texi2mdoc binary not found])
1983        texi2mdoc_msg="no (optional)"],
1984       [texi2mdoc_msg="yes"])
1985 # -- mandoc
1986 AS_IF([test "x$MANDOC_BINARY" = "false"],
1987       [AC_MSG_NOTICE([WARNING: optional mandoc binary not found])
1988        mandoc_msg="no"],
1989       [mandoc_msg="yes"])
1990 # -- texinfo
1991 AS_IF([test "x$makeinfo" != "x1"],
1992       [texinfo_msg="no"],
1993       [texinfo_msg="yes"])
1994 # -- conversation
1995 AS_IF([test "x$conversation_backend" = "xnone"],
1996       [AS_IF([test "x$pulse" != "x1"],
1997              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found (required to build conversation against it).])
1998               libpulse_msg="no"],
1999              [libpulse_msg="yes"])
2000        AS_IF([test "x$opus" != "x1"],
2001              [AC_MSG_NOTICE([WARNING: libopus not found (conversation)])
2002               libopus_msg="no"],
2003              [libopus_msg="yes"])
2004        AS_IF([test "x$gst" != "x1"],
2005              [AC_MSG_NOTICE([WARNING: GStreamer not found (required to build conversation against it).])
2006               gstreamer_msg="no"],
2007              [gstreamer_msg="yes"])],
2008       [features_msg="$features_msg conversation"])
2009 # -- interface
2010 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2011 # -- libmicrohttpd
2012 AS_IF([test "x$lmhd" != "x1"],
2013       [libmicrohttpd_msg="no (optional)"],
2014       [libmicrohttpd_msg="yes"])
2015 # -- jansson
2016 AS_IF([test "x$jansson" = "x0"],
2017       [jansson_msg="no (optional)"],
2018       [jansson_msg="yes"])
2019 # -- libextractor
2020 AS_IF([test "$extractor" != 1],
2021       [AC_MSG_WARN([WARNING: libextractor not found, but various file-sharing functions require it])],
2022       [libextractor_msg="yes"])
2023 # -- libzbar
2024 AS_IF([test "x$zbar" = "x1"],
2025       [libzbar_msg="yes"
2026        features_msg="$features_msg gnunet-qr"],
2027       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
2028        libzbar_msg="no"])
2029 # -- libgnurl
2030 AS_IF([test "$gnurl" = "0"],
2031       [AS_IF([test "x$curl" = "xfalse"],
2032              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
2033               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2034               curl_msg="no"],
2035              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
2036               curl_msg="yes"])],
2037        [gnurl_msg="yes"])
2038 # -- ifconfig
2039 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2040       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
2041        ifconfig_msg="no (optional)"],
2042       [ifconfig_msg="yes"])
2043 # -- upnpc
2044 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2045       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
2046        upnpc_msg="no (optional)"],
2047       [upnpc_msg="yes"])
2048 # -- iptables
2049 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2050       [AC_MSG_NOTICE([WARNING: optional iptables not found])
2051        iptables_msg="no (optional)"],
2052       [iptables_msg="yes"])
2053 # -- bluetooth
2054 AS_IF([test "x$bluetooth" = "x0"],
2055       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
2056        bluetooth_msg="no (optional)"],
2057       [bluetooth_msg="yes"])
2058 # -- gnutls
2059 AS_IF([test x$gnutls != xtrue],
2060       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
2061        gnutls_msg="no"],
2062       [AS_IF([test "x$gnutls_dane" != "x1"],
2063              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
2064               gnutls_msg="yes (without DANE support)"],
2065              [gnutls_msg="yes (with DANE support)"])])
2066 # -- databases
2067 # TODO: this always returns true, the check might
2068 # TODO: not be working as intended (for msqlfail).
2069 AS_IF([test x$mysqlfail = "true"]
2070       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
2071 AS_IF([test "$mysql" = true],
2072       [features_msg="$features_msg mysql"
2073        mysql_msg="yes"],
2074       [mysql_msg="no"])
2075 AS_IF([test "$sqlite" = true],
2076       [features_msg="$features_msg sqlite"
2077        sqlite_msg="yes"],
2078       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
2079        sqlite_msg="no"])
2080 AS_IF([test "$postgres" = true],
2081       [features_msg="$features_msg postgres"
2082        postgres_msg="yes"],
2083       [postgres_msg="no"])
2084 # -- features
2085 # ---- 1. replace spaces with newlines,
2086 # ---- 2. sort the lines,
2087 # ---- 3. replace the newlines with spaces.
2088 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2089 AC_SUBST(features_msg)
2090
2091
2092 # The summary
2093 # TODO: reduce the length of the last message block, following "IMPORTANT".
2094
2095 AC_MSG_NOTICE([
2096 GNUnet Configuration
2097
2098 gnunet version:                 ${VERSION}
2099
2100 Host setup:                     ${host}
2101 Install prefix:                 ${prefix}
2102 Compiler:                       ${CC}
2103 CFLAGS:                         ${CFLAGS}
2104 CPPFLAGS:                       ${CPPFLAGS}
2105 LDFLAGS:                        ${LDFLAGS}
2106 LIBS:                           ${LIBS}
2107 Build Target:                   $build_target
2108 Mac OSX framework build:        ${macosx_framework_msg}
2109
2110 Default Interface:              ${interface_msg}
2111
2112 MySQL:                          ${mysql_msg}
2113 PostgreSQL:                     ${postgres_msg}
2114 sqlite3:                        ${sqlite_msg}
2115 gnurl:                          ${gnurl_msg}
2116 curl:                           ${curl_msg}
2117 bluetooth:                      ${bluetooth_msg}
2118 jansson:                        ${jansson_msg}
2119 iptables:                       ${iptables_msg}
2120 ifconfig:                       ${ifconfig_msg}
2121 upnpc:                          ${upnpc_msg}
2122 gnutls:                         ${gnutls_msg}
2123 libzbar:                        ${libzbar_msg}
2124 java:                           ${java_msg}
2125 libmicrohttpd:                  ${libmicrohttpd_msg}
2126 libidn:                         ${libidn1_msg}${libidn2_msg}
2127 libopus:                        ${libopus_msg}
2128 gstreamer:                      ${gstreamer_msg}
2129 libpulse:                       ${libpulse_msg}
2130 libextractor:                   ${libextractor_msg}
2131 texi2mdoc:                      ${texi2mdoc_msg}
2132 mandoc:                         ${mandoc_msg}
2133
2134 texinfo manual:                 ${texinfo_msg}
2135 transpiled mdocml manual:       ${mdocml_msg}
2136
2137 features:                       ${features_msg}
2138 experimental:                   ${experimental_msg}
2139
2140
2141 IMPORTANT:
2142
2143 Please make sure NOW that you have created a user and group 'gnunet'
2144 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
2145 type:
2146
2147   addgroup gnunetdns
2148   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
2149
2150 Make sure that '/var/lib/gnunet' is owned (and writable) by user
2151 'gnunet'.  Then, you can compile GNUnet with
2152
2153   make
2154
2155 After that, run (if necessary as 'root')
2156
2157   make install
2158
2159 to install everything.
2160
2161 Each GNUnet user should be added to the 'gnunet' group (may
2162 require fresh login to come into effect):
2163
2164   adduser USERNAME gnunet
2165
2166 (run the above command as root once for each of your users, replacing
2167 "USERNAME" with the respective login names).  If you have a global IP
2168 address, no further configuration is required.
2169
2170 For more detailed setup instructions, see https://docs.gnunet.org/
2171
2172 Optionally, download and compile gnunet-gtk to get a GUI for
2173 file-sharing and configuration.  This is particularly recommended
2174 if your network setup is non-trivial, as gnunet-setup can be
2175 used to test in the GUI if your network configuration is working.
2176 gnunet-setup should be run as the "gnunet" user under X.  As it
2177 does very little with the network, running it as "root" is likely
2178 also harmless.  You can also run it as a normal user, but then
2179 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2180 home directory in the end.
2181
2182 Once you have configured your peer, run (as the 'gnunet' user)
2183
2184   gnunet-arm -s
2185
2186 to start the peer.  You can then run the various GNUnet-tools as
2187 your "normal" user (who should only be in the group 'gnunet').
2188 ])