src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(minetest)
   4
   5 INCLUDE(CheckIncludeFiles)
   6 INCLUDE(CheckLibraryExists)
   7
   8 # Add custom SemiDebug build mode
   9 set(CMAKE_CXX_FLAGS_SEMIDEBUG "-O1 -g -Wall -Wabi" CACHE STRING
  10         "Flags used by the C++ compiler during semidebug builds."
  11         FORCE
  12 )
  13 set(CMAKE_C_FLAGS_SEMIDEBUG "-O1 -g -Wall -pedantic" CACHE STRING
  14         "Flags used by the C compiler during semidebug builds."
  15         FORCE
  16 )
  17 mark_as_advanced(
  18         CMAKE_CXX_FLAGS_SEMIDEBUG
  19         CMAKE_C_FLAGS_SEMIDEBUG
  20 )
  21 set(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING
  22         "Choose the type of build. Options are: None Debug SemiDebug RelWithDebInfo MinSizeRel."
  23         FORCE
  24 )
  25
  26
  27 # Set some random things default to not being visible in the GUI
  28 mark_as_advanced(EXECUTABLE_OUTPUT_PATH LIBRARY_OUTPUT_PATH)
  29
  30
  31 if(NOT (BUILD_CLIENT OR BUILD_SERVER))
  32         message(WARNING "Neither BUILD_CLIENT nor BUILD_SERVER is set! Setting BUILD_SERVER=true")
  33         set(BUILD_SERVER TRUE)
  34 endif()
  35
  36
  37 option(ENABLE_CURL "Enable cURL support for fetching media" TRUE)
  38 set(USE_CURL FALSE)
  39
  40 if(ENABLE_CURL)
  41         find_package(CURL)
  42         if (CURL_FOUND)
  43                 message(STATUS "cURL support enabled.")
  44                 set(USE_CURL TRUE)
  45         endif()
  46 else()
  47         mark_as_advanced(CLEAR CURL_LIBRARY CURL_INCLUDE_DIR)
  48 endif()
  49
  50 if(NOT USE_CURL)
  51         if(BUILD_CLIENT)
  52                 message(WARNING "cURL is required to load the server list")
  53         endif()
  54         if(BUILD_SERVER)
  55                 message(WARNING "cURL is required to announce to the server list")
  56         endif()
  57 endif()
  58
  59
  60 option(ENABLE_GETTEXT "Use GetText for internationalization" FALSE)
  61 set(USE_GETTEXT FALSE)
  62
  63 if(ENABLE_GETTEXT)
  64         find_package(GettextLib)
  65         if(GETTEXT_FOUND)
  66                 if(WIN32)
  67                         message(STATUS "GetText library: ${GETTEXT_LIBRARY}")
  68                         message(STATUS "GetText DLL: ${GETTEXT_DLL}")
  69                         message(STATUS "GetText iconv DLL: ${GETTEXT_ICONV_DLL}")
  70                 endif()
  71                 set(USE_GETTEXT TRUE)
  72                 message(STATUS "GetText enabled; locales found: ${GETTEXT_AVAILABLE_LOCALES}")
  73         endif(GETTEXT_FOUND)
  74 else()
  75         mark_as_advanced(GETTEXT_ICONV_DLL GETTEXT_INCLUDE_DIR GETTEXT_LIBRARY GETTEXT_MSGFMT)
  76         message(STATUS "GetText disabled.")
  77 endif()
  78
  79
  80 option(ENABLE_SOUND "Enable sound" TRUE)
  81 set(USE_SOUND FALSE)
  82
  83 if(BUILD_CLIENT AND ENABLE_SOUND)
  84         # Sound libraries
  85         find_package(OpenAL)
  86         find_package(Vorbis)
  87         if(NOT OPENAL_FOUND)
  88                 message(STATUS "Sound enabled, but OpenAL not found!")
  89                 mark_as_advanced(CLEAR OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
  90         endif()
  91         if(NOT VORBIS_FOUND)
  92                 message(STATUS "Sound enabled, but Vorbis libraries not found!")
  93                 mark_as_advanced(CLEAR OGG_INCLUDE_DIR VORBIS_INCLUDE_DIR OGG_LIBRARY VORBIS_LIBRARY VORBISFILE_LIBRARY)
  94         endif()
  95         if(OPENAL_FOUND AND VORBIS_FOUND)
  96                 set(USE_SOUND TRUE)
  97                 message(STATUS "Sound enabled.")
  98         else()
  99                 message(FATAL_ERROR "Sound enabled, but cannot be used.\n"
 100                         "To continue, either fill in the required paths or disable sound. (-DENABLE_SOUND=0)")
 101         endif()
 102 endif()
 103
 104 if(USE_SOUND)
 105         set(sound_SRCS sound_openal.cpp)
 106         set(SOUND_INCLUDE_DIRS
 107                 ${OPENAL_INCLUDE_DIR}
 108                 ${VORBIS_INCLUDE_DIR}
 109                 ${OGG_INCLUDE_DIR}
 110                 )
 111         set(SOUND_LIBRARIES
 112                 ${OPENAL_LIBRARY}
 113                 ${VORBIS_LIBRARIES}
 114                 )
 115 endif()
 116
 117
 118 option(ENABLE_GLES "Enable OpenGL ES support" FALSE)
 119 mark_as_advanced(ENABLE_GLES)
 120 if(ENABLE_GLES)
 121         find_package(OpenGLES2)
 122 endif()
 123
 124
 125 option(ENABLE_FREETYPE "Enable FreeType2 (TrueType fonts and basic unicode support)" TRUE)
 126 set(USE_FREETYPE FALSE)
 127
 128 if(ENABLE_FREETYPE)
 129 ##
 130 ## Note: FindFreetype.cmake seems to have been fixed in recent versions of
 131 ## CMake. If issues persist, re-enable this workaround specificially for the
 132 ## failing platforms.
 133 ##
 134 #       if(UNIX)
 135 #               include(FindPkgConfig)
 136 #               if(PKG_CONFIG_FOUND)
 137 #                       pkg_check_modules(FREETYPE QUIET freetype2)
 138 #                       if(FREETYPE_FOUND)
 139 #                               SET(FREETYPE_PKGCONFIG_FOUND TRUE)
 140 #                               SET(FREETYPE_LIBRARY ${FREETYPE_LIBRARIES})
 141 #                               # Because CMake is idiotic
 142 #                               string(REPLACE ";" " " FREETYPE_CFLAGS_STR ${FREETYPE_CFLAGS})
 143 #                               string(REPLACE ";" " " FREETYPE_LDFLAGS_STR ${FREETYPE_LDFLAGS})
 144 #                       endif(FREETYPE_FOUND)
 145 #               endif(PKG_CONFIG_FOUND)
 146 #       endif(UNIX)
 147 #       if(NOT FREETYPE_FOUND)
 148 #               find_package(Freetype)
 149 #       endif()
 150         find_package(Freetype)
 151         if(FREETYPE_FOUND)
 152                 message(STATUS "Freetype enabled.")
 153                 set(USE_FREETYPE TRUE)
 154         endif()
 155 endif(ENABLE_FREETYPE)
 156
 157 option(ENABLE_CURSES "Enable ncurses console" TRUE)
 158 set(USE_CURSES FALSE)
 159
 160 if(ENABLE_CURSES)
 161         find_package(Ncursesw)
 162         if(CURSES_FOUND)
 163                 set(USE_CURSES TRUE)
 164                 message(STATUS "ncurses console enabled.")
 165                 include_directories(${CURSES_INCLUDE_DIRS})
 166         else()
 167                 message(STATUS "ncurses not found!")
 168         endif()
 169 endif(ENABLE_CURSES)
 170
 171 option(ENABLE_POSTGRESQL "Enable PostgreSQL backend" TRUE)
 172 set(USE_POSTGRESQL FALSE)
 173
 174 if(ENABLE_POSTGRESQL)
 175         find_program(POSTGRESQL_CONFIG_EXECUTABLE pg_config DOC "pg_config")
 176         find_library(POSTGRESQL_LIBRARY pq)
 177         if(POSTGRESQL_CONFIG_EXECUTABLE)
 178                 execute_process(COMMAND ${POSTGRESQL_CONFIG_EXECUTABLE} --includedir-server
 179                         OUTPUT_VARIABLE POSTGRESQL_SERVER_INCLUDE_DIRS
 180                         OUTPUT_STRIP_TRAILING_WHITESPACE)
 181                 execute_process(COMMAND ${POSTGRESQL_CONFIG_EXECUTABLE}
 182                         OUTPUT_VARIABLE POSTGRESQL_CLIENT_INCLUDE_DIRS
 183                         OUTPUT_STRIP_TRAILING_WHITESPACE)
 184                 # This variable is case sensitive for the cmake PostgreSQL module
 185                 set(PostgreSQL_ADDITIONAL_SEARCH_PATHS ${POSTGRESQL_SERVER_INCLUDE_DIRS} ${POSTGRESQL_CLIENT_INCLUDE_DIRS})
 186         endif()
 187
 188         find_package("PostgreSQL")
 189
 190         if(POSTGRESQL_FOUND)
 191                 set(USE_POSTGRESQL TRUE)
 192                 message(STATUS "PostgreSQL backend enabled")
 193                 # This variable is case sensitive, don't try to change it to POSTGRESQL_INCLUDE_DIR
 194                 message(STATUS "PostgreSQL includes: ${PostgreSQL_INCLUDE_DIR}")
 195                 include_directories(${PostgreSQL_INCLUDE_DIR})
 196         else()
 197                 message(STATUS "PostgreSQL not found!")
 198         endif()
 199 endif(ENABLE_POSTGRESQL)
 200
 201 option(ENABLE_LEVELDB "Enable LevelDB backend" TRUE)
 202 set(USE_LEVELDB FALSE)
 203
 204 if(ENABLE_LEVELDB)
 205         find_library(LEVELDB_LIBRARY leveldb)
 206         find_path(LEVELDB_INCLUDE_DIR db.h PATH_SUFFIXES leveldb)
 207         if(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 208                 set(USE_LEVELDB TRUE)
 209                 message(STATUS "LevelDB backend enabled.")
 210                 include_directories(${LEVELDB_INCLUDE_DIR})
 211         else()
 212                 message(STATUS "LevelDB not found!")
 213         endif()
 214 endif(ENABLE_LEVELDB)
 215
 216
 217 OPTION(ENABLE_REDIS "Enable Redis backend" TRUE)
 218 set(USE_REDIS FALSE)
 219
 220 if(ENABLE_REDIS)
 221         find_library(REDIS_LIBRARY hiredis)
 222         find_path(REDIS_INCLUDE_DIR hiredis.h PATH_SUFFIXES hiredis)
 223         if(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 224                 set(USE_REDIS TRUE)
 225                 message(STATUS "Redis backend enabled.")
 226                 include_directories(${REDIS_INCLUDE_DIR})
 227         else(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 228                 message(STATUS "Redis not found!")
 229         endif(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 230 endif(ENABLE_REDIS)
 231
 232
 233 find_package(SQLite3 REQUIRED)
 234
 235 OPTION(ENABLE_SPATIAL "Enable SpatialIndex AreaStore backend" TRUE)
 236 set(USE_SPATIAL FALSE)
 237
 238 if(ENABLE_SPATIAL)
 239         find_library(SPATIAL_LIBRARY spatialindex)
 240         find_path(SPATIAL_INCLUDE_DIR spatialindex/SpatialIndex.h)
 241         if(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 242                 set(USE_SPATIAL TRUE)
 243                 message(STATUS "SpatialIndex AreaStore backend enabled.")
 244                 include_directories(${SPATIAL_INCLUDE_DIR})
 245         else(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 246                 message(STATUS "SpatialIndex not found!")
 247         endif(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 248 endif(ENABLE_SPATIAL)
 249
 250
 251 if(NOT MSVC)
 252         set(USE_GPROF FALSE CACHE BOOL "Use -pg flag for g++")
 253 endif()
 254
 255 # Use cmake_config.h
 256 add_definitions(-DUSE_CMAKE_CONFIG_H)
 257
 258 if(WIN32)
 259         # Windows
 260         if(MSVC) # MSVC Specifics
 261                 set(PLATFORM_LIBS dbghelp.lib ${PLATFORM_LIBS})
 262                 # Surpress some useless warnings
 263                 add_definitions ( /D "_CRT_SECURE_NO_DEPRECATE" /W1 )
 264                 # Get M_PI to work
 265                 add_definitions(/D "_USE_MATH_DEFINES")
 266         else() # Probably MinGW = GCC
 267                 set(PLATFORM_LIBS "")
 268         endif()
 269         set(PLATFORM_LIBS ws2_32.lib shlwapi.lib ${PLATFORM_LIBS})
 270
 271         # Zlib stuff
 272         set(ZLIB_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/../../zlib/zlib-1.2.5"
 273                         CACHE PATH "Zlib include directory")
 274         set(ZLIB_LIBRARIES "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.lib"
 275                         CACHE FILEPATH "Path to zlib library (usually zlibwapi.lib)")
 276         set(ZLIB_DLL "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.dll"
 277                         CACHE FILEPATH "Path to zlib DLL (for installation)")
 278         set(ZLIBWAPI_DLL "" CACHE FILEPATH "Path to zlibwapi DLL")
 279         set(IRRLICHT_SOURCE_DIR "${PROJECT_SOURCE_DIR}/../../irrlicht-1.7.2"
 280                         CACHE PATH "irrlicht dir")
 281         if(USE_FREETYPE)
 282                 set(FREETYPE_INCLUDE_DIR_ft2build "${PROJECT_SOURCE_DIR}/../../freetype2/include/"
 283                                 CACHE PATH "freetype include dir")
 284                 set(FREETYPE_INCLUDE_DIR_freetype2 "${PROJECT_SOURCE_DIR}/../../freetype2/include/freetype"
 285                                 CACHE PATH "freetype include dir")
 286                 set(FREETYPE_LIBRARY "${PROJECT_SOURCE_DIR}/../../freetype2/objs/win32/vc2005/freetype247.lib"
 287                                 CACHE FILEPATH "Path to freetype247.lib")
 288         endif()
 289         if(ENABLE_SOUND)
 290                 set(OPENAL_DLL "" CACHE FILEPATH "Path to OpenAL32.dll for installation (optional)")
 291                 set(OGG_DLL "" CACHE FILEPATH "Path to libogg.dll for installation (optional)")
 292                 set(VORBIS_DLL "" CACHE FILEPATH "Path to libvorbis.dll for installation (optional)")
 293                 set(VORBISFILE_DLL "" CACHE FILEPATH "Path to libvorbisfile.dll for installation (optional)")
 294         endif()
 295 else()
 296         # Unix probably
 297         if(BUILD_CLIENT)
 298                 find_package(X11 REQUIRED)
 299                 find_package(OpenGL REQUIRED)
 300                 find_package(JPEG REQUIRED)
 301                 find_package(BZip2 REQUIRED)
 302                 find_package(PNG REQUIRED)
 303                 if(APPLE)
 304                         find_library(CARBON_LIB Carbon)
 305                         find_library(COCOA_LIB Cocoa)
 306                         find_library(IOKIT_LIB IOKit)
 307                         mark_as_advanced(
 308                                 CARBON_LIB
 309                                 COCOA_LIB
 310                                 IOKIT_LIB
 311                         )
 312                         SET(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${CARBON_LIB} ${COCOA_LIB} ${IOKIT_LIB})
 313                 endif(APPLE)
 314         endif(BUILD_CLIENT)
 315         find_package(ZLIB REQUIRED)
 316         set(PLATFORM_LIBS -lpthread ${CMAKE_DL_LIBS})
 317         if(APPLE)
 318                 set(PLATFORM_LIBS "-framework CoreFoundation" ${PLATFORM_LIBS})
 319         else()
 320                 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 321                 if (HAVE_LIBRT)
 322                         set(PLATFORM_LIBS -lrt ${PLATFORM_LIBS})
 323                 endif(HAVE_LIBRT)
 324         endif(APPLE)
 325
 326         # This way Xxf86vm is found on OpenBSD too
 327         find_library(XXF86VM_LIBRARY Xxf86vm)
 328         mark_as_advanced(XXF86VM_LIBRARY)
 329         set(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${XXF86VM_LIBRARY})
 330
 331         # Prefer local iconv if installed
 332         find_library(ICONV_LIBRARY iconv)
 333         mark_as_advanced(ICONV_LIBRARY)
 334         if (ICONV_LIBRARY)
 335                 set(PLATFORM_LIBS ${PLATFORM_LIBS} ${ICONV_LIBRARY})
 336         endif()
 337 endif()
 338
 339 check_include_files(endian.h HAVE_ENDIAN_H)
 340
 341 configure_file(
 342         "${PROJECT_SOURCE_DIR}/cmake_config.h.in"
 343         "${PROJECT_BINARY_DIR}/cmake_config.h"
 344 )
 345
 346
 347 # Add a target that always rebuilds cmake_config_githash.h
 348 add_custom_target(GenerateVersion
 349         COMMAND ${CMAKE_COMMAND}
 350         -D "GENERATE_VERSION_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
 351         -D "GENERATE_VERSION_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
 352         -D "VERSION_STRING=${VERSION_STRING}"
 353         -D "DEVELOPMENT_BUILD=${DEVELOPMENT_BUILD}"
 354         -P "${CMAKE_SOURCE_DIR}/cmake/Modules/GenerateVersion.cmake"
 355         WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}")
 356
 357
 358 add_subdirectory(threading)
 359 add_subdirectory(network)
 360 add_subdirectory(script)
 361 add_subdirectory(unittest)
 362 add_subdirectory(util)
 363 add_subdirectory(irrlicht_changes)
 364
 365 set(common_SRCS
 366         ban.cpp
 367         cavegen.cpp
 368         chat.cpp
 369         clientiface.cpp
 370         collision.cpp
 371         content_mapnode.cpp
 372         content_nodemeta.cpp
 373         content_sao.cpp
 374         convert_json.cpp
 375         craftdef.cpp
 376         database-dummy.cpp
 377         database-files.cpp
 378         database-leveldb.cpp
 379         database-postgresql.cpp
 380         database-redis.cpp
 381         database-sqlite3.cpp
 382         database.cpp
 383         debug.cpp
 384         defaultsettings.cpp
 385         dungeongen.cpp
 386         emerge.cpp
 387         environment.cpp
 388         face_position_cache.cpp
 389         filesys.cpp
 390         genericobject.cpp
 391         gettext.cpp
 392         httpfetch.cpp
 393         inventory.cpp
 394         inventorymanager.cpp
 395         itemdef.cpp
 396         itemstackmetadata.cpp
 397         light.cpp
 398         log.cpp
 399         map.cpp
 400         map_settings_manager.cpp
 401         mapblock.cpp
 402         mapgen.cpp
 403         mapgen_flat.cpp
 404         mapgen_fractal.cpp
 405         mapgen_singlenode.cpp
 406         mapgen_v5.cpp
 407         mapgen_v6.cpp
 408         mapgen_v7.cpp
 409         mapgen_valleys.cpp
 410         mapnode.cpp
 411         mapsector.cpp
 412         metadata.cpp
 413         mg_biome.cpp
 414         mg_decoration.cpp
 415         mg_ore.cpp
 416         mg_schematic.cpp
 417         mods.cpp
 418         nameidmapping.cpp
 419         nodedef.cpp
 420         nodemetadata.cpp
 421         nodetimer.cpp
 422         noise.cpp
 423         objdef.cpp
 424         object_properties.cpp
 425         pathfinder.cpp
 426         player.cpp
 427         porting.cpp
 428         profiler.cpp
 429         quicktune.cpp
 430         reflowscan.cpp
 431         remoteplayer.cpp
 432         raycast.cpp
 433         rollback.cpp
 434         rollback_interface.cpp
 435         serialization.cpp
 436         server.cpp
 437         serverenvironment.cpp
 438         serverlist.cpp
 439         serverobject.cpp
 440         settings.cpp
 441         socket.cpp
 442         sound.cpp
 443         staticobject.cpp
 444         subgame.cpp
 445         terminal_chat_console.cpp
 446         tileanimation.cpp
 447         tool.cpp
 448         treegen.cpp
 449         version.cpp
 450         voxel.cpp
 451         voxelalgorithms.cpp
 452         ${common_network_SRCS}
 453         ${JTHREAD_SRCS}
 454         ${common_SCRIPT_SRCS}
 455         ${UTIL_SRCS}
 456         ${UNITTEST_SRCS}
 457 )
 458
 459
 460 # This gives us the icon and file version information
 461 if(WIN32)
 462         set(WINRESOURCE_FILE "${CMAKE_CURRENT_SOURCE_DIR}/../misc/winresource.rc")
 463         set(MINETEST_EXE_MANIFEST_FILE "${CMAKE_CURRENT_SOURCE_DIR}/../misc/minetest.exe.manifest")
 464         if(MINGW)
 465                 if(NOT CMAKE_RC_COMPILER)
 466                         set(CMAKE_RC_COMPILER "windres.exe")
 467                 endif()
 468                 ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 469                         COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR} -I${CMAKE_CURRENT_BINARY_DIR}
 470                         -i${WINRESOURCE_FILE}
 471                         -o ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 472                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 473                         DEPENDS ${WINRESOURCE_FILE})
 474                 SET(common_SRCS ${common_SRCS} ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o)
 475         else(MINGW) # Probably MSVC
 476                 set(common_SRCS ${common_SRCS} ${WINRESOURCE_FILE} ${MINETEST_EXE_MANIFEST_FILE})
 477         endif(MINGW)
 478 endif()
 479
 480
 481 # Client sources
 482 if (BUILD_CLIENT)
 483         add_subdirectory(client)
 484 endif(BUILD_CLIENT)
 485
 486 set(client_SRCS
 487         ${client_SRCS}
 488         ${common_SRCS}
 489         ${sound_SRCS}
 490         ${client_network_SRCS}
 491         ${client_irrlicht_changes_SRCS}
 492         camera.cpp
 493         client.cpp
 494         clientenvironment.cpp
 495         clientmap.cpp
 496         clientmedia.cpp
 497         clientobject.cpp
 498         clouds.cpp
 499         content_cao.cpp
 500         content_cso.cpp
 501         content_mapblock.cpp
 502         convert_json.cpp
 503         filecache.cpp
 504         fontengine.cpp
 505         game.cpp
 506         guiChatConsole.cpp
 507         guiEngine.cpp
 508         guiPathSelectMenu.cpp
 509         guiFormSpecMenu.cpp
 510         guiKeyChangeMenu.cpp
 511         guiPasswordChange.cpp
 512         guiscalingfilter.cpp
 513         guiTable.cpp
 514         guiVolumeChange.cpp
 515         hud.cpp
 516         imagefilters.cpp
 517         intlGUIEditBox.cpp
 518         keycode.cpp
 519         localplayer.cpp
 520         main.cpp
 521         mapblock_mesh.cpp
 522         mesh.cpp
 523         mesh_generator_thread.cpp
 524         minimap.cpp
 525         particles.cpp
 526         shader.cpp
 527         sky.cpp
 528         wieldmesh.cpp
 529         ${client_SCRIPT_SRCS}
 530         ${UNITTEST_CLIENT_SRCS}
 531 )
 532 list(SORT client_SRCS)
 533
 534 # Server sources
 535 set(server_SRCS
 536         ${common_SRCS}
 537         main.cpp
 538 )
 539 list(SORT server_SRCS)
 540
 541 include_directories(
 542         ${PROJECT_BINARY_DIR}
 543         ${PROJECT_SOURCE_DIR}
 544         ${IRRLICHT_INCLUDE_DIR}
 545         ${ZLIB_INCLUDE_DIR}
 546         ${CMAKE_BUILD_TYPE}
 547         ${PNG_INCLUDE_DIR}
 548         ${GETTEXT_INCLUDE_DIR}
 549         ${SOUND_INCLUDE_DIRS}
 550         ${SQLITE3_INCLUDE_DIR}
 551         ${LUA_INCLUDE_DIR}
 552         ${GMP_INCLUDE_DIR}
 553         ${JSON_INCLUDE_DIR}
 554         ${X11_INCLUDE_DIR}
 555         ${PROJECT_SOURCE_DIR}/script
 556 )
 557
 558
 559 if(USE_FREETYPE)
 560         include_directories(${FREETYPE_INCLUDE_DIRS})
 561 endif()
 562
 563 if(USE_CURL)
 564         include_directories(${CURL_INCLUDE_DIR})
 565 endif()
 566
 567
 568 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_SOURCE_DIR}/bin")
 569
 570
 571 if(BUILD_CLIENT)
 572         add_executable(${PROJECT_NAME} ${client_SRCS})
 573         add_dependencies(${PROJECT_NAME} GenerateVersion)
 574         set(client_LIBS
 575                 ${PROJECT_NAME}
 576                 ${ZLIB_LIBRARIES}
 577                 ${IRRLICHT_LIBRARY}
 578                 ${OPENGL_LIBRARIES}
 579                 ${JPEG_LIBRARIES}
 580                 ${BZIP2_LIBRARIES}
 581                 ${PNG_LIBRARIES}
 582                 ${X11_LIBRARIES}
 583                 ${GETTEXT_LIBRARY}
 584                 ${SOUND_LIBRARIES}
 585                 ${SQLITE3_LIBRARY}
 586                 ${LUA_LIBRARY}
 587                 ${GMP_LIBRARY}
 588                 ${JSON_LIBRARY}
 589                 ${OPENGLES2_LIBRARIES}
 590                 ${PLATFORM_LIBS}
 591                 ${CLIENT_PLATFORM_LIBS}
 592         )
 593         if(APPLE)
 594                 target_link_libraries(
 595                         ${client_LIBS}
 596                         ${ICONV_LIBRARY}
 597                 )
 598         else()
 599                 target_link_libraries(
 600                         ${client_LIBS}
 601                 )
 602         endif()
 603         if(USE_CURL)
 604                 target_link_libraries(
 605                         ${PROJECT_NAME}
 606                         ${CURL_LIBRARY}
 607                 )
 608         endif()
 609         if(USE_FREETYPE)
 610                 if(FREETYPE_PKGCONFIG_FOUND)
 611                         set_target_properties(${PROJECT_NAME}
 612                                 PROPERTIES
 613                                 COMPILE_FLAGS "${FREETYPE_CFLAGS_STR}"
 614                         )
 615                 endif()
 616                 target_link_libraries(
 617                         ${PROJECT_NAME}
 618                         ${FREETYPE_LIBRARY}
 619                 )
 620         endif()
 621         if (USE_CURSES)
 622                 target_link_libraries(${PROJECT_NAME} ${CURSES_LIBRARIES})
 623         endif()
 624         if (USE_POSTGRESQL)
 625                 target_link_libraries(${PROJECT_NAME} ${POSTGRESQL_LIBRARY})
 626         endif()
 627         if (USE_LEVELDB)
 628                 target_link_libraries(${PROJECT_NAME} ${LEVELDB_LIBRARY})
 629         endif()
 630         if (USE_REDIS)
 631                 target_link_libraries(${PROJECT_NAME} ${REDIS_LIBRARY})
 632         endif()
 633         if (USE_SPATIAL)
 634                 target_link_libraries(${PROJECT_NAME} ${SPATIAL_LIBRARY})
 635         endif()
 636 endif(BUILD_CLIENT)
 637
 638
 639 if(BUILD_SERVER)
 640         add_executable(${PROJECT_NAME}server ${server_SRCS})
 641         add_dependencies(${PROJECT_NAME}server GenerateVersion)
 642         target_link_libraries(
 643                 ${PROJECT_NAME}server
 644                 ${ZLIB_LIBRARIES}
 645                 ${SQLITE3_LIBRARY}
 646                 ${JSON_LIBRARY}
 647                 ${GETTEXT_LIBRARY}
 648                 ${LUA_LIBRARY}
 649                 ${GMP_LIBRARY}
 650                 ${PLATFORM_LIBS}
 651         )
 652         set_target_properties(${PROJECT_NAME}server PROPERTIES
 653                         COMPILE_DEFINITIONS "SERVER")
 654         if (USE_CURSES)
 655                 target_link_libraries(${PROJECT_NAME}server ${CURSES_LIBRARIES})
 656         endif()
 657         if (USE_POSTGRESQL)
 658                 target_link_libraries(${PROJECT_NAME}server ${POSTGRESQL_LIBRARY})
 659         endif()
 660         if (USE_LEVELDB)
 661                 target_link_libraries(${PROJECT_NAME}server ${LEVELDB_LIBRARY})
 662         endif()
 663         if (USE_REDIS)
 664                 target_link_libraries(${PROJECT_NAME}server ${REDIS_LIBRARY})
 665         endif()
 666         if (USE_SPATIAL)
 667                 target_link_libraries(${PROJECT_NAME}server ${SPATIAL_LIBRARY})
 668         endif()
 669         if(USE_CURL)
 670                 target_link_libraries(
 671                         ${PROJECT_NAME}server
 672                         ${CURL_LIBRARY}
 673                 )
 674         endif()
 675 endif(BUILD_SERVER)
 676
 677 # Blacklisted locales that don't work.
 678 # see issue #4638
 679 set(GETTEXT_BLACKLISTED_LOCALES
 680         be
 681         he
 682         ko
 683         ky
 684         zh_CN
 685         zh_TW
 686 )
 687
 688 option(APPLY_LOCALE_BLACKLIST "Use a blacklist to avoid broken locales" TRUE)
 689
 690 if (GETTEXT_FOUND AND APPLY_LOCALE_BLACKLIST)
 691         set(GETTEXT_USED_LOCALES "")
 692         foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 693                 if (NOT ";${GETTEXT_BLACKLISTED_LOCALES};" MATCHES ";${LOCALE};")
 694                         list(APPEND GETTEXT_USED_LOCALES ${LOCALE})
 695                 endif()
 696         endforeach()
 697         message(STATUS "Locale blacklist applied; Locales used: ${GETTEXT_USED_LOCALES}")
 698 endif()
 699
 700 # Set some optimizations and tweaks
 701
 702 include(CheckCXXCompilerFlag)
 703
 704 if(MSVC)
 705         # Visual Studio
 706         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /D WIN32_LEAN_AND_MEAN /MP")
 707         # EHa enables SEH exceptions (used for catching segfaults)
 708         set(CMAKE_CXX_FLAGS_RELEASE "/EHa /Ox /GL /FD /MT /GS- /Zi /fp:fast /D NDEBUG /D _HAS_ITERATOR_DEBUGGING=0 /TP")
 709         if(CMAKE_SIZEOF_VOID_P EQUAL 4)
 710                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /arch:SSE")
 711         endif()
 712         #set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /NODEFAULTLIB:\"libcmtd.lib\" /NODEFAULTLIB:\"libcmt.lib\"")
 713         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /INCREMENTAL:NO /DEBUG /OPT:REF /OPT:ICF")
 714
 715
 716         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup")
 717
 718
 719         set(CMAKE_CXX_FLAGS_SEMIDEBUG "/MDd /Zi /Ob0 /O1 /RTC1")
 720
 721         # Debug build doesn't catch exceptions by itself
 722         # Add some optimizations because otherwise it's VERY slow
 723         set(CMAKE_CXX_FLAGS_DEBUG "/MDd /Zi /Ob0 /Od /RTC1")
 724
 725         # Flags for C files (sqlite)
 726         # /MT = Link statically with standard library stuff
 727         set(CMAKE_C_FLAGS_RELEASE "/O2 /Ob2 /MT")
 728 else()
 729         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 730         # Probably GCC
 731         if(APPLE)
 732                 SET(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} -pagezero_size 10000 -image_base 100000000" )
 733         endif()
 734         if(WARN_ALL)
 735                 set(RELEASE_WARNING_FLAGS "-Wall")
 736         else()
 737                 set(RELEASE_WARNING_FLAGS "")
 738         endif()
 739
 740         if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 741                 # clang does not understand __extern_always_inline but libc headers use it
 742                 set(OTHER_FLAGS "${OTHER_FLAGS} \"-D__extern_always_inline=extern __always_inline\"")
 743                 set(OTHER_FLAGS "${OTHER_FLAGS} -Wsign-compare")
 744         endif()
 745
 746         if(WIN32 AND NOT ZLIBWAPI_DLL AND CMAKE_SIZEOF_VOID_P EQUAL 4)
 747                 set(OTHER_FLAGS "${OTHER_FLAGS} -DWIN32_NO_ZLIB_WINAPI")
 748                 message(WARNING "Defaulting to cdecl for zlib on win32 because ZLIBWAPI_DLL"
 749                         " isn't set, ensure that ZLIBWAPI_DLL is set if you want stdcall.")
 750         endif()
 751
 752         if(MINGW)
 753                 set(OTHER_FLAGS "${OTHER_FLAGS} -mthreads -fexceptions")
 754                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DWIN32_LEAN_AND_MEAN")
 755         endif()
 756
 757         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${RELEASE_WARNING_FLAGS} ${WARNING_FLAGS} ${OTHER_FLAGS} -Wall -pipe -funroll-loops")
 758         if(CMAKE_SYSTEM_NAME MATCHES "(Darwin|FreeBSD)")
 759                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Os")
 760         else()
 761                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3 -ffast-math -fomit-frame-pointer")
 762         endif(CMAKE_SYSTEM_NAME MATCHES "(Darwin|FreeBSD)")
 763         set(CMAKE_CXX_FLAGS_SEMIDEBUG "-g -O1 -Wall -Wabi ${WARNING_FLAGS} ${OTHER_FLAGS}")
 764         set(CMAKE_CXX_FLAGS_DEBUG "-g -O0 -Wall -Wabi ${WARNING_FLAGS} ${OTHER_FLAGS}")
 765
 766         if(USE_GPROF)
 767                 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 768         endif()
 769
 770         if(MINGW)
 771                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -mwindows")
 772         endif()
 773 endif()
 774
 775
 776 # Installation
 777
 778 if(WIN32)
 779         if(USE_SOUND)
 780                 if(OPENAL_DLL)
 781                         install(FILES ${OPENAL_DLL} DESTINATION ${BINDIR})
 782                 endif()
 783                 if(OGG_DLL)
 784                         install(FILES ${OGG_DLL} DESTINATION ${BINDIR})
 785                 endif()
 786                 if(VORBIS_DLL)
 787                         install(FILES ${VORBIS_DLL} DESTINATION ${BINDIR})
 788                 endif()
 789                 if(VORBISFILE_DLL)
 790                         install(FILES ${VORBISFILE_DLL} DESTINATION ${BINDIR})
 791                 endif()
 792         endif()
 793         if(CURL_DLL)
 794                 install(FILES ${CURL_DLL} DESTINATION ${BINDIR})
 795         endif()
 796         if(ZLIB_DLL)
 797                 install(FILES ${ZLIB_DLL} DESTINATION ${BINDIR})
 798         endif()
 799         if(ZLIBWAPI_DLL)
 800                 install(FILES ${ZLIBWAPI_DLL} DESTINATION ${BINDIR})
 801         endif()
 802         if(FREETYPE_DLL)
 803                 install(FILES ${FREETYPE_DLL} DESTINATION ${BINDIR})
 804         endif()
 805         if(SQLITE3_DLL)
 806                 install(FILES ${SQLITE3_DLL} DESTINATION ${BINDIR})
 807         endif()
 808         if(LEVELDB_DLL)
 809                 install(FILES ${LEVELDB_DLL} DESTINATION ${BINDIR})
 810         endif()
 811 endif()
 812
 813 if(BUILD_CLIENT)
 814         install(TARGETS ${PROJECT_NAME}
 815                 RUNTIME DESTINATION ${BINDIR}
 816                 LIBRARY DESTINATION ${BINDIR}
 817                 ARCHIVE DESTINATION ${BINDIR}
 818                 BUNDLE DESTINATION .
 819         )
 820
 821         if(APPLE)
 822                 install(CODE "
 823                         set(BU_CHMOD_BUNDLE_ITEMS ON)
 824                         include(BundleUtilities)
 825                         fixup_bundle(\"\${CMAKE_INSTALL_PREFIX}/${BUNDLE_PATH}\" \"\" \"\${CMAKE_INSTALL_PREFIX}/${BINDIR}\")
 826                 " COMPONENT Runtime)
 827         endif()
 828
 829         if(USE_GETTEXT)
 830                 foreach(LOCALE ${GETTEXT_USED_LOCALES})
 831                         set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 832                         set(MO_BUILD_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 833                         install(FILES ${MO_BUILD_PATH} DESTINATION ${MO_DEST_PATH})
 834                 endforeach()
 835         endif()
 836
 837         if(WIN32)
 838                 if(DEFINED IRRLICHT_DLL)
 839                         install(FILES ${IRRLICHT_DLL} DESTINATION ${BINDIR})
 840                 endif()
 841                 if(USE_GETTEXT)
 842                         if(DEFINED GETTEXT_DLL)
 843                                 install(FILES ${GETTEXT_DLL} DESTINATION ${BINDIR})
 844                         endif()
 845                         if(DEFINED GETTEXT_ICONV_DLL)
 846                                 install(FILES ${GETTEXT_ICONV_DLL} DESTINATION ${BINDIR})
 847                         endif()
 848                 endif()
 849         endif()
 850 endif(BUILD_CLIENT)
 851
 852 if(BUILD_SERVER)
 853         install(TARGETS ${PROJECT_NAME}server DESTINATION ${BINDIR})
 854 endif()
 855
 856 if (USE_GETTEXT)
 857         set(MO_FILES)
 858
 859         foreach(LOCALE ${GETTEXT_USED_LOCALES})
 860                 set(PO_FILE_PATH "${GETTEXT_PO_PATH}/${LOCALE}/${PROJECT_NAME}.po")
 861                 set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 862                 set(MO_FILE_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 863
 864                 add_custom_command(OUTPUT ${MO_BUILD_PATH}
 865                         COMMAND ${CMAKE_COMMAND} -E make_directory ${MO_BUILD_PATH}
 866                         COMMENT "mo-update [${LOCALE}]: Creating locale directory.")
 867
 868                 add_custom_command(
 869                         OUTPUT ${MO_FILE_PATH}
 870                         COMMAND ${GETTEXT_MSGFMT} -o ${MO_FILE_PATH} ${PO_FILE_PATH}
 871                         DEPENDS ${MO_BUILD_PATH} ${PO_FILE_PATH}
 872                         WORKING_DIRECTORY "${GETTEXT_PO_PATH}/${LOCALE}"
 873                         COMMENT "mo-update [${LOCALE}]: Creating mo file."
 874                         )
 875
 876                 set(MO_FILES ${MO_FILES} ${MO_FILE_PATH})
 877         endforeach()
 878
 879         add_custom_target(translations ALL COMMENT "mo update" DEPENDS ${MO_FILES})
 880 endif()