src/CMakeLists.txt

   1 project(minetest)
   2 cmake_minimum_required( VERSION 2.6 )
   3
   4 # Set some random things default to not being visible in the GUI
   5 mark_as_advanced(EXECUTABLE_OUTPUT_PATH LIBRARY_OUTPUT_PATH)
   6 mark_as_advanced(JTHREAD_INCLUDE_DIR JTHREAD_LIBRARY)
   7 mark_as_advanced(SQLITE3_INCLUDE_DIR SQLITE3_LIBRARY)
   8 mark_as_advanced(JSON_INCLUDE_DIR JSON_LIBRARY)
   9
  10 option(ENABLE_CURL "Enable cURL support for fetching media" 1)
  11
  12 if (NOT ENABLE_CURL)
  13         mark_as_advanced(CLEAR CURL_LIBRARY CURL_INCLUDE_DIR)
  14 endif(NOT ENABLE_CURL)
  15
  16 if( ENABLE_CURL )
  17         find_package(CURL)
  18 endif( ENABLE_CURL )
  19 set(USE_CURL 0)
  20 if (CURL_FOUND AND ENABLE_CURL)
  21         message(STATUS "cURL support enabled")
  22         set(USE_CURL 1)
  23 endif(CURL_FOUND AND ENABLE_CURL)
  24
  25 # user-visible option to enable/disable gettext usage
  26 OPTION(ENABLE_GETTEXT "Use GetText for internationalization" 0)
  27
  28 # this is only set to 1 if gettext is enabled _and_ available
  29 set(USE_GETTEXT 0)
  30
  31 if(ENABLE_GETTEXT)
  32         find_package(GettextLib)
  33 else()
  34         MARK_AS_ADVANCED(GETTEXT_ICONV_DLL GETTEXT_INCLUDE_DIR GETTEXT_LIBRARY GETTEXT_MSGFMT)
  35 endif()
  36
  37 if(GETTEXT_FOUND AND ENABLE_GETTEXT)
  38         message(STATUS "gettext include path: ${GETTEXT_INCLUDE_DIR}")
  39         message(STATUS "gettext msgfmt path: ${GETTEXT_MSGFMT}")
  40         if(WIN32)
  41                 message(STATUS "gettext library: ${GETTEXT_LIBRARY}")
  42                 message(STATUS "gettext dll: ${GETTEXT_DLL}")
  43                 message(STATUS "gettext iconv dll: ${GETTEXT_ICONV_DLL}")
  44         endif()
  45         set(USE_GETTEXT 1)
  46         message(STATUS "GetText enabled; locales found: ${GETTEXT_AVAILABLE_LOCALES}")
  47 elseif(GETTEXT_FOUND AND NOT ENABLE_GETTEXT)
  48         MESSAGE(STATUS "GetText found but disabled;")
  49 else(GETTEXT_FOUND AND ENABLE_GETTEXT)
  50         message(STATUS "GetText disabled")
  51 endif(GETTEXT_FOUND AND ENABLE_GETTEXT)
  52
  53 # user visible option to enable/disable sound
  54 OPTION(ENABLE_SOUND "Enable sound" ON)
  55
  56 # this is only set to 1 if sound is enabled _and_ available
  57 set(USE_SOUND 0)
  58 set(SOUND_PROBLEM 0)
  59
  60 if(ENABLE_SOUND AND BUILD_CLIENT)
  61         # Sound libraries
  62         find_package(OpenAL)
  63         find_package(Vorbis)
  64         if(NOT OPENAL_FOUND)
  65                 message(STATUS "Sound enabled, but OpenAL not found!")
  66                 set(SOUND_PROBLEM 1)
  67                 MARK_AS_ADVANCED(CLEAR OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
  68         endif()
  69         if(NOT VORBIS_FOUND)
  70                 message(STATUS "Sound enabled, but Vorbis libraries not found!")
  71                 set(SOUND_PROBLEM 1)
  72                 MARK_AS_ADVANCED(CLEAR OGG_INCLUDE_DIR VORBIS_INCLUDE_DIR OGG_LIBRARY VORBIS_LIBRARY VORBISFILE_LIBRARY)
  73         endif()
  74         if(OPENAL_FOUND AND VORBIS_FOUND)
  75                 set(USE_SOUND 1)
  76                 message(STATUS "Sound enabled")
  77         endif()
  78 endif(ENABLE_SOUND AND BUILD_CLIENT)
  79
  80 if(SOUND_PROBLEM)
  81         message(FATAL_ERROR "Sound enabled, but cannot be used.\n"
  82                 "To continue, either fill in the required paths or disable sound. (-DENABLE_SOUND=0)")
  83 endif()
  84 if(USE_SOUND)
  85         set(sound_SRCS sound_openal.cpp)
  86         set(SOUND_INCLUDE_DIRS
  87                 ${OPENAL_INCLUDE_DIR}
  88                 ${VORBIS_INCLUDE_DIR}
  89                 ${OGG_INCLUDE_DIR}
  90                 )
  91         set(SOUND_LIBRARIES
  92                 ${OPENAL_LIBRARY}
  93                 ${VORBIS_LIBRARIES}
  94                 )
  95 endif()
  96
  97 option(ENABLE_FREETYPE "Enable freetype2 (truetype fonts and basic unicode support)" OFF)
  98 set(USE_FREETYPE 0)
  99 if(ENABLE_FREETYPE)
 100         set(USE_FREETYPE 1)
 101 endif(ENABLE_FREETYPE)
 102
 103 if(NOT MSVC)
 104         set(USE_GPROF 0 CACHE BOOL "Use -pg flag for g++")
 105 endif()
 106
 107 # Use cmake_config.h
 108 add_definitions ( -DUSE_CMAKE_CONFIG_H )
 109
 110 if(WIN32)
 111         # Windows
 112         if(MSVC) # MSVC Specifics
 113                 # Surpress some useless warnings
 114                 add_definitions ( /D "_CRT_SECURE_NO_DEPRECATE" /W1 )
 115         else() # Probably MinGW = GCC
 116                 set(PLATFORM_LIBS ws2_32.lib)
 117         endif()
 118         # Zlib stuff
 119         set(ZLIB_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/../../zlib/zlib-1.2.5"
 120                         CACHE PATH "Zlib include directory")
 121         set(ZLIB_LIBRARIES "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.lib"
 122                         CACHE FILEPATH "Path to zlibwapi.lib")
 123         set(ZLIB_DLL "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.dll"
 124                         CACHE FILEPATH "Path to zlibwapi.dll (for installation)")
 125         set(IRRLICHT_SOURCE_DIR "${PROJECT_SOURCE_DIR}/../../irrlicht-1.7.2"
 126                         CACHE PATH "irrlicht dir")
 127         if(USE_FREETYPE)
 128                 set(FREETYPE_INCLUDE_DIR_ft2build "${PROJECT_SOURCE_DIR}/../../freetype2/include/"
 129                                 CACHE PATH "freetype include dir")
 130                 set(FREETYPE_INCLUDE_DIR_freetype2 "${PROJECT_SOURCE_DIR}/../../freetype2/include/freetype"
 131                                 CACHE PATH "freetype include dir")
 132                 set(FREETYPE_LIBRARY "${PROJECT_SOURCE_DIR}/../../freetype2/objs/win32/vc2005/freetype247.lib"
 133                                 CACHE FILEPATH "Path to freetype247.lib")
 134         endif(USE_FREETYPE)
 135         set(MINGWM10_DLL ""
 136                         CACHE FILEPATH "Path to mingwm10.dll (for installation)")
 137         if(ENABLE_SOUND)
 138                 set(OPENAL_DLL "" CACHE FILEPATH "Path to OpenAL32.dll for installation (optional)")
 139                 set(OGG_DLL "" CACHE FILEPATH "Path to libogg.dll for installation (optional)")
 140                 set(VORBIS_DLL "" CACHE FILEPATH "Path to libvorbis.dll for installation (optional)")
 141                 set(VORBISFILE_DLL "" CACHE FILEPATH "Path to libvorbisfile.dll for installation (optional)")
 142         endif()
 143 else()
 144         # Unix probably
 145         if(BUILD_CLIENT)
 146                 find_package(X11 REQUIRED)
 147                 find_package(OpenGL REQUIRED)
 148                 find_package(JPEG REQUIRED)
 149                 find_package(BZip2 REQUIRED)
 150                 find_package(PNG REQUIRED)
 151                 if(APPLE)
 152                         FIND_LIBRARY(CARBON_LIB Carbon)
 153                         FIND_LIBRARY(COCOA_LIB Cocoa)
 154                         FIND_LIBRARY(IOKIT_LIB IOKit)
 155                         mark_as_advanced(
 156                                 CARBON_LIB
 157                                 COCOA_LIB
 158                                 IOKIT_LIB
 159                         )
 160                         SET(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${CARBON_LIB} ${COCOA_LIB} ${IOKIT_LIB})
 161                 endif(APPLE)
 162         endif(BUILD_CLIENT)
 163         find_package(ZLIB REQUIRED)
 164         set(PLATFORM_LIBS -lpthread -lrt ${CMAKE_DL_LIBS})
 165         #set(CLIENT_PLATFORM_LIBS -lXxf86vm)
 166         # This way Xxf86vm is found on OpenBSD too
 167         find_library(XXF86VM_LIBRARY Xxf86vm)
 168         mark_as_advanced(XXF86VM_LIBRARY)
 169         set(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${XXF86VM_LIBRARY})
 170 endif()
 171
 172 find_package(Jthread REQUIRED)
 173 find_package(Sqlite3 REQUIRED)
 174 find_package(Json REQUIRED)
 175 find_package(OpenGLES2)
 176
 177 if(USE_FREETYPE)
 178         find_package(Freetype REQUIRED)
 179         set(CGUITTFONT_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cguittfont")
 180         set(CGUITTFONT_LIBRARY cguittfont)
 181 endif(USE_FREETYPE)
 182
 183
 184 find_library(LUA_LIBRARY luajit
 185                 NAMES luajit-5.1)
 186 find_path(LUA_INCLUDE_DIR luajit.h
 187         NAMES luajit.h
 188         PATH_SUFFIXES luajit-2.0)
 189 message (STATUS "LuaJIT library: ${LUA_LIBRARY}")
 190 message (STATUS "LuaJIT headers: ${LUA_INCLUDE_DIR}")
 191
 192 if(LUA_LIBRARY AND LUA_INCLUDE_DIR)
 193         message (STATUS "LuaJIT found.")
 194 else(LUA_LIBRARY AND LUA_INCLUDE_DIR)
 195         message (STATUS "LuaJIT not found, using bundled Lua.")
 196         set(LUA_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/lua/src")
 197         set(LUA_LIBRARY "lua")
 198         add_subdirectory(lua)
 199 endif(LUA_LIBRARY AND LUA_INCLUDE_DIR)
 200
 201 mark_as_advanced(LUA_LIBRARY)
 202 mark_as_advanced(LUA_INCLUDE_DIR)
 203
 204 configure_file(
 205         "${PROJECT_SOURCE_DIR}/cmake_config.h.in"
 206         "${PROJECT_BINARY_DIR}/cmake_config.h"
 207 )
 208
 209 set(common_SRCS
 210         rollback_interface.cpp
 211         rollback.cpp
 212         genericobject.cpp
 213         voxelalgorithms.cpp
 214         sound.cpp
 215         quicktune.cpp
 216         subgame.cpp
 217         inventorymanager.cpp
 218         mods.cpp
 219         content_abm.cpp
 220         craftdef.cpp
 221         nameidmapping.cpp
 222         itemdef.cpp
 223         nodedef.cpp
 224         object_properties.cpp
 225         scriptapi_types.cpp
 226         scriptapi_common.cpp
 227         scriptapi_content.cpp
 228         scriptapi_craft.cpp
 229         scriptapi_node.cpp
 230         scriptapi_item.cpp
 231         scriptapi_env.cpp
 232         scriptapi_nodetimer.cpp
 233         scriptapi_noise.cpp
 234         scriptapi_entity.cpp
 235         scriptapi_object.cpp
 236         scriptapi_nodemeta.cpp
 237         scriptapi_inventory.cpp
 238         scriptapi_particles.cpp
 239         scriptapi.cpp
 240         script.cpp
 241         log.cpp
 242         content_sao.cpp
 243         emerge.cpp
 244         mapgen.cpp
 245         mapgen_v6.cpp
 246         mapgen_v7.cpp
 247         mapgen_indev.cpp
 248         mapgen_singlenode.cpp
 249         treegen.cpp
 250         dungeongen.cpp
 251         content_nodemeta.cpp
 252         content_mapnode.cpp
 253         collision.cpp
 254         nodemetadata.cpp
 255         nodetimer.cpp
 256         serverobject.cpp
 257         noise.cpp
 258         porting.cpp
 259         tool.cpp
 260         defaultsettings.cpp
 261         mapnode.cpp
 262         voxel.cpp
 263         inventory.cpp
 264         debug.cpp
 265         serialization.cpp
 266         light.cpp
 267         filesys.cpp
 268         connection.cpp
 269         environment.cpp
 270         server.cpp
 271         socket.cpp
 272         mapblock.cpp
 273         mapsector.cpp
 274         map.cpp
 275         player.cpp
 276         test.cpp
 277         sha1.cpp
 278         base64.cpp
 279         ban.cpp
 280         biome.cpp
 281         clientserver.cpp
 282         staticobject.cpp
 283         serverlist.cpp
 284         pathfinder.cpp
 285         util/serialize.cpp
 286         util/directiontables.cpp
 287         util/numeric.cpp
 288         util/pointedthing.cpp
 289         util/string.cpp
 290         util/timetaker.cpp
 291 )
 292
 293 # This gives us the icon
 294 if(WIN32)
 295         set(WINRESOURCE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/../misc/winresource.rc)
 296         if(MINGW)
 297                 if(NOT CMAKE_RC_COMPILER)
 298                         set(CMAKE_RC_COMPILER "windres.exe")
 299                 endif()
 300                 ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 301                         COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR}
 302                         -i${WINRESOURCE_FILE}
 303                         -o ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 304                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
 305                 SET(common_SRCS ${common_SRCS} ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o)
 306         else(MINGW) # Probably MSVC
 307                 set(common_SRCS ${common_SRCS} ${WINRESOURCE_FILE})
 308         endif(MINGW)
 309 endif()
 310
 311 # Client sources
 312 set(minetest_SRCS
 313         ${common_SRCS}
 314         ${sound_SRCS}
 315         localplayer.cpp
 316         sky.cpp
 317         clientmap.cpp
 318         content_cso.cpp
 319         content_mapblock.cpp
 320         content_cao.cpp
 321         mesh.cpp
 322         mapblock_mesh.cpp
 323         farmesh.cpp
 324         keycode.cpp
 325         camera.cpp
 326         clouds.cpp
 327         particles.cpp
 328         clientobject.cpp
 329         chat.cpp
 330         hud.cpp
 331         guiMainMenu.cpp
 332         guiKeyChangeMenu.cpp
 333         guiMessageMenu.cpp
 334         guiTextInputMenu.cpp
 335         guiFormSpecMenu.cpp
 336         guiPauseMenu.cpp
 337         guiPasswordChange.cpp
 338         guiVolumeChange.cpp
 339         guiDeathScreen.cpp
 340         guiChatConsole.cpp
 341         guiCreateWorld.cpp
 342         guiConfigureWorld.cpp
 343         guiConfirmMenu.cpp
 344         client.cpp
 345         filecache.cpp
 346         tile.cpp
 347         shader.cpp
 348         game.cpp
 349         main.cpp
 350 )
 351
 352 if(USE_FREETYPE)
 353         set(minetest_SRCS
 354                 ${minetest_SRCS}
 355                 intlGUIEditBox.cpp
 356         )
 357 endif(USE_FREETYPE)
 358
 359 # Server sources
 360 set(minetestserver_SRCS
 361         ${common_SRCS}
 362         main.cpp
 363 )
 364
 365 include_directories(
 366         ${PROJECT_BINARY_DIR}
 367         ${IRRLICHT_INCLUDE_DIR}
 368         ${ZLIB_INCLUDE_DIR}
 369         ${CMAKE_BUILD_TYPE}
 370         ${PNG_INCLUDE_DIR}
 371         ${GETTEXT_INCLUDE_DIR}
 372         ${SOUND_INCLUDE_DIRS}
 373         ${JTHREAD_INCLUDE_DIR}
 374         ${SQLITE3_INCLUDE_DIR}
 375         ${LUA_INCLUDE_DIR}
 376         ${JSON_INCLUDE_DIR}
 377 )
 378
 379 if(USE_FREETYPE)
 380         include_directories(
 381                 ${FREETYPE_INCLUDE_DIRS}
 382                 ${CGUITTFONT_INCLUDE_DIR}
 383         )
 384 endif(USE_FREETYPE)
 385
 386 if(USE_CURL)
 387         include_directories(
 388                 ${CURL_INCLUDE_DIR}
 389         )
 390 endif(USE_CURL)
 391
 392 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_SOURCE_DIR}/bin")
 393
 394 if(BUILD_CLIENT)
 395         add_executable(${PROJECT_NAME} ${minetest_SRCS})
 396         target_link_libraries(
 397                 ${PROJECT_NAME}
 398                 ${ZLIB_LIBRARIES}
 399                 ${IRRLICHT_LIBRARY}
 400                 ${OPENGL_LIBRARIES}
 401                 ${JPEG_LIBRARIES}
 402                 ${BZIP2_LIBRARIES}
 403                 ${PNG_LIBRARIES}
 404                 ${X11_LIBRARIES}
 405                 ${GETTEXT_LIBRARY}
 406                 ${SOUND_LIBRARIES}
 407                 ${JTHREAD_LIBRARY}
 408                 ${SQLITE3_LIBRARY}
 409                 ${LUA_LIBRARY}
 410                 ${JSON_LIBRARY}
 411                 ${OPENGLES2_LIBRARIES}
 412                 ${PLATFORM_LIBS}
 413                 ${CLIENT_PLATFORM_LIBS}
 414         )
 415         if(USE_CURL)
 416                 target_link_libraries(
 417                         ${PROJECT_NAME}
 418                         ${CURL_LIBRARY}
 419                 )
 420         endif(USE_CURL)
 421         if(USE_FREETYPE)
 422                 target_link_libraries(
 423                         ${PROJECT_NAME}
 424                         ${FREETYPE_LIBRARY}
 425                         ${CGUITTFONT_LIBRARY}
 426                 )
 427         endif(USE_FREETYPE)
 428 endif(BUILD_CLIENT)
 429
 430 if(BUILD_SERVER)
 431         add_executable(${PROJECT_NAME}server ${minetestserver_SRCS})
 432         target_link_libraries(
 433                 ${PROJECT_NAME}server
 434                 ${ZLIB_LIBRARIES}
 435                 ${JTHREAD_LIBRARY}
 436                 ${SQLITE3_LIBRARY}
 437                 ${JSON_LIBRARY}
 438                 ${GETTEXT_LIBRARY}
 439                 ${LUA_LIBRARY}
 440                 ${PLATFORM_LIBS}
 441         )
 442         if(USE_CURL)
 443                 target_link_libraries(
 444                         ${PROJECT_NAME}server
 445                         ${CURL_LIBRARY}
 446                 )
 447         endif(USE_CURL)
 448 endif(BUILD_SERVER)
 449
 450
 451 #
 452 # Set some optimizations and tweaks
 453 #
 454
 455 include(CheckCXXCompilerFlag)
 456
 457 if(MSVC)
 458         # Visual Studio
 459
 460         # EHa enables SEH exceptions (used for catching segfaults)
 461         set(CMAKE_CXX_FLAGS_RELEASE "/EHa /O2 /Ob2 /Oi /Ot /Oy /GL /FD /MT /GS- /arch:SSE /fp:fast /D NDEBUG /D _HAS_ITERATOR_DEBUGGING=0 /TP")
 462         #set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /NODEFAULTLIB:\"libcmtd.lib\" /NODEFAULTLIB:\"libcmt.lib\"")
 463         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG")
 464
 465         # Debug build doesn't catch exceptions by itself
 466         # Add some optimizations because otherwise it's VERY slow
 467         set(CMAKE_CXX_FLAGS_DEBUG "/MDd /Zi /Ob0 /Od /RTC1")
 468
 469         # Flags for C files (sqlite)
 470         # /MT = Link statically with standard library stuff
 471         set(CMAKE_C_FLAGS_RELEASE "/O2 /Ob2 /MT")
 472
 473         if(BUILD_SERVER)
 474                 set_target_properties(${PROJECT_NAME}server PROPERTIES
 475                                 COMPILE_DEFINITIONS "SERVER")
 476         endif(BUILD_SERVER)
 477
 478 else()
 479         # Probably GCC
 480
 481         if(WARN_ALL)
 482                 set(RELEASE_WARNING_FLAGS "-Wall")
 483         else()
 484                 set(RELEASE_WARNING_FLAGS "")
 485         endif()
 486
 487         if(NOT APPLE AND NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 488                 CHECK_CXX_COMPILER_FLAG("-Wno-unused-but-set-variable" HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 489                 if(HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 490                         set(WARNING_FLAGS "${WARNING_FLAGS} -Wno-unused-but-set-variable")
 491                 endif(HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 492         endif()
 493
 494         if(MINGW)
 495                 set(OTHER_FLAGS "-mthreads -fexceptions")
 496         endif()
 497
 498         if(APPLE)
 499                 set(CMAKE_OSX_ARCHITECTURES i386 CACHE STRING "do not build for 64-bit" FORCE)
 500                 set(ARCH i386)
 501         endif()
 502
 503         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${RELEASE_WARNING_FLAGS} ${WARNING_FLAGS} ${OTHER_FLAGS} -O3 -ffast-math -Wall -fomit-frame-pointer -pipe -funroll-loops")
 504         set(CMAKE_CXX_FLAGS_DEBUG "-g -O1 -Wall ${WARNING_FLAGS} ${OTHER_FLAGS}")
 505
 506         if(USE_GPROF)
 507                 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 508         endif()
 509
 510         if(BUILD_SERVER)
 511                 set_target_properties(${PROJECT_NAME}server PROPERTIES
 512                                 COMPILE_DEFINITIONS "SERVER")
 513         endif(BUILD_SERVER)
 514
 515 endif()
 516
 517 #MESSAGE(STATUS "CMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}")
 518 #MESSAGE(STATUS "CMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}")
 519
 520 #
 521 # Installation
 522 #
 523 if(WIN32)
 524         if(MINGWM10_DLL)
 525                 install(FILES ${MINGWM10_DLL} DESTINATION ${BINDIR})
 526         endif()
 527         if(DEFINED ZLIB_DLL)
 528                 install(FILES ${ZLIB_DLL} DESTINATION ${BINDIR})
 529         endif()
 530         if(USE_SOUND)
 531                 if(OPENAL_DLL)
 532                         install(FILES ${OPENAL_DLL} DESTINATION ${BINDIR})
 533                 endif()
 534                 if(OGG_DLL)
 535                         install(FILES ${OGG_DLL} DESTINATION ${BINDIR})
 536                 endif()
 537                 if(VORBIS_DLL)
 538                         install(FILES ${VORBIS_DLL} DESTINATION ${BINDIR})
 539                 endif()
 540                 if(VORBISFILE_DLL)
 541                         install(FILES ${VORBISFILE_DLL} DESTINATION ${BINDIR})
 542                 endif()
 543                 if(CURL_DLL)
 544                         install(FILES ${CURL_DLL} DESTINATION ${BINDIR})
 545                 endif()
 546         endif()
 547 endif()
 548
 549 if(BUILD_CLIENT)
 550         install(TARGETS ${PROJECT_NAME} DESTINATION ${BINDIR})
 551
 552         if(USE_GETTEXT)
 553                 foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 554                         set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 555                         set(MO_BUILD_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 556                         install(FILES ${MO_BUILD_PATH} DESTINATION ${MO_DEST_PATH})
 557                 endforeach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 558         endif()
 559
 560         if(WIN32)
 561                 if(DEFINED IRRLICHT_DLL)
 562                         install(FILES ${IRRLICHT_DLL} DESTINATION ${BINDIR})
 563                 endif()
 564                 if(USE_GETTEXT)
 565                         if(DEFINED GETTEXT_DLL)
 566                                 install(FILES ${GETTEXT_DLL} DESTINATION ${BINDIR})
 567                         endif()
 568                         if(DEFINED GETTEXT_ICONV_DLL)
 569                                 install(FILES ${GETTEXT_ICONV_DLL} DESTINATION ${BINDIR})
 570                         endif()
 571                 endif(USE_GETTEXT)
 572         endif()
 573 endif(BUILD_CLIENT)
 574
 575 if(BUILD_SERVER)
 576         install(TARGETS ${PROJECT_NAME}server DESTINATION ${BINDIR})
 577 endif(BUILD_SERVER)
 578
 579 if (USE_GETTEXT)
 580         set(MO_FILES)
 581
 582         foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 583                 set(PO_FILE_PATH "${GETTEXT_PO_PATH}/${LOCALE}/minetest.po")
 584                 set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 585                 set(MO_FILE_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 586
 587                 add_custom_command(OUTPUT ${MO_BUILD_PATH}
 588                         COMMAND ${CMAKE_COMMAND} -E make_directory ${MO_BUILD_PATH}
 589                         COMMENT "mo-update [${LOCALE}]: Creating locale directory.")
 590
 591                 add_custom_command(
 592                         OUTPUT ${MO_FILE_PATH}
 593                         COMMAND ${GETTEXT_MSGFMT} -o ${MO_FILE_PATH} ${PO_FILE_PATH}
 594                         DEPENDS ${MO_BUILD_PATH} ${PO_FILE_PATH}
 595                         WORKING_DIRECTORY "${GETTEXT_PO_PATH}/${LOCALE}"
 596                         COMMENT "mo-update [${LOCALE}]: Creating mo file."
 597                         )
 598
 599                 set(MO_FILES ${MO_FILES} ${MO_FILE_PATH})
 600         endforeach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 601
 602         add_custom_target(translations ALL COMMENT "mo update" DEPENDS ${MO_FILES})
 603 endif(USE_GETTEXT)
 604
 605 # Subdirectories
 606
 607 if (JTHREAD_FOUND)
 608 else (JTHREAD_FOUND)
 609         add_subdirectory(jthread)
 610 endif (JTHREAD_FOUND)
 611
 612 if (SQLITE3_FOUND)
 613 else (SQLITE3_FOUND)
 614         add_subdirectory(sqlite)
 615 endif (SQLITE3_FOUND)
 616
 617 if (BUILD_CLIENT AND USE_FREETYPE)
 618         add_subdirectory(cguittfont)
 619 endif (BUILD_CLIENT AND USE_FREETYPE)
 620
 621 if (JSON_FOUND)
 622 else (JSON_FOUND)
 623         add_subdirectory(json)
 624 endif (JSON_FOUND)
 625
 626 #end