makevms.com

   1 $!
   2 $! MAKEVMS.COM
   3 $! Original Author:  UNKNOWN
   4 $! Rewritten By:  Robert Byer
   5 $!                Vice-President
   6 $!                A-Com Computing, Inc.
   7 $!                byer@mail.all-net.net
   8 $!
   9 $! Changes by Richard Levitte <richard@levitte.org>
  10 $!
  11 $! This procedure creates the SSL libraries of "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  12 $! "[.xxx.EXE.SSL]LIBSSL.OLB"
  13 $! The "xxx" denotes the machine architecture of AXP or VAX.
  14 $!
  15 $! This procedures accepts two command line options listed below.
  16 $!
  17 $! Specify one of the following build options for P1.
  18 $!
  19 $!      ALL       Just build "everything".
  20 $!      CONFIG    Just build the "[.CRYPTO]OPENSSLCONF.H" file.
  21 $!      BUILDINF  Just build the "[.CRYPTO]BUILDINF.H" file.
  22 $!      SOFTLINKS Just fix the Unix soft links.
  23 $!      BUILDALL  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done.
  24 $!      CRYPTO    Just build the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  25 $!      CRYPTO/x  Just build the x part of the
  26 $!                "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  27 $!      SSL       Just build the "[.xxx.EXE.SSL]LIBSSL.OLB" library.
  28 $!      SSL_TASK  Just build the "[.xxx.EXE.SSL]SSL_TASK.EXE" program.
  29 $!      TEST      Just build the "[.xxx.EXE.TEST]" test programs for OpenSSL.
  30 $!      APPS      Just build the "[.xxx.EXE.APPS]" application programs for OpenSSL.
  31 $!
  32 $!
  33 $! P2 is ignored (it was used to denote if RSAref should be used or not,
  34 $! and is simply kept so surrounding scripts don't get confused)
  35 $!
  36 $! Speficy DEBUG or NODEBUG as P3 to compile with or without debugging
  37 $! information.
  38 $!
  39 $! Specify which compiler at P4 to try to compile under.
  40 $!
  41 $!        VAXC   For VAX C.
  42 $!        DECC   For DEC C.
  43 $!        GNUC   For GNU C.
  44 $!        LINK   To only link the programs from existing object files.
  45 $!               (not yet implemented)
  46 $!
  47 $! If you don't speficy a compiler, it will try to determine which
  48 $! "C" compiler to use.
  49 $!
  50 $! P5, if defined, sets a TCP/IP library to use, through one of the following
  51 $! keywords:
  52 $!
  53 $!      UCX             for UCX or UCX emulation
  54 $!      TCPIP           for TCP/IP Services or TCP/IP Services emulation
  55 $!                      (this is prefered over UCX)
  56 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  57 $!      NONE            to avoid specifying which TCP/IP implementation to
  58 $!                      use at build time (this works with DEC C).  This is
  59 $!                      the default.
  60 $!
  61 $! P6, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  62 $!
  63 $!
  64 $! Check if we're in a batch job, and make sure we get to
  65 $! the directory this script is in
  66 $!
  67 $ IF F$MODE() .EQS. "BATCH"
  68 $ THEN
  69 $   COMNAME=F$ENVIRONMENT("PROCEDURE")
  70 $   COMPATH=F$PARSE("A.;",COMNAME) - "A.;"
  71 $   SET DEF 'COMPATH'
  72 $ ENDIF
  73 $!
  74 $! Check Which Architecture We Are Using.
  75 $!
  76 $ IF (F$GETSYI("CPU").GE.128)
  77 $ THEN
  78 $!
  79 $!  The Architecture Is AXP.
  80 $!
  81 $   ARCH := AXP
  82 $!
  83 $! Else...
  84 $!
  85 $ ELSE
  86 $!
  87 $!  The Architecture Is VAX.
  88 $!
  89 $   ARCH := VAX
  90 $!
  91 $! End The Architecture Check.
  92 $!
  93 $ ENDIF
  94 $!
  95 $! Check To Make Sure We Have Valid Command Line Parameters.
  96 $!
  97 $ GOSUB CHECK_OPTIONS
  98 $!
  99 $! Check To See What We Are To Do.
 100 $!
 101 $ IF (BUILDCOMMAND.EQS."ALL")
 102 $ THEN
 103 $!
 104 $!  Start with building the OpenSSL configuration file.
 105 $!
 106 $   GOSUB CONFIG
 107 $!
 108 $!  Create The "BUILDINF.H" Include File.
 109 $!
 110 $   GOSUB BUILDINF
 111 $!
 112 $!  Fix The Unix Softlinks.
 113 $!
 114 $   GOSUB SOFTLINKS
 115 $!
 116 $ ENDIF
 117 $!
 118 $ IF (BUILDCOMMAND.EQS."ALL".OR.BUILDCOMMAND.EQS."BUILDALL")
 119 $ THEN
 120 $!
 121 $!  Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 122 $!
 123 $   GOSUB CRYPTO
 124 $!
 125 $!  Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 126 $!
 127 $   GOSUB SSL
 128 $!
 129 $!  Build The [.xxx.EXE.SSL]SSL_TASK.EXE DECNet SSL Engine.
 130 $!
 131 $   GOSUB SSL_TASK
 132 $!
 133 $!  Build The [.xxx.EXE.TEST] OpenSSL Test Utilities.
 134 $!
 135 $   GOSUB TEST
 136 $!
 137 $!  Build The [.xxx.EXE.APPS] OpenSSL Application Utilities.
 138 $!
 139 $   GOSUB APPS
 140 $!
 141 $! Else...
 142 $!
 143 $ ELSE
 144 $!
 145 $!    Build Just What The User Wants Us To Build.
 146 $!
 147 $     GOSUB 'BUILDCOMMAND'
 148 $!
 149 $ ENDIF
 150 $!
 151 $! Time To EXIT.
 152 $!
 153 $ EXIT
 154 $!
 155 $! Rebuild The "[.CRYPTO]OPENSSLCONF.H" file.
 156 $!
 157 $ CONFIG:
 158 $!
 159 $! Tell The User We Are Creating The [.CRYPTO]OPENSSLCONF.H File.
 160 $!
 161 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]OPENSSLCONF.H Include File."
 162 $!
 163 $! Create The [.CRYPTO]OPENSSLCONF.H File.
 164 $!
 165 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]OPENSSLCONF.H
 166 $!
 167 $! Write The [.CRYPTO]OPENSSLCONF.H File.
 168 $!
 169 $ WRITE H_FILE "/* This file was automatically built using makevms.com */"
 170 $ WRITE H_FILE "/* and [.CRYPTO]OPENSSLCONF.H_IN */"
 171 $
 172 $!
 173 $! Write a few macros that indicate how this system was built.
 174 $!
 175 $ WRITE H_FILE ""
 176 $ WRITE H_FILE "#ifndef OPENSSL_SYS_VMS"
 177 $ WRITE H_FILE "# define OPENSSL_SYS_VMS"
 178 $ WRITE H_FILE "#endif"
 179 $ CONFIG_LOGICALS := NO_ASM,NO_RSA,NO_DSA,NO_DH,NO_MD2,NO_MD5,NO_RIPEMD,-
 180         NO_SHA,NO_SHA0,NO_SHA1,NO_DES/NO_MDC2;NO_MDC2,NO_RC2,NO_RC4,NO_RC5,-
 181         NO_IDEA,NO_BF,NO_CAST,NO_HMAC,NO_SSL2
 182 $ CONFIG_LOG_I = 0
 183 $ CONFIG_LOG_LOOP:
 184 $   CONFIG_LOG_E1 = F$ELEMENT(CONFIG_LOG_I,",",CONFIG_LOGICALS)
 185 $   CONFIG_LOG_I = CONFIG_LOG_I + 1
 186 $   IF CONFIG_LOG_E1 .EQS. "" THEN GOTO CONFIG_LOG_LOOP
 187 $   IF CONFIG_LOG_E1 .EQS. "," THEN GOTO CONFIG_LOG_LOOP_END
 188 $   CONFIG_LOG_E2 = F$EDIT(CONFIG_LOG_E1,"TRIM")
 189 $   CONFIG_LOG_E1 = F$ELEMENT(0,";",CONFIG_LOG_E2)
 190 $   CONFIG_LOG_E2 = F$ELEMENT(1,";",CONFIG_LOG_E2)
 191 $   CONFIG_LOG_E0 = F$ELEMENT(0,"/",CONFIG_LOG_E1)
 192 $   CONFIG_LOG_E1 = F$ELEMENT(1,"/",CONFIG_LOG_E1)
 193 $   IF F$TRNLNM("OPENSSL_"+CONFIG_LOG_E0)
 194 $   THEN
 195 $     WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E0
 196 $     WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E0
 197 $     WRITE H_FILE "#endif"
 198 $     IF CONFIG_LOG_E1 .NES. "/"
 199 $     THEN
 200 $       WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E1
 201 $       WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E1
 202 $       WRITE H_FILE "#endif"
 203 $     ENDIF
 204 $   ELSE
 205 $     IF CONFIG_LOG_E2 .NES. ";"
 206 $     THEN
 207 $       IF F$TRNLNM("OPENSSL_"+CONFIG_LOG_E2)
 208 $       THEN
 209 $         WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E2
 210 $         WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E2
 211 $         WRITE H_FILE "#endif"
 212 $       ENDIF
 213 $     ENDIF
 214 $   ENDIF
 215 $   GOTO CONFIG_LOG_LOOP
 216 $ CONFIG_LOG_LOOP_END:
 217 $ WRITE H_FILE "#ifndef OPENSSL_THREADS"
 218 $ WRITE H_FILE "# define OPENSSL_THREADS"
 219 $ WRITE H_FILE "#endif"
 220 $ WRITE H_FILE "#ifndef OPENSSL_NO_KRB5"
 221 $ WRITE H_FILE "# define OPENSSL_NO_KRB5"
 222 $ WRITE H_FILE "#endif"
 223 $ WRITE H_FILE ""
 224 $!
 225 $! Different tar version may have named the file differently
 226 $ IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H_IN") .NES. ""
 227 $ THEN
 228 $   TYPE [.CRYPTO]OPENSSLCONF.H_IN /OUTPUT=H_FILE:
 229 $ ELSE
 230 $   IF F$SEARCH("[.CRYPTO]OPENSSLCONF_H.IN") .NES. ""
 231 $   THEN
 232 $     TYPE [.CRYPTO]OPENSSLCONF_H.IN /OUTPUT=H_FILE:
 233 $   ELSE
 234 $     ! For ODS-5
 235 $     IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H.IN") .NES. ""
 236 $     THEN
 237 $       TYPE [.CRYPTO]OPENSSLCONF.H.IN /OUTPUT=H_FILE:
 238 $     ELSE
 239 $       WRITE SYS$ERROR "Couldn't find a [.CRYPTO]OPENSSLCONF.H_IN.  Exiting!"
 240 $       EXIT 0
 241 $     ENDIF
 242 $   ENDIF
 243 $ ENDIF
 244 $ IF ARCH .EQS. "AXP"
 245 $ THEN
 246 $!
 247 $!  Write the Alpha specific data
 248 $!
 249 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 250 $   WRITE H_FILE "#undef RC4_INT"
 251 $   WRITE H_FILE "#define RC4_INT unsigned int"
 252 $   WRITE H_FILE "#undef RC4_CHUNK"
 253 $   WRITE H_FILE "#define RC4_CHUNK unsigned long long"
 254 $   WRITE H_FILE "#endif"
 255 $!
 256 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 257 $   WRITE H_FILE "#undef DES_LONG"
 258 $   WRITE H_FILE "#define DES_LONG unsigned int"
 259 $   WRITE H_FILE "#undef DES_PTR"
 260 $   WRITE H_FILE "#define DES_PTR"
 261 $   WRITE H_FILE "#undef DES_RISC1"
 262 $   WRITE H_FILE "#undef DES_RISC2"
 263 $   WRITE H_FILE "#define DES_RISC1"
 264 $   WRITE H_FILE "#undef DES_UNROLL"
 265 $   WRITE H_FILE "#define DES_UNROLL"
 266 $   WRITE H_FILE "#endif"
 267 $!
 268 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 269 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 270 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 271 $   WRITE H_FILE "#define SIXTY_FOUR_BIT"
 272 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 273 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 274 $   WRITE H_FILE "#undef EIGHT_BIT"
 275 $   WRITE H_FILE "#endif"
 276 $
 277 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 278 $!
 279 $!  Else...
 280 $!
 281 $ ELSE
 282 $!
 283 $!  Write the VAX specific data
 284 $!
 285 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 286 $   WRITE H_FILE "#undef RC4_INT"
 287 $   WRITE H_FILE "#define RC4_INT unsigned char"
 288 $   WRITE H_FILE "#undef RC4_CHUNK"
 289 $   WRITE H_FILE "#define RC4_CHUNK unsigned long"
 290 $   WRITE H_FILE "#endif"
 291 $!
 292 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 293 $   WRITE H_FILE "#undef DES_LONG"
 294 $   WRITE H_FILE "#define DES_LONG unsigned long"
 295 $   WRITE H_FILE "#undef DES_PTR"
 296 $   WRITE H_FILE "#define DES_PTR"
 297 $   WRITE H_FILE "#undef DES_RISC1"
 298 $   WRITE H_FILE "#undef DES_RISC2"
 299 $   WRITE H_FILE "#undef DES_UNROLL"
 300 $   WRITE H_FILE "#endif"
 301 $!
 302 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 303 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 304 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 305 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 306 $   WRITE H_FILE "#define THIRTY_TWO_BIT"
 307 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 308 $   WRITE H_FILE "#undef EIGHT_BIT"
 309 $   WRITE H_FILE "#endif"
 310 $
 311 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 312 $   WRITE H_FILE "#define OPENSSL_EXPORT_VAR_AS_FUNCTION"
 313 $!
 314 $!  End
 315 $!
 316 $ ENDIF
 317 $!
 318 $! Close the [.CRYPTO]OPENSSLCONF.H file
 319 $!
 320 $ CLOSE H_FILE
 321 $!
 322 $! That's All, Time To RETURN.
 323 $!
 324 $ RETURN
 325 $!
 326 $! Rebuild The "[.CRYPTO]BUILDINF.H" file.
 327 $!
 328 $ BUILDINF:
 329 $!
 330 $! Tell The User We Are Creating The [.CRYPTO]BUILDINF.H File.
 331 $!
 332 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]BUILDINF.H Include File."
 333 $!
 334 $! Create The [.CRYPTO]BUILDINF.H File.
 335 $!
 336 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]BUILDINF.H
 337 $!
 338 $! Get The Current Date & Time.
 339 $!
 340 $ TIME = F$TIME()
 341 $!
 342 $! Write The [.CRYPTO]BUILDINF.H File.
 343 $!
 344 $ WRITE H_FILE "#define CFLAGS """" /* Not filled in for now */"
 345 $ WRITE H_FILE "#define PLATFORM ""VMS"""
 346 $ WRITE H_FILE "#define DATE ""''TIME'"" "
 347 $!
 348 $! Close The [.CRYPTO]BUILDINF.H File.
 349 $!
 350 $ CLOSE H_FILE
 351 $!
 352 $! That's All, Time To RETURN.
 353 $!
 354 $ RETURN
 355 $!
 356 $! Copy a lot of files around.
 357 $!
 358 $ SOFTLINKS:
 359 $!
 360 $! Tell The User We Are Partly Rebuilding The [.APPS] Directory.
 361 $!
 362 $ WRITE SYS$OUTPUT "Rebuilding The '[.APPS]MD4.C', '[.APPS]MD5.C' And '[.APPS]RMD160.C' Files."
 363 $!
 364 $ DELETE SYS$DISK:[.APPS]MD4.C;*,MD5.C;*,RMD160.C;*
 365 $!
 366 $! Copy MD4.C from [.CRYPTO.MD4] into [.APPS]
 367 $!
 368 $ COPY SYS$DISK:[.CRYPTO.MD4]MD4.C SYS$DISK:[.APPS]
 369 $!
 370 $! Copy MD5.C from [.CRYPTO.MD5] into [.APPS]
 371 $!
 372 $ COPY SYS$DISK:[.CRYPTO.MD5]MD5.C SYS$DISK:[.APPS]
 373 $!
 374 $! Copy RMD160.C from [.CRYPTO.RIPEMD] into [.APPS]
 375 $!
 376 $ COPY SYS$DISK:[.CRYPTO.RIPEMD]RMD160.C SYS$DISK:[.APPS]
 377 $!
 378 $! Tell The User We Are Partly Rebuilding The [.TEST] Directory.
 379 $!
 380 $ WRITE SYS$OUTPUT "Rebuilding The '[.TEST]*.C' Files."
 381 $!
 382 $! First, We Have To "Rebuild" The "[.TEST]" Directory, So Delete
 383 $! All The "C" Files That Are Currently There Now.
 384 $!
 385 $ DELETE SYS$DISK:[.TEST]*.C;*
 386 $ DELETE SYS$DISK:[.TEST]EVPTESTS.TXT;*
 387 $!
 388 $! Copy all the *TEST.C files from [.CRYPTO...] into [.TEST]
 389 $!
 390 $ COPY SYS$DISK:[.CRYPTO.*]%*TEST.C SYS$DISK:[.TEST]
 391 $ COPY SYS$DISK:[.CRYPTO.EVP]EVPTESTS.TXT SYS$DISK:[.TEST]
 392 $!
 393 $! Copy all the *TEST.C files from [.SSL...] into [.TEST]
 394 $!
 395 $ COPY SYS$DISK:[.SSL]%*TEST.C SYS$DISK:[.TEST]
 396 $!
 397 $! Tell The User We Are Rebuilding The [.INCLUDE.OPENSSL] Directory.
 398 $!
 399 $ WRITE SYS$OUTPUT "Rebuilding The '[.INCLUDE.OPENSSL]' Directory."
 400 $!
 401 $! First, make sure the directory exists
 402 $!
 403 $ IF F$PARSE("SYS$DISK:[.INCLUDE.OPENSSL]") .EQS. "" THEN -
 404      CREATE/DIRECTORY SYS$DISK:[.INCLUDE.OPENSSL]
 405 $!
 406 $! Copy All The ".H" Files From The Main Directory.
 407 $!
 408 $ EXHEADER := e_os2.h
 409 $ COPY 'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 410 $!
 411 $! Copy All The ".H" Files From The [.CRYPTO] Directory Tree.
 412 $!
 413 $ SDIRS := ,MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,-
 414    DES,RC2,RC4,RC5,IDEA,BF,CAST,-
 415    BN,EC,RSA,DSA,DH,DSO,ENGINE,AES,-
 416    BUFFER,BIO,STACK,LHASH,RAND,ERR,OBJECTS,-
 417    EVP,ASN1,PEM,X509,X509V3,CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5
 418 $ EXHEADER_ := crypto.h,tmdiff.h,opensslv.h,opensslconf.h,ebcdic.h,symhacks.h,-
 419                 ossl_typ.h
 420 $ EXHEADER_MD2 := md2.h
 421 $ EXHEADER_MD4 := md4.h
 422 $ EXHEADER_MD5 := md5.h
 423 $ EXHEADER_SHA := sha.h
 424 $ EXHEADER_MDC2 := mdc2.h
 425 $ EXHEADER_HMAC := hmac.h
 426 $ EXHEADER_RIPEMD := ripemd.h
 427 $ EXHEADER_DES := des.h,des_old.h
 428 $ EXHEADER_RC2 := rc2.h
 429 $ EXHEADER_RC4 := rc4.h
 430 $ EXHEADER_RC5 := rc5.h
 431 $ EXHEADER_IDEA := idea.h
 432 $ EXHEADER_BF := blowfish.h
 433 $ EXHEADER_CAST := cast.h
 434 $ EXHEADER_BN := bn.h
 435 $ EXHEADER_EC := ec.h
 436 $ EXHEADER_RSA := rsa.h
 437 $ EXHEADER_DSA := dsa.h
 438 $ EXHEADER_DH := dh.h
 439 $ EXHEADER_DSO := dso.h
 440 $ EXHEADER_ENGINE := engine.h
 441 $ EXHEADER_AES := aes.h
 442 $ EXHEADER_BUFFER := buffer.h
 443 $ EXHEADER_BIO := bio.h
 444 $ EXHEADER_STACK := stack.h,safestack.h
 445 $ EXHEADER_LHASH := lhash.h
 446 $ EXHEADER_RAND := rand.h
 447 $ EXHEADER_ERR := err.h
 448 $ EXHEADER_OBJECTS := objects.h,obj_mac.h
 449 $ EXHEADER_EVP := evp.h
 450 $ EXHEADER_ASN1 := asn1.h,asn1_mac.h,asn1t.h
 451 $ EXHEADER_PEM := pem.h,pem2.h
 452 $ EXHEADER_X509 := x509.h,x509_vfy.h
 453 $ EXHEADER_X509V3 := x509v3.h
 454 $ EXHEADER_CONF := conf.h,conf_api.h
 455 $ EXHEADER_TXT_DB := txt_db.h
 456 $ EXHEADER_PKCS7 := pkcs7.h
 457 $ EXHEADER_PKCS12 := pkcs12.h
 458 $ EXHEADER_COMP := comp.h
 459 $ EXHEADER_OCSP := ocsp.h
 460 $ EXHEADER_UI := ui.h,ui_compat.h
 461 $ EXHEADER_KRB5 := krb5_asn.h
 462 $
 463 $ I = 0
 464 $ LOOP_SDIRS:
 465 $ D = F$EDIT(F$ELEMENT(I, ",", SDIRS),"TRIM")
 466 $ I = I + 1
 467 $ IF D .EQS. "," THEN GOTO LOOP_SDIRS_END
 468 $ tmp = EXHEADER_'D'
 469 $ IF D .EQS. ""
 470 $ THEN
 471 $   COPY [.CRYPTO]'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 472 $ ELSE
 473 $   COPY [.CRYPTO.'D']'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 474 $ ENDIF
 475 $ GOTO LOOP_SDIRS
 476 $ LOOP_SDIRS_END:
 477 $!
 478 $! Copy All The ".H" Files From The [.SSL] Directory.
 479 $!
 480 $ EXHEADER := ssl.h,ssl2.h,ssl3.h,ssl23.h,tls1.h,kssl.h
 481 $ COPY SYS$DISK:[.SSL]'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 482 $!
 483 $! Copy All The ".H" Files From The [.FIPS] Directories.
 484 $!
 485 $ FDIRS := ,SHA1,RAND,DES,AES,DSA,RSA
 486 $ EXHEADER_ := fips.h
 487 $ EXHEADER_SHA1 :=
 488 $ EXHEADER_RAND := fips_rand.h
 489 $ EXHEADER_DES :=
 490 $ EXHEADER_AES :=
 491 $ EXHEADER_DSA :=
 492 $ EXHEADER_RSA :=
 493 $
 494 $ I = 0
 495 $ LOOP_FDIRS:
 496 $ D = F$EDIT(F$ELEMENT(I, ",", FDIRS),"TRIM")
 497 $ I = I + 1
 498 $ IF D .EQS. "," THEN GOTO LOOP_FDIRS_END
 499 $ tmp = EXHEADER_'D'
 500 $ IF tmp .EQS. "" THEN GOTO LOOP_FDIRS
 501 $ IF D .EQS. ""
 502 $ THEN
 503 $   COPY [.CRYPTO]'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 504 $ ELSE
 505 $   COPY [.CRYPTO.'D']'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 506 $ ENDIF
 507 $ GOTO LOOP_FDIRS
 508 $ LOOP_FDIRS_END:
 509 $!
 510 $! Purge all doubles
 511 $!
 512 $ PURGE SYS$DISK:[.INCLUDE.OPENSSL]*.H
 513 $!
 514 $! That's All, Time To RETURN.
 515 $!
 516 $ RETURN
 517 $!
 518 $! Build The "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library.
 519 $!
 520 $ CRYPTO:
 521 $!
 522 $! Tell The User What We Are Doing.
 523 $!
 524 $ WRITE SYS$OUTPUT ""
 525 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.CRYPTO]LIBCRYPTO.OLB Library."
 526 $!
 527 $! Go To The [.CRYPTO] Directory.
 528 $!
 529 $ SET DEFAULT SYS$DISK:[.CRYPTO]
 530 $!
 531 $! Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 532 $!
 533 $ @CRYPTO-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" "''BUILDPART'"
 534 $!
 535 $! Go To The [.FIPS] Directory.
 536 $!
 537 $ SET DEFAULT SYS$DISK:[.FIPS]
 538 $!
 539 $! Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 540 $!
 541 $ @FIPS-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" "''BUILDPART'"
 542 $!
 543 $! Build The [.xxx.EXE.CRYPTO]*.EXE Test Applications.
 544 $!
 545 $ @CRYPTO-LIB APPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 546 $!
 547 $! Go Back To The Main Directory.
 548 $!
 549 $ SET DEFAULT [-]
 550 $!
 551 $! Time To RETURN.
 552 $!
 553 $ RETURN
 554 $!
 555 $! Build The "[.xxx.EXE.SSL]LIBSSL.OLB" Library.
 556 $!
 557 $ SSL:
 558 $!
 559 $! Tell The User What We Are Doing.
 560 $!
 561 $ WRITE SYS$OUTPUT ""
 562 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.SSL]LIBSSL.OLB Library."
 563 $!
 564 $! Go To The [.SSL] Directory.
 565 $!
 566 $ SET DEFAULT SYS$DISK:[.SSL]
 567 $!
 568 $! Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 569 $!
 570 $ @SSL-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 571 $!
 572 $! Go Back To The Main Directory.
 573 $!
 574 $ SET DEFAULT [-]
 575 $!
 576 $! Time To Return.
 577 $!
 578 $ RETURN
 579 $!
 580 $! Build The "[.xxx.EXE.SSL]SSL_TASK.EXE" Program.
 581 $!
 582 $ SSL_TASK:
 583 $!
 584 $! Tell The User What We Are Doing.
 585 $!
 586 $ WRITE SYS$OUTPUT ""
 587 $ WRITE SYS$OUTPUT "Building DECNet Based SSL Engine, [.",ARCH,".EXE.SSL]SSL_TASK.EXE"
 588 $!
 589 $! Go To The [.SSL] Directory.
 590 $!
 591 $ SET DEFAULT SYS$DISK:[.SSL]
 592 $!
 593 $! Build The [.xxx.EXE.SSL]SSL_TASK.EXE
 594 $!
 595 $ @SSL-LIB SSL_TASK 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 596 $!
 597 $! Go Back To The Main Directory.
 598 $!
 599 $ SET DEFAULT [-]
 600 $!
 601 $! That's All, Time To RETURN.
 602 $!
 603 $ RETURN
 604 $!
 605 $! Build The OpenSSL Test Programs.
 606 $!
 607 $ TEST:
 608 $!
 609 $! Tell The User What We Are Doing.
 610 $!
 611 $ WRITE SYS$OUTPUT ""
 612 $ WRITE SYS$OUTPUT "Building The OpenSSL [.",ARCH,".EXE.TEST] Test Utilities."
 613 $!
 614 $! Go To The [.TEST] Directory.
 615 $!
 616 $ SET DEFAULT SYS$DISK:[.TEST]
 617 $!
 618 $! Build The Test Programs.
 619 $!
 620 $ @MAKETESTS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 621 $!
 622 $! Go Back To The Main Directory.
 623 $!
 624 $ SET DEFAULT [-]
 625 $!
 626 $! That's All, Time To RETURN.
 627 $!
 628 $ RETURN
 629 $!
 630 $! Build The OpenSSL Application Programs.
 631 $!
 632 $ APPS:
 633 $!
 634 $! Tell The User What We Are Doing.
 635 $!
 636 $ WRITE SYS$OUTPUT ""
 637 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCH,".EXE.APPS] Applications."
 638 $!
 639 $! Go To The [.APPS] Directory.
 640 $!
 641 $ SET DEFAULT SYS$DISK:[.APPS]
 642 $!
 643 $! Build The Application Programs.
 644 $!
 645 $ @MAKEAPPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 646 $!
 647 $! Go Back To The Main Directory.
 648 $!
 649 $ SET DEFAULT [-]
 650 $!
 651 $! That's All, Time To RETURN.
 652 $!
 653 $ RETURN
 654 $!
 655 $! Check The User's Options.
 656 $!
 657 $ CHECK_OPTIONS:
 658 $!
 659 $! Check if there's a "part", and separate it out
 660 $!
 661 $ BUILDPART = F$ELEMENT(1,"/",P1)
 662 $ IF BUILDPART .EQS. "/"
 663 $ THEN
 664 $   BUILDPART = ""
 665 $ ELSE
 666 $   P1 = F$EXTRACT(0,F$LENGTH(P1) - F$LENGTH(BUILDPART) - 1, P1)
 667 $ ENDIF
 668 $!
 669 $! Check To See If P1 Is Blank.
 670 $!
 671 $ IF (P1.EQS."ALL")
 672 $ THEN
 673 $!
 674 $!   P1 Is ALL, So Build Everything.
 675 $!
 676 $    BUILDCOMMAND = "ALL"
 677 $!
 678 $! Else...
 679 $!
 680 $ ELSE
 681 $!
 682 $!  Else, Check To See If P1 Has A Valid Arguement.
 683 $!
 684 $   IF (P1.EQS."CONFIG").OR.(P1.EQS."BUILDINF").OR.(P1.EQS."SOFTLINKS") -
 685        .OR.(P1.EQS."BUILDALL") -
 686        .OR.(P1.EQS."CRYPTO").OR.(P1.EQS."SSL") -
 687        .OR.(P1.EQS."SSL_TASK").OR.(P1.EQS."TEST").OR.(P1.EQS."APPS")
 688 $   THEN
 689 $!
 690 $!    A Valid Arguement.
 691 $!
 692 $     BUILDCOMMAND = P1
 693 $!
 694 $!  Else...
 695 $!
 696 $   ELSE
 697 $!
 698 $!    Tell The User We Don't Know What They Want.
 699 $!
 700 $     WRITE SYS$OUTPUT ""
 701 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 702 $     WRITE SYS$OUTPUT ""
 703 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 704 $     WRITE SYS$OUTPUT "    CONFIG   :  Just build the [.CRYPTO]OPENSSLCONF.H file."
 705 $     WRITE SYS$OUTPUT "    BUILDINF :  Just build the [.CRYPTO]BUILDINF.H file."
 706 $     WRITE SYS$OUTPUT "    SOFTLINKS:  Just Fix The Unix soft links."
 707 $     WRITE SYS$OUTPUT "    BUILDALL :  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done."
 708 $     WRITE SYS$OUTPUT "    CRYPTO   :  To Build Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 709 $     WRITE SYS$OUTPUT "    CRYPTO/x :  To Build Just The x Part Of The"
 710 $     WRITE SYS$OUTPUT "                [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 711 $     WRITE SYS$OUTPUT "    SSL      :  To Build Just The [.xxx.EXE.SSL]LIBSSL.OLB Library."
 712 $     WRITE SYS$OUTPUT "    SSL_TASK :  To Build Just The [.xxx.EXE.SSL]SSL_TASK.EXE Program."
 713 $     WRITE SYS$OUTPUT "    TEST     :  To Build Just The OpenSSL Test Programs."
 714 $     WRITE SYS$OUTPUT "    APPS     :  To Build Just The OpenSSL Application Programs."
 715 $     WRITE SYS$OUTPUT ""
 716 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 717 $     WRITE SYS$OUTPUT ""
 718 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 719 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 720 $     WRITE SYS$OUTPUT ""
 721 $!
 722 $!    Time To EXIT.
 723 $!
 724 $     EXIT
 725 $!
 726 $!  End The Valid Argument Check.
 727 $!
 728 $   ENDIF
 729 $!
 730 $! End The P1 Check.
 731 $!
 732 $ ENDIF
 733 $!
 734 $! Check To See If P3 Is Blank.
 735 $!
 736 $ IF (P3.EQS."NODEBUG")
 737 $ THEN
 738 $!
 739 $!   P3 Is NODEBUG, So Compile Without Debugger Information.
 740 $!
 741 $    DEBUGGER = "NODEBUG"
 742 $!
 743 $! Else...
 744 $!
 745 $ ELSE
 746 $!
 747 $!  Check To See If We Are To Compile With Debugger Information.
 748 $!
 749 $   IF (P3.EQS."DEBUG")
 750 $   THEN
 751 $!
 752 $!    Compile With Debugger Information.
 753 $!
 754 $     DEBUGGER = "DEBUG"
 755 $!
 756 $!  Else...
 757 $!
 758 $   ELSE
 759 $!
 760 $!    Tell The User Entered An Invalid Option..
 761 $!
 762 $     WRITE SYS$OUTPUT ""
 763 $     WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
 764 $     WRITE SYS$OUTPUT ""
 765 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
 766 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
 767 $     WRITE SYS$OUTPUT ""
 768 $!
 769 $!    Time To EXIT.
 770 $!
 771 $     EXIT
 772 $!
 773 $!  End The Valid Arguement Check.
 774 $!
 775 $   ENDIF
 776 $!
 777 $! End The P3 Check.
 778 $!
 779 $ ENDIF
 780 $!
 781 $! Check To See If P4 Is Blank.
 782 $!
 783 $ IF (P4.EQS."")
 784 $ THEN
 785 $!
 786 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 787 $!  Find Out Which One To Use.
 788 $!
 789 $!  Check To See If We Have GNU C.
 790 $!
 791 $   IF (F$TRNLNM("GNU_CC").NES."")
 792 $   THEN
 793 $!
 794 $!    Looks Like GNUC, Set To Use GNUC.
 795 $!
 796 $     COMPILER = "GNUC"
 797 $!
 798 $!    Tell The User We Are Using GNUC.
 799 $!
 800 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 801 $!
 802 $!  End The GNU C Compiler Check.
 803 $!
 804 $   ENDIF
 805 $!
 806 $!  Check To See If We Have VAXC Or DECC.
 807 $!
 808 $   IF (F$GETSYI("CPU").GE.128).OR.(F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC")
 809 $   THEN
 810 $!
 811 $!    Looks Like DECC, Set To Use DECC.
 812 $!
 813 $     COMPILER = "DECC"
 814 $!
 815 $!    Tell The User We Are Using DECC.
 816 $!
 817 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 818 $!
 819 $!  Else...
 820 $!
 821 $   ELSE
 822 $!
 823 $!    Looks Like VAXC, Set To Use VAXC.
 824 $!
 825 $     COMPILER = "VAXC"
 826 $!
 827 $!    Tell The User We Are Using VAX C.
 828 $!
 829 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 830 $!
 831 $!  End The DECC & VAXC Compiler Check.
 832 $!
 833 $   ENDIF
 834 $!
 835 $! Else...
 836 $!
 837 $ ELSE
 838 $!
 839 $!  Check To See If The User Entered A Valid Paramter.
 840 $!
 841 $   IF (P4.EQS."VAXC").OR.(P4.EQS."DECC").OR.(P4.EQS."GNUC")!.OR.(P4.EQS."LINK")
 842 $   THEN
 843 $!
 844 $!    Check To See If The User Wanted To Just LINK.
 845 $!
 846 $     IF (P4.EQS."LINK")
 847 $     THEN
 848 $!
 849 $!      Looks Like LINK-only
 850 $!
 851 $       COMPILER = "LINK"
 852 $!
 853 $!      Tell The User We Are Only Linking.
 854 $!
 855 $       WRITE SYS$OUTPUT "LINK Only.  This actually NOT YET SUPPORTED!"
 856 $!
 857 $!    End LINK Check.
 858 $!
 859 $     ENDIF
 860 $!
 861 $!    Check To See If The User Wanted DECC.
 862 $!
 863 $     IF (P4.EQS."DECC")
 864 $     THEN
 865 $!
 866 $!      Looks Like DECC, Set To Use DECC.
 867 $!
 868 $       COMPILER = "DECC"
 869 $!
 870 $!      Tell The User We Are Using DECC.
 871 $!
 872 $       WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 873 $!
 874 $!    End DECC Check.
 875 $!
 876 $     ENDIF
 877 $!
 878 $!    Check To See If We Are To Use VAXC.
 879 $!
 880 $     IF (P4.EQS."VAXC")
 881 $     THEN
 882 $!
 883 $!      Looks Like VAXC, Set To Use VAXC.
 884 $!
 885 $       COMPILER = "VAXC"
 886 $!
 887 $!      Tell The User We Are Using VAX C.
 888 $!
 889 $       WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 890 $!
 891 $!    End VAXC Check
 892 $!
 893 $     ENDIF
 894 $!
 895 $!    Check To See If We Are To Use GNU C.
 896 $!
 897 $     IF (P4.EQS."GNUC")
 898 $     THEN
 899 $!
 900 $!      Looks Like GNUC, Set To Use GNUC.
 901 $!
 902 $       COMPILER = "GNUC"
 903 $!
 904 $!      Tell The User We Are Using GNUC.
 905 $!
 906 $       WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 907 $!
 908 $!    End The GNU C Check.
 909 $!
 910 $     ENDIF
 911 $!
 912 $!  Else The User Entered An Invalid Arguement.
 913 $!
 914 $   ELSE
 915 $!
 916 $!    Tell The User We Don't Know What They Want.
 917 $!
 918 $     WRITE SYS$OUTPUT ""
 919 $     WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
 920 $     WRITE SYS$OUTPUT ""
 921 $     WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 922 $     WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 923 $     WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 924 $     WRITE SYS$OUTPUT ""
 925 $!
 926 $!    Time To EXIT.
 927 $!
 928 $     EXIT
 929 $!
 930 $!  End The Valid Arguement Check.
 931 $!
 932 $   ENDIF
 933 $!
 934 $! End The P4 Check.
 935 $!
 936 $ ENDIF
 937 $!
 938 $! Time to check the contents of P5, and to make sure we get the correct library.
 939 $!
 940 $ IF P5.EQS."SOCKETSHR" .OR. P5.EQS."MULTINET" .OR. P5.EQS."UCX" -
 941      .OR. P5.EQS."TCPIP" .OR. P5.EQS."NONE"
 942 $ THEN
 943 $!
 944 $!  Check to see if SOCKETSHR was chosen
 945 $!
 946 $   IF P5.EQS."SOCKETSHR"
 947 $   THEN
 948 $!
 949 $!    Set the library to use SOCKETSHR
 950 $!
 951 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
 952 $!
 953 $!    Tell the user
 954 $!
 955 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 956 $!
 957 $!    Done with SOCKETSHR
 958 $!
 959 $   ENDIF
 960 $!
 961 $!  Check to see if MULTINET was chosen
 962 $!
 963 $   IF P5.EQS."MULTINET"
 964 $   THEN
 965 $!
 966 $!    Set the library to use UCX emulation.
 967 $!
 968 $     P5 = "UCX"
 969 $!
 970 $!    Tell the user
 971 $!
 972 $     WRITE SYS$OUTPUT "Using MultiNet via UCX emulation for TCP/IP"
 973 $!
 974 $!    Done with MULTINET
 975 $!
 976 $   ENDIF
 977 $!
 978 $!  Check to see if UCX was chosen
 979 $!
 980 $   IF P5.EQS."UCX"
 981 $   THEN
 982 $!
 983 $!    Set the library to use UCX.
 984 $!
 985 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
 986 $!
 987 $!    Tell the user
 988 $!
 989 $     WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 990 $!
 991 $!    Done with UCX
 992 $!
 993 $   ENDIF
 994 $!
 995 $!  Check to see if TCPIP was chosen
 996 $!
 997 $   IF P5.EQS."TCPIP"
 998 $   THEN
 999 $!
1000 $!    Set the library to use TCPIP (post UCX).
1001 $!
1002 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1003 $!
1004 $!    Tell the user
1005 $!
1006 $     WRITE SYS$OUTPUT "Using TCPIP (post UCX) for TCP/IP"
1007 $!
1008 $!    Done with TCPIP
1009 $!
1010 $   ENDIF
1011 $!
1012 $!  Check to see if NONE was chosen
1013 $!
1014 $   IF P5.EQS."NONE"
1015 $   THEN
1016 $!
1017 $!    Do not use a TCPIP library.
1018 $!
1019 $     TCPIP_LIB = ""
1020 $!
1021 $!    Tell the user
1022 $!
1023 $     WRITE SYS$OUTPUT "A specific TCPIP library will not be used."
1024 $!
1025 $!    Done with NONE.
1026 $!
1027 $   ENDIF
1028 $!
1029 $!  Set the TCPIP_TYPE symbol
1030 $!
1031 $   TCPIP_TYPE = P5
1032 $!
1033 $!  Print info
1034 $!
1035 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1036 $!
1037 $!  Else The User Entered An Invalid Arguement.
1038 $!
1039 $ ELSE
1040 $   IF P5 .NES. ""
1041 $   THEN
1042 $!
1043 $!    Tell The User We Don't Know What They Want.
1044 $!
1045 $     WRITE SYS$OUTPUT ""
1046 $     WRITE SYS$OUTPUT "The Option ",P5," Is Invalid.  The Valid Options Are:"
1047 $     WRITE SYS$OUTPUT ""
1048 $     WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1049 $     WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1050 $     WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP TCP/IP (post UCX) library."
1051 $     WRITE SYS$OUTPUT "    NONE       :  To not link with a specific TCP/IP library."
1052 $     WRITE SYS$OUTPUT ""
1053 $!
1054 $!    Time To EXIT.
1055 $!
1056 $     EXIT
1057 $   ELSE
1058 $!
1059 $! If TCPIP is not defined, then hardcode it to make
1060 $! it clear that no TCPIP is desired.
1061 $!
1062 $     IF P5 .EQS. ""
1063 $     THEN
1064 $       TCPIP_LIB = ""
1065 $       TCPIP_TYPE = "NONE"
1066 $     ELSE
1067 $!
1068 $!    Set the TCPIP_TYPE symbol
1069 $!
1070 $       TCPIP_TYPE = P5
1071 $     ENDIF
1072 $   ENDIF
1073 $!
1074 $!  Done with TCP/IP libraries
1075 $!
1076 $ ENDIF
1077 $!
1078 $! Special Threads For OpenVMS v7.1 Or Later
1079 $!
1080 $! Written By:  Richard Levitte
1081 $!              richard@levitte.org
1082 $!
1083 $!
1084 $! Check To See If We Have A Option For P6.
1085 $!
1086 $ IF (P6.EQS."")
1087 $ THEN
1088 $!
1089 $!  Get The Version Of VMS We Are Using.
1090 $!
1091 $   ISSEVEN :=
1092 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
1093 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1094 $!
1095 $!  Check To See If The VMS Version Is v7.1 Or Later.
1096 $!
1097 $   IF (TMP.GE.71)
1098 $   THEN
1099 $!
1100 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1101 $!
1102 $     ISSEVEN := ,PTHREAD_USE_D4
1103 $!
1104 $!  End The VMS Version Check.
1105 $!
1106 $   ENDIF
1107 $!
1108 $! End The P6 Check.
1109 $!
1110 $ ENDIF
1111 $!
1112 $!  Time To RETURN...
1113 $!
1114 $ RETURN