arch/arm/cpu/arm926ejs/orion5x/u-boot-spl.lds

   1 /*
   2  * (C) Copyright 2014 Albert ARIBAUD <albert.u.boot@aribaud.net>
   3  *
   4  * Based on:
   5  *
   6  * Allwinner Technology Co., Ltd. <www.allwinnertech.com>
   7  * Tom Cubie <tangliang@allwinnertech.com>
   8  *
   9  * Based on omap-common/u-boot-spl.lds:
  10  *
  11  * (C) Copyright 2002
  12  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  13  *
  14  * (C) Copyright 2010
  15  * Texas Instruments, <www.ti.com>
  16  *      Aneesh V <aneesh@ti.com>
  17  *
  18  * SPDX-License-Identifier:     GPL-2.0+
  19  */
  20 MEMORY { .nor : ORIGIN = CONFIG_SPL_TEXT_BASE,\
  21                 LENGTH = CONFIG_SPL_MAX_SIZE }
  22 MEMORY { .bss : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  23                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  24
  25 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  26 OUTPUT_ARCH(arm)
  27 ENTRY(_start)
  28 SECTIONS
  29 {
  30         .text      :
  31         {
  32                 __start = .;
  33                 *(.vectors)
  34                 CPUDIR/start.o  (.text)
  35                 *(.text*)
  36         } > .nor
  37
  38         . = ALIGN(4);
  39         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.nor
  40
  41         . = ALIGN(4);
  42         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.nor
  43
  44         . = ALIGN(4);
  45         .u_boot_list : {
  46                 KEEP(*(SORT(.u_boot_list*)));
  47         } > .nor
  48
  49         . = ALIGN(4);
  50         __image_copy_end = .;
  51         _end = .;
  52
  53         .bss :
  54         {
  55                 . = ALIGN(4);
  56                 __bss_start = .;
  57                 *(.bss*)
  58                 . = ALIGN(4);
  59                 __bss_end = .;
  60         } > .bss
  61 }