CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 if(${CMAKE_VERSION} STREQUAL "2.8.2")
   4         # Bug http://vtk.org/Bug/view.php?id=11020
   5         message(WARNING "CMake/CPack version 2.8.2 will not create working .deb packages!")
   6 endif()
   7
   8 # This can be read from ${PROJECT_NAME} after project() is called
   9 project(minetest)
  10 set(PROJECT_NAME_CAPITALIZED "Minetest")
  11
  12
  13 # Also remember to set PROTOCOL_VERSION in network/networkprotocol.h when releasing
  14 set(VERSION_MAJOR 0)
  15 set(VERSION_MINOR 4)
  16 set(VERSION_PATCH 15)
  17 set(VERSION_EXTRA "" CACHE STRING "Stuff to append to version string")
  18
  19 # Change to false for releases
  20 set(DEVELOPMENT_BUILD TRUE)
  21
  22 set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  23 if(VERSION_EXTRA)
  24         set(VERSION_STRING ${VERSION_STRING}-${VERSION_EXTRA})
  25 elseif(DEVELOPMENT_BUILD)
  26         set(VERSION_STRING "${VERSION_STRING}-dev")
  27 endif()
  28
  29 message(STATUS "*** Will build version ${VERSION_STRING} ***")
  30
  31
  32 # Configuration options
  33 set(DEFAULT_RUN_IN_PLACE FALSE)
  34 if(WIN32)
  35         set(DEFAULT_RUN_IN_PLACE TRUE)
  36 endif()
  37 set(RUN_IN_PLACE ${DEFAULT_RUN_IN_PLACE} CACHE BOOL
  38         "Run directly in source directory structure")
  39
  40
  41 set(BUILD_CLIENT TRUE CACHE BOOL "Build client")
  42 set(BUILD_SERVER FALSE CACHE BOOL "Build server")
  43
  44
  45 set(WARN_ALL TRUE CACHE BOOL "Enable -Wall for Release build")
  46
  47 if(NOT CMAKE_BUILD_TYPE)
  48         # Default to release
  49         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  50 endif()
  51
  52 # Included stuff
  53 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  54
  55
  56 # This is done here so that relative search paths are more reasonable
  57 find_package(Irrlicht)
  58
  59
  60 # Installation
  61
  62 if(WIN32)
  63         set(SHAREDIR ".")
  64         set(BINDIR "bin")
  65         set(DOCDIR "doc")
  66         set(EXAMPLE_CONF_DIR ".")
  67         set(LOCALEDIR "locale")
  68 elseif(APPLE)
  69         set(BUNDLE_NAME ${PROJECT_NAME}.app)
  70         set(BUNDLE_PATH "${BUNDLE_NAME}")
  71         set(BINDIR ${BUNDLE_NAME}/Contents/MacOS)
  72         set(SHAREDIR ${BUNDLE_NAME}/Contents/Resources)
  73         set(DOCDIR "${SHAREDIR}/${PROJECT_NAME}")
  74         set(EXAMPLE_CONF_DIR ${DOCDIR})
  75         set(LOCALEDIR "${SHAREDIR}/locale")
  76 elseif(UNIX) # Linux, BSD etc
  77         if(RUN_IN_PLACE)
  78                 set(SHAREDIR ".")
  79                 set(BINDIR "bin")
  80                 set(DOCDIR "doc")
  81                 set(EXAMPLE_CONF_DIR ".")
  82                 set(MANDIR "unix/man")
  83                 set(XDG_APPS_DIR "unix/applications")
  84                 set(APPDATADIR "unix/metainfo")
  85                 set(ICONDIR "unix/icons")
  86                 set(LOCALEDIR "locale")
  87         else()
  88                 set(SHAREDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}")
  89                 set(BINDIR "${CMAKE_INSTALL_PREFIX}/bin")
  90                 set(DOCDIR "${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_NAME}")
  91                 set(MANDIR "${CMAKE_INSTALL_PREFIX}/share/man")
  92                 set(EXAMPLE_CONF_DIR ${DOCDIR})
  93                 set(XDG_APPS_DIR "${CMAKE_INSTALL_PREFIX}/share/applications")
  94                 set(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/metainfo")
  95                 set(ICONDIR "${CMAKE_INSTALL_PREFIX}/share/icons")
  96                 set(LOCALEDIR "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/locale")
  97         endif()
  98 endif()
  99
 100 set(CUSTOM_SHAREDIR "" CACHE STRING "Directory to install data files into")
 101 if(NOT CUSTOM_SHAREDIR STREQUAL "")
 102         set(SHAREDIR "${CUSTOM_SHAREDIR}")
 103         message(STATUS "Using SHAREDIR=${SHAREDIR}")
 104 endif()
 105
 106 set(CUSTOM_BINDIR "" CACHE STRING "Directory to install binaries into")
 107 if(NOT CUSTOM_BINDIR STREQUAL "")
 108         set(BINDIR "${CUSTOM_BINDIR}")
 109         message(STATUS "Using BINDIR=${BINDIR}")
 110 endif()
 111
 112 set(CUSTOM_DOCDIR "" CACHE STRING "Directory to install documentation into")
 113 if(NOT CUSTOM_DOCDIR STREQUAL "")
 114         set(DOCDIR "${CUSTOM_DOCDIR}")
 115         if(NOT RUN_IN_PLACE)
 116                 set(EXAMPLE_CONF_DIR ${DOCDIR})
 117         endif()
 118         message(STATUS "Using DOCDIR=${DOCDIR}")
 119 endif()
 120
 121 set(CUSTOM_MANDIR "" CACHE STRING "Directory to install manpages into")
 122 if(NOT CUSTOM_MANDIR STREQUAL "")
 123         set(MANDIR "${CUSTOM_MANDIR}")
 124         message(STATUS "Using MANDIR=${MANDIR}")
 125 endif()
 126
 127 set(CUSTOM_EXAMPLE_CONF_DIR "" CACHE STRING "Directory to install example config file into")
 128 if(NOT CUSTOM_EXAMPLE_CONF_DIR STREQUAL "")
 129         set(EXAMPLE_CONF_DIR "${CUSTOM_EXAMPLE_CONF_DIR}")
 130         message(STATUS "Using EXAMPLE_CONF_DIR=${EXAMPLE_CONF_DIR}")
 131 endif()
 132
 133 set(CUSTOM_XDG_APPS_DIR "" CACHE STRING "Directory to install .desktop files into")
 134 if(NOT CUSTOM_XDG_APPS_DIR STREQUAL "")
 135         set(XDG_APPS_DIR "${CUSTOM_XDG_APPS_DIR}")
 136         message(STATUS "Using XDG_APPS_DIR=${XDG_APPS_DIR}")
 137 endif()
 138
 139 set(CUSTOM_ICONDIR "" CACHE STRING "Directory to install icons into")
 140 if(NOT CUSTOM_ICONDIR STREQUAL "")
 141         set(ICONDIR "${CUSTOM_ICONDIR}")
 142         message(STATUS "Using ICONDIR=${ICONDIR}")
 143 endif()
 144
 145 set(CUSTOM_LOCALEDIR "" CACHE STRING "Directory to install l10n files into")
 146 if(NOT CUSTOM_LOCALEDIR STREQUAL "")
 147         set(LOCALEDIR "${CUSTOM_LOCALEDIR}")
 148         message(STATUS "Using LOCALEDIR=${LOCALEDIR}")
 149 endif()
 150
 151
 152 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
 153 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client" DESTINATION "${SHAREDIR}")
 154 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/clientmods" DESTINATION "${SHAREDIR}")
 155 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games" DESTINATION "${SHAREDIR}" PATTERN ".git*" EXCLUDE)
 156
 157 if(BUILD_CLIENT)
 158         install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
 159 endif()
 160 if(RUN_IN_PLACE)
 161         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/mods_here.txt" DESTINATION "${SHAREDIR}/mods")
 162         install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/textures/texture_packs_here.txt" DESTINATION "${SHAREDIR}/textures")
 163 endif()
 164
 165 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/fonts" DESTINATION "${SHAREDIR}")
 166
 167 install(FILES "README.txt" DESTINATION "${DOCDIR}")
 168 install(FILES "doc/lua_api.txt" DESTINATION "${DOCDIR}")
 169 install(FILES "doc/menu_lua_api.txt" DESTINATION "${DOCDIR}")
 170 install(FILES "doc/texture_packs.txt" DESTINATION "${DOCDIR}")
 171 install(FILES "doc/world_format.txt" DESTINATION "${DOCDIR}")
 172 install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
 173
 174 if(UNIX AND NOT APPLE)
 175         install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
 176         install(FILES "misc/net.minetest.minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
 177         install(FILES "misc/net.minetest.minetest.appdata.xml" DESTINATION "${APPDATADIR}")
 178         install(FILES "misc/minetest.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
 179         install(FILES "misc/minetest-xorg-icon-128.png"
 180                 DESTINATION "${ICONDIR}/hicolor/128x128/apps"
 181                 RENAME "minetest.png")
 182 endif()
 183
 184 if(APPLE)
 185         install(FILES "misc/minetest-icon.icns" DESTINATION "${SHAREDIR}")
 186         install(FILES "misc/Info.plist" DESTINATION "${BUNDLE_PATH}/Contents")
 187 endif()
 188
 189 # Library pack
 190 find_package(GMP REQUIRED)
 191 find_package(Json REQUIRED)
 192 find_package(Lua REQUIRED)
 193
 194 # Subdirectories
 195 # Be sure to add all relevant definitions above this
 196
 197 add_subdirectory(src)
 198
 199
 200 # CPack
 201
 202 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "An InfiniMiner/Minecraft inspired game")
 203 set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
 204 set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
 205 set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
 206 set(CPACK_PACKAGE_VENDOR "celeron55")
 207 set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
 208
 209 if(WIN32)
 210         if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 211                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win64")
 212         else()
 213                 set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
 214         endif()
 215
 216         set(CPACK_GENERATOR ZIP)
 217 elseif(APPLE)
 218         set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
 219         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
 220         set(CPACK_GENERATOR ZIP)
 221 else()
 222         set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
 223         set(CPACK_GENERATOR TGZ)
 224         set(CPACK_SOURCE_GENERATOR TGZ)
 225 endif()
 226
 227 include(CPack)
 228
 229
 230 # Add a target to generate API documentation with Doxygen
 231 find_package(Doxygen)
 232 if(DOXYGEN_FOUND)
 233         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in
 234                         ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
 235         add_custom_target(doc
 236                 ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
 237                 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc
 238                 COMMENT "Generating API documentation with Doxygen" VERBATIM
 239         )
 240 endif()
 241