configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.12.2], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 136      build_target="freebsd"
 137      LIBPREFIX=
 138      DLLDIR=lib
 139      UNIXONLY="#"
 140   ],
 141   [*openbsd*],[
 142      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 143      build_target="openbsd"
 144      use_openbsd_libtool=true
 145      LIBPREFIX=
 146      DLLDIR=lib
 147      UNIXONLY="#"
 148   ],
 149   [*netbsd*],[
 150      build_target="netbsd"
 151      LIBPREFIX=
 152      DLLDIR=lib
 153      UNIXONLY="#"
 154   ],
 155   [*solaris*],[
 156      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 157      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 158      AC_CHECK_LIB(resolv, res_init)
 159      AC_CHECK_LIB(rt, nanosleep)
 160      build_target="solaris"
 161      LIBPREFIX=
 162      DLLDIR=lib
 163      UNIXONLY="#"
 164   ],
 165   [*arm-linux*],[
 166      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 167      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 168      build_target="linux"
 169      LIBPREFIX=
 170      DLLDIR=lib
 171      UNIXONLY="#"
 172   ],
 173   [gnu*],[
 174      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 175      build_target="gnu"
 176      UNIXONLY="#"
 177   ],
 178   [
 179      AC_MSG_RESULT(Unrecognised OS $host_os)
 180      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 181      UNIXONLY=""
 182 ])
 183 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 184 AC_SUBST(DEFAULT_INTERFACE)
 185
 186 # Disable TCP-based IPC on systems that support UNIX domain
 187 # sockets in default configuratin:
 188 AC_SUBST(UNIXONLY)
 189
 190
 191 AC_MSG_CHECKING([for build target])
 192 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 193 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 194 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 195 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 196 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 197 # FIXME: We need a define BSD for some binaries like we
 198 # need define LINUX for some. This does not scale, how
 199 # can we solve this better?
 200 AM_CONDITIONAL(XBSD, test "$build_target" = "netbsd" -o "$build_target" = "freebsd" -o "$build_target" = "openbsd")
 201 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 202 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 203
 204 AC_MSG_RESULT([$build_target])
 205 AC_SUBST(build_target)
 206 AM_CONDITIONAL([am__fastdepOBJC], false)
 207 AC_UNALIGNED_64_ACCESS
 208
 209 # some other checks for standard libs
 210 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 211 AC_SEARCH_LIBS([memrchr], [],
 212                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 213 AC_SEARCH_LIBS([memset_s], [],
 214                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 215 AC_SEARCH_LIBS([explicit_bzero], [],
 216                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 217 AC_CHECK_LIB(socket, socket)
 218 AC_CHECK_LIB(m, log)
 219 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 220
 221 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 222 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 223
 224 AC_CHECK_PROGS(PKG_CONFIG, [pkgconf, pkg-config], false)
 225 AM_CONDITIONAL(HAVE_PKG_CONFIG, test x$PKG_CONFIG != xfalse)
 226
 227 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 228 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 229 AC_MSG_CHECKING(for SSH key)
 230   AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 231   if test -f /tmp/gnunet_test_cosks_ssh_garbage; then
 232      rm -f /tmp/gnunet_test_cosks_ssh_garbage
 233   fi
 234
 235
 236 # autotools' m4 for python has no maximum version!
 237 # python3.4 - python3.8 for tests (3.8 unchecked)
 238 # TODO: document how to override the lowest version
 239 # TODO: found by this.
 240 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 241 AM_PATH_PYTHON([3.4],, [:])
 242 AC_SUBST([PYTHON])
 243 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 244
 245
 246 # perl
 247 AC_PATH_PROG( PERL, perl, ,
 248               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 249 AC_SUBST([PERL])
 250 AM_CONDITIONAL([HAVE_PERL], [test -x "$PERL"])
 251 AS_IF([test -x "$PERL"],
 252   [AC_DEFINE_UNQUOTED([HAVE_PERL], [1], [Path to Perl])],
 253   [AC_DEFINE_UNQUOTED([HAVE_PERL], [0], [Path to Perl])])
 254
 255 # awk
 256 AC_PATH_PROGS( AWK_BINARY, [awk gawk], ,$PATH:/usr/bin/:/usr/local/bin )
 257 AC_SUBST([AWK_BINARY])
 258 AM_CONDITIONAL([HAVE_AWK], [test -x "$AWK_BINARY"])
 259 AS_IF([test -x "$AWK_BINARY"],
 260   [AC_DEFINE_UNQUOTED([HAVE_AWK], [1], [Path to awk])],
 261   [AC_DEFINE_UNQUOTED([HAVE_AWK], [0], [Path to awk])])
 262
 263 # should we install gnunet-logread?
 264 AC_MSG_CHECKING(whether to install gnunet-logread)
 265 AC_ARG_WITH([gnunet-logread],
 266               [AS_HELP_STRING([--with-gnunet-logread],
 267                               [Install gnunet-logread])],
 268               [logread=${withval}],
 269               [logread=no])
 270 AC_MSG_RESULT($logread)
 271 AS_IF([test "x$logread" = "xyes"],
 272       [AM_CONDITIONAL([GNUNET_LOGREAD], true)
 273        AC_DEFINE([GNUNET_LOGREAD],
 274                  [1],
 275                  [Installing gnunet-logread])],
 276       [AM_CONDITIONAL([GNUNET_LOGREAD],
 277                       false)
 278        AC_DEFINE([GNUNET_LOGREAD],
 279                  [0],
 280                  [Not installing gnunet-logread])])
 281
 282 # iptables is a soft requirement to run tests
 283 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 284
 285 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 286  [AS_IF([test -x "/sbin/iptables"],
 287    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 288    [AS_IF([test -x "/usr/sbin/iptables"],
 289       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 290
 291 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 292  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 293  [AC_MSG_WARN([warning: 'iptables' not found.])])
 294
 295 # ip6tables is a soft requirement for some features
 296 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 297
 298 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 299   [AS_IF([test -x "/sbin/ip6tables"],
 300      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 301      [AS_IF([test -x "/usr/sbin/ip6tables"],
 302         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 303
 304
 305 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 306   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 307   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 308
 309 # ip is a soft requirement for some features
 310 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 311
 312 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 313  [AS_IF([test -x "/sbin/ip"],
 314    [VAR_IP_BINARY="/sbin/ip"],
 315    [AS_IF([test -x "/usr/sbin/ip"],
 316           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 317
 318 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 319  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 320  [AC_MSG_WARN([warning: 'ip' not found.])])
 321
 322 # locate 'ifconfig'
 323 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 324
 325 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 326 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 327   [AS_IF([test -x "/sbin/ifconfig"],
 328      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 329      [AS_IF([test -x "/usr/sbin/ifconfig"],
 330             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 331
 332 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 333   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 334   [AC_MSG_WARN(['ifconfig' not found.])])
 335
 336
 337 # Test if 'adduser' binary exists
 338 MSG_USER_SETUP=true
 339 AC_PATH_PROG([MSG_USER_SETUP],
 340   [adduser],
 341   false,
 342   [path=$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 343
 344 # Test if 'gnunet' user and the groups exist
 345 getent passwd gnunet > /dev/null
 346 HAVE_GNUNET_USER=$?
 347 getent group gnunet > /dev/null
 348 AS_IF([test x$? != x0],
 349       [HAVE_GNUNET_USER=1])
 350 getent group gnunetdns > /dev/null
 351 AS_IF([test x$? != x0],
 352       [HAVE_GNUNET_USER=1])
 353
 354 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 355
 356 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 357 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 358       [AS_IF([test -x "/sbin/sysctl"],
 359              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 360              [AS_IF([test -x "/usr/sbin/sysctl"],
 361                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 362 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 363       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 364       [AC_MSG_WARN(['sysctl' not found.])])
 365
 366 # miniupnpc / upnpc binary is a soft runtime requirement
 367 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 368
 369 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 370   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 371   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 372
 373
 374 # checkbashisms
 375 AC_CHECK_PROGS(CHECKBASHISMS_BINARY, [checkbashisms checkbashisms.pl], false)
 376 AM_CONDITIONAL(HAVE_CHECKBASHISMS, test x$CHECKBASHISMS_BINARY != xfalse)
 377
 378 # uncrustify
 379 # TODO: maybe add flag to pass location
 380 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 381 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 382
 383 # yapf
 384 # TODO: less repetition, add flag to pass name
 385 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 386 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 387
 388
 389 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 390   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 391      [Define if struct tm has the tm_gmtoff member.])],
 392      ,
 393      [#include <time.h>])
 394
 395 # 'save' libs; only those libs found so far will be
 396 # linked against _everywhere_.  For the others, we
 397 # will be more selective!
 398 SAVE_LIBS=$LIBS
 399
 400 have_addrinfo_a=0
 401 AC_CHECK_LIB(anl,
 402              getaddrinfo_a,
 403              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 404                                           1,
 405                                           [getaddrinfo_a supported])])
 406 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 407                [test "$have_addrinfo_a" = 1])
 408
 409 # libgcrypt
 410 gcrypt=0
 411 NEED_LIBGCRYPT_API=1
 412 NEED_LIBGCRYPT_VERSION=1.6.0
 413
 414
 415 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 416 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 417
 418 AS_IF([test $gcrypt = 0],
 419  [
 420   AC_MSG_ERROR([[
 421 ***
 422 *** You need libgcrypt to build this program.
 423 *** This library is for example available at
 424 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 425 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 426 ***  is required.
 427 ***]])
 428 ])
 429 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 430
 431 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 432
 433 AC_CHECK_HEADER([if_tun.h],
 434     [AC_DEFINE([IF_TUN_HDR], ["if_tun.h"], [if_tun.h include path])],
 435     [AC_CHECK_HEADER([linux/if_tun.h],
 436         [AC_DEFINE([IF_TUN_HDR], ["linux/if_tun.h"])],
 437         [AC_CHECK_HEADER([net/if_tun.h],
 438             [AC_DEFINE([IF_TUN_HDR], ["net/if_tun.h"])],
 439             [AC_CHECK_HEADER([net/tun/if_tun.h],
 440                 [AC_DEFINE([IF_TUN_HDR], ["net/tun/if_tun.h"])])])])])
 441
 442
 443 # should the build process be building the documentation?
 444 AC_MSG_CHECKING(whether to build documentation)
 445 AC_ARG_ENABLE([documentation],
 446               [AS_HELP_STRING([--disable-documentation],
 447                               [do not build the documentation])],
 448               [documentation=${enableval}],
 449               [documentation=yes])
 450 AC_MSG_RESULT($documentation)
 451 AS_IF([test "x$documentation" = "xyes"],
 452       [AM_CONDITIONAL([DOCUMENTATION],
 453                       true)
 454        AC_DEFINE([DOCUMENTATION],
 455                  [1],
 456                  [Building the documentation])],
 457       [AM_CONDITIONAL([DOCUMENTATION],
 458                       false)
 459        AC_DEFINE([DOCUMENTATION],
 460                  [0],
 461                  [Not building the documentation])])
 462
 463 # COMMENT: Check whether to transpile texinfo to mdoc.
 464 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 465 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 466 # COMMENT: and makes the configure fail if it is missing.
 467 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 468 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 469 # COMMENT: or nothing was set (this is the default).
 470 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 471 # COMMENT: potential non-existence of the texi2mdoc binary.
 472 # COMMENT: Default return value / setting: no
 473 AC_MSG_CHECKING(whether to include generated texi2mdoc output in installation)
 474 AC_ARG_ENABLE([texi2mdoc-generation],
 475               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 476                               [include generated texi2mdoc output in installation])],
 477               [texi2mdoc_generation=${enableval}],
 478               [texi2mdoc_generation=no])
 479 AC_MSG_RESULT($texi2mdoc_generation)
 480 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 481       [AS_IF([test "$texi2mdoc" = 0],
 482              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 483               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 484               AC_MSG_WARN([ERROR: Operating System package manager or from])
 485               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 486              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 487               AC_DEFINE([TEXI2MDOC_GENERATION],
 488                         [1],
 489                         [Building section 7 mdoc output])])],
 490       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 491                       false)
 492        AC_DEFINE([TEXI2MDOC_GENERATION],
 493                  [0],
 494                  [Not building section 7 mdoc output])])
 495
 496 # test for texi2mdoc (the binary, not the script distributed
 497 # with autogen)
 498 # TODO: refactor this and the check above.
 499 AC_MSG_CHECKING(for texi2mdoc binary)
 500 AC_CHECK_PROGS(TEXI2MDOC_BINARY, [texi2mdoc], false)
 501 AM_CONDITIONAL(HAVE_TEXI2MDOC, test x$TEXI2MDOC_BINARY != xfalse)
 502
 503 # texi2man is a tool which needs to be investigated and
 504 # is probably incompatible to texi2mdoc in invocation.
 505 # Detection at this point only serves as a reminder that
 506 # I will work this into the build-system.
 507 AC_MSG_CHECKING(for texi2man perl script)
 508 AC_CHECK_PROGS(TEXI2MAN_SCRIPT, [texi2man], false)
 509 AM_CONDITIONAL(HAVE_TEXI2MAN, test x$TEXI2MAN_SCRIPT != xfalse)
 510
 511
 512 # test for mandoc
 513 AC_MSG_CHECKING(for mandoc binary)
 514 AC_CHECK_PROGS(MANDOC_BINARY, [mandoc], false)
 515 AM_CONDITIONAL(HAVE_MANDOC, test x$MANDOC_BINARY != xfalse)
 516
 517 # should the build process be building only the documentation?
 518 AC_MSG_CHECKING(whether to build only documentation)
 519 AC_ARG_ENABLE([documentation-only],
 520    [AS_HELP_STRING([--enable-documentation-only],
 521                    [build only the documentation])],
 522    [documentation_only=${enableval}],
 523    [documentation_only=no])
 524 AC_MSG_RESULT($documentation_only)
 525 AS_IF([test "x$documentation_only" = "xyes"],
 526  [
 527   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 528   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 529  ],[
 530   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 531   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 532  ])
 533
 534 # should the build process be including the manpages? (default: yes)
 535 AC_MSG_CHECKING(whether to include man pages)
 536 AC_ARG_ENABLE([include-manpages],
 537    [AS_HELP_STRING([--disable-include-manpages],
 538                    [Do not include the man pages in build and installation])],
 539    [include_manpages=${enableval}],
 540    [include_manpages=yes])
 541 AC_MSG_RESULT($include_manpages)
 542 AS_IF([test "x$include_manpages" = "xyes"],
 543  [
 544   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 545   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 546  ],[
 547   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 548   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 549  ])
 550
 551 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 552 # (not syntax!) to the commandline tools which generate the html. If not,
 553 # texinfo5 switches are used. This comes with no version checks, is
 554 # enabled only at distributors action (ie defaults to "no").
 555 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 556 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 557 AC_ARG_ENABLE([texinfo4],
 558    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 559    [activate_texinfo4=${enableval}],
 560    [activate_texinfo4=no])
 561 AC_MSG_RESULT($activate_texinfo4)
 562 AS_IF([test "x$activate_texinfo4" = "xyes"],
 563  [
 564   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 565   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 566  ],[
 567   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 568   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 569  ])
 570
 571
 572 # Adam shostack suggests the following for Windows:
 573 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 574 AC_ARG_ENABLE([gcc-hardening],
 575    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 576 [AS_IF([test x$enableval = xyes],[
 577     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 578     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 579     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 580     LDFLAGS="$LDFLAGS -pie"
 581  ])])
 582
 583 # Linker hardening options
 584 # Currently these options are ELF specific - you can't use this with MacOSX
 585 AC_ARG_ENABLE([linker-hardening],
 586   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 587 [AS_IF([test x$enableval = xyes],
 588    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 589
 590
 591 AC_ARG_ENABLE([sanitizer],
 592   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 593 [AS_IF([test x$enableval = xyes],[
 594    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 595  ])])
 596
 597
 598 extra_logging=GNUNET_NO
 599 AC_ARG_ENABLE([logging],
 600    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 601    [AS_IF([test "x$enableval" = "xyes"], [],
 602           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 603           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 604           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 605    ], [])
 606 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 607
 608 # should memory poisoning be enabled?
 609 AC_MSG_CHECKING(whether to poison freed memory)
 610 AC_ARG_ENABLE([poisoning],
 611    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 612    [enable_poisoning=${enableval}],
 613    [
 614      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 615        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 616        [enable_poisoning=no])
 617    ])
 618 AC_MSG_RESULT($enable_poisoning)
 619 AS_IF([test ! "x$enable_poisoning" = "xno"],
 620   [enable_poisoning=1],
 621   [enable_poisoning=0])
 622 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 623
 624 AS_IF([test $build = $target],
 625 [
 626 AC_MSG_CHECKING([for working HMAC])
 627 AC_LANG_PUSH(C)
 628 LIBS="$LIBS $LIBGCRYPT_LIBS"
 629 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 630 AC_RUN_IFELSE(
 631   [AC_LANG_PROGRAM([#include <gcrypt.h>
 632         #include <stdio.h>], [[
 633         gcry_md_hd_t mac;
 634
 635         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 636             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 637             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 638         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 639         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 640             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 641             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 642             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 643             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 644             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 645
 646         if (!gcry_check_version (GCRYPT_VERSION))
 647         {
 648           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 649           return 1;
 650         }
 651
 652         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 653         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 654
 655         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 656         {
 657           fprintf (stderr, "gcry_md_open error\n");
 658           return 2;
 659         }
 660
 661         gcry_md_setkey (mac, key, sizeof (key));
 662         gcry_md_write (mac, data, sizeof (data));
 663
 664         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 665         {
 666           fprintf (stderr, "memcmp error\n");
 667           return 3;
 668         }
 669
 670         gcry_md_close (mac);
 671
 672         return 0;
 673     ]])],
 674   [AC_MSG_RESULT([yes])],
 675   [
 676    RESULT=$?
 677    if test $RESULT = 3
 678    then
 679      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 680    fi
 681    if test $RESULT = 2
 682    then
 683      AC_MSG_FAILURE([HMAC test failed])
 684    fi
 685    if test $RESULT = 1
 686    then
 687      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 688    fi
 689   ],
 690   [AC_MSG_RESULT([cross compiling, test skipped])])
 691 AC_LANG_POP(C)
 692 ])      # $build = $target
 693
 694 # check for bluetooth library
 695 bluetooth=0
 696 AC_MSG_CHECKING(for libbluetooth)
 697 AC_ARG_WITH(libbluetooth,
 698     [  --with-libbluetooth=PREFIX (base of libbluetooth installation)],
 699     [AC_MSG_RESULT([$with_libbluetooth])
 700      AS_CASE([$with_libbluetooth],
 701         [no],[],
 702         [yes],[
 703             CHECK_LIBHEADER(BLUETOOTH,
 704                             bluetooth,
 705                             ba2str,
 706                             bluetooth/bluetooth.h,
 707                             bluetooth=1,)
 708         ],[
 709             LDFLAGS="-L$with_libbluetooth/lib $LDFLAGS"
 710             CPPFLAGS="-I$with_libbluetooth/include $CPPFLAGS"
 711             AC_CHECK_HEADERS(bluetooth/bluetooth.h,
 712                              AC_CHECK_LIB([bluetooth],
 713                                           [ba2str],
 714                                           EXT_LIB_PATH="-L$with_libbluetooth/lib $EXT_LIB_PATH"
 715                                           bluetooth=1))
 716         ])
 717     ],
 718     [AC_MSG_RESULT([--with-libbluetooth not specified])
 719      CHECK_LIBHEADER(BLUETOOTH,
 720                      bluetooth,
 721                      ba2str,
 722                      bluetooth/bluetooth.h,
 723                      bluetooth=1,)])
 724 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 725 AS_IF([test "$bluetooth" = 1],
 726       [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 727       [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 728
 729 # check for zbar library
 730 # NOTE: Do not add checks for: -lSM, -lICE, -lX11, -lXv and -ljpeg
 731 # NOTE: they must be provided by the build environment, not the
 732 # NOTE: build-system of gnunet, as they are 2nd or 3rd level dependencies.
 733 zbar=0
 734 AC_MSG_CHECKING(for libzbar)
 735 AC_ARG_WITH(zbar,
 736    [  --with-zbar=PREFIX (base of libzbar installation)],
 737    [AC_MSG_RESULT([$with_zbar])
 738     AS_CASE([$with_zbar],
 739       [no],[],
 740       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 741       [
 742         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 743         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 744         AC_CHECK_HEADERS(zbar.h,
 745           AC_CHECK_LIB([zbar], [zbar_processor_create],
 746             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 747             zbar=1))
 748        ])
 749    ],
 750    [AC_MSG_RESULT([--with-zbar not specified])
 751     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 752 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 753 AS_IF([test "x$zbar" = x1],
 754       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 755       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 756
 757 # check for jansson library
 758 jansson=0
 759 AC_MSG_CHECKING(for libjansson)
 760 AC_ARG_WITH(jansson,
 761    [  --with-jansson=PREFIX (base of libjansson installation)],
 762    [AC_MSG_RESULT([$with_jansson])
 763     AS_CASE([$with_jansson],
 764       [no],[],
 765       [yes],[
 766         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 767       ],[
 768         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 769         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 770         AC_CHECK_HEADERS(jansson.h,
 771           AC_CHECK_LIB([jansson], [json_loads],
 772             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 773             jansson=1))
 774       ])
 775    ],
 776    [AC_MSG_RESULT([--with-jansson not specified])
 777     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 778 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 779 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 780 AS_IF([test "x$jansson" = x1],
 781       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 782       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 783
 784
 785 # check for libpulse(audio) library
 786 pulse=0
 787 libpulse_msg="no"
 788 AC_MSG_CHECKING(for libpulse)
 789 # TODO: --with-libpulse or --with-pulseaudio? What is more established
 790 # TODO: in this context?
 791 AC_ARG_WITH(libpulse,
 792     [  --with-libpulse=PREFIX (base of libpulse installation)],
 793     [AC_MSG_RESULT([$with_libpulse])
 794      AS_CASE([$with_libpulse],
 795         [no],[],
 796         [yes],[
 797             CHECK_LIBHEADER(LIBPULSE,
 798                             pulse,
 799                             pa_stream_peek,
 800                             pulse/simple.h,
 801                             pulse=1,)
 802         ],[
 803             LDFLAGS="-L$with_libpulse/lib $LDFLAGS"
 804             CPPFLAGS="-I$with_libpulse/include $CPPFLAGS"
 805             AC_CHECK_HEADERS(pulse/simple.h,
 806                              AC_CHECK_LIB([pulse],
 807                                           [pa_stream_peek],
 808                                           EXT_LIB_PATH="-L$with_libpulse/lib $EXT_LIB_PATH"
 809                                           pulse=1))
 810         ])
 811     ],
 812     [AC_MSG_RESULT([--with-libpulse not specified])
 813      CHECK_LIBHEADER(LIBPULSE,
 814                      pulse,
 815                      pa_stream_peek,
 816                      pulse/simple.h,
 817                      pulse=1,)])
 818 AM_CONDITIONAL(HAVE_PULSE, [test "$pulse" = 1])
 819 AS_IF([test x"$pulse" = x1],
 820       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 821        libpulse_msg="yes"],
 822       [AC_DEFINE([HAVE_PULSE],[0],[Lacking libpulse(audio) library])
 823        libpulse_msg="no"])
 824
 825 # check for libopus(audio) library
 826 opus=0
 827 libopus_msg="no"
 828 AC_MSG_CHECKING(for libopus)
 829 AC_ARG_WITH(libopus,
 830     [  --with-libopus=PREFIX (base of libopus installation)],
 831     [AC_MSG_RESULT([$with_libopus])
 832      AS_CASE([$with_libopus],
 833         [no],[],
 834         [yes],[
 835             CHECK_LIBHEADER(LIBOPUS,
 836                             opus,
 837                             opus_decode_float,
 838                             opus/opus.h,
 839                             AC_CHECK_DECL([OPUS_SET_GAIN],
 840                                           [opus=1],
 841                                           [],
 842                                           [[
 843                                           #include <opus/opus.h>
 844                                           ]]))
 845     ],[
 846         LDFLAGS="-L$with_libopus/lib $LDFLAGS"
 847         CPPFLAGS="-I$with_libopus/include $CPPFLAGS"
 848         AC_CHECK_HEADERS(opus/opus.h,
 849                          AC_CHECK_LIB([opus],
 850                                       [OPUS_SET_GAIN],
 851                                       EXT_LIB_PATH="-L$with_libopus/lib $EXT_LIB_PATH"
 852                                       opus=1))
 853       ])
 854     ],
 855     [AC_MSG_RESULT([--with-libopus not specified])
 856      CHECK_LIBHEADER(LIBOPUS,
 857                      opus,
 858                      opus_decode_float,
 859                      opus/opus.h,
 860                      AC_CHECK_DECL([OPUS_SET_GAIN],
 861                                    [opus=1],
 862                                    [],
 863                                    [[
 864                                      #include <opus/opus.h>
 865                                    ]]))])
 866 AM_CONDITIONAL(HAVE_OPUS, [test "$opus" = 1])
 867 AS_IF([test "x$opus" = x1],
 868       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 869        libopus_msg="yes"],
 870       [AC_DEFINE([HAVE_OPUS],[0],[Lacking libopus library])
 871        libopus_msg="no (required for conversation)"])
 872
 873 # libogg
 874 AC_MSG_CHECKING(for libogg)
 875 AC_ARG_WITH(libogg,
 876     [  --with-libogg=PREFIX (base of libogg installation)],
 877     [AC_MSG_RESULT([$with_libogg])
 878      AS_CASE([$with_libogg],
 879         [no],[],
 880         [yes],[
 881             CHECK_LIBHEADER(LIBOGG,
 882                             ogg,
 883                             ogg_stream_flush_fill,
 884                             ogg/ogg.h,
 885                             ogg=1,)
 886         ],[
 887             LDFLAGS="-L$with_libogg/lib $LDFLAGS"
 888             CPPFLAGS="-I$with_libogg/include $CPPFLAGS"
 889             AC_CHECK_HEADERS(ogg/ogg.h,
 890                              AC_CHECK_LIB([ogg],
 891                                           [ogg_stream_flush_fill],
 892                                           EXT_LIB_PATH="-L$with_libogg/lib $EXT_LIB_PATH"
 893                                           ogg=1))
 894         ])
 895      ],
 896      [AC_MSG_RESULT([--with-libogg not specified])
 897       CHECK_LIBHEADER(LIBOGG,
 898                       ogg,
 899                       ogg_stream_flush_fill,
 900                       ogg/ogg.h,
 901                       ogg=1,)])
 902 AM_CONDITIONAL(HAVE_OGG, [test "$ogg" = 1])
 903 AS_IF([test x"$ogg" = x1],
 904       [AC_DEFINE([HAVE_OGG],[1],[Have ogg])]
 905       [AC_DEFINE([HAVE_OGG],[0],[Lacking ogg])])
 906
 907
 908 PKG_CHECK_MODULES([GLIB],
 909                   [glib-2.0],
 910   [# check for pbc library
 911   pbc=0
 912    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 913    AC_CHECK_HEADER([gabe.h],abe=1)
 914    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 915    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 916    AS_IF([test "x$pbc" = x1],
 917      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 918      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 919    AS_IF([test "x$abe" = x1],
 920     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 921     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 922   [# glib-2 not found
 923    AM_CONDITIONAL(HAVE_PBC, [false])
 924    AM_CONDITIONAL(HAVE_ABE, [false])
 925    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 926
 927
 928 gst=0
 929 gstreamer_msg="no"
 930 AC_MSG_CHECKING(for gstreamer)
 931 PKG_CHECK_MODULES(
 932   [GST],
 933   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 934   [gst=1
 935    gstreamer_msg="yes"],
 936   [gst=0])
 937
 938 # conversation
 939 AC_MSG_CHECKING(conversation feature set to build)
 940 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 941  AS_IF([test "x$gst" != "x1"],[
 942   conversation_backend=none
 943   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 944   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 945   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 946  ],[
 947    conversation_backend=gst
 948    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 949    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 950    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 951  ])
 952 ],[
 953  conversation_backend=pulse
 954  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 955  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 956  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 957 ])
 958
 959 AS_IF([test "x$conversation_backend" = "xnone"],
 960       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 961       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 962
 963 # libgnurl
 964 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 965
 966 SAVE_CPPFLAGS=$CPPFLAGS
 967 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 968 LIBS="$LIBGNURL $LIBCURL $LIBS"
 969
 970 # libcurl-gnutls
 971 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 972 AS_IF([test "x$curl" = xtrue],[
 973  AC_CHECK_HEADER([curl/curl.h],
 974   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 975   [curl=false])
 976  # need libcurl-gnutls.so, everything else is not acceptable
 977  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 978  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 979 ])
 980
 981 # libcurl and libgnurl should be mutually exclusive
 982 AS_IF([test "$gnurl" = 1],
 983       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 984        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 985        AM_CONDITIONAL(HAVE_LIBCURL, false)
 986        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 987       [AS_IF([test "$curl" = true],
 988              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 989               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 990               AM_CONDITIONAL(HAVE_LIBCURL, true)
 991               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 992              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 993               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 994               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 995               AM_CONDITIONAL(HAVE_LIBCURL, false)
 996               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 997
 998 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 999 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
1000
1001 # restore LIBS & CPPFLAGS
1002 LIBS=$SAVE_LIBS
1003 CPPFLAGS=$SAVE_CPPFLAGS
1004
1005
1006 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
1007 AS_IF([test x$nss = xfalse],
1008   [
1009         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
1010         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
1011   ],[
1012         NSS_INCLUDES="
1013         #include <nss.h>
1014         "
1015         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
1016                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
1017                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
1018                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
1019                 [$NSS_INCLUDES])
1020 ])
1021
1022
1023
1024 # test for kvm and kstat (for CPU stats under BSD/Solaris)
1025 AC_CHECK_LIB([kvm],[kvm_open])
1026 AC_CHECK_LIB([kstat],[kstat_open])
1027
1028
1029 # test for libextractor
1030 extractor=0
1031 AC_MSG_CHECKING(for libextractor)
1032 AC_ARG_WITH(extractor,
1033    [  --with-extractor=PREFIX (base of libextractor installation)],
1034    [AC_MSG_RESULT([$with_extractor])
1035     AS_CASE([$with_extractor],
1036       [no],[],
1037       [yes],[
1038         AC_CHECK_HEADERS([extractor.h],
1039           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1040             extractor=1))
1041       ],[
1042         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
1043         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
1044         AC_CHECK_HEADERS([extractor.h],
1045           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1046             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
1047             extractor=1))
1048       ])
1049    ],
1050    [AC_MSG_RESULT([--with-extractor not specified])
1051     AC_CHECK_HEADERS([extractor.h],
1052      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
1053       extractor=1))])
1054 # restore LIBS
1055 LIBS=$SAVE_LIBS
1056
1057 AS_IF([test "$extractor" != 1],
1058  [
1059  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
1060  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
1061  ],[
1062  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
1063  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
1064  ])
1065
1066
1067 # Check for libltdl header (#2999)
1068 ltdl=0
1069 AC_MSG_CHECKING(for libltdl)
1070 AC_ARG_WITH(ltdl,
1071    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
1072    [AC_MSG_RESULT([$with_ltdl])
1073     AS_CASE([$with_ltdl],
1074       [no],[],
1075       [yes],[
1076         AC_CHECK_HEADERS(ltdl.h,
1077           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1078             ltdl=1))
1079       ],[
1080         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
1081         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
1082         AC_CHECK_HEADERS(ltdl.h,
1083           AC_CHECK_LIB([ltdl], [lt_dlopenext],
1084             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
1085             ltdl=1))
1086       ])
1087    ],
1088    [AC_MSG_RESULT([--with-ltdl not specified])
1089     AC_CHECK_HEADERS(ltdl.h,
1090      AC_CHECK_LIB([ltdl], [lt_dlopenext],
1091       ltdl=1))])
1092 AS_IF([test x$ltdl = x1],
1093 [
1094  AC_MSG_RESULT([libltdl found])
1095 ],[
1096  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool).])
1097 ])
1098 # restore LIBS
1099 LIBS=$SAVE_LIBS
1100
1101 # libidn and libidn2. The ideal goal is this:
1102 # check for libidn2, if it doesn't exist check for libidn
1103 # if both exist, prefer libidn2
1104 # if none exist, fail and message that libidn or libidn2
1105 # is required with a preference for libidn2.
1106 # TODO: What we have right here can probably be improved.
1107 AC_MSG_CHECKING(for idn or idn2)
1108
1109 AC_MSG_CHECKING(for idn)
1110 my_with_libidn=1
1111 AC_ARG_WITH(libidn,
1112             AS_HELP_STRING([--with-libidn=pathname],
1113                            [Support IDN (needs libidn)]),
1114             [],
1115             [withval="yes"])
1116 AS_IF([test x_$withval = x_yes],
1117       [AC_CHECK_HEADERS([idna.h],
1118                         AC_MSG_NOTICE([Found idna.h]),
1119                         AC_CHECK_HEADERS([idn/idna.h],
1120                                          AC_MSG_NOTICE([Found idn/idna.h]),
1121                                          my_with_libidn=0))],
1122       [AS_IF([test x_$withval != x_no],
1123              [CFLAGS="$CFLAGS -I$withval/include"
1124               LDFLAGS="$LDFLAGS -L$withval/lib"
1125               AC_CHECK_HEADERS([idna.h],
1126                                AC_MSG_NOTICE([Found idna.h]),
1127                                    [AC_MSG_NOTICE([Failed to find idna.h])
1128                                my_with_libidn=0])],
1129              [my_with_libidn=0])])
1130
1131 AC_MSG_CHECKING(for idn2)
1132 my_with_libidn2=1
1133 AC_ARG_WITH(libidn2,
1134             AS_HELP_STRING([--with-libidn2=pathname],
1135                            [Support IDN (needs libidn2)]),
1136             [],
1137             [withval="yes"])
1138 AS_IF([test x_$withval = x_yes],
1139       [AC_CHECK_HEADERS([idn2.h],
1140                         AC_MSG_NOTICE([Found idn2.h]),
1141                         AC_CHECK_HEADERS([idn2/idn2.h],
1142                                          AC_MSG_NOTICE([Found idn2/idn2.h]),
1143                                          [AC_MSG_NOTICE([Failed to find idn2.h])
1144                                          my_with_libidn2=0]))],
1145       [AS_IF([test x_$withval != x_no],
1146              [CFLAGS="$CFLAGS -I$withval/include"
1147               LDFLAGS="$LDFLAGS -L$withval/lib"],
1148                   [my_with_libidn2=0])])
1149
1150 AC_MSG_CHECKING([if libidn can be used])
1151 # Check for LIBIDNs
1152 there_can_only_be_one=1
1153
1154 working_libidn1=0
1155 working_libidn2=0
1156 AS_IF([test x$my_with_libidn2 = x1],
1157       [AC_MSG_NOTICE([Checking for libidn2])
1158        AC_CHECK_LIB([idn2],
1159                     [idn2_to_unicode_8z8z],
1160                     [working_libidn2=1
1161                     LIBS="-lidn2 $LIBS"
1162                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
1163                                        [1],
1164                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
1165                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
1166                      MISSING_SEP=", "])])
1167 AM_CONDITIONAL(HAVE_LIBIDN2, test x$working_libidn2 = x1)
1168 AS_IF([test x$working_libidn2 = x0],
1169       [AS_IF([test x$my_with_libidn = x1],
1170              [AC_MSG_NOTICE([Checking for libidn])
1171               AC_CHECK_LIB([idn],
1172                            [idna_to_ascii_8z],
1173                            [working_libidn1=1
1174                            LIBS="-lidn $LIBS"
1175                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
1176                                               [1],
1177                                               [Define to 1 if you have 'libidn' (-lidn).])],
1178                            [there_can_only_be_one=0])],
1179              [AS_IF([test x$my_with_libidn2 = x1],
1180                     [there_can_only_be_one=0
1181                      AC_MSG_FAILURE([* There can only be one libidn.
1182                                      * Provide either libidn >= 1.13
1183                                      * or
1184                                      * libidn2 to the configure
1185                                      * script via
1186                                      * --with-libidn2
1187                                      * --with-libidn])])])])
1188 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1189
1190 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1191       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1192
1193 AS_IF([test x$there_can_only_be_one = x0],
1194       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1195
1196 # test for zlib
1197 SAVE_LDFLAGS=$LDFLAGS
1198 SAVE_CPPFLAGS=$CPPFLAGS
1199 AC_ARG_WITH(zlib,
1200             [  --with-zlib[[=DIR]]       use libz in DIR],
1201             [AS_IF([test "$withval" = "no"],
1202                    [AC_MSG_ERROR([GNUnet requires zlib])],
1203                    [test "$withval" != "yes"],
1204                    [Z_DIR=$withval
1205                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1206                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1207 AC_CHECK_HEADER(zlib.h,
1208                 [],
1209                 [AC_MSG_ERROR([GNUnet requires zlib])])
1210 AC_CHECK_LIB(z,
1211              compress2,
1212              [AC_DEFINE([HAVE_ZLIB],
1213                         [],
1214                         [Have compression library])
1215               if test "x${Z_DIR}" != "x"; then
1216                       Z_CFLAGS="-I${Z_DIR}/include"
1217                       Z_LIBS="-L${Z_DIR}/lib -lz"
1218               else
1219                       Z_LIBS="-lz"
1220               fi],
1221               [AC_MSG_ERROR([GNUnet requires zlib])])
1222 AC_SUBST(Z_CFLAGS)
1223 AC_SUBST(Z_LIBS)
1224
1225 AS_IF([test "$enable_shared" = "no"],
1226       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1227
1228
1229 # restore LIBS
1230 LIBS=$SAVE_LIBS
1231
1232
1233 # check for iconv
1234 AM_ICONV
1235
1236 # test for libunistring
1237 gl_LIBUNISTRING
1238 AS_IF([test $HAVE_LIBUNISTRING != yes],
1239       [AC_MSG_ERROR([GNUnet requires libunistring])])
1240
1241 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1242       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1243 AC_CHECK_HEADERS([unistr.h],
1244                  ,
1245                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1246
1247 # restore LIBS
1248 LIBS=$SAVE_LIBS
1249
1250
1251
1252 # Checks for standard header files.
1253 AC_HEADER_DIRENT
1254 AC_HEADER_STDC
1255
1256 # Check for headers that are ALWAYS required
1257 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1258
1259
1260
1261 # Checks for headers that are only required on some systems or
1262 # opional (and where we do NOT abort if they are not there)
1263 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1264
1265 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1266 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1267 [#ifdef HAVE_SYS_TYPES_H
1268 #include <sys/types.h>
1269 #endif
1270 #ifdef HAVE_NETINET_IN_SYSTM_H
1271 #include <netinet/in_systm.h>
1272 #endif
1273 #ifdef HAVE_NETINET_IN_H
1274 #include <netinet/in.h>
1275 #endif
1276 ])
1277
1278 SAVE_LDFLAGS=$LDFLAGS
1279 SAVE_CPPFLAGS=$CPPFLAGS
1280
1281 # test for sqlite
1282 sqlite=false
1283 AC_MSG_CHECKING(for SQLite)
1284 AC_ARG_WITH(sqlite,
1285   [  --with-sqlite=PFX       base of SQLite installation],
1286   [AC_MSG_RESULT("$with_sqlite")
1287    AS_CASE([$with_sqlite],
1288      [no],[],
1289      [yes],[
1290       AC_CHECK_HEADERS(sqlite3.h,
1291       sqlite=true)],
1292      [
1293     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1294     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1295     AC_CHECK_HEADERS(sqlite3.h,
1296      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1297      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1298      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1299      sqlite=true)
1300     LDFLAGS=$SAVE_LDFLAGS
1301     CPPFLAGS=$SAVE_CPPFLAGS
1302     ])
1303   ],
1304   [AC_MSG_RESULT([--with-sqlite not specified])
1305     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1306 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1307 AC_SUBST(SQLITE_CPPFLAGS)
1308 AC_SUBST(SQLITE_LDFLAGS)
1309
1310 LDFLAGS=$SAVE_LDFLAGS
1311 CPPFLAGS=$SAVE_CPPFLAGS
1312
1313 # test for postgres:
1314 postgres=false
1315 AX_LIB_POSTGRESQL([9.5],
1316   [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1317    AC_CHECK_HEADERS([libpq-fe.h],
1318    postgres=true)
1319   ],
1320   [AC_MSG_RESULT([no postgres])])
1321
1322 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1323 AS_IF([test "x$postgres" = xtrue],
1324       [AC_DEFINE([HAVE_POSTGRESQL],[1],[Have PostgreSQL])],
1325       [AC_DEFINE([HAVE_POSTGRESQL],[0],[Lacking PostgreSQL])])
1326
1327 LDFLAGS=$SAVE_LDFLAGS
1328 CPPFLAGS=$SAVE_CPPFLAGS
1329
1330 # mysql & windows
1331 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1332 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1333
1334 # test for mysql
1335 mysql=false
1336 mysqlfail=false
1337 SAVE_LDFLAGS=$LDFLAGS
1338 SAVE_CPPFLAGS=$CPPFLAGS
1339 AC_MSG_CHECKING(for mysql)
1340 AC_ARG_WITH(mysql,
1341   [  --with-mysql=PFX        base of MySQL installation],
1342   [AC_MSG_RESULT([$with_mysql])
1343    AS_CASE([$with_mysql],
1344      [no],[],
1345      [yes|""],[
1346       AC_CHECK_HEADERS(mysql/mysql.h,
1347        AC_CHECK_LIB(mysqlclient, mysql_init,
1348        mysql=true), [], [])
1349      ],[
1350       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1351       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1352       AC_CHECK_HEADERS(mysql/mysql.h,
1353        AC_CHECK_LIB(mysqlclient, mysql_init,
1354         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1355         MYSQL_CPPFLAGS="-I$with_mysql/include"
1356
1357         mysql=true), [], [])
1358      ])
1359   ],
1360   [AC_MSG_RESULT([--with-mysql not specified])
1361    if test -d "/usr/lib64/mysql"; then
1362     MYSQL_LIBDIR="/usr/lib64/mysql"
1363    elif test -d "/usr/lib/mysql"; then
1364     MYSQL_LIBDIR="/usr/lib/mysql"
1365    else
1366     MYSQL_LIBDIR="/usr/lib"
1367    fi
1368    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1369    AC_CHECK_LIB(mysqlclient, mysql_init,
1370     [AC_CHECK_HEADERS(mysql/mysql.h,
1371       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1372       mysql=true
1373
1374      , [], [])])
1375   ])
1376
1377 AC_SUBST(MYSQL_LDFLAGS)
1378 AC_SUBST(MYSQL_CPPFLAGS)
1379
1380 # additional version check for mysql
1381 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1382 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1383  [
1384   AC_MSG_CHECKING(mysql version)
1385   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1386     [[
1387       #include <mysql/mysql.h>]],
1388     [[
1389       #if (MYSQL_VERSION_ID < 40100)
1390       #error needs at least version >= 4.1
1391       #endif
1392       int main () { return 0; }
1393     ]])
1394     ],
1395     [mysql=true],
1396     [mysql=false])
1397   AS_IF([test x$mysql = xfalse],
1398    [
1399     mysqlfail=true
1400     AC_MSG_WARN([fail, MySQL >= 4.1 required])
1401    ],[
1402     AC_MSG_NOTICE([success, will keep $mysqlfail])
1403     mysqlfail=false
1404     AC_MSG_RESULT(ok)
1405    ])
1406 ])
1407
1408 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1409 AM_CONDITIONAL(HAVE_MYSQLE, false)
1410 # restore LIBS
1411 LIBS=$SAVE_LIBS
1412 LDFLAGS=$SAVE_LDFLAGS
1413 CPPFLAGS=$SAVE_CPPFLAGS
1414
1415 # TODO: should this test for "or" not "and"?
1416 # TODO: Add postgres?
1417 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1418 [
1419  AC_MSG_ERROR([GNUnet requires SQLite or MySQL / MariaDB.])
1420 ])
1421
1422 # libmicrohttpd
1423 lmhd=0
1424 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1425 AC_ARG_WITH(microhttpd,
1426    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1427        [base of libmicrohttpd installation])],
1428    [],
1429    [with_microhttpd=check])
1430 AS_CASE([$with_microhttpd],
1431    [no], [],
1432    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1433    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1434        [lmhd=1],
1435        [AC_MSG_WARN([Building without libmicrohttpd])])],
1436    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1437     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1438     export PKG_CONFIG_PATH
1439     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1440     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1441 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1442 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1443
1444 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1445
1446 # restore LIBS
1447 LIBS=$SAVE_LIBS
1448
1449 # check for gettext
1450 AM_GNU_GETTEXT([external])
1451 AM_GNU_GETTEXT_VERSION([0.18.1])
1452
1453 # Checks for standard typedefs, structures, and compiler characteristics.
1454 AC_TYPE_PID_T
1455 AC_TYPE_SIZE_T
1456 AC_TYPE_MODE_T
1457 AC_HEADER_TIME
1458 AC_HEADER_STAT
1459 AC_HEADER_STDBOOL
1460 AC_STRUCT_TM
1461
1462 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1463    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1464    ],
1465    [],
1466    [
1467       #include <sys/types.h>
1468       #include <sys/socket.h>
1469       #include <netinet/in.h>
1470    ])
1471
1472 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1473                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1474                             1,
1475                             [Do we have sockaddr_un.sun_len?])],
1476                 [],
1477                 [
1478                 #include <sys/types.h>
1479                 #include <sys/socket.h>
1480                 #include <sys/un.h>
1481                 ])
1482
1483
1484
1485 # Checks for library functions.
1486 AC_FUNC_CLOSEDIR_VOID
1487 AC_FUNC_FORK
1488 AC_PROG_GCC_TRADITIONAL
1489 AC_FUNC_MEMCMP
1490 AC_FUNC_SELECT_ARGTYPES
1491 AC_FUNC_CHOWN
1492
1493 AC_TYPE_SIGNAL
1494 AC_FUNC_STAT
1495 AC_FUNC_STRFTIME
1496 AC_FUNC_VPRINTF
1497 AC_HEADER_SYS_WAIT
1498 AC_TYPE_OFF_T
1499 AC_TYPE_UID_T
1500 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1501
1502 # restore LIBS
1503 LIBS=$SAVE_LIBS
1504
1505 GN_INTLINCL=""
1506 GN_LIBINTL="$LTLIBINTL"
1507 AC_ARG_ENABLE(framework,
1508               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1509               enable_framework_build=$enableval)
1510 AM_CONDITIONAL(WANT_FRAMEWORK,
1511                test x$enable_framework_build = xyes)
1512 AS_IF([test x$enable_framework_build = xyes],
1513       [AC_DEFINE([FRAMEWORK_BUILD],
1514                  1,
1515                  [Build a Mac OS X Framework])
1516       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1517       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1518       AC_LIB_APPENDTOVAR([CPPFLAGS],
1519                          [$GN_INTLINCL])])
1520
1521 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1522 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1523
1524 AC_SUBST(GN_LIB_LDFLAGS)
1525 AC_SUBST(GN_PLUGIN_LDFLAGS)
1526 AC_SUBST(GN_INTLINCL)
1527 AC_SUBST(GN_LIBINTL)
1528
1529 AC_SUBST(CPPFLAGS)
1530 AC_SUBST(LIBS)
1531 AC_SUBST(LDFLAGS)
1532 AC_SUBST(EXT_LIB_PATH)
1533 AC_SUBST(EXT_LIBS)
1534
1535 AC_SUBST(LIBPREFIX)
1536 AC_SUBST(DLLDIR)
1537 AC_SUBST(EXT_LIB_PATH)
1538
1539 DATAROOTDIR=$datarootdir
1540 AC_SUBST(DATAROOTDIR)
1541
1542 # test for sudo
1543 AC_MSG_CHECKING(for sudo)
1544 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1545 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1546 AC_ARG_WITH(sudo,
1547            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1548            [AC_MSG_RESULT("$with_sudo")
1549             AS_CASE([$with_sudo],
1550                     [no],[SUDO_BINARY=],
1551                     [yes],[SUDO_BINARY=sudo],
1552                     [SUDO_BINARY=$with_sudo])],
1553            [AC_MSG_RESULT([no])])
1554 AC_SUBST(SUDO_BINARY)
1555 AM_CONDITIONAL([HAVE_SUDO],
1556               [test "x$SUDO_BINARY" != "x" -o -w /])
1557
1558 # test for doas
1559 AC_MSG_CHECKING(for doas)
1560 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1561 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1562
1563 # test for gnunetdns group name
1564 GNUNETDNS_GROUP=gnunetdns
1565 AC_MSG_CHECKING(for gnunetdns group name)
1566 AC_ARG_WITH(gnunetdns,
1567             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1568             [AC_MSG_RESULT("$with_gnunetdns")
1569              AS_CASE([$with_gnunetdns],
1570                      [no],[GNUNETDNS_GROUP=gnunet],
1571                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1572                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1573             [AC_MSG_RESULT([gnunetdns])])
1574 AC_SUBST(GNUNETDNS_GROUP)
1575
1576
1577
1578 # gnutls
1579 gnutls=0
1580 gnutls_dane=0
1581 AC_MSG_CHECKING(for gnutls)
1582 AC_ARG_WITH(gnutls,
1583             [  --with-gnutls=PFX   base of gnutls installation],
1584             [AC_MSG_RESULT([$with_gnutls])
1585              AS_CASE([$with_gnutls],
1586                      [no],[],
1587                      [yes],
1588                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1589                                        AC_CHECK_LIB([gnutls],
1590                                                     [gnutls_priority_set],
1591                                                     gnutls=true))
1592                       AC_CHECK_HEADERS([gnutls/dane.h],
1593                                        AC_CHECK_LIB([gnutls-dane],
1594                                                     [dane_verify_crt_raw],
1595                                                     gnutls_dane=1))],
1596
1597         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1598         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1599         AC_CHECK_HEADERS([gnutls/abstract.h],
1600             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1601               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1602               gnutls=true))
1603         AC_CHECK_HEADERS([gnutls/dane.h],
1604             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1605               gnutls_dane=1))
1606       ])
1607    ],
1608    [AC_MSG_RESULT([--with-gnutls not specified])
1609     AC_CHECK_HEADERS([gnutls/abstract.h],
1610         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1611           gnutls=true))
1612     AC_CHECK_HEADERS([gnutls/dane.h],
1613         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1614                      gnutls_dane=1))
1615    ])
1616 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1617 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1618 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1619 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1620
1621
1622
1623 # Test if we are building for superMUC
1624 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1625 AC_ARG_ENABLE([supermuc],
1626     [AS_HELP_STRING([--enable-supermuc],
1627        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1628     [AS_IF([test "x$enable_supermuc" = "xno"],
1629       [supermuc=0],
1630       [supermuc=1])],
1631     [supermuc=0
1632      enable_supermuc=no])
1633 AC_MSG_RESULT($enable_SUPERMUC)
1634 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1635 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1636
1637 # Check if NSE has to send timestamp information to testbed logger for
1638 # generating histogram of messages received
1639 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1640 AC_ARG_ENABLE([nse-histogram],
1641     [AS_HELP_STRING([--enable-nse-histogram],
1642        [have NSE send timestamp information to testbed logger for generating
1643        histogram of received messages.  NOT useful for production (default is
1644        NO)])],
1645     [AS_IF([test "x$enableval" = "xno"],
1646       [nse_histogram=0],
1647       [nse_histogram=1])],
1648     [nse_histogram=0
1649      enable_nse_histogram=no])
1650 AC_MSG_RESULT($enable_nse_histogram)
1651 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1652 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1653                    [have NSE send timestamp information to testbed logger])
1654
1655 # should 'make check' run tests?
1656 AC_MSG_CHECKING(whether to run tests)
1657 AC_ARG_ENABLE([testruns],
1658    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1659    [enable_tests_run=${enableval}],
1660    [enable_tests_run=yes])
1661 AC_MSG_RESULT($enable_test_run)
1662 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1663
1664
1665 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1666 AC_ARG_ENABLE([benchmark],
1667    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1668    [enable_benchmark=${enableval}],
1669    [enable_benchmark=no])
1670 AC_MSG_RESULT($enable_benchmark)
1671 AS_IF([test "x$enable_benchmark" = "xyes"],
1672       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1673 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1674
1675
1676 # should expensive tests be run?
1677 AC_MSG_CHECKING(whether to run expensive tests)
1678 AC_ARG_ENABLE([expensivetests],
1679    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1680    [enable_expensive=${enableval}],
1681    [enable_expensive=no])
1682 AC_MSG_RESULT($enable_expensive)
1683 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1684
1685 # should ports be open for Java services?
1686 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1687 AC_ARG_ENABLE([javaports],
1688    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1689    [enable_java_ports=${enableval}],
1690    [enable_java_ports=no])
1691 AC_MSG_RESULT($enable_java_ports)
1692 AS_IF([test "x$enable_java_ports" = "xyes"],
1693  [JAVAPORT=""],
1694  [JAVAPORT="$UNIXONLY"])
1695 AC_SUBST(JAVAPORT)
1696
1697 # should benchmarks be run?
1698 AC_MSG_CHECKING(whether to run benchmarks during make check)
1699 AC_ARG_ENABLE([benchmarks],
1700    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1701    [enable_benchmarks=${enableval}],
1702    [enable_benchmarks=no])
1703 AC_MSG_RESULT($enable_benchmarks)
1704 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1705
1706 # should gnunet-testing be compiled
1707 AC_MSG_CHECKING(whether to compile gnunet-testing)
1708 AC_ARG_ENABLE([testing],
1709    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1710    [enable_testing=${enableval}],
1711    [enable_testing=yes])
1712 AC_MSG_RESULT($enable_testing)
1713 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1714
1715 # should experimental code be compiled (code that may not yet compile)?
1716 AC_MSG_CHECKING(whether to compile experimental code)
1717 AC_ARG_ENABLE([experimental],
1718    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1719    [enable_experimental=${enableval}],
1720    [enable_experimental=no])
1721 AC_MSG_RESULT($enable_experimental)
1722 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1723
1724 # should malicious code be compiled (should only be used for testing)?
1725 AC_MSG_CHECKING(whether to compile malicious code)
1726 AC_ARG_ENABLE([malicious],
1727    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1728    [AS_IF([test "x$enableval" = "xno"],
1729      [malicious=0],
1730      [malicious=1])],
1731    [malicious=0
1732     enable_malicious=no])
1733 AC_MSG_RESULT($enable_malicious)
1734 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1735 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1736                    [enable compilation of malicious code])
1737
1738 # should services be started on demand when needed?
1739 # Some services may choose to never start by default
1740 # and it is up to the service/module developer to decide
1741 # by having "START_ON_DEMAND = NO" instead of
1742 # "START_ON_DEMAND = @START_ON_DEMAND@"
1743 # in the service/module's conf.in file.
1744 # See also IMMEDIATE_START for an unconditional immediate start.
1745 START_ON_DEMAND="YES"
1746 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1747 AC_ARG_ENABLE([autostart],
1748    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1749    [enable_autostart=${enableval}
1750     AS_IF([test "x$enable_autostart" = "xno"],
1751       [START_ON_DEMAND="NO"])
1752    ],
1753    [enable_autostart=yes])
1754 AC_MSG_RESULT($enable_autostart)
1755 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1756 AC_SUBST(START_ON_DEMAND)
1757
1758 # should memory statistics be kept (very expensive CPU-wise!)
1759 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1760 AC_ARG_ENABLE([heapstats],
1761    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1762    [enable_heapstats=1],
1763    [enable_heapstats=0])
1764 AC_MSG_RESULT($enable_heapstats)
1765 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1766
1767
1768 # Check if the __thread storage class for
1769 # thread-local storage is available.
1770 AC_MSG_CHECKING(whether __thread is supported)
1771 AC_LINK_IFELSE(
1772 [AC_LANG_PROGRAM([#include <stdlib.h>
1773                    #undef __thread
1774                    static __thread int a = 1;],
1775                   [exit(a-1);])],
1776  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1777 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1778 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1779       [AC_MSG_RESULT(yes)],
1780       [AC_MSG_RESULT(no)])
1781
1782 # gcov compilation
1783 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1784 AC_ARG_ENABLE([coverage],
1785               AS_HELP_STRING([--enable-coverage],
1786                              [compile the library with code coverage support]),
1787               [use_gcov=${enableval}],
1788               [use_gcov=no])
1789 AC_MSG_RESULT($use_gcov)
1790 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1791
1792
1793 # version info
1794 # TODO: git blame says this predates our switch to git.
1795 # git-svn should be adjusted to simply git, or
1796 # an external script that does the job.
1797 AC_PATH_PROG(svnversioncommand, svnversion)
1798 AC_PATH_PROG(gitcommand, git)
1799 AC_MSG_CHECKING(for source being under a VCS)
1800
1801
1802 # version info
1803 AC_PATH_PROG(gitcommand, git)
1804 AC_MSG_CHECKING(for source being under a VCS)
1805 git_version=
1806 AS_IF([test ! "X$gitcommand" = "X"],
1807 [
1808   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1809 ])
1810 AS_IF([test "X$git_version" = "X"],
1811   [
1812     vcs_name="no"
1813     vcs_version="\"release\""
1814   ],
1815   [
1816     vcs_name="yes, git-svn"
1817     vcs_version="\"git-$git_version\""
1818   ])
1819 AC_MSG_RESULT($vcs_name)
1820
1821 AC_MSG_CHECKING(VCS version)
1822 AC_MSG_RESULT($vcs_version)
1823 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1824
1825 AC_CONFIG_FILES([
1826 Makefile
1827 bin/Makefile
1828 contrib/Makefile
1829 contrib/hellos/Makefile
1830 contrib/services/Makefile
1831 contrib/services/openrc/Makefile
1832 contrib/services/systemd/Makefile
1833 contrib/scripts/Makefile
1834 contrib/scripts/gnunet-logread/Makefile
1835 doc/Makefile
1836 doc/man/Makefile
1837 doc/doxygen/Makefile
1838 doc/handbook/Makefile
1839 doc/tutorial/Makefile
1840 m4/Makefile
1841 po/Makefile.in
1842 src/Makefile
1843 src/arm/Makefile
1844 src/arm/arm.conf
1845 src/ats/Makefile
1846 src/ats/ats.conf
1847 src/ats-tool/Makefile
1848 src/ats-tests/Makefile
1849 src/auction/Makefile
1850 src/block/Makefile
1851 src/cadet/Makefile
1852 src/cadet/cadet.conf
1853 src/core/Makefile
1854 src/core/core.conf
1855 src/consensus/Makefile
1856 src/consensus/consensus.conf
1857 src/conversation/Makefile
1858 src/conversation/conversation.conf
1859 src/curl/Makefile
1860 src/datacache/Makefile
1861 src/datastore/Makefile
1862 src/datastore/datastore.conf
1863 src/dht/Makefile
1864 src/dht/dht.conf
1865 src/dns/Makefile
1866 src/dns/dns.conf
1867 src/exit/Makefile
1868 src/fragmentation/Makefile
1869 src/fs/Makefile
1870 src/fs/fs.conf
1871 src/gns/Makefile
1872 src/gns/gns.conf
1873 src/gns/nss/Makefile
1874 src/gnsrecord/Makefile
1875 src/hello/Makefile
1876 src/identity/Makefile
1877 src/identity/identity.conf
1878 src/abd/Makefile
1879 src/abd/abd.conf
1880 src/include/Makefile
1881 src/integration-tests/Makefile
1882 src/json/Makefile
1883 src/hostlist/Makefile
1884 src/my/Makefile
1885 src/mysql/Makefile
1886 src/namecache/Makefile
1887 src/namecache/namecache.conf
1888 src/namestore/Makefile
1889 src/namestore/namestore.conf
1890 src/nat/Makefile
1891 src/nat/nat.conf
1892 src/nat-auto/Makefile
1893 src/nat-auto/nat-auto.conf
1894 src/nse/Makefile
1895 src/nse/nse.conf
1896 src/nt/Makefile
1897 src/peerinfo/Makefile
1898 src/peerinfo/peerinfo.conf
1899 src/peerinfo-tool/Makefile
1900 src/peerstore/Makefile
1901 src/peerstore/peerstore.conf
1902 src/pq/Makefile
1903 src/pt/Makefile
1904 src/regex/Makefile
1905 src/regex/regex.conf
1906 src/revocation/Makefile
1907 src/revocation/revocation.conf
1908 src/rps/Makefile
1909 src/rps/rps.conf
1910 src/secretsharing/Makefile
1911 src/secretsharing/secretsharing.conf
1912 src/scalarproduct/Makefile
1913 src/scalarproduct/scalarproduct.conf
1914 src/set/Makefile
1915 src/set/set.conf
1916 src/sq/Makefile
1917 src/statistics/Makefile
1918 src/statistics/statistics.conf
1919 src/template/Makefile
1920 src/testbed/Makefile
1921 src/testbed/testbed.conf
1922 src/testbed-logger/Makefile
1923 src/testbed-logger/testbed-logger.conf
1924 src/testing/Makefile
1925 src/topology/Makefile
1926 src/transport/Makefile
1927 src/transport/transport.conf
1928 src/util/Makefile
1929 src/util/resolver.conf
1930 src/vpn/Makefile
1931 src/vpn/vpn.conf
1932 src/zonemaster/Makefile
1933 src/zonemaster/zonemaster.conf
1934 src/rest/Makefile
1935 src/abe/Makefile
1936 src/reclaim/Makefile
1937 pkgconfig/Makefile
1938 pkgconfig/gnunetarm.pc
1939 pkgconfig/gnunetats.pc
1940 pkgconfig/gnunetblock.pc
1941 pkgconfig/gnunetcadet.pc
1942 pkgconfig/gnunetconsensus.pc
1943 pkgconfig/gnunetconversation.pc
1944 pkgconfig/gnunetcore.pc
1945 pkgconfig/gnunetdatacache.pc
1946 pkgconfig/gnunetdatastore.pc
1947 pkgconfig/gnunetdht.pc
1948 pkgconfig/gnunetdns.pc
1949 pkgconfig/gnunetenv.pc
1950 pkgconfig/gnunetfragmentation.pc
1951 pkgconfig/gnunetfs.pc
1952 pkgconfig/gnunetgns.pc
1953 pkgconfig/gnunethello.pc
1954 pkgconfig/gnunetidentity.pc
1955 pkgconfig/gnunetmicrophone.pc
1956 pkgconfig/gnunetmysql.pc
1957 pkgconfig/gnunetnamestore.pc
1958 pkgconfig/gnunetnat.pc
1959 pkgconfig/gnunetnse.pc
1960 pkgconfig/gnunetpeerinfo.pc
1961 pkgconfig/gnunetpq.pc
1962 pkgconfig/gnunetregex.pc
1963 pkgconfig/gnunetrevocation.pc
1964 pkgconfig/gnunetrps.pc
1965 pkgconfig/gnunetscalarproduct.pc
1966 pkgconfig/gnunetset.pc
1967 pkgconfig/gnunetspeaker.pc
1968 pkgconfig/gnunetstatistics.pc
1969 pkgconfig/gnunettestbed.pc
1970 pkgconfig/gnunettesting.pc
1971 pkgconfig/gnunettransport.pc
1972 pkgconfig/gnunetutil.pc
1973 pkgconfig/gnunetvpn.pc
1974 ])
1975 AC_OUTPUT
1976
1977
1978 # FIXME: `some modules' -> be more specific which exact modules.
1979
1980 # java ports
1981 AS_IF([test "x$enable_java_ports" = "xyes"],
1982       [AC_MSG_NOTICE([Opening TCP ports by default to enable gnunet-java bindings.])])
1983
1984 ####
1985 #### This could be moved to the checks above,
1986 #### but for now let's keep it here.
1987 ####
1988
1989 # -- print message regarding enabled experimental features
1990 AS_IF([test "x$enable_experimental" = "xyes"],
1991       [experimental_msg="experimental features enabled"])
1992 # -- OSX Framework
1993 AS_IF([test "$enable_framework_build" = "yes"],
1994       [macosx_framework_msg="yes"],
1995       [macosx_framework_msg="no"])
1996 # -- libidn 2
1997 AS_IF([test "x$working_libidn2" = x1],
1998       [libidn2_msg="libidn2"])
1999 # -- libidn 1
2000 AS_IF([test "x$working_libidn1" = x1],
2001       [libidn1_msg="libidn1"])
2002 # -- texi2mdoc-generation
2003 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
2004       [mdocml_msg="yes"],
2005       [mdocml_msg="no"])
2006 # -- texi2mdoc
2007 AS_IF([test "x$TEXI2MDOC_BINARY" = "false"],
2008       [AC_MSG_NOTICE([texi2mdoc binary not found (will not generate mdoc documentation)])
2009        texi2mdoc_msg="no (optional)"],
2010       [texi2mdoc_msg="yes"])
2011 # -- mandoc
2012 AS_IF([test "x$MANDOC_BINARY" = "false"],
2013       [AC_MSG_NOTICE([mandoc binary not found (will not generate handbook as man page)])
2014        mandoc_msg="no"],
2015       [mandoc_msg="yes"])
2016 # -- texinfo
2017 AS_IF([test "x$makeinfo" != "x1"],
2018       [texinfo_msg="no"],
2019       [texinfo_msg="yes"])
2020 # -- conversation
2021 AS_IF([test "x$conversation_backend" = "xnone"],
2022       [AS_IF([test "x$pulse" != "x1"],
2023              [AC_MSG_WARN([libpulse(audio) not found (required to build conversation).])
2024               libpulse_msg="no (required for conversation)"],
2025              [libpulse_msg="yes"])
2026        AS_IF([test "x$opus" != "x1"],
2027              [AC_MSG_WARN([libopus not found (required to build conversation)])
2028               libopus_msg="no (required for conversation)"],
2029              [libopus_msg="yes"])
2030        AS_IF([test "x$gst" != "x1"],
2031              [AC_MSG_WARN([GStreamer not found (required to build conversation).])
2032               gstreamer_msg="no (required for conversation)"],
2033              [gstreamer_msg="yes"])],
2034       [AS_IF([test "x$opus" = x1],
2035              [features_msg="$features_msg conversation"],
2036              [AC_MSG_WARN([libopus not found (required to build conversation)])])])
2037 # -- interface
2038 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
2039 # -- libmicrohttpd
2040 AS_IF([test "x$lmhd" != "x1"],
2041       [libmicrohttpd_msg="no (optional)"],
2042       [libmicrohttpd_msg="yes"])
2043 # -- jansson
2044 AS_IF([test "x$jansson" = "x0"],
2045       [jansson_msg="no (optional)"],
2046       [jansson_msg="yes"])
2047 # -- libextractor
2048 AS_IF([test "$extractor" != 1],
2049       [AC_MSG_WARN([libextractor not found, but various file-sharing functions require it])],
2050       [libextractor_msg="yes"])
2051 # -- libzbar
2052 AS_IF([test "x$zbar" = "x1"],
2053       [libzbar_msg="yes"
2054        features_msg="$features_msg gnunet-qr"],
2055       [AC_MSG_NOTICE([zbar not found, gnunet-qr will not be built.])
2056        libzbar_msg="no"])
2057 # -- libgnurl
2058 AS_IF([test "$gnurl" = "0"],
2059       [AS_IF([test "x$curl" = "xfalse"],
2060              [AC_MSG_WARN([libgnurl not found. http client support will not be compiled.])
2061               AC_MSG_WARN([IMPORTANT: No HTTP client library found. HTTP transports and hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
2062               curl_msg="no"],
2063              [AC_MSG_NOTICE([libgnurl not found, trying to use libcurl-gnutls instead.])
2064               curl_msg="yes"])],
2065        [gnurl_msg="yes"])
2066 # -- ifconfig
2067 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
2068       [AC_MSG_WARN([ifconfig not found, some features will not work])
2069        ifconfig_msg="no (optional)"],
2070       [ifconfig_msg="yes"])
2071 # -- upnpc
2072 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
2073       [AC_MSG_WARN([upnpc binary not found, NAT traversal using UPnPc will not work])
2074        upnpc_msg="no (optional)"],
2075       [upnpc_msg="yes"])
2076 # -- iptables
2077 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
2078       [AC_MSG_WARN([iptables not found, DNS query interception will not work])
2079        iptables_msg="no (optional)"],
2080       [iptables_msg="yes"])
2081 # -- bluetooth
2082 AS_IF([test "x$bluetooth" = "x0"],
2083       [AC_MSG_NOTICE([bluetooth library not found, will not be able to use Bluetooth])
2084        bluetooth_msg="no (optional)"],
2085       [bluetooth_msg="yes"])
2086 # -- gnutls
2087 AS_IF([test x$gnutls != xtrue],
2088       [AC_MSG_WARN([GnuTLS not found, gnunet-gns-proxy will not be built])
2089        gnutls_msg="no"],
2090       [AS_IF([test "x$gnutls_dane" != "x1"],
2091              [AC_MSG_WARN([GnuTLS lacks DANE support, DANE validation will not be possible])
2092               gnutls_msg="yes (without DANE support)"],
2093              [gnutls_msg="yes (with DANE support)"])])
2094 # -- databases
2095 # TODO: this always returns true, the check might
2096 # TODO: not be working as intended (for msqlfail).
2097 AS_IF([test "$mysql" = true],
2098       [features_msg="$features_msg mysql"
2099        mysql_msg="yes"],
2100       [mysql_msg="no"])
2101 AS_IF([test x$mysqlfail = xtrue],
2102       [AC_MSG_WARN([MySQL not found (or too old), will not create MySQL database support])
2103        mysql_msg="unsupported version"])
2104 AS_IF([test "$sqlite" = true],
2105       [features_msg="$features_msg sqlite"
2106        sqlite_msg="yes"],
2107       [AC_MSG_ERROR([sqlite3 not found, but sqlite3 is required.])
2108        sqlite_msg="no"])
2109 AS_IF([test "$postgres" = true],
2110       [features_msg="$features_msg postgres"
2111        postgres_msg="yes"],
2112       [postgres_msg="no"])
2113 # -- features
2114 # ---- 1. replace spaces with newlines,
2115 # ---- 2. sort the lines,
2116 # ---- 3. replace the newlines with spaces.
2117 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
2118 AC_SUBST(features_msg)
2119
2120
2121 # The summary
2122 # TODO: reduce the length of the last message block, following "IMPORTANT".
2123
2124 AC_MSG_NOTICE([
2125 GNUnet Configuration
2126 ====================
2127
2128 GNUnet version:                 ${VERSION}
2129
2130 Host setup:                     ${host}
2131 Install prefix:                 ${prefix}
2132 Compiler:                       ${CC}
2133 CFLAGS:                         ${CFLAGS}
2134 CPPFLAGS:                       ${CPPFLAGS}
2135 LDFLAGS:                        ${LDFLAGS}
2136 LIBS:                           ${LIBS}
2137 Build Target:                   $build_target
2138 Mac OSX framework build:        ${macosx_framework_msg}
2139
2140 Default Interface:              ${interface_msg}
2141
2142 MySQL:                          ${mysql_msg}
2143 PostgreSQL:                     ${postgres_msg}
2144 sqlite3:                        ${sqlite_msg}
2145 gnurl:                          ${gnurl_msg}
2146 curl:                           ${curl_msg}
2147 bluetooth:                      ${bluetooth_msg}
2148 jansson:                        ${jansson_msg}
2149 iptables:                       ${iptables_msg}
2150 ifconfig:                       ${ifconfig_msg}
2151 upnpc:                          ${upnpc_msg}
2152 gnutls:                         ${gnutls_msg}
2153 libzbar:                        ${libzbar_msg}
2154 java:                           ${java_msg}
2155 libmicrohttpd:                  ${libmicrohttpd_msg}
2156 libidn:                         ${libidn1_msg}${libidn2_msg}
2157 libopus:                        ${libopus_msg}
2158 gstreamer:                      ${gstreamer_msg}
2159 libpulse:                       ${libpulse_msg}
2160 libextractor:                   ${libextractor_msg}
2161 texi2mdoc:                      ${texi2mdoc_msg}
2162 mandoc:                         ${mandoc_msg}
2163
2164 texinfo manual:                 ${texinfo_msg}
2165 transpiled mdocml manual:       ${mdocml_msg}
2166
2167 features:                       ${features_msg}
2168 experimental:                   ${experimental_msg}
2169 ])
2170
2171 AS_IF([test x$MSG_USER_SETUP != xfalse],
2172  [AC_MSG_WARN([Please make sure NOW to create a user and group 'gnunet' and additionally a group 'gnunetdns'. Make sure that '/var/lib/gnunet' is owned (and writable) by user 'gnunet'.])
2173   AS_IF([test x$HAVE_GNUNET_USER != 0],
2174     [AC_MSG_NOTICE([To do this on this system, run:
2175 # addgroup gnunetdns
2176 # adduser --system --disabled-login --home /var/lib/gnunet gnunet
2177 ])])
2178   AC_MSG_WARN([Each user of GNUnet should be added to the 'gnunet' group.])
2179   AS_IF([test x$HAVE_GNUNET_USER != 0],
2180     [AC_MSG_NOTICE([To do this on this system, run:
2181 # adduser USERNAME gnunet
2182    for each of your users, replacing \"USERNAME\" with the respective login name. Users may have to login again for the changes to take effect.
2183 ])])])
2184
2185 AC_MSG_NOTICE([For detailed setup instructions, type 'info gnunet' after the installation or visit https://docs.gnunet.org/])