configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2016 GNUnet e.V.
   3 #
   4 # GNUnet is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published
   6 # by the Free Software Foundation; either version 3, or (at your
   7 # option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with GNUnet; see the file COPYING.  If not, write to the
  16 # Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  17 # Boston, MA 02110-1301, USA.
  18 #
  19 #
  20 # Process this file with autoconf to produce a configure script.
  21 #
  22 #
  23 AC_PREREQ(2.61)
  24 # Checks for programs.
  25 AC_INIT([gnunet], [0.10.1], [bug-gnunet@gnu.org])
  26
  27 AC_CANONICAL_TARGET
  28 AC_CANONICAL_HOST
  29 AC_CANONICAL_SYSTEM
  30
  31 AM_INIT_AUTOMAKE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33 AC_CONFIG_HEADERS([gnunet_config.h])
  34 AH_TOP([#define _GNU_SOURCE  1])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_PROG_AWK
  37 AC_PROG_CC
  38 AC_PROG_CPP
  39 AC_PROG_CXX
  40 AC_PROG_OBJC
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AM_PROG_CC_C_O
  45 LT_INIT([disable-static dlopen win32-dll])
  46 AC_SUBST(MKDIR_P)
  47
  48 # large file support
  49 AC_SYS_LARGEFILE
  50 AC_FUNC_FSEEKO
  51
  52
  53 CFLAGS="-Wall $CFLAGS"
  54 # use '-fno-strict-aliasing', but only if the compiler can take it
  55 if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
  56 then
  57  CFLAGS="-fno-strict-aliasing $CFLAGS"
  58 fi
  59
  60 # Use Linux interface name unless the OS has a different preference
  61 DEFAULT_INTERFACE="\"eth0\""
  62
  63 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo"
  64
  65 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  66 native_srcdir=$srcdir
  67
  68 # Check system type
  69 case "$host_os" in
  70 *darwin* | *rhapsody* | *macosx*)
  71      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  72      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  73      CFLAGS="-fno-common $CFLAGS"
  74      AC_MSG_WARN([The VPN application cannot be compiled on your OS])
  75      build_target="darwin"
  76      DEFAULT_INTERFACE="\"en0\""
  77      LIBPREFIX=
  78      DLLDIR=lib
  79      UNIXONLY="#"
  80      ;;
  81 linux*)
  82      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
  83      build_target="linux"
  84      LIBPREFIX=
  85      DLLDIR=lib
  86      UNIXONLY="#"
  87      AC_PATH_XTRA
  88      ;;
  89 *freebsd*)
  90      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  91      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
  92      CFLAGS="-D_THREAD_SAFE $CFLAGS"
  93      build_target="freebsd"
  94      LIBPREFIX=
  95      DLLDIR=lib
  96      UNIXONLY="#"
  97      ;;
  98 *openbsd*)
  99      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 100      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 101      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 102      build_target="openbsd"
 103      LIBPREFIX=
 104      DLLDIR=lib
 105      UNIXONLY="#"
 106      ;;
 107 *netbsd*)
 108      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 109      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 110      LIBPREFIX=
 111      DLLDIR=lib
 112      UNIXONLY="#"
 113      ;;
 114 *solaris*)
 115      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 116      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 117      AC_CHECK_LIB(resolv, res_init)
 118      AC_CHECK_LIB(rt, nanosleep)
 119      build_target="solaris"
 120      LIBPREFIX=
 121      DLLDIR=lib
 122      UNIXONLY="#"
 123      ;;
 124 *arm-linux*)
 125      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 126      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 127      build_target="linux"
 128      LIBPREFIX=
 129      DLLDIR=lib
 130      UNIXONLY="#"
 131      ;;
 132 *cygwin*)
 133      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 134      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 135      AC_CHECK_LIB(intl, gettext)
 136      CFLAGS="-mms-bitfields $CFLAGS"
 137      build_target="cygwin"
 138      LIBPREFIX=lib
 139      DLLDIR=bin
 140      AC_PROG_CXX
 141      UNIXONLY=""
 142      ;;
 143 *mingw*)
 144      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 145      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 146      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 147      AC_CHECK_LIB(intl, gettext)
 148      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 149      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 150      CFLAGS="-mms-bitfields $CFLAGS"
 151      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 152      build_target="mingw"
 153      AC_PROG_CXX
 154      LIBPREFIX=lib
 155      DLLDIR=bin
 156      UNIXONLY=""
 157      funcstocheck=""
 158      native_srcdir=$(cd $srcdir; pwd -W)
 159      ;;
 160 gnu*)
 161      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 162      build_target="gnu"
 163      UNIXONLY="#"
 164      ;;
 165 *)
 166      AC_MSG_RESULT(Unrecognised OS $host_os)
 167      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 168      UNIXONLY=""
 169 ;;
 170 esac
 171 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 172 AC_SUBST(DEFAULT_INTERFACE)
 173
 174 # Disable TCP-based IPC on systems that support UNIX domain
 175 # sockets in default configuratin:
 176 AC_SUBST(UNIXONLY)
 177
 178
 179 AC_MSG_CHECKING([for build target])
 180 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 181 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 182 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 183 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 184 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 185 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 186 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 187 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 188
 189 AC_MSG_RESULT([$build_target])
 190 AC_SUBST(build_target)
 191 AM_CONDITIONAL([am__fastdepOBJC], false)
 192 AC_UNALIGNED_64_ACCESS
 193
 194 # some other checks for standard libs
 195 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 196 AC_CHECK_LIB(socket, socket)
 197 AC_CHECK_LIB(m, log)
 198 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 199
 200 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 201 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 202
 203 AC_CHECK_PROG(VAR_SSH_BINARY,ssh,true,false)
 204 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 205 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 206 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 207
 208
 209 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 210   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 211      [Define if struct tm has the tm_gmtoff member.])],
 212      ,
 213      [#include <time.h>])
 214
 215 AC_CHECK_DECLS([_stati64])
 216
 217 # 'save' libs; only those libs found so far will be
 218 # linked against _everywhere_.  For the others, we
 219 # will be more selective!
 220 SAVE_LIBS=$LIBS
 221
 222 # tests only run on Windows
 223 if test "x$build_target" = "xmingw"
 224 then
 225   AC_CHECK_LIB(plibc, plibc_init, [], [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 226   AC_CHECK_LIB(gnurx, regexec, [], [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])
 227 fi
 228
 229 # libgcrypt
 230 gcrypt=0
 231 NEED_LIBGCRYPT_API=1
 232 NEED_LIBGCRYPT_VERSION=1.6.0
 233
 234
 235 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 236 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 237
 238 if test $gcrypt = 0
 239 then
 240   AC_MSG_ERROR([[
 241 ***
 242 *** You need libgcrypt to build this program.
 243 **  This library is for example available at
 244 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 245 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 246 ***  is required.)
 247 ***]])
 248 fi
 249 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 250
 251 # Adam shostack suggests the following for Windows:
 252 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 253 AC_ARG_ENABLE(gcc-hardening,
 254    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 255 [if test x$enableval = xyes; then
 256     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 257     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 258     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 259     LDFLAGS="$LDFLAGS -pie"
 260 fi])
 261
 262
 263 # Linker hardening options
 264 # Currently these options are ELF specific - you can't use this with MacOSX
 265 AC_ARG_ENABLE(linker-hardening,
 266   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 267 [if test x$enableval = xyes; then
 268    LDFLAGS="$LDFLAGS -z relro -z now"
 269 fi])
 270
 271
 272 extra_logging=GNUNET_NO
 273 AC_ARG_ENABLE([logging],
 274    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 275    [AS_IF([test "x$enableval" = "xyes"], [],
 276           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 277           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 278           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 279    ], [])
 280 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 281
 282 # should memory poisoning be enabled?
 283 AC_MSG_CHECKING(whether to poison freed memory)
 284 AC_ARG_ENABLE([poisoning],
 285    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 286    [enable_poisoning=${enableval}],
 287    [
 288      if test "x$extra_logging" != "xGNUNET_NO"; then
 289        enable_poisoning="defaults to yes (extra logging is enabled)"
 290      else
 291        enable_poisoning=no
 292      fi
 293    ])
 294 AC_MSG_RESULT($enable_poisoning)
 295 if test ! "x$enable_poisoning" = "xno"; then
 296   enable_poisoning=1
 297 else
 298   enable_poisoning=0
 299 fi
 300 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 301
 302 if test $build = $target
 303 then
 304 AC_MSG_CHECKING([for working HMAC])
 305 AC_LANG_PUSH(C)
 306 LIBS="$LIBS $LIBGCRYPT_LIBS"
 307 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 308 AC_RUN_IFELSE(
 309   [AC_LANG_PROGRAM([#include <gcrypt.h>
 310         #include <stdio.h>], [[
 311         gcry_md_hd_t mac;
 312
 313         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 314             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 315             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 316         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 317         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 318             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 319             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 320             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 321             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 322             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 323
 324         if (!gcry_check_version (GCRYPT_VERSION))
 325         {
 326           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 327           return 1;
 328         }
 329
 330         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 331         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 332
 333         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 334         {
 335           fprintf (stderr, "gcry_md_open error\n");
 336           return 2;
 337         }
 338
 339         gcry_md_setkey (mac, key, sizeof (key));
 340         gcry_md_write (mac, data, sizeof (data));
 341
 342         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 343         {
 344           fprintf (stderr, "memcmp error\n");
 345           return 3;
 346         }
 347
 348         gcry_md_close (mac);
 349
 350         return 0;
 351     ]])],
 352   [AC_MSG_RESULT([yes])],
 353   [
 354    RESULT=$?
 355    if test $RESULT = 3
 356    then
 357      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 358    fi
 359    if test $RESULT = 2
 360    then
 361      AC_MSG_FAILURE([HMAC test failed])
 362    fi
 363    if test $RESULT = 1
 364    then
 365      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 366    fi
 367   ],
 368   [AC_MSG_RESULT([cross compiling, test skipped])])
 369 AC_LANG_POP(C)
 370 fi      # $build = $target
 371
 372 # check for bluetooth library
 373 bluetooth=0
 374 AC_CHECK_LIB(bluetooth, ba2str,[AC_CHECK_HEADER([bluetooth/bluetooth.h],bluetooth=1)])
 375 if test "$build_target" = "mingw"
 376 then
 377   bluetooth=1
 378 fi
 379 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 380 if test "$bluetooth" = 1
 381 then
 382   AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])
 383 else
 384   AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])
 385 fi
 386
 387 # check for jansson library
 388 jansson=0
 389 AC_CHECK_HEADER([jansson.h],jansson=1)
 390 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 391 if test "x$jansson" = x1
 392 then
 393   AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])
 394 else
 395   AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])
 396 fi
 397
 398 # check for libpulse(audio) library
 399 pulse=0
 400 AC_CHECK_LIB(pulse,pa_stream_peek,
 401   [AC_CHECK_HEADER([pulse/simple.h],pulse=1)])
 402 if test "$build_target" = "mingw"
 403 then
 404   pulse=0
 405 fi
 406 if test "$pulse" = 1
 407 then
 408   AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 409 fi
 410
 411 # check for libopus(audio) library
 412 opus=0
 413 AC_CHECK_LIB(opus,opus_decode_float,
 414   [AC_CHECK_HEADER([opus/opus.h],
 415     [AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]
 416     )]
 417   )]
 418 )
 419 if test "$opus" = 1
 420 then
 421   AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 422 fi
 423
 424 # libogg
 425 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 426         [AC_CHECK_HEADERS([ogg/ogg.h],
 427           AM_CONDITIONAL(HAVE_OGG, true)
 428           ogg=1
 429           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 430           AM_CONDITIONAL(HAVE_OGG, false)
 431           ogg=0
 432           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 433         AM_CONDITIONAL(HAVE_OGG, false)
 434         ogg=0)
 435
 436
 437
 438 gst=0
 439 PKG_CHECK_MODULES(
 440   [GST],
 441   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 442   [
 443     gst=1
 444     AC_MSG_RESULT(ok)
 445   ], [
 446     gst=0
 447     AC_MSG_RESULT(not found)
 448   ])
 449
 450 # Pulse Audio
 451 if test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"
 452 then
 453  if test "x$gst" != "x1"
 454  then
 455   conversation_backend=none
 456   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 457   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 458   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 459  else
 460    conversation_backend=gst
 461    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 462    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 463    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 464  fi
 465 else
 466
 467  conversation_backend=pulse
 468  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 469  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 470  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 471 fi
 472
 473 # libgnurl
 474 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 475 if test "$gnurl" = 1
 476 then
 477         AM_CONDITIONAL(HAVE_LIBGNURL, true)
 478         AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 479 else
 480         AM_CONDITIONAL(HAVE_LIBGNURL, false)
 481         AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 482 fi
 483
 484 SAVE_CPPFLAGS=$CPPFLAGS
 485 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 486 LIBS="$LIBGNURL $LIBCURL $LIBS"
 487
 488 # libcurl-gnutls
 489 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 490 if test "x$curl" = xtrue
 491 then
 492
 493  AC_CHECK_HEADERS([curl/curl.h],
 494   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 495   [curl=false])
 496  AC_CHECK_HEADERS([gnurl/curl.h],
 497   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],,[[#include <gnurl/curl.h>]]))
 498  # need libcurl-gnutls.so, everything else is not acceptable
 499  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 500  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 501 fi
 502
 503 # Check for curl/curl.h and gnurl/curl.h so we can use #ifdef
 504 # HAVE_CURL_CURL_H later (the above LIBCURL_CHECK_CONFIG accepted
 505 # *either* header set).
 506 AC_CHECK_HEADERS([curl/curl.h],,
 507   curl=false
 508   AC_CHECK_HEADERS([gnurl/curl.h],,
 509   gnurl=false))
 510
 511
 512
 513 if test x$curl = xfalse
 514 then
 515         AM_CONDITIONAL(HAVE_LIBCURL, false)
 516 if test "$gnurl" = 0
 517 then
 518         AC_MSG_WARN([GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 519 fi
 520 else
 521         AM_CONDITIONAL(HAVE_LIBCURL, true)
 522         AC_DEFINE([HAVE_LIBCURL],[1],[Have CURL])
 523 fi
 524
 525
 526 # restore LIBS & CPPFLAGS
 527 LIBS=$SAVE_LIBS
 528 CPPFLAGS=$SAVE_CPPFLAGS
 529
 530 AC_CHECK_HEADERS([glpk.h],[glpk=true],[gplk=false])
 531 # GLPK must support glpk_init_env, version >= 4.43
 532 AC_CHECK_LIB([glpk],[glp_init_env],,[gplk=false])
 533 # GLPK must support atm MLP presolving, version >= 4.32
 534 AC_CHECK_MEMBERS(glp_iocp.presolve,,[gplk=false],[[#include <glpk.h>]])
 535 if test x$gplk = xfalse
 536 then
 537         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 538         AC_MSG_WARN([GNUnet requires GLPK  >= 4.32])
 539 else
 540         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 541         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 542 fi
 543
 544
 545
 546 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 547 if test x$nss = xfalse
 548 then
 549         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 550         AC_MSG_WARN([No GNU libc nss header, will not build NSS plugin])
 551 else
 552         AM_CONDITIONAL(HAVE_GLIBCNSS, true)
 553 fi
 554
 555
 556
 557 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 558 AC_CHECK_LIB([kvm],[kvm_open])
 559 AC_CHECK_LIB([kstat],[kstat_open])
 560
 561
 562 # should the build process be restricted to the code required
 563 # for GNU Taler wallets?
 564 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 565 AC_ARG_ENABLE([taler-wallet],
 566    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 567    [taler_only=${enableval}],
 568    [taler_only=no])
 569 AC_MSG_RESULT($taler_only)
 570 AM_CONDITIONAL([TALER_ONLY], [test "x$taler_only" = "xyes"])
 571
 572 # test for libextractor
 573 extractor=0
 574 AC_MSG_CHECKING(for libextractor)
 575 AC_ARG_WITH(extractor,
 576    [  --with-extractor=PFX    base of libextractor installation],
 577    [AC_MSG_RESULT([$with_extractor])
 578     case $with_extractor in
 579       no)
 580         ;;
 581       yes)
 582         AC_CHECK_HEADERS(extractor.h,
 583           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 584             extractor=1))
 585         ;;
 586       *)
 587         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 588         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 589         AC_CHECK_HEADERS(extractor.h,
 590           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 591             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 592             extractor=1))
 593         ;;
 594     esac
 595    ],
 596    [AC_MSG_RESULT([--with-extractor not specified])
 597     AC_CHECK_HEADERS(extractor.h,
 598      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 599       extractor=1))])
 600 # restore LIBS
 601 LIBS=$SAVE_LIBS
 602
 603 if test "$extractor" != 1
 604 then
 605  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 606  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 607 else
 608  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 609  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 610 fi
 611
 612
 613 if test "$taler_only" != yes
 614 then
 615
 616 # Check for libltdl header (#2999)
 617 ltdl=0
 618 AC_MSG_CHECKING(for libltdl)
 619 AC_ARG_WITH(ltdl,
 620    [  --with-ltdl=PFX    base of libltdl installation],
 621    [AC_MSG_RESULT([$with_ltdl])
 622     case $with_ltdl in
 623       no)
 624         ;;
 625       yes)
 626         AC_CHECK_HEADERS(ltdl.h,
 627           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 628             ltdl=1))
 629         ;;
 630       *)
 631         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 632         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 633         AC_CHECK_HEADERS(ltdl.h,
 634           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 635             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 636             ltdl=1))
 637         ;;
 638     esac
 639    ],
 640    [AC_MSG_RESULT([--with-ltdl not specified])
 641     AC_CHECK_HEADERS(ltdl.h,
 642      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 643       ltdl=1))])
 644 if test x$ltdl = x1
 645 then
 646  AC_MSG_RESULT([libltdl found])
 647 else
 648  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 649 fi
 650 # restore LIBS
 651 LIBS=$SAVE_LIBS
 652
 653
 654 # libidn
 655 AC_MSG_CHECKING([if Libidn can be used])
 656 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 657                                     [Support IDN (needs GNU Libidn)]),
 658 libidn=$withval, libidn=yes)
 659 if test "$libidn" != "no"; then
 660   if test "$libidn" != "yes"; then
 661      LDFLAGS="${LDFLAGS} -L$libidn/lib"
 662      CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 663   fi
 664 fi
 665 libidn=no
 666 AC_CHECK_HEADER(idna.h,
 667   AC_CHECK_LIB(idn, stringprep_check_version,
 668     [libidn=yes LIBS="${LIBS} -lidn"], []), [])
 669 if test "$libidn" != "yes"; then
 670   AC_MSG_FAILURE([GNUnet requires libidn.
 671 libidn-1.13 should be sufficient, newer versions work too.])
 672 fi
 673 AC_MSG_RESULT($libidn)
 674
 675
 676 # test for zlib
 677 SAVE_LDFLAGS=$LDFLAGS
 678 SAVE_CPPFLAGS=$CPPFLAGS
 679 AC_ARG_WITH(zlib,
 680             [  --with-zlib[[=DIR]]       use libz in DIR],
 681             [AS_IF([test "$withval" = "no"],
 682                    [AC_MSG_ERROR([GNUnet requires zlib])],
 683                    [test "$withval" != "yes"],
 684                    [
 685                      Z_DIR=$withval
 686                      CPPFLAGS="${CPPFLAGS} -I$withval/include"
 687                      LDFLAGS="${LDFLAGS} -L$withval/lib"
 688                    ])
 689             ])
 690 AC_CHECK_HEADER(zlib.h,
 691                 [],
 692                 [AC_MSG_ERROR([GNUnet requires zlib])])
 693 AC_CHECK_LIB(z, compress2,
 694              [
 695               AC_DEFINE([HAVE_ZLIB], [], [Have compression library])
 696               if test "x${Z_DIR}" != "x"; then
 697                       Z_CFLAGS="-I${Z_DIR}/include"
 698                       Z_LIBS="-L${Z_DIR}/lib -lz"
 699               else
 700                       Z_LIBS="-lz"
 701               fi],
 702               [AC_MSG_ERROR([GNUnet requires zlib])])
 703 AC_SUBST(Z_CFLAGS)
 704 AC_SUBST(Z_LIBS)
 705
 706 if test "$enable_shared" = "no"
 707 then
 708  AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])
 709 fi
 710
 711
 712
 713 # restore LIBS
 714 LIBS=$SAVE_LIBS
 715
 716
 717 fi
 718
 719 # check for iconv
 720 AM_ICONV
 721
 722 # test for libunistring
 723 gl_LIBUNISTRING
 724 if test $HAVE_LIBUNISTRING != yes; then
 725  AC_MSG_ERROR([GNUnet requires libunistring])
 726 fi
 727 if test $gl_libunistring_hexversion -le 2305; then
 728  AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])
 729 fi
 730 # restore LIBS
 731 LIBS=$SAVE_LIBS
 732
 733
 734
 735 # Checks for standard header files.
 736 AC_HEADER_DIRENT
 737 AC_HEADER_STDC
 738
 739 # Check for headers that are ALWAYS required
 740 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files]))
 741
 742
 743
 744 # Checks for headers that are only required on some systems or opional (and where we do NOT abort if they are not there)
 745 AC_CHECK_HEADERS([malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
 746
 747 # FreeBSD requires something more funky for netinet/in_systm.h and netinet/ip.h...
 748 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
 749 [#ifdef HAVE_SYS_TYPES_H
 750 #include <sys/types.h>
 751 #endif
 752 #ifdef HAVE_NETINET_IN_SYSTM_H
 753 #include <netinet/in_systm.h>
 754 #endif
 755 #ifdef HAVE_NETINET_IN_H
 756 #include <netinet/in.h>
 757 #endif
 758 ])
 759
 760 SAVE_LDFLAGS=$LDFLAGS
 761 SAVE_CPPFLAGS=$CPPFLAGS
 762
 763 # test for sqlite
 764 sqlite=false
 765 AC_MSG_CHECKING(for SQLite)
 766 AC_ARG_WITH(sqlite,
 767   [  --with-sqlite=PFX       base of SQLite installation],
 768   [AC_MSG_RESULT("$with_sqlite")
 769    case $with_sqlite in
 770    no)
 771      ;;
 772    yes)
 773     AC_CHECK_HEADERS(sqlite3.h,
 774      sqlite=true)
 775      ;;
 776    *)
 777     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
 778     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
 779     AC_CHECK_HEADERS(sqlite3.h,
 780      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
 781      SQLITE_LDFLAGS="-L$with_sqlite/lib"
 782      SQLITE_CPPFLAGS="-I$with_sqlite/include"
 783      sqlite=true)
 784     LDFLAGS=$SAVE_LDFLAGS
 785     CPPFLAGS=$SAVE_CPPFLAGS
 786     ;;
 787    esac
 788   ],
 789   [AC_MSG_RESULT([--with-sqlite not specified])
 790     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
 791 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
 792 AC_SUBST(SQLITE_CPPFLAGS)
 793 AC_SUBST(SQLITE_LDFLAGS)
 794
 795 # test for postgres
 796 postgres=false
 797 AX_LIB_POSTGRESQL([])
 798 if test "$found_postgresql" = "yes"; then
 799   CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
 800   AC_CHECK_HEADERS([libpq-fe.h],
 801     postgres=true)
 802 fi
 803
 804 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
 805
 806
 807 LDFLAGS=$SAVE_LDFLAGS
 808 CPPFLAGS=$SAVE_CPPFLAGS
 809
 810 # mysql & windows
 811 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
 812 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
 813
 814 if test "$build_target" = "mingw"
 815 then
 816   CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"
 817 fi
 818
 819 # test for mysql
 820 mysql=false
 821 mysqlfail=false
 822 SAVE_LDFLAGS=$LDFLAGS
 823 SAVE_CPPFLAGS=$CPPFLAGS
 824 AC_MSG_CHECKING(for mysql)
 825 AC_ARG_WITH(mysql,
 826   [  --with-mysql=PFX        base of MySQL installation],
 827   [AC_MSG_RESULT("$with_mysql")
 828    if test "$with_mysql" != "no"
 829    then
 830     if test "$with_mysql" != "yes"
 831     then
 832       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
 833       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
 834       AC_CHECK_HEADERS(mysql/mysql.h,
 835        AC_CHECK_LIB(mysqlclient, mysql_init,
 836         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
 837         MYSQL_CPPFLAGS="-I$with_mysql/include"
 838
 839         mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 840     fi
 841    fi
 842   ],
 843   [AC_MSG_RESULT([--with-mysql not specified])
 844    if test -d "/usr/lib64/mysql"; then
 845     MYSQL_LIBDIR="/usr/lib64/mysql"
 846    elif test -d "/usr/lib/mysql"; then
 847     MYSQL_LIBDIR="/usr/lib/mysql"
 848    else
 849     MYSQL_LIBDIR="/usr/lib"
 850    fi
 851    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
 852    AC_CHECK_LIB(mysqlclient, mysql_init,
 853     [AC_CHECK_HEADERS(mysql/mysql.h,
 854       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
 855       mysql=true
 856
 857      , [], [$CYGWIN_MYSQL_MAGIC])])
 858   ])
 859
 860 AC_SUBST(MYSQL_LDFLAGS)
 861 AC_SUBST(MYSQL_CPPFLAGS)
 862
 863 # additional version check for mysql
 864 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
 865 if test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"
 866 then
 867   AC_MSG_CHECKING(mysql version)
 868   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 869     [[$CYGWIN_MYSQL_MAGIC
 870       #include <mysql/mysql.h>]],
 871     [[
 872       #if (MYSQL_VERSION_ID < 40100)
 873       #error needs at least version >= 4.1
 874       #endif
 875       int main () { return 0; }
 876     ]])
 877     ],mysql=true,mysql=false)
 878   if test "$mysql" = "false"
 879   then
 880     mysqlfail=true
 881     AC_MSG_RESULT([fail, >= 4.1 required])
 882   else
 883     AC_MSG_RESULT(ok)
 884   fi
 885 fi
 886 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
 887 AM_CONDITIONAL(HAVE_MYSQLE, test "0" = "1")
 888 # restore LIBS
 889 LIBS=$SAVE_LIBS
 890 LDFLAGS=$SAVE_LDFLAGS
 891 CPPFLAGS=$SAVE_CPPFLAGS
 892
 893 if test "$sqlite" = 0 -a "$mysql" = 0
 894 then
 895  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
 896 fi
 897
 898 # libmicrohttpd
 899 lmhd=0
 900 AC_MSG_CHECKING([for libmicrohttpd])
 901 AC_ARG_WITH(microhttpd,
 902    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
 903    [AC_MSG_RESULT([$with_microhttpd])
 904     case $with_microhttpd in
 905       no)
 906         ;;
 907       yes)
 908         AC_CHECK_HEADERS([microhttpd.h],
 909           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 910             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 911               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 912               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 913                 #include "$native_srcdir/src/include/platform.h"
 914                 #include <microhttpd.h>
 915                 #if (MHD_VERSION < 0x0094200)
 916                 #error needs at least version 0.9.42
 917                 #endif
 918                 int main () { return 0; }
 919                ])],
 920                [AC_MSG_RESULT(ok)
 921                 lmhd=1],
 922                [AC_MSG_RESULT(failed)])]),
 923             [],[#include "$native_srcdir/src/include/platform.h"
 924                 #include <microhttpd.h>]),,
 925             [#include "$native_srcdir/src/include/platform.h"])
 926         ;;
 927       *)
 928         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
 929         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
 930         AC_CHECK_HEADERS(microhttpd.h,
 931           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 932             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 933               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
 934               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 935                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 936                 #include "$native_srcdir/src/include/platform.h"
 937                 #include <microhttpd.h>
 938                 #if (MHD_VERSION < 0x0094200)
 939                 #error needs at least version 0.9.42
 940                 #endif
 941                 int main () { return 0; }
 942                ])],
 943                [AC_MSG_RESULT(ok)
 944                 lmhd=1],
 945                [AC_MSG_RESULT(failed)])]),
 946             [],[#include "$native_srcdir/src/include/platform.h"
 947                 #include <microhttpd.h>]),,
 948             [#include "$native_srcdir/src/include/platform.h"])
 949         ;;
 950     esac
 951    ],
 952    [AC_MSG_RESULT([--with-microhttpd not specified])
 953     AC_CHECK_HEADERS([microhttpd.h],
 954       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 955         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 956           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 957               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 958                 #include "$native_srcdir/src/include/platform.h"
 959                 #include <microhttpd.h>
 960                 #if (MHD_VERSION < 0x0094200)
 961                 #error needs at least version 0.9.42
 962                 #endif
 963                ])],
 964                [AC_MSG_RESULT(ok)
 965                 lmhd=1],
 966                [AC_MSG_RESULT(failed)])]),
 967         [],[#include "$native_srcdir/src/include/platform.h"
 968             #include <microhttpd.h>]),,
 969        [#include "$native_srcdir/src/include/platform.h"])])
 970 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
 971 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
 972
 973 AM_CONDITIONAL(HAVE_REST, [test x$lmhd = x1 -a x$jansson = x1])
 974
 975 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
 976
 977 # restore LIBS
 978 LIBS=$SAVE_LIBS
 979
 980 # check for python & pexpect (used for some testcases only)
 981 AM_PATH_PYTHON([2.6],, [:])
 982 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 983
 984 # check for gettext
 985 AM_GNU_GETTEXT([external])
 986 AM_GNU_GETTEXT_VERSION([0.18.1])
 987
 988 # Checks for standard typedefs, structures, and compiler characteristics.
 989 AC_TYPE_PID_T
 990 AC_TYPE_SIZE_T
 991 AC_TYPE_MODE_T
 992 AC_HEADER_TIME
 993 AC_HEADER_STAT
 994 AC_HEADER_STDBOOL
 995 AC_STRUCT_TM
 996
 997 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 998    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
 999    ],
1000    [],
1001    [
1002       #include <sys/types.h>
1003       #include <sys/socket.h>
1004       #include <netinet/in.h>
1005    ])
1006
1007
1008
1009 # Checks for library functions.
1010 AC_FUNC_CLOSEDIR_VOID
1011 AC_FUNC_FORK
1012 AC_PROG_GCC_TRADITIONAL
1013 AC_FUNC_MEMCMP
1014 AC_FUNC_SELECT_ARGTYPES
1015 AC_FUNC_CHOWN
1016
1017 AC_TYPE_SIGNAL
1018 AC_FUNC_STAT
1019 AC_FUNC_STRFTIME
1020 AC_FUNC_VPRINTF
1021 AC_HEADER_SYS_WAIT
1022 AC_TYPE_OFF_T
1023 AC_TYPE_UID_T
1024 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1025
1026 # restore LIBS
1027 LIBS=$SAVE_LIBS
1028
1029 GN_INTLINCL=""
1030 GN_LIBINTL="$LTLIBINTL"
1031 AC_ARG_ENABLE(framework, [  --enable-framework      enable Mac OS X framework build helpers],enable_framework_build=$enableval)
1032 AM_CONDITIONAL(WANT_FRAMEWORK, test x$enable_framework_build = xyes)
1033 if test x$enable_framework_build = xyes
1034 then
1035   AC_DEFINE([FRAMEWORK_BUILD], 1, [Build a Mac OS X Framework])
1036   GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1037   GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1038   AC_LIB_APPENDTOVAR([CPPFLAGS], [$GN_INTLINCL])
1039 fi
1040
1041 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1042 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1043
1044 AC_SUBST(GN_LIB_LDFLAGS)
1045 AC_SUBST(GN_PLUGIN_LDFLAGS)
1046 AC_SUBST(GN_INTLINCL)
1047 AC_SUBST(GN_LIBINTL)
1048
1049 AC_SUBST(CPPFLAGS)
1050 AC_SUBST(LIBS)
1051 AC_SUBST(LDFLAGS)
1052 AC_SUBST(EXT_LIB_PATH)
1053 AC_SUBST(EXT_LIBS)
1054
1055 AC_SUBST(LIBPREFIX)
1056 AC_SUBST(DLLDIR)
1057 AC_SUBST(EXT_LIB_PATH)
1058
1059
1060 # test for sudo
1061 AC_MSG_CHECKING(for sudo)
1062 AC_ARG_WITH(sudo,
1063   [  --with-sudo=PATH       path to sudo binary (or just yes)],
1064   [AC_MSG_RESULT("$with_sudo")
1065    case $with_sudo in
1066    no)
1067      SUDO_BINARY=
1068      ;;
1069    yes)
1070      SUDO_BINARY=sudo
1071      ;;
1072    *)
1073      SUDO_BINARY=$with_sudo
1074     ;;
1075    esac
1076   ],
1077   [AC_MSG_RESULT([no])])
1078 AC_SUBST(SUDO_BINARY)
1079 AM_CONDITIONAL([HAVE_SUDO], [test "x$SUDO_BINARY" != "x" -o -w /])
1080
1081
1082 # test for nssdir
1083 AC_MSG_CHECKING(with nssdir)
1084 AC_ARG_WITH(nssdir,
1085   [  --with-nssdir=PATH       where to install NSS plugins],
1086   [AC_MSG_RESULT("$with_nssdir")
1087    case $with_nssdir in
1088    no)
1089      NSS_DIR=
1090      install_nss=0
1091      ;;
1092    yes)
1093      NSS_DIR="/lib"
1094      install_nss=1
1095      ;;
1096    *)
1097      NSS_DIR=$with_nssdir
1098      install_nss=1
1099     ;;
1100    esac
1101   ],
1102   [
1103    if test "x$SUDO_BINARY" != "x" -o -w /
1104    then
1105      NSS_DIR="/lib"
1106      install_nss=1
1107      AC_MSG_RESULT([yes, to /lib])
1108    else
1109      NSS_DIR=
1110      install_nss=0
1111      AC_MSG_RESULT([no])
1112    fi
1113   ])
1114 AC_SUBST(NSS_DIR)
1115 AM_CONDITIONAL([INSTALL_NSS], [test "x$install_nss" != "x0"])
1116
1117 # test for gnunetdns group name
1118 GNUNETDNS_GROUP=gnunetdns
1119 AC_MSG_CHECKING(for gnunetdns group name)
1120 AC_ARG_WITH(gnunetdns,
1121   [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1122   [AC_MSG_RESULT("$with_gnunetdns")
1123    case $with_gnunetdns in
1124    no)
1125      GNUNETDNS_GROUP=gnunet
1126      ;;
1127    yes)
1128      GNUNETDNS_GROUP=gnunetdns
1129      ;;
1130    *)
1131      GNUNETDNS_GROUP=$with_gnunetdns
1132     ;;
1133    esac
1134   ],
1135   [AC_MSG_RESULT([gnunetdns])])
1136 AC_SUBST(GNUNETDNS_GROUP)
1137
1138
1139
1140 # gnutls
1141 gnutls=0
1142 gnutls_dane=0
1143 AC_MSG_CHECKING(for gnutls)
1144 AC_ARG_WITH(gnutls,
1145    [  --with-gnutls=PFX   base of gnutls installation],
1146    [AC_MSG_RESULT([$with_gnutls])
1147     case $with_gnutls in
1148       no)
1149         ;;
1150       yes)
1151         AC_CHECK_HEADERS([gnutls/abstract.h],
1152             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1153              gnutls=true))
1154         AC_CHECK_HEADERS([gnutls/dane.h],
1155             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1156               gnutls_dane=1))
1157         ;;
1158       *)
1159         LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1160         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1161         AC_CHECK_HEADERS([gnutls/abstract.h],
1162             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1163               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1164               gnutls=true))
1165         AC_CHECK_HEADERS([gnutls/dane.h],
1166             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1167               gnutls_dane=1))
1168         ;;
1169     esac
1170    ],
1171    [AC_MSG_RESULT([--with-gnutls not specified])
1172     AC_CHECK_HEADERS([gnutls/abstract.h],
1173         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1174           gnutls=true))
1175     AC_CHECK_HEADERS([gnutls/dane.h],
1176         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1177                      gnutls_dane=1))
1178    ])
1179 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1180 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1181 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1182 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1183
1184
1185 # Test if we are building for superMUC
1186 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1187 AC_ARG_ENABLE([supermuc],
1188     [AS_HELP_STRING([--enable-supermuc],
1189        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1190     [if test "x$enable_supermuc" = "xno"
1191      then
1192        supermuc=0
1193      else
1194        supermuc=1
1195      fi],
1196     [supermuc=0
1197      enable_supermuc=no])
1198 AC_MSG_RESULT($enable_SUPERMUC)
1199 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1200 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1201
1202 # Check if NSE has to send timestamp information to testbed logger for
1203 # generating histogram of messages received
1204 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1205 AC_ARG_ENABLE([nse-histogram],
1206     [AS_HELP_STRING([--enable-nse-histogram],
1207        [have NSE send timestamp information to testbed logger for generating
1208        histogram of received messages.  NOT useful for production (default is
1209        NO)])],
1210     [if test "x$enableval" = "xno"
1211      then
1212        nse_histogram=0
1213      else
1214        nse_histogram=1
1215      fi],
1216     [nse_histogram=0
1217      enable_nse_histogram=no])
1218 AC_MSG_RESULT($enable_nse_histogram)
1219 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1220 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1221                    [have NSE send timestamp information to testbed logger])
1222
1223 # should 'make check' run tests?
1224 AC_MSG_CHECKING(whether to run tests)
1225 AC_ARG_ENABLE([testruns],
1226    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1227    [enable_tests_run=${enableval}],
1228    [enable_tests_run=yes])
1229 AC_MSG_RESULT($enable_test_run)
1230 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1231
1232
1233 # should monkey be used when running (certain) services?
1234 AC_MSG_CHECKING(whether to run with monkey)
1235 AC_ARG_ENABLE([monkey],
1236    [AS_HELP_STRING([--enable-monkey], [enable running with monkey])],
1237    [enable_monkey=${enableval}],
1238    [enable_monkey=no])
1239 AC_MSG_RESULT($enable_monkey)
1240 AM_CONDITIONAL([ENABLE_MONKEY], [test "x$enable_monkey" = "xyes"])
1241 if test "x$enable_monkey" = "xyes"
1242 then
1243   MONKEYPREFIX="pathologist -d $(eval echo ${datarootdir}/gnunet/gnunet.sqlite) -p 30 --"
1244 else
1245   MONKEYPREFIX=""
1246 fi
1247 AC_SUBST(MONKEYPREFIX)
1248
1249
1250 # should expensive tests be run?
1251 AC_MSG_CHECKING(whether to run expensive tests)
1252 AC_ARG_ENABLE([expensivetests],
1253    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1254    [enable_expensive=${enableval}],
1255    [enable_expensive=no])
1256 AC_MSG_RESULT($enable_expensive)
1257 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1258
1259 # should ports be open for Java services?
1260 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1261 AC_ARG_ENABLE([javaports],
1262    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1263    [enable_java_ports=${enableval}],
1264    [enable_java_ports=no])
1265 AC_MSG_RESULT($enable_java_ports)
1266 if test "x$enable_java_ports" = "xyes"
1267 then
1268   JAVAPORT=""
1269 else
1270   JAVAPORT="$UNIXONLY"
1271 fi
1272 AC_SUBST(JAVAPORT)
1273
1274 # should benchmarks be run?
1275 AC_MSG_CHECKING(whether to run benchmarks during make check)
1276 AC_ARG_ENABLE([benchmarks],
1277    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1278    [enable_benchmarks=${enableval}],
1279    [enable_benchmarks=no])
1280 AC_MSG_RESULT($enable_benchmarks)
1281 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1282
1283 # should gnunet-testing be compiled
1284 AC_MSG_CHECKING(wether to compile gnunet-testing)
1285 AC_ARG_ENABLE([testing],
1286    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1287    [enable_testing=${enableval}],
1288    [enable_testing=yes])
1289 AC_MSG_RESULT($enable_testing)
1290 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1291
1292 # should experimental code be compiled (code that may not yet compile)?
1293 AC_MSG_CHECKING(whether to compile experimental code)
1294 AC_ARG_ENABLE([experimental],
1295    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1296    [enable_experimental=${enableval}],
1297    [enable_experimental=no])
1298 AC_MSG_RESULT($enable_experimental)
1299 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1300
1301 # FTBFS right now...
1302 AC_MSG_CHECKING(whether to compile ATS test code)
1303 AC_ARG_ENABLE([wachs],
1304    [AS_HELP_STRING([--enable-wachs], [enable compiling ATS test code])],
1305    [enable_wachs=${enableval}],
1306    [enable_wachs=no])
1307 AC_MSG_RESULT($enable_wachs)
1308 AM_CONDITIONAL([HAVE_WACHS], [test "x$enable_wachs" = "xyes"])
1309
1310 # should malicious code be compiled (should only be used for testing)?
1311 AC_MSG_CHECKING(whether to compile malicious code)
1312 AC_ARG_ENABLE([malicious],
1313    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1314    [if test "x$enableval" = "xno"
1315      then
1316        malicious=0
1317      else
1318        malicious=1
1319      fi],
1320    [malicious=0
1321     enable_malicious=no])
1322 AC_MSG_RESULT($enable_malicious)
1323 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1324 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1325                    [enable compilation of malicious code])
1326
1327 # should services be started by default when a peer starts?  Some services may
1328 # choose to never start by default and it is upto the service/module developer to
1329 # decide it by having "AUTOSTART = NO" instead of "AUTOSTART = @AUTOSTART@" in
1330 # the service/module's conf.in file.
1331 AUTOSTART="YES"
1332 AC_MSG_CHECKING(whether to auto-start peer's services by default)
1333 AC_ARG_ENABLE([autostart],
1334    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1335    [enable_autostart=${enableval}
1336     if test "x$enable_autostart" == "xno"
1337     then
1338         AUTOSTART="NO"
1339     fi
1340    ],
1341    [enable_autostart=yes])
1342 AC_MSG_RESULT($enable_autostart)
1343 #AM_CONDITIONAL([HAVE_AUTOSTART], [test "x$enable_autostart" = "xyes"])
1344 AC_SUBST(AUTOSTART)
1345
1346 # should memory statistics be kept (very expensive CPU-wise!)
1347 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1348 AC_ARG_ENABLE([heapstats],
1349    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1350    [enable_heapstats=1],
1351    [enable_heapstats=0])
1352 AC_MSG_RESULT($enable_heapstats)
1353 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1354
1355 # should code be enabled that works around missing OS functionality on Windows?
1356 # used for test cases
1357 if test $build_target = "mingw"
1358 then
1359         workarounds=1
1360
1361 AC_LINK_IFELSE(
1362  [AC_LANG_PROGRAM(
1363   [#include <ws2tcpip.h>
1364   ],[
1365   int s = socket (0, 0, 0);])
1366  ],[
1367   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1368  ],[
1369   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1370  ])
1371
1372 AC_LINK_IFELSE(
1373  [AC_LANG_PROGRAM(
1374   [#include <ws2tcpip.h>
1375   ],[
1376   int s = select (0, NULL, NULL, NULL, NULL);])
1377  ],[
1378   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1379  ],[
1380   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1381  ])
1382
1383 AC_LINK_IFELSE(
1384  [AC_LANG_PROGRAM(
1385   [#include <ws2tcpip.h>
1386   ],[
1387   struct in_addr i;
1388   char *s = inet_ntoa (i);])
1389  ],[
1390   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1391  ],[
1392   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1393  ])
1394
1395 AC_LINK_IFELSE(
1396  [AC_LANG_PROGRAM(
1397   [#include <ws2tcpip.h>
1398   ],[
1399   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1400  ],[
1401   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1402  ],[
1403   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1404  ])
1405
1406 AC_LINK_IFELSE(
1407  [AC_LANG_PROGRAM(
1408   [#include <ws2tcpip.h>
1409   ],[
1410   int s = gethostname (NULL, 0);])
1411  ],[
1412   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1413  ],[
1414   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1415  ])
1416
1417 AC_LINK_IFELSE(
1418  [AC_LANG_PROGRAM(
1419   [#include <ws2tcpip.h>
1420   ],[
1421   void *s = gethostbyname (NULL);])
1422  ],[
1423   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1424  ],[
1425   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1426  ])
1427
1428 AC_LINK_IFELSE(
1429  [AC_LANG_PROGRAM(
1430   [#include <ws2tcpip.h>
1431   ],[
1432   void *s = gethostbyaddr (NULL, 0, 0);])
1433  ],[
1434   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1435  ],[
1436   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1437  ])
1438
1439 AC_LINK_IFELSE(
1440  [AC_LANG_PROGRAM(
1441   [#include <ws2tcpip.h>
1442   ],[
1443   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1444  ],[
1445   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1446  ],[
1447   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1448  ])
1449
1450 else
1451   AC_MSG_CHECKING(whether to enable windows workarounds)
1452   AC_ARG_ENABLE([windows_workarounds],
1453      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1454      [enable_workarounds=${enableval}],
1455      [enable_workarounds=no])
1456   AC_MSG_RESULT($enable_workarounds)
1457   if test x$enable_windows_workarounds = "xyes"
1458   then
1459      workarounds=1
1460   else
1461      workarounds=0
1462    fi
1463 fi
1464 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1465
1466 # gcov compilation
1467 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1468 AC_ARG_ENABLE([coverage],
1469               AS_HELP_STRING([--enable-coverage],
1470                              [compile the library with code coverage support]),
1471               [use_gcov=${enableval}],
1472               [use_gcov=no])
1473 AC_MSG_RESULT($use_gcov)
1474 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1475
1476
1477 # version info
1478 AC_PATH_PROG(svnversioncommand, svnversion)
1479 AC_PATH_PROG(gitcommand, git)
1480 AC_MSG_CHECKING(for source being under a VCS)
1481 svn_version=
1482 gitsvn_version=
1483 AS_IF([test ! "X$svnversioncommand" = "X"],
1484 [
1485   svn_version=$(cd $srcdir ; $svnversioncommand -n 2>/dev/null)
1486 ])
1487 AS_IF([test ! "X$gitcommand" = "X"],
1488 [
1489   gitsvn_version=$(cd $srcdir ; git log -1 2>/dev/null | grep "git-svn-id" | sed -e 's/.*@\([[0-9]]\+\) .*/\1/')
1490 ])
1491 AS_IF([test "X$svn_version" = "X" -o "X$svn_version" = "Xexported" -o "X$svn_version" = "XUnversioned directory"],
1492 [
1493   AS_IF([test "X$gitsvn_version" = "X"],
1494   [
1495     vcs_name="no"
1496     vcs_version="\"release\""
1497   ],
1498   [
1499     vcs_name="yes, git-svn"
1500     vcs_version="\"svn-r$gitsvn_version\""
1501   ])
1502 ],
1503 [
1504   vcs_name="yes, svn"
1505   vcs_version="\"svn-r$svn_version\""
1506 ])
1507 AC_MSG_RESULT($vcs_name)
1508
1509 AC_MSG_CHECKING(VCS version)
1510 AC_MSG_RESULT($vcs_version)
1511 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1512
1513 AC_CONFIG_FILES([
1514 Makefile
1515 contrib/Makefile
1516 doc/Makefile
1517 doc/man/Makefile
1518 doc/doxygen/Makefile
1519 m4/Makefile
1520 po/Makefile.in
1521 src/Makefile
1522 src/arm/Makefile
1523 src/arm/arm.conf
1524 src/ats/Makefile
1525 src/ats/ats.conf
1526 src/ats-tool/Makefile
1527 src/ats-tests/Makefile
1528 src/block/Makefile
1529 src/cadet/Makefile
1530 src/cadet/cadet.conf
1531 src/core/Makefile
1532 src/core/core.conf
1533 src/consensus/Makefile
1534 src/consensus/consensus.conf
1535 src/conversation/Makefile
1536 src/conversation/conversation.conf
1537 src/curl/Makefile
1538 src/datacache/Makefile
1539 src/datastore/Makefile
1540 src/datastore/datastore.conf
1541 src/dht/Makefile
1542 src/dht/dht.conf
1543 src/dns/Makefile
1544 src/dns/dns.conf
1545 src/dv/Makefile
1546 src/dv/dv.conf
1547 src/exit/Makefile
1548 src/fragmentation/Makefile
1549 src/fs/Makefile
1550 src/fs/fs.conf
1551 src/gns/Makefile
1552 src/gns/gns.conf
1553 src/gns/nss/Makefile
1554 src/gnsrecord/Makefile
1555 src/hello/Makefile
1556 src/identity/Makefile
1557 src/identity/identity.conf
1558 src/include/Makefile
1559 src/integration-tests/Makefile
1560 src/json/Makefile
1561 src/hostlist/Makefile
1562 src/multicast/Makefile
1563 src/multicast/multicast.conf
1564 src/mysql/Makefile
1565 src/namecache/Makefile
1566 src/namecache/namecache.conf
1567 src/namestore/Makefile
1568 src/namestore/namestore.conf
1569 src/nat/Makefile
1570 src/nse/Makefile
1571 src/nse/nse.conf
1572 src/peerinfo/Makefile
1573 src/peerinfo/peerinfo.conf
1574 src/peerinfo-tool/Makefile
1575 src/peerstore/Makefile
1576 src/peerstore/peerstore.conf
1577 src/pq/Makefile
1578 src/postgres/Makefile
1579 src/psycutil/Makefile
1580 src/psyc/Makefile
1581 src/psyc/psyc.conf
1582 src/psycstore/Makefile
1583 src/psycstore/psycstore.conf
1584 src/pt/Makefile
1585 src/regex/Makefile
1586 src/regex/regex.conf
1587 src/revocation/Makefile
1588 src/revocation/revocation.conf
1589 src/rps/Makefile
1590 src/rps/rps.conf
1591 src/secretsharing/Makefile
1592 src/secretsharing/secretsharing.conf
1593 src/scalarproduct/Makefile
1594 src/scalarproduct/scalarproduct.conf
1595 src/set/Makefile
1596 src/set/set.conf
1597 src/social/Makefile
1598 src/social/social.conf
1599 src/statistics/Makefile
1600 src/statistics/statistics.conf
1601 src/template/Makefile
1602 src/testbed/Makefile
1603 src/testbed/testbed.conf
1604 src/testing/Makefile
1605 src/topology/Makefile
1606 src/transport/Makefile
1607 src/transport/transport.conf
1608 src/tun/Makefile
1609 src/util/Makefile
1610 src/util/resolver.conf
1611 src/vpn/Makefile
1612 src/vpn/vpn.conf
1613 src/rest/Makefile
1614 src/identity-provider/Makefile
1615 pkgconfig/Makefile
1616 pkgconfig/gnunetarm.pc
1617 pkgconfig/gnunetats.pc
1618 pkgconfig/gnunetblock.pc
1619 pkgconfig/gnunetcadet.pc
1620 pkgconfig/gnunetconsensus.pc
1621 pkgconfig/gnunetconversation.pc
1622 pkgconfig/gnunetcore.pc
1623 pkgconfig/gnunetdatacache.pc
1624 pkgconfig/gnunetdatastore.pc
1625 pkgconfig/gnunetdht.pc
1626 pkgconfig/gnunetdns.pc
1627 pkgconfig/gnunetdnsparser.pc
1628 pkgconfig/gnunetdnsstub.pc
1629 pkgconfig/gnunetdv.pc
1630 pkgconfig/gnunetenv.pc
1631 pkgconfig/gnunetfragmentation.pc
1632 pkgconfig/gnunetfs.pc
1633 pkgconfig/gnunetgns.pc
1634 pkgconfig/gnunethello.pc
1635 pkgconfig/gnunetidentity.pc
1636 pkgconfig/gnunetmicrophone.pc
1637 pkgconfig/gnunetmulticast.pc
1638 pkgconfig/gnunetmysql.pc
1639 pkgconfig/gnunetnamestore.pc
1640 pkgconfig/gnunetnat.pc
1641 pkgconfig/gnunetnse.pc
1642 pkgconfig/gnunetpeerinfo.pc
1643 pkgconfig/gnunetpq.pc
1644 pkgconfig/gnunetpostgres.pc
1645 pkgconfig/gnunetpsyc.pc
1646 pkgconfig/gnunetpsycstore.pc
1647 pkgconfig/gnunetregex.pc
1648 pkgconfig/gnunetrevocation.pc
1649 pkgconfig/gnunetrps.pc
1650 pkgconfig/gnunetscalarproduct.pc
1651 pkgconfig/gnunetset.pc
1652 pkgconfig/gnunetsocial.pc
1653 pkgconfig/gnunetspeaker.pc
1654 pkgconfig/gnunetstatistics.pc
1655 pkgconfig/gnunettestbed.pc
1656 pkgconfig/gnunettesting.pc
1657 pkgconfig/gnunettransport.pc
1658 pkgconfig/gnunettun.pc
1659 pkgconfig/gnunetutil.pc
1660 pkgconfig/gnunetvpn.pc
1661 ])
1662 AC_OUTPUT
1663
1664 # Finally: summary!
1665
1666 # warn user if mysql found but not used due to version
1667 if test "$mysqlfail" = "true"
1668 then
1669   AC_MSG_NOTICE([NOTICE: MySQL found, but too old. MySQL support will not be compiled.])
1670 fi
1671
1672 # sqlite
1673 if test "x$sqlite" = "x0"
1674 then
1675   AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1676 fi
1677
1678 # libgnurl
1679 if test "$gnurl" = "0"
1680 then
1681   if test "x$curl" = "xfalse"
1682   then
1683     AC_MSG_NOTICE([NOTICE: libgnurl not found.  http client support will not be compiled.])
1684     AC_MSG_WARN([ERROR: libgnurl not found.  hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1685   else
1686     AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1687   fi
1688 fi
1689
1690
1691 # bluetooth
1692 if test "x$bluetooth" = "x0"
1693 then
1694   AC_MSG_NOTICE([NOTICE: bluetooth library not found.  bluetooth support will not be compiled.])
1695 fi
1696
1697 #gnutls
1698 if test x$gnutls != xtrue
1699 then
1700   AC_MSG_NOTICE([NOTICE: GnuTLS not found, gnunet-gns-proxy will not be built])
1701 else
1702 if test "x$gnutls_dane" != "x1"
1703 then
1704   AC_MSG_NOTICE([NOTICE: GnuTLS has no DANE support, DANE validation will not be possible])
1705 fi
1706 fi
1707
1708 # java ports
1709 if test "x$enable_java_ports" = "xyes"
1710 then
1711   AC_MSG_NOTICE([NOTICE: opening ports for gnunet-java bindings by default.])
1712 fi
1713
1714 # MHD
1715 if test "x$lmhd" != "x1"
1716 then
1717  AC_MSG_NOTICE([NOTICE: libmicrohttpd not found, http transport will not be installed.])
1718 fi
1719
1720 # conversation
1721 if test "x$conversation_backend" = "xnone"
1722 then
1723   if test "x$pulse" != "x1"
1724   then
1725     AC_MSG_NOTICE([NOTICE: libpulse(audio) not found, conversation will not be built.])
1726   fi
1727   if test "x$opus" != "x1"
1728   then
1729    AC_MSG_NOTICE([NOTICE: libopus not found, conversation will not be built.])
1730   fi
1731   if test "x$gst" != "x1"
1732   then
1733    AC_MSG_NOTICE([NOTICE: GStreamer not found, conversation will not be built.])
1734   fi
1735 fi
1736
1737 if test "$extractor" != 1
1738 then
1739  AC_MSG_WARN([NOTICE: libextractor not found, but various file-sharing functions require it])
1740 fi
1741
1742 AC_MSG_NOTICE([NOTICE: Database support is set to MySQL: $mysql, SQLite: $sqlite, Postgres: $postgres])
1743
1744 if test "$enable_framework_build" = "yes"
1745 then
1746   AC_MSG_NOTICE([NOTICE: Mac OS X framework build enabled.])
1747 fi
1748
1749 if test "x$SUDO_BINARY" = "x" -a ! -w /
1750 then
1751   AC_MSG_NOTICE([NOTICE: --with-sudo not specified and not running as 'root', will not install GNS NSS library])
1752 fi
1753
1754
1755 AC_MSG_NOTICE([********************************************
1756 Please make sure NOW that you have created a user and group 'gnunet'
1757 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux, type:
1758         addgroup gnunetdns
1759         adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1760
1761 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1762 'gnunet'.  Then, you can compile GNUnet with
1763         make
1764
1765 After that, run (if necessary as 'root')
1766         make install
1767 to install everything.
1768
1769 Each GNUnet user should be added to the 'gnunet' group (may
1770 require fresh login to come into effect):
1771         adduser USERNAME gnunet
1772 (run the above command as root once for each of your users, replacing
1773 "USERNAME" with the respective login names).  If you have a global IP
1774 address, no further configuration is required.
1775
1776 For more detailed setup instructions, see https://gnunet.org/installation
1777
1778 Optionally, download and compile gnunet-gtk to get a GUI for
1779 file-sharing and configuration.  This is particularly recommended
1780 if your network setup is non-trivial, as gnunet-setup can be
1781 used to test in the GUI if your network configuration is working.
1782 gnunet-setup should be run as the "gnunet" user under X.  As it
1783 does very little with the network, running it as "root" is likely
1784 also harmless.  You can also run it as a normal user, but then
1785 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
1786 home directory in the end.
1787
1788 Once you have configured your peer, run (as the 'gnunet' user)
1789         gnunet-arm -s
1790 to start the peer.  You can then run the various GNUnet-tools as
1791 your "normal" user (who should only be in the group 'gnunet').
1792 ********************************************])