configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2015 Christian Grothoff (and other contributing authors)
   3 #
   4 # GNUnet is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published
   6 # by the Free Software Foundation; either version 3, or (at your
   7 # option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with GNUnet; see the file COPYING.  If not, write to the
  16 # Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18 #
  19 #
  20 # Process this file with autoconf to produce a configure script.
  21 #
  22 #
  23 AC_PREREQ(2.61)
  24 # Checks for programs.
  25 AC_INIT([gnunet], [0.10.1], [bug-gnunet@gnu.org])
  26
  27 AC_CANONICAL_TARGET
  28 AC_CANONICAL_HOST
  29 AC_CANONICAL_SYSTEM
  30
  31 AM_INIT_AUTOMAKE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33 AC_CONFIG_HEADERS([gnunet_config.h])
  34 AH_TOP([#define _GNU_SOURCE  1])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_PROG_AWK
  37 AC_PROG_CC
  38 AC_PROG_CPP
  39 AC_PROG_CXX
  40 AC_PROG_OBJC
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AM_PROG_CC_C_O
  45 LT_INIT([disable-static dlopen win32-dll])
  46 AC_SUBST(MKDIR_P)
  47
  48 # large file support
  49 AC_SYS_LARGEFILE
  50 AC_FUNC_FSEEKO
  51
  52
  53 CFLAGS="-Wall $CFLAGS"
  54 # use '-fno-strict-aliasing', but only if the compiler can take it
  55 if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
  56 then
  57  CFLAGS="-fno-strict-aliasing $CFLAGS"
  58 fi
  59
  60 # Use Linux interface name unless the OS has a different preference
  61 DEFAULT_INTERFACE="\"eth0\""
  62
  63 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo"
  64
  65 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  66 native_srcdir=$srcdir
  67
  68 # Check system type
  69 case "$host_os" in
  70 *darwin* | *rhapsody* | *macosx*)
  71      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  72      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  73      CFLAGS="-fno-common $CFLAGS"
  74      AC_MSG_WARN([The VPN application cannot be compiled on your OS])
  75      build_target="darwin"
  76      DEFAULT_INTERFACE="\"en0\""
  77      LIBPREFIX=
  78      DLLDIR=lib
  79      UNIXONLY="#"
  80      ;;
  81 linux*)
  82      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
  83      build_target="linux"
  84      LIBPREFIX=
  85      DLLDIR=lib
  86      UNIXONLY="#"
  87      AC_PATH_XTRA
  88      ;;
  89 *freebsd*)
  90      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  91      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
  92      CFLAGS="-D_THREAD_SAFE $CFLAGS"
  93      build_target="freebsd"
  94      LIBPREFIX=
  95      DLLDIR=lib
  96      UNIXONLY="#"
  97      ;;
  98 *openbsd*)
  99      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 100      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 101      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 102      build_target="openbsd"
 103      LIBPREFIX=
 104      DLLDIR=lib
 105      UNIXONLY="#"
 106      ;;
 107 *netbsd*)
 108      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 109      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 110      LIBPREFIX=
 111      DLLDIR=lib
 112      UNIXONLY="#"
 113      ;;
 114 *solaris*)
 115      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 116      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 117      AC_CHECK_LIB(resolv, res_init)
 118      AC_CHECK_LIB(rt, nanosleep)
 119      build_target="solaris"
 120      LIBPREFIX=
 121      DLLDIR=lib
 122      UNIXONLY="#"
 123      ;;
 124 *arm-linux*)
 125      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 126      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 127      build_target="linux"
 128      LIBPREFIX=
 129      DLLDIR=lib
 130      UNIXONLY="#"
 131      ;;
 132 *cygwin*)
 133      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 134      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 135      AC_CHECK_LIB(intl, gettext)
 136      CFLAGS="-mms-bitfields $CFLAGS"
 137      build_target="cygwin"
 138      LIBPREFIX=lib
 139      DLLDIR=bin
 140      AC_PROG_CXX
 141      UNIXONLY=""
 142      ;;
 143 *mingw*)
 144      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 145      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 146      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 147      AC_CHECK_LIB(intl, gettext)
 148      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 149      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 150      CFLAGS="-mms-bitfields $CFLAGS"
 151      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 152      build_target="mingw"
 153      AC_PROG_CXX
 154      LIBPREFIX=lib
 155      DLLDIR=bin
 156      UNIXONLY=""
 157      funcstocheck=""
 158      native_srcdir=$(cd $srcdir; pwd -W)
 159      ;;
 160 gnu*)
 161      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 162      build_target="gnu"
 163      UNIXONLY="#"
 164      ;;
 165 *)
 166      AC_MSG_RESULT(Unrecognised OS $host_os)
 167      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 168      UNIXONLY=""
 169 ;;
 170 esac
 171 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 172 AC_SUBST(DEFAULT_INTERFACE)
 173
 174 # Disable TCP-based IPC on systems that support UNIX domain
 175 # sockets in default configuratin:
 176 AC_SUBST(UNIXONLY)
 177
 178
 179 AC_MSG_CHECKING([for build target])
 180 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 181 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 182 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 183 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 184 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 185 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 186 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 187 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 188
 189 AC_MSG_RESULT([$build_target])
 190 AC_SUBST(build_target)
 191 AM_CONDITIONAL([am__fastdepOBJC], false)
 192 AC_UNALIGNED_64_ACCESS
 193
 194 # some other checks for standard libs
 195 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 196 AC_CHECK_LIB(socket, socket)
 197 AC_CHECK_LIB(m, log)
 198 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 199
 200 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 201 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 202
 203
 204
 205 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 206   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 207      [Define if struct tm has the tm_gmtoff member.])],
 208      ,
 209      [#include <time.h>])
 210
 211 AC_CHECK_DECLS([_stati64])
 212
 213 # 'save' libs; only those libs found so far will be
 214 # linked against _everywhere_.  For the others, we
 215 # will be more selective!
 216 SAVE_LIBS=$LIBS
 217
 218 # tests only run on Windows
 219 if test "x$build_target" = "xmingw"
 220 then
 221   AC_CHECK_LIB(plibc, plibc_init, [], [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 222   AC_CHECK_LIB(gnurx, regexec, [], [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])
 223 fi
 224
 225 # libgcrypt
 226 gcrypt=0
 227 NEED_LIBGCRYPT_API=1
 228 NEED_LIBGCRYPT_VERSION=1.6.0
 229
 230
 231 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 232 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 233
 234 if test $gcrypt = 0
 235 then
 236   AC_MSG_ERROR([[
 237 ***
 238 *** You need libgcrypt to build this program.
 239 **  This library is for example available at
 240 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 241 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 242 ***  is required.)
 243 ***]])
 244 fi
 245 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 246
 247 # Adam shostack suggests the following for Windows:
 248 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 249 AC_ARG_ENABLE(gcc-hardening,
 250    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 251 [if test x$enableval = xyes; then
 252     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 253     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 254     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 255     LDFLAGS="$LDFLAGS -pie"
 256 fi])
 257
 258
 259 # Linker hardening options
 260 # Currently these options are ELF specific - you can't use this with MacOSX
 261 AC_ARG_ENABLE(linker-hardening,
 262   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 263 [if test x$enableval = xyes; then
 264    LDFLAGS="$LDFLAGS -z relro -z now"
 265 fi])
 266
 267
 268 extra_logging=GNUNET_NO
 269 AC_ARG_ENABLE([logging],
 270    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 271    [AS_IF([test "x$enableval" = "xyes"], [],
 272           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 273           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 274           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 275    ], [])
 276 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 277
 278 # should memory poisoning be enabled?
 279 AC_MSG_CHECKING(whether to poison freed memory)
 280 AC_ARG_ENABLE([poisoning],
 281    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 282    [enable_poisoning=${enableval}],
 283    [
 284      if test "x$extra_logging" != "xGNUNET_NO"; then
 285        enable_poisoning="defaults to yes (extra logging is enabled)"
 286      else
 287        enable_poisoning=no
 288      fi
 289    ])
 290 AC_MSG_RESULT($enable_poisoning)
 291 if test ! "x$enable_poisoning" = "xno"; then
 292   enable_poisoning=1
 293 else
 294   enable_poisoning=0
 295 fi
 296 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 297
 298 if test $build = $target
 299 then
 300 AC_MSG_CHECKING([for working HMAC])
 301 AC_LANG_PUSH(C)
 302 LIBS="$LIBS $LIBGCRYPT_LIBS"
 303 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 304 AC_RUN_IFELSE(
 305   [AC_LANG_PROGRAM([#include <gcrypt.h>
 306         #include <stdio.h>], [[
 307         gcry_md_hd_t mac;
 308
 309         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 310             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 311             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 312         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 313         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 314             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 315             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 316             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 317             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 318             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 319
 320         if (!gcry_check_version (GCRYPT_VERSION))
 321         {
 322           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 323           return 1;
 324         }
 325
 326         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 327         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 328
 329         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 330         {
 331           fprintf (stderr, "gcry_md_open error\n");
 332           return 2;
 333         }
 334
 335         gcry_md_setkey (mac, key, sizeof (key));
 336         gcry_md_write (mac, data, sizeof (data));
 337
 338         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 339         {
 340           fprintf (stderr, "memcmp error\n");
 341           return 3;
 342         }
 343
 344         gcry_md_close (mac);
 345
 346         return 0;
 347     ]])],
 348   [AC_MSG_RESULT([yes])],
 349   [
 350    RESULT=$?
 351    if test $RESULT = 3
 352    then
 353      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 354    fi
 355    if test $RESULT = 2
 356    then
 357      AC_MSG_FAILURE([HMAC test failed])
 358    fi
 359    if test $RESULT = 1
 360    then
 361      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 362    fi
 363   ],
 364   [AC_MSG_RESULT([cross compiling, test skipped])])
 365 AC_LANG_POP(C)
 366 fi      # $build = $target
 367
 368 # check for bluetooth library
 369 bluetooth=0
 370 AC_CHECK_LIB(bluetooth, ba2str,[AC_CHECK_HEADER([bluetooth/bluetooth.h],bluetooth=1)])
 371 if test "$build_target" = "mingw"
 372 then
 373   bluetooth=1
 374 fi
 375 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 376 if test "$bluetooth" = 1
 377 then
 378   AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])
 379 else
 380   AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])
 381 fi
 382
 383
 384 # check for libpulse(audio) library
 385 pulse=0
 386 AC_CHECK_LIB(pulse,pa_stream_peek,
 387   [AC_CHECK_HEADER([pulse/simple.h],pulse=1)])
 388 if test "$build_target" = "mingw"
 389 then
 390   pulse=0
 391 fi
 392 if test "$pulse" = 1
 393 then
 394   AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 395 fi
 396
 397 # check for libopus(audio) library
 398 opus=0
 399 AC_CHECK_LIB(opus,opus_decode_float,
 400   [AC_CHECK_HEADER([opus/opus.h],
 401     [AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]
 402     )]
 403   )]
 404 )
 405 if test "$opus" = 1
 406 then
 407   AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 408 fi
 409
 410 # libogg
 411 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 412         [AC_CHECK_HEADERS([ogg/ogg.h],
 413           AM_CONDITIONAL(HAVE_OGG, true)
 414           ogg=1
 415           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 416           AM_CONDITIONAL(HAVE_OGG, false)
 417           ogg=0
 418           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 419         AM_CONDITIONAL(HAVE_OGG, false)
 420         ogg=0)
 421
 422
 423
 424 gst=0
 425 PKG_CHECK_MODULES(
 426   [GST],
 427   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 428   [
 429     gst=1
 430     AC_MSG_RESULT(ok)
 431   ], [
 432     gst=0
 433     AC_MSG_RESULT(not found)
 434   ])
 435
 436 # Pulse Audio
 437 if test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"
 438 then
 439  if test "x$gst" != "x1"
 440  then
 441   conversation_backend=none
 442   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 443   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 444  else
 445    conversation_backend=gst
 446    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 447    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 448  fi
 449 else
 450  conversation_backend=pulse
 451  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 452  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 453 fi
 454
 455 # libgnurl
 456 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 457 if test "$gnurl" = 1
 458 then
 459         AM_CONDITIONAL(HAVE_LIBGNURL, true)
 460         AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 461 else
 462         AM_CONDITIONAL(HAVE_LIBGNURL, false)
 463         AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 464 fi
 465
 466 SAVE_CPPFLAGS=$CPPFLAGS
 467 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 468 LIBS="$LIBGNURL $LIBCURL $LIBS"
 469
 470 # libcurl-gnutls
 471 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 472 if test "x$curl" = xtrue
 473 then
 474
 475  AC_CHECK_HEADERS([curl/curl.h],
 476   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 477   [curl=false])
 478  AC_CHECK_HEADERS([gnurl/curl.h],
 479   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],,[[#include <gnurl/curl.h>]]))
 480  # need libcurl-gnutls.so, everything else is not acceptable
 481  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 482  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 483 fi
 484
 485 # Check for curl/curl.h and gnurl/curl.h so we can use #ifdef
 486 # HAVE_CURL_CURL_H later (the above LIBCURL_CHECK_CONFIG accepted
 487 # *either* header set).
 488 AC_CHECK_HEADERS([curl/curl.h],,
 489   curl=false
 490   AC_CHECK_HEADERS([gnurl/curl.h],,
 491   gnurl=false))
 492
 493
 494
 495 if test x$curl = xfalse
 496 then
 497         AM_CONDITIONAL(HAVE_LIBCURL, false)
 498 if test "$gnurl" = 0
 499 then
 500         AC_MSG_WARN([GNUnet requires libcurl-gnutls  >= 7.34])
 501 fi
 502 else
 503         AM_CONDITIONAL(HAVE_LIBCURL, true)
 504         AC_DEFINE([HAVE_LIBCURL],[1],[Have CURL])
 505 fi
 506
 507
 508 # restore LIBS & CPPFLAGS
 509 LIBS=$SAVE_LIBS
 510 CPPFLAGS=$SAVE_CPPFLAGS
 511
 512 AC_CHECK_HEADERS([glpk.h],[glpk=true],[gplk=false])
 513 # GLPK must support glpk_init_env, version >= 4.43
 514 AC_CHECK_LIB([glpk],[glp_init_env],,[gplk=false])
 515 # GLPK must support atm MLP presolving, version >= 4.32
 516 AC_CHECK_MEMBERS(glp_iocp.presolve,,[gplk=false],[[#include <glpk.h>]])
 517 if test x$gplk = xfalse
 518 then
 519         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 520         AC_MSG_WARN([GNUnet requires GLPK  >= 4.32])
 521 else
 522         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 523         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 524 fi
 525
 526
 527
 528 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 529 if test x$nss = xfalse
 530 then
 531         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 532         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 533 else
 534         AM_CONDITIONAL(HAVE_GLIBCNSS, true)
 535 fi
 536
 537
 538
 539 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 540 AC_CHECK_LIB([kvm],[kvm_open])
 541 AC_CHECK_LIB([kstat],[kstat_open])
 542
 543
 544 # should the build process be restricted to the code required
 545 # for GNU Taler wallets?
 546 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 547 AC_ARG_ENABLE([taler-wallet],
 548    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 549    [taler_only=${enableval}],
 550    [taler_only=no])
 551 AC_MSG_RESULT($taler_only)
 552 AM_CONDITIONAL([TALER_ONLY], [test "x$taler_only" = "xyes"])
 553
 554 # test for libextractor
 555 extractor=0
 556 AC_MSG_CHECKING(for libextractor)
 557 AC_ARG_WITH(extractor,
 558    [  --with-extractor=PFX    base of libextractor installation],
 559    [AC_MSG_RESULT([$with_extractor])
 560     case $with_extractor in
 561       no)
 562         ;;
 563       yes)
 564         AC_CHECK_HEADERS(extractor.h,
 565           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 566             extractor=1))
 567         ;;
 568       *)
 569         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 570         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 571         AC_CHECK_HEADERS(extractor.h,
 572           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 573             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 574             extractor=1))
 575         ;;
 576     esac
 577    ],
 578    [AC_MSG_RESULT([--with-extractor not specified])
 579     AC_CHECK_HEADERS(extractor.h,
 580      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 581       extractor=1))])
 582 # restore LIBS
 583 LIBS=$SAVE_LIBS
 584
 585 if test "$extractor" != 1
 586 then
 587  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 588  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 589 else
 590  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 591  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 592 fi
 593
 594
 595 if test "$taler_only" != yes
 596 then
 597
 598 # Check for libltdl header (#2999)
 599 ltdl=0
 600 AC_MSG_CHECKING(for libltdl)
 601 AC_ARG_WITH(ltdl,
 602    [  --with-ltdl=PFX    base of libltdl installation],
 603    [AC_MSG_RESULT([$with_ltdl])
 604     case $with_ltdl in
 605       no)
 606         ;;
 607       yes)
 608         AC_CHECK_HEADERS(ltdl.h,
 609           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 610             ltdl=1))
 611         ;;
 612       *)
 613         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 614         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 615         AC_CHECK_HEADERS(ltdl.h,
 616           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 617             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 618             ltdl=1))
 619         ;;
 620     esac
 621    ],
 622    [AC_MSG_RESULT([--with-ltdl not specified])
 623     AC_CHECK_HEADERS(ltdl.h,
 624      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 625       ltdl=1))])
 626 if test x$ltdl = x1
 627 then
 628  AC_MSG_RESULT([libltdl found])
 629 else
 630  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 631 fi
 632 # restore LIBS
 633 LIBS=$SAVE_LIBS
 634
 635
 636 # libidn
 637 AC_MSG_CHECKING([if Libidn can be used])
 638 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 639                                     [Support IDN (needs GNU Libidn)]),
 640 libidn=$withval, libidn=yes)
 641 if test "$libidn" != "no"; then
 642   if test "$libidn" != "yes"; then
 643      LDFLAGS="${LDFLAGS} -L$libidn/lib"
 644      CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 645   fi
 646 fi
 647 libidn=no
 648 AC_CHECK_HEADER(idna.h,
 649   AC_CHECK_LIB(idn, stringprep_check_version,
 650     [libidn=yes LIBS="${LIBS} -lidn"], []), [])
 651 if test "$libidn" != "yes"; then
 652   AC_MSG_FAILURE([GNUnet requires libidn.
 653 libidn-1.13 should be sufficient, newer versions work too.])
 654 fi
 655 AC_MSG_RESULT($libidn)
 656
 657
 658 # test for zlib
 659 SAVE_LDFLAGS=$LDFLAGS
 660 SAVE_CPPFLAGS=$CPPFLAGS
 661 AC_ARG_WITH(zlib,
 662             [  --with-zlib[[=DIR]]       use libz in DIR],
 663             [AS_IF([test "$withval" = "no"],
 664                    [AC_MSG_ERROR([GNUnet requires zlib])],
 665                    [test "$withval" != "yes"],
 666                    [
 667                      Z_DIR=$withval
 668                      CPPFLAGS="${CPPFLAGS} -I$withval/include"
 669                      LDFLAGS="${LDFLAGS} -L$withval/lib"
 670                    ])
 671             ])
 672 AC_CHECK_HEADER(zlib.h,
 673                 [],
 674                 [AC_MSG_ERROR([GNUnet requires zlib])])
 675 AC_CHECK_LIB(z, compress2,
 676              [
 677               AC_DEFINE([HAVE_ZLIB], [], [Have compression library])
 678               if test "x${Z_DIR}" != "x"; then
 679                       Z_CFLAGS="-I${Z_DIR}/include"
 680                       Z_LIBS="-L${Z_DIR}/lib -lz"
 681               else
 682                       Z_LIBS="-lz"
 683               fi],
 684               [AC_MSG_ERROR([GNUnet requires zlib])])
 685 AC_SUBST(Z_CFLAGS)
 686 AC_SUBST(Z_LIBS)
 687
 688 if test "$enable_shared" = "no"
 689 then
 690  AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])
 691 fi
 692
 693
 694
 695 # restore LIBS
 696 LIBS=$SAVE_LIBS
 697
 698
 699 fi
 700
 701 # check for iconv
 702 AM_ICONV
 703
 704 # test for libunistring
 705 gl_LIBUNISTRING
 706 if test $HAVE_LIBUNISTRING != yes; then
 707  AC_MSG_ERROR([GNUnet requires libunistring])
 708 fi
 709 if test $gl_libunistring_hexversion -le 2305; then
 710  AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])
 711 fi
 712 # restore LIBS
 713 LIBS=$SAVE_LIBS
 714
 715
 716
 717 # Checks for standard header files.
 718 AC_HEADER_DIRENT
 719 AC_HEADER_STDC
 720
 721 # Check for headers that are ALWAYS required
 722 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files]))
 723
 724
 725
 726 # Checks for headers that are only required on some systems or opional (and where we do NOT abort if they are not there)
 727 AC_CHECK_HEADERS([malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
 728
 729 # FreeBSD requires something more funky for netinet/in_systm.h and netinet/ip.h...
 730 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
 731 [#ifdef HAVE_SYS_TYPES_H
 732 #include <sys/types.h>
 733 #endif
 734 #ifdef HAVE_NETINET_IN_SYSTM_H
 735 #include <netinet/in_systm.h>
 736 #endif
 737 #ifdef HAVE_NETINET_IN_H
 738 #include <netinet/in.h>
 739 #endif
 740 ])
 741
 742 SAVE_LDFLAGS=$LDFLAGS
 743 SAVE_CPPFLAGS=$CPPFLAGS
 744
 745 # test for sqlite
 746 sqlite=false
 747 AC_MSG_CHECKING(for SQLite)
 748 AC_ARG_WITH(sqlite,
 749   [  --with-sqlite=PFX       base of SQLite installation],
 750   [AC_MSG_RESULT("$with_sqlite")
 751    case $with_sqlite in
 752    no)
 753      ;;
 754    yes)
 755     AC_CHECK_HEADERS(sqlite3.h,
 756      sqlite=true)
 757      ;;
 758    *)
 759     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
 760     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
 761     AC_CHECK_HEADERS(sqlite3.h,
 762      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
 763      SQLITE_LDFLAGS="-L$with_sqlite/lib"
 764      SQLITE_CPPFLAGS="-I$with_sqlite/include"
 765      sqlite=true)
 766     LDFLAGS=$SAVE_LDFLAGS
 767     CPPFLAGS=$SAVE_CPPFLAGS
 768     ;;
 769    esac
 770   ],
 771   [AC_MSG_RESULT([--with-sqlite not specified])
 772     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
 773 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
 774 AC_SUBST(SQLITE_CPPFLAGS)
 775 AC_SUBST(SQLITE_LDFLAGS)
 776
 777 # test for postgres
 778 postgres=false
 779 AX_LIB_POSTGRESQL([])
 780 if test "$found_postgresql" = "yes"; then
 781   AC_CHECK_HEADERS([libpq-fe.h],
 782     postgres=true)
 783 fi
 784
 785 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
 786
 787
 788 LDFLAGS=$SAVE_LDFLAGS
 789 CPPFLAGS=$SAVE_CPPFLAGS
 790
 791 # mysql & windows
 792 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
 793 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
 794
 795 if test "$build_target" = "mingw"
 796 then
 797   CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"
 798 fi
 799
 800 # test for mysql
 801 mysql=false
 802 mysqlfail=false
 803 SAVE_LDFLAGS=$LDFLAGS
 804 SAVE_CPPFLAGS=$CPPFLAGS
 805 AC_MSG_CHECKING(for mysql)
 806 AC_ARG_WITH(mysql,
 807   [  --with-mysql=PFX        base of MySQL installation],
 808   [AC_MSG_RESULT("$with_mysql")
 809    if test "$with_mysql" != "no"
 810    then
 811     if test "$with_mysql" != "yes"
 812     then
 813       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
 814       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
 815     fi
 816     AC_CHECK_HEADERS(mysql/mysql.h,
 817      AC_CHECK_LIB(mysqlclient, mysql_init,
 818       MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
 819       MYSQL_CPPFLAGS="-I$with_mysql/include"
 820
 821       mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 822    fi
 823   ],
 824   [AC_MSG_RESULT([--with-mysql not specified])
 825    if test -d "/usr/lib64/mysql"; then
 826     MYSQL_LIBDIR="/usr/lib64/mysql"
 827    elif test -d "/usr/lib/mysql"; then
 828     MYSQL_LIBDIR="/usr/lib/mysql"
 829    else
 830     MYSQL_LIBDIR="/usr/lib"
 831    fi
 832    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
 833    AC_CHECK_LIB(mysqlclient, mysql_init,
 834     [AC_CHECK_HEADERS(mysql/mysql.h,
 835       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
 836       mysql=true
 837
 838      , [], [$CYGWIN_MYSQL_MAGIC])])
 839   ])
 840
 841 AC_SUBST(MYSQL_LDFLAGS)
 842 AC_SUBST(MYSQL_CPPFLAGS)
 843
 844 # additional version check for mysql
 845 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
 846 if test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"
 847 then
 848   AC_MSG_CHECKING(mysql version)
 849   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 850     [[$CYGWIN_MYSQL_MAGIC
 851       #include <mysql/mysql.h>]],
 852     [[
 853       #if (MYSQL_VERSION_ID < 40100)
 854       #error needs at least version >= 4.1
 855       #endif
 856       int main () { return 0; }
 857     ]])
 858     ],mysql=true,mysql=false)
 859   if test "$mysql" = "false"
 860   then
 861     mysqlfail=true
 862     AC_MSG_RESULT([fail, >= 4.1 required])
 863   else
 864     AC_MSG_RESULT(ok)
 865   fi
 866 fi
 867 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
 868 AM_CONDITIONAL(HAVE_MYSQLE, test "0" = "1")
 869 # restore LIBS
 870 LIBS=$SAVE_LIBS
 871 LDFLAGS=$SAVE_LDFLAGS
 872 CPPFLAGS=$SAVE_CPPFLAGS
 873
 874 if test "$sqlite" = 0 -a "$mysql" = 0
 875 then
 876  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
 877 fi
 878
 879 # libmicrohttpd
 880 lmhd=0
 881 AC_MSG_CHECKING([for libmicrohttpd])
 882 AC_ARG_WITH(microhttpd,
 883    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
 884    [AC_MSG_RESULT([$with_microhttpd])
 885     case $with_microhttpd in
 886       no)
 887         ;;
 888       yes)
 889         AC_CHECK_HEADERS([microhttpd.h],
 890           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 891             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 892               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 893               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 894                 #include "$native_srcdir/src/include/platform.h"
 895                 #include <microhttpd.h>
 896                 #if (MHD_VERSION < 0x0094200)
 897                 #error needs at least version 0.9.42
 898                 #endif
 899                 int main () { return 0; }
 900                ])],
 901                [AC_MSG_RESULT(ok)
 902                 lmhd=1],
 903                [AC_MSG_RESULT(failed)])]),
 904             [],[#include "$native_srcdir/src/include/platform.h"
 905                 #include <microhttpd.h>]),,
 906             [#include "$native_srcdir/src/include/platform.h"])
 907         ;;
 908       *)
 909         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
 910         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
 911         AC_CHECK_HEADERS(microhttpd.h,
 912           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 913             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 914               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
 915               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 916                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 917                 #include "$native_srcdir/src/include/platform.h"
 918                 #include <microhttpd.h>
 919                 #if (MHD_VERSION < 0x0094200)
 920                 #error needs at least version 0.9.42
 921                 #endif
 922                 int main () { return 0; }
 923                ])],
 924                [AC_MSG_RESULT(ok)
 925                 lmhd=1],
 926                [AC_MSG_RESULT(failed)])]),
 927             [],[#include "$native_srcdir/src/include/platform.h"
 928                 #include <microhttpd.h>]),,
 929             [#include "$native_srcdir/src/include/platform.h"])
 930         ;;
 931     esac
 932    ],
 933    [AC_MSG_RESULT([--with-microhttpd not specified])
 934     AC_CHECK_HEADERS([microhttpd.h],
 935       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 936         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 937           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 938               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 939                 #include "$native_srcdir/src/include/platform.h"
 940                 #include <microhttpd.h>
 941                 #if (MHD_VERSION < 0x0094200)
 942                 #error needs at least version 0.9.42
 943                 #endif
 944                ])],
 945                [AC_MSG_RESULT(ok)
 946                 lmhd=1],
 947                [AC_MSG_RESULT(failed)])]),
 948         [],[#include "$native_srcdir/src/include/platform.h"
 949             #include <microhttpd.h>]),,
 950        [#include "$native_srcdir/src/include/platform.h"])])
 951 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
 952 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
 953
 954
 955 # restore LIBS
 956 LIBS=$SAVE_LIBS
 957
 958 # check for python & pexpect (used for some testcases only)
 959 AM_PATH_PYTHON([2.6],, [:])
 960 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 961
 962 # check for gettext
 963 AM_GNU_GETTEXT([external])
 964 AM_GNU_GETTEXT_VERSION([0.18.3])
 965
 966 # Checks for standard typedefs, structures, and compiler characteristics.
 967 AC_TYPE_PID_T
 968 AC_TYPE_SIZE_T
 969 AC_TYPE_MODE_T
 970 AC_HEADER_TIME
 971 AC_HEADER_STAT
 972 AC_HEADER_STDBOOL
 973 AC_STRUCT_TM
 974
 975 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 976    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
 977    ],
 978    [],
 979    [
 980       #include <sys/types.h>
 981       #include <sys/socket.h>
 982       #include <netinet/in.h>
 983    ])
 984
 985
 986
 987 # Checks for library functions.
 988 AC_FUNC_CLOSEDIR_VOID
 989 AC_FUNC_FORK
 990 AC_PROG_GCC_TRADITIONAL
 991 AC_FUNC_MEMCMP
 992 AC_FUNC_SELECT_ARGTYPES
 993 AC_FUNC_CHOWN
 994
 995 AC_TYPE_SIGNAL
 996 AC_FUNC_STAT
 997 AC_FUNC_STRFTIME
 998 AC_FUNC_VPRINTF
 999 AC_HEADER_SYS_WAIT
1000 AC_TYPE_OFF_T
1001 AC_TYPE_UID_T
1002 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs])
1003
1004 # restore LIBS
1005 LIBS=$SAVE_LIBS
1006
1007 GN_INTLINCL=""
1008 GN_LIBINTL="$LTLIBINTL"
1009 AC_ARG_ENABLE(framework, [  --enable-framework      enable Mac OS X framework build helpers],enable_framework_build=$enableval)
1010 AM_CONDITIONAL(WANT_FRAMEWORK, test x$enable_framework_build = xyes)
1011 if test x$enable_framework_build = xyes
1012 then
1013   AC_DEFINE([FRAMEWORK_BUILD], 1, [Build a Mac OS X Framework])
1014   GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1015   GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1016   AC_LIB_APPENDTOVAR([CPPFLAGS], [$GN_INTLINCL])
1017 fi
1018
1019 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1020 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1021
1022 AC_SUBST(GN_LIB_LDFLAGS)
1023 AC_SUBST(GN_PLUGIN_LDFLAGS)
1024 AC_SUBST(GN_INTLINCL)
1025 AC_SUBST(GN_LIBINTL)
1026
1027 AC_SUBST(CPPFLAGS)
1028 AC_SUBST(LIBS)
1029 AC_SUBST(LDFLAGS)
1030 AC_SUBST(EXT_LIB_PATH)
1031 AC_SUBST(EXT_LIBS)
1032
1033 AC_SUBST(LIBPREFIX)
1034 AC_SUBST(DLLDIR)
1035 AC_SUBST(EXT_LIB_PATH)
1036
1037
1038 # test for sudo
1039 AC_MSG_CHECKING(for sudo)
1040 AC_ARG_WITH(sudo,
1041   [  --with-sudo=PATH       path to sudo binary (or just yes)],
1042   [AC_MSG_RESULT("$with_sudo")
1043    case $with_sudo in
1044    no)
1045      SUDO_BINARY=
1046      ;;
1047    yes)
1048      SUDO_BINARY=sudo
1049      ;;
1050    *)
1051      SUDO_BINARY=$with_sudo
1052     ;;
1053    esac
1054   ],
1055   [AC_MSG_RESULT([no])])
1056 AC_SUBST(SUDO_BINARY)
1057 AM_CONDITIONAL([HAVE_SUDO], [test "x$SUDO_BINARY" != "x" -o -w /])
1058
1059
1060 # test for nssdir
1061 AC_MSG_CHECKING(with nssdir)
1062 AC_ARG_WITH(nssdir,
1063   [  --with-nssdir=PATH       where to install NSS plugins],
1064   [AC_MSG_RESULT("$with_nssdir")
1065    case $with_nssdir in
1066    no)
1067      NSS_DIR=
1068      install_nss=0
1069      ;;
1070    yes)
1071      NSS_DIR="/lib"
1072      install_nss=1
1073      ;;
1074    *)
1075      NSS_DIR=$with_nssdir
1076      install_nss=1
1077     ;;
1078    esac
1079   ],
1080   [
1081    if test "x$SUDO_BINARY" != "x" -o -w /
1082    then
1083      NSS_DIR="/lib"
1084      install_nss=1
1085      AC_MSG_RESULT([yes, to /lib])
1086    else
1087      NSS_DIR=
1088      install_nss=0
1089      AC_MSG_RESULT([no])
1090    fi
1091   ])
1092 AC_SUBST(NSS_DIR)
1093 AM_CONDITIONAL([INSTALL_NSS], [test "x$install_nss" != "x0"])
1094
1095 # test for gnunetdns group name
1096 GNUNETDNS_GROUP=gnunetdns
1097 AC_MSG_CHECKING(for gnunetdns group name)
1098 AC_ARG_WITH(gnunetdns,
1099   [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1100   [AC_MSG_RESULT("$with_gnunetdns")
1101    case $with_gnunetdns in
1102    no)
1103      GNUNETDNS_GROUP=gnunet
1104      ;;
1105    yes)
1106      GNUNETDNS_GROUP=gnunetdns
1107      ;;
1108    *)
1109      GNUNETDNS_GROUP=$with_gnunetdns
1110     ;;
1111    esac
1112   ],
1113   [AC_MSG_RESULT([gnunetdns])])
1114 AC_SUBST(GNUNETDNS_GROUP)
1115
1116
1117
1118 # gnutls
1119 gnutls=0
1120 gnutls_dane=0
1121 AC_MSG_CHECKING(for gnutls)
1122 AC_ARG_WITH(gnutls,
1123    [  --with-gnutls=PFX   base of gnutls installation],
1124    [AC_MSG_RESULT([$with_gnutls])
1125     case $with_gnutls in
1126       no)
1127         ;;
1128       yes)
1129         AC_CHECK_HEADERS([gnutls/abstract.h],
1130             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1131              gnutls=true))
1132         AC_CHECK_HEADERS([gnutls/dane.h],
1133             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1134               gnutls_dane=1))
1135         ;;
1136       *)
1137         LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1138         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1139         AC_CHECK_HEADERS([gnutls/abstract.h],
1140             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1141               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1142               gnutls=true))
1143         AC_CHECK_HEADERS([gnutls/dane.h],
1144             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1145               gnutls_dane=1))
1146         ;;
1147     esac
1148    ],
1149    [AC_MSG_RESULT([--with-gnutls not specified])
1150     AC_CHECK_HEADERS([gnutls/abstract.h],
1151         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1152           gnutls=true))
1153     AC_CHECK_HEADERS([gnutls/dane.h],
1154         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1155                      gnutls_dane=1))
1156    ])
1157 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1158 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1159 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1160 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1161
1162
1163 # Test if we are building for superMUC
1164 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1165 AC_ARG_ENABLE([supermuc],
1166     [AS_HELP_STRING([--enable-supermuc],
1167        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1168     [if test "x$enable_supermuc" = "xno"
1169      then
1170        supermuc=0
1171      else
1172        supermuc=1
1173      fi],
1174     [supermuc=0
1175      enable_supermuc=no])
1176 AC_MSG_RESULT($enable_SUPERMUC)
1177 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1178 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1179
1180 # Check if NSE has to send timestamp information to testbed logger for
1181 # generating histogram of messages received
1182 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1183 AC_ARG_ENABLE([nse-histogram],
1184     [AS_HELP_STRING([--enable-nse-histogram],
1185        [have NSE send timestamp information to testbed logger for generating
1186        histogram of received messages.  NOT useful for production (default is
1187        NO)])],
1188     [if test "x$enableval" = "xno"
1189      then
1190        nse_histogram=0
1191      else
1192        nse_histogram=1
1193      fi],
1194     [nse_histogram=0
1195      enable_nse_histogram=no])
1196 AC_MSG_RESULT($enable_nse_histogram)
1197 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1198 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1199                    [have NSE send timestamp information to testbed logger])
1200
1201 # should 'make check' run tests?
1202 AC_MSG_CHECKING(whether to run tests)
1203 AC_ARG_ENABLE([testruns],
1204    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1205    [enable_tests_run=${enableval}],
1206    [enable_tests_run=yes])
1207 AC_MSG_RESULT($enable_test_run)
1208 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1209
1210
1211 # should monkey be used when running (certain) services?
1212 AC_MSG_CHECKING(whether to run with monkey)
1213 AC_ARG_ENABLE([monkey],
1214    [AS_HELP_STRING([--enable-monkey], [enable running with monkey])],
1215    [enable_monkey=${enableval}],
1216    [enable_monkey=no])
1217 AC_MSG_RESULT($enable_monkey)
1218 AM_CONDITIONAL([ENABLE_MONKEY], [test "x$enable_monkey" = "xyes"])
1219 if test "x$enable_monkey" = "xyes"
1220 then
1221   MONKEYPREFIX="pathologist -d $(eval echo ${datarootdir}/gnunet/gnunet.sqlite) -p 30 --"
1222 else
1223   MONKEYPREFIX=""
1224 fi
1225 AC_SUBST(MONKEYPREFIX)
1226
1227
1228 # should expensive tests be run?
1229 AC_MSG_CHECKING(whether to run expensive tests)
1230 AC_ARG_ENABLE([expensivetests],
1231    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1232    [enable_expensive=${enableval}],
1233    [enable_expensive=no])
1234 AC_MSG_RESULT($enable_expensive)
1235 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1236
1237 # should ports be open for Java services?
1238 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1239 AC_ARG_ENABLE([javaports],
1240    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1241    [enable_java_ports=${enableval}],
1242    [enable_java_ports=no])
1243 AC_MSG_RESULT($enable_java_ports)
1244 if test "x$enable_java_ports" = "xyes"
1245 then
1246   JAVAPORT=""
1247 else
1248   JAVAPORT="$UNIXONLY"
1249 fi
1250 AC_SUBST(JAVAPORT)
1251
1252 # should benchmarks be run?
1253 AC_MSG_CHECKING(whether to run benchmarks during make check)
1254 AC_ARG_ENABLE([benchmarks],
1255    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1256    [enable_benchmarks=${enableval}],
1257    [enable_benchmarks=no])
1258 AC_MSG_RESULT($enable_benchmarks)
1259 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1260
1261 # should gnunet-testing be compiled
1262 AC_MSG_CHECKING(wether to compile gnunet-testing)
1263 AC_ARG_ENABLE([testing],
1264    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1265    [enable_testing=${enableval}],
1266    [enable_testing=yes])
1267 AC_MSG_RESULT($enable_testing)
1268 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1269
1270 # should experimental code be compiled (code that may not yet compile)?
1271 AC_MSG_CHECKING(whether to compile experimental code)
1272 AC_ARG_ENABLE([experimental],
1273    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1274    [enable_experimental=${enableval}],
1275    [enable_experimental=no])
1276 AC_MSG_RESULT($enable_experimental)
1277 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1278
1279 # FTBFS right now...
1280 AC_MSG_CHECKING(whether to compile ATS test code)
1281 AC_ARG_ENABLE([wachs],
1282    [AS_HELP_STRING([--enable-wachs], [enable compiling ATS test code])],
1283    [enable_wachs=${enableval}],
1284    [enable_wachs=no])
1285 AC_MSG_RESULT($enable_wachs)
1286 AM_CONDITIONAL([HAVE_WACHS], [test "x$enable_wachs" = "xyes"])
1287
1288 # REST API
1289 AC_MSG_CHECKING(whether to compile REST API)
1290 AC_ARG_ENABLE([rest],
1291    [AS_HELP_STRING([--enable-rest], [enable REST])],
1292    [enable_rest=${enableval}],
1293    [enable_rest=no])
1294 AC_MSG_RESULT($enable_rest)
1295 AM_CONDITIONAL([HAVE_REST], [test "x$enable_rest" = "xyes"])
1296
1297 # should malicious code be compiled (should only be used for testing)?
1298 AC_MSG_CHECKING(whether to compile malicious code)
1299 AC_ARG_ENABLE([malicious],
1300    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1301    [if test "x$enableval" = "xno"
1302      then
1303        malicious=0
1304      else
1305        malicious=1
1306      fi],
1307    [malicious=0
1308     enable_malicious=no])
1309 AC_MSG_RESULT($enable_malicious)
1310 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1311 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1312                    [enable compilation of malicious code])
1313
1314 # should services be started by default when a peer starts?  Some services may
1315 # choose to never start by default and it is upto the service/module developer to
1316 # decide it by having "AUTOSTART = NO" instead of "AUTOSTART = @AUTOSTART@" in
1317 # the service/module's conf.in file.
1318 AUTOSTART="YES"
1319 AC_MSG_CHECKING(whether to auto-start peer's services by default)
1320 AC_ARG_ENABLE([autostart],
1321    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1322    [enable_autostart=${enableval}
1323     if test "x$enable_autostart" == "xno"
1324     then
1325         AUTOSTART="NO"
1326     fi
1327    ],
1328    [enable_autostart=yes])
1329 AC_MSG_RESULT($enable_autostart)
1330 #AM_CONDITIONAL([HAVE_AUTOSTART], [test "x$enable_autostart" = "xyes"])
1331 AC_SUBST(AUTOSTART)
1332
1333 # should memory statistics be kept (very expensive CPU-wise!)
1334 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1335 AC_ARG_ENABLE([heapstats],
1336    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1337    [enable_heapstats=1],
1338    [enable_heapstats=0])
1339 AC_MSG_RESULT($enable_heapstats)
1340 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1341
1342 # should code be enabled that works around missing OS functionality on Windows?
1343 # used for test cases
1344 if test $build_target = "mingw"
1345 then
1346         workarounds=1
1347
1348 AC_LINK_IFELSE(
1349  [AC_LANG_PROGRAM(
1350   [#include <ws2tcpip.h>
1351   ],[
1352   int s = socket (0, 0, 0);])
1353  ],[
1354   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1355  ],[
1356   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1357  ])
1358
1359 AC_LINK_IFELSE(
1360  [AC_LANG_PROGRAM(
1361   [#include <ws2tcpip.h>
1362   ],[
1363   int s = select (0, NULL, NULL, NULL, NULL);])
1364  ],[
1365   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1366  ],[
1367   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1368  ])
1369
1370 AC_LINK_IFELSE(
1371  [AC_LANG_PROGRAM(
1372   [#include <ws2tcpip.h>
1373   ],[
1374   struct in_addr i;
1375   char *s = inet_ntoa (i);])
1376  ],[
1377   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1378  ],[
1379   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1380  ])
1381
1382 AC_LINK_IFELSE(
1383  [AC_LANG_PROGRAM(
1384   [#include <ws2tcpip.h>
1385   ],[
1386   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1387  ],[
1388   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1389  ],[
1390   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1391  ])
1392
1393 AC_LINK_IFELSE(
1394  [AC_LANG_PROGRAM(
1395   [#include <ws2tcpip.h>
1396   ],[
1397   int s = gethostname (NULL, 0);])
1398  ],[
1399   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1400  ],[
1401   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1402  ])
1403
1404 AC_LINK_IFELSE(
1405  [AC_LANG_PROGRAM(
1406   [#include <ws2tcpip.h>
1407   ],[
1408   void *s = gethostbyname (NULL);])
1409  ],[
1410   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1411  ],[
1412   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1413  ])
1414
1415 AC_LINK_IFELSE(
1416  [AC_LANG_PROGRAM(
1417   [#include <ws2tcpip.h>
1418   ],[
1419   void *s = gethostbyaddr (NULL, 0, 0);])
1420  ],[
1421   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1422  ],[
1423   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1424  ])
1425
1426 AC_LINK_IFELSE(
1427  [AC_LANG_PROGRAM(
1428   [#include <ws2tcpip.h>
1429   ],[
1430   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1431  ],[
1432   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1433  ],[
1434   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1435  ])
1436
1437 else
1438   AC_MSG_CHECKING(whether to enable windows workarounds)
1439   AC_ARG_ENABLE([windows_workarounds],
1440      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1441      [enable_workarounds=${enableval}],
1442      [enable_workarounds=no])
1443   AC_MSG_RESULT($enable_workarounds)
1444   if test x$enable_windows_workarounds = "xyes"
1445   then
1446      workarounds=1
1447   else
1448      workarounds=0
1449    fi
1450 fi
1451 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1452
1453 # gcov compilation
1454 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1455 AC_ARG_ENABLE([coverage],
1456               AS_HELP_STRING([--enable-coverage],
1457                              [compile the library with code coverage support]),
1458               [use_gcov=${enableval}],
1459               [use_gcov=no])
1460 AC_MSG_RESULT($use_gcov)
1461 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1462
1463
1464 # version info
1465 AC_PATH_PROG(svnversioncommand, svnversion)
1466 AC_PATH_PROG(gitcommand, git)
1467 AC_MSG_CHECKING(for source being under a VCS)
1468 svn_version=
1469 gitsvn_version=
1470 AS_IF([test ! "X$svnversioncommand" = "X"],
1471 [
1472   svn_version=$(cd $srcdir ; $svnversioncommand -n 2>/dev/null)
1473 ])
1474 AS_IF([test ! "X$gitcommand" = "X"],
1475 [
1476   gitsvn_version=$(cd $srcdir ; git log -1 2>/dev/null | grep "git-svn-id" | sed -e 's/.*@\([[0-9]]\+\) .*/\1/')
1477 ])
1478 AS_IF([test "X$svn_version" = "X" -o "X$svn_version" = "Xexported" -o "X$svn_version" = "XUnversioned directory"],
1479 [
1480   AS_IF([test "X$gitsvn_version" = "X"],
1481   [
1482     vcs_name="no"
1483     vcs_version="\"release\""
1484   ],
1485   [
1486     vcs_name="yes, git-svn"
1487     vcs_version="\"svn-r$gitsvn_version\""
1488   ])
1489 ],
1490 [
1491   vcs_name="yes, svn"
1492   vcs_version="\"svn-r$svn_version\""
1493 ])
1494 AC_MSG_RESULT($vcs_name)
1495
1496 AC_MSG_CHECKING(VCS version)
1497 AC_MSG_RESULT($vcs_version)
1498 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1499
1500 AC_CONFIG_FILES([
1501 Makefile
1502 contrib/Makefile
1503 doc/Makefile
1504 doc/man/Makefile
1505 doc/doxygen/Makefile
1506 m4/Makefile
1507 po/Makefile.in
1508 src/Makefile
1509 src/arm/Makefile
1510 src/arm/arm.conf
1511 src/ats/Makefile
1512 src/ats/ats.conf
1513 src/ats-tool/Makefile
1514 src/ats-tests/Makefile
1515 src/block/Makefile
1516 src/cadet/Makefile
1517 src/cadet/cadet.conf
1518 src/core/Makefile
1519 src/core/core.conf
1520 src/consensus/Makefile
1521 src/consensus/consensus.conf
1522 src/conversation/Makefile
1523 src/conversation/conversation.conf
1524 src/datacache/Makefile
1525 src/datastore/Makefile
1526 src/datastore/datastore.conf
1527 src/dht/Makefile
1528 src/dht/dht.conf
1529 src/dns/Makefile
1530 src/dns/dns.conf
1531 src/dv/Makefile
1532 src/dv/dv.conf
1533 src/env/Makefile
1534 src/exit/Makefile
1535 src/fragmentation/Makefile
1536 src/fs/Makefile
1537 src/fs/fs.conf
1538 src/gns/Makefile
1539 src/gns/gns.conf
1540 src/gns/nss/Makefile
1541 src/gnsrecord/Makefile
1542 src/hello/Makefile
1543 src/identity/Makefile
1544 src/identity/identity.conf
1545 src/include/Makefile
1546 src/integration-tests/Makefile
1547 src/hostlist/Makefile
1548 src/multicast/Makefile
1549 src/multicast/multicast.conf
1550 src/mysql/Makefile
1551 src/namecache/Makefile
1552 src/namecache/namecache.conf
1553 src/namestore/Makefile
1554 src/namestore/namestore.conf
1555 src/nat/Makefile
1556 src/nse/Makefile
1557 src/nse/nse.conf
1558 src/peerinfo/Makefile
1559 src/peerinfo/peerinfo.conf
1560 src/peerinfo-tool/Makefile
1561 src/peerstore/Makefile
1562 src/peerstore/peerstore.conf
1563 src/postgres/Makefile
1564 src/psyc/Makefile
1565 src/psyc/psyc.conf
1566 src/psycstore/Makefile
1567 src/psycstore/psycstore.conf
1568 src/pt/Makefile
1569 src/regex/Makefile
1570 src/regex/regex.conf
1571 src/revocation/Makefile
1572 src/revocation/revocation.conf
1573 src/rps/Makefile
1574 src/rps/rps.conf
1575 src/secretsharing/Makefile
1576 src/secretsharing/secretsharing.conf
1577 src/sensor/Makefile
1578 src/sensor/sensor.conf
1579 src/sensordashboard/Makefile
1580 src/sensordashboard/sensordashboard.conf
1581 src/scalarproduct/Makefile
1582 src/scalarproduct/scalarproduct.conf
1583 src/set/Makefile
1584 src/set/set.conf
1585 src/social/Makefile
1586 src/social/social.conf
1587 src/statistics/Makefile
1588 src/statistics/statistics.conf
1589 src/template/Makefile
1590 src/testbed/Makefile
1591 src/testbed/testbed.conf
1592 src/testing/Makefile
1593 src/topology/Makefile
1594 src/transport/Makefile
1595 src/transport/transport.conf
1596 src/tun/Makefile
1597 src/util/Makefile
1598 src/util/resolver.conf
1599 src/vpn/Makefile
1600 src/vpn/vpn.conf
1601 src/rest/Makefile
1602 pkgconfig/Makefile
1603 pkgconfig/gnunetarm.pc
1604 pkgconfig/gnunetats.pc
1605 pkgconfig/gnunetblock.pc
1606 pkgconfig/gnunetcadet.pc
1607 pkgconfig/gnunetconsensus.pc
1608 pkgconfig/gnunetconversation.pc
1609 pkgconfig/gnunetcore.pc
1610 pkgconfig/gnunetdatacache.pc
1611 pkgconfig/gnunetdatastore.pc
1612 pkgconfig/gnunetdht.pc
1613 pkgconfig/gnunetdns.pc
1614 pkgconfig/gnunetdnsparser.pc
1615 pkgconfig/gnunetdnsstub.pc
1616 pkgconfig/gnunetdv.pc
1617 pkgconfig/gnunetenv.pc
1618 pkgconfig/gnunetfragmentation.pc
1619 pkgconfig/gnunetfs.pc
1620 pkgconfig/gnunetgns.pc
1621 pkgconfig/gnunethello.pc
1622 pkgconfig/gnunetidentity.pc
1623 pkgconfig/gnunetmicrophone.pc
1624 pkgconfig/gnunetmulticast.pc
1625 pkgconfig/gnunetmysql.pc
1626 pkgconfig/gnunetnamestore.pc
1627 pkgconfig/gnunetnat.pc
1628 pkgconfig/gnunetnse.pc
1629 pkgconfig/gnunetpeerinfo.pc
1630 pkgconfig/gnunetpostgres.pc
1631 pkgconfig/gnunetpsyc.pc
1632 pkgconfig/gnunetpsycstore.pc
1633 pkgconfig/gnunetregex.pc
1634 pkgconfig/gnunetrevocation.pc
1635 pkgconfig/gnunetrps.pc
1636 pkgconfig/gnunetscalarproduct.pc
1637 pkgconfig/gnunetset.pc
1638 pkgconfig/gnunetsocial.pc
1639 pkgconfig/gnunetspeaker.pc
1640 pkgconfig/gnunetstatistics.pc
1641 pkgconfig/gnunettestbed.pc
1642 pkgconfig/gnunettesting.pc
1643 pkgconfig/gnunettransport.pc
1644 pkgconfig/gnunettun.pc
1645 pkgconfig/gnunetutil.pc
1646 pkgconfig/gnunetvpn.pc
1647 ])
1648 AC_OUTPUT
1649
1650 # Finally: summary!
1651
1652 # warn user if mysql found but not used due to version
1653 if test "$mysqlfail" = "true"
1654 then
1655   AC_MSG_NOTICE([NOTICE: MySQL found, but too old. MySQL support will not be compiled.])
1656 fi
1657
1658 # sqlite
1659 if test "x$sqlite" = "x0"
1660 then
1661   AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1662 fi
1663
1664 # libgnurl
1665 if test "x$gnurl" = "xfalse"
1666 then
1667   if test "x$curl" = "xfalse"
1668   then
1669     AC_MSG_NOTICE([NOTICE: libgnurl not found.  http client support will not be compiled.])
1670     AC_MSG_WARN([ERROR: libgnurl not found.  hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1671   else
1672     AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1673   fi
1674 fi
1675
1676
1677 # bluetooth
1678 if test "x$bluetooth" = "x0"
1679 then
1680   AC_MSG_NOTICE([NOTICE: bluetooth library not found.  bluetooth support will not be compiled.])
1681 fi
1682
1683 #gnutls
1684 if test x$gnutls != xtrue
1685 then
1686   AC_MSG_NOTICE([NOTICE: GnuTLS not found, gnunet-gns-proxy will not be built])
1687 else
1688 if test "x$gnutls_dane" != "x1"
1689 then
1690   AC_MSG_NOTICE([NOTICE: GnuTLS has no DANE support, DANE validation will not be possible])
1691 fi
1692 fi
1693
1694 # java ports
1695 if test "x$enable_java_ports" = "xyes"
1696 then
1697   AC_MSG_NOTICE([NOTICE: opening ports for gnunet-java bindings by default.])
1698 fi
1699
1700 # MHD
1701 if test "x$lmhd" != "x1"
1702 then
1703  AC_MSG_NOTICE([NOTICE: libmicrohttpd not found, http transport will not be installed.])
1704 fi
1705
1706 # conversation
1707 if test "x$conversation_backend" = "xnone"
1708 then
1709   if test "x$pulse" != "x1"
1710   then
1711     AC_MSG_NOTICE([NOTICE: libpulse(audio) not found, conversation will not be built.])
1712   fi
1713   if test "x$opus" != "x1"
1714   then
1715    AC_MSG_NOTICE([NOTICE: libopus not found, conversation will not be built.])
1716   fi
1717   if test "x$gst" != "x1"
1718   then
1719    AC_MSG_NOTICE([NOTICE: GStreamer not found, conversation will not be built.])
1720   fi
1721 fi
1722
1723 if test "$extractor" != 1
1724 then
1725  AC_MSG_WARN([NOTICE: libextractor not found, but various file-sharing functions require it])
1726 fi
1727
1728 AC_MSG_NOTICE([NOTICE: Database support is set to MySQL: $mysql, SQLite: $sqlite, Postgres: $postgres])
1729
1730 if test "$enable_framework_build" = "yes"
1731 then
1732   AC_MSG_NOTICE([NOTICE: Mac OS X framework build enabled.])
1733 fi
1734
1735 if test "x$SUDO_BINARY" = "x" -a ! -w /
1736 then
1737   AC_MSG_NOTICE([NOTICE: --with-sudo not specified and not running as 'root', will not install GNS NSS library])
1738 fi
1739
1740
1741 AC_MSG_NOTICE([********************************************
1742 Please make sure NOW that you have created a user and group 'gnunet'
1743 and additionally a group 'gnunetdns':
1744         addgroup gnunetdns
1745         adduser gnunet
1746
1747 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1748 'gnunet'.  Then, you can compile GNUnet with
1749         make
1750
1751 After that, run (if necessary as 'root')
1752         make install
1753 to install everything.
1754
1755 Each GNUnet user should be added to the 'gnunet' group (may
1756 require fresh login to come into effect):
1757         adduser USERNAME gnunet
1758 (run the above command as root once for each of your users, replacing
1759 "USERNAME" with the respective login names).  If you have a global IP
1760 address, no further configuration is required.
1761
1762 Optionally, download and compile gnunet-gtk to get a GUI for
1763 file-sharing and configuration.  This is particularly recommended
1764 if your network setup is non-trivial, as gnunet-setup can be
1765 used to test in the GUI if your network configuration is working.
1766 gnunet-setup should be run as the "gnunet" user under X.  As it
1767 does very little with the network, running it as "root" is likely
1768 also harmless.  You can also run it as a normal user, but then
1769 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
1770 home directory in the end.
1771
1772 Once you have configured your peer, run (as the 'gnunet' user)
1773         gnunet-arm -s
1774 to start the peer.  You can then run the various GNUnet-tools as
1775 your "normal" user (who should only be in the group 'gnunet').
1776 ********************************************])