makevms.com

   1 $!
   2 $! MAKEVMS.COM
   3 $! Original Author:  UNKNOWN
   4 $! Rewritten By:  Robert Byer
   5 $!                Vice-President
   6 $!                A-Com Computing, Inc.
   7 $!                byer@mail.all-net.net
   8 $!
   9 $! Changes by Richard Levitte <richard@levitte.org>
  10 $!            Zoltan Arpadffy <zoli@polarhome.com>
  11 $!
  12 $! This procedure creates the SSL libraries of "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  13 $! "[.xxx.EXE.SSL]LIBSSL.OLB"
  14 $! The "xxx" denotes the machine architecture of ALPHA, IA64 or VAX.
  15 $!
  16 $! This procedures accepts two command line options listed below.
  17 $!
  18 $! P1 specifies one of the following build options:
  19 $!
  20 $!      ALL       Just build "everything".
  21 $!      CONFIG    Just build the "[.CRYPTO._xxx]OPENSSLCONF.H" file.
  22 $!      BUILDINF  Just build the "[.CRYPTO._xxx]BUILDINF.H" file.
  23 $!      SOFTLINKS Just fix the Unix soft links.
  24 $!      BUILDALL  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done.
  25 $!      CRYPTO    Just build the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  26 $!      CRYPTO/x  Just build the x part of the
  27 $!                "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  28 $!      SSL       Just build the "[.xxx.EXE.SSL]LIBSSL.OLB" library.
  29 $!      SSL_TASK  Just build the "[.xxx.EXE.SSL]SSL_TASK.EXE" program.
  30 $!      TEST      Just build the "[.xxx.EXE.TEST]" test programs for OpenSSL.
  31 $!      APPS      Just build the "[.xxx.EXE.APPS]" application programs for OpenSSL.
  32 $!      ENGINES   Just build the "[.xxx.EXE.ENGINES]" application programs for OpenSSL.
  33 $!
  34 $! P2, if defined, specifies the C pointer size.  Ignored on VAX.
  35 $!      ("64=ARGV" gives more efficient code with HP C V7.3 or newer.)
  36 $!      Supported values are:
  37 $!
  38 $!      ""       Compile with default (/NOPOINTER_SIZE).
  39 $!      32       Compile with /POINTER_SIZE=32 (SHORT).
  40 $!      64       Compile with /POINTER_SIZE=64[=ARGV] (LONG[=ARGV]).
  41 $!               (Automatically select ARGV if compiler supports it.)
  42 $!      64=      Compile with /POINTER_SIZE=64 (LONG).
  43 $!      64=ARGV  Compile with /POINTER_SIZE=64=ARGV (LONG=ARGV).
  44 $!
  45 $! P3 specifies DEBUG or NODEBUG, to compile with or without debugging
  46 $!    information.
  47 $!
  48 $! P4 specifies which compiler to try to compile under.
  49 $!
  50 $!        VAXC   For VAX C.
  51 $!        DECC   For DEC C.
  52 $!        GNUC   For GNU C.
  53 $!        LINK   To only link the programs from existing object files.
  54 $!               (not yet implemented)
  55 $!
  56 $! If you don't specify a compiler, it will try to determine which
  57 $! "C" compiler to use.
  58 $!
  59 $! P5, if defined, sets a TCP/IP library to use, through one of the following
  60 $! keywords:
  61 $!
  62 $!      UCX             for UCX or UCX emulation
  63 $!      TCPIP           for TCP/IP Services or TCP/IP Services emulation
  64 $!                      (this is prefered over UCX)
  65 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  66 $!      NONE            to avoid specifying which TCP/IP implementation to
  67 $!                      use at build time (this works with DEC C).  This is
  68 $!                      the default.
  69 $!
  70 $! P6, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up).
  71 $!
  72 $! P7, if defined, specifies a directory where ZLIB files (zlib.h,
  73 $! libz.olb) may be found.  Optionally, a non-default object library
  74 $! name may be included ("dev:[dir]libz_64.olb", for example).
  75 $!
  76 $!
  77 $! Announce/identify.
  78 $!
  79 $ proc = f$environment( "procedure")
  80 $ write sys$output "@@@ "+ -
  81    f$parse( proc, , , "name")+ f$parse( proc, , , "type")
  82 $!
  83 $ DEF_ORIG = F$ENVIRONMENT( "DEFAULT")
  84 $ ON ERROR THEN GOTO TIDY
  85 $ ON CONTROL_C THEN GOTO TIDY
  86 $!
  87 $! Check if we're in a batch job, and make sure we get to
  88 $! the directory this script is in
  89 $!
  90 $ IF F$MODE() .EQS. "BATCH"
  91 $ THEN
  92 $   COMNAME=F$ENVIRONMENT("PROCEDURE")
  93 $   COMPATH=F$PARSE("A.;",COMNAME) - "A.;"
  94 $   SET DEF 'COMPATH'
  95 $ ENDIF
  96 $!
  97 $! Check What Architecture We Are Using.
  98 $!
  99 $ IF (F$GETSYI("CPU").LT.128)
 100 $ THEN
 101 $!
 102 $!  The Architecture Is VAX.
 103 $!
 104 $   ARCH = "VAX"
 105 $!
 106 $! Else...
 107 $!
 108 $ ELSE
 109 $!
 110 $!  The Architecture Is Alpha, IA64 or whatever comes in the future.
 111 $!
 112 $   ARCH = F$EDIT( F$GETSYI( "ARCH_NAME"), "UPCASE")
 113 $   IF (ARCH .EQS. "") THEN ARCH = "UNK"
 114 $!
 115 $! End The Architecture Check.
 116 $!
 117 $ ENDIF
 118 $!
 119 $ ARCHD = ARCH
 120 $ LIB32 = "32"
 121 $ POINTER_SIZE = ""
 122 $!
 123 $! Get VMS version.
 124 $!
 125 $ VMS_VERSION = f$edit( f$getsyi( "VERSION"), "TRIM")
 126 $!
 127 $! Check To Make Sure We Have Valid Command Line Parameters.
 128 $!
 129 $ GOSUB CHECK_OPTIONS
 130 $!
 131 $! Check To See What We Are To Do.
 132 $!
 133 $ IF (BUILDCOMMAND.EQS."ALL")
 134 $ THEN
 135 $!
 136 $!  Start with building the OpenSSL configuration file.
 137 $!
 138 $   GOSUB CONFIG
 139 $!
 140 $!  Create The "BUILDINF.H" Include File.
 141 $!
 142 $   GOSUB BUILDINF
 143 $!
 144 $!  Fix The Unix Softlinks.
 145 $!
 146 $   GOSUB SOFTLINKS
 147 $!
 148 $ ENDIF
 149 $!
 150 $ IF (BUILDCOMMAND.EQS."ALL".OR.BUILDCOMMAND.EQS."BUILDALL")
 151 $ THEN
 152 $!
 153 $!  Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 154 $!
 155 $   GOSUB CRYPTO
 156 $!
 157 $!  Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 158 $!
 159 $   GOSUB SSL
 160 $!
 161 $!  Build The [.xxx.EXE.SSL]SSL_TASK.EXE DECNet SSL Engine.
 162 $!
 163 $   GOSUB SSL_TASK
 164 $!
 165 $!  Build The [.xxx.EXE.TEST] OpenSSL Test Utilities.
 166 $!
 167 $   GOSUB TEST
 168 $!
 169 $!  Build The [.xxx.EXE.APPS] OpenSSL Application Utilities.
 170 $!
 171 $   GOSUB APPS
 172 $!
 173 $!  Build The [.xxx.EXE.ENGINES] OpenSSL Shareable Engines.
 174 $!
 175 $   GOSUB ENGINES
 176 $!
 177 $! Else...
 178 $!
 179 $ ELSE
 180 $!
 181 $!    Build Just What The User Wants Us To Build.
 182 $!
 183 $     GOSUB 'BUILDCOMMAND'
 184 $!
 185 $ ENDIF
 186 $!
 187 $! Time To EXIT.
 188 $!
 189 $ GOTO TIDY
 190 $!
 191 $! Rebuild The [.CRYPTO._xxx]OPENSSLCONF.H" file.
 192 $!
 193 $ CONFIG:
 194 $!
 195 $! Tell The User We Are Creating The [.CRYPTO._xxx]OPENSSLCONF.H File.
 196 $!
 197 $ WRITE SYS$OUTPUT "Creating [.CRYPTO.''ARCHD']OPENSSLCONF.H Include File."
 198 $!
 199 $! First, make sure the directory exists.
 200 $!
 201 $ IF F$PARSE("SYS$DISK:[.CRYPTO.''ARCHD']") .EQS. "" THEN -
 202      CREATE/DIRECTORY SYS$DISK:[.CRYPTO.'ARCHD']
 203 $!
 204 $! Different tar/UnZip versions/option may have named the file differently
 205 $ IF F$SEARCH("[.crypto]opensslconf.h_in") .NES. ""
 206 $ THEN
 207 $   OPENSSLCONF_H_IN = "[.crypto]opensslconf.h_in"
 208 $ ELSE
 209 $   IF F$SEARCH( "[.crypto]opensslconf_h.in") .NES. ""
 210 $   THEN
 211 $     OPENSSLCONF_H_IN = "[.crypto]opensslconf_h.in"
 212 $   ELSE
 213 $     ! For ODS-5
 214 $     IF F$SEARCH( "[.crypto]opensslconf.h.in") .NES. ""
 215 $     THEN
 216 $       OPENSSLCONF_H_IN = "[.crypto]opensslconf.h.in"
 217 $     ELSE
 218 $       WRITE SYS$ERROR "Couldn't find a [.crypto]opensslconf.h.in.  Exiting!"
 219 $       $STATUS = %X00018294 ! "%RMS-F-FNF, file not found".
 220 $       GOTO TIDY
 221 $     ENDIF
 222 $   ENDIF
 223 $ ENDIF
 224 $!
 225 $! Create The [.CRYPTO._xxx]OPENSSLCONF.H File.
 226 $! Make sure it has the right format.
 227 $!
 228 $ OSCH_NAME = "SYS$DISK:[.CRYPTO.''ARCHD']OPENSSLCONF.H"
 229 $ CREATE /FDL=SYS$INPUT: 'OSCH_NAME'
 230 RECORD
 231         FORMAT stream_lf
 232 $ OPEN /APPEND H_FILE 'OSCH_NAME'
 233 $!
 234 $! Write The [.CRYPTO._xxx]OPENSSLCONF.H File.
 235 $!
 236 $ WRITE H_FILE "/* This file was automatically built using makevms.com */"
 237 $ WRITE H_FILE "/* and ''OPENSSLCONF_H_IN' */"
 238 $!
 239 $! Write a few macros that indicate how this system was built.
 240 $!
 241 $ WRITE H_FILE ""
 242 $ WRITE H_FILE "#ifndef OPENSSL_SYS_VMS"
 243 $ WRITE H_FILE "# define OPENSSL_SYS_VMS"
 244 $ WRITE H_FILE "#endif"
 245 $!
 246 $! One of the best way to figure out what the list should be is to do
 247 $! the following on a Unix system:
 248 $!   grep OPENSSL_NO_ crypto/*/*.h ssl/*.h engines/*.h engines/*/*.h|grep ':# *if'|sed -e 's/^.*def //'|sort|uniq
 249 $! For that reason, the list will also always end up in alphabetical order
 250 $ CONFIG_LOGICALS := AES,-
 251                      ASM,INLINE_ASM,-
 252                      BF,-
 253                      BIO,-
 254                      BUFFER,-
 255                      BUF_FREELISTS,-
 256                      CAMELLIA,-
 257                      CAST,-
 258                      CMS,-
 259                      COMP,-
 260                      DEPRECATED,-
 261                      DES,-
 262                      DGRAM,-
 263                      DH,-
 264                      DSA,-
 265                      EC,-
 266                      EC2M,-
 267                      ECDH,-
 268                      ECDSA,-
 269                      EC_NISTP_64_GCC_128,-
 270                      ENGINE,-
 271                      ERR,-
 272                      EVP,-
 273                      FP_API,-
 274                      GMP,-
 275                      GOST,-
 276                      HASH_COMP,-
 277                      HEARTBEATS,-
 278                      HMAC,-
 279                      IDEA,-
 280                      JPAKE,-
 281                      KRB5,-
 282                      LHASH,-
 283                      MD2,-
 284                      MD4,-
 285                      MD5,-
 286                      MDC2,-
 287                      NEXTPROTONEG,-
 288                      OCSP,-
 289                      PSK,-
 290                      RC2,-
 291                      RC4,-
 292                      RC5,-
 293                      RFC3779,-
 294                      RIPEMD,-
 295                      RSA,-
 296                      SCTP,-
 297                      SEED,-
 298                      SHA,-
 299                      SHA0,-
 300                      SHA1,-
 301                      SHA256,-
 302                      SHA512,-
 303                      SOCK,-
 304                      SRP,-
 305                      SSL2,-
 306                      SSL_INTERN,-
 307                      SSL_TRACE,-
 308                      STACK,-
 309                      STATIC_ENGINE,-
 310                      STDIO,-
 311                      STORE,-
 312                      TLSEXT,-
 313                      WHIRLPOOL,-
 314                      X509
 315 $! Add a few that we know about
 316 $ CONFIG_LOGICALS := 'CONFIG_LOGICALS',-
 317                      THREADS
 318 $! The following rules, which dictate how some algorithm choices affect
 319 $! others, are picked from Configure.
 320 $! Quick syntax:
 321 $!  list = item[ ; list]
 322 $!  item = algos / dependents
 323 $!  algos = algo [, algos]
 324 $!  dependents = dependent [, dependents]
 325 $! When a list of algos is specified in one item, it means that they must
 326 $! all be disabled for the rule to apply.
 327 $! When a list of dependents is specified in one item, it means that they
 328 $! will all be disabled if the rule applies.
 329 $! Rules are checked sequentially.  If a rule disables an algorithm, it will
 330 $! affect all following rules that depend on that algorithm being disabled.
 331 $! To force something to be enabled or disabled, have no algorithms in the
 332 $! algos part.
 333 $ CONFIG_DISABLE_RULES := RIJNDAEL/AES;-
 334                           DES/MDC2;-
 335                           EC/ECDSA,ECDH;-
 336                           MD5/SSL2,SSL3,TLS1;-
 337                           SHA/SSL3,TLS1;-
 338                           RSA/SSL2;-
 339                           RSA,DSA/SSL2;-
 340                           DH/SSL3,TLS1;-
 341                           TLS1/TLSEXT;-
 342                           EC/GOST;-
 343                           DSA/GOST;-
 344                           DH/GOST;-
 345                           /STATIC_ENGINE;-
 346                           /KRB5;-
 347                           /EC_NISTP_64_GCC_128;-
 348                           /GMP;-
 349                           /MD2;-
 350                           /RC5;-
 351                           /RFC3779;-
 352                           /SCTP;-
 353                           /SSL_TRACE
 354 $ CONFIG_ENABLE_RULES := ZLIB_DYNAMIC/ZLIB;-
 355                          /THREADS
 356 $
 357 $! Architecture specific rule addtions
 358 $ IF ARCH .EQS. "VAX"
 359 $ THEN
 360 $   ! Disable algorithms that require 64-bit integers in C
 361 $   CONFIG_DISABLE_RULES = CONFIG_DISABLE_RULES + -
 362                            ";/GOST" + -
 363                            ";/WHIRLPOOL"
 364 $ ENDIF
 365 $
 366 $ CONFIG_LOG_I = 0
 367 $ CONFIG_LOG_LOOP1:
 368 $   CONFIG_LOG_E = F$EDIT(F$ELEMENT(CONFIG_LOG_I,",",CONFIG_LOGICALS),"TRIM")
 369 $   CONFIG_LOG_I = CONFIG_LOG_I + 1
 370 $   IF CONFIG_LOG_E .EQS. "" THEN GOTO CONFIG_LOG_LOOP1
 371 $   IF CONFIG_LOG_E .EQS. "," THEN GOTO CONFIG_LOG_LOOP1_END
 372 $   IF F$TRNLNM("OPENSSL_NO_"+CONFIG_LOG_E)
 373 $   THEN
 374 $       CONFIG_DISABLED_'CONFIG_LOG_E' := YES
 375 $       CONFIG_ENABLED_'CONFIG_LOG_E' := NO
 376 $       CONFIG_CHANGED_'CONFIG_LOG_E' := YES
 377 $   ELSE
 378 $       CONFIG_DISABLED_'CONFIG_LOG_E' := NO
 379 $       CONFIG_ENABLED_'CONFIG_LOG_E' := YES
 380 $       ! Because all algorithms are assumed enabled by default
 381 $       CONFIG_CHANGED_'CONFIG_LOG_E' := NO
 382 $   ENDIF
 383 $   GOTO CONFIG_LOG_LOOP1
 384 $ CONFIG_LOG_LOOP1_END:
 385 $
 386 $! Apply cascading disable rules
 387 $ CONFIG_DISABLE_I = 0
 388 $ CONFIG_DISABLE_LOOP0:
 389 $   CONFIG_DISABLE_E = F$EDIT(F$ELEMENT(CONFIG_DISABLE_I,";", -
 390      CONFIG_DISABLE_RULES),"TRIM")
 391 $   CONFIG_DISABLE_I = CONFIG_DISABLE_I + 1
 392 $   IF CONFIG_DISABLE_E .EQS. "" THEN GOTO CONFIG_DISABLE_LOOP0
 393 $   IF CONFIG_DISABLE_E .EQS. ";" THEN GOTO CONFIG_DISABLE_LOOP0_END
 394 $
 395 $   CONFIG_DISABLE_ALGOS = F$EDIT(F$ELEMENT(0,"/",CONFIG_DISABLE_E),"TRIM")
 396 $   CONFIG_DISABLE_DEPENDENTS = F$EDIT(F$ELEMENT(1,"/",CONFIG_DISABLE_E),"TRIM")
 397 $   TO_DISABLE := YES
 398 $   CONFIG_ALGO_I = 0
 399 $   CONFIG_DISABLE_LOOP1:
 400 $     CONFIG_ALGO_E = F$EDIT(F$ELEMENT(CONFIG_ALGO_I,",", -
 401        CONFIG_DISABLE_ALGOS),"TRIM")
 402 $     CONFIG_ALGO_I = CONFIG_ALGO_I + 1
 403 $     IF CONFIG_ALGO_E .EQS. "" THEN GOTO CONFIG_DISABLE_LOOP1
 404 $     IF CONFIG_ALGO_E .EQS. "," THEN GOTO CONFIG_DISABLE_LOOP1_END
 405 $     IF F$TYPE(CONFIG_DISABLED_'CONFIG_ALGO_E') .EQS. ""
 406 $     THEN
 407 $       TO_DISABLE := NO
 408 $     ELSE
 409 $       IF .NOT. CONFIG_DISABLED_'CONFIG_ALGO_E' THEN TO_DISABLE := NO
 410 $     ENDIF
 411 $     GOTO CONFIG_DISABLE_LOOP1
 412 $   CONFIG_DISABLE_LOOP1_END:
 413 $
 414 $   IF TO_DISABLE
 415 $   THEN
 416 $     CONFIG_DEPENDENT_I = 0
 417 $     CONFIG_DISABLE_LOOP2:
 418 $       CONFIG_DEPENDENT_E = F$EDIT(F$ELEMENT(CONFIG_DEPENDENT_I,",", -
 419          CONFIG_DISABLE_DEPENDENTS),"TRIM")
 420 $       CONFIG_DEPENDENT_I = CONFIG_DEPENDENT_I + 1
 421 $       IF CONFIG_DEPENDENT_E .EQS. "" THEN GOTO CONFIG_DISABLE_LOOP2
 422 $       IF CONFIG_DEPENDENT_E .EQS. "," THEN GOTO CONFIG_DISABLE_LOOP2_END
 423 $       CONFIG_DISABLED_'CONFIG_DEPENDENT_E' := YES
 424 $       CONFIG_ENABLED_'CONFIG_DEPENDENT_E' := NO
 425 $       ! Better not to assume defaults at this point...
 426 $       CONFIG_CHANGED_'CONFIG_DEPENDENT_E' := YES
 427 $       WRITE SYS$ERROR -
 428          "''CONFIG_DEPENDENT_E' disabled by rule ''CONFIG_DISABLE_E'"
 429 $       GOTO CONFIG_DISABLE_LOOP2
 430 $     CONFIG_DISABLE_LOOP2_END:
 431 $   ENDIF
 432 $   GOTO CONFIG_DISABLE_LOOP0
 433 $ CONFIG_DISABLE_LOOP0_END:
 434 $
 435 $! Apply cascading enable rules
 436 $ CONFIG_ENABLE_I = 0
 437 $ CONFIG_ENABLE_LOOP0:
 438 $   CONFIG_ENABLE_E = F$EDIT(F$ELEMENT(CONFIG_ENABLE_I,";", -
 439      CONFIG_ENABLE_RULES),"TRIM")
 440 $   CONFIG_ENABLE_I = CONFIG_ENABLE_I + 1
 441 $   IF CONFIG_ENABLE_E .EQS. "" THEN GOTO CONFIG_ENABLE_LOOP0
 442 $   IF CONFIG_ENABLE_E .EQS. ";" THEN GOTO CONFIG_ENABLE_LOOP0_END
 443 $
 444 $   CONFIG_ENABLE_ALGOS = F$EDIT(F$ELEMENT(0,"/",CONFIG_ENABLE_E),"TRIM")
 445 $   CONFIG_ENABLE_DEPENDENTS = F$EDIT(F$ELEMENT(1,"/",CONFIG_ENABLE_E),"TRIM")
 446 $   TO_ENABLE := YES
 447 $   CONFIG_ALGO_I = 0
 448 $   CONFIG_ENABLE_LOOP1:
 449 $     CONFIG_ALGO_E = F$EDIT(F$ELEMENT(CONFIG_ALGO_I,",", -
 450        CONFIG_ENABLE_ALGOS),"TRIM")
 451 $     CONFIG_ALGO_I = CONFIG_ALGO_I + 1
 452 $     IF CONFIG_ALGO_E .EQS. "" THEN GOTO CONFIG_ENABLE_LOOP1
 453 $     IF CONFIG_ALGO_E .EQS. "," THEN GOTO CONFIG_ENABLE_LOOP1_END
 454 $     IF F$TYPE(CONFIG_ENABLED_'CONFIG_ALGO_E') .EQS. ""
 455 $     THEN
 456 $       TO_ENABLE := NO
 457 $     ELSE
 458 $       IF .NOT. CONFIG_ENABLED_'CONFIG_ALGO_E' THEN TO_ENABLE := NO
 459 $     ENDIF
 460 $     GOTO CONFIG_ENABLE_LOOP1
 461 $   CONFIG_ENABLE_LOOP1_END:
 462 $
 463 $   IF TO_ENABLE
 464 $   THEN
 465 $     CONFIG_DEPENDENT_I = 0
 466 $     CONFIG_ENABLE_LOOP2:
 467 $       CONFIG_DEPENDENT_E = F$EDIT(F$ELEMENT(CONFIG_DEPENDENT_I,",", -
 468          CONFIG_ENABLE_DEPENDENTS),"TRIM")
 469 $       CONFIG_DEPENDENT_I = CONFIG_DEPENDENT_I + 1
 470 $       IF CONFIG_DEPENDENT_E .EQS. "" THEN GOTO CONFIG_ENABLE_LOOP2
 471 $       IF CONFIG_DEPENDENT_E .EQS. "," THEN GOTO CONFIG_ENABLE_LOOP2_END
 472 $       CONFIG_DISABLED_'CONFIG_DEPENDENT_E' := NO
 473 $       CONFIG_ENABLED_'CONFIG_DEPENDENT_E' := YES
 474 $       ! Better not to assume defaults at this point...
 475 $       CONFIG_CHANGED_'CONFIG_DEPENDENT_E' := YES
 476 $       WRITE SYS$ERROR -
 477          "''CONFIG_DEPENDENT_E' enabled by rule ''CONFIG_ENABLE_E'"
 478 $       GOTO CONFIG_ENABLE_LOOP2
 479 $     CONFIG_ENABLE_LOOP2_END:
 480 $   ENDIF
 481 $   GOTO CONFIG_ENABLE_LOOP0
 482 $ CONFIG_ENABLE_LOOP0_END:
 483 $
 484 $! Write to the configuration
 485 $ CONFIG_LOG_I = 0
 486 $ CONFIG_LOG_LOOP2:
 487 $   CONFIG_LOG_E = F$EDIT(F$ELEMENT(CONFIG_LOG_I,",",CONFIG_LOGICALS),"TRIM")
 488 $   CONFIG_LOG_I = CONFIG_LOG_I + 1
 489 $   IF CONFIG_LOG_E .EQS. "" THEN GOTO CONFIG_LOG_LOOP2
 490 $   IF CONFIG_LOG_E .EQS. "," THEN GOTO CONFIG_LOG_LOOP2_END
 491 $   IF CONFIG_CHANGED_'CONFIG_LOG_E'
 492 $   THEN
 493 $     IF CONFIG_DISABLED_'CONFIG_LOG_E'
 494 $     THEN
 495 $       WRITE H_FILE "#ifndef OPENSSL_NO_",CONFIG_LOG_E
 496 $       WRITE H_FILE "# define OPENSSL_NO_",CONFIG_LOG_E
 497 $       WRITE H_FILE "#endif"
 498 $     ELSE
 499 $       WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E
 500 $       WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E
 501 $       WRITE H_FILE "#endif"
 502 $     ENDIF
 503 $   ENDIF
 504 $   GOTO CONFIG_LOG_LOOP2
 505 $ CONFIG_LOG_LOOP2_END:
 506 $!
 507 $ WRITE H_FILE ""
 508 $ WRITE H_FILE "/* 2011-02-23 SMS."
 509 $ WRITE H_FILE " * On VMS (V8.3), setvbuf() doesn't support a 64-bit"
 510 $ WRITE H_FILE " * ""in"" pointer, and the help says:"
 511 $ WRITE H_FILE " *       Please note that the previously documented"
 512 $ WRITE H_FILE " *       value _IONBF is not supported."
 513 $ WRITE H_FILE " * So, skip it on VMS."
 514 $ WRITE H_FILE " */"
 515 $ WRITE H_FILE "#define OPENSSL_NO_SETVBUF_IONBF"
 516 $ WRITE H_FILE "/* STCP support comes with TCPIP 5.7 ECO 2 "
 517 $ WRITE H_FILE " * enable on newer systems / 2012-02-24 arpadffy */"
 518 $ WRITE H_FILE "#define OPENSSL_NO_SCTP"
 519 $ WRITE H_FILE "#define OPENSSL_NO_LIBUNBOUND"
 520 $ WRITE H_FILE ""
 521 $!
 522 $! Add in the common "crypto/opensslconf.h.in".
 523 $!
 524 $ TYPE 'OPENSSLCONF_H_IN' /OUTPUT=H_FILE:
 525 $!
 526 $ IF ARCH .NES. "VAX"
 527 $ THEN
 528 $!
 529 $!  Write the non-VAX specific data
 530 $!
 531 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 532 $   WRITE H_FILE "#undef RC4_INT"
 533 $   WRITE H_FILE "#define RC4_INT unsigned int"
 534 $   WRITE H_FILE "#undef RC4_CHUNK"
 535 $   WRITE H_FILE "#define RC4_CHUNK unsigned long long"
 536 $   WRITE H_FILE "#endif"
 537 $!
 538 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 539 $   WRITE H_FILE "#undef DES_LONG"
 540 $   WRITE H_FILE "#define DES_LONG unsigned int"
 541 $   WRITE H_FILE "#undef DES_PTR"
 542 $   WRITE H_FILE "#define DES_PTR"
 543 $   WRITE H_FILE "#undef DES_RISC1"
 544 $   WRITE H_FILE "#undef DES_RISC2"
 545 $   WRITE H_FILE "#define DES_RISC1"
 546 $   WRITE H_FILE "#undef DES_UNROLL"
 547 $   WRITE H_FILE "#define DES_UNROLL"
 548 $   WRITE H_FILE "#endif"
 549 $!
 550 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 551 $   WRITE H_FILE "#undef BN_LLONG"      ! Never define with SIXTY_FOUR_BIT
 552 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 553 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 554 $   WRITE H_FILE "#define SIXTY_FOUR_BIT"
 555 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 556 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 557 $   WRITE H_FILE "#undef EIGHT_BIT"
 558 $   WRITE H_FILE "#endif"
 559 $
 560 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 561 $!
 562 $!  Else...
 563 $!
 564 $ ELSE
 565 $!
 566 $!  Write the VAX specific data
 567 $!
 568 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 569 $   WRITE H_FILE "#undef RC4_INT"
 570 $   WRITE H_FILE "#define RC4_INT unsigned char"
 571 $   WRITE H_FILE "#undef RC4_CHUNK"
 572 $   WRITE H_FILE "#define RC4_CHUNK unsigned long"
 573 $   WRITE H_FILE "#endif"
 574 $!
 575 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 576 $   WRITE H_FILE "#undef DES_LONG"
 577 $   WRITE H_FILE "#define DES_LONG unsigned long"
 578 $   WRITE H_FILE "#undef DES_PTR"
 579 $   WRITE H_FILE "#define DES_PTR"
 580 $   WRITE H_FILE "#undef DES_RISC1"
 581 $   WRITE H_FILE "#undef DES_RISC2"
 582 $   WRITE H_FILE "#undef DES_UNROLL"
 583 $   WRITE H_FILE "#endif"
 584 $!
 585 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 586 $   WRITE H_FILE "#undef BN_LLONG"      ! VAX C/DEC C doesn't have long long
 587 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 588 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 589 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 590 $   WRITE H_FILE "#define THIRTY_TWO_BIT"
 591 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 592 $   WRITE H_FILE "#undef EIGHT_BIT"
 593 $   WRITE H_FILE "#endif"
 594 $!
 595 $! Oddly enough, the following symbol is tested in crypto/sha/sha512.c
 596 $! before sha.h gets included (and HEADER_SHA_H defined), so we will not
 597 $! protect this one...
 598 $   WRITE H_FILE "#undef OPENSSL_NO_SHA512"
 599 $   WRITE H_FILE "#define OPENSSL_NO_SHA512"
 600 $!
 601 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 602 $   WRITE H_FILE "#define OPENSSL_EXPORT_VAR_AS_FUNCTION"
 603 $!
 604 $!  End
 605 $!
 606 $ ENDIF
 607 $!
 608 $! Close the [.CRYPTO._xxx]OPENSSLCONF.H file
 609 $!
 610 $ CLOSE H_FILE
 611 $!
 612 $! Purge The [.CRYPTO._xxx]OPENSSLCONF.H file
 613 $!
 614 $ PURGE SYS$DISK:[.CRYPTO.'ARCHD']OPENSSLCONF.H
 615 $!
 616 $! That's All, Time To RETURN.
 617 $!
 618 $ RETURN
 619 $!
 620 $! Rebuild The "[.CRYPTO._xxx]BUILDINF.H" file.
 621 $!
 622 $ BUILDINF:
 623 $!
 624 $! Tell The User We Are Creating The [.CRYPTO._xxx]BUILDINF.H File.
 625 $!
 626 $ WRITE SYS$OUTPUT "Creating [.CRYPTO.''ARCHD']BUILDINF.H Include File."
 627 $!
 628 $! Create The [.CRYPTO._xxx]BUILDINF.H File.
 629 $!
 630 $ BIH_NAME = "SYS$DISK:[.CRYPTO.''ARCHD']BUILDINF.H"
 631 $ CREATE /FDL=SYS$INPUT: 'BIH_NAME'
 632 RECORD
 633         FORMAT stream_lf
 634 $!
 635 $ OPEN /APPEND H_FILE 'bih_name'
 636 $!
 637 $! Get The Current Date & Time.
 638 $!
 639 $ TIME = F$TIME()
 640 $!
 641 $! Write The [.CRYPTO._xxx]BUILDINF.H File.
 642 $!
 643 $ CFLAGS = ""
 644 $ if (POINTER_SIZE .nes. "")
 645 $ then
 646 $   CFLAGS = CFLAGS+ "/POINTER_SIZE=''POINTER_SIZE'"
 647 $ endif
 648 $ if (ZLIB .nes. "")
 649 $ then
 650 $   if (CFLAGS .nes. "") then CFLAGS = CFLAGS+ " "
 651 $   CFLAGS = CFLAGS+ "/DEFINE=ZLIB"
 652 $ endif
 653 $!
 654 $ WRITE H_FILE "#define CFLAGS ""''CFLAGS'"""
 655 $ WRITE H_FILE "#define PLATFORM ""VMS ''ARCHD' ''VMS_VERSION'"""
 656 $ WRITE H_FILE "#define DATE ""''TIME'"" "
 657 $!
 658 $! Close The [.CRYPTO._xxx]BUILDINF.H File.
 659 $!
 660 $ CLOSE H_FILE
 661 $!
 662 $! Purge The [.CRYPTO._xxx]BUILDINF.H File.
 663 $!
 664 $ PURGE SYS$DISK:[.CRYPTO.'ARCHD']BUILDINF.H
 665 $!
 666 $! Delete [.CRYPTO]BUILDINF.H File, as there might be some residue from Unix.
 667 $!
 668 $ IF F$SEARCH("[.CRYPTO]BUILDINF.H") .NES. "" THEN -
 669      DELETE SYS$DISK:[.CRYPTO]BUILDINF.H;*
 670 $!
 671 $! That's All, Time To RETURN.
 672 $!
 673 $ RETURN
 674 $!
 675 $! Copy a lot of files around.
 676 $!
 677 $ SOFTLINKS:
 678 $!
 679 $!!!! Tell The User We Are Partly Rebuilding The [.APPS] Directory.
 680 $!!!!
 681 $!!! WRITE SYS$OUTPUT "Rebuilding The '[.APPS]MD4.C' File."
 682 $!!!!
 683 $!!! DELETE SYS$DISK:[.APPS]MD4.C;*
 684 $!!!!
 685 $!!!! Copy MD4.C from [.CRYPTO.MD4] into [.APPS]
 686 $!!!!
 687 $!!! COPY SYS$DISK:[.CRYPTO.MD4]MD4.C SYS$DISK:[.APPS]
 688 $!
 689 $! Ensure that the [.include.openssl] directory contains a full set of
 690 $! real header files.  The distribution kit may have left real or fake
 691 $! symlinks there.  Rather than think about what's there, simply delete
 692 $! the destination files (fake or real symlinks) before copying the real
 693 $! header files in.  (Copying a real header file onto a real symlink
 694 $! merely duplicates the real header file at its source.)
 695 $!
 696 $! Tell The User We Are Rebuilding The [.include.openssl] Directory.
 697 $!
 698 $ WRITE SYS$OUTPUT "Rebuilding The '[.include.openssl]' Directory."
 699 $!
 700 $! First, make sure the directory exists.  If it did exist, delete all
 701 $! the existing header files (or fake or real symlinks).
 702 $!
 703 $ if f$parse( "sys$disk:[.include.openssl]") .eqs. ""
 704 $ then
 705 $   create /directory sys$disk:[.include.openssl]
 706 $ else
 707 $   delete sys$disk:[.include.openssl]*.h;*
 708 $ endif
 709 $!
 710 $! Copy All The ".H" Files From The Main Directory.
 711 $!
 712 $ EXHEADER := e_os2.h
 713 $ copy 'exheader' sys$disk:[.include.openssl]
 714 $!
 715 $! Copy All The ".H" Files From The [.CRYPTO] Directory Tree.
 716 $!
 717 $ SDIRS := , -
 718    'ARCHD', -
 719    OBJECTS, -
 720    MD4, MD5, SHA, MDC2, HMAC, RIPEMD, WHRLPOOL, -
 721    DES, AES, RC2, RC4, IDEA, BF, CAST, CAMELLIA, SEED, MODES, -
 722    BN, EC, RSA, DSA, ECDSA, DH, ECDH, DSO, ENGINE, -
 723    BUFFER, BIO, STACK, LHASH, RAND, ERR, -
 724    EVP, ASN1, PEM, X509, X509V3, CONF, TXT_DB, PKCS7, PKCS12, -
 725    COMP, OCSP, UI, KRB5, -
 726    CMS, PQUEUE, TS, JPAKE, SRP, STORE, CMAC
 727 $!
 728 $ EXHEADER_ := crypto.h, opensslv.h, ebcdic.h, symhacks.h, ossl_typ.h
 729 $ EXHEADER_'ARCHD' := opensslconf.h
 730 $ EXHEADER_OBJECTS := objects.h, obj_mac.h
 731 $ EXHEADER_MD2 := md2.h
 732 $ EXHEADER_MD4 := md4.h
 733 $ EXHEADER_MD5 := md5.h
 734 $ EXHEADER_SHA := sha.h
 735 $ EXHEADER_MDC2 := mdc2.h
 736 $ EXHEADER_HMAC := hmac.h
 737 $ EXHEADER_RIPEMD := ripemd.h
 738 $ EXHEADER_WHRLPOOL := whrlpool.h
 739 $ EXHEADER_DES := des.h, des_old.h
 740 $ EXHEADER_AES := aes.h
 741 $ EXHEADER_RC2 := rc2.h
 742 $ EXHEADER_RC4 := rc4.h
 743 $ EXHEADER_RC5 := rc5.h
 744 $ EXHEADER_IDEA := idea.h
 745 $ EXHEADER_BF := blowfish.h
 746 $ EXHEADER_CAST := cast.h
 747 $ EXHEADER_CAMELLIA := camellia.h
 748 $ EXHEADER_SEED := seed.h
 749 $ EXHEADER_MODES := modes.h
 750 $ EXHEADER_BN := bn.h
 751 $ EXHEADER_EC := ec.h
 752 $ EXHEADER_RSA := rsa.h
 753 $ EXHEADER_DSA := dsa.h
 754 $ EXHEADER_ECDSA := ecdsa.h
 755 $ EXHEADER_DH := dh.h
 756 $ EXHEADER_ECDH := ecdh.h
 757 $ EXHEADER_DSO := dso.h
 758 $ EXHEADER_ENGINE := engine.h
 759 $ EXHEADER_BUFFER := buffer.h
 760 $ EXHEADER_BIO := bio.h
 761 $ EXHEADER_STACK := stack.h, safestack.h
 762 $ EXHEADER_LHASH := lhash.h
 763 $ EXHEADER_RAND := rand.h
 764 $ EXHEADER_ERR := err.h
 765 $ EXHEADER_EVP := evp.h
 766 $ EXHEADER_ASN1 := asn1.h, asn1_mac.h, asn1t.h
 767 $ EXHEADER_PEM := pem.h, pem2.h
 768 $ EXHEADER_X509 := x509.h, x509_vfy.h
 769 $ EXHEADER_X509V3 := x509v3.h
 770 $ EXHEADER_CONF := conf.h, conf_api.h
 771 $ EXHEADER_TXT_DB := txt_db.h
 772 $ EXHEADER_PKCS7 := pkcs7.h
 773 $ EXHEADER_PKCS12 := pkcs12.h
 774 $ EXHEADER_COMP := comp.h
 775 $ EXHEADER_OCSP := ocsp.h
 776 $ EXHEADER_UI := ui.h, ui_compat.h
 777 $ EXHEADER_KRB5 := krb5_asn.h
 778 $ EXHEADER_CMS := cms.h
 779 $ EXHEADER_PQUEUE := pqueue.h
 780 $ EXHEADER_TS := ts.h
 781 $ EXHEADER_JPAKE := jpake.h
 782 $ EXHEADER_SRP := srp.h
 783 $!!! EXHEADER_STORE := store.h, str_compat.h
 784 $ EXHEADER_STORE := store.h
 785 $ EXHEADER_CMAC := cmac.h
 786 $!
 787 $ i = 0
 788 $ loop_sdirs:
 789 $   sdir = f$edit( f$element( i, ",", sdirs), "trim")
 790 $   i = i + 1
 791 $   if (sdir .eqs. ",") then goto loop_sdirs_end
 792 $   hdr_list = exheader_'sdir'
 793 $   if (sdir .nes. "") then sdir = "."+ sdir
 794 $   copy [.crypto'sdir']'hdr_list' sys$disk:[.include.openssl]
 795 $ goto loop_sdirs
 796 $ loop_sdirs_end:
 797 $!
 798 $! Copy All The ".H" Files From The [.SSL] Directory.
 799 $!
 800 $! (keep these in the same order as ssl/Makefile)
 801 $ EXHEADER := ssl.h, ssl2.h, ssl3.h, ssl23.h, tls1.h, dtls1.h, kssl.h, srtp.h
 802 $ copy sys$disk:[.ssl]'exheader' sys$disk:[.include.openssl]
 803 $!
 804 $! Purge the [.include.openssl] header files.
 805 $!
 806 $ purge sys$disk:[.include.openssl]*.h
 807 $!
 808 $! That's All, Time To RETURN.
 809 $!
 810 $ RETURN
 811 $!
 812 $! Build The "[.xxx.EXE.CRYPTO]SSL_LIBCRYPTO''LIB32'.OLB" Library.
 813 $!
 814 $ CRYPTO:
 815 $!
 816 $! Tell The User What We Are Doing.
 817 $!
 818 $ WRITE SYS$OUTPUT ""
 819 $ WRITE SYS$OUTPUT -
 820    "Building The [.",ARCHD,".EXE.CRYPTO]SSL_LIBCRYPTO''LIB32'.OLB Library."
 821 $!
 822 $! Go To The [.CRYPTO] Directory.
 823 $!
 824 $ SET DEFAULT SYS$DISK:[.CRYPTO]
 825 $!
 826 $! Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 827 $!
 828 $ @CRYPTO-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" -
 829    "''ISSEVEN'" "''BUILDPART'" "''POINTER_SIZE'" "''ZLIB'"
 830 $!
 831 $! Build The [.xxx.EXE.CRYPTO]*.EXE Test Applications.
 832 $!
 833 $!!! DISABLED, as these test programs lack any support
 834 $!!!$ @CRYPTO-LIB APPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" -
 835 $!!!   "''ISSEVEN'" "''BUILDPART'" "''POINTER_SIZE'" "''ZLIB'"
 836 $!
 837 $! Go Back To The Main Directory.
 838 $!
 839 $ SET DEFAULT [-]
 840 $!
 841 $! Time To RETURN.
 842 $!
 843 $ RETURN
 844 $!
 845 $! Build The "[.xxx.EXE.SSL]SSL_LIBSSL''LIB32'.OLB" Library.
 846 $!
 847 $ SSL:
 848 $!
 849 $! Tell The User What We Are Doing.
 850 $!
 851 $ WRITE SYS$OUTPUT ""
 852 $ WRITE SYS$OUTPUT -
 853    "Building The [.",ARCHD,".EXE.SSL]SSL_LIBSSL''LIB32'.OLB Library."
 854 $!
 855 $! Go To The [.SSL] Directory.
 856 $!
 857 $ SET DEFAULT SYS$DISK:[.SSL]
 858 $!
 859 $! Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 860 $!
 861 $ @SSL-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" -
 862    "''ISSEVEN'" "''POINTER_SIZE'" "''ZLIB'"
 863 $!
 864 $! Go Back To The Main Directory.
 865 $!
 866 $ SET DEFAULT [-]
 867 $!
 868 $! Time To Return.
 869 $!
 870 $ RETURN
 871 $!
 872 $! Build The "[.xxx.EXE.SSL]SSL_TASK.EXE" Program.
 873 $!
 874 $ SSL_TASK:
 875 $!
 876 $! Tell The User What We Are Doing.
 877 $!
 878 $ WRITE SYS$OUTPUT ""
 879 $ WRITE SYS$OUTPUT -
 880    "Building DECNet Based SSL Engine, [.",ARCHD,".EXE.SSL]SSL_TASK.EXE"
 881 $!
 882 $! Go To The [.SSL] Directory.
 883 $!
 884 $ SET DEFAULT SYS$DISK:[.SSL]
 885 $!
 886 $! Build The [.xxx.EXE.SSL]SSL_TASK.EXE
 887 $!
 888 $ @SSL-LIB SSL_TASK 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" -
 889    "''ISSEVEN'" "''POINTER_SIZE'" "''ZLIB'"
 890 $!
 891 $! Go Back To The Main Directory.
 892 $!
 893 $ SET DEFAULT [-]
 894 $!
 895 $! That's All, Time To RETURN.
 896 $!
 897 $ RETURN
 898 $!
 899 $! Build The OpenSSL Test Programs.
 900 $!
 901 $ TEST:
 902 $!
 903 $! Tell The User What We Are Doing.
 904 $!
 905 $ WRITE SYS$OUTPUT ""
 906 $ WRITE SYS$OUTPUT "Building The OpenSSL [.",ARCHD,".EXE.TEST] Test Utilities."
 907 $!
 908 $! Go To The [.TEST] Directory.
 909 $!
 910 $ SET DEFAULT SYS$DISK:[.TEST]
 911 $!
 912 $! Build The Test Programs.
 913 $!
 914 $ @MAKETESTS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" -
 915    "''POINTER_SIZE'" "''ZLIB'"
 916 $!
 917 $! Go Back To The Main Directory.
 918 $!
 919 $ SET DEFAULT [-]
 920 $!
 921 $! That's All, Time To RETURN.
 922 $!
 923 $ RETURN
 924 $!
 925 $! Build The OpenSSL Application Programs.
 926 $!
 927 $ APPS:
 928 $!
 929 $! Tell The User What We Are Doing.
 930 $!
 931 $ WRITE SYS$OUTPUT ""
 932 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCHD,".EXE.APPS] Applications."
 933 $!
 934 $! Go To The [.APPS] Directory.
 935 $!
 936 $ SET DEFAULT SYS$DISK:[.APPS]
 937 $!
 938 $! Build The Application Programs.
 939 $!
 940 $ @MAKEAPPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" -
 941    "" "''POINTER_SIZE'" "''ZLIB'"
 942 $!
 943 $! Go Back To The Main Directory.
 944 $!
 945 $ SET DEFAULT [-]
 946 $!
 947 $! That's All, Time To RETURN.
 948 $!
 949 $ RETURN
 950 $!
 951 $! Build The OpenSSL Application Programs.
 952 $!
 953 $ ENGINES:
 954 $!
 955 $! Tell The User What We Are Doing.
 956 $!
 957 $ WRITE SYS$OUTPUT ""
 958 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCHD,".EXE.ENGINES] Engines."
 959 $!
 960 $! Go To The [.ENGINES] Directory.
 961 $!
 962 $ SET DEFAULT SYS$DISK:[.ENGINES]
 963 $!
 964 $! Build The Application Programs.
 965 $!
 966 $ @MAKEENGINES ENGINES 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" -
 967    "''ISSEVEN'" "''BUILDPART'" "''POINTER_SIZE'" "''ZLIB'"
 968 $!
 969 $! Go Back To The Main Directory.
 970 $!
 971 $ SET DEFAULT [-]
 972 $!
 973 $! That's All, Time To RETURN.
 974 $!
 975 $ RETURN
 976 $!
 977 $! Check The User's Options.
 978 $!
 979 $ CHECK_OPTIONS:
 980 $!
 981 $! Check if there's a "part", and separate it out
 982 $!
 983 $ BUILDPART = F$ELEMENT(1,"/",P1)
 984 $ IF BUILDPART .EQS. "/"
 985 $ THEN
 986 $   BUILDPART = ""
 987 $ ELSE
 988 $   P1 = F$EXTRACT(0,F$LENGTH(P1) - F$LENGTH(BUILDPART) - 1, P1)
 989 $ ENDIF
 990 $!
 991 $! Check To See If P1 Is Blank.
 992 $!
 993 $ IF (P1.EQS."ALL")
 994 $ THEN
 995 $!
 996 $!   P1 Is ALL, So Build Everything.
 997 $!
 998 $    BUILDCOMMAND = "ALL"
 999 $!
1000 $! Else...
1001 $!
1002 $ ELSE
1003 $!
1004 $!  Else, Check To See If P1 Has A Valid Argument.
1005 $!
1006 $   IF (P1.EQS."CONFIG").OR.(P1.EQS."BUILDINF").OR.(P1.EQS."SOFTLINKS") -
1007        .OR.(P1.EQS."BUILDALL") -
1008        .OR.(P1.EQS."CRYPTO").OR.(P1.EQS."SSL") -
1009        .OR.(P1.EQS."SSL_TASK").OR.(P1.EQS."TEST").OR.(P1.EQS."APPS") -
1010        .OR.(P1.EQS."ENGINES")
1011 $   THEN
1012 $!
1013 $!    A Valid Argument.
1014 $!
1015 $     BUILDCOMMAND = P1
1016 $!
1017 $!  Else...
1018 $!
1019 $   ELSE
1020 $!
1021 $!    Tell The User We Don't Know What They Want.
1022 $!
1023 $     WRITE SYS$OUTPUT ""
1024 $     WRITE SYS$OUTPUT "USAGE:   @MAKEVMS.COM [Target] [Pointer size] [Debug option] <Compiler> <TCP/IP library>"
1025 $     WRITE SYS$OUTPUT ""
1026 $     WRITE SYS$OUTPUT "Example: @MAKEVMS.COM ALL """" NODEBUG DECC TCPIP"
1027 $     WRITE SYS$OUTPUT ""
1028 $     WRITE SYS$OUTPUT "The Target ",P1," Is Invalid.  The Valid Target Options Are:"
1029 $     WRITE SYS$OUTPUT ""
1030 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
1031 $     WRITE SYS$OUTPUT "    CONFIG   :  Just build the [.CRYPTO._xxx]OPENSSLCONF.H file."
1032 $     WRITE SYS$OUTPUT "    BUILDINF :  Just build the [.CRYPTO._xxx]BUILDINF.H file."
1033 $     WRITE SYS$OUTPUT "    SOFTLINKS:  Just Fix The Unix soft links."
1034 $     WRITE SYS$OUTPUT "    BUILDALL :  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done."
1035 $     WRITE SYS$OUTPUT "    CRYPTO   :  To Build Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
1036 $     WRITE SYS$OUTPUT "    CRYPTO/x :  To Build Just The x Part Of The"
1037 $     WRITE SYS$OUTPUT "                [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
1038 $     WRITE SYS$OUTPUT "    SSL      :  To Build Just The [.xxx.EXE.SSL]LIBSSL.OLB Library."
1039 $     WRITE SYS$OUTPUT "    SSL_TASK :  To Build Just The [.xxx.EXE.SSL]SSL_TASK.EXE Program."
1040 $     WRITE SYS$OUTPUT "    TEST     :  To Build Just The OpenSSL Test Programs."
1041 $     WRITE SYS$OUTPUT "    APPS     :  To Build Just The OpenSSL Application Programs."
1042 $     WRITE SYS$OUTPUT "    ENGINES  :  To Build Just The ENGINES"
1043 $     WRITE SYS$OUTPUT ""
1044 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
1045 $     WRITE SYS$OUTPUT ""
1046 $     WRITE SYS$OUTPUT "    ALPHA[64]:  Alpha Architecture."
1047 $     WRITE SYS$OUTPUT "    IA64[64] :  IA64 Architecture."
1048 $     WRITE SYS$OUTPUT "    VAX      :  VAX Architecture."
1049 $     WRITE SYS$OUTPUT ""
1050 $!
1051 $!    Time To EXIT.
1052 $!
1053 $     GOTO TIDY
1054 $!
1055 $!  End The Valid Argument Check.
1056 $!
1057 $   ENDIF
1058 $!
1059 $! End The P1 Check.
1060 $!
1061 $ ENDIF
1062 $!
1063 $! Check P2 (POINTER_SIZE).
1064 $!
1065 $ IF (P2 .NES. "") .AND. (ARCH .NES. "VAX")
1066 $ THEN
1067 $!
1068 $   IF (P2 .EQS. "32")
1069 $   THEN
1070 $     POINTER_SIZE = "32"
1071 $   ELSE
1072 $     POINTER_SIZE = F$EDIT( P2, "COLLAPSE, UPCASE")
1073 $     IF ((POINTER_SIZE .EQS. "64") .OR. -
1074        (POINTER_SIZE .EQS. "64=") .OR. -
1075        (POINTER_SIZE .EQS. "64=ARGV"))
1076 $     THEN
1077 $       ARCHD = ARCH+ "_64"
1078 $       LIB32 = ""
1079 $     ELSE
1080 $!
1081 $!      Tell The User Entered An Invalid Option.
1082 $!
1083 $       WRITE SYS$OUTPUT ""
1084 $       WRITE SYS$OUTPUT "The Option ", P2, -
1085          " Is Invalid.  The Valid Options Are:"
1086 $       WRITE SYS$OUTPUT ""
1087 $       WRITE SYS$OUTPUT -
1088          "    """"       :  Compile with default (short) pointers."
1089 $       WRITE SYS$OUTPUT -
1090          "    32       :  Compile with 32-bit (short) pointers."
1091 $       WRITE SYS$OUTPUT -
1092          "    64       :  Compile with 64-bit (long) pointers (auto ARGV)."
1093 $       WRITE SYS$OUTPUT -
1094          "    64=      :  Compile with 64-bit (long) pointers (no ARGV)."
1095 $       WRITE SYS$OUTPUT -
1096          "    64=ARGV  :  Compile with 64-bit (long) pointers (ARGV)."
1097 $       WRITE SYS$OUTPUT ""
1098 $!
1099 $!      Time To EXIT.
1100 $!
1101 $       GOTO TIDY
1102 $!
1103 $     ENDIF
1104 $!
1105 $   ENDIF
1106 $!
1107 $! End The P2 (POINTER_SIZE) Check.
1108 $!
1109 $ ENDIF
1110 $!
1111 $! Check To See If P3 Is Blank.
1112 $!
1113 $ IF (P3.EQS."NODEBUG")
1114 $ THEN
1115 $!
1116 $!   P3 Is NODEBUG, So Compile Without Debugger Information.
1117 $!
1118 $    DEBUGGER = "NODEBUG"
1119 $!
1120 $! Else...
1121 $!
1122 $ ELSE
1123 $!
1124 $!  Check To See If We Are To Compile With Debugger Information.
1125 $!
1126 $   IF (P3.EQS."DEBUG")
1127 $   THEN
1128 $!
1129 $!    Compile With Debugger Information.
1130 $!
1131 $     DEBUGGER = "DEBUG"
1132 $!
1133 $!  Else...
1134 $!
1135 $   ELSE
1136 $!
1137 $!    Tell The User Entered An Invalid Option.
1138 $!
1139 $     WRITE SYS$OUTPUT ""
1140 $     WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1141 $     WRITE SYS$OUTPUT ""
1142 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
1143 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
1144 $     WRITE SYS$OUTPUT ""
1145 $!
1146 $!    Time To EXIT.
1147 $!
1148 $     GOTO TIDY
1149 $!
1150 $!  End The Valid Argument Check.
1151 $!
1152 $   ENDIF
1153 $!
1154 $! End The P3 Check.
1155 $!
1156 $ ENDIF
1157 $!
1158 $! Check To See If P4 Is Blank.
1159 $!
1160 $ IF (P4.EQS."")
1161 $ THEN
1162 $!
1163 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
1164 $!  Find Out Which One To Use.
1165 $!
1166 $!  Check To See If We Have GNU C.
1167 $!
1168 $   IF (F$TRNLNM("GNU_CC").NES."")
1169 $   THEN
1170 $!
1171 $!    Looks Like GNUC, Set To Use GNUC.
1172 $!
1173 $     COMPILER = "GNUC"
1174 $!
1175 $!    Tell The User We Are Using GNUC.
1176 $!
1177 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1178 $!
1179 $!  End The GNU C Compiler Check.
1180 $!
1181 $   ENDIF
1182 $!
1183 $!  Check To See If We Have VAXC Or DECC.
1184 $!
1185 $   IF (F$GETSYI("CPU").GE.128).OR.(F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC")
1186 $   THEN
1187 $!
1188 $!    Looks Like DECC, Set To Use DECC.
1189 $!
1190 $     COMPILER = "DECC"
1191 $!
1192 $!    Tell The User We Are Using DECC.
1193 $!
1194 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1195 $!
1196 $!  Else...
1197 $!
1198 $   ELSE
1199 $!
1200 $!    Looks Like VAXC, Set To Use VAXC.
1201 $!
1202 $     COMPILER = "VAXC"
1203 $!
1204 $!    Tell The User We Are Using VAX C.
1205 $!
1206 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1207 $!
1208 $!  End The DECC & VAXC Compiler Check.
1209 $!
1210 $   ENDIF
1211 $!
1212 $! Else...
1213 $!
1214 $ ELSE
1215 $!
1216 $!  Check To See If The User Entered A Valid Parameter.
1217 $!
1218 $   IF (P4.EQS."VAXC").OR.(P4.EQS."DECC").OR.(P4.EQS."GNUC")!.OR.(P4.EQS."LINK")
1219 $   THEN
1220 $!
1221 $!    Check To See If The User Wanted To Just LINK.
1222 $!
1223 $     IF (P4.EQS."LINK")
1224 $     THEN
1225 $!
1226 $!      Looks Like LINK-only
1227 $!
1228 $       COMPILER = "LINK"
1229 $!
1230 $!      Tell The User We Are Only Linking.
1231 $!
1232 $       WRITE SYS$OUTPUT "LINK Only.  This actually NOT YET SUPPORTED!"
1233 $!
1234 $!    End LINK Check.
1235 $!
1236 $     ENDIF
1237 $!
1238 $!    Check To See If The User Wanted DECC.
1239 $!
1240 $     IF (P4.EQS."DECC")
1241 $     THEN
1242 $!
1243 $!      Looks Like DECC, Set To Use DECC.
1244 $!
1245 $       COMPILER = "DECC"
1246 $!
1247 $!      Tell The User We Are Using DECC.
1248 $!
1249 $       WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1250 $!
1251 $!    End DECC Check.
1252 $!
1253 $     ENDIF
1254 $!
1255 $!    Check To See If We Are To Use VAXC.
1256 $!
1257 $     IF (P4.EQS."VAXC")
1258 $     THEN
1259 $!
1260 $!      Looks Like VAXC, Set To Use VAXC.
1261 $!
1262 $       COMPILER = "VAXC"
1263 $!
1264 $!      Tell The User We Are Using VAX C.
1265 $!
1266 $       WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1267 $!
1268 $!    End VAXC Check
1269 $!
1270 $     ENDIF
1271 $!
1272 $!    Check To See If We Are To Use GNU C.
1273 $!
1274 $     IF (P4.EQS."GNUC")
1275 $     THEN
1276 $!
1277 $!      Looks Like GNUC, Set To Use GNUC.
1278 $!
1279 $       COMPILER = "GNUC"
1280 $!
1281 $!      Tell The User We Are Using GNUC.
1282 $!
1283 $       WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1284 $!
1285 $!    End The GNU C Check.
1286 $!
1287 $     ENDIF
1288 $!
1289 $!  Else The User Entered An Invalid Argument.
1290 $!
1291 $   ELSE
1292 $!
1293 $!    Tell The User We Don't Know What They Want.
1294 $!
1295 $     WRITE SYS$OUTPUT ""
1296 $     WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1297 $     WRITE SYS$OUTPUT ""
1298 $     WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1299 $     WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1300 $     WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1301 $     WRITE SYS$OUTPUT ""
1302 $!
1303 $!    Time To EXIT.
1304 $!
1305 $     GOTO TIDY
1306 $!
1307 $!  End The Valid Argument Check.
1308 $!
1309 $   ENDIF
1310 $!
1311 $! End The P4 Check.
1312 $!
1313 $ ENDIF
1314 $!
1315 $! Time to check the contents of P5, and to make sure we get the correct
1316 $! library.
1317 $!
1318 $ IF P5.EQS."SOCKETSHR" .OR. P5.EQS."MULTINET" .OR. P5.EQS."UCX" -
1319      .OR. P5.EQS."TCPIP" .OR. P5.EQS."NONE"
1320 $ THEN
1321 $!
1322 $!  Check to see if SOCKETSHR was chosen
1323 $!
1324 $   IF P5.EQS."SOCKETSHR"
1325 $   THEN
1326 $!
1327 $!    Set the library to use SOCKETSHR
1328 $!
1329 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT /OPTIONS"
1330 $!
1331 $!    Tell the user
1332 $!
1333 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
1334 $!
1335 $!    Done with SOCKETSHR
1336 $!
1337 $   ENDIF
1338 $!
1339 $!  Check to see if MULTINET was chosen
1340 $!
1341 $   IF P5.EQS."MULTINET"
1342 $   THEN
1343 $!
1344 $!    Set the library to use UCX emulation.
1345 $!
1346 $     P5 = "UCX"
1347 $!
1348 $!    Tell the user
1349 $!
1350 $     WRITE SYS$OUTPUT "Using MultiNet via UCX emulation for TCP/IP"
1351 $!
1352 $!    Done with MULTINET
1353 $!
1354 $   ENDIF
1355 $!
1356 $!  Check to see if UCX was chosen
1357 $!
1358 $   IF P5.EQS."UCX"
1359 $   THEN
1360 $!
1361 $!    Set the library to use UCX.
1362 $!
1363 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT /OPTIONS"
1364 $!
1365 $!    Tell the user
1366 $!
1367 $     WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
1368 $!
1369 $!    Done with UCX
1370 $!
1371 $   ENDIF
1372 $!
1373 $!  Check to see if TCPIP was chosen
1374 $!
1375 $   IF P5.EQS."TCPIP"
1376 $   THEN
1377 $!
1378 $!    Set the library to use TCPIP (post UCX).
1379 $!
1380 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT /OPTIONS"
1381 $!
1382 $!    Tell the user
1383 $!
1384 $     WRITE SYS$OUTPUT "Using TCPIP (post UCX) for TCP/IP"
1385 $!
1386 $!    Done with TCPIP
1387 $!
1388 $   ENDIF
1389 $!
1390 $!  Check to see if NONE was chosen
1391 $!
1392 $   IF P5.EQS."NONE"
1393 $   THEN
1394 $!
1395 $!    Do not use a TCPIP library.
1396 $!
1397 $     TCPIP_LIB = ""
1398 $!
1399 $!    Tell the user
1400 $!
1401 $     WRITE SYS$OUTPUT "A specific TCPIP library will not be used."
1402 $!
1403 $!    Done with NONE.
1404 $!
1405 $   ENDIF
1406 $!
1407 $!  Set the TCPIP_TYPE symbol
1408 $!
1409 $   TCPIP_TYPE = P5
1410 $!
1411 $!  Print info
1412 $!
1413 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1414 $!
1415 $!  Else The User Entered An Invalid Argument.
1416 $!
1417 $ ELSE
1418 $   IF P5 .NES. ""
1419 $   THEN
1420 $!
1421 $!    Tell The User We Don't Know What They Want.
1422 $!
1423 $     WRITE SYS$OUTPUT ""
1424 $     WRITE SYS$OUTPUT "The Option ",P5," Is Invalid.  The Valid Options Are:"
1425 $     WRITE SYS$OUTPUT ""
1426 $     WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1427 $     WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1428 $     WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP TCP/IP (post UCX) library."
1429 $     WRITE SYS$OUTPUT "    NONE       :  To not link with a specific TCP/IP library."
1430 $     WRITE SYS$OUTPUT ""
1431 $!
1432 $!    Time To EXIT.
1433 $!
1434 $     GOTO TIDY
1435 $   ELSE
1436 $!
1437 $! If TCPIP is not defined, then hardcode it to make
1438 $! it clear that no TCPIP is desired.
1439 $!
1440 $     IF P5 .EQS. ""
1441 $     THEN
1442 $       TCPIP_LIB = ""
1443 $       TCPIP_TYPE = "NONE"
1444 $     ELSE
1445 $!
1446 $!    Set the TCPIP_TYPE symbol
1447 $!
1448 $       TCPIP_TYPE = P5
1449 $     ENDIF
1450 $   ENDIF
1451 $!
1452 $!  Done with TCP/IP libraries
1453 $!
1454 $ ENDIF
1455 $!
1456 $! Special Threads For OpenVMS v7.1 Or Later
1457 $!
1458 $! Written By:  Richard Levitte
1459 $!              richard@levitte.org
1460 $!
1461 $!
1462 $! Check To See If We Have A Option For P6.
1463 $!
1464 $ IF (P6.EQS."")
1465 $ THEN
1466 $!
1467 $!  Get The Version Of VMS We Are Using.
1468 $!
1469 $   ISSEVEN :=
1470 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,VMS_VERSION))
1471 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1472 $!
1473 $!  Check To See If The VMS Version Is v7.1 Or Later.
1474 $!
1475 $   IF (TMP.GE.71)
1476 $   THEN
1477 $!
1478 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1479 $!
1480 $     ISSEVEN := ,PTHREAD_USE_D4
1481 $!
1482 $!  End The VMS Version Check.
1483 $!
1484 $   ENDIF
1485 $!
1486 $! End The P6 Check.
1487 $!
1488 $ ENDIF
1489 $!
1490 $!
1491 $! Check To See If We Have A ZLIB Option.
1492 $!
1493 $ ZLIB = P7
1494 $ IF (ZLIB .NES. "")
1495 $ THEN
1496 $!
1497 $!  Check for expected ZLIB files.
1498 $!
1499 $   err = 0
1500 $   file1 = f$parse( "zlib.h", ZLIB, , , "SYNTAX_ONLY")
1501 $   if (f$search( file1) .eqs. "")
1502 $   then
1503 $     WRITE SYS$OUTPUT ""
1504 $     WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
1505 $     WRITE SYS$OUTPUT "    Can't find header: ''file1'"
1506 $     err = 1
1507 $   endif
1508 $!
1509 $   file2 = f$parse( ZLIB, "libz.olb", , , "SYNTAX_ONLY")
1510 $   if (f$search( file2) .eqs. "")
1511 $   then
1512 $     if (err .eq. 0)
1513 $     then
1514 $       WRITE SYS$OUTPUT ""
1515 $       WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
1516 $     endif
1517 $     WRITE SYS$OUTPUT "    Can't find library: ''file2'"
1518 $     WRITE SYS$OUTPUT ""
1519 $     err = err+ 2
1520 $   endif
1521 $   if (err .eq. 1)
1522 $   then
1523 $     WRITE SYS$OUTPUT ""
1524 $   endif
1525 $!
1526 $   if (err .ne. 0)
1527 $   then
1528 $     GOTO TIDY
1529 $   endif
1530 $!
1531 $!  Print info
1532 $!
1533 $   WRITE SYS$OUTPUT "ZLIB library spec: ", file2
1534 $!
1535 $! End The ZLIB Check.
1536 $!
1537 $ ENDIF
1538 $!
1539 $!  Time To RETURN...
1540 $!
1541 $ RETURN
1542 $!
1543 $ TIDY:
1544 $!
1545 $! Close any open files.
1546 $!
1547 $ if (f$trnlnm( "h_file", "LNM$PROCESS", 0, "SUPERVISOR") .nes. "") then -
1548    close h_file
1549 $!
1550 $! Restore the original default device:[directory].
1551 $!
1552 $ SET DEFAULT 'DEF_ORIG'
1553 $!
1554 $ EXIT
1555 $!