src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(minetest)
   4
   5 INCLUDE(CheckIncludeFiles)
   6
   7 # Add custom SemiDebug build mode
   8 set(CMAKE_CXX_FLAGS_SEMIDEBUG "-O1 -g -Wall -Wabi" CACHE STRING
   9         "Flags used by the C++ compiler during semidebug builds."
  10         FORCE
  11 )
  12 set(CMAKE_C_FLAGS_SEMIDEBUG "-O1 -g -Wall -pedantic" CACHE STRING
  13         "Flags used by the C compiler during semidebug builds."
  14         FORCE
  15 )
  16 mark_as_advanced(
  17         CMAKE_CXX_FLAGS_SEMIDEBUG
  18         CMAKE_C_FLAGS_SEMIDEBUG
  19 )
  20 set(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING
  21         "Choose the type of build. Options are: None Debug SemiDebug RelWithDebInfo MinSizeRel."
  22         FORCE
  23 )
  24
  25
  26 # Set some random things default to not being visible in the GUI
  27 mark_as_advanced(EXECUTABLE_OUTPUT_PATH LIBRARY_OUTPUT_PATH)
  28
  29
  30 option(ENABLE_CURL "Enable cURL support for fetching media" TRUE)
  31 set(USE_CURL FALSE)
  32
  33 if(ENABLE_CURL)
  34         find_package(CURL)
  35         if (CURL_FOUND)
  36                 message(STATUS "cURL support enabled.")
  37                 set(USE_CURL TRUE)
  38         endif()
  39 else()
  40         mark_as_advanced(CLEAR CURL_LIBRARY CURL_INCLUDE_DIR)
  41 endif()
  42
  43
  44 option(ENABLE_GETTEXT "Use GetText for internationalization" FALSE)
  45 set(USE_GETTEXT FALSE)
  46
  47 if(ENABLE_GETTEXT)
  48         find_package(GettextLib)
  49         if(GETTEXT_FOUND)
  50                 if(WIN32)
  51                         message(STATUS "GetText library: ${GETTEXT_LIBRARY}")
  52                         message(STATUS "GetText DLL: ${GETTEXT_DLL}")
  53                         message(STATUS "GetText iconv DLL: ${GETTEXT_ICONV_DLL}")
  54                 endif()
  55                 set(USE_GETTEXT TRUE)
  56                 message(STATUS "GetText enabled; locales found: ${GETTEXT_AVAILABLE_LOCALES}")
  57         endif(GETTEXT_FOUND)
  58 else()
  59         mark_as_advanced(GETTEXT_ICONV_DLL GETTEXT_INCLUDE_DIR GETTEXT_LIBRARY GETTEXT_MSGFMT)
  60         message(STATUS "GetText disabled.")
  61 endif()
  62
  63
  64 option(ENABLE_SOUND "Enable sound" TRUE)
  65 set(USE_SOUND FALSE)
  66
  67 if(BUILD_CLIENT AND ENABLE_SOUND)
  68         # Sound libraries
  69         find_package(OpenAL)
  70         find_package(Vorbis)
  71         if(NOT OPENAL_FOUND)
  72                 message(STATUS "Sound enabled, but OpenAL not found!")
  73                 mark_as_advanced(CLEAR OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
  74         endif()
  75         if(NOT VORBIS_FOUND)
  76                 message(STATUS "Sound enabled, but Vorbis libraries not found!")
  77                 mark_as_advanced(CLEAR OGG_INCLUDE_DIR VORBIS_INCLUDE_DIR OGG_LIBRARY VORBIS_LIBRARY VORBISFILE_LIBRARY)
  78         endif()
  79         if(OPENAL_FOUND AND VORBIS_FOUND)
  80                 set(USE_SOUND TRUE)
  81                 message(STATUS "Sound enabled.")
  82         else()
  83                 message(FATAL_ERROR "Sound enabled, but cannot be used.\n"
  84                         "To continue, either fill in the required paths or disable sound. (-DENABLE_SOUND=0)")
  85         endif()
  86 endif()
  87
  88 if(USE_SOUND)
  89         set(sound_SRCS sound_openal.cpp)
  90         set(SOUND_INCLUDE_DIRS
  91                 ${OPENAL_INCLUDE_DIR}
  92                 ${VORBIS_INCLUDE_DIR}
  93                 ${OGG_INCLUDE_DIR}
  94                 )
  95         set(SOUND_LIBRARIES
  96                 ${OPENAL_LIBRARY}
  97                 ${VORBIS_LIBRARIES}
  98                 )
  99 endif()
 100
 101
 102 option(ENABLE_GLES "Enable OpenGL ES support" FALSE)
 103 mark_as_advanced(ENABLE_GLES)
 104 if(ENABLE_GLES)
 105         find_package(OpenGLES2)
 106 endif()
 107
 108
 109 option(ENABLE_FREETYPE "Enable FreeType2 (TrueType fonts and basic unicode support)" TRUE)
 110 set(USE_FREETYPE FALSE)
 111
 112 if(ENABLE_FREETYPE)
 113 ##
 114 ## Note: FindFreetype.cmake seems to have been fixed in recent versions of
 115 ## CMake. If issues persist, re-enable this workaround specificially for the
 116 ## failing platforms.
 117 ##
 118 #       if(UNIX)
 119 #               include(FindPkgConfig)
 120 #               if(PKG_CONFIG_FOUND)
 121 #                       pkg_check_modules(FREETYPE QUIET freetype2)
 122 #                       if(FREETYPE_FOUND)
 123 #                               SET(FREETYPE_PKGCONFIG_FOUND TRUE)
 124 #                               SET(FREETYPE_LIBRARY ${FREETYPE_LIBRARIES})
 125 #                               # Because CMake is idiotic
 126 #                               string(REPLACE ";" " " FREETYPE_CFLAGS_STR ${FREETYPE_CFLAGS})
 127 #                               string(REPLACE ";" " " FREETYPE_LDFLAGS_STR ${FREETYPE_LDFLAGS})
 128 #                       endif(FREETYPE_FOUND)
 129 #               endif(PKG_CONFIG_FOUND)
 130 #       endif(UNIX)
 131 #       if(NOT FREETYPE_FOUND)
 132 #               find_package(Freetype)
 133 #       endif()
 134         find_package(Freetype)
 135         if(FREETYPE_FOUND)
 136                 message(STATUS "Freetype enabled.")
 137                 set(USE_FREETYPE TRUE)
 138                 set(CGUITTFONT_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cguittfont")
 139                 set(CGUITTFONT_LIBRARY cguittfont)
 140         endif()
 141 endif(ENABLE_FREETYPE)
 142
 143
 144 find_package(Lua REQUIRED)
 145
 146 find_package(GMP REQUIRED)
 147
 148 option(ENABLE_LEVELDB "Enable LevelDB backend" TRUE)
 149 set(USE_LEVELDB FALSE)
 150
 151 if(ENABLE_LEVELDB)
 152         find_library(LEVELDB_LIBRARY leveldb)
 153         find_path(LEVELDB_INCLUDE_DIR db.h PATH_SUFFIXES leveldb)
 154         if(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 155                 set(USE_LEVELDB TRUE)
 156                 message(STATUS "LevelDB backend enabled.")
 157                 include_directories(${LEVELDB_INCLUDE_DIR})
 158         else()
 159                 message(STATUS "LevelDB not found!")
 160         endif()
 161 endif(ENABLE_LEVELDB)
 162
 163
 164 OPTION(ENABLE_REDIS "Enable Redis backend" TRUE)
 165 set(USE_REDIS FALSE)
 166
 167 if(ENABLE_REDIS)
 168         find_library(REDIS_LIBRARY hiredis)
 169         find_path(REDIS_INCLUDE_DIR hiredis.h PATH_SUFFIXES hiredis)
 170         if(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 171                 set(USE_REDIS TRUE)
 172                 message(STATUS "Redis backend enabled.")
 173                 include_directories(${REDIS_INCLUDE_DIR})
 174         else(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 175                 message(STATUS "Redis not found!")
 176         endif(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 177 endif(ENABLE_REDIS)
 178
 179
 180 find_package(SQLite3 REQUIRED)
 181 find_package(Json REQUIRED)
 182
 183
 184 if(NOT MSVC)
 185         set(USE_GPROF FALSE CACHE BOOL "Use -pg flag for g++")
 186 endif()
 187
 188 # Use cmake_config.h
 189 add_definitions(-DUSE_CMAKE_CONFIG_H)
 190
 191 if(WIN32)
 192         # Windows
 193         if(MSVC) # MSVC Specifics
 194                 set(PLATFORM_LIBS dbghelp.lib ${PLATFORM_LIBS})
 195                 # Surpress some useless warnings
 196                 add_definitions ( /D "_CRT_SECURE_NO_DEPRECATE" /W1 )
 197         else() # Probably MinGW = GCC
 198                 set(PLATFORM_LIBS "")
 199         endif()
 200         set(PLATFORM_LIBS ws2_32.lib shlwapi.lib ${PLATFORM_LIBS})
 201
 202         # Zlib stuff
 203         set(ZLIB_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/../../zlib/zlib-1.2.5"
 204                         CACHE PATH "Zlib include directory")
 205         set(ZLIB_LIBRARIES "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.lib"
 206                         CACHE FILEPATH "Path to zlibwapi.lib")
 207         set(ZLIB_DLL "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.dll"
 208                         CACHE FILEPATH "Path to zlibwapi.dll (for installation)")
 209         set(IRRLICHT_SOURCE_DIR "${PROJECT_SOURCE_DIR}/../../irrlicht-1.7.2"
 210                         CACHE PATH "irrlicht dir")
 211         if(USE_FREETYPE)
 212                 set(FREETYPE_INCLUDE_DIR_ft2build "${PROJECT_SOURCE_DIR}/../../freetype2/include/"
 213                                 CACHE PATH "freetype include dir")
 214                 set(FREETYPE_INCLUDE_DIR_freetype2 "${PROJECT_SOURCE_DIR}/../../freetype2/include/freetype"
 215                                 CACHE PATH "freetype include dir")
 216                 set(FREETYPE_LIBRARY "${PROJECT_SOURCE_DIR}/../../freetype2/objs/win32/vc2005/freetype247.lib"
 217                                 CACHE FILEPATH "Path to freetype247.lib")
 218         endif()
 219         if(ENABLE_SOUND)
 220                 set(OPENAL_DLL "" CACHE FILEPATH "Path to OpenAL32.dll for installation (optional)")
 221                 set(OGG_DLL "" CACHE FILEPATH "Path to libogg.dll for installation (optional)")
 222                 set(VORBIS_DLL "" CACHE FILEPATH "Path to libvorbis.dll for installation (optional)")
 223                 set(VORBISFILE_DLL "" CACHE FILEPATH "Path to libvorbisfile.dll for installation (optional)")
 224         endif()
 225 else()
 226         # Unix probably
 227         if(BUILD_CLIENT)
 228                 find_package(X11 REQUIRED)
 229                 find_package(OpenGL REQUIRED)
 230                 find_package(JPEG REQUIRED)
 231                 find_package(BZip2 REQUIRED)
 232                 find_package(PNG REQUIRED)
 233                 if(APPLE)
 234                         find_library(CARBON_LIB Carbon)
 235                         find_library(COCOA_LIB Cocoa)
 236                         find_library(IOKIT_LIB IOKit)
 237                         mark_as_advanced(
 238                                 CARBON_LIB
 239                                 COCOA_LIB
 240                                 IOKIT_LIB
 241                         )
 242                         SET(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${CARBON_LIB} ${COCOA_LIB} ${IOKIT_LIB})
 243                 endif(APPLE)
 244         endif(BUILD_CLIENT)
 245         find_package(ZLIB REQUIRED)
 246         set(PLATFORM_LIBS -lpthread ${CMAKE_DL_LIBS})
 247         if(APPLE)
 248                 set(PLATFORM_LIBS "-framework CoreFoundation" ${PLATFORM_LIBS})
 249         else()
 250                 set(PLATFORM_LIBS -lrt ${PLATFORM_LIBS})
 251         endif(APPLE)
 252         #set(CLIENT_PLATFORM_LIBS -lXxf86vm)
 253         # This way Xxf86vm is found on OpenBSD too
 254         find_library(XXF86VM_LIBRARY Xxf86vm)
 255         mark_as_advanced(XXF86VM_LIBRARY)
 256         set(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${XXF86VM_LIBRARY})
 257 endif()
 258
 259 check_include_files(endian.h HAVE_ENDIAN_H)
 260
 261 configure_file(
 262         "${PROJECT_SOURCE_DIR}/cmake_config.h.in"
 263         "${PROJECT_BINARY_DIR}/cmake_config.h"
 264 )
 265
 266
 267 # Add a target that always rebuilds cmake_config_githash.h
 268 add_custom_target(GenerateVersion
 269         COMMAND ${CMAKE_COMMAND}
 270         -D "GENERATE_VERSION_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
 271         -D "GENERATE_VERSION_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
 272         -D "VERSION_STRING=${VERSION_STRING}"
 273         -D "DEVELOPMENT_BUILD=${DEVELOPMENT_BUILD}"
 274         -P "${CMAKE_SOURCE_DIR}/cmake/Modules/GenerateVersion.cmake"
 275         WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}")
 276
 277
 278 add_subdirectory(jthread)
 279 add_subdirectory(network)
 280 add_subdirectory(script)
 281 add_subdirectory(unittest)
 282 add_subdirectory(util)
 283
 284 set(common_SRCS
 285         ban.cpp
 286         cavegen.cpp
 287         clientiface.cpp
 288         collision.cpp
 289         content_abm.cpp
 290         content_mapnode.cpp
 291         content_nodemeta.cpp
 292         content_sao.cpp
 293         convert_json.cpp
 294         craftdef.cpp
 295         database-dummy.cpp
 296         database-leveldb.cpp
 297         database-redis.cpp
 298         database-sqlite3.cpp
 299         database.cpp
 300         debug.cpp
 301         defaultsettings.cpp
 302         dungeongen.cpp
 303         emerge.cpp
 304         environment.cpp
 305         filesys.cpp
 306         genericobject.cpp
 307         gettext.cpp
 308         httpfetch.cpp
 309         inventory.cpp
 310         inventorymanager.cpp
 311         itemdef.cpp
 312         light.cpp
 313         log.cpp
 314         map.cpp
 315         mapblock.cpp
 316         mapgen.cpp
 317         mapgen_singlenode.cpp
 318         mapgen_v5.cpp
 319         mapgen_v6.cpp
 320         mapgen_v7.cpp
 321         mapnode.cpp
 322         mapsector.cpp
 323         mg_biome.cpp
 324         mg_decoration.cpp
 325         mg_ore.cpp
 326         mg_schematic.cpp
 327         mods.cpp
 328         nameidmapping.cpp
 329         nodedef.cpp
 330         nodemetadata.cpp
 331         nodetimer.cpp
 332         noise.cpp
 333         object_properties.cpp
 334         pathfinder.cpp
 335         player.cpp
 336         porting.cpp
 337         profiler.cpp
 338         quicktune.cpp
 339         rollback.cpp
 340         rollback_interface.cpp
 341         serialization.cpp
 342         server.cpp
 343         serverlist.cpp
 344         serverobject.cpp
 345         settings.cpp
 346         socket.cpp
 347         sound.cpp
 348         staticobject.cpp
 349         subgame.cpp
 350         tool.cpp
 351         treegen.cpp
 352         version.cpp
 353         voxel.cpp
 354         voxelalgorithms.cpp
 355         ${common_network_SRCS}
 356         ${JTHREAD_SRCS}
 357         ${common_SCRIPT_SRCS}
 358         ${UTIL_SRCS}
 359         ${UNITTEST_SRCS}
 360 )
 361
 362
 363 # This gives us the icon and file version information
 364 if(WIN32)
 365         set(WINRESOURCE_FILE "${CMAKE_CURRENT_SOURCE_DIR}/../misc/winresource.rc")
 366         if(MINGW)
 367                 if(NOT CMAKE_RC_COMPILER)
 368                         set(CMAKE_RC_COMPILER "windres.exe")
 369                 endif()
 370                 ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 371                         COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR} -I${CMAKE_CURRENT_BINARY_DIR}
 372                         -i${WINRESOURCE_FILE}
 373                         -o ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 374                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 375                         DEPENDS ${WINRESOURCE_FILE})
 376                 SET(common_SRCS ${common_SRCS} ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o)
 377         else(MINGW) # Probably MSVC
 378                 set(common_SRCS ${common_SRCS} ${WINRESOURCE_FILE})
 379         endif(MINGW)
 380 endif()
 381
 382
 383 # Client sources
 384 if (BUILD_CLIENT)
 385         add_subdirectory(client)
 386 endif(BUILD_CLIENT)
 387
 388 set(client_SRCS
 389         ${client_SRCS}
 390         ${common_SRCS}
 391         ${sound_SRCS}
 392         ${client_network_SRCS}
 393         camera.cpp
 394         chat.cpp
 395         client.cpp
 396         clientmap.cpp
 397         clientmedia.cpp
 398         clientobject.cpp
 399         clouds.cpp
 400         content_cao.cpp
 401         content_cso.cpp
 402         content_mapblock.cpp
 403         convert_json.cpp
 404         drawscene.cpp
 405         filecache.cpp
 406         fontengine.cpp
 407         game.cpp
 408         guiChatConsole.cpp
 409         guiEngine.cpp
 410         guiFileSelectMenu.cpp
 411         guiFormSpecMenu.cpp
 412         guiKeyChangeMenu.cpp
 413         guiPasswordChange.cpp
 414         guiscalingfilter.cpp
 415         guiTable.cpp
 416         guiVolumeChange.cpp
 417         hud.cpp
 418         imagefilters.cpp
 419         keycode.cpp
 420         localplayer.cpp
 421         main.cpp
 422         mapblock_mesh.cpp
 423         mesh.cpp
 424         particles.cpp
 425         shader.cpp
 426         sky.cpp
 427         wieldmesh.cpp
 428         ${client_SCRIPT_SRCS}
 429 )
 430 list(SORT client_SRCS)
 431
 432 # Server sources
 433 set(server_SRCS
 434         ${common_SRCS}
 435         main.cpp
 436 )
 437 list(SORT server_SRCS)
 438
 439 include_directories(
 440         ${PROJECT_BINARY_DIR}
 441         ${PROJECT_SOURCE_DIR}
 442         ${IRRLICHT_INCLUDE_DIR}
 443         ${ZLIB_INCLUDE_DIR}
 444         ${CMAKE_BUILD_TYPE}
 445         ${PNG_INCLUDE_DIR}
 446         ${GETTEXT_INCLUDE_DIR}
 447         ${SOUND_INCLUDE_DIRS}
 448         ${SQLITE3_INCLUDE_DIR}
 449         ${LUA_INCLUDE_DIR}
 450         ${GMP_INCLUDE_DIR}
 451         ${JSON_INCLUDE_DIR}
 452         ${PROJECT_SOURCE_DIR}/script
 453 )
 454
 455
 456 if(USE_FREETYPE)
 457         include_directories(${FREETYPE_INCLUDE_DIRS} ${CGUITTFONT_INCLUDE_DIR})
 458 endif()
 459
 460 if(USE_CURL)
 461         include_directories(${CURL_INCLUDE_DIR})
 462 endif()
 463
 464
 465 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_SOURCE_DIR}/bin")
 466
 467
 468 if(BUILD_CLIENT)
 469         add_executable(${PROJECT_NAME} ${client_SRCS})
 470         add_dependencies(${PROJECT_NAME} GenerateVersion)
 471         set(client_LIBS
 472                 ${PROJECT_NAME}
 473                 ${ZLIB_LIBRARIES}
 474                 ${IRRLICHT_LIBRARY}
 475                 ${OPENGL_LIBRARIES}
 476                 ${JPEG_LIBRARIES}
 477                 ${BZIP2_LIBRARIES}
 478                 ${PNG_LIBRARIES}
 479                 ${X11_LIBRARIES}
 480                 ${GETTEXT_LIBRARY}
 481                 ${SOUND_LIBRARIES}
 482                 ${SQLITE3_LIBRARY}
 483                 ${LUA_LIBRARY}
 484                 ${GMP_LIBRARY}
 485                 ${JSON_LIBRARY}
 486                 ${OPENGLES2_LIBRARIES}
 487                 ${PLATFORM_LIBS}
 488                 ${CLIENT_PLATFORM_LIBS}
 489         )
 490         if(APPLE)
 491                 target_link_libraries(
 492                         ${client_LIBS}
 493                         ${ICONV_LIBRARY}
 494                 )
 495         else()
 496                 target_link_libraries(
 497                         ${client_LIBS}
 498                 )
 499         endif()
 500         if(USE_CURL)
 501                 target_link_libraries(
 502                         ${PROJECT_NAME}
 503                         ${CURL_LIBRARY}
 504                 )
 505         endif()
 506         if(USE_FREETYPE)
 507                 if(FREETYPE_PKGCONFIG_FOUND)
 508                         set_target_properties(${PROJECT_NAME}
 509                                 PROPERTIES
 510                                 COMPILE_FLAGS "${FREETYPE_CFLAGS_STR}"
 511                         )
 512                 endif()
 513                 target_link_libraries(
 514                         ${PROJECT_NAME}
 515                         ${FREETYPE_LIBRARY}
 516                         ${CGUITTFONT_LIBRARY}
 517                 )
 518         endif()
 519         if (USE_LEVELDB)
 520                 target_link_libraries(${PROJECT_NAME} ${LEVELDB_LIBRARY})
 521         endif()
 522         if (USE_REDIS)
 523                 target_link_libraries(${PROJECT_NAME} ${REDIS_LIBRARY})
 524         endif()
 525 endif(BUILD_CLIENT)
 526
 527
 528 if(BUILD_SERVER)
 529         add_executable(${PROJECT_NAME}server ${server_SRCS})
 530         add_dependencies(${PROJECT_NAME}server GenerateVersion)
 531         target_link_libraries(
 532                 ${PROJECT_NAME}server
 533                 ${ZLIB_LIBRARIES}
 534                 ${SQLITE3_LIBRARY}
 535                 ${JSON_LIBRARY}
 536                 ${GETTEXT_LIBRARY}
 537                 ${LUA_LIBRARY}
 538                 ${GMP_LIBRARY}
 539                 ${PLATFORM_LIBS}
 540         )
 541         set_target_properties(${PROJECT_NAME}server PROPERTIES
 542                         COMPILE_DEFINITIONS "SERVER")
 543         if (USE_LEVELDB)
 544                 target_link_libraries(${PROJECT_NAME}server ${LEVELDB_LIBRARY})
 545         endif()
 546         if (USE_REDIS)
 547                 target_link_libraries(${PROJECT_NAME}server ${REDIS_LIBRARY})
 548         endif()
 549         if(USE_CURL)
 550                 target_link_libraries(
 551                         ${PROJECT_NAME}server
 552                         ${CURL_LIBRARY}
 553                 )
 554         endif()
 555 endif(BUILD_SERVER)
 556
 557
 558 # Set some optimizations and tweaks
 559
 560 include(CheckCXXCompilerFlag)
 561
 562 if(MSVC)
 563         # Visual Studio
 564
 565         # EHa enables SEH exceptions (used for catching segfaults)
 566         set(CMAKE_CXX_FLAGS_RELEASE "/EHa /Ox /Ob2 /Oi /Ot /Oy /GL /FD /MT /GS- /arch:SSE /fp:fast /D NDEBUG /D _HAS_ITERATOR_DEBUGGING=0 /TP")
 567         #set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /NODEFAULTLIB:\"libcmtd.lib\" /NODEFAULTLIB:\"libcmt.lib\"")
 568         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG")
 569
 570         set(CMAKE_CXX_FLAGS_SEMIDEBUG "/MDd /Zi /Ob0 /O1 /RTC1")
 571
 572         # Debug build doesn't catch exceptions by itself
 573         # Add some optimizations because otherwise it's VERY slow
 574         set(CMAKE_CXX_FLAGS_DEBUG "/MDd /Zi /Ob0 /Od /RTC1")
 575
 576         # Flags for C files (sqlite)
 577         # /MT = Link statically with standard library stuff
 578         set(CMAKE_C_FLAGS_RELEASE "/O2 /Ob2 /MT")
 579 else()
 580         # Probably GCC
 581         if(APPLE)
 582                 SET( CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} -pagezero_size 10000 -image_base 100000000" )
 583         endif()
 584         if(WARN_ALL)
 585                 set(RELEASE_WARNING_FLAGS "-Wall")
 586         else()
 587                 set(RELEASE_WARNING_FLAGS "")
 588         endif()
 589
 590         if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 591                 # clang does not understand __extern_always_inline but libc headers use it
 592                 set(OTHER_FLAGS "${OTHER_FLAGS} \"-D__extern_always_inline=extern __always_inline\"")
 593         endif()
 594
 595         if(MINGW)
 596                 set(OTHER_FLAGS "-mthreads -fexceptions")
 597         endif()
 598
 599         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${RELEASE_WARNING_FLAGS} ${WARNING_FLAGS} ${OTHER_FLAGS} -ffast-math -Wall -pipe -funroll-loops")
 600         if(APPLE)
 601                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Os")
 602         else()
 603                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3 -fomit-frame-pointer")
 604         endif(APPLE)
 605         set(CMAKE_CXX_FLAGS_SEMIDEBUG "-g -O1 -Wall -Wabi ${WARNING_FLAGS} ${OTHER_FLAGS}")
 606         set(CMAKE_CXX_FLAGS_DEBUG "-g -O0 -Wall -Wabi ${WARNING_FLAGS} ${OTHER_FLAGS}")
 607
 608         if(USE_GPROF)
 609                 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 610         endif()
 611 endif()
 612
 613
 614 # Installation
 615
 616 if(WIN32)
 617         if(USE_SOUND)
 618                 if(OPENAL_DLL)
 619                         install(FILES ${OPENAL_DLL} DESTINATION ${BINDIR})
 620                 endif()
 621                 if(OGG_DLL)
 622                         install(FILES ${OGG_DLL} DESTINATION ${BINDIR})
 623                 endif()
 624                 if(VORBIS_DLL)
 625                         install(FILES ${VORBIS_DLL} DESTINATION ${BINDIR})
 626                 endif()
 627                 if(VORBISFILE_DLL)
 628                         install(FILES ${VORBISFILE_DLL} DESTINATION ${BINDIR})
 629                 endif()
 630         endif()
 631         if(CURL_DLL)
 632                 install(FILES ${CURL_DLL} DESTINATION ${BINDIR})
 633         endif()
 634         if(ZLIB_DLL)
 635                 install(FILES ${ZLIB_DLL} DESTINATION ${BINDIR})
 636         endif()
 637         if(ZLIBWAPI_DLL)
 638                 install(FILES ${ZLIBWAPI_DLL} DESTINATION ${BINDIR})
 639         endif()
 640         if(FREETYPE_DLL)
 641                 install(FILES ${FREETYPE_DLL} DESTINATION ${BINDIR})
 642         endif()
 643         if(SQLITE3_DLL)
 644                 install(FILES ${SQLITE3_DLL} DESTINATION ${BINDIR})
 645         endif()
 646         if(LEVELDB_DLL)
 647                 install(FILES ${LEVELDB_DLL} DESTINATION ${BINDIR})
 648         endif()
 649 endif()
 650
 651 if(BUILD_CLIENT)
 652         install(TARGETS ${PROJECT_NAME}
 653                 RUNTIME DESTINATION ${BINDIR}
 654                 LIBRARY DESTINATION ${BINDIR}
 655                 ARCHIVE DESTINATION ${BINDIR}
 656                 BUNDLE DESTINATION .
 657         )
 658
 659         if(APPLE)
 660                 install(CODE "
 661                         set(BU_CHMOD_BUNDLE_ITEMS ON)
 662                         include(BundleUtilities)
 663                         fixup_bundle(\"\${CMAKE_INSTALL_PREFIX}/${BUNDLE_PATH}\" \"\" \"\${CMAKE_INSTALL_PREFIX}/${BINDIR}\")
 664                 " COMPONENT Runtime)
 665         endif()
 666
 667         if(USE_GETTEXT)
 668                 foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 669                         set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 670                         set(MO_BUILD_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 671                         install(FILES ${MO_BUILD_PATH} DESTINATION ${MO_DEST_PATH})
 672                 endforeach()
 673         endif()
 674
 675         if(WIN32)
 676                 if(DEFINED IRRLICHT_DLL)
 677                         install(FILES ${IRRLICHT_DLL} DESTINATION ${BINDIR})
 678                 endif()
 679                 if(USE_GETTEXT)
 680                         if(DEFINED GETTEXT_DLL)
 681                                 install(FILES ${GETTEXT_DLL} DESTINATION ${BINDIR})
 682                         endif()
 683                         if(DEFINED GETTEXT_ICONV_DLL)
 684                                 install(FILES ${GETTEXT_ICONV_DLL} DESTINATION ${BINDIR})
 685                         endif()
 686                 endif()
 687         endif()
 688 endif(BUILD_CLIENT)
 689
 690 if(BUILD_SERVER)
 691         install(TARGETS ${PROJECT_NAME}server DESTINATION ${BINDIR})
 692 endif()
 693
 694 if (USE_GETTEXT)
 695         set(MO_FILES)
 696
 697         foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 698                 set(PO_FILE_PATH "${GETTEXT_PO_PATH}/${LOCALE}/${PROJECT_NAME}.po")
 699                 set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 700                 set(MO_FILE_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 701
 702                 add_custom_command(OUTPUT ${MO_BUILD_PATH}
 703                         COMMAND ${CMAKE_COMMAND} -E make_directory ${MO_BUILD_PATH}
 704                         COMMENT "mo-update [${LOCALE}]: Creating locale directory.")
 705
 706                 add_custom_command(
 707                         OUTPUT ${MO_FILE_PATH}
 708                         COMMAND ${GETTEXT_MSGFMT} -o ${MO_FILE_PATH} ${PO_FILE_PATH}
 709                         DEPENDS ${MO_BUILD_PATH} ${PO_FILE_PATH}
 710                         WORKING_DIRECTORY "${GETTEXT_PO_PATH}/${LOCALE}"
 711                         COMMENT "mo-update [${LOCALE}]: Creating mo file."
 712                         )
 713
 714                 set(MO_FILES ${MO_FILES} ${MO_FILE_PATH})
 715         endforeach()
 716
 717         add_custom_target(translations ALL COMMENT "mo update" DEPENDS ${MO_FILES})
 718 endif()
 719
 720
 721 # Subdirectories
 722
 723 if (BUILD_CLIENT AND USE_FREETYPE)
 724         add_subdirectory(cguittfont)
 725 endif()
 726