configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2017 GNUnet e.V.
   3 #
   4 # GNUnet is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published
   6 # by the Free Software Foundation; either version 3, or (at your
   7 # option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with GNUnet; see the file COPYING.  If not, write to the
  16 # Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  17 # Boston, MA 02110-1301, USA.
  18 #
  19 #
  20 # Process this file with autoconf to produce a configure script.
  21 #
  22 #
  23 AC_PREREQ(2.61)
  24 # Checks for programs.
  25 AC_INIT([gnunet], [0.10.1], [bug-gnunet@gnu.org])
  26
  27 AC_CANONICAL_TARGET
  28 AC_CANONICAL_HOST
  29 AC_CANONICAL_SYSTEM
  30
  31 AM_INIT_AUTOMAKE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33 AC_CONFIG_HEADERS([gnunet_config.h])
  34 AH_TOP([#define _GNU_SOURCE  1])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_PROG_AWK
  37 AC_PROG_CC_C99
  38 AC_PROG_CPP
  39 AC_PROG_CXX
  40 AC_PROG_OBJC
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AM_PROG_CC_C_O
  45 LT_INIT([disable-static dlopen win32-dll])
  46 AC_SUBST(MKDIR_P)
  47
  48 # large file support
  49 AC_SYS_LARGEFILE
  50 AC_FUNC_FSEEKO
  51
  52
  53 CFLAGS="-Wall $CFLAGS"
  54 # use '-fno-strict-aliasing', but only if the compiler can take it
  55 if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
  56 then
  57  CFLAGS="-fno-strict-aliasing $CFLAGS"
  58 fi
  59
  60 # Use Linux interface name unless the OS has a different preference
  61 DEFAULT_INTERFACE="\"eth0\""
  62
  63 funcstocheck="getnameinfo gethostname gethostbyname gethostbyaddr getaddrinfo"
  64
  65 # Srcdir in a form that native compiler understands (i.e. DOS path on W32)
  66 native_srcdir=$srcdir
  67
  68 # Check system type
  69 case "$host_os" in
  70 *darwin* | *rhapsody* | *macosx*)
  71      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  72      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  73      CFLAGS="-fno-common $CFLAGS"
  74      AC_MSG_WARN([WARNING: The VPN application cannot be compiled on your OS])
  75      build_target="darwin"
  76      DEFAULT_INTERFACE="\"en0\""
  77      LIBPREFIX=
  78      DLLDIR=lib
  79      UNIXONLY="#"
  80      ;;
  81 linux*)
  82      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
  83      build_target="linux"
  84      LIBPREFIX=
  85      DLLDIR=lib
  86      UNIXONLY="#"
  87      AC_PATH_XTRA
  88      ;;
  89 *freebsd*)
  90      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  91      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
  92      CFLAGS="-D_THREAD_SAFE $CFLAGS"
  93      build_target="freebsd"
  94      LIBPREFIX=
  95      DLLDIR=lib
  96      UNIXONLY="#"
  97      ;;
  98 *openbsd*)
  99      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 100      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 101      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 102      build_target="openbsd"
 103      LIBPREFIX=
 104      DLLDIR=lib
 105      UNIXONLY="#"
 106      ;;
 107 *netbsd*)
 108      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 109      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 110      LIBPREFIX=
 111      DLLDIR=lib
 112      UNIXONLY="#"
 113      ;;
 114 *solaris*)
 115      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 116      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 117      AC_CHECK_LIB(resolv, res_init)
 118      AC_CHECK_LIB(rt, nanosleep)
 119      build_target="solaris"
 120      LIBPREFIX=
 121      DLLDIR=lib
 122      UNIXONLY="#"
 123      ;;
 124 *arm-linux*)
 125      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux kernel])
 126      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 127      build_target="linux"
 128      LIBPREFIX=
 129      DLLDIR=lib
 130      UNIXONLY="#"
 131      ;;
 132 *cygwin*)
 133      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 134      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 135      AC_CHECK_LIB(intl, gettext)
 136      CFLAGS="-mms-bitfields $CFLAGS"
 137      build_target="cygwin"
 138      LIBPREFIX=lib
 139      DLLDIR=bin
 140      AC_PROG_CXX
 141      UNIXONLY=""
 142      ;;
 143 *mingw*)
 144      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 145      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 146      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 147      AC_CHECK_LIB(intl, gettext)
 148      LDFLAGS="$LDFLAGS -Wl,--export-all-symbols"
 149      LIBS="$LIBS -lws2_32 -lplibc -lgnurx -lole32"
 150      CFLAGS="-mms-bitfields $CFLAGS"
 151      CPPFLAGS="-D_WIN32_WINNT=0x0501 -DHAVE_STAT64=1 -D__USE_MINGW_ANSI_STDIO=1 $CPPFLAGS"
 152      build_target="mingw"
 153      AC_PROG_CXX
 154      LIBPREFIX=lib
 155      DLLDIR=bin
 156      UNIXONLY=""
 157      funcstocheck=""
 158      native_srcdir=$(cd $srcdir; pwd -W)
 159      ;;
 160 gnu*)
 161      AC_DEFINE_UNQUOTED(GNU,1,[This is a GNU system])
 162      build_target="gnu"
 163      UNIXONLY="#"
 164      ;;
 165 *)
 166      AC_MSG_RESULT(Unrecognised OS $host_os)
 167      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 168      UNIXONLY=""
 169 ;;
 170 esac
 171 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 172 AC_SUBST(DEFAULT_INTERFACE)
 173
 174 # Disable TCP-based IPC on systems that support UNIX domain
 175 # sockets in default configuratin:
 176 AC_SUBST(UNIXONLY)
 177
 178
 179 AC_MSG_CHECKING([for build target])
 180 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 181 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 182 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 183 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 184 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 185 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 186 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 187 AM_CONDITIONAL(GNU, test "$build_target" = "gnu")
 188
 189 AC_MSG_RESULT([$build_target])
 190 AC_SUBST(build_target)
 191 AM_CONDITIONAL([am__fastdepOBJC], false)
 192 AC_UNALIGNED_64_ACCESS
 193
 194 # some other checks for standard libs
 195 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 196 AC_CHECK_LIB(socket, socket)
 197 AC_CHECK_LIB(m, log)
 198 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 199
 200 AC_CHECK_PROG(VAR_GETOPT_BINARY, getopt, true, false)
 201 AM_CONDITIONAL(HAVE_GETOPT_BINARY, $VAR_GETOPT_BINARY)
 202
 203 AC_CHECK_PROG(VAR_SSH_BINARY,ssh,true,false)
 204 AM_CONDITIONAL(HAVE_SSH_BINARY, $VAR_SSH_BINARY)
 205 AM_CONDITIONAL(HAVE_SSH_KEY,  ssh -D 12345 -o "BatchMode yes" -o "UserKnownHostsFile /tmp/gnunet_test_cosks_ssh_garbage" -o "StrictHostKeyChecking no" 127.0.0.1 echo -n)
 206 rm -f /tmp/gnunet_test_cosks_ssh_garbage
 207
 208
 209 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
 210   [AC_DEFINE(HAVE_TM_GMTOFF, 1,
 211      [Define if struct tm has the tm_gmtoff member.])],
 212      ,
 213      [#include <time.h>])
 214
 215 AC_CHECK_DECLS([_stati64])
 216
 217 # 'save' libs; only those libs found so far will be
 218 # linked against _everywhere_.  For the others, we
 219 # will be more selective!
 220 SAVE_LIBS=$LIBS
 221
 222 # tests only run on Windows
 223 if test "x$build_target" = "xmingw"
 224 then
 225   AC_CHECK_LIB(plibc, plibc_init, [], [AC_MSG_ERROR([GNUnet requires PlibC on Windows])])
 226   AC_CHECK_LIB(gnurx, regexec, [], [AC_MSG_ERROR([GNUnet requires libgnurx on Windows])])
 227 fi
 228
 229 # libgcrypt
 230 gcrypt=0
 231 NEED_LIBGCRYPT_API=1
 232 NEED_LIBGCRYPT_VERSION=1.6.0
 233
 234
 235 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION", gcrypt=1)
 236 AC_CHECK_DECLS([gcry_mpi_set_opaque_copy], [], [], [[#include <gcrypt.h>]])
 237
 238 if test $gcrypt = 0
 239 then
 240   AC_MSG_ERROR([[
 241 ***
 242 *** You need libgcrypt to build this program.
 243 **  This library is for example available at
 244 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 245 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API)
 246 ***  is required.)
 247 ***]])
 248 fi
 249 AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], "$NEED_LIBGCRYPT_VERSION", [required libgcrypt version])
 250
 251 # Adam shostack suggests the following for Windows:
 252 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 253 AC_ARG_ENABLE(gcc-hardening,
 254    AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
 255 [if test x$enableval = xyes; then
 256     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 257     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 258     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 259     LDFLAGS="$LDFLAGS -pie"
 260 fi])
 261
 262
 263 # Linker hardening options
 264 # Currently these options are ELF specific - you can't use this with MacOSX
 265 AC_ARG_ENABLE(linker-hardening,
 266   AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 267 [if test x$enableval = xyes; then
 268    LDFLAGS="$LDFLAGS -z relro -z now"
 269 fi])
 270
 271
 272 AC_ARG_ENABLE(sanitizer,
 273   AS_HELP_STRING(--enable-sanitizer, enable Address Sanitizer and Undefined Behavior Sanitizer),
 274 [if test x$enableval = xyes; then
 275    LDFLAGS="$CFLAGS -fsanitize=address,undefined -fno-omit-frame-pointer"
 276 fi])
 277
 278
 279 extra_logging=GNUNET_NO
 280 AC_ARG_ENABLE([logging],
 281    AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose,veryverbose ('yes' is the default)]),
 282    [AS_IF([test "x$enableval" = "xyes"], [],
 283           [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
 284           [test "x$enableval" = "xverbose"], [extra_logging=GNUNET_YES]
 285           [test "x$enableval" = "xveryverbose"], [extra_logging=\(GNUNET_YES+1\)])
 286    ], [])
 287 AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
 288
 289 # should memory poisoning be enabled?
 290 AC_MSG_CHECKING(whether to poison freed memory)
 291 AC_ARG_ENABLE([poisoning],
 292    [AS_HELP_STRING([--enable-poisoning], [enable poisoning of freed memory (good for debugging)])],
 293    [enable_poisoning=${enableval}],
 294    [
 295      if test "x$extra_logging" != "xGNUNET_NO"; then
 296        enable_poisoning="defaults to yes (extra logging is enabled)"
 297      else
 298        enable_poisoning=no
 299      fi
 300    ])
 301 AC_MSG_RESULT($enable_poisoning)
 302 if test ! "x$enable_poisoning" = "xno"; then
 303   enable_poisoning=1
 304 else
 305   enable_poisoning=0
 306 fi
 307 AC_DEFINE_UNQUOTED([ENABLE_POISONING],[$enable_poisoning],[1 if freed memory should be poisoned, 0 otherwise])
 308
 309 if test $build = $target
 310 then
 311 AC_MSG_CHECKING([for working HMAC])
 312 AC_LANG_PUSH(C)
 313 LIBS="$LIBS $LIBGCRYPT_LIBS"
 314 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 315 AC_RUN_IFELSE(
 316   [AC_LANG_PROGRAM([#include <gcrypt.h>
 317         #include <stdio.h>], [[
 318         gcry_md_hd_t mac;
 319
 320         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 321             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 322             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 323         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 324         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 325             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 326             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 327             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 328             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 329             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 330
 331         if (!gcry_check_version (GCRYPT_VERSION))
 332         {
 333           fprintf (stderr, "Version mismatch %s <-> %s \n", gcry_check_version (NULL), GCRYPT_VERSION);
 334           return 1;
 335         }
 336
 337         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 338         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 339
 340         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 341         {
 342           fprintf (stderr, "gcry_md_open error\n");
 343           return 2;
 344         }
 345
 346         gcry_md_setkey (mac, key, sizeof (key));
 347         gcry_md_write (mac, data, sizeof (data));
 348
 349         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 350         {
 351           fprintf (stderr, "memcmp error\n");
 352           return 3;
 353         }
 354
 355         gcry_md_close (mac);
 356
 357         return 0;
 358     ]])],
 359   [AC_MSG_RESULT([yes])],
 360   [
 361    RESULT=$?
 362    if test $RESULT = 3
 363    then
 364      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 365    fi
 366    if test $RESULT = 2
 367    then
 368      AC_MSG_FAILURE([HMAC test failed])
 369    fi
 370    if test $RESULT = 1
 371    then
 372      AC_MSG_FAILURE([libgcrypt header version does not match library version])
 373    fi
 374   ],
 375   [AC_MSG_RESULT([cross compiling, test skipped])])
 376 AC_LANG_POP(C)
 377 fi      # $build = $target
 378
 379 # check for bluetooth library
 380 bluetooth=0
 381 AC_CHECK_LIB(bluetooth, ba2str,[AC_CHECK_HEADER([bluetooth/bluetooth.h],bluetooth=1)])
 382 if test "$build_target" = "mingw"
 383 then
 384   bluetooth=1
 385 fi
 386 AM_CONDITIONAL(HAVE_LIBBLUETOOTH, [test "$bluetooth" = 1])
 387 if test "$bluetooth" = 1
 388 then
 389   AC_DEFINE([HAVE_LIBBLUETOOTH],[1],[Have bluetooth library])
 390 else
 391   AC_DEFINE([HAVE_LIBBLUETOOTH],[0],[Lacking bluetooth library])
 392 fi
 393
 394 # check for jansson library
 395 jansson=0
 396 AC_CHECK_HEADER([jansson.h],jansson=1)
 397 AM_CONDITIONAL(HAVE_JANSSON, [test "$jansson" = 1])
 398 if test "x$jansson" = x1
 399 then
 400   AC_DEFINE([HAVE_JANSSON],[1],[Have jansson library])
 401 else
 402   AC_DEFINE([HAVE_JANSSON],[0],[Lacking jansson library])
 403 fi
 404
 405 # check for libpulse(audio) library
 406 pulse=0
 407 AC_CHECK_LIB(pulse,pa_stream_peek,
 408   [AC_CHECK_HEADER([pulse/simple.h],pulse=1)])
 409 if test "$build_target" = "mingw"
 410 then
 411   pulse=0
 412 fi
 413 if test "$pulse" = 1
 414 then
 415   AC_DEFINE([HAVE_PULSE],[1],[Have libpulse(audio) library])
 416 fi
 417
 418 # check for libopus(audio) library
 419 opus=0
 420 AC_CHECK_LIB(opus,opus_decode_float,
 421   [AC_CHECK_HEADER([opus/opus.h],
 422     [AC_CHECK_DECL([OPUS_SET_GAIN],[opus=1],[],[[#include <opus/opus.h>]]
 423     )]
 424   )]
 425 )
 426 if test "$opus" = 1
 427 then
 428   AC_DEFINE([HAVE_OPUS],[1],[Have libopus library])
 429 fi
 430
 431 # libogg
 432 AC_CHECK_LIB(ogg, ogg_stream_flush_fill,
 433         [AC_CHECK_HEADERS([ogg/ogg.h],
 434           AM_CONDITIONAL(HAVE_OGG, true)
 435           ogg=1
 436           AC_DEFINE(HAVE_OGG,1,[Have ogg]),
 437           AM_CONDITIONAL(HAVE_OGG, false)
 438           ogg=0
 439           AC_DEFINE(HAVE_OGG,0,[lacking ogg]))],
 440         AM_CONDITIONAL(HAVE_OGG, false)
 441         ogg=0)
 442
 443
 444 PKG_CHECK_MODULES([GLIB], [glib-2.0])
 445 # check for pbc library
 446 pbc=0
 447 AC_CHECK_HEADER([pbc/pbc.h],pbc=1)
 448 AC_CHECK_HEADER([gabe.h],abe=1)
 449 AM_CONDITIONAL(HAVE_PBC, [test "$pbc" = 1])
 450 AM_CONDITIONAL(HAVE_ABE, [test "$abe" = 1])
 451 if test "x$pbc" = x1
 452 then
 453   AC_DEFINE([HAVE_PBC],[1],[Have pbc library])
 454 else
 455   AC_DEFINE([HAVE_PBC],[0],[Lacking pbc library])
 456 fi
 457 if test "x$abe" = x1
 458 then
 459   AC_DEFINE([HAVE_ABE],[1],[Have ABE library])
 460 else
 461   AC_DEFINE([HAVE_ABE],[0],[Lacking ABE library])
 462 fi
 463
 464
 465
 466 gst=0
 467 PKG_CHECK_MODULES(
 468   [GST],
 469   [glib-2.0 gobject-2.0 gstreamer-1.0 gstreamer-app-1.0 gstreamer-audio-1.0],
 470   [
 471     gst=1
 472     AC_MSG_RESULT(ok)
 473   ], [
 474     gst=0
 475     AC_MSG_RESULT(not found)
 476   ])
 477
 478 # Pulse Audio
 479 if test "x$pulse" != "x1" -o "x$opus" != "x1" -o "x$ogg" != "x1"
 480 then
 481  if test "x$gst" != "x1"
 482  then
 483   conversation_backend=none
 484   AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 485   AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 486   AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 487  else
 488    conversation_backend=gst
 489    AM_CONDITIONAL(BUILD_PULSE_HELPERS, false)
 490    AM_CONDITIONAL(BUILD_GST_HELPERS, true)
 491    AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 492  fi
 493 else
 494
 495  conversation_backend=pulse
 496  AM_CONDITIONAL(BUILD_PULSE_HELPERS, true)
 497  AM_CONDITIONAL(BUILD_GST_HELPERS, false)
 498  AM_CONDITIONAL(BUILD_EXPERIMENTAL_HELPERS, false)
 499 fi
 500
 501 # libgnurl
 502 LIBGNURL_CHECK_CONFIG(,7.34.0,gnurl=1,gnurl=0)
 503 if test "$gnurl" = 1
 504 then
 505         AM_CONDITIONAL(HAVE_LIBGNURL, true)
 506         AC_DEFINE([HAVE_LIBGNURL],[1],[Have libgnurl])
 507 else
 508         AM_CONDITIONAL(HAVE_LIBGNURL, false)
 509         AC_DEFINE([HAVE_LIBGNURL],[0],[Lacking libgnurl])
 510 fi
 511
 512 SAVE_CPPFLAGS=$CPPFLAGS
 513 CPPFLAGS="$LIBGNURL_CPPFLAGS $LIBCURL_CPPFLAGS $CPPFLAGS"
 514 LIBS="$LIBGNURL $LIBCURL $LIBS"
 515
 516 # libcurl-gnutls
 517 LIBCURL_CHECK_CONFIG(,7.34.0,[curl=true],[curl=false])
 518 if test "x$curl" = xtrue
 519 then
 520
 521  AC_CHECK_HEADERS([curl/curl.h],
 522   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],[curl=false],[[#include <curl/curl.h>]]),
 523   [curl=false])
 524  AC_CHECK_HEADERS([gnurl/curl.h],
 525   AC_CHECK_DECLS(CURLINFO_TLS_SESSION,[curl=true],,[[#include <gnurl/curl.h>]]))
 526  # need libcurl-gnutls.so, everything else is not acceptable
 527  AC_CHECK_LIB([curl-gnutls],[curl_easy_getinfo],,[curl=false])
 528  # cURL must support CURLINFO_TLS_SESSION, version >= 7.34
 529 fi
 530
 531 # Check for curl/curl.h and gnurl/curl.h so we can use #ifdef
 532 # HAVE_CURL_CURL_H later (the above LIBCURL_CHECK_CONFIG accepted
 533 # *either* header set).
 534 AC_CHECK_HEADERS([curl/curl.h],,
 535   curl=false
 536   AC_CHECK_HEADERS([gnurl/curl.h],,
 537   gnurl=false))
 538
 539
 540
 541 if test x$curl = xfalse
 542 then
 543         AM_CONDITIONAL(HAVE_LIBCURL, false)
 544 if test "$gnurl" = 0
 545 then
 546         AC_MSG_WARN([ERROR: GNUnet requires libcurl-gnutls or gnurl >= 7.34])
 547 fi
 548 else
 549         AM_CONDITIONAL(HAVE_LIBCURL, true)
 550         AC_DEFINE([HAVE_LIBCURL],[1],[Have CURL])
 551 fi
 552
 553
 554 # restore LIBS & CPPFLAGS
 555 LIBS=$SAVE_LIBS
 556 CPPFLAGS=$SAVE_CPPFLAGS
 557
 558 AC_CHECK_HEADERS([glpk.h],[glpk=true],[gplk=false])
 559 # GLPK must support glpk_init_env, version >= 4.43
 560 AC_CHECK_LIB([glpk],[glp_init_env],,[gplk=false])
 561 # GLPK must support atm MLP presolving, version >= 4.32
 562 AC_CHECK_MEMBERS(glp_iocp.presolve,,[gplk=false],[[#include <glpk.h>]])
 563 if test x$gplk = xfalse
 564 then
 565         AM_CONDITIONAL(HAVE_LIBGLPK, false)
 566         AC_MSG_WARN([ERROR: GNUnet requires GLPK  >= 4.32])
 567 else
 568         AM_CONDITIONAL(HAVE_LIBGLPK, true)
 569         AC_DEFINE([HAVE_LIBGLPK],[1],[Have GLPK])
 570 fi
 571
 572
 573 AC_CHECK_HEADERS([nss.h],[nss=true],[nss=false])
 574 if test x$nss = xfalse
 575 then
 576         AM_CONDITIONAL(HAVE_GLIBCNSS, false)
 577         AC_MSG_WARN([ERROR: No GNU libc nss header, will not build NSS plugin])
 578 else
 579         AM_CONDITIONAL(HAVE_GLIBCNSS, true)
 580 fi
 581
 582
 583
 584 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 585 AC_CHECK_LIB([kvm],[kvm_open])
 586 AC_CHECK_LIB([kstat],[kstat_open])
 587
 588
 589 # should the build process be restricted to only building
 590 # the documentation?
 591 AC_MSG_CHECKING(whether to build documentation ONLY)
 592 AC_ARG_ENABLE([documentation],
 593    [AS_HELP_STRING([--enable-documentation], [only build the documentation])],
 594    [doc_only=${enableval}],
 595    [doc_only=no])
 596 AC_MSG_RESULT($doc_only)
 597 if test "x$doc_only" = "xyes"
 598 then
 599   AM_CONDITIONAL([DOC_ONLY],true)
 600   AC_DEFINE([DOC_ONLY],[1],[Building the documentation])
 601 else
 602   AM_CONDITIONAL([DOC_ONLY],false)
 603   AC_DEFINE([DOC_ONLY],[0],[Canonical compilation])
 604 fi
 605
 606 # should the build process be restricted to the code required
 607 # for GNU Taler wallets?
 608 AC_MSG_CHECKING(whether to compile GNU Taler Wallet library ONLY)
 609 AC_ARG_ENABLE([taler-wallet],
 610    [AS_HELP_STRING([--enable-taler-wallet], [only compile for Taler wallet])],
 611    [taler_only=${enableval}],
 612    [taler_only=no])
 613 AC_MSG_RESULT($taler_only)
 614 if test "x$taler_only" = "xyes"
 615 then
 616   AM_CONDITIONAL([TALER_ONLY],true)
 617   AC_DEFINE([TALER_WALLET_ONLY],[1],[Compiling for Taler wallet])
 618 else
 619   AM_CONDITIONAL([TALER_ONLY],false)
 620   AC_DEFINE([TALER_WALLET_ONLY],[0],[Canonical compilation])
 621 fi
 622
 623 # test for libextractor
 624 extractor=0
 625 AC_MSG_CHECKING(for libextractor)
 626 AC_ARG_WITH(extractor,
 627    [  --with-extractor=PFX    base of libextractor installation],
 628    [AC_MSG_RESULT([$with_extractor])
 629     case $with_extractor in
 630       no)
 631         ;;
 632       yes)
 633         AC_CHECK_HEADERS(extractor.h,
 634           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 635             extractor=1))
 636         ;;
 637       *)
 638         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 639         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 640         AC_CHECK_HEADERS(extractor.h,
 641           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 642             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 643             extractor=1))
 644         ;;
 645     esac
 646    ],
 647    [AC_MSG_RESULT([--with-extractor not specified])
 648     AC_CHECK_HEADERS(extractor.h,
 649      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 650       extractor=1))])
 651 # restore LIBS
 652 LIBS=$SAVE_LIBS
 653
 654 if test "$extractor" != 1
 655 then
 656  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, false)
 657  AC_DEFINE([HAVE_LIBEXTRACTOR],[0],[Lacking libextractor])
 658 else
 659  AM_CONDITIONAL(HAVE_LIBEXTRACTOR, true)
 660  AC_DEFINE([HAVE_LIBEXTRACTOR],[1],[Have libextractor])
 661 fi
 662
 663
 664 if test "$taler_only" != yes
 665 then
 666
 667 # Check for libltdl header (#2999)
 668 ltdl=0
 669 AC_MSG_CHECKING(for libltdl)
 670 AC_ARG_WITH(ltdl,
 671    [  --with-ltdl=PFX    base of libltdl installation],
 672    [AC_MSG_RESULT([$with_ltdl])
 673     case $with_ltdl in
 674       no)
 675         ;;
 676       yes)
 677         AC_CHECK_HEADERS(ltdl.h,
 678           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 679             ltdl=1))
 680         ;;
 681       *)
 682         LDFLAGS="-L$with_ltdl/lib $LDFLAGS"
 683         CPPFLAGS="-I$with_ltdl/include $CPPFLAGS"
 684         AC_CHECK_HEADERS(ltdl.h,
 685           AC_CHECK_LIB([ltdl], [lt_dlopenext],
 686             EXT_LIB_PATH="-L$with_ltdl/lib $EXT_LIB_PATH"
 687             ltdl=1))
 688         ;;
 689     esac
 690    ],
 691    [AC_MSG_RESULT([--with-ltdl not specified])
 692     AC_CHECK_HEADERS(ltdl.h,
 693      AC_CHECK_LIB([ltdl], [lt_dlopenext],
 694       ltdl=1))])
 695 if test x$ltdl = x1
 696 then
 697  AC_MSG_RESULT([libltdl found])
 698 else
 699  AC_MSG_ERROR([GNUnet requires libltdl (from GNU libtool), try installing libltdl-dev])
 700 fi
 701 # restore LIBS
 702 LIBS=$SAVE_LIBS
 703
 704
 705 # libidn
 706 AC_MSG_CHECKING([if Libidn can be used])
 707 AC_ARG_WITH(libidn, AC_HELP_STRING([--with-libidn=[DIR]],
 708                                     [Support IDN (needs GNU Libidn)]),
 709 libidn=$withval, libidn=yes)
 710 if test "$libidn" != "no"; then
 711   if test "$libidn" != "yes"; then
 712      LDFLAGS="${LDFLAGS} -L$libidn/lib"
 713      CPPFLAGS="${CPPFLAGS} -I$libidn/include"
 714   fi
 715 fi
 716 libidn=no
 717 AC_CHECK_HEADER(idna.h,
 718   AC_CHECK_LIB(idn, stringprep_check_version,
 719     [libidn=yes LIBS="${LIBS} -lidn"], []), [])
 720 if test "$libidn" != "yes"; then
 721   AC_MSG_FAILURE([GNUnet requires libidn.
 722 libidn-1.13 should be sufficient, newer versions work too.])
 723 fi
 724 AC_MSG_RESULT($libidn)
 725
 726
 727 # test for zlib
 728 SAVE_LDFLAGS=$LDFLAGS
 729 SAVE_CPPFLAGS=$CPPFLAGS
 730 AC_ARG_WITH(zlib,
 731             [  --with-zlib[[=DIR]]       use libz in DIR],
 732             [AS_IF([test "$withval" = "no"],
 733                    [AC_MSG_ERROR([GNUnet requires zlib])],
 734                    [test "$withval" != "yes"],
 735                    [
 736                      Z_DIR=$withval
 737                      CPPFLAGS="${CPPFLAGS} -I$withval/include"
 738                      LDFLAGS="${LDFLAGS} -L$withval/lib"
 739                    ])
 740             ])
 741 AC_CHECK_HEADER(zlib.h,
 742                 [],
 743                 [AC_MSG_ERROR([GNUnet requires zlib])])
 744 AC_CHECK_LIB(z, compress2,
 745              [
 746               AC_DEFINE([HAVE_ZLIB], [], [Have compression library])
 747               if test "x${Z_DIR}" != "x"; then
 748                       Z_CFLAGS="-I${Z_DIR}/include"
 749                       Z_LIBS="-L${Z_DIR}/lib -lz"
 750               else
 751                       Z_LIBS="-lz"
 752               fi],
 753               [AC_MSG_ERROR([GNUnet requires zlib])])
 754 AC_SUBST(Z_CFLAGS)
 755 AC_SUBST(Z_LIBS)
 756
 757 if test "$enable_shared" = "no"
 758 then
 759  AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])
 760 fi
 761
 762
 763
 764 # restore LIBS
 765 LIBS=$SAVE_LIBS
 766
 767
 768 fi
 769
 770 # check for iconv
 771 AM_ICONV
 772
 773 # test for libunistring
 774 gl_LIBUNISTRING
 775 if test $HAVE_LIBUNISTRING != yes; then
 776  AC_MSG_ERROR([GNUnet requires libunistring])
 777 fi
 778 # under emscripten, $gl_libunistring_hexversion is undefined
 779 if test "$taler_only" != yes; then
 780 if test "x$gl_libunistring_hexversion" = "x" || test "$gl_libunistring_hexversion" -le 2305; then
 781  AC_MSG_ERROR([GNUnet requires libunistring >= 0.9.1.1])
 782 fi
 783 fi
 784 AC_CHECK_HEADERS([unistr.h],,AC_MSG_ERROR([Compiling GNUnet requires unistr.h (from libunistring) to be installed]))
 785
 786 # restore LIBS
 787 LIBS=$SAVE_LIBS
 788
 789
 790
 791 # Checks for standard header files.
 792 AC_HEADER_DIRENT
 793 AC_HEADER_STDC
 794
 795 # Check for headers that are ALWAYS required
 796 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files]))
 797
 798
 799
 800 # Checks for headers that are only required on some systems or opional (and where we do NOT abort if they are not there)
 801 AC_CHECK_HEADERS([malloc.h malloc/malloc.h malloc/malloc_np.h langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h sys/ucred.h endian.h sys/endian.h execinfo.h byteswap.h])
 802
 803 # FreeBSD requires something more funky for netinet/in_systm.h and netinet/ip.h...
 804 AC_CHECK_HEADERS([sys/types.h netinet/in_systm.h netinet/in.h netinet/ip.h],,,
 805 [#ifdef HAVE_SYS_TYPES_H
 806 #include <sys/types.h>
 807 #endif
 808 #ifdef HAVE_NETINET_IN_SYSTM_H
 809 #include <netinet/in_systm.h>
 810 #endif
 811 #ifdef HAVE_NETINET_IN_H
 812 #include <netinet/in.h>
 813 #endif
 814 ])
 815
 816 SAVE_LDFLAGS=$LDFLAGS
 817 SAVE_CPPFLAGS=$CPPFLAGS
 818
 819 # test for sqlite
 820 sqlite=false
 821 AC_MSG_CHECKING(for SQLite)
 822 AC_ARG_WITH(sqlite,
 823   [  --with-sqlite=PFX       base of SQLite installation],
 824   [AC_MSG_RESULT("$with_sqlite")
 825    case $with_sqlite in
 826    no)
 827      ;;
 828    yes)
 829     AC_CHECK_HEADERS(sqlite3.h,
 830      sqlite=true)
 831      ;;
 832    *)
 833     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
 834     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
 835     AC_CHECK_HEADERS(sqlite3.h,
 836      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
 837      SQLITE_LDFLAGS="-L$with_sqlite/lib"
 838      SQLITE_CPPFLAGS="-I$with_sqlite/include"
 839      sqlite=true)
 840     LDFLAGS=$SAVE_LDFLAGS
 841     CPPFLAGS=$SAVE_CPPFLAGS
 842     ;;
 843    esac
 844   ],
 845   [AC_MSG_RESULT([--with-sqlite not specified])
 846     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
 847 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
 848 AC_SUBST(SQLITE_CPPFLAGS)
 849 AC_SUBST(SQLITE_LDFLAGS)
 850
 851 LDFLAGS=$SAVE_LDFLAGS
 852 CPPFLAGS=$SAVE_CPPFLAGS
 853
 854 # test for postgres
 855 postgres=false
 856 # even running the check for postgres breaks emscripten ...
 857 if test "$taler_only" != yes; then
 858   AX_LIB_POSTGRESQL([9.5])
 859   if test "$found_postgresql" = "yes"; then
 860     CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
 861     AC_CHECK_HEADERS([libpq-fe.h],
 862       postgres=true)
 863   fi
 864 fi
 865 AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
 866
 867
 868 LDFLAGS=$SAVE_LDFLAGS
 869 CPPFLAGS=$SAVE_CPPFLAGS
 870
 871 # mysql & windows
 872 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
 873 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
 874
 875 if test "$build_target" = "mingw"
 876 then
 877   CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"
 878 fi
 879
 880 # test for mysql
 881 mysql=false
 882 mysqlfail=false
 883 SAVE_LDFLAGS=$LDFLAGS
 884 SAVE_CPPFLAGS=$CPPFLAGS
 885 AC_MSG_CHECKING(for mysql)
 886 AC_ARG_WITH(mysql,
 887   [  --with-mysql=PFX        base of MySQL installation],
 888   [AC_MSG_RESULT([$with_mysql])
 889    case $with_mysql in
 890    no)
 891       ;;
 892    yes|"")
 893       AC_CHECK_HEADERS(mysql/mysql.h,
 894        AC_CHECK_LIB(mysqlclient, mysql_init,
 895
 896        mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 897       ;;
 898    *)
 899       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
 900       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
 901       AC_CHECK_HEADERS(mysql/mysql.h,
 902        AC_CHECK_LIB(mysqlclient, mysql_init,
 903         MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
 904         MYSQL_CPPFLAGS="-I$with_mysql/include"
 905
 906         mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 907       ;;
 908    esac
 909   ],
 910   [AC_MSG_RESULT([--with-mysql not specified])
 911    if test -d "/usr/lib64/mysql"; then
 912     MYSQL_LIBDIR="/usr/lib64/mysql"
 913    elif test -d "/usr/lib/mysql"; then
 914     MYSQL_LIBDIR="/usr/lib/mysql"
 915    else
 916     MYSQL_LIBDIR="/usr/lib"
 917    fi
 918    LDFLAGS="-L$MYSQL_LIBDIR $LDFLAGS $ZLIBS"
 919    AC_CHECK_LIB(mysqlclient, mysql_init,
 920     [AC_CHECK_HEADERS(mysql/mysql.h,
 921       MYSQL_LDFLAGS="-L$MYSQL_LIBDIR"
 922       mysql=true
 923
 924      , [], [$CYGWIN_MYSQL_MAGIC])])
 925   ])
 926
 927 AC_SUBST(MYSQL_LDFLAGS)
 928 AC_SUBST(MYSQL_CPPFLAGS)
 929
 930 # additional version check for mysql
 931 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
 932 if test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"
 933 then
 934   AC_MSG_CHECKING(mysql version)
 935   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 936     [[$CYGWIN_MYSQL_MAGIC
 937       #include <mysql/mysql.h>]],
 938     [[
 939       #if (MYSQL_VERSION_ID < 40100)
 940       #error needs at least version >= 4.1
 941       #endif
 942       int main () { return 0; }
 943     ]])
 944     ],mysql=true,mysql=false)
 945   if test "$mysql" = "false"
 946   then
 947     mysqlfail=true
 948     AC_MSG_RESULT([fail, >= 4.1 required])
 949   else
 950     AC_MSG_RESULT(ok)
 951   fi
 952 fi
 953 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
 954 AM_CONDITIONAL(HAVE_MYSQLE, test "0" = "1")
 955 # restore LIBS
 956 LIBS=$SAVE_LIBS
 957 LDFLAGS=$SAVE_LDFLAGS
 958 CPPFLAGS=$SAVE_CPPFLAGS
 959
 960 if test "$sqlite" = 0 -a "$mysql" = 0
 961 then
 962  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
 963 fi
 964
 965 # libmicrohttpd
 966 lmhd=0
 967 AC_MSG_CHECKING([for libmicrohttpd])
 968 AC_ARG_WITH(microhttpd,
 969    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
 970    [AC_MSG_RESULT([$with_microhttpd])
 971     case $with_microhttpd in
 972       no)
 973         ;;
 974       yes|"")
 975         AC_CHECK_HEADERS([microhttpd.h],
 976           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 977             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
 978               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
 979               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 980                 #include "$native_srcdir/src/include/platform.h"
 981                 #include <microhttpd.h>
 982                 #if (MHD_VERSION < 0x0094200)
 983                 #error needs at least version 0.9.42
 984                 #endif
 985                 int main () { return 0; }
 986                ])],
 987                [AC_MSG_RESULT(ok)
 988                 lmhd=1],
 989                [AC_MSG_RESULT(failed)])]),
 990             [],[#include "$native_srcdir/src/include/platform.h"
 991                 #include <microhttpd.h>]),,
 992             [#include "$native_srcdir/src/include/platform.h"])
 993         ;;
 994       *)
 995         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
 996         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
 997         AC_CHECK_HEADERS(microhttpd.h,
 998           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 999             AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1000               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
1001               [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
1002                AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1003                 #include "$native_srcdir/src/include/platform.h"
1004                 #include <microhttpd.h>
1005                 #if (MHD_VERSION < 0x0094200)
1006                 #error needs at least version 0.9.42
1007                 #endif
1008                 int main () { return 0; }
1009                ])],
1010                [AC_MSG_RESULT(ok)
1011                 lmhd=1],
1012                [AC_MSG_RESULT(failed)])]),
1013             [],[#include "$native_srcdir/src/include/platform.h"
1014                 #include <microhttpd.h>]),,
1015             [#include "$native_srcdir/src/include/platform.h"])
1016         ;;
1017     esac
1018    ],
1019    [AC_MSG_RESULT([--with-microhttpd not specified])
1020     AC_CHECK_HEADERS([microhttpd.h],
1021       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
1022         AC_CHECK_LIB([microhttpd], [MHD_get_fdset2],
1023           [AC_MSG_CHECKING([for libmicrohttpd >= 0.9.42])
1024               AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1025                 #include "$native_srcdir/src/include/platform.h"
1026                 #include <microhttpd.h>
1027                 #if (MHD_VERSION < 0x0094200)
1028                 #error needs at least version 0.9.42
1029                 #endif
1030                ])],
1031                [AC_MSG_RESULT(ok)
1032                 lmhd=1],
1033                [AC_MSG_RESULT(failed)])]),
1034         [],[#include "$native_srcdir/src/include/platform.h"
1035             #include <microhttpd.h>]),,
1036        [#include "$native_srcdir/src/include/platform.h"])])
1037 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
1038 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
1039
1040 AM_CONDITIONAL(HAVE_JSON, [test x$jansson = x1])
1041
1042 # restore LIBS
1043 LIBS=$SAVE_LIBS
1044
1045 # check for python & pexpect (used for some testcases only)
1046 AM_PATH_PYTHON([2.6],, [:])
1047 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
1048
1049 # check for gettext
1050 AM_GNU_GETTEXT([external])
1051 AM_GNU_GETTEXT_VERSION([0.18.1])
1052
1053 # Checks for standard typedefs, structures, and compiler characteristics.
1054 AC_TYPE_PID_T
1055 AC_TYPE_SIZE_T
1056 AC_TYPE_MODE_T
1057 AC_HEADER_TIME
1058 AC_HEADER_STAT
1059 AC_HEADER_STDBOOL
1060 AC_STRUCT_TM
1061
1062 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
1063    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
1064    ],
1065    [],
1066    [
1067       #include <sys/types.h>
1068       #include <sys/socket.h>
1069       #include <netinet/in.h>
1070    ])
1071
1072 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1073    [ AC_DEFINE(HAVE_SOCKADDR_UN_SUN_LEN, 1, [Do we have sockaddr_un.sun_len?])
1074    ],
1075    [],
1076    [
1077       #include <sys/types.h>
1078       #include <sys/socket.h>
1079       #include <sys/un.h>
1080    ])
1081
1082
1083
1084 # Checks for library functions.
1085 AC_FUNC_CLOSEDIR_VOID
1086 AC_FUNC_FORK
1087 AC_PROG_GCC_TRADITIONAL
1088 AC_FUNC_MEMCMP
1089 AC_FUNC_SELECT_ARGTYPES
1090 AC_FUNC_CHOWN
1091
1092 AC_TYPE_SIGNAL
1093 AC_FUNC_STAT
1094 AC_FUNC_STRFTIME
1095 AC_FUNC_VPRINTF
1096 AC_HEADER_SYS_WAIT
1097 AC_TYPE_OFF_T
1098 AC_TYPE_UID_T
1099 AC_CHECK_FUNCS([atoll stat64 strnlen mremap getrlimit setrlimit sysconf initgroups strndup gethostbyname2 getpeerucred getpeereid setresuid $funcstocheck getifaddrs freeifaddrs getresgid mallinfo malloc_size malloc_usable_size getrusage random srandom stat statfs statvfs wait4])
1100
1101 # restore LIBS
1102 LIBS=$SAVE_LIBS
1103
1104 GN_INTLINCL=""
1105 GN_LIBINTL="$LTLIBINTL"
1106 AC_ARG_ENABLE(framework, [  --enable-framework      enable Mac OS X framework build helpers],enable_framework_build=$enableval)
1107 AM_CONDITIONAL(WANT_FRAMEWORK, test x$enable_framework_build = xyes)
1108 if test x$enable_framework_build = xyes
1109 then
1110   AC_DEFINE([FRAMEWORK_BUILD], 1, [Build a Mac OS X Framework])
1111   GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
1112   GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
1113   AC_LIB_APPENDTOVAR([CPPFLAGS], [$GN_INTLINCL])
1114 fi
1115
1116 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
1117 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
1118
1119 AC_SUBST(GN_LIB_LDFLAGS)
1120 AC_SUBST(GN_PLUGIN_LDFLAGS)
1121 AC_SUBST(GN_INTLINCL)
1122 AC_SUBST(GN_LIBINTL)
1123
1124 AC_SUBST(CPPFLAGS)
1125 AC_SUBST(LIBS)
1126 AC_SUBST(LDFLAGS)
1127 AC_SUBST(EXT_LIB_PATH)
1128 AC_SUBST(EXT_LIBS)
1129
1130 AC_SUBST(LIBPREFIX)
1131 AC_SUBST(DLLDIR)
1132 AC_SUBST(EXT_LIB_PATH)
1133
1134
1135 # test for sudo
1136 AC_MSG_CHECKING(for sudo)
1137 AC_ARG_WITH(sudo,
1138   [  --with-sudo=PATH       path to sudo binary (or just yes)],
1139   [AC_MSG_RESULT("$with_sudo")
1140    case $with_sudo in
1141    no)
1142      SUDO_BINARY=
1143      ;;
1144    yes)
1145      SUDO_BINARY=sudo
1146      ;;
1147    *)
1148      SUDO_BINARY=$with_sudo
1149     ;;
1150    esac
1151   ],
1152   [AC_MSG_RESULT([no])])
1153 AC_SUBST(SUDO_BINARY)
1154 AM_CONDITIONAL([HAVE_SUDO], [test "x$SUDO_BINARY" != "x" -o -w /])
1155
1156
1157 # test for gnunetdns group name
1158 GNUNETDNS_GROUP=gnunetdns
1159 AC_MSG_CHECKING(for gnunetdns group name)
1160 AC_ARG_WITH(gnunetdns,
1161   [  --with-gnunetdns=GRPNAME       name for gnunetdns group],
1162   [AC_MSG_RESULT("$with_gnunetdns")
1163    case $with_gnunetdns in
1164    no)
1165      GNUNETDNS_GROUP=gnunet
1166      ;;
1167    yes)
1168      GNUNETDNS_GROUP=gnunetdns
1169      ;;
1170    *)
1171      GNUNETDNS_GROUP=$with_gnunetdns
1172     ;;
1173    esac
1174   ],
1175   [AC_MSG_RESULT([gnunetdns])])
1176 AC_SUBST(GNUNETDNS_GROUP)
1177
1178
1179
1180 # gnutls
1181 gnutls=0
1182 gnutls_dane=0
1183 AC_MSG_CHECKING(for gnutls)
1184 AC_ARG_WITH(gnutls,
1185    [  --with-gnutls=PFX   base of gnutls installation],
1186    [AC_MSG_RESULT([$with_gnutls])
1187     case $with_gnutls in
1188       no)
1189         ;;
1190       yes)
1191         AC_CHECK_HEADERS([gnutls/abstract.h],
1192             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1193              gnutls=true))
1194         AC_CHECK_HEADERS([gnutls/dane.h],
1195             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1196               gnutls_dane=1))
1197         ;;
1198       *)
1199         LDFLAGS="-L$with_gnutls/lib $LDFLAGS"
1200         CPPFLAGS="-I$with_gnutls/include $CPPFLAGS"
1201         AC_CHECK_HEADERS([gnutls/abstract.h],
1202             AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1203               EXT_LIB_PATH="-L$with_gnutls/lib $EXT_LIB_PATH"
1204               gnutls=true))
1205         AC_CHECK_HEADERS([gnutls/dane.h],
1206             AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1207               gnutls_dane=1))
1208         ;;
1209     esac
1210    ],
1211    [AC_MSG_RESULT([--with-gnutls not specified])
1212     AC_CHECK_HEADERS([gnutls/abstract.h],
1213         AC_CHECK_LIB([gnutls], [gnutls_priority_set],
1214           gnutls=true))
1215     AC_CHECK_HEADERS([gnutls/dane.h],
1216         AC_CHECK_LIB([gnutls-dane], [dane_verify_crt_raw],
1217                      gnutls_dane=1))
1218    ])
1219 AM_CONDITIONAL(HAVE_GNUTLS, test x$gnutls = xtrue)
1220 AC_DEFINE_UNQUOTED([HAVE_GNUTLS], $gnutls, [We have GnuTLS])
1221 AM_CONDITIONAL(HAVE_GNUTLS_DANE, test x$gnutls_dane = x1)
1222 AC_DEFINE_UNQUOTED([HAVE_GNUTLS_DANE], $gnutls_dane, [We have GnuTLS with DANE support])
1223
1224
1225 # Test if we are building for superMUC
1226 AC_MSG_CHECKING(if GNUnet is being configured to run on the SuperMUC)
1227 AC_ARG_ENABLE([supermuc],
1228     [AS_HELP_STRING([--enable-supermuc],
1229        [build GNUnet with support to run on the SuperMUC (default is NO)])],
1230     [if test "x$enable_supermuc" = "xno"
1231      then
1232        supermuc=0
1233      else
1234        supermuc=1
1235      fi],
1236     [supermuc=0
1237      enable_supermuc=no])
1238 AC_MSG_RESULT($enable_SUPERMUC)
1239 AM_CONDITIONAL([ENABLE_SUPERMUC], [test "x$supermuc" = "x1"])
1240 AC_DEFINE_UNQUOTED([ENABLE_SUPERMUC], [$supermuc], [Build with support for SuperMUC])
1241
1242 # Check if NSE has to send timestamp information to testbed logger for
1243 # generating histogram of messages received
1244 AC_MSG_CHECKING(if NSE has to send timestamp information to testbed logger)
1245 AC_ARG_ENABLE([nse-histogram],
1246     [AS_HELP_STRING([--enable-nse-histogram],
1247        [have NSE send timestamp information to testbed logger for generating
1248        histogram of received messages.  NOT useful for production (default is
1249        NO)])],
1250     [if test "x$enableval" = "xno"
1251      then
1252        nse_histogram=0
1253      else
1254        nse_histogram=1
1255      fi],
1256     [nse_histogram=0
1257      enable_nse_histogram=no])
1258 AC_MSG_RESULT($enable_nse_histogram)
1259 AM_CONDITIONAL([ENABLE_NSE_HISTOGRAM], [test "x$nse_histogram" = "x1"])
1260 AC_DEFINE_UNQUOTED([ENABLE_NSE_HISTOGRAM], [$nse_histogram],
1261                    [have NSE send timestamp information to testbed logger])
1262
1263 # should 'make check' run tests?
1264 AC_MSG_CHECKING(whether to run tests)
1265 AC_ARG_ENABLE([testruns],
1266    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
1267    [enable_tests_run=${enableval}],
1268    [enable_tests_run=yes])
1269 AC_MSG_RESULT($enable_test_run)
1270 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
1271
1272
1273 # should monkey be used when running (certain) services?
1274 AC_MSG_CHECKING(whether to run with monkey)
1275 AC_ARG_ENABLE([monkey],
1276    [AS_HELP_STRING([--enable-monkey], [enable running with monkey])],
1277    [enable_monkey=${enableval}],
1278    [enable_monkey=no])
1279 AC_MSG_RESULT($enable_monkey)
1280 AM_CONDITIONAL([ENABLE_MONKEY], [test "x$enable_monkey" = "xyes"])
1281 if test "x$enable_monkey" = "xyes"
1282 then
1283   MONKEYPREFIX="pathologist -d $(eval echo ${datarootdir}/gnunet/gnunet.sqlite) -p 30 --"
1284 else
1285   MONKEYPREFIX=""
1286 fi
1287 AC_SUBST(MONKEYPREFIX)
1288
1289
1290 # should expensive tests be run?
1291 AC_MSG_CHECKING(whether to run expensive tests)
1292 AC_ARG_ENABLE([expensivetests],
1293    [AS_HELP_STRING([--enable-expensivetests], [enable running expensive testcases])],
1294    [enable_expensive=${enableval}],
1295    [enable_expensive=no])
1296 AC_MSG_RESULT($enable_expensive)
1297 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
1298
1299 # should ports be open for Java services?
1300 AC_MSG_CHECKING(whether to enable ports for gnunet-java)
1301 AC_ARG_ENABLE([javaports],
1302    [AS_HELP_STRING([--enable-javaports], [use non-zero ports for services with Java bindings (default is NO)])],
1303    [enable_java_ports=${enableval}],
1304    [enable_java_ports=no])
1305 AC_MSG_RESULT($enable_java_ports)
1306 if test "x$enable_java_ports" = "xyes"
1307 then
1308   JAVAPORT=""
1309 else
1310   JAVAPORT="$UNIXONLY"
1311 fi
1312 AC_SUBST(JAVAPORT)
1313
1314 # should benchmarks be run?
1315 AC_MSG_CHECKING(whether to run benchmarks during make check)
1316 AC_ARG_ENABLE([benchmarks],
1317    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
1318    [enable_benchmarks=${enableval}],
1319    [enable_benchmarks=no])
1320 AC_MSG_RESULT($enable_benchmarks)
1321 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
1322
1323 # should gnunet-testing be compiled
1324 AC_MSG_CHECKING(wether to compile gnunet-testing)
1325 AC_ARG_ENABLE([testing],
1326    [AS_HELP_STRING([--disable-testing], [do not build gnunet-testing])],
1327    [enable_testing=${enableval}],
1328    [enable_testing=yes])
1329 AC_MSG_RESULT($enable_testing)
1330 AM_CONDITIONAL([HAVE_TESTING], [test "x$enable_testing" = "xyes"])
1331
1332 # should experimental code be compiled (code that may not yet compile)?
1333 AC_MSG_CHECKING(whether to compile experimental code)
1334 AC_ARG_ENABLE([experimental],
1335    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
1336    [enable_experimental=${enableval}],
1337    [enable_experimental=no])
1338 AC_MSG_RESULT($enable_experimental)
1339 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
1340
1341 # should malicious code be compiled (should only be used for testing)?
1342 AC_MSG_CHECKING(whether to compile malicious code)
1343 AC_ARG_ENABLE([malicious],
1344    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code])],
1345    [if test "x$enableval" = "xno"
1346      then
1347        malicious=0
1348      else
1349        malicious=1
1350      fi],
1351    [malicious=0
1352     enable_malicious=no])
1353 AC_MSG_RESULT($enable_malicious)
1354 AM_CONDITIONAL([ENABLE_MALICIOUS], [test 1=$malicious])
1355 AC_DEFINE_UNQUOTED([ENABLE_MALICIOUS], [$malicious],
1356                    [enable compilation of malicious code])
1357
1358 # should services be started by default when a peer starts?  Some services may
1359 # choose to never start by default and it is upto the service/module developer to
1360 # decide it by having "AUTOSTART = NO" instead of "AUTOSTART = @AUTOSTART@" in
1361 # the service/module's conf.in file.
1362 AUTOSTART="YES"
1363 AC_MSG_CHECKING(whether to auto-start peer's services by default)
1364 AC_ARG_ENABLE([autostart],
1365    [AS_HELP_STRING([--disable-autostart], [do not start peer's services by default])],
1366    [enable_autostart=${enableval}
1367     if test "x$enable_autostart" == "xno"
1368     then
1369         AUTOSTART="NO"
1370     fi
1371    ],
1372    [enable_autostart=yes])
1373 AC_MSG_RESULT($enable_autostart)
1374 #AM_CONDITIONAL([HAVE_AUTOSTART], [test "x$enable_autostart" = "xyes"])
1375 AC_SUBST(AUTOSTART)
1376
1377 # should memory statistics be kept (very expensive CPU-wise!)
1378 AC_MSG_CHECKING(whether to create expensive statistics on memory use)
1379 AC_ARG_ENABLE([heapstats],
1380    [AS_HELP_STRING([--enable-heapstats], [enable expensive heap statistics])],
1381    [enable_heapstats=1],
1382    [enable_heapstats=0])
1383 AC_MSG_RESULT($enable_heapstats)
1384 AC_DEFINE_UNQUOTED([ENABLE_HEAP_STATISTICS],$enable_heapstats,[enable expensive heap statistics])
1385
1386 # should code be enabled that works around missing OS functionality on Windows?
1387 # used for test cases
1388 if test $build_target = "mingw"
1389 then
1390         workarounds=1
1391
1392 AC_LINK_IFELSE(
1393  [AC_LANG_PROGRAM(
1394   [#include <ws2tcpip.h>
1395   ],[
1396   int s = socket (0, 0, 0);])
1397  ],[
1398   AC_DEFINE_UNQUOTED([HAVE_SOCKET],1,[Define this if socket() is available])
1399  ],[
1400   AC_DEFINE_UNQUOTED([HAVE_SOCKET],0,[Define this if socket() is available])
1401  ])
1402
1403 AC_LINK_IFELSE(
1404  [AC_LANG_PROGRAM(
1405   [#include <ws2tcpip.h>
1406   ],[
1407   int s = select (0, NULL, NULL, NULL, NULL);])
1408  ],[
1409   AC_DEFINE_UNQUOTED([HAVE_SELECT],1,[Define this if select() is available])
1410  ],[
1411   AC_DEFINE_UNQUOTED([HAVE_SELECT],0,[Define this if select() is available])
1412  ])
1413
1414 AC_LINK_IFELSE(
1415  [AC_LANG_PROGRAM(
1416   [#include <ws2tcpip.h>
1417   ],[
1418   struct in_addr i;
1419   char *s = inet_ntoa (i);])
1420  ],[
1421   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],1,[Define this if inet_ntoa() is available])
1422  ],[
1423   AC_DEFINE_UNQUOTED([HAVE_INET_NTOA],0,[Define this if inet_ntoa() is available])
1424  ])
1425
1426 AC_LINK_IFELSE(
1427  [AC_LANG_PROGRAM(
1428   [#include <ws2tcpip.h>
1429   ],[
1430   int s = getnameinfo (NULL, 0, NULL, 0, NULL, 0, 0);])
1431  ],[
1432   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],1,[Define this if getnameinfo() is available])
1433  ],[
1434   AC_DEFINE_UNQUOTED([HAVE_GETNAMEINFO],0,[Define this if getnameinfo() is available])
1435  ])
1436
1437 AC_LINK_IFELSE(
1438  [AC_LANG_PROGRAM(
1439   [#include <ws2tcpip.h>
1440   ],[
1441   int s = gethostname (NULL, 0);])
1442  ],[
1443   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],1,[Define this if gethostname() is available])
1444  ],[
1445   AC_DEFINE_UNQUOTED([HAVE_GETHOSTNAME],0,[Define this if gethostname() is available])
1446  ])
1447
1448 AC_LINK_IFELSE(
1449  [AC_LANG_PROGRAM(
1450   [#include <ws2tcpip.h>
1451   ],[
1452   void *s = gethostbyname (NULL);])
1453  ],[
1454   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],1,[Define this if gethostbyname() is available])
1455  ],[
1456   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYNAME],0,[Define this if gethostbyname() is available])
1457  ])
1458
1459 AC_LINK_IFELSE(
1460  [AC_LANG_PROGRAM(
1461   [#include <ws2tcpip.h>
1462   ],[
1463   void *s = gethostbyaddr (NULL, 0, 0);])
1464  ],[
1465   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],1,[Define this if gethostbyaddr() is available])
1466  ],[
1467   AC_DEFINE_UNQUOTED([HAVE_GETHOSTBYADDR],0,[Define this if gethostbyaddr() is available])
1468  ])
1469
1470 AC_LINK_IFELSE(
1471  [AC_LANG_PROGRAM(
1472   [#include <ws2tcpip.h>
1473   ],[
1474   int s = getaddrinfo (NULL, NULL, NULL, NULL);])
1475  ],[
1476   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1477  ],[
1478   AC_DEFINE_UNQUOTED([HAVE_GETADDRINFO],1,[Define this if getaddrinfo() is available])
1479  ])
1480
1481 else
1482   AC_MSG_CHECKING(whether to enable windows workarounds)
1483   AC_ARG_ENABLE([windows_workarounds],
1484      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
1485      [enable_workarounds=${enableval}],
1486      [enable_workarounds=no])
1487   AC_MSG_RESULT($enable_workarounds)
1488   if test x$enable_windows_workarounds = "xyes"
1489   then
1490      workarounds=1
1491   else
1492      workarounds=0
1493    fi
1494 fi
1495 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
1496
1497 # gcov compilation
1498 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
1499 AC_ARG_ENABLE([coverage],
1500               AS_HELP_STRING([--enable-coverage],
1501                              [compile the library with code coverage support]),
1502               [use_gcov=${enableval}],
1503               [use_gcov=no])
1504 AC_MSG_RESULT($use_gcov)
1505 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
1506
1507
1508 # version info
1509 AC_PATH_PROG(svnversioncommand, svnversion)
1510 AC_PATH_PROG(gitcommand, git)
1511 AC_MSG_CHECKING(for source being under a VCS)
1512 svn_version=
1513 gitsvn_version=
1514 AS_IF([test ! "X$svnversioncommand" = "X"],
1515 [
1516   svn_version=$(cd $srcdir ; $svnversioncommand -n 2>/dev/null)
1517 ])
1518 AS_IF([test ! "X$gitcommand" = "X"],
1519 [
1520   gitsvn_version=$(cd $srcdir ; git log -1 2>/dev/null | grep "git-svn-id" | sed -e 's/.*@\([[0-9]]\+\) .*/\1/')
1521 ])
1522 AS_IF([test "X$svn_version" = "X" -o "X$svn_version" = "Xexported" -o "X$svn_version" = "XUnversioned directory"],
1523 [
1524   AS_IF([test "X$gitsvn_version" = "X"],
1525   [
1526     vcs_name="no"
1527     vcs_version="\"release\""
1528   ],
1529   [
1530     vcs_name="yes, git-svn"
1531     vcs_version="\"svn-r$gitsvn_version\""
1532   ])
1533 ],
1534 [
1535   vcs_name="yes, svn"
1536   vcs_version="\"svn-r$svn_version\""
1537 ])
1538 AC_MSG_RESULT($vcs_name)
1539
1540 AC_MSG_CHECKING(VCS version)
1541 AC_MSG_RESULT($vcs_version)
1542 AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
1543
1544 AC_CONFIG_FILES([
1545 Makefile
1546 contrib/Makefile
1547 doc/Makefile
1548 doc/man/Makefile
1549 doc/doxygen/Makefile
1550 m4/Makefile
1551 po/Makefile.in
1552 src/Makefile
1553 src/arm/Makefile
1554 src/arm/arm.conf
1555 src/ats/Makefile
1556 src/ats/ats.conf
1557 src/ats-tool/Makefile
1558 src/ats-tests/Makefile
1559 src/auction/Makefile
1560 src/block/Makefile
1561 src/cadet/Makefile
1562 src/cadet/cadet.conf
1563 src/core/Makefile
1564 src/core/core.conf
1565 src/consensus/Makefile
1566 src/consensus/consensus.conf
1567 src/conversation/Makefile
1568 src/conversation/conversation.conf
1569 src/curl/Makefile
1570 src/datacache/Makefile
1571 src/datastore/Makefile
1572 src/datastore/datastore.conf
1573 src/dht/Makefile
1574 src/dht/dht.conf
1575 src/dns/Makefile
1576 src/dns/dns.conf
1577 src/dv/Makefile
1578 src/dv/dv.conf
1579 src/exit/Makefile
1580 src/fragmentation/Makefile
1581 src/fs/Makefile
1582 src/fs/fs.conf
1583 src/gns/Makefile
1584 src/gns/gns.conf
1585 src/gns/nss/Makefile
1586 src/gnsrecord/Makefile
1587 src/hello/Makefile
1588 src/identity/Makefile
1589 src/identity/identity.conf
1590 src/credential/Makefile
1591 src/credential/credential.conf
1592 src/include/Makefile
1593 src/integration-tests/Makefile
1594 src/json/Makefile
1595 src/jsonapi/Makefile
1596 src/hostlist/Makefile
1597 src/multicast/Makefile
1598 src/multicast/multicast.conf
1599 src/my/Makefile
1600 src/mysql/Makefile
1601 src/namecache/Makefile
1602 src/namecache/namecache.conf
1603 src/namestore/Makefile
1604 src/namestore/namestore.conf
1605 src/nat/Makefile
1606 src/nat/nat.conf
1607 src/nat-auto/Makefile
1608 src/nat-auto/nat-auto.conf
1609 src/nse/Makefile
1610 src/nse/nse.conf
1611 src/peerinfo/Makefile
1612 src/peerinfo/peerinfo.conf
1613 src/peerinfo-tool/Makefile
1614 src/peerstore/Makefile
1615 src/peerstore/peerstore.conf
1616 src/pq/Makefile
1617 src/psycutil/Makefile
1618 src/psyc/Makefile
1619 src/psyc/psyc.conf
1620 src/psycstore/Makefile
1621 src/psycstore/psycstore.conf
1622 src/pt/Makefile
1623 src/regex/Makefile
1624 src/regex/regex.conf
1625 src/revocation/Makefile
1626 src/revocation/revocation.conf
1627 src/rps/Makefile
1628 src/rps/rps.conf
1629 src/secretsharing/Makefile
1630 src/secretsharing/secretsharing.conf
1631 src/scalarproduct/Makefile
1632 src/scalarproduct/scalarproduct.conf
1633 src/set/Makefile
1634 src/set/set.conf
1635 src/social/Makefile
1636 src/social/social.conf
1637 src/sq/Makefile
1638 src/statistics/Makefile
1639 src/statistics/statistics.conf
1640 src/template/Makefile
1641 src/testbed/Makefile
1642 src/testbed/testbed.conf
1643 src/testbed-logger/Makefile
1644 src/testbed-logger/testbed-logger.conf
1645 src/testing/Makefile
1646 src/topology/Makefile
1647 src/transport/Makefile
1648 src/transport/transport.conf
1649 src/tun/Makefile
1650 src/util/Makefile
1651 src/util/resolver.conf
1652 src/vpn/Makefile
1653 src/vpn/vpn.conf
1654 src/zonemaster/Makefile
1655 src/zonemaster/zonemaster.conf
1656 src/rest/Makefile
1657 src/identity-provider/Makefile
1658 pkgconfig/Makefile
1659 pkgconfig/gnunetarm.pc
1660 pkgconfig/gnunetats.pc
1661 pkgconfig/gnunetblock.pc
1662 pkgconfig/gnunetcadet.pc
1663 pkgconfig/gnunetconsensus.pc
1664 pkgconfig/gnunetconversation.pc
1665 pkgconfig/gnunetcore.pc
1666 pkgconfig/gnunetdatacache.pc
1667 pkgconfig/gnunetdatastore.pc
1668 pkgconfig/gnunetdht.pc
1669 pkgconfig/gnunetdns.pc
1670 pkgconfig/gnunetdnsparser.pc
1671 pkgconfig/gnunetdnsstub.pc
1672 pkgconfig/gnunetdv.pc
1673 pkgconfig/gnunetenv.pc
1674 pkgconfig/gnunetfragmentation.pc
1675 pkgconfig/gnunetfs.pc
1676 pkgconfig/gnunetgns.pc
1677 pkgconfig/gnunethello.pc
1678 pkgconfig/gnunetidentity.pc
1679 pkgconfig/gnunetmicrophone.pc
1680 pkgconfig/gnunetmulticast.pc
1681 pkgconfig/gnunetmysql.pc
1682 pkgconfig/gnunetnamestore.pc
1683 pkgconfig/gnunetnat.pc
1684 pkgconfig/gnunetnse.pc
1685 pkgconfig/gnunetpeerinfo.pc
1686 pkgconfig/gnunetpq.pc
1687 pkgconfig/gnunetpsyc.pc
1688 pkgconfig/gnunetpsycstore.pc
1689 pkgconfig/gnunetregex.pc
1690 pkgconfig/gnunetrevocation.pc
1691 pkgconfig/gnunetrps.pc
1692 pkgconfig/gnunetscalarproduct.pc
1693 pkgconfig/gnunetset.pc
1694 pkgconfig/gnunetsocial.pc
1695 pkgconfig/gnunetspeaker.pc
1696 pkgconfig/gnunetstatistics.pc
1697 pkgconfig/gnunettestbed.pc
1698 pkgconfig/gnunettesting.pc
1699 pkgconfig/gnunettransport.pc
1700 pkgconfig/gnunettun.pc
1701 pkgconfig/gnunetutil.pc
1702 pkgconfig/gnunetvpn.pc
1703 ])
1704 AC_OUTPUT
1705
1706 # Finally: summary!
1707
1708 # warn user if mysql found but not used due to version
1709 if test "$mysqlfail" = "true"
1710 then
1711   AC_MSG_NOTICE([WARNING: MySQL found, but too old. MySQL support will not be compiled.])
1712 fi
1713
1714 # sqlite
1715 if test "x$sqlite" = "x0"
1716 then
1717   AC_MSG_ERROR([ERROR: sqlite3 not found, but sqlite3 is required.])
1718 fi
1719
1720 # libgnurl
1721 if test "$gnurl" = "0"
1722 then
1723   if test "x$curl" = "xfalse"
1724   then
1725     AC_MSG_NOTICE([WARNING: libgnurl not found.  http client support will not be compiled.])
1726     AC_MSG_WARN([ERROR: libgnurl not found.  hostlist daemon will not be compiled, and you probably WANT the hostlist daemon])
1727   else
1728     AC_MSG_NOTICE([WARNING: libgnurl not found, trying to use libcurl-gnutls instead.])
1729   fi
1730 fi
1731
1732
1733 # bluetooth
1734 if test "x$bluetooth" = "x0"
1735 then
1736   AC_MSG_NOTICE([WARNING: bluetooth library not found.  bluetooth support will not be compiled.])
1737 fi
1738
1739 # jansson
1740 if test "x$jansson" = "x0"
1741 then
1742   AC_MSG_NOTICE([WARNING: jansson library not found.  json support will not be compiled.])
1743 fi
1744
1745 #gnutls
1746 if test x$gnutls != xtrue
1747 then
1748   AC_MSG_NOTICE([WARNING: GnuTLS not found, gnunet-gns-proxy will not be built])
1749 else
1750 if test "x$gnutls_dane" != "x1"
1751 then
1752   AC_MSG_NOTICE([WARNING: GnuTLS has no DANE support, DANE validation will not be possible])
1753 fi
1754 fi
1755
1756 # java ports
1757 if test "x$enable_java_ports" = "xyes"
1758 then
1759   AC_MSG_NOTICE([NOTICE: Opening ports for gnunet-java bindings by default.])
1760 fi
1761
1762 # MHD
1763 if test "x$lmhd" != "x1"
1764 then
1765  AC_MSG_NOTICE([WARNING: libmicrohttpd not found, http transport will not be installed.])
1766 fi
1767
1768 # conversation
1769 if test "x$conversation_backend" = "xnone"
1770 then
1771   if test "x$pulse" != "x1"
1772   then
1773     AC_MSG_NOTICE([WARNING: libpulse(audio) not found, conversation will not be built.])
1774   fi
1775   if test "x$opus" != "x1"
1776   then
1777    AC_MSG_NOTICE([WARNING: libopus not found, conversation will not be built.])
1778   fi
1779   if test "x$gst" != "x1"
1780   then
1781    AC_MSG_NOTICE([WARNING: GStreamer not found, conversation will not be built.])
1782   fi
1783 fi
1784
1785 if test "$extractor" != 1
1786 then
1787  AC_MSG_WARN([ERROR: libextractor not found, but various file-sharing functions require it])
1788 fi
1789
1790 AC_MSG_NOTICE([NOTICE: Database support is set to MySQL: $mysql, SQLite: $sqlite, Postgres: $postgres])
1791
1792 if test "$enable_framework_build" = "yes"
1793 then
1794   AC_MSG_NOTICE([Mac OS X framework build enabled.])
1795 fi
1796
1797 AC_MSG_NOTICE([********************************************
1798 Please make sure NOW that you have created a user and group 'gnunet'
1799 and additionally a group 'gnunetdns'. On Debian and Ubuntu GNU/Linux, type:
1800         addgroup gnunetdns
1801         adduser --system --group --disabled-login --home /var/lib/gnunet gnunet
1802
1803 Make sure that '/var/lib/gnunet' is owned (and writable) by user
1804 'gnunet'.  Then, you can compile GNUnet with
1805         make
1806
1807 After that, run (if necessary as 'root')
1808         make install
1809 to install everything.
1810
1811 Each GNUnet user should be added to the 'gnunet' group (may
1812 require fresh login to come into effect):
1813         adduser USERNAME gnunet
1814 (run the above command as root once for each of your users, replacing
1815 "USERNAME" with the respective login names).  If you have a global IP
1816 address, no further configuration is required.
1817
1818 For more detailed setup instructions, see https://gnunet.org/installation
1819
1820 Optionally, download and compile gnunet-gtk to get a GUI for
1821 file-sharing and configuration.  This is particularly recommended
1822 if your network setup is non-trivial, as gnunet-setup can be
1823 used to test in the GUI if your network configuration is working.
1824 gnunet-setup should be run as the "gnunet" user under X.  As it
1825 does very little with the network, running it as "root" is likely
1826 also harmless.  You can also run it as a normal user, but then
1827 you have to copy ~/.gnunet/gnunet.conf" over to the "gnunet" user's
1828 home directory in the end.
1829
1830 Once you have configured your peer, run (as the 'gnunet' user)
1831         gnunet-arm -s
1832 to start the peer.  You can then run the various GNUnet-tools as
1833 your "normal" user (who should only be in the group 'gnunet').
1834 ********************************************])