arch/powerpc/kernel/idle_book3s.S

   1 /*
   2  *  This file contains idle entry/exit functions for POWER7,
   3  *  POWER8 and POWER9 CPUs.
   4  *
   5  *  This program is free software; you can redistribute it and/or
   6  *  modify it under the terms of the GNU General Public License
   7  *  as published by the Free Software Foundation; either version
   8  *  2 of the License, or (at your option) any later version.
   9  */
  10
  11 #include <linux/threads.h>
  12 #include <asm/processor.h>
  13 #include <asm/page.h>
  14 #include <asm/cputable.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/ppc_asm.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/ppc-opcode.h>
  19 #include <asm/hw_irq.h>
  20 #include <asm/kvm_book3s_asm.h>
  21 #include <asm/opal.h>
  22 #include <asm/cpuidle.h>
  23 #include <asm/exception-64s.h>
  24 #include <asm/book3s/64/mmu-hash.h>
  25 #include <asm/mmu.h>
  26
  27 #undef DEBUG
  28
  29 /*
  30  * Use unused space in the interrupt stack to save and restore
  31  * registers for winkle support.
  32  */
  33 #define _MMCR0  GPR0
  34 #define _SDR1   GPR3
  35 #define _PTCR   GPR3
  36 #define _RPR    GPR4
  37 #define _SPURR  GPR5
  38 #define _PURR   GPR6
  39 #define _TSCR   GPR7
  40 #define _DSCR   GPR8
  41 #define _AMOR   GPR9
  42 #define _WORT   GPR10
  43 #define _WORC   GPR11
  44 #define _LPCR   GPR12
  45
  46 #define PSSCR_EC_ESL_MASK_SHIFTED          (PSSCR_EC | PSSCR_ESL) >> 16
  47
  48         .text
  49
  50 /*
  51  * Used by threads before entering deep idle states. Saves SPRs
  52  * in interrupt stack frame
  53  */
  54 save_sprs_to_stack:
  55         /*
  56          * Note all register i.e per-core, per-subcore or per-thread is saved
  57          * here since any thread in the core might wake up first
  58          */
  59 BEGIN_FTR_SECTION
  60         /*
  61          * Note - SDR1 is dropped in Power ISA v3. Hence not restoring
  62          * SDR1 here
  63          */
  64         mfspr   r3,SPRN_PTCR
  65         std     r3,_PTCR(r1)
  66         mfspr   r3,SPRN_LPCR
  67         std     r3,_LPCR(r1)
  68 FTR_SECTION_ELSE
  69         mfspr   r3,SPRN_SDR1
  70         std     r3,_SDR1(r1)
  71 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_300)
  72         mfspr   r3,SPRN_RPR
  73         std     r3,_RPR(r1)
  74         mfspr   r3,SPRN_SPURR
  75         std     r3,_SPURR(r1)
  76         mfspr   r3,SPRN_PURR
  77         std     r3,_PURR(r1)
  78         mfspr   r3,SPRN_TSCR
  79         std     r3,_TSCR(r1)
  80         mfspr   r3,SPRN_DSCR
  81         std     r3,_DSCR(r1)
  82         mfspr   r3,SPRN_AMOR
  83         std     r3,_AMOR(r1)
  84         mfspr   r3,SPRN_WORT
  85         std     r3,_WORT(r1)
  86         mfspr   r3,SPRN_WORC
  87         std     r3,_WORC(r1)
  88 /*
  89  * On POWER9, there are idle states such as stop4, invoked via cpuidle,
  90  * that lose hypervisor resources. In such cases, we need to save
  91  * additional SPRs before entering those idle states so that they can
  92  * be restored to their older values on wakeup from the idle state.
  93  *
  94  * On POWER8, the only such deep idle state is winkle which is used
  95  * only in the context of CPU-Hotplug, where these additional SPRs are
  96  * reinitiazed to a sane value. Hence there is no need to save/restore
  97  * these SPRs.
  98  */
  99 BEGIN_FTR_SECTION
 100         blr
 101 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 102
 103 power9_save_additional_sprs:
 104         mfspr   r3, SPRN_PID
 105         mfspr   r4, SPRN_LDBAR
 106         std     r3, STOP_PID(r13)
 107         std     r4, STOP_LDBAR(r13)
 108
 109         mfspr   r3, SPRN_FSCR
 110         mfspr   r4, SPRN_HFSCR
 111         std     r3, STOP_FSCR(r13)
 112         std     r4, STOP_HFSCR(r13)
 113
 114         mfspr   r3, SPRN_MMCRA
 115         mfspr   r4, SPRN_MMCR1
 116         std     r3, STOP_MMCRA(r13)
 117         std     r4, STOP_MMCR1(r13)
 118
 119         mfspr   r3, SPRN_MMCR2
 120         std     r3, STOP_MMCR2(r13)
 121         blr
 122
 123 power9_restore_additional_sprs:
 124         ld      r3,_LPCR(r1)
 125         ld      r4, STOP_PID(r13)
 126         mtspr   SPRN_LPCR,r3
 127         mtspr   SPRN_PID, r4
 128
 129         ld      r3, STOP_LDBAR(r13)
 130         ld      r4, STOP_FSCR(r13)
 131         mtspr   SPRN_LDBAR, r3
 132         mtspr   SPRN_FSCR, r4
 133
 134         ld      r3, STOP_HFSCR(r13)
 135         ld      r4, STOP_MMCRA(r13)
 136         mtspr   SPRN_HFSCR, r3
 137         mtspr   SPRN_MMCRA, r4
 138         /* We have already restored PACA_MMCR0 */
 139         ld      r3, STOP_MMCR1(r13)
 140         ld      r4, STOP_MMCR2(r13)
 141         mtspr   SPRN_MMCR1, r3
 142         mtspr   SPRN_MMCR2, r4
 143         ld      r4, PACA_SPRG_VDSO(r13)
 144         mtspr   SPRN_SPRG3, r4
 145         blr
 146
 147 /*
 148  * Used by threads when the lock bit of core_idle_state is set.
 149  * Threads will spin in HMT_LOW until the lock bit is cleared.
 150  * r14 - pointer to core_idle_state
 151  * r15 - used to load contents of core_idle_state
 152  * r9  - used as a temporary variable
 153  */
 154
 155 core_idle_lock_held:
 156         HMT_LOW
 157 3:      lwz     r15,0(r14)
 158         andis.  r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 159         bne     3b
 160         HMT_MEDIUM
 161         lwarx   r15,0,r14
 162         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 163         bne-    core_idle_lock_held
 164         blr
 165
 166 /*
 167  * Pass requested state in r3:
 168  *      r3 - PNV_THREAD_NAP/SLEEP/WINKLE in POWER8
 169  *         - Requested PSSCR value in POWER9
 170  *
 171  * Address of idle handler to branch to in realmode in r4
 172  */
 173 pnv_powersave_common:
 174         /* Use r3 to pass state nap/sleep/winkle */
 175         /* NAP is a state loss, we create a regs frame on the
 176          * stack, fill it up with the state we care about and
 177          * stick a pointer to it in PACAR1. We really only
 178          * need to save PC, some CR bits and the NV GPRs,
 179          * but for now an interrupt frame will do.
 180          */
 181         mtctr   r4
 182
 183         mflr    r0
 184         std     r0,16(r1)
 185         stdu    r1,-INT_FRAME_SIZE(r1)
 186         std     r0,_LINK(r1)
 187         std     r0,_NIP(r1)
 188
 189         /* We haven't lost state ... yet */
 190         li      r0,0
 191         stb     r0,PACA_NAPSTATELOST(r13)
 192
 193         /* Continue saving state */
 194         SAVE_GPR(2, r1)
 195         SAVE_NVGPRS(r1)
 196         mfcr    r5
 197         std     r5,_CCR(r1)
 198         std     r1,PACAR1(r13)
 199
 200 BEGIN_FTR_SECTION
 201         /*
 202          * POWER9 does not require real mode to stop, and presently does not
 203          * set hwthread_state for KVM (threads don't share MMU context), so
 204          * we can remain in virtual mode for this.
 205          */
 206         bctr
 207 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 208         /*
 209          * POWER8
 210          * Go to real mode to do the nap, as required by the architecture.
 211          * Also, we need to be in real mode before setting hwthread_state,
 212          * because as soon as we do that, another thread can switch
 213          * the MMU context to the guest.
 214          */
 215         LOAD_REG_IMMEDIATE(r7, MSR_IDLE)
 216         mtmsrd  r7,0
 217         bctr
 218
 219 /*
 220  * This is the sequence required to execute idle instructions, as
 221  * specified in ISA v2.07 (and earlier). MSR[IR] and MSR[DR] must be 0.
 222  */
 223 #define IDLE_STATE_ENTER_SEQ_NORET(IDLE_INST)                   \
 224         /* Magic NAP/SLEEP/WINKLE mode enter sequence */        \
 225         std     r0,0(r1);                                       \
 226         ptesync;                                                \
 227         ld      r0,0(r1);                                       \
 228 236:    cmpd    cr0,r0,r0;                                      \
 229         bne     236b;                                           \
 230         IDLE_INST;
 231
 232
 233         .globl pnv_enter_arch207_idle_mode
 234 pnv_enter_arch207_idle_mode:
 235 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 236         /* Tell KVM we're entering idle */
 237         li      r4,KVM_HWTHREAD_IN_IDLE
 238         /******************************************************/
 239         /*  N O T E   W E L L    ! ! !    N O T E   W E L L   */
 240         /* The following store to HSTATE_HWTHREAD_STATE(r13)  */
 241         /* MUST occur in real mode, i.e. with the MMU off,    */
 242         /* and the MMU must stay off until we clear this flag */
 243         /* and test HSTATE_HWTHREAD_REQ(r13) in               */
 244         /* pnv_powersave_wakeup in this file.                 */
 245         /* The reason is that another thread can switch the   */
 246         /* MMU to a guest context whenever this flag is set   */
 247         /* to KVM_HWTHREAD_IN_IDLE, and if the MMU was on,    */
 248         /* that would potentially cause this thread to start  */
 249         /* executing instructions from guest memory in        */
 250         /* hypervisor mode, leading to a host crash or data   */
 251         /* corruption, or worse.                              */
 252         /******************************************************/
 253         stb     r4,HSTATE_HWTHREAD_STATE(r13)
 254 #endif
 255         stb     r3,PACA_THREAD_IDLE_STATE(r13)
 256         cmpwi   cr3,r3,PNV_THREAD_SLEEP
 257         bge     cr3,2f
 258         IDLE_STATE_ENTER_SEQ_NORET(PPC_NAP)
 259         /* No return */
 260 2:
 261         /* Sleep or winkle */
 262         lbz     r7,PACA_THREAD_MASK(r13)
 263         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 264         li      r5,0
 265         beq     cr3,3f
 266         lis     r5,PNV_CORE_IDLE_WINKLE_COUNT@h
 267 3:
 268 lwarx_loop1:
 269         lwarx   r15,0,r14
 270
 271         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 272         bnel-   core_idle_lock_held
 273
 274         add     r15,r15,r5                      /* Add if winkle */
 275         andc    r15,r15,r7                      /* Clear thread bit */
 276
 277         andi.   r9,r15,PNV_CORE_IDLE_THREAD_BITS
 278
 279 /*
 280  * If cr0 = 0, then current thread is the last thread of the core entering
 281  * sleep. Last thread needs to execute the hardware bug workaround code if
 282  * required by the platform.
 283  * Make the workaround call unconditionally here. The below branch call is
 284  * patched out when the idle states are discovered if the platform does not
 285  * require it.
 286  */
 287 .global pnv_fastsleep_workaround_at_entry
 288 pnv_fastsleep_workaround_at_entry:
 289         beq     fastsleep_workaround_at_entry
 290
 291         stwcx.  r15,0,r14
 292         bne-    lwarx_loop1
 293         isync
 294
 295 common_enter: /* common code for all the threads entering sleep or winkle */
 296         bgt     cr3,enter_winkle
 297         IDLE_STATE_ENTER_SEQ_NORET(PPC_SLEEP)
 298
 299 fastsleep_workaround_at_entry:
 300         oris    r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 301         stwcx.  r15,0,r14
 302         bne-    lwarx_loop1
 303         isync
 304
 305         /* Fast sleep workaround */
 306         li      r3,1
 307         li      r4,1
 308         bl      opal_config_cpu_idle_state
 309
 310         /* Unlock */
 311         xoris   r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 312         lwsync
 313         stw     r15,0(r14)
 314         b       common_enter
 315
 316 enter_winkle:
 317         bl      save_sprs_to_stack
 318
 319         IDLE_STATE_ENTER_SEQ_NORET(PPC_WINKLE)
 320
 321 /*
 322  * r3 - PSSCR value corresponding to the requested stop state.
 323  */
 324 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 325 power_enter_stop_kvm_rm:
 326         /*
 327          * This is currently unused because POWER9 KVM does not have to
 328          * gather secondary threads into sibling mode, but the code is
 329          * here in case that function is required.
 330          *
 331          * Tell KVM we're entering idle.
 332          */
 333         li      r4,KVM_HWTHREAD_IN_IDLE
 334         /* DO THIS IN REAL MODE!  See comment above. */
 335         stb     r4,HSTATE_HWTHREAD_STATE(r13)
 336 #endif
 337 power_enter_stop:
 338 /*
 339  * Check if we are executing the lite variant with ESL=EC=0
 340  */
 341         andis.   r4,r3,PSSCR_EC_ESL_MASK_SHIFTED
 342         clrldi   r3,r3,60 /* r3 = Bits[60:63] = Requested Level (RL) */
 343         bne      .Lhandle_esl_ec_set
 344         PPC_STOP
 345         li      r3,0  /* Since we didn't lose state, return 0 */
 346
 347         /*
 348          * pnv_wakeup_noloss() expects r12 to contain the SRR1 value so
 349          * it can determine if the wakeup reason is an HMI in
 350          * CHECK_HMI_INTERRUPT.
 351          *
 352          * However, when we wakeup with ESL=0, SRR1 will not contain the wakeup
 353          * reason, so there is no point setting r12 to SRR1.
 354          *
 355          * Further, we clear r12 here, so that we don't accidentally enter the
 356          * HMI in pnv_wakeup_noloss() if the value of r12[42:45] == WAKE_HMI.
 357          */
 358         li      r12, 0
 359         b       pnv_wakeup_noloss
 360
 361 .Lhandle_esl_ec_set:
 362         /*
 363          * POWER9 DD2 can incorrectly set PMAO when waking up after a
 364          * state-loss idle. Saving and restoring MMCR0 over idle is a
 365          * workaround.
 366          */
 367         mfspr   r4,SPRN_MMCR0
 368         std     r4,_MMCR0(r1)
 369
 370 /*
 371  * Check if the requested state is a deep idle state.
 372  */
 373         LOAD_REG_ADDRBASE(r5,pnv_first_deep_stop_state)
 374         ld      r4,ADDROFF(pnv_first_deep_stop_state)(r5)
 375         cmpd    r3,r4
 376         bge     .Lhandle_deep_stop
 377         PPC_STOP        /* Does not return (system reset interrupt) */
 378
 379 .Lhandle_deep_stop:
 380 /*
 381  * Entering deep idle state.
 382  * Clear thread bit in PACA_CORE_IDLE_STATE, save SPRs to
 383  * stack and enter stop
 384  */
 385         lbz     r7,PACA_THREAD_MASK(r13)
 386         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 387
 388 lwarx_loop_stop:
 389         lwarx   r15,0,r14
 390         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 391         bnel-   core_idle_lock_held
 392         andc    r15,r15,r7                      /* Clear thread bit */
 393
 394         stwcx.  r15,0,r14
 395         bne-    lwarx_loop_stop
 396         isync
 397
 398         bl      save_sprs_to_stack
 399
 400         PPC_STOP        /* Does not return (system reset interrupt) */
 401
 402 /*
 403  * Entered with MSR[EE]=0 and no soft-masked interrupts pending.
 404  * r3 contains desired idle state (PNV_THREAD_NAP/SLEEP/WINKLE).
 405  */
 406 _GLOBAL(power7_idle_insn)
 407         /* Now check if user or arch enabled NAP mode */
 408         LOAD_REG_ADDR(r4, pnv_enter_arch207_idle_mode)
 409         b       pnv_powersave_common
 410
 411 #define CHECK_HMI_INTERRUPT                                             \
 412 BEGIN_FTR_SECTION_NESTED(66);                                           \
 413         rlwinm  r0,r12,45-31,0xf;  /* extract wake reason field (P8) */ \
 414 FTR_SECTION_ELSE_NESTED(66);                                            \
 415         rlwinm  r0,r12,45-31,0xe;  /* P7 wake reason field is 3 bits */ \
 416 ALT_FTR_SECTION_END_NESTED_IFSET(CPU_FTR_ARCH_207S, 66);                \
 417         cmpwi   r0,0xa;                 /* Hypervisor maintenance ? */  \
 418         bne+    20f;                                                    \
 419         /* Invoke opal call to handle hmi */                            \
 420         ld      r2,PACATOC(r13);                                        \
 421         ld      r1,PACAR1(r13);                                         \
 422         std     r3,ORIG_GPR3(r1);       /* Save original r3 */          \
 423         li      r3,0;                   /* NULL argument */             \
 424         bl      hmi_exception_realmode;                                 \
 425         nop;                                                            \
 426         ld      r3,ORIG_GPR3(r1);       /* Restore original r3 */       \
 427 20:     nop;
 428
 429 /*
 430  * Entered with MSR[EE]=0 and no soft-masked interrupts pending.
 431  * r3 contains desired PSSCR register value.
 432  */
 433 _GLOBAL(power9_idle_stop)
 434         std     r3, PACA_REQ_PSSCR(r13)
 435         mtspr   SPRN_PSSCR,r3
 436         LOAD_REG_ADDR(r4,power_enter_stop)
 437         b       pnv_powersave_common
 438         /* No return */
 439
 440 /*
 441  * On waking up from stop 0,1,2 with ESL=1 on POWER9 DD1,
 442  * HSPRG0 will be set to the HSPRG0 value of one of the
 443  * threads in this core. Thus the value we have in r13
 444  * may not be this thread's paca pointer.
 445  *
 446  * Fortunately, the TIR remains invariant. Since this thread's
 447  * paca pointer is recorded in all its sibling's paca, we can
 448  * correctly recover this thread's paca pointer if we
 449  * know the index of this thread in the core.
 450  *
 451  * This index can be obtained from the TIR.
 452  *
 453  * i.e, thread's position in the core = TIR.
 454  * If this value is i, then this thread's paca is
 455  * paca->thread_sibling_pacas[i].
 456  */
 457 power9_dd1_recover_paca:
 458         mfspr   r4, SPRN_TIR
 459         /*
 460          * Since each entry in thread_sibling_pacas is 8 bytes
 461          * we need to left-shift by 3 bits. Thus r4 = i * 8
 462          */
 463         sldi    r4, r4, 3
 464         /* Get &paca->thread_sibling_pacas[0] in r5 */
 465         ld      r5, PACA_SIBLING_PACA_PTRS(r13)
 466         /* Load paca->thread_sibling_pacas[i] into r13 */
 467         ldx     r13, r4, r5
 468         SET_PACA(r13)
 469         /*
 470          * Indicate that we have lost NVGPR state
 471          * which needs to be restored from the stack.
 472          */
 473         li      r3, 1
 474         stb     r3,PACA_NAPSTATELOST(r13)
 475         blr
 476
 477 /*
 478  * Called from machine check handler for powersave wakeups.
 479  * Low level machine check processing has already been done. Now just
 480  * go through the wake up path to get everything in order.
 481  *
 482  * r3 - The original SRR1 value.
 483  * Original SRR[01] have been clobbered.
 484  * MSR_RI is clear.
 485  */
 486 .global pnv_powersave_wakeup_mce
 487 pnv_powersave_wakeup_mce:
 488         /* Set cr3 for pnv_powersave_wakeup */
 489         rlwinm  r11,r3,47-31,30,31
 490         cmpwi   cr3,r11,2
 491
 492         /*
 493          * Now put the original SRR1 with SRR1_WAKEMCE_RESVD as the wake
 494          * reason into r12, which allows reuse of the system reset wakeup
 495          * code without being mistaken for another type of wakeup.
 496          */
 497         oris    r12,r3,SRR1_WAKEMCE_RESVD@h
 498
 499         b       pnv_powersave_wakeup
 500
 501 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 502 kvm_start_guest_check:
 503         li      r0,KVM_HWTHREAD_IN_KERNEL
 504         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 505         /* Order setting hwthread_state vs. testing hwthread_req */
 506         sync
 507         lbz     r0,HSTATE_HWTHREAD_REQ(r13)
 508         cmpwi   r0,0
 509         beqlr
 510         b       kvm_start_guest
 511 #endif
 512
 513 /*
 514  * Called from reset vector for powersave wakeups.
 515  * cr3 - set to gt if waking up with partial/complete hypervisor state loss
 516  * r12 - SRR1
 517  */
 518 .global pnv_powersave_wakeup
 519 pnv_powersave_wakeup:
 520         ld      r2, PACATOC(r13)
 521
 522 BEGIN_FTR_SECTION
 523 BEGIN_FTR_SECTION_NESTED(70)
 524         bl      power9_dd1_recover_paca
 525 END_FTR_SECTION_NESTED_IFSET(CPU_FTR_POWER9_DD1, 70)
 526         bl      pnv_restore_hyp_resource_arch300
 527 FTR_SECTION_ELSE
 528         bl      pnv_restore_hyp_resource_arch207
 529 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_300)
 530
 531         li      r0,PNV_THREAD_RUNNING
 532         stb     r0,PACA_THREAD_IDLE_STATE(r13)  /* Clear thread state */
 533
 534         mr      r3,r12
 535
 536 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 537 BEGIN_FTR_SECTION
 538         bl      kvm_start_guest_check
 539 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 540 #endif
 541
 542         /* Return SRR1 from power7_nap() */
 543         blt     cr3,pnv_wakeup_noloss
 544         b       pnv_wakeup_loss
 545
 546 /*
 547  * Check whether we have woken up with hypervisor state loss.
 548  * If yes, restore hypervisor state and return back to link.
 549  *
 550  * cr3 - set to gt if waking up with partial/complete hypervisor state loss
 551  */
 552 pnv_restore_hyp_resource_arch300:
 553         /*
 554          * Workaround for POWER9, if we lost resources, the ERAT
 555          * might have been mixed up and needs flushing. We also need
 556          * to reload MMCR0 (see comment above). We also need to set
 557          * then clear bit 60 in MMCRA to ensure the PMU starts running.
 558          */
 559         blt     cr3,1f
 560         PPC_INVALIDATE_ERAT
 561         ld      r1,PACAR1(r13)
 562         mfspr   r4,SPRN_MMCRA
 563         ori     r4,r4,(1 << (63-60))
 564         mtspr   SPRN_MMCRA,r4
 565         xori    r4,r4,(1 << (63-60))
 566         mtspr   SPRN_MMCRA,r4
 567         ld      r4,_MMCR0(r1)
 568         mtspr   SPRN_MMCR0,r4
 569 1:
 570         /*
 571          * POWER ISA 3. Use PSSCR to determine if we
 572          * are waking up from deep idle state
 573          */
 574         LOAD_REG_ADDRBASE(r5,pnv_first_deep_stop_state)
 575         ld      r4,ADDROFF(pnv_first_deep_stop_state)(r5)
 576
 577 BEGIN_FTR_SECTION_NESTED(71)
 578         /*
 579          * Assume that we are waking up from the state
 580          * same as the Requested Level (RL) in the PSSCR
 581          * which are Bits 60-63
 582          */
 583         ld      r5,PACA_REQ_PSSCR(r13)
 584         rldicl  r5,r5,0,60
 585 FTR_SECTION_ELSE_NESTED(71)
 586         /*
 587          * 0-3 bits correspond to Power-Saving Level Status
 588          * which indicates the idle state we are waking up from
 589          */
 590         mfspr   r5, SPRN_PSSCR
 591         rldicl  r5,r5,4,60
 592 ALT_FTR_SECTION_END_NESTED_IFSET(CPU_FTR_POWER9_DD1, 71)
 593         cmpd    cr4,r5,r4
 594         bge     cr4,pnv_wakeup_tb_loss /* returns to caller */
 595
 596         blr     /* Waking up without hypervisor state loss. */
 597
 598 /* Same calling convention as arch300 */
 599 pnv_restore_hyp_resource_arch207:
 600         /*
 601          * POWER ISA 2.07 or less.
 602          * Check if we slept with sleep or winkle.
 603          */
 604         lbz     r4,PACA_THREAD_IDLE_STATE(r13)
 605         cmpwi   cr2,r4,PNV_THREAD_NAP
 606         bgt     cr2,pnv_wakeup_tb_loss  /* Either sleep or Winkle */
 607
 608         /*
 609          * We fall through here if PACA_THREAD_IDLE_STATE shows we are waking
 610          * up from nap. At this stage CR3 shouldn't contains 'gt' since that
 611          * indicates we are waking with hypervisor state loss from nap.
 612          */
 613         bgt     cr3,.
 614
 615         blr     /* Waking up without hypervisor state loss */
 616
 617 /*
 618  * Called if waking up from idle state which can cause either partial or
 619  * complete hyp state loss.
 620  * In POWER8, called if waking up from fastsleep or winkle
 621  * In POWER9, called if waking up from stop state >= pnv_first_deep_stop_state
 622  *
 623  * r13 - PACA
 624  * cr3 - gt if waking up with partial/complete hypervisor state loss
 625  *
 626  * If ISA300:
 627  * cr4 - gt or eq if waking up from complete hypervisor state loss.
 628  *
 629  * If ISA207:
 630  * r4 - PACA_THREAD_IDLE_STATE
 631  */
 632 pnv_wakeup_tb_loss:
 633         ld      r1,PACAR1(r13)
 634         /*
 635          * Before entering any idle state, the NVGPRs are saved in the stack.
 636          * If there was a state loss, or PACA_NAPSTATELOST was set, then the
 637          * NVGPRs are restored. If we are here, it is likely that state is lost,
 638          * but not guaranteed -- neither ISA207 nor ISA300 tests to reach
 639          * here are the same as the test to restore NVGPRS:
 640          * PACA_THREAD_IDLE_STATE test for ISA207, PSSCR test for ISA300,
 641          * and SRR1 test for restoring NVGPRs.
 642          *
 643          * We are about to clobber NVGPRs now, so set NAPSTATELOST to
 644          * guarantee they will always be restored. This might be tightened
 645          * with careful reading of specs (particularly for ISA300) but this
 646          * is already a slow wakeup path and it's simpler to be safe.
 647          */
 648         li      r0,1
 649         stb     r0,PACA_NAPSTATELOST(r13)
 650
 651         /*
 652          *
 653          * Save SRR1 and LR in NVGPRs as they might be clobbered in
 654          * opal_call() (called in CHECK_HMI_INTERRUPT). SRR1 is required
 655          * to determine the wakeup reason if we branch to kvm_start_guest. LR
 656          * is required to return back to reset vector after hypervisor state
 657          * restore is complete.
 658          */
 659         mr      r19,r12
 660         mr      r18,r4
 661         mflr    r17
 662 BEGIN_FTR_SECTION
 663         CHECK_HMI_INTERRUPT
 664 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 665
 666         ld      r14,PACA_CORE_IDLE_STATE_PTR(r13)
 667         lbz     r7,PACA_THREAD_MASK(r13)
 668
 669         /*
 670          * Take the core lock to synchronize against other threads.
 671          *
 672          * Lock bit is set in one of the 2 cases-
 673          * a. In the sleep/winkle enter path, the last thread is executing
 674          * fastsleep workaround code.
 675          * b. In the wake up path, another thread is executing fastsleep
 676          * workaround undo code or resyncing timebase or restoring context
 677          * In either case loop until the lock bit is cleared.
 678          */
 679 1:
 680         lwarx   r15,0,r14
 681         andis.  r9,r15,PNV_CORE_IDLE_LOCK_BIT@h
 682         bnel-   core_idle_lock_held
 683         oris    r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 684         stwcx.  r15,0,r14
 685         bne-    1b
 686         isync
 687
 688         andi.   r9,r15,PNV_CORE_IDLE_THREAD_BITS
 689         cmpwi   cr2,r9,0
 690
 691         /*
 692          * At this stage
 693          * cr2 - eq if first thread to wakeup in core
 694          * cr3-  gt if waking up with partial/complete hypervisor state loss
 695          * ISA300:
 696          * cr4 - gt or eq if waking up from complete hypervisor state loss.
 697          */
 698
 699 BEGIN_FTR_SECTION
 700         /*
 701          * Were we in winkle?
 702          * If yes, check if all threads were in winkle, decrement our
 703          * winkle count, set all thread winkle bits if all were in winkle.
 704          * Check if our thread has a winkle bit set, and set cr4 accordingly
 705          * (to match ISA300, above). Pseudo-code for core idle state
 706          * transitions for ISA207 is as follows (everything happens atomically
 707          * due to store conditional and/or lock bit):
 708          *
 709          * nap_idle() { }
 710          * nap_wake() { }
 711          *
 712          * sleep_idle()
 713          * {
 714          *      core_idle_state &= ~thread_in_core
 715          * }
 716          *
 717          * sleep_wake()
 718          * {
 719          *     bool first_in_core, first_in_subcore;
 720          *
 721          *     first_in_core = (core_idle_state & IDLE_THREAD_BITS) == 0;
 722          *     first_in_subcore = (core_idle_state & SUBCORE_SIBLING_MASK) == 0;
 723          *
 724          *     core_idle_state |= thread_in_core;
 725          * }
 726          *
 727          * winkle_idle()
 728          * {
 729          *      core_idle_state &= ~thread_in_core;
 730          *      core_idle_state += 1 << WINKLE_COUNT_SHIFT;
 731          * }
 732          *
 733          * winkle_wake()
 734          * {
 735          *     bool first_in_core, first_in_subcore, winkle_state_lost;
 736          *
 737          *     first_in_core = (core_idle_state & IDLE_THREAD_BITS) == 0;
 738          *     first_in_subcore = (core_idle_state & SUBCORE_SIBLING_MASK) == 0;
 739          *
 740          *     core_idle_state |= thread_in_core;
 741          *
 742          *     if ((core_idle_state & WINKLE_MASK) == (8 << WINKLE_COUNT_SIHFT))
 743          *         core_idle_state |= THREAD_WINKLE_BITS;
 744          *     core_idle_state -= 1 << WINKLE_COUNT_SHIFT;
 745          *
 746          *     winkle_state_lost = core_idle_state &
 747          *                              (thread_in_core << WINKLE_THREAD_SHIFT);
 748          *     core_idle_state &= ~(thread_in_core << WINKLE_THREAD_SHIFT);
 749          * }
 750          *
 751          */
 752         cmpwi   r18,PNV_THREAD_WINKLE
 753         bne     2f
 754         andis.  r9,r15,PNV_CORE_IDLE_WINKLE_COUNT_ALL_BIT@h
 755         subis   r15,r15,PNV_CORE_IDLE_WINKLE_COUNT@h
 756         beq     2f
 757         ori     r15,r15,PNV_CORE_IDLE_THREAD_WINKLE_BITS /* all were winkle */
 758 2:
 759         /* Shift thread bit to winkle mask, then test if this thread is set,
 760          * and remove it from the winkle bits */
 761         slwi    r8,r7,8
 762         and     r8,r8,r15
 763         andc    r15,r15,r8
 764         cmpwi   cr4,r8,1 /* cr4 will be gt if our bit is set, lt if not */
 765
 766         lbz     r4,PACA_SUBCORE_SIBLING_MASK(r13)
 767         and     r4,r4,r15
 768         cmpwi   r4,0    /* Check if first in subcore */
 769
 770         or      r15,r15,r7              /* Set thread bit */
 771         beq     first_thread_in_subcore
 772 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 773
 774         or      r15,r15,r7              /* Set thread bit */
 775         beq     cr2,first_thread_in_core
 776
 777         /* Not first thread in core or subcore to wake up */
 778         b       clear_lock
 779
 780 first_thread_in_subcore:
 781         /*
 782          * If waking up from sleep, subcore state is not lost. Hence
 783          * skip subcore state restore
 784          */
 785         blt     cr4,subcore_state_restored
 786
 787         /* Restore per-subcore state */
 788         ld      r4,_SDR1(r1)
 789         mtspr   SPRN_SDR1,r4
 790
 791         ld      r4,_RPR(r1)
 792         mtspr   SPRN_RPR,r4
 793         ld      r4,_AMOR(r1)
 794         mtspr   SPRN_AMOR,r4
 795
 796 subcore_state_restored:
 797         /*
 798          * Check if the thread is also the first thread in the core. If not,
 799          * skip to clear_lock.
 800          */
 801         bne     cr2,clear_lock
 802
 803 first_thread_in_core:
 804
 805         /*
 806          * First thread in the core waking up from any state which can cause
 807          * partial or complete hypervisor state loss. It needs to
 808          * call the fastsleep workaround code if the platform requires it.
 809          * Call it unconditionally here. The below branch instruction will
 810          * be patched out if the platform does not have fastsleep or does not
 811          * require the workaround. Patching will be performed during the
 812          * discovery of idle-states.
 813          */
 814 .global pnv_fastsleep_workaround_at_exit
 815 pnv_fastsleep_workaround_at_exit:
 816         b       fastsleep_workaround_at_exit
 817
 818 timebase_resync:
 819         /*
 820          * Use cr3 which indicates that we are waking up with atleast partial
 821          * hypervisor state loss to determine if TIMEBASE RESYNC is needed.
 822          */
 823         ble     cr3,.Ltb_resynced
 824         /* Time base re-sync */
 825         bl      opal_resync_timebase;
 826         /*
 827          * If waking up from sleep (POWER8), per core state
 828          * is not lost, skip to clear_lock.
 829          */
 830 .Ltb_resynced:
 831         blt     cr4,clear_lock
 832
 833         /*
 834          * First thread in the core to wake up and its waking up with
 835          * complete hypervisor state loss. Restore per core hypervisor
 836          * state.
 837          */
 838 BEGIN_FTR_SECTION
 839         ld      r4,_PTCR(r1)
 840         mtspr   SPRN_PTCR,r4
 841         ld      r4,_RPR(r1)
 842         mtspr   SPRN_RPR,r4
 843         ld      r4,_AMOR(r1)
 844         mtspr   SPRN_AMOR,r4
 845 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 846
 847         ld      r4,_TSCR(r1)
 848         mtspr   SPRN_TSCR,r4
 849         ld      r4,_WORC(r1)
 850         mtspr   SPRN_WORC,r4
 851
 852 clear_lock:
 853         xoris   r15,r15,PNV_CORE_IDLE_LOCK_BIT@h
 854         lwsync
 855         stw     r15,0(r14)
 856
 857 common_exit:
 858         /*
 859          * Common to all threads.
 860          *
 861          * If waking up from sleep, hypervisor state is not lost. Hence
 862          * skip hypervisor state restore.
 863          */
 864         blt     cr4,hypervisor_state_restored
 865
 866         /* Waking up from winkle */
 867
 868 BEGIN_MMU_FTR_SECTION
 869         b       no_segments
 870 END_MMU_FTR_SECTION_IFSET(MMU_FTR_TYPE_RADIX)
 871         /* Restore SLB  from PACA */
 872         ld      r8,PACA_SLBSHADOWPTR(r13)
 873
 874         .rept   SLB_NUM_BOLTED
 875         li      r3, SLBSHADOW_SAVEAREA
 876         LDX_BE  r5, r8, r3
 877         addi    r3, r3, 8
 878         LDX_BE  r6, r8, r3
 879         andis.  r7,r5,SLB_ESID_V@h
 880         beq     1f
 881         slbmte  r6,r5
 882 1:      addi    r8,r8,16
 883         .endr
 884 no_segments:
 885
 886         /* Restore per thread state */
 887
 888         ld      r4,_SPURR(r1)
 889         mtspr   SPRN_SPURR,r4
 890         ld      r4,_PURR(r1)
 891         mtspr   SPRN_PURR,r4
 892         ld      r4,_DSCR(r1)
 893         mtspr   SPRN_DSCR,r4
 894         ld      r4,_WORT(r1)
 895         mtspr   SPRN_WORT,r4
 896
 897         /* Call cur_cpu_spec->cpu_restore() */
 898         LOAD_REG_ADDR(r4, cur_cpu_spec)
 899         ld      r4,0(r4)
 900         ld      r12,CPU_SPEC_RESTORE(r4)
 901 #ifdef PPC64_ELF_ABI_v1
 902         ld      r12,0(r12)
 903 #endif
 904         mtctr   r12
 905         bctrl
 906
 907 /*
 908  * On POWER9, we can come here on wakeup from a cpuidle stop state.
 909  * Hence restore the additional SPRs to the saved value.
 910  *
 911  * On POWER8, we come here only on winkle. Since winkle is used
 912  * only in the case of CPU-Hotplug, we don't need to restore
 913  * the additional SPRs.
 914  */
 915 BEGIN_FTR_SECTION
 916         bl      power9_restore_additional_sprs
 917 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 918 hypervisor_state_restored:
 919
 920         mr      r12,r19
 921         mtlr    r17
 922         blr             /* return to pnv_powersave_wakeup */
 923
 924 fastsleep_workaround_at_exit:
 925         li      r3,1
 926         li      r4,0
 927         bl      opal_config_cpu_idle_state
 928         b       timebase_resync
 929
 930 /*
 931  * R3 here contains the value that will be returned to the caller
 932  * of power7_nap.
 933  * R12 contains SRR1 for CHECK_HMI_INTERRUPT.
 934  */
 935 .global pnv_wakeup_loss
 936 pnv_wakeup_loss:
 937         ld      r1,PACAR1(r13)
 938 BEGIN_FTR_SECTION
 939         CHECK_HMI_INTERRUPT
 940 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 941         REST_NVGPRS(r1)
 942         REST_GPR(2, r1)
 943         ld      r4,PACAKMSR(r13)
 944         ld      r5,_LINK(r1)
 945         ld      r6,_CCR(r1)
 946         addi    r1,r1,INT_FRAME_SIZE
 947         mtlr    r5
 948         mtcr    r6
 949         mtmsrd  r4
 950         blr
 951
 952 /*
 953  * R3 here contains the value that will be returned to the caller
 954  * of power7_nap.
 955  * R12 contains SRR1 for CHECK_HMI_INTERRUPT.
 956  */
 957 pnv_wakeup_noloss:
 958         lbz     r0,PACA_NAPSTATELOST(r13)
 959         cmpwi   r0,0
 960         bne     pnv_wakeup_loss
 961         ld      r1,PACAR1(r13)
 962 BEGIN_FTR_SECTION
 963         CHECK_HMI_INTERRUPT
 964 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 965         ld      r4,PACAKMSR(r13)
 966         ld      r5,_NIP(r1)
 967         ld      r6,_CCR(r1)
 968         addi    r1,r1,INT_FRAME_SIZE
 969         mtlr    r5
 970         mtcr    r6
 971         mtmsrd  r4
 972         blr