makevms.com

   1 $!
   2 $! MAKEVMS.COM
   3 $! Original Author:  UNKNOWN
   4 $! Rewritten By:  Robert Byer
   5 $!                Vice-President
   6 $!                A-Com Computing, Inc.
   7 $!                byer@mail.all-net.net
   8 $!
   9 $! Changes by Richard Levitte <richard@levitte.org>
  10 $!
  11 $! This procedure creates the SSL libraries of "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  12 $! "[.xxx.EXE.SSL]LIBSSL.OLB" and if specified "[.xxx.EXE.RSAREF]LIBRSAGLUE.OLB".
  13 $! The "xxx" denotes the machine architecture of AXP or VAX.
  14 $!
  15 $! This procedures accepts two command line options listed below.
  16 $!
  17 $! Specify one of the following build options for P1.
  18 $!
  19 $!      ALL       Just build "everything".
  20 $!      CONFIG    Just build the "[.CRYPTO]OPENSSLCONF.H" file.
  21 $!      BUILDINF  Just build the "[.CRYPTO]BUILDINF.H" file.
  22 $!      SOFTLINKS Just fix the Unix soft links.
  23 $!      BUILDALL  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done.
  24 $!      RSAREF    Just build the "[.xxx.EXE.RSAREF]LIBRSAGLUE.OLB" library.
  25 $!      CRYPTO    Just build the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  26 $!      CRYPTO/x  Just build the x part of the
  27 $!                "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  28 $!      SSL       Just build the "[.xxx.EXE.SSL]LIBSSL.OLB" library.
  29 $!      SSL_TASK  Just build the "[.xxx.EXE.SSL]SSL_TASK.EXE" program.
  30 $!      TEST      Just build the "[.xxx.EXE.TEST]" test programs for OpenSSL.
  31 $!      APPS      Just build the "[.xxx.EXE.APPS]" application programs for OpenSSL.
  32 $!
  33 $!
  34 $! Specify RSAREF as P2 to compile using the RSAREF Library.
  35 $! If you specify NORSAREF, it will compile without using RSAREF.
  36 $! (If in the United States, You Must Compile Using RSAREF).
  37 $!
  38 $! Note: The RSAREF libraries are NOT INCLUDED and you have to
  39 $!       download it from "ftp://ftp.rsa.com/rsaref".  You have to
  40 $!       get the ".tar-Z" file as the ".zip" file dosen't have the
  41 $!       directory structure stored.  You have to extract the file
  42 $!       into the [.RSAREF] directory as that is where the scripts
  43 $!       will look for the files.
  44 $!
  45 $! Speficy DEBUG or NODEBUG as P3 to compile with or without debugging
  46 $! information.
  47 $!
  48 $! Specify which compiler at P4 to try to compile under.
  49 $!
  50 $!        VAXC   For VAX C.
  51 $!        DECC   For DEC C.
  52 $!        GNUC   For GNU C.
  53 $!        LINK   To only link the programs from existing object files.
  54 $!               (not yet implemented)
  55 $!
  56 $! If you don't speficy a compiler, it will try to determine which
  57 $! "C" compiler to use.
  58 $!
  59 $!  P5, if defined, sets a TCP/IP library to use, through one of the following
  60 $!  keywords:
  61 $!
  62 $!      UCX             for UCX or UCX emulation
  63 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  64 $!
  65 $! P6, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  66 $!
  67 $!
  68 $! Check if we're in a batch job, and make sure we get to
  69 $! the directory this script is in
  70 $!
  71 $ IF F$MODE() .EQS. "BATCH"
  72 $ THEN
  73 $   COMNAME=F$ENVIRONMENT("PROCEDURE")
  74 $   COMPATH=F$PARSE("A.;",COMNAME) - "A.;"
  75 $   SET DEF 'COMPATH'
  76 $ ENDIF
  77 $!
  78 $! Check Which Architecture We Are Using.
  79 $!
  80 $ IF (F$GETSYI("CPU").GE.128)
  81 $ THEN
  82 $!
  83 $!  The Architecture Is AXP.
  84 $!
  85 $   ARCH := AXP
  86 $!
  87 $! Else...
  88 $!
  89 $ ELSE
  90 $!
  91 $!  The Architecture Is VAX.
  92 $!
  93 $   ARCH := VAX
  94 $!
  95 $! End The Architecture Check.
  96 $!
  97 $ ENDIF
  98 $!
  99 $! Check To Make Sure We Have Valid Command Line Parameters.
 100 $!
 101 $ GOSUB CHECK_OPTIONS
 102 $!
 103 $! Check To See What We Are To Do.
 104 $!
 105 $ IF (BUILDCOMMAND.EQS."ALL")
 106 $ THEN
 107 $!
 108 $!  Start with building the OpenSSL configuration file.
 109 $!
 110 $   GOSUB CONFIG
 111 $!
 112 $!  Create The "BUILDINF.H" Include File.
 113 $!
 114 $   GOSUB BUILDINF
 115 $!
 116 $!  Fix The Unix Softlinks.
 117 $!
 118 $   GOSUB SOFTLINKS
 119 $!
 120 $ ENDIF
 121 $!
 122 $ IF (BUILDCOMMAND.EQS."ALL".OR.BUILDCOMMAND.EQS."BUILDALL")
 123 $ THEN
 124 $!
 125 $!  Check To See If We Are Going To Be Building The
 126 $!  [.xxx.EXE.RSAREF]LIBRSAGLUE.OLB Library.
 127 $!
 128 $   IF (RSAREF.EQS."RSAREF")
 129 $   THEN
 130 $!
 131 $!    Build The [.xxx.EXE.RSAREF]LIBRSAGLUE.OLB Library.
 132 $!
 133 $     GOSUB RSAREF
 134 $!
 135 $!  End The RSAREF Check.
 136 $!
 137 $   ENDIF
 138 $!
 139 $!  Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 140 $!
 141 $   GOSUB CRYPTO
 142 $!
 143 $!  Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 144 $!
 145 $   GOSUB SSL
 146 $!
 147 $!  Build The [.xxx.EXE.SSL]SSL_TASK.EXE DECNet SSL Engine.
 148 $!
 149 $   GOSUB SSL_TASK
 150 $!
 151 $!  Build The [.xxx.EXE.TEST] OpenSSL Test Utilities.
 152 $!
 153 $   GOSUB TEST
 154 $!
 155 $!  Build The [.xxx.EXE.APPS] OpenSSL Application Utilities.
 156 $!
 157 $   GOSUB APPS
 158 $!
 159 $! Else...
 160 $!
 161 $ ELSE
 162 $!
 163 $!    Build Just What The User Wants Us To Build.
 164 $!
 165 $     GOSUB 'BUILDCOMMAND'
 166 $!
 167 $ ENDIF
 168 $!
 169 $! Time To EXIT.
 170 $!
 171 $ EXIT
 172 $!
 173 $! Rebuild The "[.CRYPTO]OPENSSLCONF.H" file.
 174 $!
 175 $ CONFIG:
 176 $!
 177 $! Tell The User We Are Creating The [.CRYPTO]OPENSSLCONF.H File.
 178 $!
 179 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]OPENSSLCONF.H Include File."
 180 $!
 181 $! Create The [.CRYPTO]OPENSSLCONF.H File.
 182 $!
 183 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]OPENSSLCONF.H
 184 $!
 185 $! Write The [.CRYPTO]OPENSSLCONF.H File.
 186 $!
 187 $ WRITE H_FILE "/* This file was automatically built using makevms.com */"
 188 $ WRITE H_FILE "/* and [.CRYPTO]OPENSSLCONF.H_IN */"
 189 $
 190 $! Different tar version may have named the file differently
 191 $ IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H_IN") .NES. ""
 192 $ THEN
 193 $   TYPE [.CRYPTO]OPENSSLCONF.H_IN /OUTPUT=H_FILE:
 194 $ ELSE
 195 $   IF F$SEARCH("[.CRYPTO]OPENSSLCONF_H.IN") .NES. ""
 196 $   THEN
 197 $     TYPE [.CRYPTO]OPENSSLCONF_H.IN /OUTPUT=H_FILE:
 198 $   ELSE
 199 $     ! For ODS-5
 200 $     IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H.IN") .NES. ""
 201 $     THEN
 202 $       TYPE [.CRYPTO]OPENSSLCONF.H.IN /OUTPUT=H_FILE:
 203 $     ELSE
 204 $       WRITE SYS$ERROR "Couldn't find a [.CRYPTO]OPENSSLCONF.H_IN.  Exiting!"
 205 $       EXIT 0
 206 $     ENDIF
 207 $   ENDIF
 208 $ ENDIF
 209 $!
 210 $ IF ARCH .EQS. "AXP"
 211 $ THEN
 212 $!
 213 $!  Write the Alpha specific data
 214 $!
 215 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 216 $   WRITE H_FILE "#undef RC4_INT"
 217 $   WRITE H_FILE "#define RC4_INT unsigned int"
 218 $   WRITE H_FILE "#undef RC4_CHUNK"
 219 $   WRITE H_FILE "#define RC4_CHUNK unsigned long long"
 220 $   WRITE H_FILE "#endif"
 221 $!
 222 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 223 $   WRITE H_FILE "#undef DES_LONG"
 224 $   WRITE H_FILE "#define DES_LONG unsigned int"
 225 $   WRITE H_FILE "#undef DES_PTR"
 226 $   WRITE H_FILE "#define DES_PTR"
 227 $   WRITE H_FILE "#undef DES_RISC1"
 228 $   WRITE H_FILE "#undef DES_RISC2"
 229 $   WRITE H_FILE "#define DES_RISC1"
 230 $   WRITE H_FILE "#undef DES_UNROLL"
 231 $   WRITE H_FILE "#define DES_UNROLL"
 232 $   WRITE H_FILE "#endif"
 233 $!
 234 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 235 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 236 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 237 $   WRITE H_FILE "#define SIXTY_FOUR_BIT"
 238 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 239 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 240 $   WRITE H_FILE "#undef EIGHT_BIT"
 241 $   WRITE H_FILE "#endif"
 242 $!
 243 $!  Else...
 244 $!
 245 $ ELSE
 246 $!
 247 $!  Write the VAX specific data
 248 $!
 249 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 250 $   WRITE H_FILE "#undef RC4_INT"
 251 $   WRITE H_FILE "#define RC4_INT unsigned char"
 252 $   WRITE H_FILE "#undef RC4_CHUNK"
 253 $   WRITE H_FILE "#define RC4_CHUNK unsigned long"
 254 $   WRITE H_FILE "#endif"
 255 $!
 256 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 257 $   WRITE H_FILE "#undef DES_LONG"
 258 $   WRITE H_FILE "#define DES_LONG unsigned long"
 259 $   WRITE H_FILE "#undef DES_PTR"
 260 $   WRITE H_FILE "#define DES_PTR"
 261 $   WRITE H_FILE "#undef DES_RISC1"
 262 $   WRITE H_FILE "#undef DES_RISC2"
 263 $   WRITE H_FILE "#undef DES_UNROLL"
 264 $   WRITE H_FILE "#endif"
 265 $!
 266 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 267 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 268 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 269 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 270 $   WRITE H_FILE "#define THIRTY_TWO_BIT"
 271 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 272 $   WRITE H_FILE "#undef EIGHT_BIT"
 273 $   WRITE H_FILE "#endif"
 274 $!
 275 $!  End
 276 $!
 277 $ ENDIF
 278 $!
 279 $! Close the [.CRYPTO]OPENSSLCONF.H file
 280 $!
 281 $ CLOSE H_FILE
 282 $!
 283 $! That's All, Time To RETURN.
 284 $!
 285 $ RETURN
 286 $!
 287 $! Rebuild The "[.CRYPTO]BUILDINF.H" file.
 288 $!
 289 $ BUILDINF:
 290 $!
 291 $! Tell The User We Are Creating The [.CRYPTO]BUILDINF.H File.
 292 $!
 293 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]BUILDINF.H Include File."
 294 $!
 295 $! Create The [.CRYPTO]BUILDINF.H File.
 296 $!
 297 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]BUILDINF.H
 298 $!
 299 $! Get The Current Date & Time.
 300 $!
 301 $ TIME = F$TIME()
 302 $!
 303 $! Write The [.CRYPTO]BUILDINF.H File.
 304 $!
 305 $ WRITE H_FILE "#define CFLAGS """" /* Not filled in for now */"
 306 $ WRITE H_FILE "#define PLATFORM ""VMS"""
 307 $ WRITE H_FILE "#define DATE ""''TIME'"" "
 308 $!
 309 $! Close The [.CRYPTO]BUILDINF.H File.
 310 $!
 311 $ CLOSE H_FILE
 312 $!
 313 $! That's All, Time To RETURN.
 314 $!
 315 $ RETURN
 316 $!
 317 $! Copy a lot of files around.
 318 $!
 319 $ SOFTLINKS:
 320 $!
 321 $! Tell The User We Are Partly Rebuilding The [.TEST] Directory.
 322 $!
 323 $ WRITE SYS$OUTPUT "Rebuilding The '[.APPS]MD5.C' And '[.APPS]RMD160.C' Files."
 324 $!
 325 $ DELETE SYS$DISK:[.APPS]MD4.C;*,MD5.C;*,RMD160.C;*
 326 $!
 327 $! Copy MD4.C from [.CRYPTO.MD4] into [.APPS]
 328 $!
 329 $ COPY SYS$DISK:[.CRYPTO.MD4]MD4.C SYS$DISK:[.APPS]
 330 $!
 331 $! Copy MD5.C from [.CRYPTO.MD5] into [.APPS]
 332 $!
 333 $ COPY SYS$DISK:[.CRYPTO.MD5]MD5.C SYS$DISK:[.APPS]
 334 $!
 335 $! Copy RMD160.C from [.CRYPTO.RIPEMD] into [.APPS]
 336 $!
 337 $ COPY SYS$DISK:[.CRYPTO.RIPEMD]RMD160.C SYS$DISK:[.APPS]
 338 $!
 339 $! Tell The User We Are Partly Rebuilding The [.TEST] Directory.
 340 $!
 341 $ WRITE SYS$OUTPUT "Rebuilding The '[.TEST]*.C' Files."
 342 $!
 343 $! First, We Have To "Rebuild" The "[.TEST]" Directory, So Delete
 344 $! All The "C" Files That Are Currently There Now.
 345 $!
 346 $ DELETE SYS$DISK:[.TEST]*.C;*
 347 $!
 348 $! Copy all the *TEST.C files from [.CRYPTO...] into [.TEST]
 349 $!
 350 $ COPY SYS$DISK:[.CRYPTO.*]%*TEST.C SYS$DISK:[.TEST]
 351 $!
 352 $! Copy all the *TEST.C files from [.SSL...] into [.TEST]
 353 $!
 354 $ COPY SYS$DISK:[.SSL]%*TEST.C SYS$DISK:[.TEST]
 355 $!
 356 $! Tell The User We Are Rebuilding The [.INCLUDE.OPENSSL] Directory.
 357 $!
 358 $ WRITE SYS$OUTPUT "Rebuilding The '[.INCLUDE.OPENSSL]' Directory."
 359 $!
 360 $! First, make sure the directory exists
 361 $!
 362 $ IF F$PARSE("SYS$DISK:[.INCLUDE.OPENSSL]") .EQS. "" THEN -
 363      CREATE/DIRECTORY SYS$DISK:[.INCLUDE.OPENSSL]
 364 $!
 365 $! Copy All The ".H" Files From The Main Directory.
 366 $!
 367 $ EXHEADER := e_os.h,e_os2.h
 368 $ COPY 'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 369 $!
 370 $! Copy All The ".H" Files From The [.CRYPTO] Directory Tree.
 371 $!
 372 $ SDIRS := ,MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,-
 373    DES,RC2,RC4,RC5,IDEA,BF,CAST,-
 374    BN,RSA,DSA,DH,DSO,-
 375    BUFFER,BIO,STACK,LHASH,RAND,ERR,OBJECTS,-
 376    EVP,ASN1,PEM,X509,X509V3,CONF,TXT_DB,PKCS7,PKCS12,COMP
 377 $ EXHEADER_ := crypto.h,tmdiff.h,opensslv.h,opensslconf.h,ebcdic.h,symhacks.h
 378 $ EXHEADER_MD2 := md2.h
 379 $ EXHEADER_MD4 := md4.h
 380 $ EXHEADER_MD5 := md5.h
 381 $ EXHEADER_SHA := sha.h
 382 $ EXHEADER_MDC2 := mdc2.h
 383 $ EXHEADER_HMAC := hmac.h
 384 $ EXHEADER_RIPEMD := ripemd.h
 385 $ EXHEADER_DES := des.h
 386 $ EXHEADER_RC2 := rc2.h
 387 $ EXHEADER_RC4 := rc4.h
 388 $ EXHEADER_RC5 := rc5.h
 389 $ EXHEADER_IDEA := idea.h
 390 $ EXHEADER_BF := blowfish.h
 391 $ EXHEADER_CAST := cast.h
 392 $ EXHEADER_BN := bn.h
 393 $ EXHEADER_RSA := rsa.h
 394 $ EXHEADER_DSA := dsa.h
 395 $ EXHEADER_DH := dh.h
 396 $ EXHEADER_DSO := dso.h
 397 $ EXHEADER_BUFFER := buffer.h
 398 $ EXHEADER_BIO := bio.h
 399 $ EXHEADER_STACK := stack.h,safestack.h
 400 $ EXHEADER_LHASH := lhash.h
 401 $ EXHEADER_RAND := rand.h
 402 $ EXHEADER_ERR := err.h
 403 $ EXHEADER_OBJECTS := objects.h,obj_mac.h
 404 $ EXHEADER_EVP := evp.h
 405 $ EXHEADER_ASN1 := asn1.h,asn1_mac.h
 406 $ EXHEADER_PEM := pem.h,pem2.h
 407 $ EXHEADER_X509 := x509.h,x509_vfy.h
 408 $ EXHEADER_X509V3 := x509v3.h
 409 $ EXHEADER_CONF := conf.h,conf_api.h
 410 $ EXHEADER_TXT_DB := txt_db.h
 411 $ EXHEADER_PKCS7 := pkcs7.h
 412 $ EXHEADER_PKCS12 := pkcs12.h
 413 $ EXHEADER_COMP := comp.h
 414 $
 415 $ I = 0
 416 $ LOOP_SDIRS:
 417 $ D = F$EDIT(F$ELEMENT(I, ",", SDIRS),"TRIM")
 418 $ I = I + 1
 419 $ IF D .EQS. "," THEN GOTO LOOP_SDIRS_END
 420 $ tmp = EXHEADER_'D'
 421 $ IF D .EQS. ""
 422 $ THEN
 423 $   COPY [.CRYPTO]'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 424 $ ELSE
 425 $   COPY [.CRYPTO.'D']'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 426 $ ENDIF
 427 $ GOTO LOOP_SDIRS
 428 $ LOOP_SDIRS_END:
 429 $!
 430 $! Copy All The ".H" Files From The [.RSAREF] Directory.
 431 $!
 432 $ EXHEADER := rsaref.h
 433 $ COPY SYS$DISK:[.RSAREF]'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 434 $!
 435 $! Copy All The ".H" Files From The [.SSL] Directory.
 436 $!
 437 $ EXHEADER := ssl.h,ssl2.h,ssl3.h,ssl23.h,tls1.h
 438 $ COPY SYS$DISK:[.SSL]'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 439 $!
 440 $! Purge all doubles
 441 $!
 442 $ PURGE SYS$DISK:[.INCLUDE.OPENSSL]*.H
 443 $!
 444 $! That's All, Time To RETURN.
 445 $!
 446 $ RETURN
 447 $!
 448 $! Build The "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library.
 449 $!
 450 $ CRYPTO:
 451 $!
 452 $! Tell The User What We Are Doing.
 453 $!
 454 $ WRITE SYS$OUTPUT ""
 455 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.CRYPTO]LIBCRYPTO.OLB Library."
 456 $!
 457 $! Go To The [.CRYPTO] Directory.
 458 $!
 459 $ SET DEFAULT SYS$DISK:[.CRYPTO]
 460 $!
 461 $! Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 462 $!
 463 $ @CRYPTO-LIB LIBRARY 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" "''BUILDPART'"
 464 $!
 465 $! Build The [.xxx.EXE.CRYPTO]*.EXE Test Applications.
 466 $!
 467 $ @CRYPTO-LIB APPS 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 468 $!
 469 $! Go Back To The Main Directory.
 470 $!
 471 $ SET DEFAULT [-]
 472 $!
 473 $! Time To RETURN.
 474 $!
 475 $ RETURN
 476 $!
 477 $! Build The [.xxx.EXE.RSAREF]LIBRSAGLUE Library.
 478 $!
 479 $ RSAREF:
 480 $!
 481 $! Tell The User What We Are Doing.
 482 $!
 483 $ WRITE SYS$OUTPUT ""
 484 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.RSAREF]LIBRSAGLUE.OLB Library."
 485 $!
 486 $! Go To The [.RSAREF] Directory.
 487 $!
 488 $ SET DEFAULT SYS$DISK:[.RSAREF]
 489 $!
 490 $! Build The [.xxx.EXE.RSAREF]LIBRSAGLUE.OLB Library.
 491 $!
 492 $ @RSAREF-LIB LIBRARY 'DEBUGGER' "''COMPILER'" 'ISSEVEN'
 493 $!
 494 $! Go Back To The Main Directory.
 495 $!
 496 $ SET DEFAULT [-]
 497 $!
 498 $! Time To Return.
 499 $!
 500 $ RETURN
 501 $!
 502 $! Build The "[.xxx.EXE.SSL]LIBSSL.OLB" Library.
 503 $!
 504 $ SSL:
 505 $!
 506 $! Tell The User What We Are Doing.
 507 $!
 508 $ WRITE SYS$OUTPUT ""
 509 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.SSL]LIBSSL.OLB Library."
 510 $!
 511 $! Go To The [.SSL] Directory.
 512 $!
 513 $ SET DEFAULT SYS$DISK:[.SSL]
 514 $!
 515 $! Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 516 $!
 517 $ @SSL-LIB LIBRARY 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 518 $!
 519 $! Go Back To The Main Directory.
 520 $!
 521 $ SET DEFAULT [-]
 522 $!
 523 $! Time To Return.
 524 $!
 525 $ RETURN
 526 $!
 527 $! Build The "[.xxx.EXE.SSL]SSL_TASK.EXE" Program.
 528 $!
 529 $ SSL_TASK:
 530 $!
 531 $! Tell The User What We Are Doing.
 532 $!
 533 $ WRITE SYS$OUTPUT ""
 534 $ WRITE SYS$OUTPUT "Building DECNet Based SSL Engine, [.",ARCH,".EXE.SSL]SSL_TASK.EXE"
 535 $!
 536 $! Go To The [.SSL] Directory.
 537 $!
 538 $ SET DEFAULT SYS$DISK:[.SSL]
 539 $!
 540 $! Build The [.xxx.EXE.SSL]SSL_TASK.EXE
 541 $!
 542 $ @SSL-LIB SSL_TASK 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 543 $!
 544 $! Go Back To The Main Directory.
 545 $!
 546 $ SET DEFAULT [-]
 547 $!
 548 $! That's All, Time To RETURN.
 549 $!
 550 $ RETURN
 551 $!
 552 $! Build The OpenSSL Test Programs.
 553 $!
 554 $ TEST:
 555 $!
 556 $! Tell The User What We Are Doing.
 557 $!
 558 $ WRITE SYS$OUTPUT ""
 559 $ WRITE SYS$OUTPUT "Building The OpenSSL [.",ARCH,".EXE.TEST] Test Utilities."
 560 $!
 561 $! Go To The [.TEST] Directory.
 562 $!
 563 $ SET DEFAULT SYS$DISK:[.TEST]
 564 $!
 565 $! Build The Test Programs.
 566 $!
 567 $ @MAKETESTS 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 568 $!
 569 $! Go Back To The Main Directory.
 570 $!
 571 $ SET DEFAULT [-]
 572 $!
 573 $! That's All, Time To RETURN.
 574 $!
 575 $ RETURN
 576 $!
 577 $! Build The OpenSSL Application Programs.
 578 $!
 579 $ APPS:
 580 $!
 581 $! Tell The User What We Are Doing.
 582 $!
 583 $ WRITE SYS$OUTPUT ""
 584 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCH,".EXE.APPS] Applications."
 585 $!
 586 $! Go To The [.APPS] Directory.
 587 $!
 588 $ SET DEFAULT SYS$DISK:[.APPS]
 589 $!
 590 $! Build The Application Programs.
 591 $!
 592 $ @MAKEAPPS 'RSAREF' 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 593 $!
 594 $! Go Back To The Main Directory.
 595 $!
 596 $ SET DEFAULT [-]
 597 $!
 598 $! That's All, Time To RETURN.
 599 $!
 600 $ RETURN
 601 $!
 602 $! Check The User's Options.
 603 $!
 604 $ CHECK_OPTIONS:
 605 $!
 606 $! Check if there's a "part", and separate it out
 607 $!
 608 $ BUILDPART = F$ELEMENT(1,"/",P1)
 609 $ IF BUILDPART .EQS. "/"
 610 $ THEN
 611 $   BUILDPART = ""
 612 $ ELSE
 613 $   P1 = F$EXTRACT(0,F$LENGTH(P1) - F$LENGTH(BUILDPART) - 1, P1)
 614 $ ENDIF
 615 $!
 616 $! Check To See If P1 Is Blank.
 617 $!
 618 $ IF (P1.EQS."ALL")
 619 $ THEN
 620 $!
 621 $!   P1 Is ALL, So Build Everything.
 622 $!
 623 $    BUILDCOMMAND = "ALL"
 624 $!
 625 $! Else...
 626 $!
 627 $ ELSE
 628 $!
 629 $!  Else, Check To See If P1 Has A Valid Arguement.
 630 $!
 631 $   IF (P1.EQS."CONFIG").OR.(P1.EQS."BUILDINF").OR.(P1.EQS."SOFTLINKS") -
 632        .OR.(P1.EQS."BUILDALL") -
 633        .OR.(P1.EQS."CRYPTO").OR.(P1.EQS."SSL").OR.(P1.EQS."RSAREF") -
 634        .OR.(P1.EQS."SSL_TASK").OR.(P1.EQS."TEST").OR.(P1.EQS."APPS")
 635 $   THEN
 636 $!
 637 $!    A Valid Arguement.
 638 $!
 639 $     BUILDCOMMAND = P1
 640 $!
 641 $!  Else...
 642 $!
 643 $   ELSE
 644 $!
 645 $!    Tell The User We Don't Know What They Want.
 646 $!
 647 $     WRITE SYS$OUTPUT ""
 648 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 649 $     WRITE SYS$OUTPUT ""
 650 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 651 $     WRITE SYS$OUTPUT "    CONFIG   :  Just build the [.CRYPTO]OPENSSLCONF.H file."
 652 $     WRITE SYS$OUTPUT "    BUILDINF :  Just build the [.CRYPTO]BUILDINF.H file."
 653 $     WRITE SYS$OUTPUT "    SOFTLINKS:  Just Fix The Unix soft links."
 654 $     WRITE SYS$OUTPUT "    BUILDALL :  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done."
 655 $     WRITE SYS$OUTPUT "    RSAREF   :  To Build Just The [.xxx.EXE.RSAREF]LIBRSAGLUE.OLB Library."
 656 $     WRITE SYS$OUTPUT "    CRYPTO   :  To Build Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 657 $     WRITE SYS$OUTPUT "    CRYPTO/x :  To Build Just The x Part Of The"
 658 $     WRITE SYS$OUTPUT "                [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 659 $     WRITE SYS$OUTPUT "    SSL      :  To Build Just The [.xxx.EXE.SSL]LIBSSL.OLB Library."
 660 $     WRITE SYS$OUTPUT "    SSL_TASK :  To Build Just The [.xxx.EXE.SSL]SSL_TASK.EXE Program."
 661 $     WRITE SYS$OUTPUT "    TEST     :  To Build Just The OpenSSL Test Programs."
 662 $     WRITE SYS$OUTPUT "    APPS     :  To Build Just The OpenSSL Application Programs."
 663 $     WRITE SYS$OUTPUT ""
 664 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 665 $     WRITE SYS$OUTPUT ""
 666 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 667 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 668 $     WRITE SYS$OUTPUT ""
 669 $!
 670 $!    Time To EXIT.
 671 $!
 672 $     EXIT
 673 $!
 674 $!  End The Valid Argument Check.
 675 $!
 676 $   ENDIF
 677 $!
 678 $! End The P1 Check.
 679 $!
 680 $ ENDIF
 681 $!
 682 $! Check To See If P2 Is Blank.
 683 $!
 684 $ IF (P2.EQS."NORSAREF")
 685 $ THEN
 686 $!
 687 $!   P2 Is NORSAREF, So Compile Without RSAREF.
 688 $!
 689 $    RSAREF = "NORSAREF"
 690 $!
 691 $! Else...
 692 $!
 693 $ ELSE
 694 $!
 695 $!  Check To See If We Are To Compile Using The RSAREF Library.
 696 $!
 697 $   IF (P2.EQS."RSAREF")
 698 $   THEN
 699 $!
 700 $!    Compile With RSAREF Library.
 701 $!
 702 $     RSAREF = "RSAREF"
 703 $!
 704 $!  Else...
 705 $!
 706 $   ELSE
 707 $!
 708 $!    Tell The User Entered An Invalid Option..
 709 $!
 710 $     WRITE SYS$OUTPUT ""
 711 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 712 $     WRITE SYS$OUTPUT ""
 713 $     WRITE SYS$OUTPUT "    RSAREF   :  To Compile With The RSAREF Library."
 714 $     WRITE SYS$OUTPUT "    NORSAREF :  To Compile With The Regular RSA Library."
 715 $     WRITE SYS$OUTPUT ""
 716 $!
 717 $!    Time To EXIT.
 718 $!
 719 $     EXIT
 720 $!
 721 $!  End The Valid Arguemnt Check.
 722 $!
 723 $   ENDIF
 724 $!
 725 $! End The P2 Check.
 726 $!
 727 $ ENDIF
 728 $!
 729 $! Check To See If P3 Is Blank.
 730 $!
 731 $ IF (P3.EQS."NODEBUG")
 732 $ THEN
 733 $!
 734 $!   P3 Is NODEBUG, So Compile Without Debugger Information.
 735 $!
 736 $    DEBUGGER = "NODEBUG"
 737 $!
 738 $! Else...
 739 $!
 740 $ ELSE
 741 $!
 742 $!  Check To See If We Are To Compile With Debugger Information.
 743 $!
 744 $   IF (P3.EQS."DEBUG")
 745 $   THEN
 746 $!
 747 $!    Compile With Debugger Information.
 748 $!
 749 $     DEBUGGER = "DEBUG"
 750 $!
 751 $!  Else...
 752 $!
 753 $   ELSE
 754 $!
 755 $!    Tell The User Entered An Invalid Option..
 756 $!
 757 $     WRITE SYS$OUTPUT ""
 758 $     WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
 759 $     WRITE SYS$OUTPUT ""
 760 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
 761 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
 762 $     WRITE SYS$OUTPUT ""
 763 $!
 764 $!    Time To EXIT.
 765 $!
 766 $     EXIT
 767 $!
 768 $!  End The Valid Arguement Check.
 769 $!
 770 $   ENDIF
 771 $!
 772 $! End The P3 Check.
 773 $!
 774 $ ENDIF
 775 $!
 776 $! Check To See If P4 Is Blank.
 777 $!
 778 $ IF (P4.EQS."")
 779 $ THEN
 780 $!
 781 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 782 $!  Find Out Which One To Use.
 783 $!
 784 $!  Check To See If We Have GNU C.
 785 $!
 786 $   IF (F$TRNLNM("GNU_CC").NES."")
 787 $   THEN
 788 $!
 789 $!    Looks Like GNUC, Set To Use GNUC.
 790 $!
 791 $     COMPILER = "GNUC"
 792 $!
 793 $!    Tell The User We Are Using GNUC.
 794 $!
 795 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 796 $!
 797 $!  End The GNU C Compiler Check.
 798 $!
 799 $   ENDIF
 800 $!
 801 $!  Check To See If We Have VAXC Or DECC.
 802 $!
 803 $   IF (F$GETSYI("CPU").GE.128).OR.(F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC")
 804 $   THEN
 805 $!
 806 $!    Looks Like DECC, Set To Use DECC.
 807 $!
 808 $     COMPILER = "DECC"
 809 $!
 810 $!    Tell The User We Are Using DECC.
 811 $!
 812 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 813 $!
 814 $!  Else...
 815 $!
 816 $   ELSE
 817 $!
 818 $!    Looks Like VAXC, Set To Use VAXC.
 819 $!
 820 $     COMPILER = "VAXC"
 821 $!
 822 $!    Tell The User We Are Using VAX C.
 823 $!
 824 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 825 $!
 826 $!  End The DECC & VAXC Compiler Check.
 827 $!
 828 $   ENDIF
 829 $!
 830 $! Else...
 831 $!
 832 $ ELSE
 833 $!
 834 $!  Check To See If The User Entered A Valid Paramter.
 835 $!
 836 $   IF (P4.EQS."VAXC").OR.(P4.EQS."DECC").OR.(P4.EQS."GNUC")!.OR.(P4.EQS."LINK")
 837 $   THEN
 838 $!
 839 $!    Check To See If The User Wanted To Just LINK.
 840 $!
 841 $     IF (P4.EQS."LINK")
 842 $     THEN
 843 $!
 844 $!      Looks Like LINK-only
 845 $!
 846 $       COMPILER = "LINK"
 847 $!
 848 $!      Tell The User We Are Only Linking.
 849 $!
 850 $       WRITE SYS$OUTPUT "LINK Only.  This actually NOT YET SUPPORTED!"
 851 $!
 852 $!    End LINK Check.
 853 $!
 854 $     ENDIF
 855 $!
 856 $!    Check To See If The User Wanted DECC.
 857 $!
 858 $     IF (P4.EQS."DECC")
 859 $     THEN
 860 $!
 861 $!      Looks Like DECC, Set To Use DECC.
 862 $!
 863 $       COMPILER = "DECC"
 864 $!
 865 $!      Tell The User We Are Using DECC.
 866 $!
 867 $       WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 868 $!
 869 $!    End DECC Check.
 870 $!
 871 $     ENDIF
 872 $!
 873 $!    Check To See If We Are To Use VAXC.
 874 $!
 875 $     IF (P4.EQS."VAXC")
 876 $     THEN
 877 $!
 878 $!      Looks Like VAXC, Set To Use VAXC.
 879 $!
 880 $       COMPILER = "VAXC"
 881 $!
 882 $!      Tell The User We Are Using VAX C.
 883 $!
 884 $       WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 885 $!
 886 $!    End VAXC Check
 887 $!
 888 $     ENDIF
 889 $!
 890 $!    Check To See If We Are To Use GNU C.
 891 $!
 892 $     IF (P4.EQS."GNUC")
 893 $     THEN
 894 $!
 895 $!      Looks Like GNUC, Set To Use GNUC.
 896 $!
 897 $       COMPILER = "GNUC"
 898 $!
 899 $!      Tell The User We Are Using GNUC.
 900 $!
 901 $       WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 902 $!
 903 $!    End The GNU C Check.
 904 $!
 905 $     ENDIF
 906 $!
 907 $!  Else The User Entered An Invalid Arguement.
 908 $!
 909 $   ELSE
 910 $!
 911 $!    Tell The User We Don't Know What They Want.
 912 $!
 913 $     WRITE SYS$OUTPUT ""
 914 $     WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
 915 $     WRITE SYS$OUTPUT ""
 916 $     WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 917 $     WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 918 $     WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 919 $     WRITE SYS$OUTPUT ""
 920 $!
 921 $!    Time To EXIT.
 922 $!
 923 $     EXIT
 924 $!
 925 $!  End The Valid Arguement Check.
 926 $!
 927 $   ENDIF
 928 $!
 929 $! End The P4 Check.
 930 $!
 931 $ ENDIF
 932 $!
 933 $! Time to check the contents of P5, and to make sure we get the correct library.
 934 $!
 935 $ IF P5.EQS."SOCKETSHR" .OR. P5.EQS."MULTINET" .OR. P5.EQS."UCX"
 936 $ THEN
 937 $!
 938 $!  Check to see if SOCKETSHR was chosen
 939 $!
 940 $   IF P5.EQS."SOCKETSHR"
 941 $   THEN
 942 $!
 943 $!    Set the library to use SOCKETSHR
 944 $!
 945 $     TCPIP_LIB = "[-.VMS]SOCKETSHR_SHR.OPT/OPT"
 946 $!
 947 $!    Tell the user
 948 $!
 949 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 950 $!
 951 $!    Done with SOCKETSHR
 952 $!
 953 $   ENDIF
 954 $!
 955 $!  Check to see if MULTINET was chosen
 956 $!
 957 $   IF P5.EQS."MULTINET"
 958 $   THEN
 959 $!
 960 $!    Set the library to use UCX emulation.
 961 $!
 962 $     P5 = "UCX"
 963 $!
 964 $!    Tell the user
 965 $!
 966 $     WRITE SYS$OUTPUT "Using MultiNet via UCX emulation for TCP/IP"
 967 $!
 968 $!    Done with MULTINET
 969 $!
 970 $   ENDIF
 971 $!
 972 $!  Check to see if UCX was chosen
 973 $!
 974 $   IF P5.EQS."UCX"
 975 $   THEN
 976 $!
 977 $!    Set the library to use UCX.
 978 $!
 979 $     TCPIP_LIB = "[-.VMS]UCX_SHR_DECC.OPT/OPT"
 980 $!
 981 $!    Tell the user
 982 $!
 983 $     WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 984 $!
 985 $!    Done with UCX
 986 $!
 987 $   ENDIF
 988 $!
 989 $!  Set the TCPIP_TYPE symbol
 990 $!
 991 $   TCPIP_TYPE = P5
 992 $!
 993 $!  Print info
 994 $!
 995 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
 996 $!
 997 $!  Else The User Entered An Invalid Arguement.
 998 $!
 999 $ ELSE
1000 $   IF P5 .NES. ""
1001 $   THEN
1002 $!
1003 $!    Tell The User We Don't Know What They Want.
1004 $!
1005 $     WRITE SYS$OUTPUT ""
1006 $     WRITE SYS$OUTPUT "The Option ",P5," Is Invalid.  The Valid Options Are:"
1007 $     WRITE SYS$OUTPUT ""
1008 $     WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1009 $     WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1010 $     WRITE SYS$OUTPUT ""
1011 $!
1012 $!    Time To EXIT.
1013 $!
1014 $     EXIT
1015 $   ELSE
1016 $!
1017 $!    Set the TCPIP_TYPE symbol
1018 $!
1019 $     TCPIP_TYPE = P5
1020 $   ENDIF
1021 $!
1022 $!  Done with TCP/IP libraries
1023 $!
1024 $ ENDIF
1025 $!
1026 $! Special Threads For OpenVMS v7.1 Or Later
1027 $!
1028 $! Written By:  Richard Levitte
1029 $!              richard@levitte.org
1030 $!
1031 $!
1032 $! Check To See If We Have A Option For P6.
1033 $!
1034 $ IF (P6.EQS."")
1035 $ THEN
1036 $!
1037 $!  Get The Version Of VMS We Are Using.
1038 $!
1039 $   ISSEVEN :=
1040 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
1041 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1042 $!
1043 $!  Check To See If The VMS Version Is v7.1 Or Later.
1044 $!
1045 $   IF (TMP.GE.71)
1046 $   THEN
1047 $!
1048 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1049 $!
1050 $     ISSEVEN := ,PTHREAD_USE_D4
1051 $!
1052 $!  End The VMS Version Check.
1053 $!
1054 $   ENDIF
1055 $!
1056 $! End The P6 Check.
1057 $!
1058 $ ENDIF
1059 $!
1060 $!  Time To RETURN...
1061 $!
1062 $ RETURN