configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id$
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AC_GNU_SOURCE
   9 AM_INIT_AUTOMAKE(tinc, 1.1-cvs)
  10 AC_CONFIG_HEADERS([config.h])
  11 AM_MAINTAINER_MODE
  12
  13 AM_GNU_GETTEXT([external])
  14 AM_GNU_GETTEXT_VERSION(0.14.1)
  15
  16 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  17
  18 ALL_LINGUAS="nl"
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC
  22 AC_PROG_CPP
  23 AC_PROG_INSTALL
  24 AC_PROG_LN_S
  25 AC_PROG_RANLIB
  26
  27 dnl Check and set OS
  28
  29 #AC_CANONICAL_HOST
  30
  31 case $host_os in
  32   *linux*)
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  35   ;;
  36   *freebsd*)
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  39   ;;
  40   *darwin*)
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  43   ;;
  44   *solaris*)
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  47   ;;
  48   *openbsd*)
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  51   ;;
  52   *netbsd*)
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  55   ;;
  56   *bsd*)
  57     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  58     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  59     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  60   ;;
  61   *cygwin*)
  62     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  63     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  64   ;;
  65   *mingw*)
  66     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  67     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  68     LIBS="$LIBS -lws2_32"
  69   ;;
  70   *)
  71     AC_MSG_ERROR("Unknown operating system.")
  72   ;;
  73 esac
  74
  75 AC_CACHE_SAVE
  76
  77 if test -d /sw/include ; then
  78   CPPFLAGS="$CPPFLAGS -I/sw/include"
  79 fi
  80 if test -d /sw/lib ; then
  81   LIBS="$LIBS -L/sw/lib"
  82 fi
  83
  84 dnl Checks for libraries.
  85
  86 AC_CHECK_LIB(event, event_init,
  87   [], [AC_MSG_ERROR(libevent is required)])
  88
  89 dnl Checks for header files.
  90 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
  91
  92 AC_HEADER_STDC
  93 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/socket.h sys/time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h])
  94 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h],
  95   [], [], [#include "have.h"]
  96 )
  97 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
  98   [], [], [#include "have.h"]
  99 )
 100 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 101   [], [], [#include "have.h"]
 102 )
 103
 104 dnl Checks for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_VOLATILE
 107 AC_TYPE_PID_T
 108 AC_TYPE_SIZE_T
 109 AC_HEADER_TIME
 110 AC_STRUCT_TM
 111
 112 tinc_ATTRIBUTE(__malloc__)
 113
 114 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 115   [#include "have.h"]
 116 )
 117
 118 dnl Checks for library functions.
 119 AC_FUNC_MEMCMP
 120 AC_FUNC_ALLOCA
 121 AC_TYPE_SIGNAL
 122 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time unsetenv vsyslog writev],
 123   [], [], [#include "have.h"]
 124 )
 125 AC_FUNC_MALLOC
 126 AC_FUNC_REALLOC
 127
 128 dnl Support for SunOS
 129
 130 AC_CHECK_FUNC(socket, [], [
 131   AC_CHECK_LIB(socket, connect)
 132 ])
 133 AC_CHECK_FUNC(gethostbyname, [], [
 134   AC_CHECK_LIB(nsl, gethostbyname)
 135 ])
 136
 137 AC_CHECK_FUNCS([freeaddrinfo gai_strerror getaddrinfo getnameinfo inet_aton],
 138   [], [], [#include "have.h"]
 139 )
 140
 141 AC_CACHE_SAVE
 142
 143 dnl These are defined in files in m4/
 144
 145 AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 146
 147 tinc_ZLIB
 148 tinc_LZO
 149
 150 if test "$with_libgcrypt" = yes; then
 151         AM_PATH_LIBGCRYPT([1.4.0], [], [])
 152         ln -sf gcrypt/cipher.c gcrypt/cipher.h gcrypt/crypto.c gcrypt/crypto.h gcrypt/digest.c gcrypt/digest.h gcrypt/rsa.c gcrypt/rsa.h gcrypt/rsagen.c gcrypt/rsagen.h src/
 153 else
 154         tinc_OPENSSL
 155         ln -sf openssl/cipher.c openssl/cipher.h openssl/crypto.c openssl/crypto.h openssl/digest.c openssl/digest.h openssl/rsa.c openssl/rsa.h openssl/rsagen.c openssl/rsagen.h src/
 156 fi
 157
 158
 159 dnl Check if support for jumbograms is requested
 160 AC_ARG_ENABLE(jumbograms,
 161   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 162   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 163 )
 164
 165 dnl Check if checkpoint tracing has to be enabled
 166 AC_ARG_ENABLE(tracing,
 167   AS_HELP_STRING([--enable-tracing], [enable checkpoint tracing (debugging only)]),
 168   [ AC_DEFINE(ENABLE_TRACING, 1, [Checkpoint tracing]) ]
 169 )
 170
 171 AC_SUBST(INCLUDES)
 172
 173 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile lib/Makefile po/Makefile.in m4/Makefile])
 174
 175 AC_OUTPUT