configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2010 Christian Grothoff (and other contributing authors)
   3 #
   4 # GNUnet is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published
   6 # by the Free Software Foundation; either version 2, or (at your
   7 # option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with GNUnet; see the file COPYING.  If not, write to the
  16 # Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18 #
  19 #
  20 # Process this file with autoconf to produce a configure script.
  21 #
  22 #
  23 AC_PREREQ(2.61)
  24 AC_INIT([gnunet], [0.9.0pre1],[bug-gnunet@gnu.org])
  25 AM_INIT_AUTOMAKE([gnunet], [0.9.0pre1])
  26 AC_CONFIG_HEADERS([gnunet_config.h])
  27
  28 AH_TOP([#define _GNU_SOURCE  1])
  29
  30 # Checks for programs.
  31 AC_CANONICAL_HOST
  32 AC_PROG_AWK
  33 AC_PROG_CC
  34 AC_PROG_CPP
  35 AC_PROG_CXX
  36 AC_PROG_OBJC
  37 AC_PROG_INSTALL
  38 AC_PROG_LN_S
  39 AC_PROG_MAKE_SET
  40 AM_PROG_CC_C_O
  41 AC_CANONICAL_HOST
  42 LT_INIT([disable-static dlopen win32-dll])
  43 LTDL_INIT
  44 AC_SUBST(LTDLINCL)
  45 AC_SUBST(LIBLTDL)
  46 AC_SUBST(MKDIR_P)
  47
  48 # large file support
  49 AC_SYS_LARGEFILE
  50 AC_FUNC_FSEEKO
  51
  52
  53 if test "$enable_shared" = "no"
  54 then
  55  AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])
  56 fi
  57
  58 CFLAGS="-Wall $CFLAGS"
  59 # use '-fno-strict-aliasing', but only if the compiler can take it
  60 if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
  61 then
  62  CFLAGS="-fno-strict-aliasing $CFLAGS"
  63 fi
  64
  65 # Use Linux interface name unless the OS has a different preference
  66 DEFAULT_INTERFACE="\"eth0\""
  67
  68 # Check system type
  69 case "$host_os" in
  70 *darwin* | *rhapsody* | *macosx*)
  71      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  72      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  73      CFLAGS="-no-cpp-precomp -fno-common $CFLAGS"
  74      AC_MSG_WARN([The VPN application cannot be compiled on your OS])
  75      build_target="darwin"
  76      DEFAULT_INTERFACE="\"en0\""
  77      LIBPREFIX=
  78      DLLDIR=lib
  79      ;;
  80 linux*)
  81      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux system])
  82      build_target="linux"
  83      LIBPREFIX=
  84      DLLDIR=lib
  85      AC_PATH_XTRA
  86      ;;
  87 freebsd*)
  88      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  89      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
  90      CFLAGS="-D_THREAD_SAFE $CFLAGS"
  91      build_target="freebsd"
  92      LIBPREFIX=
  93      DLLDIR=lib
  94      ;;
  95 openbsd*)
  96      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  97      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
  98      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
  99      build_target="openbsd"
 100      LIBPREFIX=
 101      DLLDIR=lib
 102      ;;
 103 netbsd*)
 104      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 105      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 106      LIBPREFIX=
 107      DLLDIR=lib
 108      ;;
 109 *solaris*)
 110      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 111      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 112      AC_CHECK_LIB(resolv, res_init)
 113      AC_CHECK_LIB(rt, nanosleep)
 114      build_target="solaris"
 115      LIBPREFIX=
 116      DLLDIR=lib
 117      ;;
 118 *arm-linux*)
 119      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux system])
 120      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 121      build_target="linux"
 122      LIBPREFIX=
 123      DLLDIR=lib
 124      ;;
 125 *cygwin*)
 126      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 127      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 128      AC_CHECK_LIB(intl, gettext)
 129      LDFLAGS="$LDFLAGS -no-undefined"
 130      CFLAGS="-mms-bitfields $CFLAGS"
 131      build_target="cygwin"
 132      LIBPREFIX=lib
 133      DLLDIR=bin
 134      AC_PROG_CXX
 135      ;;
 136 *mingw*)
 137      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 138      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 139      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 140      AC_CHECK_LIB(intl, gettext)
 141      LDFLAGS="$LDFLAGS -no-undefined -Wl,--export-all-symbols"
 142      LIBS="$LIBS -lws2_32 -lplibc"
 143      CFLAGS="-mms-bitfields $CFLAGS"
 144      build_target="mingw"
 145      AC_PROG_CXX
 146      LIBPREFIX=lib
 147      DLLDIR=bin
 148      ;;
 149 *)
 150      AC_MSG_RESULT(Unrecognised OS $host_os)
 151      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 152 ;;
 153 esac
 154 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 155 AC_SUBST(DEFAULT_INTERFACE)
 156
 157 AC_MSG_CHECKING([for build target])
 158 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 159 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 160 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 161 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 162 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 163 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 164 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 165
 166 AC_MSG_RESULT([$build_target])
 167 AC_SUBST(build_target)
 168 AM_CONDITIONAL([am__fastdepOBJC], false)
 169 AC_UNALIGNED_64_ACCESS
 170
 171 # some other checks for standard libs
 172 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 173 AC_CHECK_LIB(socket, socket)
 174 AC_CHECK_LIB(m, log)
 175 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 176
 177 # 'save' libs; only those libs found so far will be
 178 # linked against _everywhere_.  For the others, we
 179 # will be more selective!
 180 SAVE_LIBS=$LIBS
 181
 182 # libgcrypt
 183 gcrypt=0
 184 AM_PATH_LIBGCRYPT(1.2.0, gcrypt=1)
 185
 186 if test $gcrypt = 0
 187 then
 188   AC_MSG_ERROR([GNUnet needs libgcrypt])
 189 fi
 190
 191
 192 # libcurl
 193 LIBCURL_CHECK_CONFIG(,7.20.1,,AC_MSG_ERROR([GNUnet requires libcurl >= 7.20.1]))
 194 # restore LIBS
 195 LIBS=$SAVE_LIBS
 196
 197 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 198 AC_CHECK_LIB([kvm],[kvm_open])
 199 AC_CHECK_LIB([kstat],[kstat_open])
 200
 201 # test for libextractor
 202 extractor=0
 203 AC_MSG_CHECKING(for libextractor)
 204 AC_ARG_WITH(extractor,
 205    [  --with-extractor=PFX    base of libextractor installation],
 206    [AC_MSG_RESULT([$with_extractor])
 207     case $with_extractor in
 208       no)
 209         ;;
 210       yes)
 211         AC_CHECK_HEADERS(extractor.h,
 212           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 213             extractor=1))
 214         ;;
 215       *)
 216         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 217         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 218         AC_CHECK_HEADERS(extractor.h,
 219           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 220             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 221             extractor=1))
 222         ;;
 223     esac
 224    ],
 225    [AC_MSG_RESULT([--with-extractor not specified])
 226     AC_CHECK_HEADERS(extractor.h,
 227      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 228       extractor=1))])
 229 if test "$extractor" != 1
 230 then
 231  AC_MSG_ERROR([GNUnet requires libextractor])
 232 fi
 233 # restore LIBS
 234 LIBS=$SAVE_LIBS
 235
 236
 237 # Checks for standard header files.
 238 AC_HEADER_DIRENT
 239 AC_HEADER_STDC
 240
 241 # Check for headers that are ALWAYS required
 242 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files]))
 243
 244 # Checks for headers that are only required on some systems or opional (and where we do NOT abort if they are not there)
 245 AC_CHECK_HEADERS([langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h netinet/in_systm.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h])
 246
 247 # test for libgmp
 248 gmp=0
 249 AC_MSG_CHECKING(for libgmp)
 250 AC_ARG_WITH(gmp,
 251    [  --with-gmp=PFX          base of libgmp installation],
 252    [AC_MSG_RESULT([$with_gmp])
 253     case $with_gmp in
 254       no)
 255         ;;
 256       yes)
 257         AC_CHECK_HEADERS(gmp.h,
 258           AC_CHECK_LIB([gmp], [__gmpz_add],
 259             gmp=1))
 260         ;;
 261       *)
 262         LDFLAGS="-L$with_gmp/lib $LDFLAGS"
 263         CPPFLAGS="-I$with_gmp/include $CPPFLAGS"
 264         AC_CHECK_HEADERS(gmp.h,
 265           AC_CHECK_LIB([gmp], [__gmpz_add],
 266             EXT_LIB_PATH="-L$with_gmp/lib $EXT_LIB_PATH"
 267             gmp=1))
 268         ;;
 269     esac
 270    ],
 271    [AC_MSG_RESULT([--with-gmp not specified])
 272     AC_CHECK_HEADERS(gmp.h,
 273      AC_CHECK_LIB([gmp], [__gmpz_add],
 274       gmp=1))])
 275 if test "$gmp" != 1
 276 then
 277  AC_MSG_ERROR([GNUnet requires libgmp])
 278 fi
 279
 280 SAVE_LDFLAGS=$LDFLAGS
 281 SAVE_CPPFLAGS=$CPPFLAGS
 282
 283 # test for sqlite
 284 sqlite=false
 285 AC_MSG_CHECKING(for SQLite)
 286 AC_ARG_WITH(sqlite,
 287   [  --with-sqlite=PFX       base of SQLite installation],
 288   [AC_MSG_RESULT("$with_sqlite")
 289    case $with_sqlite in
 290    no)
 291      ;;
 292    yes)
 293     AC_CHECK_HEADERS(sqlite3.h,
 294      sqlite=true)
 295      ;;
 296    *)
 297     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
 298     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
 299     AC_CHECK_HEADERS(sqlite3.h,
 300      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
 301      SQLITE_LDFLAGS="-L$with_sqlite/lib"
 302      SQLITE_CPPFLAGS="-I$with_sqlite/include"
 303      sqlite=true)
 304     LDFLAGS=$SAVE_LDFLAGS
 305     CPPFLAGS=$SAVE_CPPFLAGS
 306     ;;
 307    esac
 308   ],
 309   [AC_MSG_RESULT([--with-sqlite not specified])
 310     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
 311 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
 312 AC_SUBST(SQLITE_CPPFLAGS)
 313 AC_SUBST(SQLITE_LDFLAGS)
 314
 315 # test for postgres
 316 postgres=false
 317 AC_MSG_CHECKING(for postgres)
 318 AC_ARG_WITH(postgres,
 319   [  --with-postgres=PFX       base of postgres installation],
 320   [AC_MSG_RESULT("$with_postgres")
 321    case $with_postgres in
 322    no)
 323      ;;
 324    yes)
 325     AC_CHECK_HEADERS(postgresql/libpq-fe.h,
 326      postgres=true)
 327      ;;
 328    *)
 329     LDFLAGS="-L$with_postgres/lib $LDFLAGS"
 330     CPPFLAGS="-I$with_postgres/include $CPPFLAGS"
 331     AC_CHECK_HEADERS(postgresql/libpq-fe.h,
 332      EXT_LIB_PATH="-L$with_postgres/lib $EXT_LIB_PATH"
 333      SQLITE_LDFLAGS="-L$with_postgres/lib"
 334      SQLITE_CPPFLAGS="-I$with_postgres/include"
 335      postgres=true)
 336     LDFLAGS=$SAVE_LDFLAGS
 337     CPPFLAGS=$SAVE_CPPFLAGS
 338     ;;
 339    esac
 340   ],
 341   [AC_MSG_RESULT([--with-postgres not specified])
 342     AC_CHECK_HEADERS(postgresql/libpq-fe.h, postgres=true)])
 343 AM_CONDITIONAL(HAVE_POSTGRES, test x$postgres = xtrue)
 344 AC_SUBST(POSTGRES_CPPFLAGS)
 345 AC_SUBST(POSTGRES_LDFLAGS)
 346
 347 # test for pcap
 348 pcap=0
 349 AC_MSG_CHECKING(for libpcap)
 350 AC_ARG_WITH(pcap,
 351   [  --with-pcap=PFX       base of pcap installation],
 352   [AC_MSG_RESULT("$with_pcap")
 353    case $with_pcap in
 354    no)
 355      ;;
 356    yes)
 357     AC_CHECK_HEADERS(pcap.h,
 358      pcap=1)
 359      ;;
 360    *)
 361     LDFLAGS="-L$with_pcap/lib $LDFLAGS"
 362     CPPFLAGS="-I$with_pcap/include $CPPFLAGS"
 363     AC_CHECK_HEADERS(pcap.h,
 364      EXT_LIB_PATH="-L$with_pcap/lib $EXT_LIB_PATH"
 365      PCAP_LDFLAGS="-L$with_pcap/lib"
 366      PCAP_CPPFLAGS="-I$with_pcap/include"
 367      pcap=1)
 368     LDFLAGS=$SAVE_LDFLAGS
 369     CPPFLAGS=$SAVE_CPPFLAGS
 370     ;;
 371    esac
 372   ],
 373   [AC_MSG_RESULT([--with-pcap not specified])
 374     AC_CHECK_HEADERS(pcap.h, pcap=1)])
 375 AM_CONDITIONAL(HAVE_PCAP, test x$pcap = x1)
 376 AC_SUBST(PCAP_CPPFLAGS)
 377 AC_SUBST(PCAP_LDFLAGS)
 378
 379
 380 # test for libz (maybe required for linking mysql)
 381 zlib=1
 382 AC_CHECK_LIB(z, compress,,zlib=0)
 383 AM_CONDITIONAL(HAVE_ZLIB, test x$zlib = x1)
 384 if test "$zlib" != 1
 385 then
 386  AC_MSG_ERROR([GNUnet requires zlib])
 387 fi
 388
 389 # mysql & windows
 390 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
 391 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
 392
 393 if test "$build_target" = "mingw"
 394 then
 395   CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"
 396 fi
 397
 398 # test for mysql
 399 mysql=false
 400 mysqlfail=false
 401 SAVE_LDFLAGS=$LDFLAGS
 402 SAVE_CPPFLAGS=$CPPFLAGS
 403 AC_MSG_CHECKING(for mysql)
 404 AC_ARG_WITH(mysql,
 405   [  --with-mysql=PFX        base of MySQL installation],
 406   [AC_MSG_RESULT("$with_mysql")
 407    if test "$with_mysql" != "no"
 408    then
 409     if test "$with_mysql" != "yes"
 410     then
 411       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
 412       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
 413     fi
 414     AC_CHECK_HEADERS(mysql/mysql.h,
 415      AC_CHECK_LIB(mysqlclient, mysql_init,
 416       MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
 417       MYSQL_CPPFLAGS="-I$with_mysql/include"
 418
 419       mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 420    fi
 421   ],
 422   [AC_MSG_RESULT([--with-mysql not specified])
 423    LDFLAGS="-L/usr/lib/mysql $LDFLAGS $ZLIBS"
 424    AC_CHECK_LIB(mysqlclient, mysql_init,
 425     [AC_CHECK_HEADERS(mysql/mysql.h,
 426       MYSQL_LDFLAGS="-L/usr/lib/mysql"
 427       mysql=true
 428
 429      , [], [$CYGWIN_MYSQL_MAGIC])])
 430   ])
 431
 432 AC_SUBST(MYSQL_LDFLAGS)
 433 AC_SUBST(MYSQL_CPPFLAGS)
 434
 435 # additional version check for mysql
 436 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
 437 if test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"
 438 then
 439   AC_MSG_CHECKING(mysql version)
 440   AC_RUN_IFELSE([AC_LANG_PROGRAM(
 441     [[$CYGWIN_MYSQL_MAGIC
 442       #include <mysql/mysql.h>]],
 443     [[if (MYSQL_VERSION_ID < 40100)
 444         return(-1);
 445       else
 446         return(0);
 447     ]])
 448     ],mysql=true,mysql=false)
 449   if test "$mysql" = "false"
 450   then
 451     mysqlfail=true
 452     AC_MSG_RESULT([fail, >= 4.1 required])
 453   else
 454     AC_MSG_RESULT(ok)
 455   fi
 456 fi
 457 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
 458 AM_CONDITIONAL(HAVE_MYSQLE, test "0" = "1")
 459 # restore LIBS
 460 LIBS=$SAVE_LIBS
 461 LDFLAGS=$SAVE_LDFLAGS
 462 CPPFLAGS=$SAVE_CPPFLAGS
 463
 464 if test "$sqlite" = 0 -a "$mysql" = 0
 465 then
 466  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
 467 fi
 468
 469 # libmicrohttpd
 470 lmhd=0
 471 AC_MSG_CHECKING([for libmicrohttpd])
 472 AC_ARG_WITH(microhttpd,
 473    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
 474    [AC_MSG_RESULT([$with_microhttpd])
 475     case $with_microhttpd in
 476       no)
 477         ;;
 478       yes)
 479         AC_CHECK_HEADERS([microhttpd.h],
 480           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 481             AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 482               lmhd=1),
 483             [],[#include "src/include/platform.h"
 484                 #include <microhttpd.h>]),,
 485             [#include "src/include/platform.h"])
 486         ;;
 487       *)
 488         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
 489         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
 490         AC_CHECK_HEADERS(microhttpd.h,
 491           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 492             AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 493               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
 494               lmhd=1),
 495             [],[#include "src/include/platform.h"
 496                 #include <microhttpd.h>]),,
 497             [#include "src/include/platform.h"])
 498         ;;
 499     esac
 500    ],
 501    [AC_MSG_RESULT([--with-microhttpd not specified])
 502     AC_CHECK_HEADERS([microhttpd.h],
 503       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 504         AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 505           lmhd=1),
 506         [],[#include "src/include/platform.h"
 507             #include <microhttpd.h>]),,
 508        [#include "src/include/platform.h"])])
 509 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
 510 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
 511
 512
 513 # openssl
 514 openssl=0
 515 AC_MSG_CHECKING([for openssl])
 516 AC_ARG_WITH(openssl,
 517    [  --with-openssl=PFX   base of openssl installation],
 518    [AC_MSG_RESULT([$with_openssl])
 519     case $with_openssl in
 520       no)
 521         ;;
 522       yes)
 523         AC_CHECK_HEADERS([openssl/ssl.h],
 524             AC_CHECK_LIB([ssl], [SSL_new],
 525              openssl=1))
 526         ;;
 527       *)
 528         LDFLAGS="-L$with_openssl/lib $LDFLAGS"
 529         CPPFLAGS="-I$with_openssl/include $CPPFLAGS"
 530         AC_CHECK_HEADERS([openssl/ssl.h],
 531             AC_CHECK_LIB([ssl], [SSL_new],
 532               EXT_LIB_PATH="-L$with_openssl/lib $EXT_LIB_PATH"
 533               openssl=1))
 534         ;;
 535     esac
 536    ],
 537    [AC_MSG_RESULT([--with-openssl not specified])
 538     AC_CHECK_HEADERS([openssl/ssl.h],
 539         AC_CHECK_LIB([ssl], [SSL_new],
 540           openssl=1))])
 541 AM_CONDITIONAL(HAVE_OPENSSL, test x$openssl = x1)
 542 AC_DEFINE_UNQUOTED([HAVE_OPENSSL], $openssl, [We have openssl])
 543
 544
 545
 546
 547
 548
 549 # restore LIBS
 550 LIBS=$SAVE_LIBS
 551
 552 # check for python & pexpect (used for some testcases only)
 553 AM_PATH_PYTHON([2.5],, [:])
 554 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 555
 556 if test "$PYTHON" != :
 557 then
 558   AC_MSG_CHECKING([for pexpect])
 559   $PYTHON -c "import pexpect" > /dev/null 2> /dev/null
 560   PYEX=$?
 561   AM_CONDITIONAL(HAVE_PYTHON_PEXPECT, test $PYEX -eq 0)
 562   if test $PYEX -eq 0
 563   then
 564     AC_MSG_RESULT([yes])
 565   else
 566     AC_MSG_RESULT([not found])
 567   fi
 568 else
 569   AM_CONDITIONAL(HAVE_PYTHON_PEXPECT, 0)
 570 fi
 571
 572 # libesmtp
 573 esmtp=0
 574 AC_MSG_CHECKING([for libesmtp])
 575 AC_ARG_WITH(esmtp,
 576    [  --with-esmtp=PFX        base of libesmtp installation],
 577    [AC_MSG_RESULT([$with_esmtp])
 578     case $with_esmtp in
 579       no)
 580         ;;
 581       yes)
 582         AC_CHECK_HEADERS(libesmtp.h,
 583           AC_CHECK_LIB([esmtp], [smtp_start_session],
 584             esmtp=1))
 585         ;;
 586       *)
 587         LDFLAGS="-L$with_esmtp/lib $LDFLAGS"
 588         CPPFLAGS="-I$with_esmtp/include $CPPFLAGS"
 589         AC_CHECK_HEADERS(libesmtp.h,
 590           AC_CHECK_LIB([esmtp], [smtp_start_session],
 591             EXT_LIB_PATH="-L$with_esmtp/lib $EXT_LIB_PATH"
 592               esmtp=1))
 593         ;;
 594     esac
 595    ],
 596    [AC_MSG_RESULT([--with-esmtp not specified])
 597     AC_CHECK_HEADERS(libesmtp.h,
 598       AC_CHECK_LIB([esmtp], [smtp_start_session],
 599           esmtp=1))])
 600 AM_CONDITIONAL(HAVE_ESMTP, test x$esmtp = x1)
 601 AC_DEFINE_UNQUOTED([HAVE_ESMTP], $esmtp, [We have libesmtp])
 602 # restore LIBS
 603 LIBS=$SAVE_LIBS
 604
 605 # check for gettext
 606 AM_GNU_GETTEXT([external])
 607 AM_GNU_GETTEXT_VERSION([0.16.1])
 608
 609 # check for iconv
 610 AM_ICONV
 611
 612 # Checks for standard typedefs, structures, and compiler characteristics.
 613 AC_TYPE_PID_T
 614 AC_TYPE_SIZE_T
 615 AC_TYPE_MODE_T
 616 AC_HEADER_TIME
 617 AC_HEADER_STAT
 618 AC_HEADER_STDBOOL
 619 AC_STRUCT_TM
 620
 621 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 622    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
 623    ],
 624    [],
 625    [
 626       #include <sys/types.h>
 627       #include <sys/socket.h>
 628       #include <netinet/in.h>
 629    ])
 630
 631
 632
 633 # Checks for library functions.
 634 AC_FUNC_CLOSEDIR_VOID
 635 AC_FUNC_FORK
 636 AC_FUNC_VFORK
 637 AC_PROG_GCC_TRADITIONAL
 638 AC_FUNC_MEMCMP
 639 AC_FUNC_SELECT_ARGTYPES
 640 AC_FUNC_CHOWN
 641
 642 AC_TYPE_SIGNAL
 643 AC_FUNC_STAT
 644 AC_FUNC_STRFTIME
 645 AC_FUNC_VPRINTF
 646 AC_HEADER_SYS_WAIT
 647 AC_TYPE_OFF_T
 648 AC_TYPE_UID_T
 649 AC_CHECK_FUNCS([floor gethostname memmove rmdir strncasecmp strrchr strtol atoll dup2 fdatasync ftruncate gettimeofday memset mkdir mkfifo select socket strcasecmp strchr strdup strerror strstr clock_gettime getrusage rand uname setlocale getcwd mktime gmtime_r gmtime strlcpy strlcat ftruncate stat64 sbrk mmap mremap setrlimit sysconf gethostbyaddr initgroups getifaddrs freeifaddrs getnameinfo getaddrinfo inet_ntoa localtime_r nl_langinfo putenv realpath strndup gethostbyname2 gethostbyname])
 650
 651 # restore LIBS
 652 LIBS=$SAVE_LIBS
 653
 654 gn_user_home_dir="~/.gnunet"
 655 AC_ARG_WITH(user-home-dir,
 656         AC_HELP_STRING(
 657                 [--with-user-home-dir=DIR],
 658                 [default user home directory (~/.gnunet)]),
 659         [gn_user_home_dir=$withval])
 660 AC_SUBST(GN_USER_HOME_DIR, $gn_user_home_dir)
 661 gn_daemon_home_dir="/var/lib/gnunet"
 662 AC_ARG_WITH(daemon-home-dir,
 663         AC_HELP_STRING(
 664                 [--with-daemon-home-dir=DIR],
 665                 [default daemon home directory (/var/lib/gnunet)]),
 666         [gn_daemon_home_dir=$withval])
 667 AC_SUBST(GN_DAEMON_HOME_DIR, $gn_daemon_home_dir)
 668 gn_daemon_config_dir="/etc"
 669 AC_ARG_WITH(daemon-config-dir,
 670         AC_HELP_STRING(
 671                 [--with-daemon-config-dir=DIR],
 672                 [default daemon config directory (/etc)]),
 673         [gn_daemon_config_dir=$withval])
 674 AC_SUBST(GN_DAEMON_CONFIG_DIR, $gn_daemon_config_dir)
 675
 676 GN_INTLINCL=""
 677 GN_LIBINTL="$LTLIBINTL"
 678 AC_ARG_ENABLE(framework, [  --enable-framework      enable Mac OS X framework build helpers],enable_framework_build=$enableval)
 679 AM_CONDITIONAL(WANT_FRAMEWORK, test x$enable_framework_build = xyes)
 680 if test x$enable_framework_build = xyes
 681 then
 682   AC_DEFINE([FRAMEWORK_BUILD], 1, [Build a Mac OS X Framework])
 683   GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
 684   GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
 685   AC_LIB_APPENDTOVAR([CPPFLAGS], [$GN_INTLINCL])
 686 fi
 687
 688 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
 689 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
 690
 691 AC_SUBST(GN_LIB_LDFLAGS)
 692 AC_SUBST(GN_PLUGIN_LDFLAGS)
 693 AC_SUBST(GN_INTLINCL)
 694 AC_SUBST(GN_LIBINTL)
 695
 696 AC_SUBST(CPPFLAGS)
 697 AC_SUBST(LIBS)
 698 AC_SUBST(LDFLAGS)
 699 AC_SUBST(EXT_LIB_PATH)
 700 AC_SUBST(EXT_LIBS)
 701
 702 AC_SUBST(LIBPREFIX)
 703 AC_SUBST(DLLDIR)
 704 AC_SUBST(EXT_LIB_PATH)
 705
 706
 707 # should 'make check' run tests?
 708 AC_MSG_CHECKING(whether to disable running tests)
 709 AC_ARG_ENABLE(testruns,
 710    [AS_HELP_STRING([--enable-test-suppression],
 711                [disable running tests on make check])],
 712    [disable_tests_run=$enableval],
 713    [disable_tests_run="no"])
 714 AC_MSG_RESULT($disable_test_run)
 715 AM_CONDITIONAL([DISABLE_TEST_RUN], [test "x$disable_tests_run" = "xyes"])
 716
 717 # should experimental code be compiled (code that may not yet compile)?
 718 disable_experimental=yes
 719 AC_MSG_CHECKING(whether to compile experimental code)
 720 AC_ARG_ENABLE(experimental,
 721    [AS_HELP_STRING([--enable-experimental],
 722                [enable compiling experimental code])],
 723    [enable_experimental=$enableval],
 724    [enable_experimental="no"])
 725 AC_MSG_RESULT($enable_experimental)
 726 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
 727
 728 # gcov compilation
 729 use_gcov=no
 730 AC_ARG_ENABLE([coverage], AS_HELP_STRING([--enable-coverage],
 731                                         [Compile the library with code coverage support (default is NO)]),
 732                                         [use_gcov=yes], [use_gcov=no])
 733 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
 734
 735 AC_CONFIG_FILES([
 736 Makefile
 737 contrib/Makefile
 738 m4/Makefile
 739 po/Makefile.in
 740 src/Makefile
 741 src/arm/Makefile
 742 src/block/Makefile
 743 src/core/Makefile
 744 src/datacache/Makefile
 745 src/datastore/Makefile
 746 src/dht/Makefile
 747 src/dv/Makefile
 748 src/fragmentation/Makefile
 749 src/fs/Makefile
 750 src/hello/Makefile
 751 src/include/Makefile
 752 src/include/gnunet_directories.h
 753 src/hostlist/Makefile
 754 src/monkey/Makefile
 755 src/nat/Makefile
 756 src/nat/libnatpmp/Makefile
 757 src/nat/miniupnp/Makefile
 758 src/peerinfo/Makefile
 759 src/peerinfo-tool/Makefile
 760 src/statistics/Makefile
 761 src/template/Makefile
 762 src/testing/Makefile
 763 src/topology/Makefile
 764 src/transport/Makefile
 765 src/util/Makefile
 766 src/vpn/Makefile
 767 ])
 768 AC_OUTPUT
 769
 770 # Finally: summary!
 771
 772 # warn user if mysql found but not used due to version
 773 if test "$mysqlfail" = "true"
 774 then
 775   AC_MSG_NOTICE([NOTICE: MySQL found, but too old. MySQL support will not be compiled.])
 776 fi
 777
 778 # sqlite
 779 if test "x$sqlite" = "x0"
 780 then
 781   AC_MSG_NOTICE([NOTICE: sqlite not found.  sqLite support will not be compiled.])
 782 fi
 783
 784 if test "x$lmhd" != "x1"
 785 then
 786  AC_MSG_NOTICE([NOTICE: libmicrohttpd not found, http transport will not be installed.])
 787 fi
 788
 789 if test "x$esmtp" != "x1"
 790 then
 791  AC_MSG_NOTICE([NOTICE: libesmtp not found, monkey will not be installed.])
 792 fi
 793
 794 if test "x$pcap" != "x1"
 795 then
 796  AC_MSG_NOTICE([NOTICE: libpcap not found, WiFi support will not be installed.])
 797 fi
 798
 799 if test "x$openssl" != "x1"
 800 then
 801  AC_MSG_NOTICE([NOTICE: OpenSSL not found, monkey will not be installed.])
 802 fi
 803
 804 AC_MSG_NOTICE([NOTICE: Database support is set to MySQL: $mysql, SQLite: $sqlite, Postgres: $postgres])
 805
 806 if test "$enable_framework_build" = "yes"
 807 then
 808   AC_MSG_NOTICE([NOTICE: Mac OS X framework build enabled.])
 809 fi
 810
 811 AC_MSG_NOTICE([********************************************
 812 You can compile GNUnet with
 813         make
 814 now. After that, run (if necessary as 'root')
 815         make install
 816 to install everything. You may want to create a new user account
 817 to run the GNUnet service:
 818         adduser gnunet
 819 You also need to create an configuration file that should
 820 specify the path where GNUnet should store data.  For example,
 821 you could store in "/etc/gnunet.conf" the following lines:
 822
 823 [PATHS]
 824 SERVICEHOME = /opt/gnunet/
 825 DEFAULTCONFIG = /etc/gnunet.conf
 826
 827 Now, in order to start your peer, run as the 'gnunet' user
 828         gnunet-arm -s
 829
 830 Each GNUnet user should also create an (at least initially) empty
 831 configuration file:
 832         mkdir $HOME/.gnunet/
 833         touch $HOME/.gnunet/gnunet.conf
 834
 835 Optionally, download and compile gnunet-gtk to get a GUI.
 836 ********************************************])