engines/makeengines.com

   1 $!
   2 $!  MAKEAPPS.COM
   3 $!  Written By:  Richard Levitte
   4 $!               richard@levitte.org
   5 $!
   6 $!  This command file compiles and creates the various engines in form
   7 $!  of shared images.  They are placed in [.xxx.EXE.ENGINES], where "xxx"
   8 $!  is either AXP or VAX depending on your hardware.
   9 $!
  10 $!  P1  if this is ENGINES or ALL, the engines will build, otherwise not.
  11 $!
  12 $!  P2  DEBUG or NODEBUG to compile with or without debugger information.
  13 $!
  14 $!  P3  VAXC            for VAX C
  15 $!      DECC            for DEC C
  16 $!      GNUC            for GNU C (untested)
  17 $!
  18 $!  P4  if defined, sets the TCP/IP libraries to use.  UCX or TCPIP is
  19 $!      used by default since most other implementations come with a
  20 $!      compatibility library.  The value must be one of the following:
  21 $!
  22 $!      UCX             for UCX
  23 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  24 $!      TCPIP           for TCPIP (post UCX)
  25 $!
  26 $!  P5  if defined, tells the compiler not to use special threads.
  27 $!
  28 $!  P6  if defined, denotes which engines to build.  If not defined,
  29 $!      all available engines are built.
  30 $!
  31 $!-----------------------------------------------------------------------------
  32 $!
  33 $! Set the names of the engines we want to build
  34 $!
  35 $ ENGINES = "," + P6
  36 $ IF ENGINES .EQS. "," THEN -
  37         ENGINES = ",4758cca,aep,atalla,cswift,chil,nuron,sureware,ubsec,capi"
  38 $!
  39 $! Set the default TCP/IP library to link against if needed
  40 $!
  41 $ TCPIP_LIB = ""
  42 $!
  43 $! Set the architecture name
  44 $!
  45 $ ARCH := VAX
  46 $ IF F$GETSYI("CPU") .GE. 128 THEN ARCH := AXP
  47 $!
  48 $! Set the goal directories, and creat them if necessary
  49 $!
  50 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.ENGINES]
  51 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.ENGINES]
  52 $ IF F$PARSE(OBJ_DIR) .EQS. "" THEN CREATE/DIRECTORY 'OBJ_DIR'
  53 $ IF F$PARSE(EXE_DIR) .EQS. "" THEN CREATE/DIRECTORY 'EXE_DIR'
  54 $!
  55 $! Set the goal files, and create them if necessary
  56 $!
  57 $ CRYPTO_LIB :=SYS$DISK:[-.'ARCH'.EXE.CRYPTO]LIBCRYPTO.OLB
  58 $ CRYPTO_EXE :=SYS$DISK:[-.'ARCH'.EXE.CRYPTO]LIBCRYPTO.EXE
  59 $ IF F$SEARCH(CRYPTO_LIB) .EQS. "" THEN LIBRARY/CREATE/OBJECT 'CRYPTO_LIB'
  60 $!
  61 $! OK, time to check options and initialise
  62 $!
  63 $ OPT_PHASE = P1
  64 $ ACCEPT_PHASE = "ALL,ENGINES"
  65 $ OPT_DEBUG = P2
  66 $ OPT_COMPILER = P3
  67 $ OPT_TCPIP_LIB = P4
  68 $ OPT_SPECIAL_THREADS = P5
  69 $
  70 $ GOSUB CHECK_OPTIONS
  71 $ GOSUB INITIALISE
  72 $ GOSUB CHECK_OPT_FILE
  73 $!
  74 $! Define what goes into each engine
  75 $!
  76 $ ENGINE_ = ""
  77 $ IF ARCH .EQS. "VAX"
  78 $ THEN
  79 $   ENGINE_ = "engine_vector.mar"
  80 $   EXTRA_OBJ := ,'OBJ_DIR'ENGINE_VECTOR.OBJ
  81 $ ENDIF
  82 $ ENGINE_4758CCA = "e_4758cca"
  83 $ ENGINE_aep = "e_aep"
  84 $ ENGINE_atalla = "e_atalla"
  85 $ ENGINE_cswift = "e_cswift"
  86 $ ENGINE_chil = "e_chil"
  87 $ ENGINE_nuron = "e_nuron"
  88 $ ENGINE_sureware = "e_sureware"
  89 $ ENGINE_ubsec = "e_ubsec"
  90 $ ENGINE_capi = "e_capi"
  91 $!
  92 $! Define which programs need to be linked with a TCP/IP library
  93 $!
  94 $ TCPIP_ENGINES = ",,"
  95 $ IF COMPILER .EQS. "VAXC" THEN -
  96      TCPIP_ENGINES = ",,"
  97 $!
  98 $! Set up two loops, one that keeps track of the engines,
  99 $! and one that keeps track of all the files going into
 100 $! the current engine.
 101 $!
 102 $! Here's the start of the engine loop.
 103 $!
 104 $ ENGINE_COUNTER = 0
 105 $ ENGINE_NEXT:
 106 $!
 107 $! Extract the current engine name, and if we've reached the end, stop
 108 $!
 109 $ ENGINE_NAME = F$ELEMENT(ENGINE_COUNTER,",",ENGINES)
 110 $ IF (ENGINE_NAME.EQS.",") THEN GOTO ENGINE_DONE
 111 $!
 112 $ ENGINE_COUNTER = ENGINE_COUNTER + 1
 113 $!
 114 $! Set up the engine library names.
 115 $!
 116 $ LIB_ENGINE = "ENGINE_" + ENGINE_NAME
 117 $!
 118 $! Check if the library module name actually is defined
 119 $!
 120 $ IF F$TYPE('LIB_ENGINE') .EQS. ""
 121 $ THEN
 122 $   WRITE SYS$ERROR ""
 123 $   WRITE SYS$ERROR "The module ",ENGINE_NAME," does not exist.  Continuing..."
 124 $   WRITE SYS$ERROR ""
 125 $   GOTO ENGINE_NEXT
 126 $ ENDIF
 127 $!
 128 $! Talk to the user
 129 $!
 130 $ IF ENGINE_NAME .NES. ""
 131 $ THEN
 132 $   WRITE SYS$OUTPUT "Compiling The ",ENGINE_NAME," Library Files. (",BUILDALL,")"
 133 $ ELSE
 134 $   WRITE SYS$OUTPUT "Compiling Support Files. (",BUILDALL,")"
 135 $ ENDIF
 136 $!
 137 $! Here's the start of per-engine module loop.
 138 $!
 139 $ FILE_COUNTER = 0
 140 $ FILE_NEXT:
 141 $!
 142 $! Extract the file name from the file list, and if we've reached the end, stop
 143 $!
 144 $ FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_ENGINE')
 145 $ IF (FILE_NAME.EQS.",") THEN GOTO FILE_DONE
 146 $!
 147 $ FILE_COUNTER = FILE_COUNTER + 1
 148 $!
 149 $ IF FILE_NAME .EQS. "" THEN GOTO FILE_NEXT
 150 $!
 151 $! Set up the source and object reference
 152 $!
 153 $ SOURCE_FILE = F$PARSE(FILE_NAME,"SYS$DISK:[].C",,,"SYNTAX_ONLY")
 154 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 155 $!
 156 $! If we get some problem, we just go on trying to build the next module.
 157 $ ON WARNING THEN GOTO FILE_NEXT
 158 $!
 159 $! Check if the module we want to compile is actually there.
 160 $!
 161 $ IF F$SEARCH(SOURCE_FILE) .EQS. ""
 162 $ THEN
 163 $   WRITE SYS$OUTPUT ""
 164 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 165 $   WRITE SYS$OUTPUT ""
 166 $   GOTO EXIT
 167 $ ENDIF
 168 $!
 169 $! Talk to the user.
 170 $!
 171 $ WRITE SYS$OUTPUT "    ",FILE_NAME,""
 172 $!
 173 $! Do the dirty work.
 174 $!
 175 $ ON ERROR THEN GOTO FILE_NEXT
 176 $ IF FILE_NAME - ".MAR" .NES. FILE_NAME
 177 $ THEN
 178 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 179 $ ELSE
 180 $   CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 181 $ ENDIF
 182 $!
 183 $! Now, there are two ways to handle this.  We can either build
 184 $! shareable images or stick the engine object file into libcrypto.
 185 $! For now, the latter is NOT supported.
 186 $!
 187 $!!!!! LIBRARY/REPLACE 'CRYPTO_LIB' 'OBJECT_FILE'
 188 $!
 189 $! For shareable libraries, we need to do things a little differently
 190 $! depending on if we link with a TCP/IP library or not.
 191 $!
 192 $ ENGINE_OPT := SYS$DISK:[]'ARCH'.OPT
 193 $ IF TCPIP_LIB .NES. ""
 194 $ THEN
 195 $   LINK/'DEBUGGER'/'TRACEBACK' /SHARE='EXE_DIR''ENGINE_NAME'.EXE -
 196         'OBJECT_FILE''EXTRA_OBJ', -
 197         'CRYPTO_LIB'/LIBRARY, -
 198         'ENGINE_OPT'/OPTION,'TCPIP_LIB','OPT_FILE'/OPTION
 199 $ ELSE
 200 $   LINK/'DEBUGGER'/'TRACEBACK' /SHARE='EXE_DIR''ENGINE_NAME'.EXE -
 201         'OBJECT_FILE''EXTRA_OBJ', -
 202         'CRYPTO_LIB'/LIBRARY, -
 203         'ENGINE_OPT'/OPTION,'OPT_FILE'/OPTION
 204 $ ENDIF
 205 $!
 206 $! Clean up
 207 $!
 208 $ DELETE 'OBJECT_FILE';*
 209 $!
 210 $! Next file
 211 $!
 212 $ GOTO FILE_NEXT
 213 $!
 214 $ FILE_DONE:
 215 $!
 216 $! Next engine
 217 $!
 218 $ GOTO ENGINE_NEXT
 219 $!
 220 $ ENGINE_DONE:
 221 $!
 222 $! Talk to the user
 223 $!
 224 $ WRITE SYS$OUTPUT "All Done..."
 225 $ EXIT:
 226 $ GOSUB CLEANUP
 227 $ EXIT
 228 $!
 229 $! Check For The Link Option FIle.
 230 $!
 231 $ CHECK_OPT_FILE:
 232 $!
 233 $! Check To See If We Need To Make A VAX C Option File.
 234 $!
 235 $ IF (COMPILER.EQS."VAXC")
 236 $ THEN
 237 $!
 238 $!  Check To See If We Already Have A VAX C Linker Option File.
 239 $!
 240 $   IF (F$SEARCH(OPT_FILE).EQS."")
 241 $   THEN
 242 $!
 243 $!    We Need A VAX C Linker Option File.
 244 $!
 245 $     CREATE 'OPT_FILE'
 246 $DECK
 247 !
 248 ! Default System Options File To Link Agianst
 249 ! The Sharable VAX C Runtime Library.
 250 !
 251 SYS$SHARE:VAXCRTL.EXE/SHARE
 252 $EOD
 253 $!
 254 $!  End The Option File Check.
 255 $!
 256 $   ENDIF
 257 $!
 258 $! End The VAXC Check.
 259 $!
 260 $ ENDIF
 261 $!
 262 $! Check To See If We Need A GNU C Option File.
 263 $!
 264 $ IF (COMPILER.EQS."GNUC")
 265 $ THEN
 266 $!
 267 $!  Check To See If We Already Have A GNU C Linker Option File.
 268 $!
 269 $   IF (F$SEARCH(OPT_FILE).EQS."")
 270 $   THEN
 271 $!
 272 $!    We Need A GNU C Linker Option File.
 273 $!
 274 $     CREATE 'OPT_FILE'
 275 $DECK
 276 !
 277 ! Default System Options File To Link Agianst
 278 ! The Sharable C Runtime Library.
 279 !
 280 GNU_CC:[000000]GCCLIB/LIBRARY
 281 SYS$SHARE:VAXCRTL/SHARE
 282 $EOD
 283 $!
 284 $!  End The Option File Check.
 285 $!
 286 $   ENDIF
 287 $!
 288 $! End The GNU C Check.
 289 $!
 290 $ ENDIF
 291 $!
 292 $! Check To See If We Need A DEC C Option File.
 293 $!
 294 $ IF (COMPILER.EQS."DECC")
 295 $ THEN
 296 $!
 297 $!  Check To See If We Already Have A DEC C Linker Option File.
 298 $!
 299 $   IF (F$SEARCH(OPT_FILE).EQS."")
 300 $   THEN
 301 $!
 302 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
 303 $!
 304 $     IF ARCH .EQS. "VAX"
 305 $     THEN
 306 $!
 307 $!      We Need A DEC C Linker Option File For VAX.
 308 $!
 309 $       CREATE 'OPT_FILE'
 310 $DECK
 311 !
 312 ! Default System Options File To Link Agianst
 313 ! The Sharable DEC C Runtime Library.
 314 !
 315 SYS$SHARE:DECC$SHR.EXE/SHARE
 316 $EOD
 317 $!
 318 $!    Else...
 319 $!
 320 $     ELSE
 321 $!
 322 $!      Create The AXP Linker Option File.
 323 $!
 324 $       CREATE 'OPT_FILE'
 325 $DECK
 326 !
 327 ! Default System Options File For AXP To Link Agianst
 328 ! The Sharable C Runtime Library.
 329 !
 330 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 331 SYS$SHARE:CMA$OPEN_RTL/SHARE
 332 $EOD
 333 $!
 334 $!    End The VAX/AXP DEC C Option File Check.
 335 $!
 336 $     ENDIF
 337 $!
 338 $!  End The Option File Search.
 339 $!
 340 $   ENDIF
 341 $!
 342 $! End The DEC C Check.
 343 $!
 344 $ ENDIF
 345 $!
 346 $!  Tell The User What Linker Option File We Are Using.
 347 $!
 348 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 349 $!
 350 $! Time To RETURN.
 351 $!
 352 $ RETURN
 353 $!
 354 $! Check The User's Options.
 355 $!
 356 $ CHECK_OPTIONS:
 357 $!
 358 $! Check To See If OPT_PHASE Is Blank.
 359 $!
 360 $ IF (OPT_PHASE.EQS."ALL")
 361 $ THEN
 362 $!
 363 $!   OPT_PHASE Is Blank, So Build Everything.
 364 $!
 365 $    BUILDALL = "ALL"
 366 $!
 367 $! Else...
 368 $!
 369 $ ELSE
 370 $!
 371 $!  Else, Check To See If OPT_PHASE Has A Valid Arguement.
 372 $!
 373 $   IF ("," + ACCEPT_PHASE + ",") - ("," + OPT_PHASE + ",") -
 374        .NES. ("," + ACCEPT_PHASE + ",")
 375 $   THEN
 376 $!
 377 $!    A Valid Arguement.
 378 $!
 379 $     BUILDALL = OPT_PHASE
 380 $!
 381 $!  Else...
 382 $!
 383 $   ELSE
 384 $!
 385 $!    Tell The User We Don't Know What They Want.
 386 $!
 387 $     WRITE SYS$OUTPUT ""
 388 $     WRITE SYS$OUTPUT "The option ",OPT_PHASE," is invalid.  The valid options are:"
 389 $     WRITE SYS$OUTPUT ""
 390 $     IF ("," + ACCEPT_PHASE + ",") - ",ALL," -
 391         .NES. ("," + ACCEPT_PHASE + ",") THEN -
 392         WRITE SYS$OUTPUT "    ALL      :  just build everything."
 393 $     IF ("," + ACCEPT_PHASE + ",") - ",ENGINES," -
 394         .NES. ("," + ACCEPT_PHASE + ",") THEN -
 395         WRITE SYS$OUTPUT "    ENGINES  :  to compile just the [.xxx.EXE.ENGINES]*.EXE hareable images."
 396 $     WRITE SYS$OUTPUT ""
 397 $     WRITE SYS$OUTPUT " where 'xxx' stands for:"
 398 $     WRITE SYS$OUTPUT ""
 399 $     WRITE SYS$OUTPUT "        AXP  :  Alpha architecture."
 400 $     WRITE SYS$OUTPUT "        VAX  :  VAX architecture."
 401 $     WRITE SYS$OUTPUT ""
 402 $!
 403 $!    Time To EXIT.
 404 $!
 405 $     EXIT
 406 $!
 407 $!  End The Valid Arguement Check.
 408 $!
 409 $   ENDIF
 410 $!
 411 $! End The OPT_PHASE Check.
 412 $!
 413 $ ENDIF
 414 $!
 415 $! Check To See If OPT_DEBUG Is Blank.
 416 $!
 417 $ IF (OPT_DEBUG.EQS."NODEBUG")
 418 $ THEN
 419 $!
 420 $!   OPT_DEBUG Is NODEBUG, So Compile Without The Debugger Information.
 421 $!
 422 $    DEBUGGER = "NODEBUG"
 423 $    TRACEBACK = "NOTRACEBACK"
 424 $    GCC_OPTIMIZE = "OPTIMIZE"
 425 $    CC_OPTIMIZE = "OPTIMIZE"
 426 $    MACRO_OPTIMIZE = "OPTIMIZE"
 427 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 428 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 429 $ ELSE
 430 $!
 431 $!  Check To See If We Are To Compile With Debugger Information.
 432 $!
 433 $   IF (OPT_DEBUG.EQS."DEBUG")
 434 $   THEN
 435 $!
 436 $!    Compile With Debugger Information.
 437 $!
 438 $     DEBUGGER = "DEBUG"
 439 $     TRACEBACK = "TRACEBACK"
 440 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 441 $     CC_OPTIMIZE = "NOOPTIMIZE"
 442 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 443 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 444 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 445 $   ELSE
 446 $!
 447 $!    They Entered An Invalid Option..
 448 $!
 449 $     WRITE SYS$OUTPUT ""
 450 $     WRITE SYS$OUTPUT "The Option ",OPT_DEBUG," Is Invalid.  The Valid Options Are:"
 451 $     WRITE SYS$OUTPUT ""
 452 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 453 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 454 $     WRITE SYS$OUTPUT ""
 455 $!
 456 $!    Time To EXIT.
 457 $!
 458 $     EXIT
 459 $!
 460 $!  End The Valid Arguement Check.
 461 $!
 462 $   ENDIF
 463 $!
 464 $! End The OPT_DEBUG Check.
 465 $!
 466 $ ENDIF
 467 $!
 468 $! Special Threads For OpenVMS v7.1 Or Later
 469 $!
 470 $! Written By:  Richard Levitte
 471 $!              richard@levitte.org
 472 $!
 473 $!
 474 $! Check To See If We Have A Option For OPT_SPECIAL_THREADS.
 475 $!
 476 $ IF (OPT_SPECIAL_THREADS.EQS."")
 477 $ THEN
 478 $!
 479 $!  Get The Version Of VMS We Are Using.
 480 $!
 481 $   ISSEVEN :=
 482 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 483 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 484 $!
 485 $!  Check To See If The VMS Version Is v7.1 Or Later.
 486 $!
 487 $   IF (TMP.GE.71)
 488 $   THEN
 489 $!
 490 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 491 $!
 492 $     ISSEVEN := ,PTHREAD_USE_D4
 493 $!
 494 $!  End The VMS Version Check.
 495 $!
 496 $   ENDIF
 497 $!
 498 $! End The OPT_SPECIAL_THREADS Check.
 499 $!
 500 $ ENDIF
 501 $!
 502 $! Check To See If OPT_COMPILER Is Blank.
 503 $!
 504 $ IF (OPT_COMPILER.EQS."")
 505 $ THEN
 506 $!
 507 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 508 $!  Find Out Which One To Use.
 509 $!
 510 $!  Check To See If We Have GNU C.
 511 $!
 512 $   IF (F$TRNLNM("GNU_CC").NES."")
 513 $   THEN
 514 $!
 515 $!    Looks Like GNUC, Set To Use GNUC.
 516 $!
 517 $     OPT_COMPILER = "GNUC"
 518 $!
 519 $!  Else...
 520 $!
 521 $   ELSE
 522 $!
 523 $!    Check To See If We Have VAXC Or DECC.
 524 $!
 525 $     IF (ARCH.EQS."AXP").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 526 $     THEN
 527 $!
 528 $!      Looks Like DECC, Set To Use DECC.
 529 $!
 530 $       OPT_COMPILER = "DECC"
 531 $!
 532 $!    Else...
 533 $!
 534 $     ELSE
 535 $!
 536 $!      Looks Like VAXC, Set To Use VAXC.
 537 $!
 538 $       OPT_COMPILER = "VAXC"
 539 $!
 540 $!    End The VAXC Compiler Check.
 541 $!
 542 $     ENDIF
 543 $!
 544 $!  End The DECC & VAXC Compiler Check.
 545 $!
 546 $   ENDIF
 547 $!
 548 $!  End The Compiler Check.
 549 $!
 550 $ ENDIF
 551 $!
 552 $! Check To See If We Have A Option For OPT_TCPIP_LIB.
 553 $!
 554 $ IF (OPT_TCPIP_LIB.EQS."")
 555 $ THEN
 556 $!
 557 $!  Find out what socket library we have available
 558 $!
 559 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 560 $   THEN
 561 $!
 562 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 563 $!
 564 $     OPT_TCPIP_LIB = "SOCKETSHR"
 565 $!
 566 $!    Tell the user
 567 $!
 568 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 569 $!
 570 $!    Else, let's look for something else
 571 $!
 572 $   ELSE
 573 $!
 574 $!    Like UCX (the reason to do this before Multinet is that the UCX
 575 $!    emulation is easier to use...)
 576 $!
 577 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 578          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 579          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 580 $     THEN
 581 $!
 582 $!      Last resort: a UCX or UCX-compatible library
 583 $!
 584 $       OPT_TCPIP_LIB = "UCX"
 585 $!
 586 $!      Tell the user
 587 $!
 588 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 589 $!
 590 $!      That was all...
 591 $!
 592 $     ENDIF
 593 $   ENDIF
 594 $ ENDIF
 595 $!
 596 $! Set Up Initial CC Definitions, Possibly With User Ones
 597 $!
 598 $ CCDEFS = "TCPIP_TYPE_''OPT_TCPIP_LIB',DSO_VMS"
 599 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 600 $ CCEXTRAFLAGS = ""
 601 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 602 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX"
 603 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 604         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 605 $!
 606 $!  Check To See If The User Entered A Valid Paramter.
 607 $!
 608 $ IF (OPT_COMPILER.EQS."VAXC").OR.(OPT_COMPILER.EQS."DECC").OR.(OPT_COMPILER.EQS."GNUC")
 609 $ THEN
 610 $!
 611 $!    Check To See If The User Wanted DECC.
 612 $!
 613 $   IF (OPT_COMPILER.EQS."DECC")
 614 $   THEN
 615 $!
 616 $!    Looks Like DECC, Set To Use DECC.
 617 $!
 618 $     COMPILER = "DECC"
 619 $!
 620 $!    Tell The User We Are Using DECC.
 621 $!
 622 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
 623 $!
 624 $!    Use DECC...
 625 $!
 626 $     CC = "CC"
 627 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
 628          THEN CC = "CC/DECC"
 629 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
 630            "/NOLIST/PREFIX=ALL" + -
 631            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.VENDOR_DEFNS])" + -
 632            CCEXTRAFLAGS
 633 $!
 634 $!    Define The Linker Options File Name.
 635 $!
 636 $     OPT_FILE = "SYS$DISK:[]VAX_DECC_OPTIONS.OPT"
 637 $!
 638 $!  End DECC Check.
 639 $!
 640 $   ENDIF
 641 $!
 642 $!  Check To See If We Are To Use VAXC.
 643 $!
 644 $   IF (OPT_COMPILER.EQS."VAXC")
 645 $   THEN
 646 $!
 647 $!    Looks Like VAXC, Set To Use VAXC.
 648 $!
 649 $     COMPILER = "VAXC"
 650 $!
 651 $!    Tell The User We Are Using VAX C.
 652 $!
 653 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
 654 $!
 655 $!    Compile Using VAXC.
 656 $!
 657 $     CC = "CC"
 658 $     IF ARCH.EQS."AXP"
 659 $     THEN
 660 $       WRITE SYS$OUTPUT "There is no VAX C on Alpha!"
 661 $       EXIT
 662 $     ENDIF
 663 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
 664 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 665            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
 666            CCEXTRAFLAGS
 667 $     CCDEFS = """VAXC""," + CCDEFS
 668 $!
 669 $!    Define <sys> As SYS$COMMON:[SYSLIB]
 670 $!
 671 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
 672 $!
 673 $!    Define The Linker Options File Name.
 674 $!
 675 $     OPT_FILE = "SYS$DISK:[]VAX_VAXC_OPTIONS.OPT"
 676 $!
 677 $!  End VAXC Check
 678 $!
 679 $   ENDIF
 680 $!
 681 $!  Check To See If We Are To Use GNU C.
 682 $!
 683 $   IF (OPT_COMPILER.EQS."GNUC")
 684 $   THEN
 685 $!
 686 $!    Looks Like GNUC, Set To Use GNUC.
 687 $!
 688 $     COMPILER = "GNUC"
 689 $!
 690 $!    Tell The User We Are Using GNUC.
 691 $!
 692 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
 693 $!
 694 $!    Use GNU C...
 695 $!
 696 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
 697            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
 698            CCEXTRAFLAGS
 699 $!
 700 $!    Define The Linker Options File Name.
 701 $!
 702 $     OPT_FILE = "SYS$DISK:[]VAX_GNUC_OPTIONS.OPT"
 703 $!
 704 $!  End The GNU C Check.
 705 $!
 706 $   ENDIF
 707 $!
 708 $!  Set up default defines
 709 $!
 710 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
 711 $!
 712 $!  Finish up the definition of CC.
 713 $!
 714 $   IF COMPILER .EQS. "DECC"
 715 $   THEN
 716 $     IF CCDISABLEWARNINGS .NES. ""
 717 $     THEN
 718 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
 719 $     ENDIF
 720 $   ELSE
 721 $     CCDISABLEWARNINGS = ""
 722 $   ENDIF
 723 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
 724 $!
 725 $!  Show user the result
 726 $!
 727 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
 728 $!
 729 $!  Else The User Entered An Invalid Arguement.
 730 $!
 731 $ ELSE
 732 $!
 733 $!  Tell The User We Don't Know What They Want.
 734 $!
 735 $   WRITE SYS$OUTPUT ""
 736 $   WRITE SYS$OUTPUT "The Option ",OPT_COMPILER," Is Invalid.  The Valid Options Are:"
 737 $   WRITE SYS$OUTPUT ""
 738 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
 739 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
 740 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
 741 $   WRITE SYS$OUTPUT ""
 742 $!
 743 $!  Time To EXIT.
 744 $!
 745 $   EXIT
 746 $!
 747 $! End The Valid Arguement Check.
 748 $!
 749 $ ENDIF
 750 $!
 751 $! Build a MACRO command for the architecture at hand
 752 $!
 753 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
 754 $ IF ARCH .EQS. "AXP" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
 755 $!
 756 $!  Show user the result
 757 $!
 758 $ WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
 759 $!
 760 $! Time to check the contents, and to make sure we get the correct library.
 761 $!
 762 $ IF OPT_TCPIP_LIB.EQS."SOCKETSHR" .OR. OPT_TCPIP_LIB.EQS."MULTINET" -
 763      .OR. OPT_TCPIP_LIB.EQS."UCX" .OR. OPT_TCPIP_LIB.EQS."TCPIP" -
 764      .OR. OPT_TCPIP_LIB.EQS."NONE"
 765 $ THEN
 766 $!
 767 $!  Check to see if SOCKETSHR was chosen
 768 $!
 769 $   IF OPT_TCPIP_LIB.EQS."SOCKETSHR"
 770 $   THEN
 771 $!
 772 $!    Set the library to use SOCKETSHR
 773 $!
 774 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
 775 $!
 776 $!    Done with SOCKETSHR
 777 $!
 778 $   ENDIF
 779 $!
 780 $!  Check to see if MULTINET was chosen
 781 $!
 782 $   IF OPT_TCPIP_LIB.EQS."MULTINET"
 783 $   THEN
 784 $!
 785 $!    Set the library to use UCX emulation.
 786 $!
 787 $     OPT_TCPIP_LIB = "UCX"
 788 $!
 789 $!    Done with MULTINET
 790 $!
 791 $   ENDIF
 792 $!
 793 $!  Check to see if UCX was chosen
 794 $!
 795 $   IF OPT_TCPIP_LIB.EQS."UCX"
 796 $   THEN
 797 $!
 798 $!    Set the library to use UCX.
 799 $!
 800 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
 801 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
 802 $     THEN
 803 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
 804 $     ELSE
 805 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
 806           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
 807 $     ENDIF
 808 $!
 809 $!    Done with UCX
 810 $!
 811 $   ENDIF
 812 $!
 813 $!  Check to see if TCPIP was chosen
 814 $!
 815 $   IF OPT_TCPIP_LIB.EQS."TCPIP"
 816 $   THEN
 817 $!
 818 $!    Set the library to use TCPIP (post UCX).
 819 $!
 820 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
 821 $!
 822 $!    Done with TCPIP
 823 $!
 824 $   ENDIF
 825 $!
 826 $!  Check to see if NONE was chosen
 827 $!
 828 $   IF OPT_TCPIP_LIB.EQS."NONE"
 829 $   THEN
 830 $!
 831 $!    Do not use a TCPIP library.
 832 $!
 833 $     TCPIP_LIB = ""
 834 $!
 835 $!    Done with TCPIP
 836 $!
 837 $   ENDIF
 838 $!
 839 $!  Print info
 840 $!
 841 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
 842 $!
 843 $!  Else The User Entered An Invalid Arguement.
 844 $!
 845 $ ELSE
 846 $!
 847 $!  Tell The User We Don't Know What They Want.
 848 $!
 849 $   WRITE SYS$OUTPUT ""
 850 $   WRITE SYS$OUTPUT "The Option ",OPT_TCPIP_LIB," Is Invalid.  The Valid Options Are:"
 851 $   WRITE SYS$OUTPUT ""
 852 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
 853 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
 854 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
 855 $   WRITE SYS$OUTPUT ""
 856 $!
 857 $!  Time To EXIT.
 858 $!
 859 $   EXIT
 860 $!
 861 $!  Done with TCP/IP libraries
 862 $!
 863 $ ENDIF
 864 $!
 865 $!  Time To RETURN...
 866 $!
 867 $ RETURN
 868 $!
 869 $ INITIALISE:
 870 $!
 871 $! Save old value of the logical name OPENSSL
 872 $!
 873 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
 874 $!
 875 $! Save directory information
 876 $!
 877 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
 878 $ __HERE = F$EDIT(__HERE,"UPCASE")
 879 $ __TOP = __HERE - "ENGINES]"
 880 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
 881 $!
 882 $! Set up the logical name OPENSSL to point at the include directory
 883 $!
 884 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
 885 $!
 886 $! Done
 887 $!
 888 $ RETURN
 889 $!
 890 $ CLEANUP:
 891 $!
 892 $! Restore the logical name OPENSSL if it had a value
 893 $!
 894 $ IF __SAVE_OPENSSL .EQS. ""
 895 $ THEN
 896 $   DEASSIGN OPENSSL
 897 $ ELSE
 898 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
 899 $ ENDIF
 900 $!
 901 $! Done
 902 $!
 903 $ RETURN