test/maketests.com

   1 $!
   2 $!  MAKETESTS.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates all the various different
  11 $!  "test" programs for the different types of encryption for OpenSSL.
  12 $!  It was written so it would try to determine what "C" compiler to
  13 $!  use or you can specify which "C" compiler to use.
  14 $!
  15 $!  The test "executables" will be placed in a directory called
  16 $!  [.xxx.EXE.TEST] where "xxx" denotes ALPHA, IA64, or VAX, depending
  17 $!  on your machine architecture.
  18 $!
  19 $!  Specify DEBUG or NODEBUG P1 to compile with or without debugger
  20 $!  information.
  21 $!
  22 $!  Specify which compiler at P2 to try to compile under.
  23 $!
  24 $!         VAXC  For VAX C.
  25 $!         DECC  For DEC C.
  26 $!         GNUC  For GNU C.
  27 $!
  28 $!  If you don't specify a compiler, it will try to determine which
  29 $!  "C" compiler to use.
  30 $!
  31 $!  P3, if defined, sets a TCP/IP library to use, through one of the following
  32 $!  keywords:
  33 $!
  34 $!      UCX             for UCX
  35 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  36 $!
  37 $!  P4, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  38 $!
  39 $!
  40 $!  P5, if defined, specifies the C pointer size.  Ignored on VAX.
  41 $!      Supported values are:
  42 $!
  43 $!      ""      Compile with default (/NOPOINTER_SIZE)
  44 $!      32      Compile with /POINTER_SIZE=32 (SHORT)
  45 $!      64      Compile with /POINTER_SIZE=64[=ARGV] (LONG[=ARGV])
  46 $!               (Automatically select ARGV if compiler supports it.)
  47 $!      64=      Compile with /POINTER_SIZE=64 (LONG).
  48 $!      64=ARGV  Compile with /POINTER_SIZE=64=ARGV (LONG=ARGV).
  49 $!
  50 $!  P6, if defined, specifies a directory where ZLIB files (zlib.h,
  51 $!  libz.olb) may be found.  Optionally, a non-default object library
  52 $!  name may be included ("dev:[dir]libz_64.olb", for example).
  53 $!
  54 $!
  55 $! Announce/identify.
  56 $!
  57 $ proc = f$environment( "procedure")
  58 $ write sys$output "@@@ "+ -
  59    f$parse( proc, , , "name")+ f$parse( proc, , , "type")
  60 $!
  61 $! Define A TCP/IP Library That We Will Need To Link To.
  62 $! (That is, If We Need To Link To One.)
  63 $!
  64 $ TCPIP_LIB = ""
  65 $ ZLIB_LIB = ""
  66 $!
  67 $! Check Which Architecture We Are Using.
  68 $!
  69 $ if (f$getsyi( "cpu") .lt. 128)
  70 $ then
  71 $    ARCH = "VAX"
  72 $ else
  73 $    ARCH = f$edit( f$getsyi( "ARCH_NAME"), "UPCASE")
  74 $    if (ARCH .eqs. "") then ARCH = "UNK"
  75 $ endif
  76 $!
  77 $ ARCHD = ARCH
  78 $ LIB32 = "32"
  79 $ OPT_FILE = ""
  80 $ POINTER_SIZE = ""
  81 $!
  82 $! Check To Make Sure We Have Valid Command Line Parameters.
  83 $!
  84 $ GOSUB CHECK_OPTIONS
  85 $!
  86 $! Define The OBJ and EXE Directories.
  87 $!
  88 $ OBJ_DIR := SYS$DISK:[-.'ARCHD'.OBJ.TEST]
  89 $ EXE_DIR := SYS$DISK:[-.'ARCHD'.EXE.TEST]
  90 $!
  91 $! Specify the destination directory in any /MAP option.
  92 $!
  93 $ if (LINKMAP .eqs. "MAP")
  94 $ then
  95 $   LINKMAP = LINKMAP+ "=''EXE_DIR'"
  96 $ endif
  97 $!
  98 $! Add the location prefix to the linker options file name.
  99 $!
 100 $ if (OPT_FILE .nes. "")
 101 $ then
 102 $   OPT_FILE = EXE_DIR+ OPT_FILE
 103 $ endif
 104 $!
 105 $! Initialise logical names and such
 106 $!
 107 $ GOSUB INITIALISE
 108 $!
 109 $! Tell The User What Kind of Machine We Run On.
 110 $!
 111 $ WRITE SYS$OUTPUT "Host system architecture: ''ARCHD'"
 112 $!
 113 $! Define The CRYPTO-LIB We Are To Use.
 114 $!
 115 $ CRYPTO_LIB := SYS$DISK:[-.'ARCHD'.EXE.CRYPTO]SSL_LIBCRYPTO'LIB32'.OLB
 116 $!
 117 $! Define The SSL We Are To Use.
 118 $!
 119 $ SSL_LIB := SYS$DISK:[-.'ARCHD'.EXE.SSL]SSL_LIBSSL'LIB32'.OLB
 120 $!
 121 $! Create the OBJ and EXE Directories, if needed.
 122 $!
 123 $ IF (F$PARSE(OBJ_DIR).EQS."") THEN -
 124    CREATE /DIRECTORY 'OBJ_DIR'
 125 $ IF (F$PARSE(EXE_DIR).EQS."") THEN -
 126    CREATE /DIRECTORY 'EXE_DIR'
 127 $!
 128 $! Check To See If We Have The Proper Libraries.
 129 $!
 130 $ GOSUB LIB_CHECK
 131 $!
 132 $! Check To See If We Have A Linker Option File.
 133 $!
 134 $ GOSUB CHECK_OPT_FILE
 135 $!
 136 $! Define The TEST Files.
 137 $! NOTE: Some might think this list ugly.  However, it's made this way to
 138 $! reflect the EXE variable in Makefile as closely as possible,
 139 $! thereby making it fairly easy to verify that the lists are the same.
 140 $!
 141 $ TEST_FILES = "BNTEST,ECTEST,ECDSATEST,ECDHTEST,IDEATEST,"+ -
 142                "MD2TEST,MD4TEST,MD5TEST,HMACTEST,WP_TEST,"+ -
 143                "RC2TEST,RC4TEST,RC5TEST,"+ -
 144                "DESTEST,SHATEST,SHA1TEST,SHA256T,SHA512T,"+ -
 145                "MDC2TEST,RMDTEST,"+ -
 146                "RANDTEST,DHTEST,ENGINETEST,"+ -
 147                "BFTEST,CASTTEST,SSLTEST,EXPTEST,DSATEST,RSA_TEST,"+ -
 148                "EVP_TEST,IGETEST,JPAKETEST,SRPTEST,"+ -
 149                "ASN1TEST"
 150 $! Should we add MTTEST,PQ_TEST,LH_TEST,DIVTEST,TABTEST as well?
 151 $!
 152 $! Additional directory information.
 153 $ T_D_BNTEST     := [-.crypto.bn]
 154 $ T_D_ECTEST     := [-.crypto.ec]
 155 $ T_D_ECDSATEST  := [-.crypto.ecdsa]
 156 $ T_D_ECDHTEST   := [-.crypto.ecdh]
 157 $ T_D_IDEATEST   := [-.crypto.idea]
 158 $ T_D_MD2TEST    := [-.crypto.md2]
 159 $ T_D_MD4TEST    := [-.crypto.md4]
 160 $ T_D_MD5TEST    := [-.crypto.md5]
 161 $ T_D_HMACTEST   := [-.crypto.hmac]
 162 $ T_D_WP_TEST    := [-.crypto.whrlpool]
 163 $ T_D_RC2TEST    := [-.crypto.rc2]
 164 $ T_D_RC4TEST    := [-.crypto.rc4]
 165 $ T_D_RC5TEST    := [-.crypto.rc5]
 166 $ T_D_DESTEST    := [-.crypto.des]
 167 $ T_D_SHATEST    := [-.crypto.sha]
 168 $ T_D_SHA1TEST   := [-.crypto.sha]
 169 $ T_D_SHA256T    := [-.crypto.sha]
 170 $ T_D_SHA512T    := [-.crypto.sha]
 171 $ T_D_MDC2TEST   := [-.crypto.mdc2]
 172 $ T_D_RMDTEST    := [-.crypto.ripemd]
 173 $ T_D_RANDTEST   := [-.crypto.rand]
 174 $ T_D_DHTEST     := [-.crypto.dh]
 175 $ T_D_ENGINETEST := [-.crypto.engine]
 176 $ T_D_BFTEST     := [-.crypto.bf]
 177 $ T_D_CASTTEST   := [-.crypto.cast]
 178 $ T_D_SSLTEST    := [-.ssl]
 179 $ T_D_EXPTEST    := [-.crypto.bn]
 180 $ T_D_DSATEST    := [-.crypto.dsa]
 181 $ T_D_RSA_TEST   := [-.crypto.rsa]
 182 $ T_D_EVP_TEST   := [-.crypto.evp]
 183 $ T_D_IGETEST    := [-.test]
 184 $ T_D_JPAKETEST  := [-.crypto.jpake]
 185 $ T_D_SRPTEST    := [-.crypto.srp]
 186 $ T_D_ASN1TEST   := [-.test]
 187 $!
 188 $ TCPIP_PROGRAMS = ",,"
 189 $ IF COMPILER .EQS. "VAXC" THEN -
 190      TCPIP_PROGRAMS = ",SSLTEST,"
 191 $!
 192 $! Define A File Counter And Set It To "0".
 193 $!
 194 $ FILE_COUNTER = 0
 195 $!
 196 $! Top Of The File Loop.
 197 $!
 198 $ NEXT_FILE:
 199 $!
 200 $! O.K, Extract The File Name From The File List.
 201 $!
 202 $ FILE_NAME = F$ELEMENT(FILE_COUNTER,",",TEST_FILES)
 203 $!
 204 $! Check To See If We Are At The End Of The File List.
 205 $!
 206 $ IF (FILE_NAME.EQS.",") THEN GOTO FILE_DONE
 207 $!
 208 $! Increment The Counter.
 209 $!
 210 $ FILE_COUNTER = FILE_COUNTER + 1
 211 $!
 212 $! Create The Source File Name.
 213 $!
 214 $ SOURCE_FILE = "SYS$DISK:" + T_D_'FILE_NAME' + FILE_NAME + ".C"
 215 $!
 216 $! Create The Object File Name.
 217 $!
 218 $ OBJECT_FILE = OBJ_DIR + FILE_NAME + ".OBJ"
 219 $!
 220 $! Create The Executable File Name.
 221 $!
 222 $ EXE_FILE = EXE_DIR + FILE_NAME + ".EXE"
 223 $ ON WARNING THEN GOTO NEXT_FILE
 224 $!
 225 $! Check To See If The File We Want To Compile Actually Exists.
 226 $!
 227 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 228 $ THEN
 229 $!
 230 $!  Tell The User That The File Dosen't Exist.
 231 $!
 232 $   WRITE SYS$OUTPUT ""
 233 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Dosen't Exist."
 234 $   WRITE SYS$OUTPUT ""
 235 $!
 236 $!  Exit The Build.
 237 $!
 238 $   GOTO EXIT
 239 $ ENDIF
 240 $!
 241 $! Tell The User What We Are Building.
 242 $!
 243 $ WRITE SYS$OUTPUT "Building The ",FILE_NAME," Test Program."
 244 $!
 245 $! Compile The File.
 246 $!
 247 $ ON ERROR THEN GOTO NEXT_FILE
 248 $ CC /OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 249 $ ON WARNING THEN GOTO NEXT_FILE
 250 $!
 251 $! Check If What We Are About To Compile Works Without A TCP/IP Library.
 252 $!
 253 $ IF ((TCPIP_LIB.EQS."").AND.((TCPIP_PROGRAMS-FILE_NAME).NES.TCPIP_PROGRAMS))
 254 $ THEN
 255 $!
 256 $!  Inform The User That A TCP/IP Library Is Needed To Compile This Program.
 257 $!
 258 $   WRITE SYS$OUTPUT -
 259           FILE_NAME," Needs A TCP/IP Library.  Can't Link.  Skipping..."
 260 $   GOTO NEXT_FILE
 261 $!
 262 $! End The TCP/IP Library Check.
 263 $!
 264 $ ENDIF
 265 $!
 266 $! Link The Program, Check To See If We Need To Link With RSAREF Or Not.
 267 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 268 $!
 269 $!  Don't Link With The RSAREF Routines And TCP/IP Library.
 270 $!
 271 $ LINK /'DEBUGGER' /'LINKMAP' /'TRACEBACK' /EXECTABLE = 'EXE_FILE' -
 272    'OBJECT_FILE', -
 273    'SSL_LIB' /LIBRARY, -
 274    'CRYPTO_LIB' /LIBRARY -
 275    'TCPIP_LIB' -
 276    'ZLIB_LIB' -
 277    ,'OPT_FILE' /OPTIONS
 278 $!
 279 $! Go Back And Do It Again.
 280 $!
 281 $ GOTO NEXT_FILE
 282 $!
 283 $! All Done With This Library Part.
 284 $!
 285 $ FILE_DONE:
 286 $!
 287 $! All Done, Time To Exit.
 288 $!
 289 $ EXIT:
 290 $ GOSUB CLEANUP
 291 $ EXIT
 292 $!
 293 $! Check For The Link Option FIle.
 294 $!
 295 $ CHECK_OPT_FILE:
 296 $!
 297 $! Check To See If We Need To Make A VAX C Option File.
 298 $!
 299 $ IF (COMPILER.EQS."VAXC")
 300 $ THEN
 301 $!
 302 $!  Check To See If We Already Have A VAX C Linker Option File.
 303 $!
 304 $   IF (F$SEARCH(OPT_FILE).EQS."")
 305 $   THEN
 306 $!
 307 $!    We Need A VAX C Linker Option File.
 308 $!
 309 $     CREATE 'OPT_FILE'
 310 $DECK
 311 !
 312 ! Default System Options File To Link Against
 313 ! The Sharable VAX C Runtime Library.
 314 !
 315 SYS$SHARE:VAXCRTL.EXE /SHAREABLE
 316 $EOD
 317 $!
 318 $!  End The Option File Check.
 319 $!
 320 $   ENDIF
 321 $!
 322 $! End The VAXC Check.
 323 $!
 324 $ ENDIF
 325 $!
 326 $! Check To See If We Need A GNU C Option File.
 327 $!
 328 $ IF (COMPILER.EQS."GNUC")
 329 $ THEN
 330 $!
 331 $!  Check To See If We Already Have A GNU C Linker Option File.
 332 $!
 333 $   IF (F$SEARCH(OPT_FILE).EQS."")
 334 $   THEN
 335 $!
 336 $!    We Need A GNU C Linker Option File.
 337 $!
 338 $     CREATE 'OPT_FILE'
 339 $DECK
 340 !
 341 ! Default System Options File To Link Against
 342 ! The Sharable C Runtime Library.
 343 !
 344 GNU_CC:[000000]GCCLIB.OLB /LIBRARY
 345 SYS$SHARE:VAXCRTL.EXE /SHAREABLE
 346 $EOD
 347 $!
 348 $!  End The Option File Check.
 349 $!
 350 $   ENDIF
 351 $!
 352 $! End The GNU C Check.
 353 $!
 354 $ ENDIF
 355 $!
 356 $! Check To See If We Need A DEC C Option File.
 357 $!
 358 $ IF (COMPILER.EQS."DECC")
 359 $ THEN
 360 $!
 361 $!  Check To See If We Already Have A DEC C Linker Option File.
 362 $!
 363 $   IF (F$SEARCH(OPT_FILE).EQS."")
 364 $   THEN
 365 $!
 366 $!    Figure Out If We Need A non-VAX Or A VAX Linker Option File.
 367 $!
 368 $     IF (ARCH.EQS."VAX")
 369 $     THEN
 370 $!
 371 $!      We Need A DEC C Linker Option File For VAX.
 372 $!
 373 $       CREATE 'OPT_FILE'
 374 $DECK
 375 !
 376 ! Default System Options File To Link Against
 377 ! The Sharable DEC C Runtime Library.
 378 !
 379 SYS$SHARE:DECC$SHR.EXE /SHAREABLE
 380 $EOD
 381 $!
 382 $!    Else...
 383 $!
 384 $     ELSE
 385 $!
 386 $!      Create The non-VAX Linker Option File.
 387 $!
 388 $       CREATE 'OPT_FILE'
 389 $DECK
 390 !
 391 ! Default System Options File For non-VAX To Link Against
 392 ! The Sharable C Runtime Library.
 393 !
 394 SYS$SHARE:CMA$OPEN_LIB_SHR.EXE /SHAREABLE
 395 SYS$SHARE:CMA$OPEN_RTL.EXE /SHAREABLE
 396 $EOD
 397 $!
 398 $!    End The DEC C Option File Check.
 399 $!
 400 $     ENDIF
 401 $!
 402 $!  End The Option File Search.
 403 $!
 404 $   ENDIF
 405 $!
 406 $! End The DEC C Check.
 407 $!
 408 $ ENDIF
 409 $!
 410 $!  Tell The User What Linker Option File We Are Using.
 411 $!
 412 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 413 $!
 414 $! Time To RETURN.
 415 $!
 416 $ RETURN
 417 $!
 418 $! Check To See If We Have The Appropiate Libraries.
 419 $!
 420 $ LIB_CHECK:
 421 $!
 422 $! Look For The Library LIBCRYPTO.OLB.
 423 $!
 424 $ IF (F$SEARCH(CRYPTO_LIB).EQS."")
 425 $ THEN
 426 $!
 427 $!  Tell The User We Can't Find The LIBCRYPTO.OLB Library.
 428 $!
 429 $   WRITE SYS$OUTPUT ""
 430 $   WRITE SYS$OUTPUT "Can't Find The Library ",CRYPTO_LIB,"."
 431 $   WRITE SYS$OUTPUT "We Can't Link Without It."
 432 $   WRITE SYS$OUTPUT ""
 433 $!
 434 $!  Since We Can't Link Without It, Exit.
 435 $!
 436 $   EXIT
 437 $!
 438 $! End The Crypto Library Check.
 439 $!
 440 $ ENDIF
 441 $!
 442 $! Look For The Library LIBSSL.OLB.
 443 $!
 444 $ IF (F$SEARCH(SSL_LIB).EQS."")
 445 $ THEN
 446 $!
 447 $!  Tell The User We Can't Find The LIBSSL.OLB Library.
 448 $!
 449 $   WRITE SYS$OUTPUT ""
 450 $   WRITE SYS$OUTPUT "Can't Find The Library ",SSL_LIB,"."
 451 $   WRITE SYS$OUTPUT "Some Of The Test Programs Need To Link To It."
 452 $   WRITE SYS$OUTPUT ""
 453 $!
 454 $!  Since We Can't Link Without It, Exit.
 455 $!
 456 $   EXIT
 457 $!
 458 $! End The SSL Library Check.
 459 $!
 460 $ ENDIF
 461 $!
 462 $! Time To Return.
 463 $!
 464 $ RETURN
 465 $!
 466 $! Check The User's Options.
 467 $!
 468 $ CHECK_OPTIONS:
 469 $!
 470 $! Set basic C compiler /INCLUDE directories.
 471 $!
 472 $ CC_INCLUDES = "SYS$DISK:[-],SYS$DISK:[-.CRYPTO]"
 473 $!
 474 $! Check To See If P1 Is Blank.
 475 $!
 476 $ IF (P1.EQS."NODEBUG")
 477 $ THEN
 478 $!
 479 $!  P1 Is NODEBUG, So Compile Without Debugger Information.
 480 $!
 481 $   DEBUGGER  = "NODEBUG"
 482 $   LINKMAP = "NOMAP"
 483 $   TRACEBACK = "NOTRACEBACK"
 484 $   GCC_OPTIMIZE = "OPTIMIZE"
 485 $   CC_OPTIMIZE = "OPTIMIZE"
 486 $   WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 487 $   WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 488 $!
 489 $! Else...
 490 $!
 491 $ ELSE
 492 $!
 493 $!  Check To See If We Are To Compile With Debugger Information.
 494 $!
 495 $   IF (P1.EQS."DEBUG")
 496 $   THEN
 497 $!
 498 $!    Compile With Debugger Information.
 499 $!
 500 $     DEBUGGER  = "DEBUG"
 501 $     LINKMAP = "MAP"
 502 $     TRACEBACK = "TRACEBACK"
 503 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 504 $     CC_OPTIMIZE = "NOOPTIMIZE"
 505 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 506 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 507 $!
 508 $!  Else...
 509 $!
 510 $   ELSE
 511 $!
 512 $!    Tell The User Entered An Invalid Option.
 513 $!
 514 $     WRITE SYS$OUTPUT ""
 515 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 516 $     WRITE SYS$OUTPUT ""
 517 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
 518 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
 519 $     WRITE SYS$OUTPUT ""
 520 $!
 521 $!    Time To EXIT.
 522 $!
 523 $     EXIT
 524 $!
 525 $!  End The Valid Argument Check.
 526 $!
 527 $   ENDIF
 528 $!
 529 $! End The P1 Check.
 530 $!
 531 $ ENDIF
 532 $!
 533 $! Check P5 (POINTER_SIZE).
 534 $!
 535 $ IF (P5 .NES. "") .AND. (ARCH .NES. "VAX")
 536 $ THEN
 537 $!
 538 $   IF (P5 .EQS. "32")
 539 $   THEN
 540 $     POINTER_SIZE = "/POINTER_SIZE=32"
 541 $   ELSE
 542 $     POINTER_SIZE = F$EDIT( P5, "COLLAPSE, UPCASE")
 543 $     IF ((POINTER_SIZE .EQS. "64") .OR. -
 544        (POINTER_SIZE .EQS. "64=") .OR. -
 545        (POINTER_SIZE .EQS. "64=ARGV"))
 546 $     THEN
 547 $       ARCHD = ARCH+ "_64"
 548 $       LIB32 = ""
 549 $       IF (F$EXTRACT( 2, 1, POINTER_SIZE) .EQS. "=")
 550 $       THEN
 551 $!         Explicit user choice: "64" or "64=ARGV".
 552 $          IF (POINTER_SIZE .EQS. "64=") THEN POINTER_SIZE = "64"
 553 $       ELSE
 554 $       SET NOON
 555 $         DEFINE /USER_MODE SYS$OUTPUT NL:
 556 $         DEFINE /USER_MODE SYS$ERROR NL:
 557 $         CC /NOLIST /NOOBJECT /POINTER_SIZE=64=ARGV NL:
 558 $       IF ($STATUS .AND. %X0FFF0000) .EQ. %X00030000
 559 $       THEN
 560 $         ! If we got here, it means DCL complained like this:
 561 $         ! %DCL-W-NOVALU, value not allowed - remove value specification
 562 $         !  \64=\
 563 $         !
 564 $         ! If the compiler was run, logicals defined in /USER would
 565 $         ! have been deassigned automatically.  However, when DCL
 566 $         ! complains, they aren't, so we do it here (it might be
 567 $         ! unnecessary, but just in case there will be another error
 568 $         ! message further on that we don't want to miss)
 569 $           DEASSIGN /USER_MODE SYS$ERROR
 570 $           DEASSIGN /USER_MODE SYS$OUTPUT
 571 $       ELSE
 572 $         POINTER_SIZE = POINTER_SIZE + "=ARGV"
 573 $       ENDIF
 574 $       SET ON
 575 $       ENDIF
 576 $       POINTER_SIZE = "/POINTER_SIZE=''POINTER_SIZE'"
 577 $     ELSE
 578 $!
 579 $!      Tell The User Entered An Invalid Option.
 580 $!
 581 $       WRITE SYS$OUTPUT ""
 582 $       WRITE SYS$OUTPUT "The Option ", P5, -
 583          " Is Invalid.  The Valid Options Are:"
 584 $       WRITE SYS$OUTPUT ""
 585 $       WRITE SYS$OUTPUT -
 586          "    """"  :  Compile with default (short) pointers."
 587 $       WRITE SYS$OUTPUT -
 588          "    32  :  Compile with 32-bit (short) pointers."
 589 $       WRITE SYS$OUTPUT -
 590          "    64       :  Compile with 64-bit (long) pointers (auto ARGV)."
 591 $       WRITE SYS$OUTPUT -
 592          "    64=      :  Compile with 64-bit (long) pointers (no ARGV)."
 593 $       WRITE SYS$OUTPUT -
 594          "    64=ARGV  :  Compile with 64-bit (long) pointers (ARGV)."
 595 $       WRITE SYS$OUTPUT ""
 596 $!
 597 $!      Time To EXIT.
 598 $!
 599 $       EXIT
 600 $!
 601 $     ENDIF
 602 $!
 603 $   ENDIF
 604 $!
 605 $! End The P5 (POINTER_SIZE) Check.
 606 $!
 607 $ ENDIF
 608 $!
 609 $! Check To See If P2 Is Blank.
 610 $!
 611 $ IF (P2.EQS."")
 612 $ THEN
 613 $!
 614 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 615 $!  Find Out Which One To Use.
 616 $!
 617 $!  Check To See If We Have GNU C.
 618 $!
 619 $   IF (F$TRNLNM("GNU_CC").NES."")
 620 $   THEN
 621 $!
 622 $!    Looks Like GNUC, Set To Use GNUC.
 623 $!
 624 $     P2 = "GNUC"
 625 $!
 626 $!  End The GNU C Compiler Check.
 627 $!
 628 $   ELSE
 629 $!
 630 $!  Check To See If We Have VAXC Or DECC.
 631 $!
 632 $     IF (ARCH.NES."VAX").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 633 $     THEN
 634 $!
 635 $!      Looks Like DECC, Set To Use DECC.
 636 $!
 637 $       P2 = "DECC"
 638 $!
 639 $!      Else...
 640 $!
 641 $     ELSE
 642 $!
 643 $!      Looks Like VAXC, Set To Use VAXC.
 644 $!
 645 $       P2 = "VAXC"
 646 $!
 647 $!    End The VAXC Compiler Check.
 648 $!
 649 $     ENDIF
 650 $!
 651 $!  End The DECC & VAXC Compiler Check.
 652 $!
 653 $   ENDIF
 654 $!
 655 $!  End The Compiler Check.
 656 $!
 657 $ ENDIF
 658 $!
 659 $! Check To See If We Have A Option For P3.
 660 $!
 661 $ IF (P3.EQS."")
 662 $ THEN
 663 $!
 664 $!  Find out what socket library we have available
 665 $!
 666 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 667 $   THEN
 668 $!
 669 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 670 $!
 671 $     P3 = "SOCKETSHR"
 672 $!
 673 $!    Tell the user
 674 $!
 675 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 676 $!
 677 $!    Else, let's look for something else
 678 $!
 679 $   ELSE
 680 $!
 681 $!    Like UCX (the reason to do this before Multinet is that the UCX
 682 $!    emulation is easier to use...)
 683 $!
 684 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 685          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 686          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 687 $     THEN
 688 $!
 689 $!      Last resort: a UCX or UCX-compatible library
 690 $!
 691 $       P3 = "UCX"
 692 $!
 693 $!      Tell the user
 694 $!
 695 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 696 $!
 697 $!      That was all...
 698 $!
 699 $     ENDIF
 700 $   ENDIF
 701 $ ENDIF
 702 $!
 703 $! Set Up Initial CC Definitions, Possibly With User Ones
 704 $!
 705 $ CCDEFS = "TCPIP_TYPE_''P3'"
 706 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 707 $ CCEXTRAFLAGS = ""
 708 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 709 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 710 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 711         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 712 $!
 713 $! Check To See If We Have A ZLIB Option.
 714 $!
 715 $ ZLIB = P6
 716 $ IF (ZLIB .NES. "")
 717 $ THEN
 718 $!
 719 $!  Check for expected ZLIB files.
 720 $!
 721 $   err = 0
 722 $   file1 = f$parse( "zlib.h", ZLIB, , , "SYNTAX_ONLY")
 723 $   if (f$search( file1) .eqs. "")
 724 $   then
 725 $     WRITE SYS$OUTPUT ""
 726 $     WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
 727 $     WRITE SYS$OUTPUT "    Can't find header: ''file1'"
 728 $     err = 1
 729 $   endif
 730 $   file1 = f$parse( "A.;", ZLIB)- "A.;"
 731 $!
 732 $   file2 = f$parse( ZLIB, "libz.olb", , , "SYNTAX_ONLY")
 733 $   if (f$search( file2) .eqs. "")
 734 $   then
 735 $     if (err .eq. 0)
 736 $     then
 737 $       WRITE SYS$OUTPUT ""
 738 $       WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
 739 $     endif
 740 $     WRITE SYS$OUTPUT "    Can't find library: ''file2'"
 741 $     WRITE SYS$OUTPUT ""
 742 $     err = err+ 2
 743 $   endif
 744 $   if (err .eq. 1)
 745 $   then
 746 $     WRITE SYS$OUTPUT ""
 747 $   endif
 748 $!
 749 $   if (err .ne. 0)
 750 $   then
 751 $     GOTO EXIT
 752 $   endif
 753 $!
 754 $   CCDEFS = """ZLIB=1"", "+ CCDEFS
 755 $   CC_INCLUDES = CC_INCLUDES+ ", "+ file1
 756 $   ZLIB_LIB = ", ''file2' /library"
 757 $!
 758 $!  Print info
 759 $!
 760 $   WRITE SYS$OUTPUT "ZLIB library spec: ", file2
 761 $!
 762 $! End The P8 Check.
 763 $!
 764 $ ENDIF
 765 $!
 766 $!  Check To See If The User Entered A Valid Parameter.
 767 $!
 768 $ IF (P2.EQS."VAXC").OR.(P2.EQS."DECC").OR.(P2.EQS."GNUC")
 769 $ THEN
 770 $!
 771 $!  Check To See If The User Wanted DECC.
 772 $!
 773 $   IF (P2.EQS."DECC")
 774 $   THEN
 775 $!
 776 $!    Looks Like DECC, Set To Use DECC.
 777 $!
 778 $     COMPILER = "DECC"
 779 $!
 780 $!    Tell The User We Are Using DECC.
 781 $!
 782 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 783 $!
 784 $!    Use DECC...
 785 $!
 786 $     CC = "CC"
 787 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
 788          THEN CC = "CC /DECC"
 789 $     CC = CC + "/''CC_OPTIMIZE' /''DEBUGGER' /STANDARD=RELAXED"+ -
 790        "''POINTER_SIZE' /NOLIST /PREFIX=ALL" + -
 791        "/INCLUDE=(''CC_INCLUDES')" + CCEXTRAFLAGS
 792 $!
 793 $!    Define The Linker Options File Name.
 794 $!
 795 $     OPT_FILE = "VAX_DECC_OPTIONS.OPT"
 796 $!
 797 $!  End DECC Check.
 798 $!
 799 $   ENDIF
 800 $!
 801 $!  Check To See If We Are To Use VAXC.
 802 $!
 803 $   IF (P2.EQS."VAXC")
 804 $   THEN
 805 $!
 806 $!    Looks Like VAXC, Set To Use VAXC.
 807 $!
 808 $     COMPILER = "VAXC"
 809 $!
 810 $!    Tell The User We Are Using VAX C.
 811 $!
 812 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 813 $!
 814 $!    Compile Using VAXC.
 815 $!
 816 $     CC = "CC"
 817 $     IF ARCH.NES."VAX"
 818 $     THEN
 819 $       WRITE SYS$OUTPUT "There is no VAX C on ''ARCH'!"
 820 $       EXIT
 821 $     ENDIF
 822 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC /VAXC"
 823 $     CC = CC + "/''CC_OPTIMIZE' /''DEBUGGER' /NOLIST" + -
 824            "/INCLUDE=(''CC_INCLUDES')" + CCEXTRAFLAGS
 825 $     CCDEFS = CCDEFS + ",""VAXC"""
 826 $!
 827 $!    Define <sys> As SYS$COMMON:[SYSLIB]
 828 $!
 829 $     DEFINE /NOLOG SYS SYS$COMMON:[SYSLIB]
 830 $!
 831 $!    Define The Linker Options File Name.
 832 $!
 833 $     OPT_FILE = "VAX_VAXC_OPTIONS.OPT"
 834 $!
 835 $!  End VAXC Check
 836 $!
 837 $   ENDIF
 838 $!
 839 $!  Check To See If We Are To Use GNU C.
 840 $!
 841 $   IF (P2.EQS."GNUC")
 842 $   THEN
 843 $!
 844 $!    Looks Like GNUC, Set To Use GNUC.
 845 $!
 846 $     COMPILER = "GNUC"
 847 $!
 848 $!    Tell The User We Are Using GNUC.
 849 $!
 850 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 851 $!
 852 $!    Use GNU C...
 853 $!
 854 $     CC = "GCC /NOCASE_HACK /''GCC_OPTIMIZE' /''DEBUGGER' /NOLIST" + -
 855            "/INCLUDE=(''CC_INCLUDES')" + CCEXTRAFLAGS
 856 $!
 857 $!    Define The Linker Options File Name.
 858 $!
 859 $     OPT_FILE = "VAX_GNUC_OPTIONS.OPT"
 860 $!
 861 $!  End The GNU C Check.
 862 $!
 863 $   ENDIF
 864 $!
 865 $!  Set up default defines
 866 $!
 867 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
 868 $!
 869 $!  Finish up the definition of CC.
 870 $!
 871 $   IF COMPILER .EQS. "DECC"
 872 $   THEN
 873 $     IF CCDISABLEWARNINGS .EQS. ""
 874 $     THEN
 875 $       CC4DISABLEWARNINGS = "DOLLARID"
 876 $     ELSE
 877 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
 878 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
 879 $     ENDIF
 880 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
 881 $   ELSE
 882 $     CCDISABLEWARNINGS = ""
 883 $     CC4DISABLEWARNINGS = ""
 884 $   ENDIF
 885 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
 886 $!
 887 $!  Show user the result
 888 $!
 889 $   WRITE /SYMBOL SYS$OUTPUT "Main Compiling Command: ", CC
 890 $!
 891 $!  Else The User Entered An Invalid Argument.
 892 $!
 893 $ ELSE
 894 $!
 895 $!  Tell The User We Don't Know What They Want.
 896 $!
 897 $   WRITE SYS$OUTPUT ""
 898 $   WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 899 $   WRITE SYS$OUTPUT ""
 900 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 901 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 902 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 903 $   WRITE SYS$OUTPUT ""
 904 $!
 905 $!  Time To EXIT.
 906 $!
 907 $   EXIT
 908 $ ENDIF
 909 $!
 910 $! Time to check the contents, and to make sure we get the correct library.
 911 $!
 912 $ IF P3.EQS."SOCKETSHR" .OR. P3.EQS."MULTINET" .OR. P3.EQS."UCX" -
 913      .OR. P3.EQS."TCPIP" .OR. P3.EQS."NONE"
 914 $ THEN
 915 $!
 916 $!  Check to see if SOCKETSHR was chosen
 917 $!
 918 $   IF P3.EQS."SOCKETSHR"
 919 $   THEN
 920 $!
 921 $!    Set the library to use SOCKETSHR
 922 $!
 923 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT /OPTIONS"
 924 $!
 925 $!    Done with SOCKETSHR
 926 $!
 927 $   ENDIF
 928 $!
 929 $!  Check to see if MULTINET was chosen
 930 $!
 931 $   IF P3.EQS."MULTINET"
 932 $   THEN
 933 $!
 934 $!    Set the library to use UCX emulation.
 935 $!
 936 $     P3 = "UCX"
 937 $!
 938 $!    Done with MULTINET
 939 $!
 940 $   ENDIF
 941 $!
 942 $!  Check to see if UCX was chosen
 943 $!
 944 $   IF P3.EQS."UCX"
 945 $   THEN
 946 $!
 947 $!    Set the library to use UCX.
 948 $!
 949 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT /OPTIONS"
 950 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
 951 $     THEN
 952 $       TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT /OPTIONS"
 953 $     ELSE
 954 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
 955           TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT /OPTIONS"
 956 $     ENDIF
 957 $!
 958 $!    Done with UCX
 959 $!
 960 $   ENDIF
 961 $!
 962 $!  Check to see if TCPIP was chosen
 963 $!
 964 $   IF P3.EQS."TCPIP"
 965 $   THEN
 966 $!
 967 $!    Set the library to use TCPIP (post UCX).
 968 $!
 969 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT /OPTIONS"
 970 $!
 971 $!    Done with TCPIP
 972 $!
 973 $   ENDIF
 974 $!
 975 $!  Check to see if NONE was chosen
 976 $!
 977 $   IF P3.EQS."NONE"
 978 $   THEN
 979 $!
 980 $!    Do not use a TCPIP library.
 981 $!
 982 $     TCPIP_LIB = ""
 983 $!
 984 $!    Done with NONE
 985 $!
 986 $   ENDIF
 987 $!
 988 $!  Print info
 989 $!
 990 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB- ","
 991 $!
 992 $!  Else The User Entered An Invalid Argument.
 993 $!
 994 $ ELSE
 995 $!
 996 $!  Tell The User We Don't Know What They Want.
 997 $!
 998 $   WRITE SYS$OUTPUT ""
 999 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1000 $   WRITE SYS$OUTPUT ""
1001 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1002 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1003 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1004 $   WRITE SYS$OUTPUT ""
1005 $!
1006 $!  Time To EXIT.
1007 $!
1008 $   EXIT
1009 $!
1010 $!  Done with TCP/IP libraries
1011 $!
1012 $ ENDIF
1013 $!
1014 $! Special Threads For OpenVMS v7.1 Or Later
1015 $!
1016 $! Written By:  Richard Levitte
1017 $!              richard@levitte.org
1018 $!
1019 $!
1020 $! Check To See If We Have A Option For P4.
1021 $!
1022 $ IF (P4.EQS."")
1023 $ THEN
1024 $!
1025 $!  Get The Version Of VMS We Are Using.
1026 $!
1027 $   ISSEVEN :=
1028 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
1029 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1030 $!
1031 $!  Check To See If The VMS Version Is v7.1 Or Later.
1032 $!
1033 $   IF (TMP.GE.71)
1034 $   THEN
1035 $!
1036 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1037 $!
1038 $     ISSEVEN := ,PTHREAD_USE_D4
1039 $!
1040 $!  End The VMS Version Check.
1041 $!
1042 $   ENDIF
1043 $!
1044 $! End The P4 Check.
1045 $!
1046 $ ENDIF
1047 $!
1048 $!  Time To RETURN...
1049 $!
1050 $ RETURN
1051 $!
1052 $ INITIALISE:
1053 $!
1054 $! Save old value of the logical name OPENSSL
1055 $!
1056 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1057 $!
1058 $! Save directory information
1059 $!
1060 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1061 $ __HERE = F$EDIT(__HERE,"UPCASE")
1062 $ __TOP = __HERE - "TEST]"
1063 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1064 $!
1065 $! Set up the logical name OPENSSL to point at the include directory
1066 $!
1067 $ DEFINE OPENSSL /NOLOG '__INCLUDE'
1068 $!
1069 $! Done
1070 $!
1071 $ RETURN
1072 $!
1073 $ CLEANUP:
1074 $!
1075 $! Restore the logical name OPENSSL if it had a value
1076 $!
1077 $ IF __SAVE_OPENSSL .EQS. ""
1078 $ THEN
1079 $   DEASSIGN OPENSSL
1080 $ ELSE
1081 $   DEFINE /NOLOG OPENSSL '__SAVE_OPENSSL'
1082 $ ENDIF
1083 $!
1084 $! Done
1085 $!
1086 $ RETURN