src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(minetest)
   4
   5 INCLUDE(CheckIncludeFiles)
   6 INCLUDE(CheckLibraryExists)
   7
   8 # Add custom SemiDebug build mode
   9 set(CMAKE_CXX_FLAGS_SEMIDEBUG "-O1 -g -Wall" CACHE STRING
  10         "Flags used by the C++ compiler during semidebug builds."
  11         FORCE
  12 )
  13 set(CMAKE_C_FLAGS_SEMIDEBUG "-O1 -g -Wall -pedantic" CACHE STRING
  14         "Flags used by the C compiler during semidebug builds."
  15         FORCE
  16 )
  17 mark_as_advanced(
  18         CMAKE_CXX_FLAGS_SEMIDEBUG
  19         CMAKE_C_FLAGS_SEMIDEBUG
  20 )
  21 set(CMAKE_BUILD_TYPE "${CMAKE_BUILD_TYPE}" CACHE STRING
  22         "Choose the type of build. Options are: None Debug SemiDebug RelWithDebInfo MinSizeRel."
  23         FORCE
  24 )
  25
  26
  27 # Set some random things default to not being visible in the GUI
  28 mark_as_advanced(EXECUTABLE_OUTPUT_PATH LIBRARY_OUTPUT_PATH)
  29
  30
  31 if(NOT (BUILD_CLIENT OR BUILD_SERVER))
  32         message(WARNING "Neither BUILD_CLIENT nor BUILD_SERVER is set! Setting BUILD_SERVER=true")
  33         set(BUILD_SERVER TRUE)
  34 endif()
  35
  36
  37 option(ENABLE_CURL "Enable cURL support for fetching media" TRUE)
  38 set(USE_CURL FALSE)
  39
  40 if(ENABLE_CURL)
  41         find_package(CURL)
  42         if (CURL_FOUND)
  43                 message(STATUS "cURL support enabled.")
  44                 set(USE_CURL TRUE)
  45         endif()
  46 else()
  47         mark_as_advanced(CLEAR CURL_LIBRARY CURL_INCLUDE_DIR)
  48 endif()
  49
  50 if(NOT USE_CURL)
  51         if(BUILD_CLIENT)
  52                 message(WARNING "cURL is required to load the server list")
  53         endif()
  54         if(BUILD_SERVER)
  55                 message(WARNING "cURL is required to announce to the server list")
  56         endif()
  57 endif()
  58
  59
  60 option(ENABLE_GETTEXT "Use GetText for internationalization" TRUE)
  61 set(USE_GETTEXT FALSE)
  62
  63 if(ENABLE_GETTEXT)
  64         find_package(GettextLib)
  65         if(GETTEXT_FOUND)
  66                 if(WIN32)
  67                         message(STATUS "GetText library: ${GETTEXT_LIBRARY}")
  68                         message(STATUS "GetText DLL: ${GETTEXT_DLL}")
  69                         message(STATUS "GetText iconv DLL: ${GETTEXT_ICONV_DLL}")
  70                 endif()
  71                 set(USE_GETTEXT TRUE)
  72                 message(STATUS "GetText enabled; locales found: ${GETTEXT_AVAILABLE_LOCALES}")
  73         endif(GETTEXT_FOUND)
  74 else()
  75         mark_as_advanced(GETTEXT_ICONV_DLL GETTEXT_INCLUDE_DIR GETTEXT_LIBRARY GETTEXT_MSGFMT)
  76         message(STATUS "GetText disabled.")
  77 endif()
  78
  79
  80 option(ENABLE_SOUND "Enable sound" TRUE)
  81 set(USE_SOUND FALSE)
  82
  83 if(BUILD_CLIENT AND ENABLE_SOUND)
  84         # Sound libraries
  85         find_package(OpenAL)
  86         find_package(Vorbis)
  87         if(NOT OPENAL_FOUND)
  88                 message(STATUS "Sound enabled, but OpenAL not found!")
  89                 mark_as_advanced(CLEAR OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
  90         endif()
  91         if(NOT VORBIS_FOUND)
  92                 message(STATUS "Sound enabled, but Vorbis libraries not found!")
  93                 mark_as_advanced(CLEAR OGG_INCLUDE_DIR VORBIS_INCLUDE_DIR OGG_LIBRARY VORBIS_LIBRARY VORBISFILE_LIBRARY)
  94         endif()
  95         if(OPENAL_FOUND AND VORBIS_FOUND)
  96                 set(USE_SOUND TRUE)
  97                 message(STATUS "Sound enabled.")
  98         else()
  99                 message(FATAL_ERROR "Sound enabled, but cannot be used.\n"
 100                         "To continue, either fill in the required paths or disable sound. (-DENABLE_SOUND=0)")
 101         endif()
 102 endif()
 103
 104
 105 option(ENABLE_GLES "Use OpenGL ES instead of OpenGL" FALSE)
 106 mark_as_advanced(ENABLE_GLES)
 107 if(BUILD_CLIENT)
 108         if(ENABLE_GLES)
 109                 find_package(OpenGLES2 REQUIRED)
 110         else()
 111                 # transitive dependency from Irrlicht (see longer explanation below)
 112                 if(NOT WIN32)
 113                         set(OPENGL_GL_PREFERENCE "LEGACY" CACHE STRING
 114                                 "See CMake Policy CMP0072 for reference. GLVND is broken on some nvidia setups")
 115                         set(OpenGL_GL_PREFERENCE ${OPENGL_GL_PREFERENCE})
 116
 117                         find_package(OpenGL REQUIRED)
 118                 endif()
 119         endif()
 120 endif()
 121
 122
 123 option(ENABLE_FREETYPE "Enable FreeType2 (TrueType fonts and basic unicode support)" TRUE)
 124 set(USE_FREETYPE FALSE)
 125
 126 if(ENABLE_FREETYPE)
 127 ##
 128 ## Note: FindFreetype.cmake seems to have been fixed in recent versions of
 129 ## CMake. If issues persist, re-enable this workaround specificially for the
 130 ## failing platforms.
 131 ##
 132 #       if(UNIX)
 133 #               include(FindPkgConfig)
 134 #               if(PKG_CONFIG_FOUND)
 135 #                       pkg_check_modules(FREETYPE QUIET freetype2)
 136 #                       if(FREETYPE_FOUND)
 137 #                               SET(FREETYPE_PKGCONFIG_FOUND TRUE)
 138 #                               SET(FREETYPE_LIBRARY ${FREETYPE_LIBRARIES})
 139 #                               # Because CMake is idiotic
 140 #                               string(REPLACE ";" " " FREETYPE_CFLAGS_STR ${FREETYPE_CFLAGS})
 141 #                               string(REPLACE ";" " " FREETYPE_LDFLAGS_STR ${FREETYPE_LDFLAGS})
 142 #                       endif(FREETYPE_FOUND)
 143 #               endif(PKG_CONFIG_FOUND)
 144 #       endif(UNIX)
 145 #       if(NOT FREETYPE_FOUND)
 146 #               find_package(Freetype)
 147 #       endif()
 148         find_package(Freetype)
 149         if(FREETYPE_FOUND)
 150                 message(STATUS "Freetype enabled.")
 151                 set(USE_FREETYPE TRUE)
 152         endif()
 153 endif(ENABLE_FREETYPE)
 154
 155 option(ENABLE_CURSES "Enable ncurses console" TRUE)
 156 set(USE_CURSES FALSE)
 157
 158 if(ENABLE_CURSES)
 159         find_package(Ncursesw)
 160         if(CURSES_FOUND)
 161                 set(USE_CURSES TRUE)
 162                 message(STATUS "ncurses console enabled.")
 163                 include_directories(${CURSES_INCLUDE_DIRS})
 164         else()
 165                 message(STATUS "ncurses not found!")
 166         endif()
 167 endif(ENABLE_CURSES)
 168
 169 option(ENABLE_POSTGRESQL "Enable PostgreSQL backend" TRUE)
 170 set(USE_POSTGRESQL FALSE)
 171
 172 if(ENABLE_POSTGRESQL)
 173         find_package("PostgreSQL")
 174
 175         if(PostgreSQL_FOUND)
 176                 set(USE_POSTGRESQL TRUE)
 177                 message(STATUS "PostgreSQL backend enabled")
 178                 # This variable is case sensitive, don't try to change it to POSTGRESQL_INCLUDE_DIR
 179                 message(STATUS "PostgreSQL includes: ${PostgreSQL_INCLUDE_DIRS}")
 180                 include_directories(${PostgreSQL_INCLUDE_DIRS})
 181         else()
 182                 message(STATUS "PostgreSQL not found!")
 183         endif()
 184 endif(ENABLE_POSTGRESQL)
 185
 186 option(ENABLE_LEVELDB "Enable LevelDB backend" TRUE)
 187 set(USE_LEVELDB FALSE)
 188
 189 if(ENABLE_LEVELDB)
 190         find_library(LEVELDB_LIBRARY NAMES leveldb libleveldb)
 191         find_path(LEVELDB_INCLUDE_DIR db.h PATH_SUFFIXES leveldb)
 192         if(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 193                 set(USE_LEVELDB TRUE)
 194                 message(STATUS "LevelDB backend enabled.")
 195                 include_directories(${LEVELDB_INCLUDE_DIR})
 196         else()
 197                 message(STATUS "LevelDB not found!")
 198         endif()
 199 endif(ENABLE_LEVELDB)
 200
 201
 202 OPTION(ENABLE_REDIS "Enable Redis backend" TRUE)
 203 set(USE_REDIS FALSE)
 204
 205 if(ENABLE_REDIS)
 206         find_library(REDIS_LIBRARY hiredis)
 207         find_path(REDIS_INCLUDE_DIR hiredis.h PATH_SUFFIXES hiredis)
 208         if(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 209                 set(USE_REDIS TRUE)
 210                 message(STATUS "Redis backend enabled.")
 211                 include_directories(${REDIS_INCLUDE_DIR})
 212         else(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 213                 message(STATUS "Redis not found!")
 214         endif(REDIS_LIBRARY AND REDIS_INCLUDE_DIR)
 215 endif(ENABLE_REDIS)
 216
 217
 218 find_package(SQLite3 REQUIRED)
 219
 220 OPTION(ENABLE_SPATIAL "Enable SpatialIndex AreaStore backend" TRUE)
 221 set(USE_SPATIAL FALSE)
 222
 223 if(ENABLE_SPATIAL)
 224         find_library(SPATIAL_LIBRARY spatialindex)
 225         find_path(SPATIAL_INCLUDE_DIR spatialindex/SpatialIndex.h)
 226         if(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 227                 set(USE_SPATIAL TRUE)
 228                 message(STATUS "SpatialIndex AreaStore backend enabled.")
 229                 include_directories(${SPATIAL_INCLUDE_DIR})
 230         else(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 231                 message(STATUS "SpatialIndex not found!")
 232         endif(SPATIAL_LIBRARY AND SPATIAL_INCLUDE_DIR)
 233 endif(ENABLE_SPATIAL)
 234
 235
 236 if(NOT MSVC)
 237         set(USE_GPROF FALSE CACHE BOOL "Use -pg flag for g++")
 238 endif()
 239
 240 # Haiku endian support
 241 if(HAIKU)
 242         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_BSD_SOURCE")
 243         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_BSD_SOURCE")
 244 endif()
 245
 246 # Use cmake_config.h
 247 add_definitions(-DUSE_CMAKE_CONFIG_H)
 248
 249 if(WIN32)
 250         # Windows
 251         if(MSVC) # MSVC Specifics
 252                 set(PLATFORM_LIBS dbghelp.lib ${PLATFORM_LIBS})
 253                 # Surpress some useless warnings
 254                 add_definitions ( /D "_CRT_SECURE_NO_DEPRECATE" /W1 )
 255                 # Get M_PI to work
 256                 add_definitions(/D "_USE_MATH_DEFINES")
 257                 # Dont define min/max macros in minwindef.h
 258                 add_definitions(/D "NOMINMAX")
 259         else() # Probably MinGW = GCC
 260                 set(PLATFORM_LIBS "")
 261         endif()
 262         set(PLATFORM_LIBS ws2_32.lib version.lib shlwapi.lib ${PLATFORM_LIBS})
 263
 264         # Zlib stuff
 265         find_path(ZLIB_INCLUDE_DIR "zlib.h" DOC "Zlib include directory")
 266         find_library(ZLIB_LIBRARIES "zlib" DOC "Path to zlib library")
 267
 268         # Dll's are automatically copied to the output directory by vcpkg when VCPKG_APPLOCAL_DEPS=ON
 269         if(NOT VCPKG_APPLOCAL_DEPS)
 270                 find_file(ZLIB_DLL NAMES "zlib.dll" "zlib1.dll" DOC "Path to zlib.dll for installation (optional)")
 271                 if(ENABLE_SOUND)
 272                         set(OPENAL_DLL "" CACHE FILEPATH "Path to OpenAL32.dll for installation (optional)")
 273                         set(OGG_DLL "" CACHE FILEPATH "Path to libogg.dll for installation (optional)")
 274                         set(VORBIS_DLL "" CACHE FILEPATH "Path to libvorbis.dll for installation (optional)")
 275                         set(VORBISFILE_DLL "" CACHE FILEPATH "Path to libvorbisfile.dll for installation (optional)")
 276                 endif()
 277                 if(USE_LUAJIT)
 278                         set(LUA_DLL "" CACHE FILEPATH "Path to luajit-5.1.dll for installation (optional)")
 279                 endif()
 280         endif()
 281
 282 else()
 283         # Unix probably
 284         if(BUILD_CLIENT)
 285                 if(NOT HAIKU AND NOT APPLE)
 286                         find_package(X11 REQUIRED)
 287                 endif(NOT HAIKU AND NOT APPLE)
 288
 289                 ##
 290                 # The following dependencies are transitive dependencies from Irrlicht.
 291                 # Minetest itself does not use them, but we link them so that statically
 292                 # linking Irrlicht works.
 293                 if(NOT HAIKU AND NOT APPLE)
 294                         # This way Xxf86vm is found on OpenBSD too
 295                         find_library(XXF86VM_LIBRARY Xxf86vm)
 296                         mark_as_advanced(XXF86VM_LIBRARY)
 297                         set(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${XXF86VM_LIBRARY})
 298                 endif(NOT HAIKU AND NOT APPLE)
 299
 300                 find_package(JPEG REQUIRED)
 301                 find_package(BZip2 REQUIRED)
 302                 find_package(PNG REQUIRED)
 303                 if(APPLE)
 304                         find_library(CARBON_LIB Carbon REQUIRED)
 305                         find_library(COCOA_LIB Cocoa REQUIRED)
 306                         find_library(IOKIT_LIB IOKit REQUIRED)
 307                         mark_as_advanced(
 308                                 CARBON_LIB
 309                                 COCOA_LIB
 310                                 IOKIT_LIB
 311                         )
 312                         SET(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${CARBON_LIB} ${COCOA_LIB} ${IOKIT_LIB})
 313                 endif(APPLE)
 314                 ##
 315         endif(BUILD_CLIENT)
 316
 317         find_package(ZLIB REQUIRED)
 318         set(PLATFORM_LIBS -lpthread ${CMAKE_DL_LIBS})
 319         if(APPLE)
 320                 set(PLATFORM_LIBS "-framework CoreFoundation" ${PLATFORM_LIBS})
 321         else()
 322                 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 323                 if (HAVE_LIBRT)
 324                         set(PLATFORM_LIBS -lrt ${PLATFORM_LIBS})
 325                 endif(HAVE_LIBRT)
 326         endif(APPLE)
 327
 328         # Prefer local iconv if installed
 329         find_library(ICONV_LIBRARY iconv)
 330         mark_as_advanced(ICONV_LIBRARY)
 331         if (ICONV_LIBRARY)
 332                 set(PLATFORM_LIBS ${PLATFORM_LIBS} ${ICONV_LIBRARY})
 333         endif()
 334 endif()
 335
 336 check_include_files(endian.h HAVE_ENDIAN_H)
 337
 338 configure_file(
 339         "${PROJECT_SOURCE_DIR}/cmake_config.h.in"
 340         "${PROJECT_BINARY_DIR}/cmake_config.h"
 341 )
 342
 343
 344 # Add a target that always rebuilds cmake_config_githash.h
 345 add_custom_target(GenerateVersion
 346         COMMAND ${CMAKE_COMMAND}
 347         -D "GENERATE_VERSION_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
 348         -D "GENERATE_VERSION_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
 349         -D "VERSION_STRING=${VERSION_STRING}"
 350         -D "DEVELOPMENT_BUILD=${DEVELOPMENT_BUILD}"
 351         -P "${CMAKE_SOURCE_DIR}/cmake/Modules/GenerateVersion.cmake"
 352         WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}")
 353
 354
 355 add_subdirectory(threading)
 356 add_subdirectory(content)
 357 add_subdirectory(database)
 358 add_subdirectory(gui)
 359 add_subdirectory(mapgen)
 360 add_subdirectory(network)
 361 add_subdirectory(script)
 362 add_subdirectory(unittest)
 363 add_subdirectory(util)
 364 add_subdirectory(irrlicht_changes)
 365 add_subdirectory(server)
 366
 367 set(common_SRCS
 368         ${database_SRCS}
 369         ${mapgen_SRCS}
 370         ${server_SRCS}
 371         ${content_SRCS}
 372         ban.cpp
 373         chat.cpp
 374         clientiface.cpp
 375         collision.cpp
 376         content_mapnode.cpp
 377         content_nodemeta.cpp
 378         convert_json.cpp
 379         craftdef.cpp
 380         debug.cpp
 381         defaultsettings.cpp
 382         emerge.cpp
 383         environment.cpp
 384         face_position_cache.cpp
 385         filesys.cpp
 386         gettext.cpp
 387         httpfetch.cpp
 388         hud.cpp
 389         inventory.cpp
 390         inventorymanager.cpp
 391         itemdef.cpp
 392         itemstackmetadata.cpp
 393         light.cpp
 394         log.cpp
 395         main.cpp
 396         map.cpp
 397         map_settings_manager.cpp
 398         mapblock.cpp
 399         mapnode.cpp
 400         mapsector.cpp
 401         metadata.cpp
 402         modchannels.cpp
 403         nameidmapping.cpp
 404         nodedef.cpp
 405         nodemetadata.cpp
 406         nodetimer.cpp
 407         noise.cpp
 408         objdef.cpp
 409         object_properties.cpp
 410         pathfinder.cpp
 411         player.cpp
 412         porting.cpp
 413         profiler.cpp
 414         raycast.cpp
 415         reflowscan.cpp
 416         remoteplayer.cpp
 417         rollback.cpp
 418         rollback_interface.cpp
 419         serialization.cpp
 420         server.cpp
 421         serverenvironment.cpp
 422         serverlist.cpp
 423         settings.cpp
 424         staticobject.cpp
 425         terminal_chat_console.cpp
 426         texture_override.cpp
 427         tileanimation.cpp
 428         tool.cpp
 429         translation.cpp
 430         version.cpp
 431         voxel.cpp
 432         voxelalgorithms.cpp
 433         hud.cpp
 434         ${common_network_SRCS}
 435         ${JTHREAD_SRCS}
 436         ${common_SCRIPT_SRCS}
 437         ${UTIL_SRCS}
 438 )
 439
 440 if(BUILD_UNITTESTS)
 441         set(common_SRCS ${common_SRCS} ${UNITTEST_SRCS})
 442 endif()
 443
 444
 445 # This gives us the icon and file version information
 446 if(WIN32)
 447         set(WINRESOURCE_FILE "${CMAKE_CURRENT_SOURCE_DIR}/../misc/winresource.rc")
 448         set(MINETEST_EXE_MANIFEST_FILE "${CMAKE_CURRENT_SOURCE_DIR}/../misc/minetest.exe.manifest")
 449         if(MINGW)
 450                 if(NOT CMAKE_RC_COMPILER)
 451                         set(CMAKE_RC_COMPILER "windres.exe")
 452                 endif()
 453                 ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 454                         COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR} -I${CMAKE_CURRENT_BINARY_DIR}
 455                         -i${WINRESOURCE_FILE}
 456                         -o ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 457                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 458                         DEPENDS ${WINRESOURCE_FILE} ${MINETEST_EXE_MANIFEST_FILE})
 459                 SET(extra_windows_SRCS ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o)
 460         else(MINGW) # Probably MSVC
 461                 set(extra_windows_SRCS ${WINRESOURCE_FILE} ${MINETEST_EXE_MANIFEST_FILE})
 462         endif(MINGW)
 463 endif()
 464
 465
 466 # Client sources
 467 if (BUILD_CLIENT)
 468         add_subdirectory(client)
 469 endif(BUILD_CLIENT)
 470
 471 set(client_SRCS
 472         ${client_SRCS}
 473         ${common_SRCS}
 474         ${gui_SRCS}
 475         ${client_network_SRCS}
 476         ${client_irrlicht_changes_SRCS}
 477         ${client_SCRIPT_SRCS}
 478 )
 479
 480 if(BUILD_UNITTESTS)
 481         set(client_SRCS ${client_SRCS} ${UNITTEST_CLIENT_SRCS})
 482 endif()
 483
 484 list(SORT client_SRCS)
 485
 486 # Server sources
 487 set(server_SRCS
 488         ${common_SRCS}
 489 )
 490 list(SORT server_SRCS)
 491
 492 # Avoid source_group on broken CMake version.
 493 # see issue #7074 #7075
 494 if (CMAKE_VERSION VERSION_GREATER 3.8.1)
 495         source_group(TREE ${PROJECT_SOURCE_DIR} PREFIX "Source Files" FILES ${client_SRCS})
 496         source_group(TREE ${PROJECT_SOURCE_DIR} PREFIX "Source Files" FILES ${server_SRCS})
 497 endif()
 498
 499 include_directories(
 500         ${PROJECT_BINARY_DIR}
 501         ${PROJECT_SOURCE_DIR}
 502         ${IRRLICHT_INCLUDE_DIR}
 503         ${ZLIB_INCLUDE_DIR}
 504         ${PNG_INCLUDE_DIR}
 505         ${SOUND_INCLUDE_DIRS}
 506         ${SQLITE3_INCLUDE_DIR}
 507         ${LUA_INCLUDE_DIR}
 508         ${GMP_INCLUDE_DIR}
 509         ${JSON_INCLUDE_DIR}
 510         ${X11_INCLUDE_DIR}
 511         ${PROJECT_SOURCE_DIR}/script
 512 )
 513
 514 if(USE_GETTEXT)
 515         include_directories(${GETTEXT_INCLUDE_DIR})
 516 endif()
 517
 518 if(USE_FREETYPE)
 519         include_directories(${FREETYPE_INCLUDE_DIRS})
 520 endif()
 521
 522 if(USE_CURL)
 523         include_directories(${CURL_INCLUDE_DIR})
 524 endif()
 525
 526
 527 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_SOURCE_DIR}/bin")
 528
 529
 530 if(BUILD_CLIENT)
 531         add_executable(${PROJECT_NAME} ${client_SRCS} ${extra_windows_SRCS})
 532         add_dependencies(${PROJECT_NAME} GenerateVersion)
 533         set(client_LIBS
 534                 ${PROJECT_NAME}
 535                 ${ZLIB_LIBRARIES}
 536                 ${IRRLICHT_LIBRARY}
 537                 ${JPEG_LIBRARIES}
 538                 ${BZIP2_LIBRARIES}
 539                 ${PNG_LIBRARIES}
 540                 ${X11_LIBRARIES}
 541                 ${SOUND_LIBRARIES}
 542                 ${SQLITE3_LIBRARY}
 543                 ${LUA_LIBRARY}
 544                 ${GMP_LIBRARY}
 545                 ${JSON_LIBRARY}
 546                 ${PLATFORM_LIBS}
 547                 ${CLIENT_PLATFORM_LIBS}
 548         )
 549         target_link_libraries(
 550                 ${client_LIBS}
 551         )
 552         if(ENABLE_GLES)
 553                 target_link_libraries(
 554                         ${PROJECT_NAME}
 555                         ${OPENGLES2_LIBRARIES}
 556                         ${EGL_LIBRARIES}
 557                 )
 558         else()
 559                 target_link_libraries(
 560                         ${PROJECT_NAME}
 561                         ${OPENGL_LIBRARIES}
 562                 )
 563         endif()
 564         if(USE_GETTEXT)
 565                 target_link_libraries(
 566                         ${PROJECT_NAME}
 567                         ${GETTEXT_LIBRARY}
 568                 )
 569         endif()
 570         if(USE_CURL)
 571                 target_link_libraries(
 572                         ${PROJECT_NAME}
 573                         ${CURL_LIBRARY}
 574                 )
 575         endif()
 576         if(USE_FREETYPE)
 577                 if(FREETYPE_PKGCONFIG_FOUND)
 578                         set_target_properties(${PROJECT_NAME}
 579                                 PROPERTIES
 580                                 COMPILE_FLAGS "${FREETYPE_CFLAGS_STR}"
 581                         )
 582                 endif()
 583                 target_link_libraries(
 584                         ${PROJECT_NAME}
 585                         ${FREETYPE_LIBRARY}
 586                 )
 587         endif()
 588         if (USE_CURSES)
 589                 target_link_libraries(${PROJECT_NAME} ${CURSES_LIBRARIES})
 590         endif()
 591         if (USE_POSTGRESQL)
 592                 target_link_libraries(${PROJECT_NAME} ${PostgreSQL_LIBRARIES})
 593         endif()
 594         if (USE_LEVELDB)
 595                 target_link_libraries(${PROJECT_NAME} ${LEVELDB_LIBRARY})
 596         endif()
 597         if (USE_REDIS)
 598                 target_link_libraries(${PROJECT_NAME} ${REDIS_LIBRARY})
 599         endif()
 600         if (USE_SPATIAL)
 601                 target_link_libraries(${PROJECT_NAME} ${SPATIAL_LIBRARY})
 602         endif()
 603 endif(BUILD_CLIENT)
 604
 605
 606 if(BUILD_SERVER)
 607         add_executable(${PROJECT_NAME}server ${server_SRCS} ${extra_windows_SRCS})
 608         add_dependencies(${PROJECT_NAME}server GenerateVersion)
 609         target_link_libraries(
 610                 ${PROJECT_NAME}server
 611                 ${ZLIB_LIBRARIES}
 612                 ${SQLITE3_LIBRARY}
 613                 ${JSON_LIBRARY}
 614                 ${LUA_LIBRARY}
 615                 ${GMP_LIBRARY}
 616                 ${PLATFORM_LIBS}
 617         )
 618         set_target_properties(${PROJECT_NAME}server PROPERTIES
 619                         COMPILE_DEFINITIONS "SERVER")
 620         if (USE_GETTEXT)
 621                 target_link_libraries(${PROJECT_NAME}server ${GETTEXT_LIBRARY})
 622         endif()
 623         if (USE_CURSES)
 624                 target_link_libraries(${PROJECT_NAME}server ${CURSES_LIBRARIES})
 625         endif()
 626         if (USE_POSTGRESQL)
 627                 target_link_libraries(${PROJECT_NAME}server ${PostgreSQL_LIBRARIES})
 628         endif()
 629         if (USE_LEVELDB)
 630                 target_link_libraries(${PROJECT_NAME}server ${LEVELDB_LIBRARY})
 631         endif()
 632         if (USE_REDIS)
 633                 target_link_libraries(${PROJECT_NAME}server ${REDIS_LIBRARY})
 634         endif()
 635         if (USE_SPATIAL)
 636                 target_link_libraries(${PROJECT_NAME}server ${SPATIAL_LIBRARY})
 637         endif()
 638         if(USE_CURL)
 639                 target_link_libraries(
 640                         ${PROJECT_NAME}server
 641                         ${CURL_LIBRARY}
 642                 )
 643         endif()
 644 endif(BUILD_SERVER)
 645
 646 # Blacklisted locales that don't work.
 647 # see issue #4638
 648 set(GETTEXT_BLACKLISTED_LOCALES
 649         be
 650         he
 651         ko
 652         ky
 653 )
 654
 655 option(APPLY_LOCALE_BLACKLIST "Use a blacklist to avoid broken locales" TRUE)
 656
 657 if (GETTEXT_FOUND AND APPLY_LOCALE_BLACKLIST)
 658         set(GETTEXT_USED_LOCALES "")
 659         foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 660                 if (NOT ";${GETTEXT_BLACKLISTED_LOCALES};" MATCHES ";${LOCALE};")
 661                         list(APPEND GETTEXT_USED_LOCALES ${LOCALE})
 662                 endif()
 663         endforeach()
 664         message(STATUS "Locale blacklist applied; Locales used: ${GETTEXT_USED_LOCALES}")
 665 endif()
 666
 667 # Set some optimizations and tweaks
 668
 669 include(CheckCSourceCompiles)
 670
 671 if(MSVC)
 672         # Visual Studio
 673         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /D WIN32_LEAN_AND_MEAN /MP")
 674         # EHa enables SEH exceptions (used for catching segfaults)
 675         set(CMAKE_CXX_FLAGS_RELEASE "/EHa /Ox /GL /FD /MD /GS- /Zi /fp:fast /D NDEBUG /D _HAS_ITERATOR_DEBUGGING=0 /TP")
 676         if(CMAKE_SIZEOF_VOID_P EQUAL 4)
 677                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /arch:SSE")
 678         endif()
 679
 680         if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 681                 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/INCREMENTAL:NO /DEBUG /OPT:REF /OPT:ICF")
 682         else()
 683                 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /INCREMENTAL:NO /DEBUG /OPT:REF /OPT:ICF")
 684         endif()
 685
 686         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup")
 687
 688
 689         set(CMAKE_CXX_FLAGS_SEMIDEBUG "/MDd /Zi /Ob0 /O1 /RTC1")
 690
 691         # Debug build doesn't catch exceptions by itself
 692         # Add some optimizations because otherwise it's VERY slow
 693         set(CMAKE_CXX_FLAGS_DEBUG "/MDd /Zi /Ob0 /Od /RTC1")
 694
 695         # Flags for C files (sqlite)
 696         # /MD = dynamically link to MSVCRxxx.dll
 697         set(CMAKE_C_FLAGS_RELEASE "/O2 /Ob2 /MD")
 698 else()
 699         # GCC or compatible compilers such as Clang
 700         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 701         if(WARN_ALL)
 702                 set(RELEASE_WARNING_FLAGS "-Wall")
 703         else()
 704                 set(RELEASE_WARNING_FLAGS "")
 705         endif()
 706         if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 707                 set(WARNING_FLAGS "${WARNING_FLAGS} -Wsign-compare")
 708         endif()
 709
 710         if(APPLE AND USE_LUAJIT)
 711                 # required per http://luajit.org/install.html
 712                 SET(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} -pagezero_size 10000 -image_base 100000000")
 713         elseif(UNIX AND USE_LUAJIT)
 714                 check_c_source_compiles("#ifndef __aarch64__\n#error\n#endif\nint main(){}" IS_AARCH64)
 715                 if(IS_AARCH64)
 716                         # Move text segment below LuaJIT's 47-bit limit (see issue #9367)
 717                         SET(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-Ttext-segment=0x200000000")
 718                 endif()
 719         endif()
 720
 721         if(MINGW)
 722                 set(OTHER_FLAGS "${OTHER_FLAGS} -mthreads -fexceptions")
 723                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DWIN32_LEAN_AND_MEAN")
 724         endif()
 725
 726         # Use a safe subset of flags to speed up math calculations:
 727         # - we don't need errno or math exceptions
 728         # - we don't deal with Inf/NaN or signed zero
 729         set(MATH_FLAGS "-fno-math-errno -fno-trapping-math -ffinite-math-only -fno-signed-zeros")
 730
 731         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${RELEASE_WARNING_FLAGS} ${WARNING_FLAGS} ${OTHER_FLAGS} -Wall -pipe -funroll-loops")
 732         if(CMAKE_SYSTEM_NAME MATCHES "(Darwin|BSD|DragonFly)")
 733                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -Os")
 734         else()
 735                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3 -fomit-frame-pointer")
 736                 if(CMAKE_SYSTEM_NAME STREQUAL "Linux"
 737                                 AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang"
 738                                 AND CMAKE_CXX_COMPILER_VERSION MATCHES "^9\\.")
 739                         # Clang 9 has broken -ffast-math on glibc
 740                 else()
 741                         set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${MATH_FLAGS}")
 742                 endif()
 743         endif(CMAKE_SYSTEM_NAME MATCHES "(Darwin|BSD|DragonFly)")
 744         set(CMAKE_CXX_FLAGS_SEMIDEBUG "-g -O1 -Wall ${WARNING_FLAGS} ${OTHER_FLAGS}")
 745         set(CMAKE_CXX_FLAGS_DEBUG "-g -O0 -Wall ${WARNING_FLAGS} ${OTHER_FLAGS}")
 746
 747         if(USE_GPROF)
 748                 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 749         endif()
 750
 751         if(MINGW)
 752                 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -mwindows")
 753         endif()
 754 endif()
 755
 756
 757 # Installation
 758
 759 if(WIN32)
 760         if(VCPKG_APPLOCAL_DEPS)
 761                 # Collect the dll's from the output path
 762                 install(DIRECTORY ${EXECUTABLE_OUTPUT_PATH}/Release/
 763                                 DESTINATION ${BINDIR}
 764                                 CONFIGURATIONS Release
 765                                 FILES_MATCHING PATTERN "*.dll")
 766                 install(DIRECTORY ${EXECUTABLE_OUTPUT_PATH}/Debug/
 767                                 DESTINATION ${BINDIR}
 768                                 CONFIGURATIONS Debug
 769                                 FILES_MATCHING PATTERN "*.dll")
 770                 install(DIRECTORY ${EXECUTABLE_OUTPUT_PATH}/RelWithDebInfo/
 771                                 DESTINATION ${BINDIR}
 772                                 CONFIGURATIONS RelWithDebInfo
 773                                 FILES_MATCHING PATTERN "*.dll")
 774                 install(DIRECTORY ${EXECUTABLE_OUTPUT_PATH}/MinSizeRel/
 775                                 DESTINATION ${BINDIR}
 776                                 CONFIGURATIONS MinSizeRel
 777                                 FILES_MATCHING PATTERN "*.dll")
 778         else()
 779                 # Use the old-style way to install dll's
 780                 if(USE_SOUND)
 781                         if(OPENAL_DLL)
 782                                 install(FILES ${OPENAL_DLL} DESTINATION ${BINDIR})
 783                         endif()
 784                         if(OGG_DLL)
 785                                 install(FILES ${OGG_DLL} DESTINATION ${BINDIR})
 786                         endif()
 787                         if(VORBIS_DLL)
 788                                 install(FILES ${VORBIS_DLL} DESTINATION ${BINDIR})
 789                         endif()
 790                         if(VORBISFILE_DLL)
 791                                 install(FILES ${VORBISFILE_DLL} DESTINATION ${BINDIR})
 792                         endif()
 793                 endif()
 794                 if(CURL_DLL)
 795                         install(FILES ${CURL_DLL} DESTINATION ${BINDIR})
 796                 endif()
 797                 if(ZLIB_DLL)
 798                         install(FILES ${ZLIB_DLL} DESTINATION ${BINDIR})
 799                 endif()
 800                 if(FREETYPE_DLL)
 801                         install(FILES ${FREETYPE_DLL} DESTINATION ${BINDIR})
 802                 endif()
 803                 if(SQLITE3_DLL)
 804                         install(FILES ${SQLITE3_DLL} DESTINATION ${BINDIR})
 805                 endif()
 806                 if(LEVELDB_DLL)
 807                         install(FILES ${LEVELDB_DLL} DESTINATION ${BINDIR})
 808                 endif()
 809                 if(LUA_DLL)
 810                         install(FILES ${LUA_DLL} DESTINATION ${BINDIR})
 811                 endif()
 812         endif()
 813 endif()
 814
 815 if(BUILD_CLIENT)
 816         install(TARGETS ${PROJECT_NAME}
 817                 RUNTIME DESTINATION ${BINDIR}
 818                 LIBRARY DESTINATION ${BINDIR}
 819                 ARCHIVE DESTINATION ${BINDIR}
 820                 BUNDLE DESTINATION .
 821         )
 822
 823         if(APPLE)
 824                 install(CODE "
 825                         set(BU_CHMOD_BUNDLE_ITEMS ON)
 826                         include(BundleUtilities)
 827                         fixup_bundle(\"\${CMAKE_INSTALL_PREFIX}/${BUNDLE_PATH}\" \"\" \"\${CMAKE_INSTALL_PREFIX}/${BINDIR}\")
 828                 " COMPONENT Runtime)
 829         endif()
 830
 831         if(USE_GETTEXT)
 832                 foreach(LOCALE ${GETTEXT_USED_LOCALES})
 833                         set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 834                         set(MO_BUILD_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 835                         install(FILES ${MO_BUILD_PATH} DESTINATION ${MO_DEST_PATH})
 836                 endforeach()
 837         endif()
 838
 839         if(USE_FREETYPE)
 840                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/../fonts" DESTINATION "${SHAREDIR}"
 841                                 FILES_MATCHING PATTERN "*.ttf" PATTERN "*.txt")
 842         else()
 843                 install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/../fonts" DESTINATION "${SHAREDIR}"
 844                                 FILES_MATCHING PATTERN "*.png" PATTERN "*.xml")
 845         endif()
 846
 847         if(WIN32)
 848                 if(NOT VCPKG_APPLOCAL_DEPS)
 849                         if(DEFINED IRRLICHT_DLL)
 850                                 install(FILES ${IRRLICHT_DLL} DESTINATION ${BINDIR})
 851                         endif()
 852                         if(USE_GETTEXT)
 853                                 if(DEFINED GETTEXT_DLL)
 854                                         install(FILES ${GETTEXT_DLL} DESTINATION ${BINDIR})
 855                                 endif()
 856                                 if(DEFINED GETTEXT_ICONV_DLL)
 857                                         install(FILES ${GETTEXT_ICONV_DLL} DESTINATION ${BINDIR})
 858                                 endif()
 859                         endif()
 860                 endif()
 861         endif()
 862 endif(BUILD_CLIENT)
 863
 864 if(BUILD_SERVER)
 865         install(TARGETS ${PROJECT_NAME}server DESTINATION ${BINDIR})
 866 endif()
 867
 868 if (USE_GETTEXT)
 869         set(MO_FILES)
 870
 871         foreach(LOCALE ${GETTEXT_USED_LOCALES})
 872                 set(PO_FILE_PATH "${GETTEXT_PO_PATH}/${LOCALE}/${PROJECT_NAME}.po")
 873                 set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 874                 set(MO_FILE_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 875
 876                 add_custom_command(OUTPUT ${MO_BUILD_PATH}
 877                         COMMAND ${CMAKE_COMMAND} -E make_directory ${MO_BUILD_PATH}
 878                         COMMENT "mo-update [${LOCALE}]: Creating locale directory.")
 879
 880                 add_custom_command(
 881                         OUTPUT ${MO_FILE_PATH}
 882                         COMMAND ${GETTEXT_MSGFMT} -o ${MO_FILE_PATH} ${PO_FILE_PATH}
 883                         DEPENDS ${MO_BUILD_PATH} ${PO_FILE_PATH}
 884                         WORKING_DIRECTORY "${GETTEXT_PO_PATH}/${LOCALE}"
 885                         COMMENT "mo-update [${LOCALE}]: Creating mo file."
 886                         )
 887
 888                 set(MO_FILES ${MO_FILES} ${MO_FILE_PATH})
 889         endforeach()
 890
 891         add_custom_target(translations ALL COMMENT "mo update" DEPENDS ${MO_FILES})
 892 endif()