fips-1.0/fips-lib.com

   1 $!
   2 $!  FIPS-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates the FIPS parts of the
  11 $!  "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" library for OpenSSL.  The "xxx"
  12 $!  denotes the machine architecture of AXP or VAX.
  13 $!
  14 $!  It was re-written so it would try to determine what "C" compiler to use
  15 $!  or you can specify which "C" compiler to use.
  16 $!
  17 $!  Specify the following as P1 to build just that part or ALL to just
  18 $!  build everything.
  19 $!
  20 $!              LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  21 $!              APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
  22 $!              ALL        To do both LIBRARY and APPS
  23 $!
  24 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  25 $!  information.
  26 $!
  27 $!  Specify which compiler at P3 to try to compile under.
  28 $!
  29 $!         VAXC  For VAX C.
  30 $!         DECC  For DEC C.
  31 $!         GNUC  For GNU C.
  32 $!
  33 $!  If you don't speficy a compiler, it will try to determine which
  34 $!  "C" compiler to use.
  35 $!
  36 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  37 $!  keywords:
  38 $!
  39 $!      UCX             for UCX
  40 $!      TCPIP           for TCPIP (post UCX)
  41 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  42 $!
  43 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  44 $!
  45 $!  P6, if defined, sets a choice of crypto methods to compile.
  46 $!  WARNING: this should only be done to recompile some part of an already
  47 $!  fully compiled library.
  48 $!
  49 $!
  50 $! Define A TCP/IP Library That We Will Need To Link To.
  51 $! (That Is, If We Need To Link To One.)
  52 $!
  53 $ TCPIP_LIB = ""
  54 $!
  55 $! Check Which Architecture We Are Using.
  56 $!
  57 $ IF (F$GETSYI("CPU").GE.128)
  58 $ THEN
  59 $!
  60 $!  The Architecture Is AXP
  61 $!
  62 $   ARCH := AXP
  63 $!
  64 $! Else...
  65 $!
  66 $ ELSE
  67 $!
  68 $!  The Architecture Is VAX.
  69 $!
  70 $   ARCH := VAX
  71 $!
  72 $! End The Architecture Check.
  73 $!
  74 $ ENDIF
  75 $!
  76 $! Define The Different Encryption Types.
  77 $!
  78 $ ENCRYPT_TYPES = "Basic,SHA,RAND,DES,AES,DSA,RSA,DH,HMAC"
  79 $!
  80 $! Check To Make Sure We Have Valid Command Line Parameters.
  81 $!
  82 $ GOSUB CHECK_OPTIONS
  83 $!
  84 $! Initialise logical names and such
  85 $!
  86 $ GOSUB INITIALISE
  87 $!
  88 $! Tell The User What Kind of Machine We Run On.
  89 $!
  90 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
  91 $!
  92 $! Define The OBJ Directory.
  93 $!
  94 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
  95 $!
  96 $! Check To See If The Architecture Specific OBJ Directory Exists.
  97 $!
  98 $ IF (F$PARSE(OBJ_DIR).EQS."")
  99 $ THEN
 100 $!
 101 $!  It Dosen't Exist, So Create It.
 102 $!
 103 $   CREATE/DIR 'OBJ_DIR'
 104 $!
 105 $! End The Architecture Specific OBJ Directory Check.
 106 $!
 107 $ ENDIF
 108 $!
 109 $! Define The EXE Directory.
 110 $!
 111 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
 112 $!
 113 $! Check To See If The Architecture Specific Directory Exists.
 114 $!
 115 $ IF (F$PARSE(EXE_DIR).EQS."")
 116 $ THEN
 117 $!
 118 $!  It Dosen't Exist, So Create It.
 119 $!
 120 $   CREATE/DIRECTORY 'EXE_DIR'
 121 $!
 122 $! End The Architecture Specific Directory Check.
 123 $!
 124 $ ENDIF
 125 $!
 126 $! Define The Library Name.
 127 $!
 128 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
 129 $!
 130 $! Define The CRYPTO-LIB We Are To Use.
 131 $!
 132 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
 133 $!
 134 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 135 $!
 136 $ IF (F$SEARCH(LIB_NAME).EQS."")
 137 $ THEN
 138 $!
 139 $! Guess Not, Create The Library.
 140 $!
 141 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 142 $!
 143 $! End The Library Check.
 144 $!
 145 $ ENDIF
 146 $!
 147 $! Build our options file for the application
 148 $!
 149 $ GOSUB CHECK_OPT_FILE
 150 $!
 151 $! Define The Different Encryption "library" Strings.
 152 $!
 153 $ LIB_ = "fips,fips_err_wrapper"
 154 $ LIB_SHA = "fips_sha1dgst,fips_sha1_selftest,fips_sha256,fips_sha512"
 155 $ LIB_RAND = "fips_rand,fips_rand_selftest"
 156 $ LIB_DES = "fips_des_enc,fips_des_selftest,fips_set_key"
 157 $ LIB_AES = "fips_aes_core,fips_aes_selftest"
 158 $ LIB_DSA = "fips_dsa_ossl,fips_dsa_gen,fips_dsa_selftest"
 159 $ LIB_RSA = "fips_rsa_eay,fips_rsa_gen,fips_rsa_selftest,fips_rsa_x931g"
 160 $ LIB_DH = "fips_dh_check,fips_dh_gen,fips_dh_key"
 161 $ LIB_HMAC = "fips_hmac,fips_hmac_selftest"
 162 $!
 163 $! Setup exceptional compilations
 164 $!
 165 $ ! Add definitions for no threads on OpenVMS 7.1 and higher
 166 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 167 $ ! Disable the DOLLARID warning
 168 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,o_time,"
 169 $ ! Disable disjoint optimization
 170 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 171                     "sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 172 $ ! Disable the MIXLINKAGE warning
 173 $ COMPILEWITH_CC6 = ",fips_set_key,"
 174 $!
 175 $! Figure Out What Other Modules We Are To Build.
 176 $!
 177 $ BUILD_SET:
 178 $!
 179 $! Define A Module Counter.
 180 $!
 181 $ MODULE_COUNTER = 0
 182 $!
 183 $! Top Of The Loop.
 184 $!
 185 $ MODULE_NEXT:
 186 $!
 187 $! Extract The Module Name From The Encryption List.
 188 $!
 189 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 190 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 191 $ MODULE_NAME1 = MODULE_NAME
 192 $!
 193 $! Check To See If We Are At The End Of The Module List.
 194 $!
 195 $ IF (MODULE_NAME.EQS.",")
 196 $ THEN
 197 $!
 198 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 199 $!
 200 $   GOTO MODULE_DONE
 201 $!
 202 $! End The Module List Check.
 203 $!
 204 $ ENDIF
 205 $!
 206 $! Increment The Moudle Counter.
 207 $!
 208 $ MODULE_COUNTER = MODULE_COUNTER + 1
 209 $!
 210 $! Create The Library and Apps Module Names.
 211 $!
 212 $ LIB_MODULE = "LIB_" + MODULE_NAME
 213 $ APPS_MODULE = "APPS_" + MODULE_NAME
 214 $ IF (MODULE_NAME.EQS."ASN1_2")
 215 $ THEN
 216 $   MODULE_NAME = "ASN1"
 217 $ ENDIF
 218 $ IF (MODULE_NAME.EQS."EVP_2")
 219 $ THEN
 220 $   MODULE_NAME = "EVP"
 221 $ ENDIF
 222 $!
 223 $! Set state (can be LIB and APPS)
 224 $!
 225 $ STATE = "LIB"
 226 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
 227 $!
 228 $! Check if the library module name actually is defined
 229 $!
 230 $ IF F$TYPE('LIB_MODULE') .EQS. ""
 231 $ THEN
 232 $   WRITE SYS$ERROR ""
 233 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
 234 $   WRITE SYS$ERROR ""
 235 $   GOTO MODULE_NEXT
 236 $ ENDIF
 237 $!
 238 $! Top Of The Module Loop.
 239 $!
 240 $ MODULE_AGAIN:
 241 $!
 242 $! Tell The User What Module We Are Building.
 243 $!
 244 $ IF (MODULE_NAME1.NES."")
 245 $ THEN
 246 $   IF STATE .EQS. "LIB"
 247 $   THEN
 248 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
 249 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
 250 $     THEN
 251 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
 252 $     ENDIF
 253 $   ENDIF
 254 $ ENDIF
 255 $!
 256 $!  Define A File Counter And Set It To "0".
 257 $!
 258 $ FILE_COUNTER = 0
 259 $ APPLICATION = ""
 260 $ APPLICATION_COUNTER = 0
 261 $!
 262 $! Top Of The File Loop.
 263 $!
 264 $ NEXT_FILE:
 265 $!
 266 $! Look in the LIB_MODULE is we're in state LIB
 267 $!
 268 $ IF STATE .EQS. "LIB"
 269 $ THEN
 270 $!
 271 $!   O.K, Extract The File Name From The File List.
 272 $!
 273 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 274 $!
 275 $!   else
 276 $!
 277 $ ELSE
 278 $   FILE_NAME = ","
 279 $!
 280 $   IF F$TYPE('APPS_MODULE') .NES. ""
 281 $   THEN
 282 $!
 283 $!     Extract The File Name From The File List.
 284 $!     This part is a bit more complicated.
 285 $!
 286 $     IF APPLICATION .EQS. ""
 287 $     THEN
 288 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 289 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 290 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 291 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 292 $       FILE_COUNTER = 0
 293 $     ENDIF
 294 $
 295 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 296 $!     SHOW SYMBOL APPLICATION*
 297 $!
 298 $     IF APPLICATION .NES. ";"
 299 $     THEN
 300 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
 301 $       IF FILE_NAME .EQS. ","
 302 $       THEN
 303 $         APPLICATION = ""
 304 $         GOTO NEXT_FILE
 305 $       ENDIF
 306 $     ENDIF
 307 $   ENDIF
 308 $ ENDIF
 309 $!
 310 $! Check To See If We Are At The End Of The File List.
 311 $!
 312 $ IF (FILE_NAME.EQS.",")
 313 $ THEN
 314 $!
 315 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
 316 $!
 317 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
 318 $   THEN
 319 $     STATE = "APPS"
 320 $     GOTO MODULE_AGAIN
 321 $   ELSE
 322 $     GOTO FILE_DONE
 323 $   ENDIF
 324 $!
 325 $! End The File List Check.
 326 $!
 327 $ ENDIF
 328 $!
 329 $! Increment The Counter.
 330 $!
 331 $ FILE_COUNTER = FILE_COUNTER + 1
 332 $!
 333 $! Create The Source File Name.
 334 $!
 335 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 336 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 337 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 338         FILE_NAME = FILE_NAME + ".c"
 339 $ IF (MODULE_NAME.NES."")
 340 $ THEN
 341 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 342 $ ELSE
 343 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 344 $ ENDIF
 345 $ SOURCE_FILE = SOURCE_FILE - "]["
 346 $!
 347 $! Create The Object File Name.
 348 $!
 349 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 350 $ ON WARNING THEN GOTO NEXT_FILE
 351 $!
 352 $! Check To See If The File We Want To Compile Is Actually There.
 353 $!
 354 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 355 $ THEN
 356 $!
 357 $!  Tell The User That The File Doesn't Exist.
 358 $!
 359 $   WRITE SYS$OUTPUT ""
 360 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 361 $   WRITE SYS$OUTPUT ""
 362 $!
 363 $!  Exit The Build.
 364 $!
 365 $   GOTO EXIT
 366 $!
 367 $! End The File Exist Check.
 368 $!
 369 $ ENDIF
 370 $!
 371 $! Tell The User We Are Compiling The File.
 372 $!
 373 $ IF (MODULE_NAME.EQS."")
 374 $ THEN
 375 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
 376 $ ENDIF
 377 $ IF (MODULE_NAME.NES."")
 378 $ THEN
 379 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
 380 $ ENDIF
 381 $!
 382 $! Compile The File.
 383 $!
 384 $ ON ERROR THEN GOTO NEXT_FILE
 385 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
 386 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 387 $ THEN
 388 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 389 $ ELSE
 390 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 391 $   THEN
 392 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 393 $   ELSE
 394 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 395 $     THEN
 396 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 397 $     ELSE
 398 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
 399 $       THEN
 400 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 401 $       ELSE
 402 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 403 $         THEN
 404 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 405 $         ELSE
 406 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 407 $         ENDIF
 408 $       ENDIF
 409 $     ENDIF
 410 $   ENDIF
 411 $ ENDIF
 412 $ IF STATE .EQS. "LIB"
 413 $ THEN
 414 $!
 415 $!   Add It To The Library.
 416 $!
 417 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 418 $!
 419 $!   Time To Clean Up The Object File.
 420 $!
 421 $   DELETE 'OBJECT_FILE';*
 422 $ ENDIF
 423 $!
 424 $! Go Back And Do It Again.
 425 $!
 426 $ GOTO NEXT_FILE
 427 $!
 428 $! All Done With This Library Part.
 429 $!
 430 $ FILE_DONE:
 431 $!
 432 $! Time To Build Some Applications
 433 $!
 434 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
 435 $ THEN
 436 $   APPLICATION_COUNTER = 0
 437 $ NEXT_APPLICATION:
 438 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 439 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
 440 $
 441 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 442 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 443 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 444 $
 445 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 446 $!   SHOW SYMBOL APPLICATION*
 447 $!
 448 $! Tell the user what happens
 449 $!
 450 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
 451 $!
 452 $! Link The Program.
 453 $!
 454 $   ON ERROR THEN GOTO NEXT_APPLICATION
 455 $!
 456 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 457 $!
 458 $   IF (TCPIP_LIB.NES."")
 459 $   THEN
 460 $!
 461 $!    Link With A TCP/IP Library.
 462 $!
 463 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 464           'OBJ_DIR''APPLICATION_OBJECTS', -
 465           'CRYPTO_LIB'/LIBRARY, -
 466           'TCPIP_LIB','OPT_FILE'/OPTION
 467 $!
 468 $! Else...
 469 $!
 470 $   ELSE
 471 $!
 472 $!    Don't Link With A TCP/IP Library.
 473 $!
 474 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 475           'OBJ_DIR''APPLICATION_OBJECTS',-
 476           'CRYPTO_LIB'/LIBRARY, -
 477           'OPT_FILE'/OPTION
 478 $!
 479 $! End The TCP/IP Library Check.
 480 $!
 481 $   ENDIF
 482 $   GOTO NEXT_APPLICATION
 483 $  APPLICATION_DONE:
 484 $ ENDIF
 485 $!
 486 $! Go Back And Get The Next Module.
 487 $!
 488 $ GOTO MODULE_NEXT
 489 $!
 490 $! All Done With This Module.
 491 $!
 492 $ MODULE_DONE:
 493 $!
 494 $! Tell The User That We Are All Done.
 495 $!
 496 $ WRITE SYS$OUTPUT "All Done..."
 497 $ EXIT:
 498 $ GOSUB CLEANUP
 499 $ EXIT
 500 $!
 501 $! Check For The Link Option FIle.
 502 $!
 503 $ CHECK_OPT_FILE:
 504 $!
 505 $! Check To See If We Need To Make A VAX C Option File.
 506 $!
 507 $ IF (COMPILER.EQS."VAXC")
 508 $ THEN
 509 $!
 510 $!  Check To See If We Already Have A VAX C Linker Option File.
 511 $!
 512 $   IF (F$SEARCH(OPT_FILE).EQS."")
 513 $   THEN
 514 $!
 515 $!    We Need A VAX C Linker Option File.
 516 $!
 517 $     CREATE 'OPT_FILE'
 518 $DECK
 519 !
 520 ! Default System Options File To Link Agianst
 521 ! The Sharable VAX C Runtime Library.
 522 !
 523 SYS$SHARE:VAXCRTL.EXE/SHARE
 524 $EOD
 525 $!
 526 $!  End The Option File Check.
 527 $!
 528 $   ENDIF
 529 $!
 530 $! End The VAXC Check.
 531 $!
 532 $ ENDIF
 533 $!
 534 $! Check To See If We Need A GNU C Option File.
 535 $!
 536 $ IF (COMPILER.EQS."GNUC")
 537 $ THEN
 538 $!
 539 $!  Check To See If We Already Have A GNU C Linker Option File.
 540 $!
 541 $   IF (F$SEARCH(OPT_FILE).EQS."")
 542 $   THEN
 543 $!
 544 $!    We Need A GNU C Linker Option File.
 545 $!
 546 $     CREATE 'OPT_FILE'
 547 $DECK
 548 !
 549 ! Default System Options File To Link Agianst
 550 ! The Sharable C Runtime Library.
 551 !
 552 GNU_CC:[000000]GCCLIB/LIBRARY
 553 SYS$SHARE:VAXCRTL/SHARE
 554 $EOD
 555 $!
 556 $!  End The Option File Check.
 557 $!
 558 $   ENDIF
 559 $!
 560 $! End The GNU C Check.
 561 $!
 562 $ ENDIF
 563 $!
 564 $! Check To See If We Need A DEC C Option File.
 565 $!
 566 $ IF (COMPILER.EQS."DECC")
 567 $ THEN
 568 $!
 569 $!  Check To See If We Already Have A DEC C Linker Option File.
 570 $!
 571 $   IF (F$SEARCH(OPT_FILE).EQS."")
 572 $   THEN
 573 $!
 574 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
 575 $!
 576 $     IF ARCH .EQS. "VAX"
 577 $     THEN
 578 $!
 579 $!      We Need A DEC C Linker Option File For VAX.
 580 $!
 581 $       CREATE 'OPT_FILE'
 582 $DECK
 583 !
 584 ! Default System Options File To Link Agianst
 585 ! The Sharable DEC C Runtime Library.
 586 !
 587 SYS$SHARE:DECC$SHR.EXE/SHARE
 588 $EOD
 589 $!
 590 $!    Else...
 591 $!
 592 $     ELSE
 593 $!
 594 $!      Create The AXP Linker Option File.
 595 $!
 596 $       CREATE 'OPT_FILE'
 597 $DECK
 598 !
 599 ! Default System Options File For AXP To Link Agianst
 600 ! The Sharable C Runtime Library.
 601 !
 602 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 603 SYS$SHARE:CMA$OPEN_RTL/SHARE
 604 $EOD
 605 $!
 606 $!    End The VAX/AXP DEC C Option File Check.
 607 $!
 608 $     ENDIF
 609 $!
 610 $!  End The Option File Search.
 611 $!
 612 $   ENDIF
 613 $!
 614 $! End The DEC C Check.
 615 $!
 616 $ ENDIF
 617 $!
 618 $!  Tell The User What Linker Option File We Are Using.
 619 $!
 620 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 621 $!
 622 $! Time To RETURN.
 623 $!
 624 $ RETURN
 625 $!
 626 $! Check The User's Options.
 627 $!
 628 $ CHECK_OPTIONS:
 629 $!
 630 $! Check To See If P1 Is Blank.
 631 $!
 632 $ IF (P1.EQS."ALL")
 633 $ THEN
 634 $!
 635 $!   P1 Is Blank, So Build Everything.
 636 $!
 637 $    BUILDALL = "TRUE"
 638 $!
 639 $! Else...
 640 $!
 641 $ ELSE
 642 $!
 643 $!  Else, Check To See If P1 Has A Valid Arguement.
 644 $!
 645 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
 646 $   THEN
 647 $!
 648 $!    A Valid Arguement.
 649 $!
 650 $     BUILDALL = P1
 651 $!
 652 $!  Else...
 653 $!
 654 $   ELSE
 655 $!
 656 $!    Tell The User We Don't Know What They Want.
 657 $!
 658 $     WRITE SYS$OUTPUT ""
 659 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 660 $     WRITE SYS$OUTPUT ""
 661 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 662 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 663 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.CRYPTO]*.EXE Programs."
 664 $     WRITE SYS$OUTPUT ""
 665 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 666 $     WRITE SYS$OUTPUT ""
 667 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 668 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 669 $     WRITE SYS$OUTPUT ""
 670 $!
 671 $!    Time To EXIT.
 672 $!
 673 $     EXIT
 674 $!
 675 $!  End The Valid Arguement Check.
 676 $!
 677 $   ENDIF
 678 $!
 679 $! End The P1 Check.
 680 $!
 681 $ ENDIF
 682 $!
 683 $! Check To See If P2 Is Blank.
 684 $!
 685 $ IF (P2.EQS."NODEBUG")
 686 $ THEN
 687 $!
 688 $!   P2 Is NODEBUG, So Compile Without The Debugger Information.
 689 $!
 690 $    DEBUGGER = "NODEBUG"
 691 $    TRACEBACK = "NOTRACEBACK"
 692 $    GCC_OPTIMIZE = "OPTIMIZE"
 693 $    CC_OPTIMIZE = "OPTIMIZE"
 694 $    MACRO_OPTIMIZE = "OPTIMIZE"
 695 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 696 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 697 $ ELSE
 698 $!
 699 $!  Check To See If We Are To Compile With Debugger Information.
 700 $!
 701 $   IF (P2.EQS."DEBUG")
 702 $   THEN
 703 $!
 704 $!    Compile With Debugger Information.
 705 $!
 706 $     DEBUGGER = "DEBUG"
 707 $     TRACEBACK = "TRACEBACK"
 708 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 709 $     CC_OPTIMIZE = "NOOPTIMIZE"
 710 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 711 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 712 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 713 $   ELSE
 714 $!
 715 $!    They Entered An Invalid Option..
 716 $!
 717 $     WRITE SYS$OUTPUT ""
 718 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 719 $     WRITE SYS$OUTPUT ""
 720 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 721 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 722 $     WRITE SYS$OUTPUT ""
 723 $!
 724 $!    Time To EXIT.
 725 $!
 726 $     EXIT
 727 $!
 728 $!  End The Valid Arguement Check.
 729 $!
 730 $   ENDIF
 731 $!
 732 $! End The P2 Check.
 733 $!
 734 $ ENDIF
 735 $!
 736 $! Special Threads For OpenVMS v7.1 Or Later
 737 $!
 738 $! Written By:  Richard Levitte
 739 $!              richard@levitte.org
 740 $!
 741 $!
 742 $! Check To See If We Have A Option For P5.
 743 $!
 744 $ IF (P5.EQS."")
 745 $ THEN
 746 $!
 747 $!  Get The Version Of VMS We Are Using.
 748 $!
 749 $   ISSEVEN :=
 750 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 751 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 752 $!
 753 $!  Check To See If The VMS Version Is v7.1 Or Later.
 754 $!
 755 $   IF (TMP.GE.71)
 756 $   THEN
 757 $!
 758 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 759 $!
 760 $     ISSEVEN := ,PTHREAD_USE_D4
 761 $!
 762 $!  End The VMS Version Check.
 763 $!
 764 $   ENDIF
 765 $!
 766 $! End The P5 Check.
 767 $!
 768 $ ENDIF
 769 $!
 770 $! Check To See If P3 Is Blank.
 771 $!
 772 $ IF (P3.EQS."")
 773 $ THEN
 774 $!
 775 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 776 $!  Find Out Which One To Use.
 777 $!
 778 $!  Check To See If We Have GNU C.
 779 $!
 780 $   IF (F$TRNLNM("GNU_CC").NES."")
 781 $   THEN
 782 $!
 783 $!    Looks Like GNUC, Set To Use GNUC.
 784 $!
 785 $     P3 = "GNUC"
 786 $!
 787 $!  Else...
 788 $!
 789 $   ELSE
 790 $!
 791 $!    Check To See If We Have VAXC Or DECC.
 792 $!
 793 $     IF (ARCH.EQS."AXP").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 794 $     THEN
 795 $!
 796 $!      Looks Like DECC, Set To Use DECC.
 797 $!
 798 $       P3 = "DECC"
 799 $!
 800 $!    Else...
 801 $!
 802 $     ELSE
 803 $!
 804 $!      Looks Like VAXC, Set To Use VAXC.
 805 $!
 806 $       P3 = "VAXC"
 807 $!
 808 $!    End The VAXC Compiler Check.
 809 $!
 810 $     ENDIF
 811 $!
 812 $!  End The DECC & VAXC Compiler Check.
 813 $!
 814 $   ENDIF
 815 $!
 816 $!  End The Compiler Check.
 817 $!
 818 $ ENDIF
 819 $!
 820 $! Check To See If We Have A Option For P4.
 821 $!
 822 $ IF (P4.EQS."")
 823 $ THEN
 824 $!
 825 $!  Find out what socket library we have available
 826 $!
 827 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 828 $   THEN
 829 $!
 830 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 831 $!
 832 $     P4 = "SOCKETSHR"
 833 $!
 834 $!    Tell the user
 835 $!
 836 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 837 $!
 838 $!    Else, let's look for something else
 839 $!
 840 $   ELSE
 841 $!
 842 $!    Like UCX (the reason to do this before Multinet is that the UCX
 843 $!    emulation is easier to use...)
 844 $!
 845 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 846          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 847          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 848 $     THEN
 849 $!
 850 $!      Last resort: a UCX or UCX-compatible library
 851 $!
 852 $       P4 = "UCX"
 853 $!
 854 $!      Tell the user
 855 $!
 856 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 857 $!
 858 $!      That was all...
 859 $!
 860 $     ENDIF
 861 $   ENDIF
 862 $ ENDIF
 863 $!
 864 $! Set Up Initial CC Definitions, Possibly With User Ones
 865 $!
 866 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
 867 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 868 $ CCEXTRAFLAGS = ""
 869 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 870 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 871 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 872         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 873 $!
 874 $!  Check To See If The User Entered A Valid Paramter.
 875 $!
 876 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
 877 $ THEN
 878 $!
 879 $!    Check To See If The User Wanted DECC.
 880 $!
 881 $   IF (P3.EQS."DECC")
 882 $   THEN
 883 $!
 884 $!    Looks Like DECC, Set To Use DECC.
 885 $!
 886 $     COMPILER = "DECC"
 887 $!
 888 $!    Tell The User We Are Using DECC.
 889 $!
 890 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 891 $!
 892 $!    Use DECC...
 893 $!
 894 $     CC = "CC"
 895 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
 896          THEN CC = "CC/DECC"
 897 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
 898            "/NOLIST/PREFIX=ALL" + -
 899            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + -
 900            CCEXTRAFLAGS
 901 $!
 902 $!    Define The Linker Options File Name.
 903 $!
 904 $     OPT_FILE = "SYS$DISK:[]VAX_DECC_OPTIONS.OPT"
 905 $!
 906 $!  End DECC Check.
 907 $!
 908 $   ENDIF
 909 $!
 910 $!  Check To See If We Are To Use VAXC.
 911 $!
 912 $   IF (P3.EQS."VAXC")
 913 $   THEN
 914 $!
 915 $!    Looks Like VAXC, Set To Use VAXC.
 916 $!
 917 $     COMPILER = "VAXC"
 918 $!
 919 $!    Tell The User We Are Using VAX C.
 920 $!
 921 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 922 $!
 923 $!    Compile Using VAXC.
 924 $!
 925 $     CC = "CC"
 926 $     IF ARCH.EQS."AXP"
 927 $     THEN
 928 $       WRITE SYS$OUTPUT "There is no VAX C on Alpha!"
 929 $       EXIT
 930 $     ENDIF
 931 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
 932 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 933            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + -
 934            CCEXTRAFLAGS
 935 $     CCDEFS = """VAXC""," + CCDEFS
 936 $!
 937 $!    Define <sys> As SYS$COMMON:[SYSLIB]
 938 $!
 939 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
 940 $!
 941 $!    Define The Linker Options File Name.
 942 $!
 943 $     OPT_FILE = "SYS$DISK:[]VAX_VAXC_OPTIONS.OPT"
 944 $!
 945 $!  End VAXC Check
 946 $!
 947 $   ENDIF
 948 $!
 949 $!  Check To See If We Are To Use GNU C.
 950 $!
 951 $   IF (P3.EQS."GNUC")
 952 $   THEN
 953 $!
 954 $!    Looks Like GNUC, Set To Use GNUC.
 955 $!
 956 $     COMPILER = "GNUC"
 957 $!
 958 $!    Tell The User We Are Using GNUC.
 959 $!
 960 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 961 $!
 962 $!    Use GNU C...
 963 $!
 964 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 965            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[-.CRYPTO])" + -
 966            CCEXTRAFLAGS
 967 $!
 968 $!    Define The Linker Options File Name.
 969 $!
 970 $     OPT_FILE = "SYS$DISK:[]VAX_GNUC_OPTIONS.OPT"
 971 $!
 972 $!  End The GNU C Check.
 973 $!
 974 $   ENDIF
 975 $!
 976 $!  Set up default defines
 977 $!
 978 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
 979 $!
 980 $!  Finish up the definition of CC.
 981 $!
 982 $   IF COMPILER .EQS. "DECC"
 983 $   THEN
 984 $     IF CCDISABLEWARNINGS .EQS. ""
 985 $     THEN
 986 $       CC4DISABLEWARNINGS = "DOLLARID"
 987 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
 988 $     ELSE
 989 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
 990 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
 991 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
 992 $     ENDIF
 993 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
 994 $     CC6DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
 995 $   ELSE
 996 $     CCDISABLEWARNINGS = ""
 997 $     CC4DISABLEWARNINGS = ""
 998 $     CC6DISABLEWARNINGS = ""
 999 $   ENDIF
1000 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1001 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1002 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1003 $   THEN
1004 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1005 $   ELSE
1006 $     CC5 = CC + "/NOOPTIMIZE"
1007 $   ENDIF
1008 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1009 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1010 $!
1011 $!  Show user the result
1012 $!
1013 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1014 $!
1015 $!  Else The User Entered An Invalid Arguement.
1016 $!
1017 $ ELSE
1018 $!
1019 $!  Tell The User We Don't Know What They Want.
1020 $!
1021 $   WRITE SYS$OUTPUT ""
1022 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1023 $   WRITE SYS$OUTPUT ""
1024 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1025 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1026 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1027 $   WRITE SYS$OUTPUT ""
1028 $!
1029 $!  Time To EXIT.
1030 $!
1031 $   EXIT
1032 $!
1033 $! End The Valid Arguement Check.
1034 $!
1035 $ ENDIF
1036 $!
1037 $! Build a MACRO command for the architecture at hand
1038 $!
1039 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1040 $ IF ARCH .EQS. "AXP" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1041 $!
1042 $!  Show user the result
1043 $!
1044 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1045 $!
1046 $! Time to check the contents, and to make sure we get the correct library.
1047 $!
1048 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1049      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1050 $ THEN
1051 $!
1052 $!  Check to see if SOCKETSHR was chosen
1053 $!
1054 $   IF P4.EQS."SOCKETSHR"
1055 $   THEN
1056 $!
1057 $!    Set the library to use SOCKETSHR
1058 $!
1059 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1060 $!
1061 $!    Done with SOCKETSHR
1062 $!
1063 $   ENDIF
1064 $!
1065 $!  Check to see if MULTINET was chosen
1066 $!
1067 $   IF P4.EQS."MULTINET"
1068 $   THEN
1069 $!
1070 $!    Set the library to use UCX emulation.
1071 $!
1072 $     P4 = "UCX"
1073 $!
1074 $!    Done with MULTINET
1075 $!
1076 $   ENDIF
1077 $!
1078 $!  Check to see if UCX was chosen
1079 $!
1080 $   IF P4.EQS."UCX"
1081 $   THEN
1082 $!
1083 $!    Set the library to use UCX.
1084 $!
1085 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1086 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1087 $     THEN
1088 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1089 $     ELSE
1090 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1091           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1092 $     ENDIF
1093 $!
1094 $!    Done with UCX
1095 $!
1096 $   ENDIF
1097 $!
1098 $!  Check to see if TCPIP was chosen
1099 $!
1100 $   IF P4.EQS."TCPIP"
1101 $   THEN
1102 $!
1103 $!    Set the library to use TCPIP (post UCX).
1104 $!
1105 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1106 $!
1107 $!    Done with TCPIP
1108 $!
1109 $   ENDIF
1110 $!
1111 $!  Check to see if NONE was chosen
1112 $!
1113 $   IF P4.EQS."NONE"
1114 $   THEN
1115 $!
1116 $!    Do not use a TCPIP library.
1117 $!
1118 $     TCPIP_LIB = ""
1119 $!
1120 $!    Done with TCPIP
1121 $!
1122 $   ENDIF
1123 $!
1124 $!  Print info
1125 $!
1126 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1127 $!
1128 $!  Else The User Entered An Invalid Arguement.
1129 $!
1130 $ ELSE
1131 $!
1132 $!  Tell The User We Don't Know What They Want.
1133 $!
1134 $   WRITE SYS$OUTPUT ""
1135 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1136 $   WRITE SYS$OUTPUT ""
1137 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1138 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1139 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1140 $   WRITE SYS$OUTPUT ""
1141 $!
1142 $!  Time To EXIT.
1143 $!
1144 $   EXIT
1145 $!
1146 $!  Done with TCP/IP libraries
1147 $!
1148 $ ENDIF
1149 $!
1150 $! Check if the user wanted to compile just a subset of all the encryption
1151 $! methods.
1152 $!
1153 $ IF P6 .NES. ""
1154 $ THEN
1155 $   ENCRYPT_TYPES = P6
1156 $ ENDIF
1157 $!
1158 $!  Time To RETURN...
1159 $!
1160 $ RETURN
1161 $!
1162 $ INITIALISE:
1163 $!
1164 $! Save old value of the logical name OPENSSL
1165 $!
1166 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1167 $!
1168 $! Save directory information
1169 $!
1170 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1171 $ __HERE = F$EDIT(__HERE,"UPCASE")
1172 $ __TOP = __HERE - "FIPS-1_0]"
1173 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1174 $!
1175 $! Set up the logical name OPENSSL to point at the include directory
1176 $!
1177 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1178 $!
1179 $! Done
1180 $!
1181 $ RETURN
1182 $!
1183 $ CLEANUP:
1184 $!
1185 $! Restore the logical name OPENSSL if it had a value
1186 $!
1187 $ IF __SAVE_OPENSSL .EQS. ""
1188 $ THEN
1189 $   DEASSIGN OPENSSL
1190 $ ELSE
1191 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1192 $ ENDIF
1193 $!
1194 $! Done
1195 $!
1196 $ RETURN