configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.0.32])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE([1.11 check-news std-options subdir-objects nostdinc silent-rules -Wall info-in-builddir])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_SILENT_RULES([yes])
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21
  22 AM_PROG_CC_C_O
  23
  24 PKG_PROG_PKG_CONFIG
  25
  26 dnl Check and set OS
  27
  28 AC_CANONICAL_HOST
  29
  30 case $host_os in
  31   *linux*)
  32     linux=true
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34   ;;
  35   *freebsd*)
  36     bsd=true
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38   ;;
  39   *darwin*)
  40     bsd=true
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42   ;;
  43   *solaris*)
  44     solaris=true
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46   ;;
  47   *openbsd*)
  48     bsd=true
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50   ;;
  51   *netbsd*)
  52     bsd=true
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54   ;;
  55   *dragonfly*)
  56     bsd=true
  57     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  58   ;;
  59   *bsd*)
  60     bsd=true
  61     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  62     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  63   ;;
  64   *cygwin*)
  65     cygwin=true
  66     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  67   ;;
  68   *mingw*)
  69     mingw=true
  70     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  71     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  72   ;;
  73   *)
  74     AC_MSG_ERROR("Unknown operating system.")
  75   ;;
  76 esac
  77
  78 AC_ARG_ENABLE(uml,
  79   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  80   [ AS_IF([test "x$enable_uml" = "xyes"],
  81       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  82         uml=true
  83       ],
  84       [uml=false])
  85   ],
  86   [uml=false]
  87 )
  88
  89 AC_ARG_ENABLE(vde,
  90   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  91   [ AS_IF([test "x$enable_vde" = "xyes"],
  92       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  93         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  94         vde=true
  95       ],
  96       [vde=false])
  97   ],
  98   [vde=false]
  99 )
 100
 101 AC_ARG_ENABLE(tunemu,
 102   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 103   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 104       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 105         tunemu=true
 106       ],
 107       [tunemu=false])
 108   ],
 109   [tunemu=false]
 110 )
 111
 112 AC_ARG_WITH(windows2000,
 113   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 114   [ AS_IF([test "x$with_windows2000" = "xyes"],
 115       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 116   ]
 117 )
 118
 119 AC_ARG_WITH([systemdsystemunitdir],
 120      [AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files])],,
 121      [with_systemdsystemunitdir=auto])
 122 AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"], [
 123      def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
 124
 125      AS_IF([test "x$def_systemdsystemunitdir" = "x"],
 126    [AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
 127     [AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])])
 128     with_systemdsystemunitdir=no],
 129    [with_systemdsystemunitdir="$def_systemdsystemunitdir"])])
 130 AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
 131       [AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])])
 132 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$with_systemdsystemunitdir" != "xno"])
 133
 134 AM_CONDITIONAL(LINUX, test "$linux" = true)
 135 AM_CONDITIONAL(BSD, test "$bsd" = true)
 136 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 137 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 138 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 139 AM_CONDITIONAL(UML, test "$uml" = true)
 140 AM_CONDITIONAL(VDE, test "$vde" = true)
 141 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 142
 143 AC_CACHE_SAVE
 144
 145 if test -d /sw/include ; then
 146   CPPFLAGS="$CPPFLAGS -I/sw/include"
 147 fi
 148 if test -d /sw/lib ; then
 149   LIBS="$LIBS -L/sw/lib"
 150 fi
 151
 152 dnl Compiler hardening flags
 153 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 154
 155 AX_CFLAGS_WARN_ALL(CFLAGS)
 156
 157 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 158 AS_IF([test "x$enable_hardening" != "xno"],
 159   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 160    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 161    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 162    case $host_os in
 163      *mingw*)
 164        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 165        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 166        ;;
 167      *)
 168        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 169        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 170        ;;
 171    esac
 172    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 173    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 174   ]
 175 );
 176
 177 dnl Checks for libraries.
 178
 179 dnl Checks for header files.
 180 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 181
 182 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h arpa/nameser.h dirent.h getopt.h])
 183 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 184   [], [], [#include "$srcdir/src/have.h"]
 185 )
 186 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 187   [], [], [#include "$srcdir/src/have.h"]
 188 )
 189 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 190   [], [], [#include "$srcdir/src/have.h"]
 191 )
 192
 193 dnl Checks for typedefs, structures, and compiler characteristics.
 194 AC_TYPE_PID_T
 195
 196 tinc_ATTRIBUTE(__malloc__)
 197
 198 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 199   [#include "$srcdir/src/have.h"]
 200 )
 201
 202 dnl Checks for library functions.
 203 AC_TYPE_SIGNAL
 204 AC_CHECK_FUNCS([asprintf daemon fchmod flock fork gettimeofday mlockall pselect putenv strsignal system unsetenv usleep vsyslog devname fdevname],
 205   [], [], [#include "$srcdir/src/have.h"]
 206 )
 207
 208 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 209 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 210
 211 dnl Support for SunOS
 212
 213 AC_CHECK_FUNC(socket, [], [
 214   AC_CHECK_LIB(socket, connect)
 215 ])
 216 AC_CHECK_FUNC(gethostbyname, [], [
 217   AC_CHECK_LIB(nsl, gethostbyname)
 218 ])
 219
 220 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 221   [], [], [#include "$srcdir/src/have.h"]
 222 )
 223
 224 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 225   #include <netinet/in.h>
 226   #include <resolv.h>
 227 ])
 228
 229 AC_CACHE_SAVE
 230
 231 dnl These are defined in files in m4/
 232
 233 tinc_ZLIB
 234 tinc_LZO
 235 tinc_OPENSSL
 236
 237 dnl Check if support for jumbograms is requested
 238 AC_ARG_ENABLE(jumbograms,
 239   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 240   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 241       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 242   ]
 243 )
 244
 245 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile distro/Makefile])
 246
 247 AC_OUTPUT