src/CMakeLists.txt

   1 project(minetest)
   2 cmake_minimum_required( VERSION 2.6 )
   3
   4 INCLUDE(CheckCSourceRuns)
   5
   6 # Set some random things default to not being visible in the GUI
   7 mark_as_advanced(EXECUTABLE_OUTPUT_PATH LIBRARY_OUTPUT_PATH)
   8 mark_as_advanced(SQLITE3_INCLUDE_DIR SQLITE3_LIBRARY)
   9 mark_as_advanced(JSON_INCLUDE_DIR JSON_LIBRARY)
  10
  11 option(ENABLE_CURL "Enable cURL support for fetching media" 1)
  12
  13 if (NOT ENABLE_CURL)
  14         mark_as_advanced(CLEAR CURL_LIBRARY CURL_INCLUDE_DIR)
  15 endif(NOT ENABLE_CURL)
  16
  17 if( ENABLE_CURL )
  18         find_package(CURL)
  19 endif( ENABLE_CURL )
  20 set(USE_CURL 0)
  21 if (CURL_FOUND AND ENABLE_CURL)
  22         message(STATUS "cURL support enabled")
  23         set(USE_CURL 1)
  24 endif(CURL_FOUND AND ENABLE_CURL)
  25
  26 # user-visible option to enable/disable gettext usage
  27 OPTION(ENABLE_GETTEXT "Use GetText for internationalization" 0)
  28
  29 # this is only set to 1 if gettext is enabled _and_ available
  30 set(USE_GETTEXT 0)
  31
  32 if(ENABLE_GETTEXT)
  33         find_package(GettextLib)
  34 else()
  35         MARK_AS_ADVANCED(GETTEXT_ICONV_DLL GETTEXT_INCLUDE_DIR GETTEXT_LIBRARY GETTEXT_MSGFMT)
  36 endif()
  37
  38 if(GETTEXT_FOUND AND ENABLE_GETTEXT)
  39         message(STATUS "gettext include path: ${GETTEXT_INCLUDE_DIR}")
  40         message(STATUS "gettext msgfmt path: ${GETTEXT_MSGFMT}")
  41         if(WIN32)
  42                 message(STATUS "gettext library: ${GETTEXT_LIBRARY}")
  43                 message(STATUS "gettext dll: ${GETTEXT_DLL}")
  44                 message(STATUS "gettext iconv dll: ${GETTEXT_ICONV_DLL}")
  45         endif()
  46         set(USE_GETTEXT 1)
  47         message(STATUS "GetText enabled; locales found: ${GETTEXT_AVAILABLE_LOCALES}")
  48 elseif(GETTEXT_FOUND AND NOT ENABLE_GETTEXT)
  49         MESSAGE(STATUS "GetText found but disabled;")
  50 else(GETTEXT_FOUND AND ENABLE_GETTEXT)
  51         message(STATUS "GetText disabled")
  52 endif(GETTEXT_FOUND AND ENABLE_GETTEXT)
  53
  54 # user visible option to enable/disable sound
  55 OPTION(ENABLE_SOUND "Enable sound" ON)
  56
  57 # this is only set to 1 if sound is enabled _and_ available
  58 set(USE_SOUND 0)
  59 set(SOUND_PROBLEM 0)
  60
  61 if(ENABLE_SOUND AND BUILD_CLIENT)
  62         # Sound libraries
  63         find_package(OpenAL)
  64         find_package(Vorbis)
  65         if(NOT OPENAL_FOUND)
  66                 message(STATUS "Sound enabled, but OpenAL not found!")
  67                 set(SOUND_PROBLEM 1)
  68                 MARK_AS_ADVANCED(CLEAR OPENAL_LIBRARY OPENAL_INCLUDE_DIR)
  69         endif()
  70         if(NOT VORBIS_FOUND)
  71                 message(STATUS "Sound enabled, but Vorbis libraries not found!")
  72                 set(SOUND_PROBLEM 1)
  73                 MARK_AS_ADVANCED(CLEAR OGG_INCLUDE_DIR VORBIS_INCLUDE_DIR OGG_LIBRARY VORBIS_LIBRARY VORBISFILE_LIBRARY)
  74         endif()
  75         if(OPENAL_FOUND AND VORBIS_FOUND)
  76                 set(USE_SOUND 1)
  77                 message(STATUS "Sound enabled")
  78         endif()
  79 endif(ENABLE_SOUND AND BUILD_CLIENT)
  80
  81 if(SOUND_PROBLEM)
  82         message(FATAL_ERROR "Sound enabled, but cannot be used.\n"
  83                 "To continue, either fill in the required paths or disable sound. (-DENABLE_SOUND=0)")
  84 endif()
  85 if(USE_SOUND)
  86         set(sound_SRCS sound_openal.cpp)
  87         set(SOUND_INCLUDE_DIRS
  88                 ${OPENAL_INCLUDE_DIR}
  89                 ${VORBIS_INCLUDE_DIR}
  90                 ${OGG_INCLUDE_DIR}
  91                 )
  92         set(SOUND_LIBRARIES
  93                 ${OPENAL_LIBRARY}
  94                 ${VORBIS_LIBRARIES}
  95                 )
  96 endif()
  97
  98 option(ENABLE_FREETYPE "Enable freetype2 (truetype fonts and basic unicode support)" OFF)
  99 set(USE_FREETYPE 0)
 100 if(ENABLE_FREETYPE)
 101         set(USE_FREETYPE 1)
 102 endif(ENABLE_FREETYPE)
 103
 104 if(NOT MSVC)
 105         set(USE_GPROF 0 CACHE BOOL "Use -pg flag for g++")
 106 endif()
 107
 108 # Use cmake_config.h
 109 add_definitions ( -DUSE_CMAKE_CONFIG_H )
 110
 111 if(WIN32)
 112         # Windows
 113         if(MSVC) # MSVC Specifics
 114                 # Surpress some useless warnings
 115                 add_definitions ( /D "_CRT_SECURE_NO_DEPRECATE" /W1 )
 116         else() # Probably MinGW = GCC
 117                 set(PLATFORM_LIBS ws2_32.lib)
 118         endif()
 119         # Zlib stuff
 120         set(ZLIB_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/../../zlib/zlib-1.2.5"
 121                         CACHE PATH "Zlib include directory")
 122         set(ZLIB_LIBRARIES "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.lib"
 123                         CACHE FILEPATH "Path to zlibwapi.lib")
 124         set(ZLIB_DLL "${PROJECT_SOURCE_DIR}/../../zlib125dll/dll32/zlibwapi.dll"
 125                         CACHE FILEPATH "Path to zlibwapi.dll (for installation)")
 126         set(IRRLICHT_SOURCE_DIR "${PROJECT_SOURCE_DIR}/../../irrlicht-1.7.2"
 127                         CACHE PATH "irrlicht dir")
 128         if(USE_FREETYPE)
 129                 set(FREETYPE_INCLUDE_DIR_ft2build "${PROJECT_SOURCE_DIR}/../../freetype2/include/"
 130                                 CACHE PATH "freetype include dir")
 131                 set(FREETYPE_INCLUDE_DIR_freetype2 "${PROJECT_SOURCE_DIR}/../../freetype2/include/freetype"
 132                                 CACHE PATH "freetype include dir")
 133                 set(FREETYPE_LIBRARY "${PROJECT_SOURCE_DIR}/../../freetype2/objs/win32/vc2005/freetype247.lib"
 134                                 CACHE FILEPATH "Path to freetype247.lib")
 135         endif(USE_FREETYPE)
 136         set(MINGWM10_DLL ""
 137                         CACHE FILEPATH "Path to mingwm10.dll (for installation)")
 138         if(ENABLE_SOUND)
 139                 set(OPENAL_DLL "" CACHE FILEPATH "Path to OpenAL32.dll for installation (optional)")
 140                 set(OGG_DLL "" CACHE FILEPATH "Path to libogg.dll for installation (optional)")
 141                 set(VORBIS_DLL "" CACHE FILEPATH "Path to libvorbis.dll for installation (optional)")
 142                 set(VORBISFILE_DLL "" CACHE FILEPATH "Path to libvorbisfile.dll for installation (optional)")
 143         endif()
 144 else()
 145         # Unix probably
 146         if(BUILD_CLIENT)
 147                 find_package(X11 REQUIRED)
 148                 find_package(OpenGL REQUIRED)
 149                 find_package(JPEG REQUIRED)
 150                 find_package(BZip2 REQUIRED)
 151                 find_package(PNG REQUIRED)
 152                 if(APPLE)
 153                         FIND_LIBRARY(CARBON_LIB Carbon)
 154                         FIND_LIBRARY(COCOA_LIB Cocoa)
 155                         FIND_LIBRARY(IOKIT_LIB IOKit)
 156                         mark_as_advanced(
 157                                 CARBON_LIB
 158                                 COCOA_LIB
 159                                 IOKIT_LIB
 160                         )
 161                         SET(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${CARBON_LIB} ${COCOA_LIB} ${IOKIT_LIB})
 162                 endif(APPLE)
 163         endif(BUILD_CLIENT)
 164         find_package(ZLIB REQUIRED)
 165         set(PLATFORM_LIBS -lpthread -lrt ${CMAKE_DL_LIBS})
 166         #set(CLIENT_PLATFORM_LIBS -lXxf86vm)
 167         # This way Xxf86vm is found on OpenBSD too
 168         find_library(XXF86VM_LIBRARY Xxf86vm)
 169         mark_as_advanced(XXF86VM_LIBRARY)
 170         set(CLIENT_PLATFORM_LIBS ${CLIENT_PLATFORM_LIBS} ${XXF86VM_LIBRARY})
 171 endif()
 172
 173 find_package(Sqlite3 REQUIRED)
 174 find_package(Json REQUIRED)
 175
 176 option(ENABLE_GLES "Enable OpenGL ES support" 0)
 177 mark_as_advanced(ENABLE_GLES)
 178 if(ENABLE_GLES)
 179         find_package(OpenGLES2)
 180 endif(ENABLE_GLES)
 181
 182 if(USE_FREETYPE)
 183         if(UNIX)
 184                 include(FindPkgConfig)
 185                 if(PKG_CONFIG_FOUND)
 186                         pkg_check_modules(FREETYPE QUIET freetype2)
 187                         if(FREETYPE_FOUND)
 188                                 SET(FREETYPE_PKGCONFIG_FOUND TRUE)
 189                                 SET(FREETYPE_LIBRARY ${FREETYPE_LIBRARIES})
 190                                 # because cmake is idiotic
 191                                 string(REPLACE ";" " " FREETYPE_CFLAGS_STR ${FREETYPE_CFLAGS})
 192                                 string(REPLACE ";" " " FREETYPE_LDFLAGS_STR ${FREETYPE_LDFLAGS})
 193                         endif(FREETYPE_FOUND)
 194                 endif(PKG_CONFIG_FOUND)
 195         endif(UNIX)
 196         if(NOT FREETYPE_FOUND)
 197                 find_package(Freetype REQUIRED)
 198         endif(NOT FREETYPE_FOUND)
 199         set(CGUITTFONT_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cguittfont")
 200         set(CGUITTFONT_LIBRARY cguittfont)
 201 endif(USE_FREETYPE)
 202
 203 if (NOT DISABLE_LUAJIT)
 204         find_library(LUA_LIBRARY luajit
 205                         NAMES luajit-5.1)
 206         find_path(LUA_INCLUDE_DIR luajit.h
 207                 NAMES luajit.h
 208                 PATH_SUFFIXES luajit-2.0)
 209         message (STATUS "LuaJIT library: ${LUA_LIBRARY}")
 210         message (STATUS "LuaJIT headers: ${LUA_INCLUDE_DIR}")
 211 else (NOT ${DISABLE_LUAJIT} MATCHES "1")
 212         message (STATUS "LuaJIT detection disabled! (DISABLE_LUAJIT=1)")
 213         set(LUA_LIBRARY "")
 214         set(LUA_INCLUDE_DIR "")
 215 endif (NOT DISABLE_LUAJIT)
 216
 217 set(USE_LUAJIT 0)
 218 if(LUA_LIBRARY AND LUA_INCLUDE_DIR)
 219         message (STATUS "LuaJIT found, checking for broken versions...")
 220         if(CMAKE_CROSSCOMPILING)
 221                 message(WARNING "Cross-compiling enabled, assuming LuaJIT is not broken")
 222                 set(VALID_LUAJIT_VERSION 1)
 223         else(CMAKE_CROSSCOMPILING)
 224                 set(BACKUP_REQUIRED_INCS CMAKE_REQUIRED_INCLUDES)
 225                 set(CMAKE_REQUIRED_INCLUDES "${CMAKE_REQUIRED_INCLUDES} ${LUA_INCLUDE_DIR}")
 226                 CHECK_C_SOURCE_RUNS("
 227                         #include <luajit.h>
 228                         #include <stdio.h>
 229                         #include <string.h>
 230
 231                         #define ARRAYSIZE(a) (sizeof(a) / sizeof((a)[0]))
 232
 233                         static char *broken_luajit_versions[] = {
 234                                         \"LuaJIT 2.0.0-beta7\",
 235                                         \"LuaJIT 2.0.0-beta6\",
 236                                         \"LuaJIT 2.0.0-beta5\",
 237                                         \"LuaJIT 2.0.0-beta4\",
 238                                         \"LuaJIT 2.0.0-beta3\",
 239                                         \"LuaJIT 2.0.0-beta2\",
 240                                         \"LuaJIT 2.0.0-beta1\"
 241                         };
 242
 243                         int main(int argc, char *argv[]) {
 244                                 unsigned int i;
 245                                 for (i = 0; i < ARRAYSIZE(broken_luajit_versions); i++) {
 246                                         if (strcmp(LUAJIT_VERSION, broken_luajit_versions[i]) == 0) {
 247                                                 return 1;
 248                                         }
 249                                 }
 250                                 return 0;
 251                         }
 252                         "
 253                         VALID_LUAJIT_VERSION)
 254                 set(CMAKE_REQUIRED_INCLUDES BACKUP_REQUIRED_INCS)
 255         endif(CMAKE_CROSSCOMPILING)
 256         if (VALID_LUAJIT_VERSION)
 257                 message (STATUS "LuaJIT version ok")
 258                 set(USE_LUAJIT 1)
 259         else (VALID_LUAJIT_VERSION)
 260                 message (STATUS "LuaJIT versions till 2.0.0beta7 known to be broken, update to at least beta8")
 261                 set(USE_LUAJIT 0)
 262         endif (VALID_LUAJIT_VERSION)
 263 endif (LUA_LIBRARY AND LUA_INCLUDE_DIR)
 264
 265 if(NOT USE_LUAJIT)
 266         message (STATUS "LuaJIT not found, using bundled Lua.")
 267         set(LUA_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/lua/src")
 268         set(LUA_LIBRARY "lua")
 269         add_subdirectory(lua)
 270 endif(NOT USE_LUAJIT)
 271
 272 mark_as_advanced(LUA_LIBRARY)
 273 mark_as_advanced(LUA_INCLUDE_DIR)
 274
 275 set(USE_LEVELDB 0)
 276
 277 OPTION(ENABLE_LEVELDB "Enable LevelDB backend")
 278
 279 if(ENABLE_LEVELDB)
 280         find_library(LEVELDB_LIBRARY leveldb)
 281         find_path(LEVELDB_INCLUDE_DIR db.h PATH_SUFFIXES leveldb)
 282         message (STATUS "LevelDB library: ${LEVELDB_LIBRARY}")
 283         message (STATUS "LevelDB headers: ${LEVELDB_INCLUDE_DIR}")
 284         if(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 285                 set(USE_LEVELDB 1)
 286                 message(STATUS "LevelDB backend enabled")
 287                 include_directories(${LEVELDB_INCLUDE_DIR})
 288         else(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 289                 set(USE_LEVELDB 0)
 290                 message(STATUS "LevelDB not found!")
 291         endif(LEVELDB_LIBRARY AND LEVELDB_INCLUDE_DIR)
 292 endif(ENABLE_LEVELDB)
 293
 294 configure_file(
 295         "${PROJECT_SOURCE_DIR}/cmake_config.h.in"
 296         "${PROJECT_BINARY_DIR}/cmake_config.h"
 297 )
 298
 299 # Add a target that always rebuilds cmake_config_githash.h
 300 add_custom_target(GenerateVersion
 301         COMMAND ${CMAKE_COMMAND}
 302         -D "GENERATE_VERSION_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
 303         -D "GENERATE_VERSION_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
 304         -D "VERSION_STRING=${VERSION_STRING}"
 305         -D "VERSION_EXTRA=${VERSION_EXTRA}"
 306         -P "${CMAKE_SOURCE_DIR}/cmake/Modules/GenerateVersion.cmake"
 307         WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}")
 308
 309 add_subdirectory(jthread)
 310 add_subdirectory(script)
 311 add_subdirectory(util)
 312
 313 set(common_SRCS
 314         version.cpp
 315         rollback_interface.cpp
 316         rollback.cpp
 317         genericobject.cpp
 318         voxelalgorithms.cpp
 319         sound.cpp
 320         quicktune.cpp
 321         subgame.cpp
 322         inventorymanager.cpp
 323         mods.cpp
 324         content_abm.cpp
 325         craftdef.cpp
 326         nameidmapping.cpp
 327         itemdef.cpp
 328         nodedef.cpp
 329         object_properties.cpp
 330         log.cpp
 331         content_sao.cpp
 332         emerge.cpp
 333         mapgen.cpp
 334         mapgen_v6.cpp
 335         mapgen_v7.cpp
 336         mapgen_indev.cpp
 337         mapgen_singlenode.cpp
 338         mapgen_math.cpp
 339         treegen.cpp
 340         dungeongen.cpp
 341         cavegen.cpp
 342         content_nodemeta.cpp
 343         content_mapnode.cpp
 344         collision.cpp
 345         nodemetadata.cpp
 346         nodetimer.cpp
 347         serverobject.cpp
 348         noise.cpp
 349         porting.cpp
 350         tool.cpp
 351         defaultsettings.cpp
 352         mapnode.cpp
 353         voxel.cpp
 354         inventory.cpp
 355         debug.cpp
 356         serialization.cpp
 357         light.cpp
 358         filesys.cpp
 359         connection.cpp
 360         environment.cpp
 361         server.cpp
 362         clientiface.cpp
 363         socket.cpp
 364         mapblock.cpp
 365         mapsector.cpp
 366         map.cpp
 367         database.cpp
 368         database-dummy.cpp
 369         database-leveldb.cpp
 370         database-sqlite3.cpp
 371         player.cpp
 372         test.cpp
 373         sha1.cpp
 374         base64.cpp
 375         ban.cpp
 376         biome.cpp
 377         staticobject.cpp
 378         serverlist.cpp
 379         pathfinder.cpp
 380         convert_json.cpp
 381         gettext.cpp
 382         httpfetch.cpp
 383         ${JTHREAD_SRCS}
 384         ${common_SCRIPT_SRCS}
 385         ${UTIL_SRCS}
 386 )
 387
 388 # This gives us the icon and file version information
 389 if(WIN32)
 390         set(WINRESOURCE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/../misc/winresource.rc)
 391         if(MINGW)
 392                 if(NOT CMAKE_RC_COMPILER)
 393                         set(CMAKE_RC_COMPILER "windres.exe")
 394                 endif()
 395                 ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 396                         COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR}
 397                         -i${WINRESOURCE_FILE}
 398                         -o ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o
 399                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 400                         DEPENDS ${WINRESOURCE_FILE})
 401                 SET(common_SRCS ${common_SRCS} ${CMAKE_CURRENT_BINARY_DIR}/winresource_rc.o)
 402         else(MINGW) # Probably MSVC
 403                 set(common_SRCS ${common_SRCS} ${WINRESOURCE_FILE})
 404         endif(MINGW)
 405 endif()
 406
 407 # Client sources
 408 set(minetest_SRCS
 409         ${common_SRCS}
 410         ${sound_SRCS}
 411         localplayer.cpp
 412         sky.cpp
 413         clientmap.cpp
 414         content_cso.cpp
 415         content_mapblock.cpp
 416         content_cao.cpp
 417         mesh.cpp
 418         mapblock_mesh.cpp
 419         keycode.cpp
 420         camera.cpp
 421         clouds.cpp
 422         particles.cpp
 423         clientobject.cpp
 424         chat.cpp
 425         hud.cpp
 426         guiKeyChangeMenu.cpp
 427         guiMessageMenu.cpp
 428         guiTextInputMenu.cpp
 429         guiFormSpecMenu.cpp
 430         guiTable.cpp
 431         guiPauseMenu.cpp
 432         guiPasswordChange.cpp
 433         guiVolumeChange.cpp
 434         guiDeathScreen.cpp
 435         guiChatConsole.cpp
 436         client.cpp
 437         clientmedia.cpp
 438         filecache.cpp
 439         tile.cpp
 440         shader.cpp
 441         game.cpp
 442         main.cpp
 443         guiEngine.cpp
 444         guiFileSelectMenu.cpp
 445         convert_json.cpp
 446         ${minetest_SCRIPT_SRCS}
 447 )
 448
 449 if(USE_FREETYPE)
 450         set(minetest_SRCS
 451                 ${minetest_SRCS}
 452                 intlGUIEditBox.cpp
 453         )
 454 endif(USE_FREETYPE)
 455
 456 list(SORT minetest_SRCS)
 457
 458 # Server sources
 459 set(minetestserver_SRCS
 460         ${common_SRCS}
 461         main.cpp
 462 )
 463 list(SORT minetestserver_SRCS)
 464
 465 include_directories(
 466         ${PROJECT_BINARY_DIR}
 467         ${PROJECT_SOURCE_DIR}
 468         ${IRRLICHT_INCLUDE_DIR}
 469         ${ZLIB_INCLUDE_DIR}
 470         ${CMAKE_BUILD_TYPE}
 471         ${PNG_INCLUDE_DIR}
 472         ${GETTEXT_INCLUDE_DIR}
 473         ${SOUND_INCLUDE_DIRS}
 474         ${SQLITE3_INCLUDE_DIR}
 475         ${LUA_INCLUDE_DIR}
 476         ${JSON_INCLUDE_DIR}
 477         ${PROJECT_SOURCE_DIR}/script
 478 )
 479
 480 if(USE_FREETYPE)
 481         include_directories(
 482                 ${FREETYPE_INCLUDE_DIRS}
 483                 ${CGUITTFONT_INCLUDE_DIR}
 484         )
 485 endif(USE_FREETYPE)
 486
 487 if(USE_CURL)
 488         include_directories(
 489                 ${CURL_INCLUDE_DIR}
 490         )
 491 endif(USE_CURL)
 492
 493 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_SOURCE_DIR}/bin")
 494
 495 if(BUILD_CLIENT)
 496         add_executable(${PROJECT_NAME} ${minetest_SRCS})
 497         add_dependencies(${PROJECT_NAME} GenerateVersion)
 498         target_link_libraries(
 499                 ${PROJECT_NAME}
 500                 ${ZLIB_LIBRARIES}
 501                 ${IRRLICHT_LIBRARY}
 502                 ${OPENGL_LIBRARIES}
 503                 ${JPEG_LIBRARIES}
 504                 ${BZIP2_LIBRARIES}
 505                 ${PNG_LIBRARIES}
 506                 ${X11_LIBRARIES}
 507                 ${GETTEXT_LIBRARY}
 508                 ${SOUND_LIBRARIES}
 509                 ${SQLITE3_LIBRARY}
 510                 ${LUA_LIBRARY}
 511                 ${JSON_LIBRARY}
 512                 ${OPENGLES2_LIBRARIES}
 513                 ${PLATFORM_LIBS}
 514                 ${CLIENT_PLATFORM_LIBS}
 515         )
 516         if(USE_CURL)
 517                 target_link_libraries(
 518                         ${PROJECT_NAME}
 519                         ${CURL_LIBRARY}
 520                 )
 521         endif(USE_CURL)
 522         if(USE_FREETYPE)
 523                 if(FREETYPE_PKGCONFIG_FOUND)
 524                         set_target_properties(${PROJECT_NAME}
 525                                 PROPERTIES
 526                                 COMPILE_FLAGS "${FREETYPE_CFLAGS_STR}"
 527                         )
 528                 endif(FREETYPE_PKGCONFIG_FOUND)
 529                 target_link_libraries(
 530                         ${PROJECT_NAME}
 531                         ${FREETYPE_LIBRARY}
 532                         ${CGUITTFONT_LIBRARY}
 533                 )
 534         endif(USE_FREETYPE)
 535         if (USE_LEVELDB)
 536                 target_link_libraries(${PROJECT_NAME} ${LEVELDB_LIBRARY})
 537         endif(USE_LEVELDB)
 538 endif(BUILD_CLIENT)
 539
 540 if(BUILD_SERVER)
 541         add_executable(${PROJECT_NAME}server ${minetestserver_SRCS})
 542         add_dependencies(${PROJECT_NAME}server GenerateVersion)
 543         target_link_libraries(
 544                 ${PROJECT_NAME}server
 545                 ${ZLIB_LIBRARIES}
 546                 ${SQLITE3_LIBRARY}
 547                 ${JSON_LIBRARY}
 548                 ${GETTEXT_LIBRARY}
 549                 ${LUA_LIBRARY}
 550                 ${PLATFORM_LIBS}
 551         )
 552         if (USE_LEVELDB)
 553                 target_link_libraries(${PROJECT_NAME}server ${LEVELDB_LIBRARY})
 554         endif(USE_LEVELDB)
 555         if(USE_CURL)
 556                 target_link_libraries(
 557                         ${PROJECT_NAME}server
 558                         ${CURL_LIBRARY}
 559                 )
 560         endif(USE_CURL)
 561 endif(BUILD_SERVER)
 562
 563
 564 #
 565 # Set some optimizations and tweaks
 566 #
 567
 568 include(CheckCXXCompilerFlag)
 569
 570 if(MSVC)
 571         # Visual Studio
 572
 573         # EHa enables SEH exceptions (used for catching segfaults)
 574         set(CMAKE_CXX_FLAGS_RELEASE "/EHa /O2 /Ob2 /Oi /Ot /Oy /GL /FD /MT /GS- /arch:SSE /fp:fast /D NDEBUG /D _HAS_ITERATOR_DEBUGGING=0 /TP")
 575         #set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG /NODEFAULTLIB:\"libcmtd.lib\" /NODEFAULTLIB:\"libcmt.lib\"")
 576         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "/LTCG")
 577
 578         # Debug build doesn't catch exceptions by itself
 579         # Add some optimizations because otherwise it's VERY slow
 580         set(CMAKE_CXX_FLAGS_DEBUG "/MDd /Zi /Ob0 /Od /RTC1")
 581
 582         # Flags for C files (sqlite)
 583         # /MT = Link statically with standard library stuff
 584         set(CMAKE_C_FLAGS_RELEASE "/O2 /Ob2 /MT")
 585
 586         if(BUILD_SERVER)
 587                 set_target_properties(${PROJECT_NAME}server PROPERTIES
 588                                 COMPILE_DEFINITIONS "SERVER")
 589         endif(BUILD_SERVER)
 590
 591 else()
 592         # Probably GCC
 593
 594         if(WARN_ALL)
 595                 set(RELEASE_WARNING_FLAGS "-Wall")
 596         else()
 597                 set(RELEASE_WARNING_FLAGS "")
 598         endif()
 599
 600         if(NOT APPLE AND NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 601                 CHECK_CXX_COMPILER_FLAG("-Wno-unused-but-set-variable" HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 602                 if(HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 603                         set(WARNING_FLAGS "${WARNING_FLAGS} -Wno-unused-but-set-variable")
 604                 endif(HAS_UNUSED_BUT_SET_VARIABLE_WARNING)
 605         endif()
 606
 607         if(MINGW)
 608                 set(OTHER_FLAGS "-mthreads -fexceptions")
 609         endif()
 610
 611         if(APPLE)
 612                 set(CMAKE_OSX_ARCHITECTURES i386 CACHE STRING "do not build for 64-bit" FORCE)
 613                 set(ARCH i386)
 614         endif()
 615
 616         set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${RELEASE_WARNING_FLAGS} ${WARNING_FLAGS} ${OTHER_FLAGS} -O3 -ffast-math -Wall -fomit-frame-pointer -pipe -funroll-loops")
 617         set(CMAKE_CXX_FLAGS_DEBUG "-g -O1 -Wall ${WARNING_FLAGS} ${OTHER_FLAGS}")
 618
 619         if(USE_GPROF)
 620                 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 621         endif()
 622
 623         if(BUILD_SERVER)
 624                 set_target_properties(${PROJECT_NAME}server PROPERTIES
 625                                 COMPILE_DEFINITIONS "SERVER")
 626         endif(BUILD_SERVER)
 627
 628 endif()
 629
 630 #MESSAGE(STATUS "CMAKE_CXX_FLAGS_RELEASE=${CMAKE_CXX_FLAGS_RELEASE}")
 631 #MESSAGE(STATUS "CMAKE_CXX_FLAGS_DEBUG=${CMAKE_CXX_FLAGS_DEBUG}")
 632
 633 #
 634 # Installation
 635 #
 636 if(WIN32)
 637         if(MINGWM10_DLL)
 638                 install(FILES ${MINGWM10_DLL} DESTINATION ${BINDIR})
 639         endif()
 640         if(DEFINED ZLIB_DLL)
 641                 install(FILES ${ZLIB_DLL} DESTINATION ${BINDIR})
 642         endif()
 643         if(USE_SOUND)
 644                 if(OPENAL_DLL)
 645                         install(FILES ${OPENAL_DLL} DESTINATION ${BINDIR})
 646                 endif()
 647                 if(OGG_DLL)
 648                         install(FILES ${OGG_DLL} DESTINATION ${BINDIR})
 649                 endif()
 650                 if(VORBIS_DLL)
 651                         install(FILES ${VORBIS_DLL} DESTINATION ${BINDIR})
 652                 endif()
 653                 if(VORBISFILE_DLL)
 654                         install(FILES ${VORBISFILE_DLL} DESTINATION ${BINDIR})
 655                 endif()
 656         endif()
 657         if(CURL_DLL)
 658                 install(FILES ${CURL_DLL} DESTINATION ${BINDIR})
 659         endif()
 660 endif()
 661
 662 if(BUILD_CLIENT)
 663         install(TARGETS ${PROJECT_NAME} DESTINATION ${BINDIR})
 664
 665         if(USE_GETTEXT)
 666                 foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 667                         set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 668                         set(MO_BUILD_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 669                         install(FILES ${MO_BUILD_PATH} DESTINATION ${MO_DEST_PATH})
 670                 endforeach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 671         endif()
 672
 673         if(WIN32)
 674                 if(DEFINED IRRLICHT_DLL)
 675                         install(FILES ${IRRLICHT_DLL} DESTINATION ${BINDIR})
 676                 endif()
 677                 if(USE_GETTEXT)
 678                         if(DEFINED GETTEXT_DLL)
 679                                 install(FILES ${GETTEXT_DLL} DESTINATION ${BINDIR})
 680                         endif()
 681                         if(DEFINED GETTEXT_ICONV_DLL)
 682                                 install(FILES ${GETTEXT_ICONV_DLL} DESTINATION ${BINDIR})
 683                         endif()
 684                 endif(USE_GETTEXT)
 685         endif()
 686 endif(BUILD_CLIENT)
 687
 688 if(BUILD_SERVER)
 689         install(TARGETS ${PROJECT_NAME}server DESTINATION ${BINDIR})
 690 endif(BUILD_SERVER)
 691
 692 if (USE_GETTEXT)
 693         set(MO_FILES)
 694
 695         foreach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 696                 set(PO_FILE_PATH "${GETTEXT_PO_PATH}/${LOCALE}/minetest.po")
 697                 set_mo_paths(MO_BUILD_PATH MO_DEST_PATH ${LOCALE})
 698                 set(MO_FILE_PATH "${MO_BUILD_PATH}/${PROJECT_NAME}.mo")
 699
 700                 add_custom_command(OUTPUT ${MO_BUILD_PATH}
 701                         COMMAND ${CMAKE_COMMAND} -E make_directory ${MO_BUILD_PATH}
 702                         COMMENT "mo-update [${LOCALE}]: Creating locale directory.")
 703
 704                 add_custom_command(
 705                         OUTPUT ${MO_FILE_PATH}
 706                         COMMAND ${GETTEXT_MSGFMT} -o ${MO_FILE_PATH} ${PO_FILE_PATH}
 707                         DEPENDS ${MO_BUILD_PATH} ${PO_FILE_PATH}
 708                         WORKING_DIRECTORY "${GETTEXT_PO_PATH}/${LOCALE}"
 709                         COMMENT "mo-update [${LOCALE}]: Creating mo file."
 710                         )
 711
 712                 set(MO_FILES ${MO_FILES} ${MO_FILE_PATH})
 713         endforeach(LOCALE ${GETTEXT_AVAILABLE_LOCALES})
 714
 715         add_custom_target(translations ALL COMMENT "mo update" DEPENDS ${MO_FILES})
 716 endif(USE_GETTEXT)
 717
 718 # Subdirectories
 719
 720 if (SQLITE3_FOUND)
 721 else (SQLITE3_FOUND)
 722         add_subdirectory(sqlite)
 723 endif (SQLITE3_FOUND)
 724
 725 if (BUILD_CLIENT AND USE_FREETYPE)
 726         add_subdirectory(cguittfont)
 727 endif (BUILD_CLIENT AND USE_FREETYPE)
 728
 729 if (JSON_FOUND)
 730 else (JSON_FOUND)
 731         add_subdirectory(json)
 732 endif (JSON_FOUND)
 733
 734 #end