configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2019 GNUnet e.V.
   3 #
   4 # GNUnet is free software: you can redistribute it and/or modify it
   5 # under the terms of the GNU Affero General Public License as published
   6 # by the Free Software Foundation, either version 3 of the License,
   7 # or (at your option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Affero General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # SPDX-License-Identifier: AGPL3.0-or-later
  18 #
  19 # Process this file with autoconf to produce a configure script.
  20 #
  21 #
  22 AC_PREREQ(2.61)
  23 # Checks for programs.
  24 AC_INIT([gnunet], [0.11.6], [bug-gnunet@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 # check for legacy option that is no longer supported (#5627) and fail hard
  28 AC_ARG_WITH(nssdir,
  29    [  --with-nssdir=DIR    legacy switch, no longer supported, do not use],
  30    [AC_MSG_RESULT([$with_nssdir])
  31     AS_CASE([$with_nssdir],
  32       [no],[],
  33       [AC_MSG_ERROR([--with-nssdir is no longer supported])])
  34    ])
  35
  36 AC_CANONICAL_TARGET
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_SYSTEM
  39 AM_INIT_AUTOMAKE
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AM_DEFAULT_VERBOSITY=1 AC_SUBST(AM_DEFAULT_VERBOSITY)])
  41 AC_CONFIG_HEADERS([gnunet_config.h])
  42 AH_TOP([#define _GNU_SOURCE  1])
  43 AC_CONFIG_MACRO_DIR([m4])
  44 AC_PROG_AWK
  45 AC_PROG_CC_C99
  46 AC_PROG_OBJC
  47 AC_PROG_INSTALL
  48 AC_PROG_LN_S
  49 AC_PROG_MAKE_SET
  50 AM_PROG_CC_C_O
  51 LT_INIT([disable-static dlopen win32-dll])
  52 AC_SUBST(MKDIR_P)
  53
  54 # allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 # large file support
  58 AC_SYS_LARGEFILE
  59 AC_FUNC_FSEEKO
  60
  61
  62 CFLAGS="-Wall $CFLAGS"
  63 AC_MSG_CHECKING(whether cc can use -fno-strict-aliasing)
  64 # use '-fno-strict-aliasing', but only if the compiler can take it
  65 AS_IF([$CC -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
  66  [CFLAGS="-fno-strict-aliasing $CFLAGS"])
  67
  68 # A helper which allows us to check cflags if compiler
  69 AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
  70   AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
  71     [ac_save_CFLAGS="$CFLAGS"
  72      CFLAGS="$CFLAGS $1 -Werror"
  73      AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
  74        [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
  75        [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
  76      CFLAGS="$ac_save_CFLAGS"
  77     ])
  78
  79   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
  80     [$2], [$3])
  81 ])
  82
  83
  84 # CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
  85 # Check for CFLAG and appends them to CFLAGS if supported
  86 AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
  87   AC_CACHE_CHECK([if $CC supports -Wno-$1 flag],
  88     AS_TR_SH([cc_cv_cflags_-W$1]),
  89     CC_CHECK_CFLAGS_SILENT([-W$1]) #gcc is stupid. It does not fail with the -W-no option for backwards compat but then shows the error "in case something goes wrong".
  90   )
  91
  92   AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_-W$1])[ = xyes],
  93     [CFLAGS="$CFLAGS -Wno-$1"; $2], [$3])
  94 ])
  95
  96
  97 # We make heavy use of this, llvm/gcc and gcc-9 give warnings so disable.
  98 CC_CHECK_CFLAG_APPEND([address-of-packed-member])
  99
 100 # Use Linux interface name unless the OS has a different preference
 101 DEFAULT_INTERFACE="\"eth0\""
 102
 103 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo getaddrinfo_a"
 104
 105 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
 106 native_srcdir=$srcdir
 107
 108 OLD_LDFLAGS="$LDFLAGS"
 109 LDFLAGS="$LDFLAGS -Wl,--unresolved-symbols=report-all"
 110
 111 # Check system type
 112 AS_CASE(["$host_os"],
 113   [*darwin* | *rhapsody* | *macosx*],[
 114      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
 115      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
 116      CFLAGS="-fno-common $CFLAGS"
 117      LDFLAGS="$OLD_LDFLAGS"
 118      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
 119      AC_CHECK_LIB(intl, gettext)
 120      build_target="darwin"
 121      DEFAULT_INTERFACE="\"en0\""
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      UNIXONLY="#"
 125   ],
 126   [linux*],[
 127      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 128      build_target="linux"
 129      LIBPREFIX=
 130      DLLDIR=lib
 131      UNIXONLY="#"
 132      AC_PATH_XTRA
 133   ],
 134   [*freebsd*],[
 135      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 136      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
 137      CFLAGS="-D_THREAD_SAFE $CFLAGS"
 138      build_target="freebsd"
 139      LIBPREFIX=
 140      DLLDIR=lib
 141      UNIXONLY="#"
 142   ],
 143   [*openbsd*],[
 144      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 145      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 146      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 147      build_target="openbsd"
 148      LIBPREFIX=
 149      DLLDIR=lib
 150      UNIXONLY="#"
 151   ],
 152   [*netbsd*],[
 153      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 154      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 155      build_target="netbsd"
 156      LIBPREFIX=
 157      DLLDIR=lib
 158      UNIXONLY="#"
 159   ],
 160   [*solaris*],[
 161      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 162      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 163      AC_CHECK_LIB(resolv, res_init)
 164      AC_CHECK_LIB(rt, nanosleep)
 165      build_target="solaris"
 166      LIBPREFIX=
 167      DLLDIR=lib
 168      UNIXONLY="#"
 169   ],
 170   [*arm-linux*],[
 171      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 172      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 173      build_target="linux"
 174      LIBPREFIX=
 175      DLLDIR=lib
 176      UNIXONLY="#"
 177   ],
 178   [gnu*],[
 179      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 180      build_target="gnu"
 181      UNIXONLY="#"
 182   ],
 183   [
 184      AC_MSG_RESULT(Unrecognised OS $host_os)
 185      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 186      UNIXONLY=""
 187 ])
 188 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 189 AC_SUBST(DEFAULT_INTERFACE)
 190
 191 # Disable TCP-based IPC on systems that support UNIX domain
 192 # sockets in default configuratin:
 193 AC_SUBST(UNIXONLY)
 194
 195
 196 AC_MSG_CHECKING([for build target])
 197 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 198 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 199 AM_CONDITIONAL(XNETBSD, test "$build_target" = "netbsd")
 200 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 201 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 202 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 203 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 204
 205 AC_MSG_RESULT([$build_target])
 206 AC_SUBST(build_target)
 207 AM_CONDITIONAL([am__fastdepOBJC], false)
 208 AC_UNALIGNED_64_ACCESS
 209
 210 # some other checks for standard libs
 211 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 212 AC_SEARCH_LIBS([memrchr], [],
 213                AC_DEFINE(HAVE_MEMRCHR,1,[memrchr supported]), [])
 214 AC_SEARCH_LIBS([memset_s], [],
 215                AC_DEFINE(HAVE_MEMSET_S,1,[memset_s supported]), [])
 216 AC_SEARCH_LIBS([memset_s], [],
 217                AC_DEFINE(HAVE_EXPLICIT_BZERO,1,[explicit_bzero supported]), [])
 218 AC_CHECK_LIB(socket, socket)
 219 AC_CHECK_LIB(m, log)
 220 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 221
 222 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 223 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 224
 225 AC_CHECK_PROG(VAR_SSH_BINARY, ssh, true, false)
 226 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 227 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 228 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 229
 230 # autotools' m4 for python has no maximum version!
 231 # python3.4 - python3.8 for tests (3.8 unchecked)
 232 # TODO: document how to override the lowest version
 233 # TODO: found by this.
 234 m4_define_default([_AM_PYTHON_INTERPRETER_LIST],[python3 python3.4 python3.5 python3.6 python3.7 python3.8 python])
 235 AM_PATH_PYTHON([3.4],, [:])
 236 AC_SUBST([PYTHON])
 237 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 238
 239 # perl
 240 AC_PATH_PROG( PERL, perl, ,
 241               $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 242 AC_SUBST([PERL])
 243
 244 # iptables is a soft requirement to run tests
 245 AC_PATH_TARGET_TOOL(VAR_IPTABLES_BINARY, iptables, false)
 246
 247 AS_IF([test x"$VAR_IPTABLES_BINARY" = x"false"],
 248  [AS_IF([test -x "/sbin/iptables"],
 249    [VAR_IPTABLES_BINARY="/sbin/iptables"],
 250    [AS_IF([test -x "/usr/sbin/iptables"],
 251       [VAR_IPTABLES_BINARY="/usr/sbin/iptables"])])])
 252
 253 AS_IF([test x"$VAR_IPTABLES_BINARY" != x"false"],
 254  [AC_DEFINE_UNQUOTED([IPTABLES], "$VAR_IPTABLES_BINARY", [Path to iptables])],
 255  [AC_MSG_WARN([warning: 'iptables' not found.])])
 256
 257 # ip6tables is a soft requirement for some features
 258 AC_PATH_TARGET_TOOL(VAR_IP6TABLES_BINARY, ip6tables, false)
 259
 260 AS_IF([test x"$VAR_IP6TABLES_BINARY" = x"false"],
 261   [AS_IF([test -x "/sbin/ip6tables"],
 262      [VAR_IP6TABLES_BINARY="/sbin/ip6tables"],
 263      [AS_IF([test -x "/usr/sbin/ip6tables"],
 264         [VAR_IP6TABLES_BINARY="/usr/sbin/ip6tables"])])])
 265
 266
 267 AS_IF([test x"$VAR_IP6TABLES_BINARY" != x"false"],
 268   [AC_DEFINE_UNQUOTED([IP6TABLES], "$VAR_IP6TABLES_BINARY", [Path to ip6tables])],
 269   [AC_MSG_WARN([warning: 'ip6tables' not found.])])
 270
 271 # ip is a soft requirement for some features
 272 AC_PATH_TARGET_TOOL(VAR_IP_BINARY, ip, false)
 273
 274 AS_IF([test x"$VAR_IP_BINARY" = x"false"],
 275  [AS_IF([test -x "/sbin/ip"],
 276    [VAR_IP_BINARY="/sbin/ip"],
 277    [AS_IF([test -x "/usr/sbin/ip"],
 278           [VAR_IP_BINARY="/usr/sbin/ip"])])])
 279
 280 AS_IF([test x"$VAR_IP_BINARY" != x"false"],
 281  [AC_DEFINE_UNQUOTED([PATH_TO_IP], "$VAR_IP_BINARY", [Path to ip])],
 282  [AC_MSG_WARN([warning: 'ip' not found.])])
 283
 284 # locate 'ifconfig'
 285 AC_PATH_TARGET_TOOL(VAR_IFCONFIG_BINARY, ifconfig, false)
 286
 287 AC_CHECK_PROG(VAR_IFCONFIG_BINARY, ifconfig, true, false)
 288 AS_IF([test x"$VAR_IFCONFIG_BINARY" = x"false"],
 289   [AS_IF([test -x "/sbin/ifconfig"],
 290      [VAR_IFCONFIG_BINARY="/sbin/ifconfig"],
 291      [AS_IF([test -x "/usr/sbin/ifconfig"],
 292             [VAR_IFCONFIG_BINARY="/usr/sbin/ifconfig"])])])
 293
 294 AS_IF([test x"$VAR_IFCONFIG_BINARY" != x"false"],
 295   [AC_DEFINE_UNQUOTED([IFCONFIG], "$VAR_IFCONFIG_BINARY", [Path to ifconfig])],
 296   [AC_MSG_WARN(['ifconfig' not found.])])
 297
 298
 299 AC_PATH_TARGET_TOOL(VAR_SYSCTL_BINARY, sysctl, false)
 300
 301 AC_CHECK_PROG(VAR_SYSCTL_BINARY, sysctl, true, false)
 302 AS_IF([test x"$VAR_SYSCTL_BINARY" = x"false"],
 303       [AS_IF([test -x "/sbin/sysctl"],
 304              [VAR_SYSCTL_BINARY="/sbin/sysctl"],
 305              [AS_IF([test -x "/usr/sbin/sysctl"],
 306                     [VAR_SYSCTL_BINARY="/usr/sbin/sysctl"])])])
 307 AS_IF([test x"$VAR_SYSCTL_BINARY" != x"false"],
 308       [AC_DEFINE_UNQUOTED([SYSCTL], "$VAR_SYSCTL_BINARY", [Path to sysctl])],
 309       [AC_MSG_WARN(['sysctl' not found.])])
 310
 311 # miniupnpc / upnpc binary is a soft runtime requirement
 312 AC_PATH_TARGET_TOOL(VAR_UPNPC_BINARY, upnpc, false)
 313
 314 AS_IF([test x"$VAR_UPNPC_BINARY" != x"false"],
 315   [AC_DEFINE_UNQUOTED([UPNPC], "$VAR_UPNPC_BINARY", [Path to upnpc binary])],
 316   [AC_MSG_WARN([warning: 'upnpc' binary not found.])])
 317
 318
 319 # uncrustify
 320 # TODO: maybe add flag to pass location
 321 AC_CHECK_PROG(UNCRUSTIFY_BINARY, uncrustify, true)
 322 AM_CONDITIONAL(HAVE_UNCRUSTIFY_BINARY, $UNCRUSTIFY_BINARY)
 323
 324 # yapf
 325 # TODO: less repetition, add flag to pass name
 326 AC_CHECK_PROGS(YAPF_BINARY, [yapf yapf3.0 yapf3.1 yapf3.2 yapf3.3 yapf3.4 yapf3.5 yapf3.6 yapf3.7 yapf3.8 yapf3.9 yapf4.0], false)
 327 AM_CONDITIONAL(HAVE_YAPF_BINARY, test x$YAPF_BINARY != xfalse)
 328
 329
 330 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 331   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 332      [Define if struct tm has the tm_gmtoff member.])],
 333      ,
 334      [#include <time.h>])
 335
 336 # 'save' libs; only those libs found so far will be
 337 # linked against _everywhere_.  For the others, we
 338 # will be more selective!
 339 SAVE_LIBS=$LIBS
 340
 341 have_addrinfo_a=0
 342 AC_CHECK_LIB(anl,
 343              getaddrinfo_a,
 344              [have_addrinfo_a=1 AC_DEFINE(HAVE_GETADDRINFO_A,
 345                                           1,
 346                                           [getaddrinfo_a supported])])
 347 AM_CONDITIONAL(HAVE_GETADDRINFO_A,
 348                [test "$have_addrinfo_a" = 1])
 349
 350 # libgcrypt
 351 gcrypt=0
 352 NEED_LIBGCRYPT_API=1
 353 NEED_LIBGCRYPT_VERSION=1.6.0
 354
 355
 356 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 357 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 358
 359 AS_IF([test $gcrypt = 0],
 360  [
 361   AC_MSG_ERROR([[
 362 ***
 363 *** You need libgcrypt to build this program.
 364 *** This library is for example available at
 365 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/.
 366 *** At least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 367 ***  is required.
 368 ***]])
 369 ])
 370 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 371
 372 AC_CHECK_DECLS([struct in6_ifreq], [], [], [[#include <linux/if_tun.h>]])
 373
 374
 375
 376 # should the build process be building the documentation?
 377 AC_MSG_CHECKING(whether to build documentation)
 378 AC_ARG_ENABLE([documentation],
 379               [AS_HELP_STRING([--disable-documentation],
 380                               [do not build the documentation])],
 381               [documentation=${enableval}],
 382               [documentation=yes])
 383 AC_MSG_RESULT($documentation)
 384 AS_IF([test "x$documentation" = "xyes"],
 385       [AM_CONDITIONAL([DOCUMENTATION],
 386                       true)
 387        AC_DEFINE([DOCUMENTATION],
 388                  [1],
 389                  [Building the documentation])],
 390       [AM_CONDITIONAL([DOCUMENTATION],
 391                       false)
 392        AC_DEFINE([DOCUMENTATION],
 393                  [0],
 394                  [Not building the documentation])])
 395
 396 # COMMENT: Check wether to transpile texinfo to mdoc.
 397 # COMMENT: This is TRUE when --enable-texi2mdoc-generation
 398 # COMMENT: but ERRORS when texi2mdoc binary is missing in your $PATH
 399 # COMMENT: and makes the configure fail if it is missing.
 400 # COMMENT: Consequential the DEFINE and CONDITIONAL are set to true.
 401 # COMMENT: This is FALSE when --disable-texi2mdoc-generation was set
 402 # COMMENT: or nothing was set (this is the default).
 403 # COMMENT: There are 2 nested AS_IFs because we need to catch the
 404 # COMMENT: potential non-existence of the texi2mdoc binary.
 405 # COMMENT: Default return value / setting: no
 406 AC_MSG_CHECKING(wether to include generated texi2mdoc output in installation)
 407 AC_ARG_ENABLE([texi2mdoc-generation],
 408               [AS_HELP_STRING([--enable-texi2mdoc-generation],
 409                               [include generated texi2mdoc output in installation])],
 410               [texi2mdoc_generation=${enableval}],
 411               [texi2mdoc_generation=no])
 412 AC_MSG_RESULT($texi2mdoc_generation)
 413 AS_IF([test "x$texi2mdoc_generation" = "xyes"],
 414       [AS_IF([test "$texi2mdoc" = 0],
 415              [AC_MSG_WARN([ERROR: transpiled mdoc output requires texi2mdoc.])
 416               AC_MSG_WARN([ERROR: texi2mdoc can be obtained via your])
 417               AC_MSG_WARN([ERROR: Operating System package manager or from])
 418               AC_MSG_WARN([ERROR: https://mandoc.bsd.lv/texi2mdoc/])],
 419              [AM_CONDITIONAL([TEXI2MDOC_GENERATION],true)
 420               AC_DEFINE([TEXI2MDOC_GENERATION],
 421                         [1],
 422                         [Building section 7 mdoc output])])],
 423       [AM_CONDITIONAL([TEXI2MDOC_GENERATION],
 424                       false)
 425        AC_DEFINE([TEXI2MDOC_GENERATION],
 426                  [0],
 427                  [Not building section 7 mdoc output])])
 428
 429 # should the build process be building only the documentation?
 430 AC_MSG_CHECKING(whether to build only documentation)
 431 AC_ARG_ENABLE([documentation-only],
 432    [AS_HELP_STRING([--enable-documentation-only],
 433                    [build only the documentation])],
 434    [documentation_only=${enableval}],
 435    [documentation_only=no])
 436 AC_MSG_RESULT($documentation_only)
 437 AS_IF([test "x$documentation_only" = "xyes"],
 438  [
 439   AM_CONDITIONAL([DOCUMENTATION_ONLY],true)
 440   AC_DEFINE([DOCUMENTATION_ONLY],[1],[Building only the documentation])
 441  ],[
 442   AM_CONDITIONAL([DOCUMENTATION_ONLY],false)
 443   AC_DEFINE([DOCUMENTATION_ONLY],[0],[Doing a normal build, more than only documentation])
 444  ])
 445
 446 # should the build process be including the manpages? (default: yes)
 447 AC_MSG_CHECKING(whether to include man pages)
 448 AC_ARG_ENABLE([include-manpages],
 449    [AS_HELP_STRING([--disable-include-manpages],
 450                    [Do not include the man pages in build and installation])],
 451    [include_manpages=${enableval}],
 452    [include_manpages=yes])
 453 AC_MSG_RESULT($include_manpages)
 454 AS_IF([test "x$include_manpages" = "xyes"],
 455  [
 456   AM_CONDITIONAL([INCLUDE_MANPAGES],true)
 457   AC_DEFINE([INCLUDE_MANPAGES],[1],[Including the man pages in the build and installation])
 458  ],[
 459   AM_CONDITIONAL([INCLUDE_MANPAGES],false)
 460   AC_DEFINE([INCLUDE_MANPAGES],[0],[Not including the man pages in the build and installation])
 461  ])
 462
 463 # Do we have texinfo4? If yes, it is used to set texinfo4 specific switches
 464 # (not syntax!) to the commandline tools which generate the html. If not,
 465 # texinfo5 switches are used. This comes with no version checks, is
 466 # enabled only at distributors action (ie defaults to "no").
 467 # Mantis #3914 for more details (https://bugs.gnunet.org/view.php?id=3914)
 468 AC_MSG_CHECKING(whether to enable texinfo4 switches)
 469 AC_ARG_ENABLE([texinfo4],
 470    [AS_HELP_STRING([--enable-texinfo4], [Use texinfo version 4 specific switches])],
 471    [activate_texinfo4=${enableval}],
 472    [activate_texinfo4=no])
 473 AC_MSG_RESULT($activate_texinfo4)
 474 AS_IF([test "x$activate_texinfo4" = "xyes"],
 475  [
 476   AM_CONDITIONAL([ACTIVATE_TEXINFO4],true)
 477   AC_DEFINE([ACTIVATE_TEXINFO4],[1],[Using texinfo version 4 specific switches])
 478  ],[
 479   AM_CONDITIONAL([ACTIVATE_TEXINFO4],false)
 480   AC_DEFINE([INCLUDE_MANPAGES],[0],[Using texinfo version 5 or later switches])
 481  ])
 482
 483
 484 # Adam shostack suggests the following for Windows:
 485 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 486 AC_ARG_ENABLE(gcc-hardening,
 487    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 488 [AS_IF([test x$enableval = xyes],[
 489     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 490     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 491     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 492     LDFLAGS="$LDFLAGS -pie"
 493  ])])
 494
 495 # Linker hardening options
 496 # Currently these options are ELF specific - you can't use this with MacOSX
 497 AC_ARG_ENABLE(linker-hardening,
 498   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 499 [AS_IF([test x$enableval = xyes],
 500    [LDFLAGS="$LDFLAGS -z relro -z now"])])
 501
 502
 503 AC_ARG_ENABLE(sanitizer,
 504   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 505 [AS_IF([test x$enableval = xyes],[
 506    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 507  ])])
 508
 509
 510 extra_logging=GNUNET_NO
 511 AC_ARG_ENABLE([logging],
 512    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 513    [AS_IF([test "x$enableval" = "xyes"], [],
 514           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 515           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 516           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 517    ], [])
 518 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 519
 520 # should memory poisoning be enabled?
 521 AC_MSG_CHECKING(whether to poison freed memory)
 522 AC_ARG_ENABLE([poisoning],
 523    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 524    [enable_poisoning=${enableval}],
 525    [
 526      AS_IF([test "x$extra_logging" != "xGNUNET_NO"],
 527        [enable_poisoning="defaults to yes (extra logging is enabled)"],
 528        [enable_poisoning=no])
 529    ])
 530 AC_MSG_RESULT($enable_poisoning)
 531 AS_IF([test ! "x$enable_poisoning" = "xno"],
 532   [enable_poisoning=1],
 533   [enable_poisoning=0])
 534 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 535
 536 AS_IF([test $build = $target],
 537 [
 538 AC_MSG_CHECKING([for working HMAC])
 539 AC_LANG_PUSH(C)
 540 LIBS="$LIBS $LIBGCRYPT_LIBS"
 541 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 542 AC_RUN_IFELSE(
 543   [AC_LANG_PROGRAM([#include <gcrypt.h>
 544         #include <stdio.h>], [[
 545         gcry_md_hd_t mac;
 546
 547         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 548             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 549             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 550         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 551         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 552             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 553             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 554             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 555             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 556             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 557
 558         if (!gcry_check_version (GCRYPT_VERSION))
 559         {
 560           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 561           return 1;
 562         }
 563
 564         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 565         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 566
 567         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 568         {
 569           fprintf (stderr, "gcry_md_open error\n");
 570           return 2;
 571         }
 572
 573         gcry_md_setkey (mac, key, sizeof (key));
 574         gcry_md_write (mac, data, sizeof (data));
 575
 576         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 577         {
 578           fprintf (stderr, "memcmp error\n");
 579           return 3;
 580         }
 581
 582         gcry_md_close (mac);
 583
 584         return 0;
 585     ]])],
 586   [AC_MSG_RESULT([yes])],
 587   [
 588    RESULT=$?
 589    if test $RESULT = 3
 590    then
 591      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 592    fi
 593    if test $RESULT = 2
 594    then
 595      AC_MSG_FAILURE([HMAC test failed])
 596    fi
 597    if test $RESULT = 1
 598    then
 599      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 600    fi
 601   ],
 602   [AC_MSG_RESULT([cross compiling, test skipped])])
 603 AC_LANG_POP(C)
 604 ])      # $build = $target
 605
 606 # check for bluetooth library
 607 bluetooth=0
 608 CHECK_LIBHEADER(BLUETOOTH, bluetooth, ba2str, bluetooth/bluetooth.h,bluetooth=1,)
 609 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 610 AS_IF([test "$bluetooth" = 1],
 611  [AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])],
 612  [AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])])
 613
 614 # check for zbar library
 615 zbar=0
 616 AC_MSG_CHECKING(for libzbar)
 617 AC_ARG_WITH(zbar,
 618    [  --with-zbar=PREFIX (base of libzbar installation)],
 619    [AC_MSG_RESULT([$with_zbar])
 620     AS_CASE([$with_zbar],
 621       [no],[],
 622       [yes],[CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)],
 623       [
 624         LDFLAGS="-L$with_zbar/lib $LDFLAGS"
 625         CPPFLAGS="-I$with_zbar/include $CPPFLAGS"
 626         AC_CHECK_HEADERS(zbar.h,
 627           AC_CHECK_LIB([zbar], [zbar_processor_create],
 628             EXT_LIB_PATH="-L$with_zbar/lib $EXT_LIB_PATH"
 629             zbar=1))
 630        ])
 631    ],
 632    [AC_MSG_RESULT([--with-zbar not specified])
 633     CHECK_LIBHEADER(ZBAR, zbar, zbar_processor_create, zbar.h,zbar=1,,)])
 634 AM_CONDITIONAL(HAVE_ZBAR, [test "$zbar" = 1])
 635 AS_IF([test "x$zbar" = x1],
 636       [AC_DEFINE([HAVE_ZBAR],[1],[Have zbar library])],
 637       [AC_DEFINE([HAVE_ZBAR],[0],[Lacking zbar library])])
 638
 639 # check for jansson library
 640 jansson=0
 641 AC_MSG_CHECKING(for libjansson)
 642 AC_ARG_WITH(jansson,
 643    [  --with-jansson=PREFIX (base of libjansson installation)],
 644    [AC_MSG_RESULT([$with_jansson])
 645     AS_CASE([$with_jansson],
 646       [no],[],
 647       [yes],[
 648         CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)
 649       ],[
 650         LDFLAGS="-L$with_jansson/lib $LDFLAGS"
 651         CPPFLAGS="-I$with_jansson/include $CPPFLAGS"
 652         AC_CHECK_HEADERS(jansson.h,
 653           AC_CHECK_LIB([jansson], [json_loads],
 654             EXT_LIB_PATH="-L$with_jansson/lib $EXT_LIB_PATH"
 655             jansson=1))
 656       ])
 657    ],
 658    [AC_MSG_RESULT([--with-jansson not specified])
 659     CHECK_LIBHEADER(JANSSON, jansson, json_loads, jansson.h,jansson=1,)])
 660 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 661 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 662 AS_IF([test "x$jansson" = x1],
 663       [AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])],
 664       [AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])])
 665
 666
 667 # check for libpulse(audio) library
 668 pulse=0
 669 libpulse_msg="no"
 670 CHECK_LIBHEADER(LIBPULSE, pulse, pa_stream_peek, pulse/simple.h,pulse=1,)
 671 AS_IF([test "$pulse" = 1],
 672       [AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 673        libpulse_msg="yes"])
 674
 675 # check for libopus(audio) library
 676 opus=0
 677 libopus_msg="no"
 678 CHECK_LIBHEADER(LIBOPUS,
 679                 opus,
 680                 opus_decode_float,
 681                 opus/opus.h,
 682                 AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]))
 683 AS_IF([test "x$opus" = x1],
 684       [AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 685        libopus_msg="yes"])
 686
 687 # libogg
 688 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 689         [AC_CHECK_HEADERS([ogg/ogg.h],
 690           AM_CONDITIONAL(HAVE_OGG, true)
 691           ogg=1
 692           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 693           AM_CONDITIONAL(HAVE_OGG, false)
 694           ogg=0
 695           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 696         AM_CONDITIONAL(HAVE_OGG, false)
 697         ogg=0)
 698
 699
 700 PKG_CHECK_MODULES([GLIB],
 701                   [glib-2.0],
 702   [# check for pbc library
 703   pbc=0
 704    AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 705    AC_CHECK_HEADER([gabe.h],abe=1)
 706    AM_CONDITIONAL(HAVE_PBC, [test "x$pbc" = x1])
 707    AM_CONDITIONAL(HAVE_ABE, [test "x$abe" = x1])
 708    AS_IF([test "x$pbc" = x1],
 709      [AC_DEFINE([HAVE_PBC],[1],[Have pbc library])],
 710      [AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])])
 711    AS_IF([test "x$abe" = x1],
 712     [AC_DEFINE([HAVE_ABE],[1],[Have ABE library])],
 713     [AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])])],
 714   [# glib-2 not found
 715    AM_CONDITIONAL(HAVE_PBC, [false])
 716    AM_CONDITIONAL(HAVE_ABE, [false])
 717    AC_DEFINE([HAVE_PBC],[0],[Lacking glib library])])
 718
 719 gst=0
 720 gstreamer_msg="no"
 721 PKG_CHECK_MODULES(
 722   [GST],
 723   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 724   [gst=1
 725    gstreamer_msg="yes"],
 726   [gst=0])
 727
 728 # Pulse Audio
 729 AS_IF([test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"],[
 730  AS_IF([test "x$gst" != "x1"],[
 731   conversation_backend=none
 732   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 733   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 734   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 735  ],[
 736    conversation_backend=gst
 737    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 738    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 739    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 740  ])
 741 ],[
 742  conversation_backend=pulse
 743  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 744  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 745  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 746 ])
 747
 748 AS_IF([test "x$conversation_backend" = "xnone"],
 749       AM_CONDITIONAL(BUILD_CONVERSATION, false),
 750       AM_CONDITIONAL(BUILD_CONVERSATION, true))
 751
 752 # libgnurl
 753 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 754
 755 SAVE_CPPFLAGS=$CPPFLAGS
 756 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 757 LIBS="$LIBGNURL $LIBCURL $LIBS"
 758
 759 # libcurl-gnutls
 760 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 761 AS_IF([test "x$curl" = xtrue],[
 762  AC_CHECK_HEADER([curl/curl.h],
 763   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 764   [curl=false])
 765  # need libcurl-gnutls.so, everything else is not acceptable
 766  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 767  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 768 ])
 769
 770 # libcurl and libgnurl should be mutually exclusive
 771 AS_IF([test "$gnurl" = 1],
 772       [AM_CONDITIONAL(HAVE_LIBGNURL, true)
 773        AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 774        AM_CONDITIONAL(HAVE_LIBCURL, false)
 775        AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])],
 776       [AS_IF([test "$curl" = true],
 777              [AM_CONDITIONAL(HAVE_LIBGNURL, false)
 778               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 779               AM_CONDITIONAL(HAVE_LIBCURL, true)
 780               AC_DEFINE([HAVE_LIBCURL],[1],[Have libcurl])],
 781              [AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 782               AM_CONDITIONAL(HAVE_LIBGNURL, false)
 783               AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 784               AM_CONDITIONAL(HAVE_LIBCURL, false)
 785               AC_DEFINE([HAVE_LIBCURL],[0],[Lacking libcurl])])])
 786
 787 AC_SEARCH_LIBS(__atomic_load_8, atomic, [have_libatomic=1 AC_DEFINE(HAVE_LIBATOMIC,1,[external libatomic])])
 788 AM_CONDITIONAL(HAVE_LIBATOMIC, [test "$have_libatomic" = 1])
 789
 790 # restore LIBS & CPPFLAGS
 791 LIBS=$SAVE_LIBS
 792 CPPFLAGS=$SAVE_CPPFLAGS
 793
 794 AC_CHECK_HEADERS([glpk.h],[glpk=true],[glpk=false])
 795 # GLPK must support glpk_init_env, version >= 4.43
 796 AC_CHECK_LIB([glpk],[glp_init_env],,[glpk=false])
 797 # GLPK must support atm MLP presolving, version >= 4.32
 798 AC_CHECK_MEMBERS(glp_iocp.presolve,,[glpk=false],[[#include <glpk.h>]])
 799 AS_IF([test "x$glpk" = xfalse],
 800 [
 801         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 802         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 803 ],[
 804         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 805         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 806 ])
 807
 808
 809 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 810 AS_IF([test x$nss = xfalse],
 811   [
 812         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 813         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 814   ],[
 815         NSS_INCLUDES="
 816         #include <nss.h>
 817         "
 818         AC_CHECK_DECL([NSS_STATUS_UNAVAIL],
 819                 [AM_CONDITIONAL(HAVE_GLIBCNSS, true)],
 820                 [AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 821                  AC_MSG_WARN([No nss header fails to define NSS_STATUS_UNAVAIl, will not build NSS plugin])],
 822                 [$NSS_INCLUDES])
 823 ])
 824
 825
 826
 827 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 828 AC_CHECK_LIB([kvm],[kvm_open])
 829 AC_CHECK_LIB([kstat],[kstat_open])
 830
 831
 832 # should the build process be restricted to the code required
 833 # for GNU Taler wallets?
 834 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 835 AC_ARG_ENABLE([taler-wallet],
 836    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 837    [taler_only=${enableval}],
 838    [taler_only=no])
 839 AC_MSG_RESULT($taler_only)
 840 AS_IF([test "x$taler_only" = "xyes"],
 841 [
 842   AM_CONDITIONAL([TALER_ONLY],true)
 843   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 844 ],[
 845   AM_CONDITIONAL([TALER_ONLY],false)
 846   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 847 ])
 848
 849 # test for libextractor
 850 extractor=0
 851 AC_MSG_CHECKING(for libextractor)
 852 AC_ARG_WITH(extractor,
 853    [  --with-extractor=PREFIX (base of libextractor installation)],
 854    [AC_MSG_RESULT([$with_extractor])
 855     AS_CASE([$with_extractor],
 856       [no],[],
 857       [yes],[
 858         AC_CHECK_HEADERS([extractor.h],
 859           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 860             extractor=1))
 861       ],[
 862         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 863         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 864         AC_CHECK_HEADERS([extractor.h],
 865           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 866             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 867             extractor=1))
 868       ])
 869    ],
 870    [AC_MSG_RESULT([--with-extractor not specified])
 871     AC_CHECK_HEADERS([extractor.h],
 872      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 873       extractor=1))])
 874 # restore LIBS
 875 LIBS=$SAVE_LIBS
 876
 877 AS_IF([test "$extractor" != 1],
 878  [
 879  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 880  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 881  ],[
 882  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 883  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 884  ])
 885
 886
 887 AS_IF([test "$taler_only" != yes],[
 888
 889
 890 # Check for libltdl header (#2999)
 891 ltdl=0
 892 AC_MSG_CHECKING(for libltdl)
 893 AC_ARG_WITH(ltdl,
 894    [AS_HELP_STRING([--with-ltdl=PREFIX],[base of libltdl installation])],
 895    [AC_MSG_RESULT([$with_ltdl])
 896     AS_CASE([$with_ltdl],
 897       [no],[],
 898       [yes],[
 899         AC_CHECK_HEADERS(ltdl.h,
 900           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 901             ltdl=1))
 902       ],[
 903         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 904         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 905         AC_CHECK_HEADERS(ltdl.h,
 906           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 907             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 908             ltdl=1))
 909       ])
 910    ],
 911    [AC_MSG_RESULT([--with-ltdl not specified])
 912     AC_CHECK_HEADERS(ltdl.h,
 913      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 914       ltdl=1))])
 915 AS_IF([test x$ltdl = x1],
 916 [
 917  AC_MSG_RESULT([libltdl found])
 918 ],[
 919  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 920 ])
 921 # restore LIBS
 922 LIBS=$SAVE_LIBS
 923
 924 # libidn and libidn2. The ideal goal is this:
 925 # check for libidn2, if it doesn't exist check for libidn
 926 # if both exist, prefer libidn2
 927 # if none exist, fail and message that libidn or libidn2
 928 # is required with a preference for libidn2.
 929 # TODO: What we have right here can probably be improved.
 930 my_with_libidn=1
 931 AC_ARG_WITH(libidn,
 932             AS_HELP_STRING([--with-libidn=pathname],
 933                            [Support IDN (needs libidn)]),
 934             [],
 935             [withval="yes"])
 936 AS_IF([test x_$withval = x_yes],
 937       [AC_CHECK_HEADERS([idna.h],
 938           AC_MSG_NOTICE([Found idna.h]),
 939           AC_CHECK_HEADERS([idn/idna.h],
 940                AC_MSG_NOTICE([Found idn/idna.h]),
 941                my_with_libidn=0))],
 942       [AS_IF([test x_$withval != x_no],
 943              [CFLAGS="$CFLAGS -I$withval/include"
 944               LDFLAGS="$LDFLAGS -L$withval/lib"
 945               AC_CHECK_HEADERS([idna.h],
 946                 AC_MSG_NOTICE([Found idna.h]),
 947                 [AC_MSG_NOTICE([Failed to find idna.h])
 948                  my_with_libidn=0])],
 949              [my_with_libidn=0])])
 950
 951 my_with_libidn2=1
 952 AC_ARG_WITH(libidn2,
 953             AS_HELP_STRING([--with-libidn2=pathname],
 954                            [Support IDN (needs libidn2)]),
 955             [],
 956             [withval="yes"])
 957 AS_IF([test x_$withval = x_yes],
 958       [AC_CHECK_HEADERS([idn2.h],
 959        AC_MSG_NOTICE([Found idn2.h]),
 960        AC_CHECK_HEADERS([idn2/idn2.h],
 961           AC_MSG_NOTICE([Found idn2/idn2.h]),
 962           [AC_MSG_NOTICE([Failed to find idn2.h])
 963            my_with_libidn2=0]))],
 964       [AS_IF([test x_$withval != x_no],
 965              [CFLAGS="$CFLAGS -I$withval/include"
 966               LDFLAGS="$LDFLAGS -L$withval/lib"],
 967              [my_with_libidn2=0])])
 968
 969 AC_MSG_CHECKING([if libidn can be used])
 970 # Check for LIBIDNs
 971 there_can_only_be_one=1
 972
 973 working_libidn1=0
 974 working_libidn2=0
 975 AS_IF([test x$my_with_libidn2 = x1],
 976       [AC_MSG_NOTICE([Checking for libidn2])
 977        AC_CHECK_LIB([idn2],
 978                     [idn2_to_unicode_8z8z],
 979                     [working_libidn2=1
 980                     LIBS="-lidn2 $LIBS"
 981                     AC_DEFINE_UNQUOTED([HAVE_LIBIDN2],
 982                                        [1],
 983                                        [Define to 1 if you have 'libidn2' (-lidn2).])],
 984                     [MISSING_DEPS="${MISSING_DEPS}${MISSING_SEP}libidn2"
 985                      MISSING_SEP=", "])])
 986 AM_CONDITIONAL(HAVE_LIBIDN2,
 987                test x$working_libidn2 = x1)
 988 AS_IF([test x$working_libidn2 = x0],
 989       [AS_IF([test x$my_with_libidn = x1],
 990              [AC_MSG_NOTICE([Checking for libidn])
 991               AC_CHECK_LIB([idn],
 992                            [idna_to_ascii_8z],
 993                            [working_libidn1=1
 994                            LIBS="-lidn $LIBS"
 995                            AC_DEFINE_UNQUOTED([HAVE_LIBIDN],
 996                                               [1],
 997                                               [Define to 1 if you have 'libidn' (-lidn).])],
 998                            [there_can_only_be_one=0])],
 999              [AS_IF([test x$my_with_libidn2 = x1],
1000                     [there_can_only_be_one=0
1001                      AC_MSG_FAILURE([* There can only be one libidn.
1002                                      * Provide either libidn >= 1.13
1003                                      * or
1004                                      * libidn2 to the configure
1005                                      * script via
1006                                      * --with-libidn2
1007                                      * --with-libidn])])])])
1008 AM_CONDITIONAL(HAVE_LIBIDN, test x$working_libidn1 = x1)
1009
1010 AS_IF([test "$working_libidn1" = 0 -a "$working_libidn2" = 0],
1011       [AC_MSG_ERROR([GNUnet requires libidn (or libidn2)])])
1012
1013 AS_IF([test x$there_can_only_be_one = x0],
1014       [AC_MSG_FAILURE([Missing dependencies: $MISSING_DEPS])])
1015
1016 # test for zlib
1017 SAVE_LDFLAGS=$LDFLAGS
1018 SAVE_CPPFLAGS=$CPPFLAGS
1019 AC_ARG_WITH(zlib,
1020             [  --with-zlib[[=DIR]]       use libz in DIR],
1021             [AS_IF([test "$withval" = "no"],
1022                    [AC_MSG_ERROR([GNUnet requires zlib])],
1023                    [test "$withval" != "yes"],
1024                    [Z_DIR=$withval
1025                     CPPFLAGS="${CPPFLAGS} -I$withval/include"
1026                     LDFLAGS="${LDFLAGS} -L$withval/lib"])])
1027 AC_CHECK_HEADER(zlib.h,
1028                 [],
1029                 [AC_MSG_ERROR([GNUnet requires zlib])])
1030 AC_CHECK_LIB(z,
1031              compress2,
1032              [AC_DEFINE([HAVE_ZLIB],
1033                         [],
1034                         [Have compression library])
1035               if test "x${Z_DIR}" != "x"; then
1036                       Z_CFLAGS="-I${Z_DIR}/include"
1037                       Z_LIBS="-L${Z_DIR}/lib -lz"
1038               else
1039                       Z_LIBS="-lz"
1040               fi],
1041               [AC_MSG_ERROR([GNUnet requires zlib])])
1042 AC_SUBST(Z_CFLAGS)
1043 AC_SUBST(Z_LIBS)
1044
1045 AS_IF([test "$enable_shared" = "no"],
1046       [AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])])
1047
1048
1049 # restore LIBS
1050 LIBS=$SAVE_LIBS
1051
1052
1053 # end of taler-only being false
1054 ])
1055
1056
1057 # check for iconv
1058 AM_ICONV
1059
1060 # test for libunistring
1061 gl_LIBUNISTRING
1062 AS_IF([test $HAVE_LIBUNISTRING != yes],
1063       [AC_MSG_ERROR([GNUnet requires libunistring])])
1064
1065 # under emscripten, $gl_libunistring_hexversion is undefined
1066 if test "$taler_only" != yes; then
1067
1068 AS_IF([test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305],
1069       [AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])])
1070 fi
1071 AC_CHECK_HEADERS([unistr.h],
1072                  ,
1073                  AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
1074
1075 # restore LIBS
1076 LIBS=$SAVE_LIBS
1077
1078
1079
1080 # Checks for standard header files.
1081 AC_HEADER_DIRENT
1082 AC_HEADER_STDC
1083
1084 # Check for headers that are ALWAYS required
1085 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files: fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h]))
1086
1087
1088
1089 # Checks for headers that are only required on some systems or
1090 # opional (and where we do NOT abort if they are not there)
1091 AC_CHECK_HEADERS([stdatomic.h malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
1092
1093 # FreeBSD requires this for netinet/in_systm.h and netinet/ip.h
1094 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
1095 [#ifdef HAVE_SYS_TYPES_H
1096 #include <sys/types.h>
1097 #endif
1098 #ifdef HAVE_NETINET_IN_SYSTM_H
1099 #include <netinet/in_systm.h>
1100 #endif
1101 #ifdef HAVE_NETINET_IN_H
1102 #include <netinet/in.h>
1103 #endif
1104 ])
1105
1106 SAVE_LDFLAGS=$LDFLAGS
1107 SAVE_CPPFLAGS=$CPPFLAGS
1108
1109 # test for sqlite
1110 sqlite=false
1111 AC_MSG_CHECKING(for SQLite)
1112 AC_ARG_WITH(sqlite,
1113   [  --with-sqlite=PFX       base of SQLite installation],
1114   [AC_MSG_RESULT("$with_sqlite")
1115    AS_CASE([$with_sqlite],
1116      [no],[],
1117      [yes],[
1118       AC_CHECK_HEADERS(sqlite3.h,
1119       sqlite=true)],
1120      [
1121     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
1122     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
1123     AC_CHECK_HEADERS(sqlite3.h,
1124      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
1125      SQLITE_LDFLAGS="-L$with_sqlite/lib"
1126      SQLITE_CPPFLAGS="-I$with_sqlite/include"
1127      sqlite=true)
1128     LDFLAGS=$SAVE_LDFLAGS
1129     CPPFLAGS=$SAVE_CPPFLAGS
1130     ])
1131   ],
1132   [AC_MSG_RESULT([--with-sqlite not specified])
1133     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
1134 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
1135 AC_SUBST(SQLITE_CPPFLAGS)
1136 AC_SUBST(SQLITE_LDFLAGS)
1137
1138 LDFLAGS=$SAVE_LDFLAGS
1139 CPPFLAGS=$SAVE_CPPFLAGS
1140
1141 # test for postgres
1142 postgres=false
1143 # even running the check for postgres breaks emscripten ...
1144 AS_IF([test "$taler_only" != yes],
1145       [AX_LIB_POSTGRESQL([9.5],
1146         [CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
1147          AC_CHECK_HEADERS([libpq-fe.h],
1148          postgres=true)
1149         ],
1150         [AC_MSG_RESULT([no postgres])])])
1151 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
1152
1153
1154 LDFLAGS=$SAVE_LDFLAGS
1155 CPPFLAGS=$SAVE_CPPFLAGS
1156
1157 # mysql & windows
1158 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
1159 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
1160
1161 # test for mysql
1162 mysql=false
1163 mysqlfail=false
1164 SAVE_LDFLAGS=$LDFLAGS
1165 SAVE_CPPFLAGS=$CPPFLAGS
1166 AC_MSG_CHECKING(for mysql)
1167 AC_ARG_WITH(mysql,
1168   [  --with-mysql=PFX        base of MySQL installation],
1169   [AC_MSG_RESULT([$with_mysql])
1170    AS_CASE([$with_mysql],
1171      [no],[],
1172      [yes|""],[
1173       AC_CHECK_HEADERS(mysql/mysql.h,
1174        AC_CHECK_LIB(mysqlclient, mysql_init,
1175        mysql=true), [], [])
1176      ],[
1177       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
1178       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
1179       AC_CHECK_HEADERS(mysql/mysql.h,
1180        AC_CHECK_LIB(mysqlclient, mysql_init,
1181         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
1182         MYSQL_CPPFLAGS="-I$with_mysql/include"
1183
1184         mysql=true), [], [])
1185      ])
1186   ],
1187   [AC_MSG_RESULT([--with-mysql not specified])
1188    if test -d "/usr/lib64/mysql"; then
1189     MYSQL_LIBDIR="/usr/lib64/mysql"
1190    elif test -d "/usr/lib/mysql"; then
1191     MYSQL_LIBDIR="/usr/lib/mysql"
1192    else
1193     MYSQL_LIBDIR="/usr/lib"
1194    fi
1195    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
1196    AC_CHECK_LIB(mysqlclient, mysql_init,
1197     [AC_CHECK_HEADERS(mysql/mysql.h,
1198       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
1199       mysql=true
1200
1201      , [], [])])
1202   ])
1203
1204 AC_SUBST(MYSQL_LDFLAGS)
1205 AC_SUBST(MYSQL_CPPFLAGS)
1206
1207 # additional version check for mysql
1208 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
1209 AS_IF([test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"],
1210  [
1211   AC_MSG_CHECKING(mysql version)
1212   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1213     [[
1214       #include <mysql/mysql.h>]],
1215     [[
1216       #if (MYSQL_VERSION_ID < 40100)
1217       #error needs at least version >= 4.1
1218       #endif
1219       int main () { return 0; }
1220     ]])
1221     ],mysql=true,mysql=false)
1222   AS_IF([test "$mysql" = "false"],
1223    [
1224     mysqlfail=true
1225     AC_MSG_RESULT([fail, >= 4.1 required])
1226    ],[
1227     AC_MSG_RESULT(ok)
1228    ])
1229 ])
1230 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
1231 AM_CONDITIONAL(HAVE_MYSQLE, false)
1232 # restore LIBS
1233 LIBS=$SAVE_LIBS
1234 LDFLAGS=$SAVE_LDFLAGS
1235 CPPFLAGS=$SAVE_CPPFLAGS
1236
1237 AS_IF([test "$sqlite" = 0 -a "$mysql" = 0],
1238 [
1239  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
1240 ])
1241
1242 # libmicrohttpd
1243 lmhd=0
1244 m4_define([MHD_MODULE], [libmicrohttpd >= 0.9.63])
1245 AC_ARG_WITH(microhttpd,
1246    [AS_HELP_STRING([--with-microhttpd[[=PFX]]],
1247        [base of libmicrohttpd installation])],
1248    [],
1249    [with_microhttpd=check])
1250 AS_CASE([$with_microhttpd],
1251    [no], [],
1252    [yes], [PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])],
1253    [check], [PKG_CHECK_MODULES([MHD], [MHD_MODULE],
1254        [lmhd=1],
1255        [AC_MSG_WARN([Building without libmicrohttpd])])],
1256    [SAVE_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
1257     PKG_CONFIG_PATH=$with_microhttpd/lib/pkgconfig
1258     export PKG_CONFIG_PATH
1259     PKG_CHECK_MODULES([MHD], [MHD_MODULE], [lmhd=1])
1260     PKG_CONFIG_PATH=$SAVE_PKG_CONFIG_PATH])
1261 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1262 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1263
1264 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1265
1266 # restore LIBS
1267 LIBS=$SAVE_LIBS
1268
1269 # check for gettext
1270 AM_GNU_GETTEXT([external])
1271 AM_GNU_GETTEXT_VERSION([0.18.1])
1272
1273 # Checks for standard typedefs, structures, and compiler characteristics.
1274 AC_TYPE_PID_T
1275 AC_TYPE_SIZE_T
1276 AC_TYPE_MODE_T
1277 AC_HEADER_TIME
1278 AC_HEADER_STAT
1279 AC_HEADER_STDBOOL
1280 AC_STRUCT_TM
1281
1282 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1283    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1284    ],
1285    [],
1286    [
1287       #include <sys/types.h>
1288       #include <sys/socket.h>
1289       #include <netinet/in.h>
1290    ])
1291
1292 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1293                 [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN,
1294                             1,
1295                             [Do we have sockaddr_un.sun_len?])],
1296                 [],
1297                 [
1298                 #include <sys/types.h>
1299                 #include <sys/socket.h>
1300                 #include <sys/un.h>
1301                 ])
1302
1303
1304
1305 # Checks for library functions.
1306 AC_FUNC_CLOSEDIR_VOID
1307 AC_FUNC_FORK
1308 AC_PROG_GCC_TRADITIONAL
1309 AC_FUNC_MEMCMP
1310 AC_FUNC_SELECT_ARGTYPES
1311 AC_FUNC_CHOWN
1312
1313 AC_TYPE_SIGNAL
1314 AC_FUNC_STAT
1315 AC_FUNC_STRFTIME
1316 AC_FUNC_VPRINTF
1317 AC_HEADER_SYS_WAIT
1318 AC_TYPE_OFF_T
1319 AC_TYPE_UID_T
1320 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1321
1322 # restore LIBS
1323 LIBS=$SAVE_LIBS
1324
1325 GN_INTLINCL=""
1326 GN_LIBINTL="$LTLIBINTL"
1327 AC_ARG_ENABLE(framework,
1328               [AS_HELP_STRING([--enable-framework],[enable Mac OS X framework build helpers])],
1329               enable_framework_build=$enableval)
1330 AM_CONDITIONAL(WANT_FRAMEWORK,
1331                test x$enable_framework_build = xyes)
1332 AS_IF([test x$enable_framework_build = xyes],
1333       [AC_DEFINE([FRAMEWORK_BUILD],
1334                  1,
1335                  [Build a Mac OS X Framework])
1336       GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1337       GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1338       AC_LIB_APPENDTOVAR([CPPFLAGS],
1339                          [$GN_INTLINCL])])
1340
1341 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1342 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1343
1344 AC_SUBST(GN_LIB_LDFLAGS)
1345 AC_SUBST(GN_PLUGIN_LDFLAGS)
1346 AC_SUBST(GN_INTLINCL)
1347 AC_SUBST(GN_LIBINTL)
1348
1349 AC_SUBST(CPPFLAGS)
1350 AC_SUBST(LIBS)
1351 AC_SUBST(LDFLAGS)
1352 AC_SUBST(EXT_LIB_PATH)
1353 AC_SUBST(EXT_LIBS)
1354
1355 AC_SUBST(LIBPREFIX)
1356 AC_SUBST(DLLDIR)
1357 AC_SUBST(EXT_LIB_PATH)
1358
1359 DATAROOTDIR=$datarootdir
1360 AC_SUBST(DATAROOTDIR)
1361
1362 # test for sudo
1363 AC_MSG_CHECKING(for sudo)
1364 #AC_CHECK_PROGS(SUDO_BINARY, [sudo], false)
1365 #AM_CONDITIONAL(HAVE_SUDO, test x$SUDO_BINARY != xfalse)
1366 AC_ARG_WITH(sudo,
1367            [  --with-sudo=PATH       path to sudo binary (or just yes)],
1368            [AC_MSG_RESULT("$with_sudo")
1369             AS_CASE([$with_sudo],
1370                     [no],[SUDO_BINARY=],
1371                     [yes],[SUDO_BINARY=sudo],
1372                     [SUDO_BINARY=$with_sudo])],
1373            [AC_MSG_RESULT([no])])
1374 AC_SUBST(SUDO_BINARY)
1375 AM_CONDITIONAL([HAVE_SUDO],
1376               [test "x$SUDO_BINARY" != "x" -o -w /])
1377
1378 # test for doas
1379 AC_MSG_CHECKING(for doas)
1380 AC_CHECK_PROGS(DOAS_BINARY, [doas], false)
1381 AM_CONDITIONAL(HAVE_DOAS_BINARY, test x$DOAS_BINARY != xfalse)
1382
1383 # test for gnunetdns group name
1384 GNUNETDNS_GROUP=gnunetdns
1385 AC_MSG_CHECKING(for gnunetdns group name)
1386 AC_ARG_WITH(gnunetdns,
1387             [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1388             [AC_MSG_RESULT("$with_gnunetdns")
1389              AS_CASE([$with_gnunetdns],
1390                      [no],[GNUNETDNS_GROUP=gnunet],
1391                      [yes],[GNUNETDNS_GROUP=gnunetdns],
1392                      [GNUNETDNS_GROUP=$with_gnunetdns])],
1393             [AC_MSG_RESULT([gnunetdns])])
1394 AC_SUBST(GNUNETDNS_GROUP)
1395
1396
1397
1398 # gnutls
1399 gnutls=0
1400 gnutls_dane=0
1401 AC_MSG_CHECKING(for gnutls)
1402 AC_ARG_WITH(gnutls,
1403             [  --with-gnutls=PFX   base of gnutls installation],
1404             [AC_MSG_RESULT([$with_gnutls])
1405              AS_CASE([$with_gnutls],
1406                      [no],[],
1407                      [yes],
1408                      [AC_CHECK_HEADERS([gnutls/abstract.h],
1409                                        AC_CHECK_LIB([gnutls],
1410                                                     [gnutls_priority_set],
1411                                                     gnutls=true))
1412                       AC_CHECK_HEADERS([gnutls/dane.h],
1413                                        AC_CHECK_LIB([gnutls-dane],
1414                                                     [dane_verify_crt_raw],
1415                                                     gnutls_dane=1))],
1416
1417         [LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1418         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1419         AC_CHECK_HEADERS([gnutls/abstract.h],
1420             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1421               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1422               gnutls=true))
1423         AC_CHECK_HEADERS([gnutls/dane.h],
1424             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1425               gnutls_dane=1))
1426       ])
1427    ],
1428    [AC_MSG_RESULT([--with-gnutls not specified])
1429     AC_CHECK_HEADERS([gnutls/abstract.h],
1430         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1431           gnutls=true))
1432     AC_CHECK_HEADERS([gnutls/dane.h],
1433         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1434                      gnutls_dane=1))
1435    ])
1436 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1437 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1438 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1439 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1440
1441
1442
1443 # Test if we are building for superMUC
1444 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1445 AC_ARG_ENABLE([supermuc],
1446     [AS_HELP_STRING([--enable-supermuc],
1447        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1448     [AS_IF([test "x$enable_supermuc" = "xno"],
1449       [supermuc=0],
1450       [supermuc=1])],
1451     [supermuc=0
1452      enable_supermuc=no])
1453 AC_MSG_RESULT($enable_SUPERMUC)
1454 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1455 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1456
1457 # Check if NSE has to send timestamp information to testbed logger for
1458 # generating histogram of messages received
1459 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1460 AC_ARG_ENABLE([nse-histogram],
1461     [AS_HELP_STRING([--enable-nse-histogram],
1462        [have NSE send timestamp information to testbed logger for generating
1463        histogram of received messages.  NOT useful for production (default is
1464        NO)])],
1465     [AS_IF([test "x$enableval" = "xno"],
1466       [nse_histogram=0],
1467       [nse_histogram=1])],
1468     [nse_histogram=0
1469      enable_nse_histogram=no])
1470 AC_MSG_RESULT($enable_nse_histogram)
1471 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1472 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1473                    [have NSE send timestamp information to testbed logger])
1474
1475 # should 'make check' run tests?
1476 AC_MSG_CHECKING(whether to run tests)
1477 AC_ARG_ENABLE([testruns],
1478    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1479    [enable_tests_run=${enableval}],
1480    [enable_tests_run=yes])
1481 AC_MSG_RESULT($enable_test_run)
1482 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1483
1484
1485 AC_MSG_CHECKING([whether to compile in benchmarks (currently for http and crypto)])
1486 AC_ARG_ENABLE([benchmark],
1487    [AS_HELP_STRING([--enable-benchmark], [enable benchmarking])],
1488    [enable_benchmark=${enableval}],
1489    [enable_benchmark=no])
1490 AC_MSG_RESULT($enable_benchmark)
1491 AS_IF([test "x$enable_benchmark" = "xyes"],
1492       [AC_DEFINE_UNQUOTED(ENABLE_BENCHMARK,1,[Benchmarks are enabled])])
1493 AM_CONDITIONAL([ENABLE_BENCHMARK], [test "x$enable_benchmark" = "xyes"])
1494
1495
1496 # should expensive tests be run?
1497 AC_MSG_CHECKING(whether to run expensive tests)
1498 AC_ARG_ENABLE([expensivetests],
1499    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1500    [enable_expensive=${enableval}],
1501    [enable_expensive=no])
1502 AC_MSG_RESULT($enable_expensive)
1503 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1504
1505 # should ports be open for Java services?
1506 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1507 AC_ARG_ENABLE([javaports],
1508    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1509    [enable_java_ports=${enableval}],
1510    [enable_java_ports=no])
1511 AC_MSG_RESULT($enable_java_ports)
1512 AS_IF([test "x$enable_java_ports" = "xyes"],
1513  [JAVAPORT=""],
1514  [JAVAPORT="$UNIXONLY"])
1515 AC_SUBST(JAVAPORT)
1516
1517 # should benchmarks be run?
1518 AC_MSG_CHECKING(whether to run benchmarks during make check)
1519 AC_ARG_ENABLE([benchmarks],
1520    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1521    [enable_benchmarks=${enableval}],
1522    [enable_benchmarks=no])
1523 AC_MSG_RESULT($enable_benchmarks)
1524 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1525
1526 # should gnunet-testing be compiled
1527 AC_MSG_CHECKING(wether to compile gnunet-testing)
1528 AC_ARG_ENABLE([testing],
1529    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1530    [enable_testing=${enableval}],
1531    [enable_testing=yes])
1532 AC_MSG_RESULT($enable_testing)
1533 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1534
1535 # should experimental code be compiled (code that may not yet compile)?
1536 AC_MSG_CHECKING(whether to compile experimental code)
1537 AC_ARG_ENABLE([experimental],
1538    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1539    [enable_experimental=${enableval}],
1540    [enable_experimental=no])
1541 AC_MSG_RESULT($enable_experimental)
1542 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1543
1544 # should malicious code be compiled (should only be used for testing)?
1545 AC_MSG_CHECKING(whether to compile malicious code)
1546 AC_ARG_ENABLE([malicious],
1547    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1548    [AS_IF([test "x$enableval" = "xno"],
1549      [malicious=0],
1550      [malicious=1])],
1551    [malicious=0
1552     enable_malicious=no])
1553 AC_MSG_RESULT($enable_malicious)
1554 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1555 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1556                    [enable compilation of malicious code])
1557
1558 # should services be started on demand when needed?
1559 # Some services may choose to never start by default
1560 # and it is up to the service/module developer to decide
1561 # by having "START_ON_DEMAND = NO" instead of
1562 # "START_ON_DEMAND = @START_ON_DEMAND@"
1563 # in the service/module's conf.in file.
1564 # See also IMMEDIATE_START for an unconditional immediate start.
1565 START_ON_DEMAND="YES"
1566 AC_MSG_CHECKING(whether to start peer's services on demand by default)
1567 AC_ARG_ENABLE([autostart],
1568    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1569    [enable_autostart=${enableval}
1570     AS_IF([test "x$enable_autostart" = "xno"],
1571       [START_ON_DEMAND="NO"])
1572    ],
1573    [enable_autostart=yes])
1574 AC_MSG_RESULT($enable_autostart)
1575 #AM_CONDITIONAL([HAVE_START_ON_DEMAND], [test "x$enable_autostart" = "xyes"])
1576 AC_SUBST(START_ON_DEMAND)
1577
1578 # should memory statistics be kept (very expensive CPU-wise!)
1579 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1580 AC_ARG_ENABLE([heapstats],
1581    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1582    [enable_heapstats=1],
1583    [enable_heapstats=0])
1584 AC_MSG_RESULT($enable_heapstats)
1585 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1586
1587
1588 # Check if the __thread storage class for
1589 # thread-local storage is available.
1590 AC_MSG_CHECKING(whether __thread is supported)
1591 AC_LINK_IFELSE(
1592 [AC_LANG_PROGRAM([#include <stdlib.h>
1593                    #undef __thread
1594                    static __thread int a = 1;],
1595                   [exit(a-1);])],
1596  [have_thread_local_gcc=1],[have_thread_local_gcc=0])
1597 AC_DEFINE_UNQUOTED([HAVE_THREAD_LOCAL_GCC],$have_thread_local_gcc,[Define this if __thread is supported])
1598 AS_IF([test "x$have_thread_local_gcc" = "x1"],
1599       [AC_MSG_RESULT(yes)],
1600       [AC_MSG_RESULT(no)])
1601
1602 # gcov compilation
1603 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1604 AC_ARG_ENABLE([coverage],
1605               AS_HELP_STRING([--enable-coverage],
1606                              [compile the library with code coverage support]),
1607               [use_gcov=${enableval}],
1608               [use_gcov=no])
1609 AC_MSG_RESULT($use_gcov)
1610 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1611
1612
1613 # version info
1614 # TODO: git blame says this predates our switch to git.
1615 # git-svn should be adjusted to simply git, or
1616 # an external script that does the job.
1617 AC_PATH_PROG(svnversioncommand, svnversion)
1618 AC_PATH_PROG(gitcommand, git)
1619 AC_MSG_CHECKING(for source being under a VCS)
1620
1621
1622 # version info
1623 AC_PATH_PROG(gitcommand, git)
1624 AC_MSG_CHECKING(for source being under a VCS)
1625 git_version=
1626 AS_IF([test ! "X$gitcommand" = "X"],
1627 [
1628   git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
1629 ])
1630 AS_IF([test "X$git_version" = "X"],
1631   [
1632     vcs_name="no"
1633     vcs_version="\"release\""
1634   ],
1635   [
1636     vcs_name="yes, git-svn"
1637     vcs_version="\"git-$git_version\""
1638   ])
1639 AC_MSG_RESULT($vcs_name)
1640
1641 AC_MSG_CHECKING(VCS version)
1642 AC_MSG_RESULT($vcs_version)
1643 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1644
1645 AC_CONFIG_FILES([
1646 Makefile
1647 contrib/Makefile
1648 contrib/hellos/Makefile
1649 contrib/services/Makefile
1650 contrib/services/openrc/Makefile
1651 contrib/services/systemd/Makefile
1652 contrib/scripts/Makefile
1653 contrib/scripts/gnunet-logread/Makefile
1654 doc/Makefile
1655 doc/man/Makefile
1656 doc/doxygen/Makefile
1657 doc/handbook/Makefile
1658 doc/tutorial/Makefile
1659 lint/Makefile
1660 m4/Makefile
1661 po/Makefile.in
1662 src/Makefile
1663 src/arm/Makefile
1664 src/arm/arm.conf
1665 src/ats/Makefile
1666 src/ats/ats.conf
1667 src/ats-tool/Makefile
1668 src/ats-tests/Makefile
1669 src/auction/Makefile
1670 src/block/Makefile
1671 src/cadet/Makefile
1672 src/cadet/cadet.conf
1673 src/core/Makefile
1674 src/core/core.conf
1675 src/consensus/Makefile
1676 src/consensus/consensus.conf
1677 src/conversation/Makefile
1678 src/conversation/conversation.conf
1679 src/curl/Makefile
1680 src/datacache/Makefile
1681 src/datastore/Makefile
1682 src/datastore/datastore.conf
1683 src/dht/Makefile
1684 src/dht/dht.conf
1685 src/dns/Makefile
1686 src/dns/dns.conf
1687 src/exit/Makefile
1688 src/fragmentation/Makefile
1689 src/fs/Makefile
1690 src/fs/fs.conf
1691 src/gns/Makefile
1692 src/gns/gns.conf
1693 src/gns/nss/Makefile
1694 src/gnsrecord/Makefile
1695 src/hello/Makefile
1696 src/identity/Makefile
1697 src/identity/identity.conf
1698 src/abd/Makefile
1699 src/abd/abd.conf
1700 src/include/Makefile
1701 src/integration-tests/Makefile
1702 src/json/Makefile
1703 src/hostlist/Makefile
1704 src/my/Makefile
1705 src/mysql/Makefile
1706 src/namecache/Makefile
1707 src/namecache/namecache.conf
1708 src/namestore/Makefile
1709 src/namestore/namestore.conf
1710 src/nat/Makefile
1711 src/nat/nat.conf
1712 src/nat-auto/Makefile
1713 src/nat-auto/nat-auto.conf
1714 src/nse/Makefile
1715 src/nse/nse.conf
1716 src/nt/Makefile
1717 src/peerinfo/Makefile
1718 src/peerinfo/peerinfo.conf
1719 src/peerinfo-tool/Makefile
1720 src/peerstore/Makefile
1721 src/peerstore/peerstore.conf
1722 src/pq/Makefile
1723 src/pt/Makefile
1724 src/regex/Makefile
1725 src/regex/regex.conf
1726 src/revocation/Makefile
1727 src/revocation/revocation.conf
1728 src/rps/Makefile
1729 src/rps/rps.conf
1730 src/secretsharing/Makefile
1731 src/secretsharing/secretsharing.conf
1732 src/scalarproduct/Makefile
1733 src/scalarproduct/scalarproduct.conf
1734 src/set/Makefile
1735 src/set/set.conf
1736 src/sq/Makefile
1737 src/statistics/Makefile
1738 src/statistics/statistics.conf
1739 src/template/Makefile
1740 src/testbed/Makefile
1741 src/testbed/testbed.conf
1742 src/testbed-logger/Makefile
1743 src/testbed-logger/testbed-logger.conf
1744 src/testing/Makefile
1745 src/topology/Makefile
1746 src/transport/Makefile
1747 src/transport/transport.conf
1748 src/util/Makefile
1749 src/util/resolver.conf
1750 src/vpn/Makefile
1751 src/vpn/vpn.conf
1752 src/zonemaster/Makefile
1753 src/zonemaster/zonemaster.conf
1754 src/rest/Makefile
1755 src/abe/Makefile
1756 src/reclaim-attribute/Makefile
1757 src/reclaim/Makefile
1758 pkgconfig/Makefile
1759 pkgconfig/gnunetarm.pc
1760 pkgconfig/gnunetats.pc
1761 pkgconfig/gnunetblock.pc
1762 pkgconfig/gnunetcadet.pc
1763 pkgconfig/gnunetconsensus.pc
1764 pkgconfig/gnunetconversation.pc
1765 pkgconfig/gnunetcore.pc
1766 pkgconfig/gnunetdatacache.pc
1767 pkgconfig/gnunetdatastore.pc
1768 pkgconfig/gnunetdht.pc
1769 pkgconfig/gnunetdns.pc
1770 pkgconfig/gnunetenv.pc
1771 pkgconfig/gnunetfragmentation.pc
1772 pkgconfig/gnunetfs.pc
1773 pkgconfig/gnunetgns.pc
1774 pkgconfig/gnunethello.pc
1775 pkgconfig/gnunetidentity.pc
1776 pkgconfig/gnunetmicrophone.pc
1777 pkgconfig/gnunetmysql.pc
1778 pkgconfig/gnunetnamestore.pc
1779 pkgconfig/gnunetnat.pc
1780 pkgconfig/gnunetnse.pc
1781 pkgconfig/gnunetpeerinfo.pc
1782 pkgconfig/gnunetpq.pc
1783 pkgconfig/gnunetregex.pc
1784 pkgconfig/gnunetrevocation.pc
1785 pkgconfig/gnunetrps.pc
1786 pkgconfig/gnunetscalarproduct.pc
1787 pkgconfig/gnunetset.pc
1788 pkgconfig/gnunetspeaker.pc
1789 pkgconfig/gnunetstatistics.pc
1790 pkgconfig/gnunettestbed.pc
1791 pkgconfig/gnunettesting.pc
1792 pkgconfig/gnunettransport.pc
1793 pkgconfig/gnunetutil.pc
1794 pkgconfig/gnunetvpn.pc
1795 ])
1796 AC_OUTPUT
1797
1798
1799 # FIXME: `some modules' -> be more specific which exact modules.
1800
1801 # java ports
1802 AS_IF([test "x$enable_java_ports" = "xyes"],
1803       [AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])])
1804
1805 ####
1806 #### Lasciate ogne speranza, voi ch'intrate
1807 ####
1808 #### This could be moved to the checks above,
1809 #### but for now let's keep it here.
1810 ####
1811
1812 # -- print message regarding enabled experimental features
1813 AS_IF([test "x$enable_experimental" = "xyes"],
1814       [experimental_msg="experimental features enabled"])
1815 # -- OSX Framework
1816 AS_IF([test "$enable_framework_build" = "yes"],
1817       [macosx_framework_msg="yes"],
1818       [macosx_framework_msg="no"])
1819 # -- libidn 2
1820 AS_IF([test "x$working_libidn2" = x1],
1821       [libidn2_msg="libidn2"])
1822 # -- libidn 1
1823 AS_IF([test "x$working_libidn1" = x1],
1824       [libidn1_msg="libidn1"])
1825 # -- texi2mdoc
1826 AS_IF([test "x$texi2mdoc_generation" = x1],
1827       [mdoc_msg="yes"],
1828       [mdoc_msg="no"])
1829 # -- texinfo
1830 AS_IF([test "x$makeinfo" != "x1"],
1831       [texinfo_msg="no"],
1832       [texinfo_msg="yes"])
1833 # -- conversation
1834 AS_IF([test "x$conversation_backend" = "xnone"],
1835       [AS_IF([test "x$pulse" != "x1"],
1836              [AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1837               libpulse_msg="no"],
1838              [libpulse_msg="yes"])
1839        AS_IF([test "x$opus" != "x1"],
1840              [AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1841               libopus_msg="no"],
1842              [libopus_msg="yes"])
1843        AS_IF([test "x$gst" != "x1"],
1844              [AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1845               gstreamer_msg="no"],
1846              [gstreamer_msg="yes"])],
1847       [features_msg="$features_msg conversation"])
1848 # -- interface
1849 interface_msg=`echo $DEFAULT_INTERFACE | tr -d \"`
1850 # -- libmicrohttpd
1851 AS_IF([test "x$lmhd" != "x1"],
1852       [libmicrohttpd_msg="no (optional)"],
1853       [libmicrohttpd_msg="yes"])
1854 # -- jansson
1855 AS_IF([test "x$jansson" = "x0"],
1856       [jansson_msg="no (optional)"],
1857       [jansson_msg="yes"])
1858 # -- libextractor
1859 AS_IF([test "$extractor" != 1],
1860       [AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])],
1861       [libextractor_msg="yes"])
1862 # -- libzbar
1863 AS_IF([test "x$zbar" = "x1"],
1864       [libzbar_msg="yes"
1865        features_msg="$features_msg gnunet-qr"],
1866       [AC_MSG_NOTICE([WARNING: zbar not found, gnunet-qr will not be built.])
1867        libzbar_msg="no"])
1868 # -- libgnurl
1869 AS_IF([test "$gnurl" = "0"],
1870       [AS_IF([test "x$curl" = "xfalse"],
1871              [AC_MSG_NOTICE([WARNING: libgnurl not found. http client support will not be compiled.])
1872               AC_MSG_WARN([ERROR: libgnurl not found. hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1873               curl_msg="no"],
1874              [AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1875               curl_msg="yes"])],
1876        [gnurl_msg="yes"])
1877 # -- ifconfig
1878 AS_IF([test "$VAR_IFCONFIG_BINARY" = "false"],
1879       [AC_MSG_NOTICE([WARNING: optional ifconfig not found])
1880        ifconfig_msg="no (optional)"],
1881       [ifconfig_msg="yes"])
1882 # -- upnpc
1883 AS_IF([test "$VAR_UPNPC_BINARY" = "false"],
1884       [AC_MSG_NOTICE([WARNING: optional upnpc binary not found])
1885        upnpc_msg="no (optional)"],
1886       [upnpc_msg="yes"])
1887 # -- iptables
1888 AS_IF([test "$VAR_IPTABLES_BINARY" = "false"],
1889       [AC_MSG_NOTICE([WARNING: optional iptables not found])
1890        iptables_msg="no (optional)"],
1891       [iptables_msg="yes"])
1892 # -- bluetooth
1893 AS_IF([test "x$bluetooth" = "x0"],
1894       [AC_MSG_NOTICE([WARNING: optional bluetooth library not found.])
1895        bluetooth_msg="no (optional)"],
1896       [bluetooth_msg="yes"])
1897 # -- gnutls
1898 AS_IF([test x$gnutls != xtrue],
1899       [AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
1900        gnutls_msg="no"],
1901       [AS_IF([test "x$gnutls_dane" != "x1"],
1902              [AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
1903               gnutls_msg="yes (without DANE support)"],
1904              [gnutls_msg="yes (with DANE support)"])])
1905 # -- databases
1906 AS_IF([test $mysqlfail = true]
1907       [AC_MSG_NOTICE([WARNING: optional MySQL not found (or too old)])])
1908 AS_IF([test "$mysql" = true],
1909       [features_msg="$features_msg mysql"
1910        mysql_msg="yes"],
1911       [mysql_msg="no"])
1912 AS_IF([test "$sqlite" = true],
1913       [features_msg="$features_msg sqlite"
1914        sqlite_msg="yes"],
1915       [AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1916        sqlite_msg="no"])
1917 AS_IF([test "$postgres" = true],
1918       [features_msg="$features_msg postgres"
1919        postgres_msg="yes"],
1920       [postgres_msg="no"])
1921 # -- features
1922 # ---- 1. replace spaces with newlines,
1923 # ---- 2. sort the lines,
1924 # ---- 3. replace the newlines with spaces.
1925 features_msg=`echo $features_msg | tr ' ' '\012' | sort | tr '\012' ' '`
1926 AC_SUBST(features_msg)
1927
1928
1929 # The summary
1930 # TODO: reduce the length of the last message block ("the message")
1931
1932 AC_MSG_NOTICE([
1933 GNUnet Configuration
1934
1935 gnunet version:                 ${VERSION}
1936
1937 Host setup:                     ${host}
1938 Install prefix:                 ${prefix}
1939 Compiler:                       ${CC}
1940 CFLAGS:                         ${CFLAGS}
1941 CPPFLAGS:                       ${CPPFLAGS}
1942 LDFLAGS:                        ${LDFLAGS}
1943 LIBS:                           ${LIBS}
1944 Build Target:                   $build_target
1945 Mac OSX framework build:        ${macosx_framework_msg}
1946
1947 Default Interface:              ${interface_msg}
1948
1949 MySQL:                          ${mysql_msg}
1950 PostgreSQL:                     ${postgres_msg}
1951 sqlite3:                        ${sqlite_msg}
1952 gnurl:                          ${gnurl_msg}
1953 curl:                           ${curl_msg}
1954 bluetooth:                      ${bluetooth_msg}
1955 jansson:                        ${jansson_msg}
1956 iptables:                       ${iptables_msg}
1957 ifconfig:                       ${ifconfig_msg}
1958 upnpc:                          ${upnpc_msg}
1959 gnutls:                         ${gnutls_msg}
1960 libzbar:                        ${libzbar_msg}
1961 java:                           ${java_msg}
1962 libmicrohttpd:                  ${libmicrohttpd_msg}
1963 libidn:                         ${libidn1_msg}${libidn2_msg}
1964 libopus:                        ${libopus_msg}
1965 gstreamer:                      ${gstreamer_msg}
1966 libpulse:                       ${libpulse_msg}
1967 libextractor:                   ${libextractor_msg}
1968
1969 texinfo manual:                 ${texinfo_msg}
1970 transpiled mdoc manual:         ${mdoc_msg}
1971
1972 features:                       ${features_msg}
1973 experimental:                   ${experimental_msg}
1974
1975
1976 IMPORTANT:
1977
1978 Please make sure NOW that you have created a user and group 'gnunet'
1979 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux,
1980 type:
1981
1982   addgroup gnunetdns
1983   adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1984
1985 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1986 'gnunet'.  Then, you can compile GNUnet with
1987
1988   make
1989
1990 After that, run (if necessary as 'root')
1991
1992   make install
1993
1994 to install everything.
1995
1996 Each GNUnet user should be added to the 'gnunet' group (may
1997 require fresh login to come into effect):
1998
1999   adduser USERNAME gnunet
2000
2001 (run the above command as root once for each of your users, replacing
2002 "USERNAME" with the respective login names).  If you have a global IP
2003 address, no further configuration is required.
2004
2005 For more detailed setup instructions, see https://docs.gnunet.org/
2006
2007 Optionally, download and compile gnunet-gtk to get a GUI for
2008 file-sharing and configuration.  This is particularly recommended
2009 if your network setup is non-trivial, as gnunet-setup can be
2010 used to test in the GUI if your network configuration is working.
2011 gnunet-setup should be run as the "gnunet" user under X.  As it
2012 does very little with the network, running it as "root" is likely
2013 also harmless.  You can also run it as a normal user, but then
2014 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
2015 home directory in the end.
2016
2017 Once you have configured your peer, run (as the 'gnunet' user)
2018
2019   gnunet-arm -s
2020
2021 to start the peer.  You can then run the various GNUnet-tools as
2022 your "normal" user (who should only be in the group 'gnunet').
2023 ])