makevms.com

   1 $!
   2 $! MAKEVMS.COM
   3 $! Original Author:  UNKNOWN
   4 $! Rewritten By:  Robert Byer
   5 $!                Vice-President
   6 $!                A-Com Computing, Inc.
   7 $!                byer@mail.all-net.net
   8 $!
   9 $! Changes by Richard Levitte <richard@levitte.org>
  10 $!
  11 $! This procedure creates the SSL libraries of "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  12 $! "[.xxx.EXE.SSL]LIBSSL.OLB"
  13 $! The "xxx" denotes the machine architecture of AXP or VAX.
  14 $!
  15 $! This procedures accepts two command line options listed below.
  16 $!
  17 $! Specify one of the following build options for P1.
  18 $!
  19 $!      ALL       Just build "everything".
  20 $!      CONFIG    Just build the "[.CRYPTO]OPENSSLCONF.H" file.
  21 $!      BUILDINF  Just build the "[.CRYPTO]BUILDINF.H" file.
  22 $!      SOFTLINKS Just fix the Unix soft links.
  23 $!      BUILDALL  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done.
  24 $!      CRYPTO    Just build the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  25 $!      CRYPTO/x  Just build the x part of the
  26 $!                "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library.
  27 $!      SSL       Just build the "[.xxx.EXE.SSL]LIBSSL.OLB" library.
  28 $!      SSL_TASK  Just build the "[.xxx.EXE.SSL]SSL_TASK.EXE" program.
  29 $!      TEST      Just build the "[.xxx.EXE.TEST]" test programs for OpenSSL.
  30 $!      APPS      Just build the "[.xxx.EXE.APPS]" application programs for OpenSSL.
  31 $!      ENGINES   Just build the "[.xxx.EXE.ENGINES]" application programs for OpenSSL.
  32 $!
  33 $!
  34 $! P2 is ignored (it was used to denote if RSAref should be used or not,
  35 $! and is simply kept so surrounding scripts don't get confused)
  36 $!
  37 $! Speficy DEBUG or NODEBUG as P3 to compile with or without debugging
  38 $! information.
  39 $!
  40 $! Specify which compiler at P4 to try to compile under.
  41 $!
  42 $!        VAXC   For VAX C.
  43 $!        DECC   For DEC C.
  44 $!        GNUC   For GNU C.
  45 $!        LINK   To only link the programs from existing object files.
  46 $!               (not yet implemented)
  47 $!
  48 $! If you don't speficy a compiler, it will try to determine which
  49 $! "C" compiler to use.
  50 $!
  51 $! P5, if defined, sets a TCP/IP library to use, through one of the following
  52 $! keywords:
  53 $!
  54 $!      UCX             for UCX or UCX emulation
  55 $!      TCPIP           for TCP/IP Services or TCP/IP Services emulation
  56 $!                      (this is prefered over UCX)
  57 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  58 $!      NONE            to avoid specifying which TCP/IP implementation to
  59 $!                      use at build time (this works with DEC C).  This is
  60 $!                      the default.
  61 $!
  62 $! P6, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  63 $!
  64 $!
  65 $! Check if we're in a batch job, and make sure we get to
  66 $! the directory this script is in
  67 $!
  68 $ IF F$MODE() .EQS. "BATCH"
  69 $ THEN
  70 $   COMNAME=F$ENVIRONMENT("PROCEDURE")
  71 $   COMPATH=F$PARSE("A.;",COMNAME) - "A.;"
  72 $   SET DEF 'COMPATH'
  73 $ ENDIF
  74 $!
  75 $! Check Which Architecture We Are Using.
  76 $!
  77 $ IF (F$GETSYI("CPU").GE.128)
  78 $ THEN
  79 $!
  80 $!  The Architecture Is AXP.
  81 $!
  82 $   ARCH := AXP
  83 $!
  84 $! Else...
  85 $!
  86 $ ELSE
  87 $!
  88 $!  The Architecture Is VAX.
  89 $!
  90 $   ARCH := VAX
  91 $!
  92 $! End The Architecture Check.
  93 $!
  94 $ ENDIF
  95 $!
  96 $! Check To Make Sure We Have Valid Command Line Parameters.
  97 $!
  98 $ GOSUB CHECK_OPTIONS
  99 $!
 100 $! Check To See What We Are To Do.
 101 $!
 102 $ IF (BUILDCOMMAND.EQS."ALL")
 103 $ THEN
 104 $!
 105 $!  Start with building the OpenSSL configuration file.
 106 $!
 107 $   GOSUB CONFIG
 108 $!
 109 $!  Create The "BUILDINF.H" Include File.
 110 $!
 111 $   GOSUB BUILDINF
 112 $!
 113 $!  Fix The Unix Softlinks.
 114 $!
 115 $   GOSUB SOFTLINKS
 116 $!
 117 $ ENDIF
 118 $!
 119 $ IF (BUILDCOMMAND.EQS."ALL".OR.BUILDCOMMAND.EQS."BUILDALL")
 120 $ THEN
 121 $!
 122 $!  Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 123 $!
 124 $   GOSUB CRYPTO
 125 $!
 126 $!  Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 127 $!
 128 $   GOSUB SSL
 129 $!
 130 $!  Build The [.xxx.EXE.SSL]SSL_TASK.EXE DECNet SSL Engine.
 131 $!
 132 $   GOSUB SSL_TASK
 133 $!
 134 $!  Build The [.xxx.EXE.TEST] OpenSSL Test Utilities.
 135 $!
 136 $   GOSUB TEST
 137 $!
 138 $!  Build The [.xxx.EXE.APPS] OpenSSL Application Utilities.
 139 $!
 140 $   GOSUB APPS
 141 $!
 142 $!  Build The [.xxx.EXE.ENGINES] OpenSSL Shareable Engines.
 143 $!
 144 $   GOSUB ENGINES
 145 $!
 146 $! Else...
 147 $!
 148 $ ELSE
 149 $!
 150 $!    Build Just What The User Wants Us To Build.
 151 $!
 152 $     GOSUB 'BUILDCOMMAND'
 153 $!
 154 $ ENDIF
 155 $!
 156 $! Time To EXIT.
 157 $!
 158 $ EXIT
 159 $!
 160 $! Rebuild The "[.CRYPTO]OPENSSLCONF.H" file.
 161 $!
 162 $ CONFIG:
 163 $!
 164 $! Tell The User We Are Creating The [.CRYPTO]OPENSSLCONF.H File.
 165 $!
 166 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]OPENSSLCONF.H Include File."
 167 $!
 168 $! Create The [.CRYPTO]OPENSSLCONF.H File.
 169 $!
 170 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]OPENSSLCONF.H
 171 $!
 172 $! Write The [.CRYPTO]OPENSSLCONF.H File.
 173 $!
 174 $ WRITE H_FILE "/* This file was automatically built using makevms.com */"
 175 $ WRITE H_FILE "/* and [.CRYPTO]OPENSSLCONF.H_IN */"
 176 $
 177 $!
 178 $! Write a few macros that indicate how this system was built.
 179 $!
 180 $ WRITE H_FILE ""
 181 $ WRITE H_FILE "#ifndef OPENSSL_SYS_VMS"
 182 $ WRITE H_FILE "# define OPENSSL_SYS_VMS"
 183 $ WRITE H_FILE "#endif"
 184 $ CONFIG_LOGICALS := NO_ASM,NO_RSA,NO_DSA,NO_DH,NO_MD2,NO_MD5,NO_RIPEMD,-
 185         NO_SHA,NO_SHA0,NO_SHA1,NO_DES/NO_MDC2;NO_MDC2,NO_RC2,NO_RC4,NO_RC5,-
 186         NO_IDEA,NO_BF,NO_CAST,NO_CAMELLIA,NO_SEED,NO_HMAC,NO_SSL2
 187 $ CONFIG_LOG_I = 0
 188 $ CONFIG_LOG_LOOP:
 189 $   CONFIG_LOG_E1 = F$ELEMENT(CONFIG_LOG_I,",",CONFIG_LOGICALS)
 190 $   CONFIG_LOG_I = CONFIG_LOG_I + 1
 191 $   IF CONFIG_LOG_E1 .EQS. "" THEN GOTO CONFIG_LOG_LOOP
 192 $   IF CONFIG_LOG_E1 .EQS. "," THEN GOTO CONFIG_LOG_LOOP_END
 193 $   CONFIG_LOG_E2 = F$EDIT(CONFIG_LOG_E1,"TRIM")
 194 $   CONFIG_LOG_E1 = F$ELEMENT(0,";",CONFIG_LOG_E2)
 195 $   CONFIG_LOG_E2 = F$ELEMENT(1,";",CONFIG_LOG_E2)
 196 $   CONFIG_LOG_E0 = F$ELEMENT(0,"/",CONFIG_LOG_E1)
 197 $   CONFIG_LOG_E1 = F$ELEMENT(1,"/",CONFIG_LOG_E1)
 198 $   IF F$TRNLNM("OPENSSL_"+CONFIG_LOG_E0)
 199 $   THEN
 200 $     WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E0
 201 $     WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E0
 202 $     WRITE H_FILE "#endif"
 203 $     IF CONFIG_LOG_E1 .NES. "/"
 204 $     THEN
 205 $       WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E1
 206 $       WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E1
 207 $       WRITE H_FILE "#endif"
 208 $     ENDIF
 209 $   ELSE
 210 $     IF CONFIG_LOG_E2 .NES. ";"
 211 $     THEN
 212 $       IF F$TRNLNM("OPENSSL_"+CONFIG_LOG_E2)
 213 $       THEN
 214 $         WRITE H_FILE "#ifndef OPENSSL_",CONFIG_LOG_E2
 215 $         WRITE H_FILE "# define OPENSSL_",CONFIG_LOG_E2
 216 $         WRITE H_FILE "#endif"
 217 $       ENDIF
 218 $     ENDIF
 219 $   ENDIF
 220 $   GOTO CONFIG_LOG_LOOP
 221 $ CONFIG_LOG_LOOP_END:
 222 $ WRITE H_FILE "#ifndef OPENSSL_NO_STATIC_ENGINE"
 223 $ WRITE H_FILE "# define OPENSSL_NO_STATIC_ENGINE"
 224 $ WRITE H_FILE "#endif"
 225 $ WRITE H_FILE "#ifndef OPENSSL_THREADS"
 226 $ WRITE H_FILE "# define OPENSSL_THREADS"
 227 $ WRITE H_FILE "#endif"
 228 $ WRITE H_FILE "#ifndef OPENSSL_NO_KRB5"
 229 $ WRITE H_FILE "# define OPENSSL_NO_KRB5"
 230 $ WRITE H_FILE "#endif"
 231 $ WRITE H_FILE ""
 232 $!
 233 $! Different tar version may have named the file differently
 234 $ IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H_IN") .NES. ""
 235 $ THEN
 236 $   TYPE [.CRYPTO]OPENSSLCONF.H_IN /OUTPUT=H_FILE:
 237 $ ELSE
 238 $   IF F$SEARCH("[.CRYPTO]OPENSSLCONF_H.IN") .NES. ""
 239 $   THEN
 240 $     TYPE [.CRYPTO]OPENSSLCONF_H.IN /OUTPUT=H_FILE:
 241 $   ELSE
 242 $     ! For ODS-5
 243 $     IF F$SEARCH("[.CRYPTO]OPENSSLCONF.H.IN") .NES. ""
 244 $     THEN
 245 $       TYPE [.CRYPTO]OPENSSLCONF.H.IN /OUTPUT=H_FILE:
 246 $     ELSE
 247 $       WRITE SYS$ERROR "Couldn't find a [.CRYPTO]OPENSSLCONF.H_IN.  Exiting!"
 248 $       EXIT 0
 249 $     ENDIF
 250 $   ENDIF
 251 $ ENDIF
 252 $ IF ARCH .EQS. "AXP"
 253 $ THEN
 254 $!
 255 $!  Write the Alpha specific data
 256 $!
 257 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 258 $   WRITE H_FILE "#undef RC4_INT"
 259 $   WRITE H_FILE "#define RC4_INT unsigned int"
 260 $   WRITE H_FILE "#undef RC4_CHUNK"
 261 $   WRITE H_FILE "#define RC4_CHUNK unsigned long long"
 262 $   WRITE H_FILE "#endif"
 263 $!
 264 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 265 $   WRITE H_FILE "#undef DES_LONG"
 266 $   WRITE H_FILE "#define DES_LONG unsigned int"
 267 $   WRITE H_FILE "#undef DES_PTR"
 268 $   WRITE H_FILE "#define DES_PTR"
 269 $   WRITE H_FILE "#undef DES_RISC1"
 270 $   WRITE H_FILE "#undef DES_RISC2"
 271 $   WRITE H_FILE "#define DES_RISC1"
 272 $   WRITE H_FILE "#undef DES_UNROLL"
 273 $   WRITE H_FILE "#define DES_UNROLL"
 274 $   WRITE H_FILE "#endif"
 275 $!
 276 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 277 $   WRITE H_FILE "#undef BN_LLONG"      ! Never define with SIXTY_FOUR_BIT
 278 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 279 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 280 $   WRITE H_FILE "#define SIXTY_FOUR_BIT"
 281 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 282 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 283 $   WRITE H_FILE "#undef EIGHT_BIT"
 284 $   WRITE H_FILE "#endif"
 285 $
 286 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 287 $!
 288 $!  Else...
 289 $!
 290 $ ELSE
 291 $!
 292 $!  Write the VAX specific data
 293 $!
 294 $   WRITE H_FILE "#if defined(HEADER_RC4_H)"
 295 $   WRITE H_FILE "#undef RC4_INT"
 296 $   WRITE H_FILE "#define RC4_INT unsigned char"
 297 $   WRITE H_FILE "#undef RC4_CHUNK"
 298 $   WRITE H_FILE "#define RC4_CHUNK unsigned long"
 299 $   WRITE H_FILE "#endif"
 300 $!
 301 $   WRITE H_FILE "#if defined(HEADER_DES_LOCL_H)"
 302 $   WRITE H_FILE "#undef DES_LONG"
 303 $   WRITE H_FILE "#define DES_LONG unsigned long"
 304 $   WRITE H_FILE "#undef DES_PTR"
 305 $   WRITE H_FILE "#define DES_PTR"
 306 $   WRITE H_FILE "#undef DES_RISC1"
 307 $   WRITE H_FILE "#undef DES_RISC2"
 308 $   WRITE H_FILE "#undef DES_UNROLL"
 309 $   WRITE H_FILE "#endif"
 310 $!
 311 $   WRITE H_FILE "#if defined(HEADER_BN_H)"
 312 $   WRITE H_FILE "#undef BN_LLONG"      ! VAX C/DEC C doesn't have long long
 313 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT_LONG"
 314 $   WRITE H_FILE "#undef SIXTY_FOUR_BIT"
 315 $   WRITE H_FILE "#undef THIRTY_TWO_BIT"
 316 $   WRITE H_FILE "#define THIRTY_TWO_BIT"
 317 $   WRITE H_FILE "#undef SIXTEEN_BIT"
 318 $   WRITE H_FILE "#undef EIGHT_BIT"
 319 $   WRITE H_FILE "#endif"
 320 $!
 321 $   WRITE H_FILE "#if defined(HEADER_SHA_H)"
 322 $   WRITE H_FILE "#undef OPENSSL_NO_SHA512"
 323 $   WRITE H_FILE "#define OPENSSL_NO_SHA512"
 324 $   WRITE H_FILE "#endif"
 325 $!
 326 $   WRITE H_FILE "#undef OPENSSL_EXPORT_VAR_AS_FUNCTION"
 327 $   WRITE H_FILE "#define OPENSSL_EXPORT_VAR_AS_FUNCTION"
 328 $!
 329 $!  End
 330 $!
 331 $ ENDIF
 332 $!
 333 $! Close the [.CRYPTO]OPENSSLCONF.H file
 334 $!
 335 $ CLOSE H_FILE
 336 $!
 337 $! That's All, Time To RETURN.
 338 $!
 339 $ RETURN
 340 $!
 341 $! Rebuild The "[.CRYPTO]BUILDINF.H" file.
 342 $!
 343 $ BUILDINF:
 344 $!
 345 $! Tell The User We Are Creating The [.CRYPTO]BUILDINF.H File.
 346 $!
 347 $ WRITE SYS$OUTPUT "Creating [.CRYPTO]BUILDINF.H Include File."
 348 $!
 349 $! Create The [.CRYPTO]BUILDINF.H File.
 350 $!
 351 $ OPEN/WRITE H_FILE SYS$DISK:[.CRYPTO]BUILDINF.H
 352 $!
 353 $! Get The Current Date & Time.
 354 $!
 355 $ TIME = F$TIME()
 356 $!
 357 $! Write The [.CRYPTO]BUILDINF.H File.
 358 $!
 359 $ WRITE H_FILE "#define CFLAGS """" /* Not filled in for now */"
 360 $ WRITE H_FILE "#define PLATFORM ""VMS"""
 361 $ WRITE H_FILE "#define DATE ""''TIME'"" "
 362 $!
 363 $! Close The [.CRYPTO]BUILDINF.H File.
 364 $!
 365 $ CLOSE H_FILE
 366 $!
 367 $! That's All, Time To RETURN.
 368 $!
 369 $ RETURN
 370 $!
 371 $! Copy a lot of files around.
 372 $!
 373 $ SOFTLINKS:
 374 $!
 375 $! Tell The User We Are Partly Rebuilding The [.APPS] Directory.
 376 $!
 377 $ WRITE SYS$OUTPUT "Rebuilding The '[.APPS]MD4.C', '[.APPS]MD5.C' And '[.APPS]RMD160.C' Files."
 378 $!
 379 $ DELETE SYS$DISK:[.APPS]MD4.C;*,MD5.C;*,RMD160.C;*
 380 $!
 381 $! Copy MD4.C from [.CRYPTO.MD4] into [.APPS]
 382 $!
 383 $ COPY SYS$DISK:[.CRYPTO.MD4]MD4.C SYS$DISK:[.APPS]
 384 $!
 385 $! Copy MD5.C from [.CRYPTO.MD5] into [.APPS]
 386 $!
 387 $ COPY SYS$DISK:[.CRYPTO.MD5]MD5.C SYS$DISK:[.APPS]
 388 $!
 389 $! Copy RMD160.C from [.CRYPTO.RIPEMD] into [.APPS]
 390 $!
 391 $ COPY SYS$DISK:[.CRYPTO.RIPEMD]RMD160.C SYS$DISK:[.APPS]
 392 $!
 393 $! Tell The User We Are Partly Rebuilding The [.TEST] Directory.
 394 $!
 395 $ WRITE SYS$OUTPUT "Rebuilding The '[.TEST]*.C' Files."
 396 $!
 397 $! First, We Have To "Rebuild" The "[.TEST]" Directory, So Delete
 398 $! All The "C" Files That Are Currently There Now.
 399 $!
 400 $ DELETE SYS$DISK:[.TEST]*.C;*
 401 $ DELETE SYS$DISK:[.TEST]EVPTESTS.TXT;*
 402 $!
 403 $! Copy all the *TEST.C files from [.CRYPTO...] into [.TEST]
 404 $!
 405 $ COPY SYS$DISK:[.CRYPTO.*]%*TEST.C SYS$DISK:[.TEST]
 406 $ COPY SYS$DISK:[.CRYPTO.SHA]SHA%%%T.C SYS$DISK:[.TEST]
 407 $ COPY SYS$DISK:[.CRYPTO.EVP]EVPTESTS.TXT SYS$DISK:[.TEST]
 408 $!
 409 $! Copy all the *TEST.C files from [.SSL...] into [.TEST]
 410 $!
 411 $ COPY SYS$DISK:[.SSL]%*TEST.C SYS$DISK:[.TEST]
 412 $!
 413 $! Tell The User We Are Rebuilding The [.INCLUDE.OPENSSL] Directory.
 414 $!
 415 $ WRITE SYS$OUTPUT "Rebuilding The '[.INCLUDE.OPENSSL]' Directory."
 416 $!
 417 $! First, make sure the directory exists
 418 $!
 419 $ IF F$PARSE("SYS$DISK:[.INCLUDE.OPENSSL]") .EQS. "" THEN -
 420      CREATE/DIRECTORY SYS$DISK:[.INCLUDE.OPENSSL]
 421 $!
 422 $! Copy All The ".H" Files From The Main Directory.
 423 $!
 424 $ EXHEADER := e_os2.h
 425 $ COPY 'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 426 $!
 427 $! Copy All The ".H" Files From The [.CRYPTO] Directory Tree.
 428 $!
 429 $ SDIRS := ,-
 430    OBJECTS,-
 431    MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,-
 432    DES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,-
 433    BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,AES,-
 434    BUFFER,BIO,STACK,LHASH,RAND,ERR,-
 435    EVP,ASN1,PEM,X509,X509V3,CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5,-
 436    STORE,PQUEUE
 437 $ EXHEADER_ := crypto.h,tmdiff.h,opensslv.h,opensslconf.h,ebcdic.h,symhacks.h,-
 438                 ossl_typ.h
 439 $ EXHEADER_OBJECTS := objects.h,obj_mac.h
 440 $ EXHEADER_MD2 := md2.h
 441 $ EXHEADER_MD4 := md4.h
 442 $ EXHEADER_MD5 := md5.h
 443 $ EXHEADER_SHA := sha.h
 444 $ EXHEADER_MDC2 := mdc2.h
 445 $ EXHEADER_HMAC := hmac.h
 446 $ EXHEADER_RIPEMD := ripemd.h
 447 $ EXHEADER_DES := des.h,des_old.h
 448 $ EXHEADER_RC2 := rc2.h
 449 $ EXHEADER_RC4 := rc4.h
 450 $ EXHEADER_RC5 := rc5.h
 451 $ EXHEADER_IDEA := idea.h
 452 $ EXHEADER_BF := blowfish.h
 453 $ EXHEADER_CAST := cast.h
 454 $ EXHEADER_CAMELLIA := camellia.h
 455 $ EXHEADER_SEED := seed.h
 456 $ EXHEADER_BN := bn.h
 457 $ EXHEADER_EC := ec.h
 458 $ EXHEADER_RSA := rsa.h
 459 $ EXHEADER_DSA := dsa.h
 460 $ EXHEADER_ECDSA := ecdsa.h
 461 $ EXHEADER_DH := dh.h
 462 $ EXHEADER_ECDH := ecdh.h
 463 $ EXHEADER_DSO := dso.h
 464 $ EXHEADER_ENGINE := engine.h
 465 $ EXHEADER_AES := aes.h
 466 $ EXHEADER_BUFFER := buffer.h
 467 $ EXHEADER_BIO := bio.h
 468 $ EXHEADER_STACK := stack.h,safestack.h
 469 $ EXHEADER_LHASH := lhash.h
 470 $ EXHEADER_RAND := rand.h
 471 $ EXHEADER_ERR := err.h
 472 $ EXHEADER_EVP := evp.h
 473 $ EXHEADER_ASN1 := asn1.h,asn1_mac.h,asn1t.h
 474 $ EXHEADER_PEM := pem.h,pem2.h
 475 $ EXHEADER_X509 := x509.h,x509_vfy.h
 476 $ EXHEADER_X509V3 := x509v3.h
 477 $ EXHEADER_CONF := conf.h,conf_api.h
 478 $ EXHEADER_TXT_DB := txt_db.h
 479 $ EXHEADER_PKCS7 := pkcs7.h
 480 $ EXHEADER_PKCS12 := pkcs12.h
 481 $ EXHEADER_COMP := comp.h
 482 $ EXHEADER_OCSP := ocsp.h
 483 $ EXHEADER_UI := ui.h,ui_compat.h
 484 $ EXHEADER_KRB5 := krb5_asn.h
 485 $!EXHEADER_STORE := store.h,str_compat.h
 486 $ EXHEADER_STORE := store.h
 487 $ EXHEADER_PQUEUE := pqueue.h,pq_compat.h
 488 $
 489 $ I = 0
 490 $ LOOP_SDIRS:
 491 $ D = F$EDIT(F$ELEMENT(I, ",", SDIRS),"TRIM")
 492 $ I = I + 1
 493 $ IF D .EQS. "," THEN GOTO LOOP_SDIRS_END
 494 $ tmp = EXHEADER_'D'
 495 $ IF D .EQS. ""
 496 $ THEN
 497 $   COPY [.CRYPTO]'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 498 $ ELSE
 499 $   COPY [.CRYPTO.'D']'tmp' SYS$DISK:[.INCLUDE.OPENSSL] !/LOG
 500 $ ENDIF
 501 $ GOTO LOOP_SDIRS
 502 $ LOOP_SDIRS_END:
 503 $!
 504 $! Copy All The ".H" Files From The [.SSL] Directory.
 505 $!
 506 $ EXHEADER := ssl.h,ssl2.h,ssl3.h,ssl23.h,tls1.h,dtls1.h,kssl.h
 507 $ COPY SYS$DISK:[.SSL]'EXHEADER' SYS$DISK:[.INCLUDE.OPENSSL]
 508 $!
 509 $! Purge all doubles
 510 $!
 511 $ PURGE SYS$DISK:[.INCLUDE.OPENSSL]*.H
 512 $!
 513 $! That's All, Time To RETURN.
 514 $!
 515 $ RETURN
 516 $!
 517 $! Build The "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library.
 518 $!
 519 $ CRYPTO:
 520 $!
 521 $! Tell The User What We Are Doing.
 522 $!
 523 $ WRITE SYS$OUTPUT ""
 524 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.CRYPTO]LIBCRYPTO.OLB Library."
 525 $!
 526 $! Go To The [.CRYPTO] Directory.
 527 $!
 528 $ SET DEFAULT SYS$DISK:[.CRYPTO]
 529 $!
 530 $! Build The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
 531 $!
 532 $ @CRYPTO-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" "''ISSEVEN'" "''BUILDPART'"
 533 $!
 534 $! Build The [.xxx.EXE.CRYPTO]*.EXE Test Applications.
 535 $!
 536 $ @CRYPTO-LIB APPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN' "''BUILDPART'"
 537 $!
 538 $! Go Back To The Main Directory.
 539 $!
 540 $ SET DEFAULT [-]
 541 $!
 542 $! Time To RETURN.
 543 $!
 544 $ RETURN
 545 $!
 546 $! Build The "[.xxx.EXE.SSL]LIBSSL.OLB" Library.
 547 $!
 548 $ SSL:
 549 $!
 550 $! Tell The User What We Are Doing.
 551 $!
 552 $ WRITE SYS$OUTPUT ""
 553 $ WRITE SYS$OUTPUT "Building The [.",ARCH,".EXE.SSL]LIBSSL.OLB Library."
 554 $!
 555 $! Go To The [.SSL] Directory.
 556 $!
 557 $ SET DEFAULT SYS$DISK:[.SSL]
 558 $!
 559 $! Build The [.xxx.EXE.SSL]LIBSSL.OLB Library.
 560 $!
 561 $ @SSL-LIB LIBRARY 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 562 $!
 563 $! Go Back To The Main Directory.
 564 $!
 565 $ SET DEFAULT [-]
 566 $!
 567 $! Time To Return.
 568 $!
 569 $ RETURN
 570 $!
 571 $! Build The "[.xxx.EXE.SSL]SSL_TASK.EXE" Program.
 572 $!
 573 $ SSL_TASK:
 574 $!
 575 $! Tell The User What We Are Doing.
 576 $!
 577 $ WRITE SYS$OUTPUT ""
 578 $ WRITE SYS$OUTPUT "Building DECNet Based SSL Engine, [.",ARCH,".EXE.SSL]SSL_TASK.EXE"
 579 $!
 580 $! Go To The [.SSL] Directory.
 581 $!
 582 $ SET DEFAULT SYS$DISK:[.SSL]
 583 $!
 584 $! Build The [.xxx.EXE.SSL]SSL_TASK.EXE
 585 $!
 586 $ @SSL-LIB SSL_TASK 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 587 $!
 588 $! Go Back To The Main Directory.
 589 $!
 590 $ SET DEFAULT [-]
 591 $!
 592 $! That's All, Time To RETURN.
 593 $!
 594 $ RETURN
 595 $!
 596 $! Build The OpenSSL Test Programs.
 597 $!
 598 $ TEST:
 599 $!
 600 $! Tell The User What We Are Doing.
 601 $!
 602 $ WRITE SYS$OUTPUT ""
 603 $ WRITE SYS$OUTPUT "Building The OpenSSL [.",ARCH,".EXE.TEST] Test Utilities."
 604 $!
 605 $! Go To The [.TEST] Directory.
 606 $!
 607 $ SET DEFAULT SYS$DISK:[.TEST]
 608 $!
 609 $! Build The Test Programs.
 610 $!
 611 $ @MAKETESTS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 612 $!
 613 $! Go Back To The Main Directory.
 614 $!
 615 $ SET DEFAULT [-]
 616 $!
 617 $! That's All, Time To RETURN.
 618 $!
 619 $ RETURN
 620 $!
 621 $! Build The OpenSSL Application Programs.
 622 $!
 623 $ APPS:
 624 $!
 625 $! Tell The User What We Are Doing.
 626 $!
 627 $ WRITE SYS$OUTPUT ""
 628 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCH,".EXE.APPS] Applications."
 629 $!
 630 $! Go To The [.APPS] Directory.
 631 $!
 632 $ SET DEFAULT SYS$DISK:[.APPS]
 633 $!
 634 $! Build The Application Programs.
 635 $!
 636 $ @MAKEAPPS 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN'
 637 $!
 638 $! Go Back To The Main Directory.
 639 $!
 640 $ SET DEFAULT [-]
 641 $!
 642 $! That's All, Time To RETURN.
 643 $!
 644 $ RETURN
 645 $!
 646 $! Build The OpenSSL Application Programs.
 647 $!
 648 $ ENGINES:
 649 $!
 650 $! Tell The User What We Are Doing.
 651 $!
 652 $ WRITE SYS$OUTPUT ""
 653 $ WRITE SYS$OUTPUT "Building OpenSSL [.",ARCH,".EXE.ENGINES] Engines."
 654 $!
 655 $! Go To The [.ENGINES] Directory.
 656 $!
 657 $ SET DEFAULT SYS$DISK:[.ENGINES]
 658 $!
 659 $! Build The Application Programs.
 660 $!
 661 $ @MAKEENGINES ENGINES 'DEBUGGER' "''COMPILER'" "''TCPIP_TYPE'" 'ISSEVEN' "''BUILDPART'"
 662 $!
 663 $! Go Back To The Main Directory.
 664 $!
 665 $ SET DEFAULT [-]
 666 $!
 667 $! That's All, Time To RETURN.
 668 $!
 669 $ RETURN
 670 $!
 671 $! Check The User's Options.
 672 $!
 673 $ CHECK_OPTIONS:
 674 $!
 675 $! Check if there's a "part", and separate it out
 676 $!
 677 $ BUILDPART = F$ELEMENT(1,"/",P1)
 678 $ IF BUILDPART .EQS. "/"
 679 $ THEN
 680 $   BUILDPART = ""
 681 $ ELSE
 682 $   P1 = F$EXTRACT(0,F$LENGTH(P1) - F$LENGTH(BUILDPART) - 1, P1)
 683 $ ENDIF
 684 $!
 685 $! Check To See If P1 Is Blank.
 686 $!
 687 $ IF (P1.EQS."ALL")
 688 $ THEN
 689 $!
 690 $!   P1 Is ALL, So Build Everything.
 691 $!
 692 $    BUILDCOMMAND = "ALL"
 693 $!
 694 $! Else...
 695 $!
 696 $ ELSE
 697 $!
 698 $!  Else, Check To See If P1 Has A Valid Arguement.
 699 $!
 700 $   IF (P1.EQS."CONFIG").OR.(P1.EQS."BUILDINF").OR.(P1.EQS."SOFTLINKS") -
 701        .OR.(P1.EQS."BUILDALL") -
 702        .OR.(P1.EQS."CRYPTO").OR.(P1.EQS."SSL") -
 703        .OR.(P1.EQS."SSL_TASK").OR.(P1.EQS."TEST").OR.(P1.EQS."APPS")
 704 $   THEN
 705 $!
 706 $!    A Valid Arguement.
 707 $!
 708 $     BUILDCOMMAND = P1
 709 $!
 710 $!  Else...
 711 $!
 712 $   ELSE
 713 $!
 714 $!    Tell The User We Don't Know What They Want.
 715 $!
 716 $     WRITE SYS$OUTPUT ""
 717 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 718 $     WRITE SYS$OUTPUT ""
 719 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 720 $     WRITE SYS$OUTPUT "    CONFIG   :  Just build the [.CRYPTO]OPENSSLCONF.H file."
 721 $     WRITE SYS$OUTPUT "    BUILDINF :  Just build the [.CRYPTO]BUILDINF.H file."
 722 $     WRITE SYS$OUTPUT "    SOFTLINKS:  Just Fix The Unix soft links."
 723 $     WRITE SYS$OUTPUT "    BUILDALL :  Same as ALL, except CONFIG, BUILDINF and SOFTILNKS aren't done."
 724 $     WRITE SYS$OUTPUT "    CRYPTO   :  To Build Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 725 $     WRITE SYS$OUTPUT "    CRYPTO/x :  To Build Just The x Part Of The"
 726 $     WRITE SYS$OUTPUT "                [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 727 $     WRITE SYS$OUTPUT "    SSL      :  To Build Just The [.xxx.EXE.SSL]LIBSSL.OLB Library."
 728 $     WRITE SYS$OUTPUT "    SSL_TASK :  To Build Just The [.xxx.EXE.SSL]SSL_TASK.EXE Program."
 729 $     WRITE SYS$OUTPUT "    TEST     :  To Build Just The OpenSSL Test Programs."
 730 $     WRITE SYS$OUTPUT "    APPS     :  To Build Just The OpenSSL Application Programs."
 731 $     WRITE SYS$OUTPUT ""
 732 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 733 $     WRITE SYS$OUTPUT ""
 734 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 735 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 736 $     WRITE SYS$OUTPUT ""
 737 $!
 738 $!    Time To EXIT.
 739 $!
 740 $     EXIT
 741 $!
 742 $!  End The Valid Argument Check.
 743 $!
 744 $   ENDIF
 745 $!
 746 $! End The P1 Check.
 747 $!
 748 $ ENDIF
 749 $!
 750 $! Check To See If P3 Is Blank.
 751 $!
 752 $ IF (P3.EQS."NODEBUG")
 753 $ THEN
 754 $!
 755 $!   P3 Is NODEBUG, So Compile Without Debugger Information.
 756 $!
 757 $    DEBUGGER = "NODEBUG"
 758 $!
 759 $! Else...
 760 $!
 761 $ ELSE
 762 $!
 763 $!  Check To See If We Are To Compile With Debugger Information.
 764 $!
 765 $   IF (P3.EQS."DEBUG")
 766 $   THEN
 767 $!
 768 $!    Compile With Debugger Information.
 769 $!
 770 $     DEBUGGER = "DEBUG"
 771 $!
 772 $!  Else...
 773 $!
 774 $   ELSE
 775 $!
 776 $!    Tell The User Entered An Invalid Option..
 777 $!
 778 $     WRITE SYS$OUTPUT ""
 779 $     WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
 780 $     WRITE SYS$OUTPUT ""
 781 $     WRITE SYS$OUTPUT "    DEBUG    :  Compile With The Debugger Information."
 782 $     WRITE SYS$OUTPUT "    NODEBUG  :  Compile Without The Debugger Information."
 783 $     WRITE SYS$OUTPUT ""
 784 $!
 785 $!    Time To EXIT.
 786 $!
 787 $     EXIT
 788 $!
 789 $!  End The Valid Arguement Check.
 790 $!
 791 $   ENDIF
 792 $!
 793 $! End The P3 Check.
 794 $!
 795 $ ENDIF
 796 $!
 797 $! Check To See If P4 Is Blank.
 798 $!
 799 $ IF (P4.EQS."")
 800 $ THEN
 801 $!
 802 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 803 $!  Find Out Which One To Use.
 804 $!
 805 $!  Check To See If We Have GNU C.
 806 $!
 807 $   IF (F$TRNLNM("GNU_CC").NES."")
 808 $   THEN
 809 $!
 810 $!    Looks Like GNUC, Set To Use GNUC.
 811 $!
 812 $     COMPILER = "GNUC"
 813 $!
 814 $!    Tell The User We Are Using GNUC.
 815 $!
 816 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 817 $!
 818 $!  End The GNU C Compiler Check.
 819 $!
 820 $   ENDIF
 821 $!
 822 $!  Check To See If We Have VAXC Or DECC.
 823 $!
 824 $   IF (F$GETSYI("CPU").GE.128).OR.(F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC")
 825 $   THEN
 826 $!
 827 $!    Looks Like DECC, Set To Use DECC.
 828 $!
 829 $     COMPILER = "DECC"
 830 $!
 831 $!    Tell The User We Are Using DECC.
 832 $!
 833 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 834 $!
 835 $!  Else...
 836 $!
 837 $   ELSE
 838 $!
 839 $!    Looks Like VAXC, Set To Use VAXC.
 840 $!
 841 $     COMPILER = "VAXC"
 842 $!
 843 $!    Tell The User We Are Using VAX C.
 844 $!
 845 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 846 $!
 847 $!  End The DECC & VAXC Compiler Check.
 848 $!
 849 $   ENDIF
 850 $!
 851 $! Else...
 852 $!
 853 $ ELSE
 854 $!
 855 $!  Check To See If The User Entered A Valid Paramter.
 856 $!
 857 $   IF (P4.EQS."VAXC").OR.(P4.EQS."DECC").OR.(P4.EQS."GNUC")!.OR.(P4.EQS."LINK")
 858 $   THEN
 859 $!
 860 $!    Check To See If The User Wanted To Just LINK.
 861 $!
 862 $     IF (P4.EQS."LINK")
 863 $     THEN
 864 $!
 865 $!      Looks Like LINK-only
 866 $!
 867 $       COMPILER = "LINK"
 868 $!
 869 $!      Tell The User We Are Only Linking.
 870 $!
 871 $       WRITE SYS$OUTPUT "LINK Only.  This actually NOT YET SUPPORTED!"
 872 $!
 873 $!    End LINK Check.
 874 $!
 875 $     ENDIF
 876 $!
 877 $!    Check To See If The User Wanted DECC.
 878 $!
 879 $     IF (P4.EQS."DECC")
 880 $     THEN
 881 $!
 882 $!      Looks Like DECC, Set To Use DECC.
 883 $!
 884 $       COMPILER = "DECC"
 885 $!
 886 $!      Tell The User We Are Using DECC.
 887 $!
 888 $       WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 889 $!
 890 $!    End DECC Check.
 891 $!
 892 $     ENDIF
 893 $!
 894 $!    Check To See If We Are To Use VAXC.
 895 $!
 896 $     IF (P4.EQS."VAXC")
 897 $     THEN
 898 $!
 899 $!      Looks Like VAXC, Set To Use VAXC.
 900 $!
 901 $       COMPILER = "VAXC"
 902 $!
 903 $!      Tell The User We Are Using VAX C.
 904 $!
 905 $       WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 906 $!
 907 $!    End VAXC Check
 908 $!
 909 $     ENDIF
 910 $!
 911 $!    Check To See If We Are To Use GNU C.
 912 $!
 913 $     IF (P4.EQS."GNUC")
 914 $     THEN
 915 $!
 916 $!      Looks Like GNUC, Set To Use GNUC.
 917 $!
 918 $       COMPILER = "GNUC"
 919 $!
 920 $!      Tell The User We Are Using GNUC.
 921 $!
 922 $       WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 923 $!
 924 $!    End The GNU C Check.
 925 $!
 926 $     ENDIF
 927 $!
 928 $!  Else The User Entered An Invalid Arguement.
 929 $!
 930 $   ELSE
 931 $!
 932 $!    Tell The User We Don't Know What They Want.
 933 $!
 934 $     WRITE SYS$OUTPUT ""
 935 $     WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
 936 $     WRITE SYS$OUTPUT ""
 937 $     WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 938 $     WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 939 $     WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 940 $     WRITE SYS$OUTPUT ""
 941 $!
 942 $!    Time To EXIT.
 943 $!
 944 $     EXIT
 945 $!
 946 $!  End The Valid Arguement Check.
 947 $!
 948 $   ENDIF
 949 $!
 950 $! End The P4 Check.
 951 $!
 952 $ ENDIF
 953 $!
 954 $! Time to check the contents of P5, and to make sure we get the correct library.
 955 $!
 956 $ IF P5.EQS."SOCKETSHR" .OR. P5.EQS."MULTINET" .OR. P5.EQS."UCX" -
 957      .OR. P5.EQS."TCPIP" .OR. P5.EQS."NONE"
 958 $ THEN
 959 $!
 960 $!  Check to see if SOCKETSHR was chosen
 961 $!
 962 $   IF P5.EQS."SOCKETSHR"
 963 $   THEN
 964 $!
 965 $!    Set the library to use SOCKETSHR
 966 $!
 967 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
 968 $!
 969 $!    Tell the user
 970 $!
 971 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 972 $!
 973 $!    Done with SOCKETSHR
 974 $!
 975 $   ENDIF
 976 $!
 977 $!  Check to see if MULTINET was chosen
 978 $!
 979 $   IF P5.EQS."MULTINET"
 980 $   THEN
 981 $!
 982 $!    Set the library to use UCX emulation.
 983 $!
 984 $     P5 = "UCX"
 985 $!
 986 $!    Tell the user
 987 $!
 988 $     WRITE SYS$OUTPUT "Using MultiNet via UCX emulation for TCP/IP"
 989 $!
 990 $!    Done with MULTINET
 991 $!
 992 $   ENDIF
 993 $!
 994 $!  Check to see if UCX was chosen
 995 $!
 996 $   IF P5.EQS."UCX"
 997 $   THEN
 998 $!
 999 $!    Set the library to use UCX.
1000 $!
1001 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1002 $!
1003 $!    Tell the user
1004 $!
1005 $     WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
1006 $!
1007 $!    Done with UCX
1008 $!
1009 $   ENDIF
1010 $!
1011 $!  Check to see if TCPIP was chosen
1012 $!
1013 $   IF P5.EQS."TCPIP"
1014 $   THEN
1015 $!
1016 $!    Set the library to use TCPIP (post UCX).
1017 $!
1018 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1019 $!
1020 $!    Tell the user
1021 $!
1022 $     WRITE SYS$OUTPUT "Using TCPIP (post UCX) for TCP/IP"
1023 $!
1024 $!    Done with TCPIP
1025 $!
1026 $   ENDIF
1027 $!
1028 $!  Check to see if NONE was chosen
1029 $!
1030 $   IF P5.EQS."NONE"
1031 $   THEN
1032 $!
1033 $!    Do not use a TCPIP library.
1034 $!
1035 $     TCPIP_LIB = ""
1036 $!
1037 $!    Tell the user
1038 $!
1039 $     WRITE SYS$OUTPUT "A specific TCPIP library will not be used."
1040 $!
1041 $!    Done with NONE.
1042 $!
1043 $   ENDIF
1044 $!
1045 $!  Set the TCPIP_TYPE symbol
1046 $!
1047 $   TCPIP_TYPE = P5
1048 $!
1049 $!  Print info
1050 $!
1051 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1052 $!
1053 $!  Else The User Entered An Invalid Arguement.
1054 $!
1055 $ ELSE
1056 $   IF P5 .NES. ""
1057 $   THEN
1058 $!
1059 $!    Tell The User We Don't Know What They Want.
1060 $!
1061 $     WRITE SYS$OUTPUT ""
1062 $     WRITE SYS$OUTPUT "The Option ",P5," Is Invalid.  The Valid Options Are:"
1063 $     WRITE SYS$OUTPUT ""
1064 $     WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1065 $     WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1066 $     WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP TCP/IP (post UCX) library."
1067 $     WRITE SYS$OUTPUT "    NONE       :  To not link with a specific TCP/IP library."
1068 $     WRITE SYS$OUTPUT ""
1069 $!
1070 $!    Time To EXIT.
1071 $!
1072 $     EXIT
1073 $   ELSE
1074 $!
1075 $! If TCPIP is not defined, then hardcode it to make
1076 $! it clear that no TCPIP is desired.
1077 $!
1078 $     IF P5 .EQS. ""
1079 $     THEN
1080 $       TCPIP_LIB = ""
1081 $       TCPIP_TYPE = "NONE"
1082 $     ELSE
1083 $!
1084 $!    Set the TCPIP_TYPE symbol
1085 $!
1086 $       TCPIP_TYPE = P5
1087 $     ENDIF
1088 $   ENDIF
1089 $!
1090 $!  Done with TCP/IP libraries
1091 $!
1092 $ ENDIF
1093 $!
1094 $! Special Threads For OpenVMS v7.1 Or Later
1095 $!
1096 $! Written By:  Richard Levitte
1097 $!              richard@levitte.org
1098 $!
1099 $!
1100 $! Check To See If We Have A Option For P6.
1101 $!
1102 $ IF (P6.EQS."")
1103 $ THEN
1104 $!
1105 $!  Get The Version Of VMS We Are Using.
1106 $!
1107 $   ISSEVEN :=
1108 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
1109 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
1110 $!
1111 $!  Check To See If The VMS Version Is v7.1 Or Later.
1112 $!
1113 $   IF (TMP.GE.71)
1114 $   THEN
1115 $!
1116 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
1117 $!
1118 $     ISSEVEN := ,PTHREAD_USE_D4
1119 $!
1120 $!  End The VMS Version Check.
1121 $!
1122 $   ENDIF
1123 $!
1124 $! End The P6 Check.
1125 $!
1126 $ ENDIF
1127 $!
1128 $!  Time To RETURN...
1129 $!
1130 $ RETURN