crypto/crypto-lib.com

   1 $!
   2 $!  CRYPTO-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  11 $!  library for OpenSSL.  The "xxx" denotes the machine architecture of AXP
  12 $!  or VAX.
  13 $!
  14 $!  It was re-written so it would try to determine what "C" compiler to use
  15 $!  or you can specify which "C" compiler to use.
  16 $!
  17 $!  Specify the following as P1 to build just that part or ALL to just
  18 $!  build everything.
  19 $!
  20 $!              LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  21 $!              APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
  22 $!              ALL        To do both LIBRARY and APPS
  23 $!
  24 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  25 $!  information.
  26 $!
  27 $!  Specify which compiler at P3 to try to compile under.
  28 $!
  29 $!         VAXC  For VAX C.
  30 $!         DECC  For DEC C.
  31 $!         GNUC  For GNU C.
  32 $!
  33 $!  If you don't speficy a compiler, it will try to determine which
  34 $!  "C" compiler to use.
  35 $!
  36 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  37 $!  keywords:
  38 $!
  39 $!      UCX             for UCX
  40 $!      TCPIP           for TCPIP (post UCX)
  41 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  42 $!
  43 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  44 $!
  45 $!  P6, if defined, sets a choice of crypto methods to compile.
  46 $!  WARNING: this should only be done to recompile some part of an already
  47 $!  fully compiled library.
  48 $!
  49 $!
  50 $! Define A TCP/IP Library That We Will Need To Link To.
  51 $! (That Is, If We Need To Link To One.)
  52 $!
  53 $ TCPIP_LIB = ""
  54 $!
  55 $! Check Which Architecture We Are Using.
  56 $!
  57 $ IF (F$GETSYI("CPU").GE.128)
  58 $ THEN
  59 $!
  60 $!  The Architecture Is AXP
  61 $!
  62 $   ARCH := AXP
  63 $!
  64 $! Else...
  65 $!
  66 $ ELSE
  67 $!
  68 $!  The Architecture Is VAX.
  69 $!
  70 $   ARCH := VAX
  71 $!
  72 $! End The Architecture Check.
  73 $!
  74 $ ENDIF
  75 $!
  76 $! Define The Different Encryption Types.
  77 $!
  78 $ ENCRYPT_TYPES = "Basic,"+ -
  79                   "OBJECTS,"+ -
  80                   "MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ -
  81                   "DES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,"+ -
  82                   "BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,AES,"+ -
  83                   "BUFFER,BIO,STACK,LHASH,RAND,ERR,"+ -
  84                   "EVP,EVP_2,ASN1,ASN1_2,PEM,X509,X509V3,"+ -
  85                   "CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5,"+ -
  86                   "STORE,CMS,PQUEUE"
  87 $!
  88 $! Check To Make Sure We Have Valid Command Line Parameters.
  89 $!
  90 $ GOSUB CHECK_OPTIONS
  91 $!
  92 $! Initialise logical names and such
  93 $!
  94 $ GOSUB INITIALISE
  95 $!
  96 $! Tell The User What Kind of Machine We Run On.
  97 $!
  98 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
  99 $!
 100 $! Define The OBJ Directory.
 101 $!
 102 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
 103 $!
 104 $! Check To See If The Architecture Specific OBJ Directory Exists.
 105 $!
 106 $ IF (F$PARSE(OBJ_DIR).EQS."")
 107 $ THEN
 108 $!
 109 $!  It Dosen't Exist, So Create It.
 110 $!
 111 $   CREATE/DIR 'OBJ_DIR'
 112 $!
 113 $! End The Architecture Specific OBJ Directory Check.
 114 $!
 115 $ ENDIF
 116 $!
 117 $! Define The EXE Directory.
 118 $!
 119 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
 120 $!
 121 $! Check To See If The Architecture Specific Directory Exists.
 122 $!
 123 $ IF (F$PARSE(EXE_DIR).EQS."")
 124 $ THEN
 125 $!
 126 $!  It Dosen't Exist, So Create It.
 127 $!
 128 $   CREATE/DIRECTORY 'EXE_DIR'
 129 $!
 130 $! End The Architecture Specific Directory Check.
 131 $!
 132 $ ENDIF
 133 $!
 134 $! Define The Library Name.
 135 $!
 136 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
 137 $!
 138 $! Define The CRYPTO-LIB We Are To Use.
 139 $!
 140 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
 141 $!
 142 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 143 $!
 144 $ IF (F$SEARCH(LIB_NAME).EQS."")
 145 $ THEN
 146 $!
 147 $! Guess Not, Create The Library.
 148 $!
 149 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 150 $!
 151 $! End The Library Check.
 152 $!
 153 $ ENDIF
 154 $!
 155 $! Build our options file for the application
 156 $!
 157 $ GOSUB CHECK_OPT_FILE
 158 $!
 159 $! Define The Different Encryption "library" Strings.
 160 $!
 161 $ APPS_DES = "DES/DES,CBC3_ENC"
 162 $ APPS_PKCS7 = "ENC/ENC;DEC/DEC;SIGN/SIGN;VERIFY/VERIFY,EXAMPLE"
 163 $
 164 $ LIB_ = "cryptlib,mem,mem_clr,mem_dbg,cversion,ex_data,tmdiff,cpt_err,ebcdic,uid,o_time,o_str,o_dir"
 165 $ LIB_MD2 = "md2_dgst,md2_one"
 166 $ LIB_MD4 = "md4_dgst,md4_one"
 167 $ LIB_MD5 = "md5_dgst,md5_one"
 168 $ LIB_SHA = "sha_dgst,sha1dgst,sha_one,sha1_one,sha256,sha512"
 169 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
 170 $ LIB_HMAC = "hmac"
 171 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
 172 $ LIB_DES = "set_key,ecb_enc,cbc_enc,"+ -
 173         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
 174         "enc_read,enc_writ,ofb64enc,"+ -
 175         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
 176         "des_enc,fcrypt_b,"+ -
 177         "fcrypt,xcbc_enc,rpc_enc,cbc_cksm,"+ -
 178         "ede_cbcm_enc,des_old,des_old2,read2pwd"
 179 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
 180 $ LIB_RC4 = "rc4_skey,rc4_enc"
 181 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
 182 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
 183 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
 184 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
 185 $ LIB_CAMELLIA = "camellia,cmll_misc,cmll_ecb,cmll_cbc,cmll_ofb,"+ -
 186         "cmll_cfb,cmll_ctr"
 187 $ LIB_SEED = "seed,seed_cbc,seed_ecb,seed_cfb,seed_ofb"
 188 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
 189 $ IF F$TRNLNM("OPENSSL_NO_ASM").OR.ARCH.EQS."AXP" THEN LIB_BN_ASM = "bn_asm"
 190 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,bn_mod,"+ -
 191         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
 192         "bn_kron,bn_sqrt,bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+","+ -
 193         "bn_recp,bn_mont,bn_mpi,bn_exp2,bn_gf2m,bn_nist,"+ -
 194         "bn_depr,bn_const"
 195 $ LIB_EC = "ec_lib,ecp_smpl,ecp_mont,ecp_nist,ec_cvt,ec_mult,"+ -
 196         "ec_err,ec_curve,ec_check,ec_print,ec_asn1,ec_key,"+ -
 197         "ec2_smpl,ec2_mult"
 198 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
 199         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null,"+ -
 200         "rsa_pss,rsa_x931,rsa_asn1,rsa_depr"
 201 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,"+ -
 202         "dsa_err,dsa_ossl,dsa_depr"
 203 $ LIB_ECDSA = "ecs_lib,ecs_asn1,ecs_ossl,ecs_sign,ecs_vrf,ecs_err"
 204 $ LIB_DH = "dh_asn1,dh_gen,dh_key,dh_lib,dh_check,dh_err,dh_depr"
 205 $ LIB_ECDH = "ech_lib,ech_ossl,ech_key,ech_err"
 206 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
 207         "dso_openssl,dso_win32,dso_vms"
 208 $ LIB_ENGINE = "eng_err,eng_lib,eng_list,eng_init,eng_ctrl,"+ -
 209         "eng_table,eng_pkey,eng_fat,eng_all,"+ -
 210         "tb_rsa,tb_dsa,tb_ecdsa,tb_dh,tb_ecdh,tb_rand,tb_store,"+ -
 211         "tb_cipher,tb_digest,"+ -
 212         "eng_openssl,eng_dyn,eng_cnf,eng_cryptodev,eng_padlock"
 213 $ LIB_AES = "aes_core,aes_misc,aes_ecb,aes_cbc,aes_cfb,aes_ofb,"+ -
 214         "aes_ctr,aes_ige"
 215 $ LIB_BUFFER = "buffer,buf_err"
 216 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
 217         "bss_mem,bss_null,bss_fd,"+ -
 218         "bss_file,bss_sock,bss_conn,"+ -
 219         "bf_null,bf_buff,b_print,b_dump,"+ -
 220         "b_sock,bss_acpt,bf_nbio,bss_rtcp,bss_bio,bss_log,"+ -
 221         "bss_dgram,"+ -
 222         "bf_lbuf"
 223 $ LIB_STACK = "stack"
 224 $ LIB_LHASH = "lhash,lh_stats"
 225 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,"+ -
 226         "rand_vms"
 227 $ LIB_ERR = "err,err_all,err_prn"
 228 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err"
 229 $ LIB_EVP = "encode,digest,evp_enc,evp_key,evp_acnf,"+ -
 230         "e_des,e_bf,e_idea,e_des3,e_camellia,e_seed,"+ -
 231         "e_rc4,e_aes,names,"+ -
 232         "e_xcbc_d,e_rc2,e_cast,e_rc5"
 233 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha,m_sha1," + -
 234         "m_dss,m_dss1,m_mdc2,m_ripemd,m_ecdsa,"+ -
 235         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
 236         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
 237         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
 238         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
 239 $ LIB_ASN1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
 240         "a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,"+ -
 241         "a_enum,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
 242         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,x_bignum,"+ -
 243         "x_long,x_name,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
 244         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
 245 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
 246         "tasn_new,tasn_fre,tasn_enc,tasn_dec,tasn_utl,tasn_typ,"+ -
 247         "f_int,f_string,n_pkey,"+ -
 248         "f_enum,a_hdr,x_pkey,a_bool,x_exten,"+ -
 249         "asn1_gen,asn1_par,asn1_lib,asn1_err,a_meth,a_bytes,a_strnid,"+ -
 250         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey,asn_moid"
 251 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err,"+ -
 252         "pem_x509,pem_xaux,pem_oth,pem_pk8,pem_pkey"
 253 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
 254         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
 255         "x509_set,x509cset,x509rset,x509_err,"+ -
 256         "x509name,x509_v3,x509_ext,x509_att,"+ -
 257         "x509type,x509_lu,x_all,x509_txt,"+ -
 258         "x509_trs,by_file,by_dir,x509_vpm"
 259 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
 260         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
 261         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info,"+ -
 262         "v3_ocsp,v3_akeya,v3_pmaps,v3_pcons,v3_ncons,v3_pcia,v3_pci,"+ -
 263         "pcy_cache,pcy_node,pcy_data,pcy_map,pcy_tree,pcy_lib,"+ -
 264         "v3_asid,v3_addr"
 265 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def,conf_mod,conf_mall,conf_sap"
 266 $ LIB_TXT_DB = "txt_db"
 267 $ LIB_PKCS7 = "pk7_asn1,pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,"+ -
 268         "pk7_mime"
 269 $ LIB_PKCS12 = "p12_add,p12_asn,p12_attr,p12_crpt,p12_crt,p12_decr,"+ -
 270         "p12_init,p12_key,p12_kiss,p12_mutl,"+ -
 271         "p12_utl,p12_npas,pk12err,p12_p8d,p12_p8e"
 272 $ LIB_COMP = "comp_lib,comp_err,"+ -
 273         "c_rle,c_zlib"
 274 $ LIB_OCSP = "ocsp_asn,ocsp_ext,ocsp_ht,ocsp_lib,ocsp_cl,"+ -
 275         "ocsp_srv,ocsp_prn,ocsp_vfy,ocsp_err"
 276 $ LIB_UI_COMPAT = ",ui_compat"
 277 $ LIB_UI = "ui_err,ui_lib,ui_openssl,ui_util"+LIB_UI_COMPAT
 278 $ LIB_KRB5 = "krb5_asn"
 279 $ LIB_STORE = "str_err,str_lib,str_meth,str_mem"
 280 $ LIB_PQUEUE = "pqueue"
 281 $!
 282 $! Setup exceptional compilations
 283 $!
 284 $ ! Add definitions for no threads on OpenVMS 7.1 and higher
 285 $ LIB_CMS = "cms_lib,cms_asn1,cms_att,cms_io,cms_smime,cms_err,"+ -
 286         "cms_sd,cms_dd,cms_cd,cms_env,cms_enc,cms_ess"
 287 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 288 $ ! Disable the DOLLARID warning
 289 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,o_time,o_dir"
 290 $ ! Disable disjoint optimization
 291 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 292                     "sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 293 $ ! Disable the MIXLINKAGE warning
 294 $ COMPILEWITH_CC6 = ",enc_read,set_key,"
 295 $!
 296 $! Figure Out What Other Modules We Are To Build.
 297 $!
 298 $ BUILD_SET:
 299 $!
 300 $! Define A Module Counter.
 301 $!
 302 $ MODULE_COUNTER = 0
 303 $!
 304 $! Top Of The Loop.
 305 $!
 306 $ MODULE_NEXT:
 307 $!
 308 $! Extract The Module Name From The Encryption List.
 309 $!
 310 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 311 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 312 $ MODULE_NAME1 = MODULE_NAME
 313 $!
 314 $! Check To See If We Are At The End Of The Module List.
 315 $!
 316 $ IF (MODULE_NAME.EQS.",")
 317 $ THEN
 318 $!
 319 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 320 $!
 321 $   GOTO MODULE_DONE
 322 $!
 323 $! End The Module List Check.
 324 $!
 325 $ ENDIF
 326 $!
 327 $! Increment The Moudle Counter.
 328 $!
 329 $ MODULE_COUNTER = MODULE_COUNTER + 1
 330 $!
 331 $! Create The Library and Apps Module Names.
 332 $!
 333 $ LIB_MODULE = "LIB_" + MODULE_NAME
 334 $ APPS_MODULE = "APPS_" + MODULE_NAME
 335 $ IF (MODULE_NAME.EQS."ASN1_2")
 336 $ THEN
 337 $   MODULE_NAME = "ASN1"
 338 $ ENDIF
 339 $ IF (MODULE_NAME.EQS."EVP_2")
 340 $ THEN
 341 $   MODULE_NAME = "EVP"
 342 $ ENDIF
 343 $!
 344 $! Set state (can be LIB and APPS)
 345 $!
 346 $ STATE = "LIB"
 347 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
 348 $!
 349 $! Check if the library module name actually is defined
 350 $!
 351 $ IF F$TYPE('LIB_MODULE') .EQS. ""
 352 $ THEN
 353 $   WRITE SYS$ERROR ""
 354 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
 355 $   WRITE SYS$ERROR ""
 356 $   GOTO MODULE_NEXT
 357 $ ENDIF
 358 $!
 359 $! Top Of The Module Loop.
 360 $!
 361 $ MODULE_AGAIN:
 362 $!
 363 $! Tell The User What Module We Are Building.
 364 $!
 365 $ IF (MODULE_NAME1.NES."")
 366 $ THEN
 367 $   IF STATE .EQS. "LIB"
 368 $   THEN
 369 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
 370 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
 371 $     THEN
 372 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
 373 $     ENDIF
 374 $   ENDIF
 375 $ ENDIF
 376 $!
 377 $!  Define A File Counter And Set It To "0".
 378 $!
 379 $ FILE_COUNTER = 0
 380 $ APPLICATION = ""
 381 $ APPLICATION_COUNTER = 0
 382 $!
 383 $! Top Of The File Loop.
 384 $!
 385 $ NEXT_FILE:
 386 $!
 387 $! Look in the LIB_MODULE is we're in state LIB
 388 $!
 389 $ IF STATE .EQS. "LIB"
 390 $ THEN
 391 $!
 392 $!   O.K, Extract The File Name From The File List.
 393 $!
 394 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 395 $!
 396 $!   else
 397 $!
 398 $ ELSE
 399 $   FILE_NAME = ","
 400 $!
 401 $   IF F$TYPE('APPS_MODULE') .NES. ""
 402 $   THEN
 403 $!
 404 $!     Extract The File Name From The File List.
 405 $!     This part is a bit more complicated.
 406 $!
 407 $     IF APPLICATION .EQS. ""
 408 $     THEN
 409 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 410 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 411 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 412 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 413 $       FILE_COUNTER = 0
 414 $     ENDIF
 415 $
 416 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 417 $!     SHOW SYMBOL APPLICATION*
 418 $!
 419 $     IF APPLICATION .NES. ";"
 420 $     THEN
 421 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
 422 $       IF FILE_NAME .EQS. ","
 423 $       THEN
 424 $         APPLICATION = ""
 425 $         GOTO NEXT_FILE
 426 $       ENDIF
 427 $     ENDIF
 428 $   ENDIF
 429 $ ENDIF
 430 $!
 431 $! Check To See If We Are At The End Of The File List.
 432 $!
 433 $ IF (FILE_NAME.EQS.",")
 434 $ THEN
 435 $!
 436 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
 437 $!
 438 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
 439 $   THEN
 440 $     STATE = "APPS"
 441 $     GOTO MODULE_AGAIN
 442 $   ELSE
 443 $     GOTO FILE_DONE
 444 $   ENDIF
 445 $!
 446 $! End The File List Check.
 447 $!
 448 $ ENDIF
 449 $!
 450 $! Increment The Counter.
 451 $!
 452 $ FILE_COUNTER = FILE_COUNTER + 1
 453 $!
 454 $! Create The Source File Name.
 455 $!
 456 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 457 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 458 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 459         FILE_NAME = FILE_NAME + ".c"
 460 $ IF (MODULE_NAME.NES."")
 461 $ THEN
 462 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 463 $ ELSE
 464 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 465 $ ENDIF
 466 $ SOURCE_FILE = SOURCE_FILE - "]["
 467 $!
 468 $! Create The Object File Name.
 469 $!
 470 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 471 $ ON WARNING THEN GOTO NEXT_FILE
 472 $!
 473 $! Check To See If The File We Want To Compile Is Actually There.
 474 $!
 475 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 476 $ THEN
 477 $!
 478 $!  Tell The User That The File Doesn't Exist.
 479 $!
 480 $   WRITE SYS$OUTPUT ""
 481 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 482 $   WRITE SYS$OUTPUT ""
 483 $!
 484 $!  Exit The Build.
 485 $!
 486 $   GOTO EXIT
 487 $!
 488 $! End The File Exist Check.
 489 $!
 490 $ ENDIF
 491 $!
 492 $! Tell The User We Are Compiling The File.
 493 $!
 494 $ IF (MODULE_NAME.EQS."")
 495 $ THEN
 496 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
 497 $ ENDIF
 498 $ IF (MODULE_NAME.NES."")
 499 $ THEN
 500 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
 501 $ ENDIF
 502 $!
 503 $! Compile The File.
 504 $!
 505 $ ON ERROR THEN GOTO NEXT_FILE
 506 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
 507 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 508 $ THEN
 509 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 510 $ ELSE
 511 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 512 $   THEN
 513 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 514 $   ELSE
 515 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 516 $     THEN
 517 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 518 $     ELSE
 519 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
 520 $       THEN
 521 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 522 $       ELSE
 523 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 524 $         THEN
 525 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 526 $         ELSE
 527 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 528 $         ENDIF
 529 $       ENDIF
 530 $     ENDIF
 531 $   ENDIF
 532 $ ENDIF
 533 $ IF STATE .EQS. "LIB"
 534 $ THEN
 535 $!
 536 $!   Add It To The Library.
 537 $!
 538 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 539 $!
 540 $!   Time To Clean Up The Object File.
 541 $!
 542 $   DELETE 'OBJECT_FILE';*
 543 $ ENDIF
 544 $!
 545 $! Go Back And Do It Again.
 546 $!
 547 $ GOTO NEXT_FILE
 548 $!
 549 $! All Done With This Library Part.
 550 $!
 551 $ FILE_DONE:
 552 $!
 553 $! Time To Build Some Applications
 554 $!
 555 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
 556 $ THEN
 557 $   APPLICATION_COUNTER = 0
 558 $ NEXT_APPLICATION:
 559 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 560 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
 561 $
 562 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 563 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 564 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 565 $
 566 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 567 $!   SHOW SYMBOL APPLICATION*
 568 $!
 569 $! Tell the user what happens
 570 $!
 571 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
 572 $!
 573 $! Link The Program.
 574 $!
 575 $   ON ERROR THEN GOTO NEXT_APPLICATION
 576 $!
 577 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 578 $!
 579 $   IF (TCPIP_LIB.NES."")
 580 $   THEN
 581 $!
 582 $!    Link With A TCP/IP Library.
 583 $!
 584 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 585           'OBJ_DIR''APPLICATION_OBJECTS', -
 586           'CRYPTO_LIB'/LIBRARY, -
 587           'TCPIP_LIB','OPT_FILE'/OPTION
 588 $!
 589 $! Else...
 590 $!
 591 $   ELSE
 592 $!
 593 $!    Don't Link With A TCP/IP Library.
 594 $!
 595 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 596           'OBJ_DIR''APPLICATION_OBJECTS',-
 597           'CRYPTO_LIB'/LIBRARY, -
 598           'OPT_FILE'/OPTION
 599 $!
 600 $! End The TCP/IP Library Check.
 601 $!
 602 $   ENDIF
 603 $   GOTO NEXT_APPLICATION
 604 $  APPLICATION_DONE:
 605 $ ENDIF
 606 $!
 607 $! Go Back And Get The Next Module.
 608 $!
 609 $ GOTO MODULE_NEXT
 610 $!
 611 $! All Done With This Module.
 612 $!
 613 $ MODULE_DONE:
 614 $!
 615 $! Tell The User That We Are All Done.
 616 $!
 617 $ WRITE SYS$OUTPUT "All Done..."
 618 $ EXIT:
 619 $ GOSUB CLEANUP
 620 $ EXIT
 621 $!
 622 $! Check For The Link Option FIle.
 623 $!
 624 $ CHECK_OPT_FILE:
 625 $!
 626 $! Check To See If We Need To Make A VAX C Option File.
 627 $!
 628 $ IF (COMPILER.EQS."VAXC")
 629 $ THEN
 630 $!
 631 $!  Check To See If We Already Have A VAX C Linker Option File.
 632 $!
 633 $   IF (F$SEARCH(OPT_FILE).EQS."")
 634 $   THEN
 635 $!
 636 $!    We Need A VAX C Linker Option File.
 637 $!
 638 $     CREATE 'OPT_FILE'
 639 $DECK
 640 !
 641 ! Default System Options File To Link Agianst
 642 ! The Sharable VAX C Runtime Library.
 643 !
 644 SYS$SHARE:VAXCRTL.EXE/SHARE
 645 $EOD
 646 $!
 647 $!  End The Option File Check.
 648 $!
 649 $   ENDIF
 650 $!
 651 $! End The VAXC Check.
 652 $!
 653 $ ENDIF
 654 $!
 655 $! Check To See If We Need A GNU C Option File.
 656 $!
 657 $ IF (COMPILER.EQS."GNUC")
 658 $ THEN
 659 $!
 660 $!  Check To See If We Already Have A GNU C Linker Option File.
 661 $!
 662 $   IF (F$SEARCH(OPT_FILE).EQS."")
 663 $   THEN
 664 $!
 665 $!    We Need A GNU C Linker Option File.
 666 $!
 667 $     CREATE 'OPT_FILE'
 668 $DECK
 669 !
 670 ! Default System Options File To Link Agianst
 671 ! The Sharable C Runtime Library.
 672 !
 673 GNU_CC:[000000]GCCLIB/LIBRARY
 674 SYS$SHARE:VAXCRTL/SHARE
 675 $EOD
 676 $!
 677 $!  End The Option File Check.
 678 $!
 679 $   ENDIF
 680 $!
 681 $! End The GNU C Check.
 682 $!
 683 $ ENDIF
 684 $!
 685 $! Check To See If We Need A DEC C Option File.
 686 $!
 687 $ IF (COMPILER.EQS."DECC")
 688 $ THEN
 689 $!
 690 $!  Check To See If We Already Have A DEC C Linker Option File.
 691 $!
 692 $   IF (F$SEARCH(OPT_FILE).EQS."")
 693 $   THEN
 694 $!
 695 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
 696 $!
 697 $     IF ARCH .EQS. "VAX"
 698 $     THEN
 699 $!
 700 $!      We Need A DEC C Linker Option File For VAX.
 701 $!
 702 $       CREATE 'OPT_FILE'
 703 $DECK
 704 !
 705 ! Default System Options File To Link Agianst
 706 ! The Sharable DEC C Runtime Library.
 707 !
 708 SYS$SHARE:DECC$SHR.EXE/SHARE
 709 $EOD
 710 $!
 711 $!    Else...
 712 $!
 713 $     ELSE
 714 $!
 715 $!      Create The AXP Linker Option File.
 716 $!
 717 $       CREATE 'OPT_FILE'
 718 $DECK
 719 !
 720 ! Default System Options File For AXP To Link Agianst
 721 ! The Sharable C Runtime Library.
 722 !
 723 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 724 SYS$SHARE:CMA$OPEN_RTL/SHARE
 725 $EOD
 726 $!
 727 $!    End The VAX/AXP DEC C Option File Check.
 728 $!
 729 $     ENDIF
 730 $!
 731 $!  End The Option File Search.
 732 $!
 733 $   ENDIF
 734 $!
 735 $! End The DEC C Check.
 736 $!
 737 $ ENDIF
 738 $!
 739 $!  Tell The User What Linker Option File We Are Using.
 740 $!
 741 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 742 $!
 743 $! Time To RETURN.
 744 $!
 745 $ RETURN
 746 $!
 747 $! Check The User's Options.
 748 $!
 749 $ CHECK_OPTIONS:
 750 $!
 751 $! Check To See If P1 Is Blank.
 752 $!
 753 $ IF (P1.EQS."ALL")
 754 $ THEN
 755 $!
 756 $!   P1 Is Blank, So Build Everything.
 757 $!
 758 $    BUILDALL = "TRUE"
 759 $!
 760 $! Else...
 761 $!
 762 $ ELSE
 763 $!
 764 $!  Else, Check To See If P1 Has A Valid Arguement.
 765 $!
 766 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
 767 $   THEN
 768 $!
 769 $!    A Valid Arguement.
 770 $!
 771 $     BUILDALL = P1
 772 $!
 773 $!  Else...
 774 $!
 775 $   ELSE
 776 $!
 777 $!    Tell The User We Don't Know What They Want.
 778 $!
 779 $     WRITE SYS$OUTPUT ""
 780 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 781 $     WRITE SYS$OUTPUT ""
 782 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 783 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 784 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.CRYPTO]*.EXE Programs."
 785 $     WRITE SYS$OUTPUT ""
 786 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 787 $     WRITE SYS$OUTPUT ""
 788 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 789 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 790 $     WRITE SYS$OUTPUT ""
 791 $!
 792 $!    Time To EXIT.
 793 $!
 794 $     EXIT
 795 $!
 796 $!  End The Valid Arguement Check.
 797 $!
 798 $   ENDIF
 799 $!
 800 $! End The P1 Check.
 801 $!
 802 $ ENDIF
 803 $!
 804 $! Check To See If P2 Is Blank.
 805 $!
 806 $ IF (P2.EQS."NODEBUG")
 807 $ THEN
 808 $!
 809 $!   P2 Is NODEBUG, So Compile Without The Debugger Information.
 810 $!
 811 $    DEBUGGER = "NODEBUG"
 812 $    TRACEBACK = "NOTRACEBACK"
 813 $    GCC_OPTIMIZE = "OPTIMIZE"
 814 $    CC_OPTIMIZE = "OPTIMIZE"
 815 $    MACRO_OPTIMIZE = "OPTIMIZE"
 816 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 817 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 818 $ ELSE
 819 $!
 820 $!  Check To See If We Are To Compile With Debugger Information.
 821 $!
 822 $   IF (P2.EQS."DEBUG")
 823 $   THEN
 824 $!
 825 $!    Compile With Debugger Information.
 826 $!
 827 $     DEBUGGER = "DEBUG"
 828 $     TRACEBACK = "TRACEBACK"
 829 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 830 $     CC_OPTIMIZE = "NOOPTIMIZE"
 831 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 832 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 833 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 834 $   ELSE
 835 $!
 836 $!    They Entered An Invalid Option..
 837 $!
 838 $     WRITE SYS$OUTPUT ""
 839 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 840 $     WRITE SYS$OUTPUT ""
 841 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 842 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 843 $     WRITE SYS$OUTPUT ""
 844 $!
 845 $!    Time To EXIT.
 846 $!
 847 $     EXIT
 848 $!
 849 $!  End The Valid Arguement Check.
 850 $!
 851 $   ENDIF
 852 $!
 853 $! End The P2 Check.
 854 $!
 855 $ ENDIF
 856 $!
 857 $! Special Threads For OpenVMS v7.1 Or Later
 858 $!
 859 $! Written By:  Richard Levitte
 860 $!              richard@levitte.org
 861 $!
 862 $!
 863 $! Check To See If We Have A Option For P5.
 864 $!
 865 $ IF (P5.EQS."")
 866 $ THEN
 867 $!
 868 $!  Get The Version Of VMS We Are Using.
 869 $!
 870 $   ISSEVEN :=
 871 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 872 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 873 $!
 874 $!  Check To See If The VMS Version Is v7.1 Or Later.
 875 $!
 876 $   IF (TMP.GE.71)
 877 $   THEN
 878 $!
 879 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 880 $!
 881 $     ISSEVEN := ,PTHREAD_USE_D4
 882 $!
 883 $!  End The VMS Version Check.
 884 $!
 885 $   ENDIF
 886 $!
 887 $! End The P5 Check.
 888 $!
 889 $ ENDIF
 890 $!
 891 $! Check To See If P3 Is Blank.
 892 $!
 893 $ IF (P3.EQS."")
 894 $ THEN
 895 $!
 896 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 897 $!  Find Out Which One To Use.
 898 $!
 899 $!  Check To See If We Have GNU C.
 900 $!
 901 $   IF (F$TRNLNM("GNU_CC").NES."")
 902 $   THEN
 903 $!
 904 $!    Looks Like GNUC, Set To Use GNUC.
 905 $!
 906 $     P3 = "GNUC"
 907 $!
 908 $!  Else...
 909 $!
 910 $   ELSE
 911 $!
 912 $!    Check To See If We Have VAXC Or DECC.
 913 $!
 914 $     IF (ARCH.EQS."AXP").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 915 $     THEN
 916 $!
 917 $!      Looks Like DECC, Set To Use DECC.
 918 $!
 919 $       P3 = "DECC"
 920 $!
 921 $!    Else...
 922 $!
 923 $     ELSE
 924 $!
 925 $!      Looks Like VAXC, Set To Use VAXC.
 926 $!
 927 $       P3 = "VAXC"
 928 $!
 929 $!    End The VAXC Compiler Check.
 930 $!
 931 $     ENDIF
 932 $!
 933 $!  End The DECC & VAXC Compiler Check.
 934 $!
 935 $   ENDIF
 936 $!
 937 $!  End The Compiler Check.
 938 $!
 939 $ ENDIF
 940 $!
 941 $! Check To See If We Have A Option For P4.
 942 $!
 943 $ IF (P4.EQS."")
 944 $ THEN
 945 $!
 946 $!  Find out what socket library we have available
 947 $!
 948 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 949 $   THEN
 950 $!
 951 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 952 $!
 953 $     P4 = "SOCKETSHR"
 954 $!
 955 $!    Tell the user
 956 $!
 957 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 958 $!
 959 $!    Else, let's look for something else
 960 $!
 961 $   ELSE
 962 $!
 963 $!    Like UCX (the reason to do this before Multinet is that the UCX
 964 $!    emulation is easier to use...)
 965 $!
 966 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 967          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 968          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 969 $     THEN
 970 $!
 971 $!      Last resort: a UCX or UCX-compatible library
 972 $!
 973 $       P4 = "UCX"
 974 $!
 975 $!      Tell the user
 976 $!
 977 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 978 $!
 979 $!      That was all...
 980 $!
 981 $     ENDIF
 982 $   ENDIF
 983 $ ENDIF
 984 $!
 985 $! Set Up Initial CC Definitions, Possibly With User Ones
 986 $!
 987 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
 988 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 989 $ CCEXTRAFLAGS = ""
 990 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 991 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 992 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 993         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 994 $!
 995 $!  Check To See If The User Entered A Valid Paramter.
 996 $!
 997 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
 998 $ THEN
 999 $!
1000 $!    Check To See If The User Wanted DECC.
1001 $!
1002 $   IF (P3.EQS."DECC")
1003 $   THEN
1004 $!
1005 $!    Looks Like DECC, Set To Use DECC.
1006 $!
1007 $     COMPILER = "DECC"
1008 $!
1009 $!    Tell The User We Are Using DECC.
1010 $!
1011 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1012 $!
1013 $!    Use DECC...
1014 $!
1015 $     CC = "CC"
1016 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1017          THEN CC = "CC/DECC"
1018 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
1019            "/NOLIST/PREFIX=ALL" + -
1020            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS],SYS$DISK:[.EVP])" + -
1021            CCEXTRAFLAGS
1022 $!
1023 $!    Define The Linker Options File Name.
1024 $!
1025 $     OPT_FILE = "SYS$DISK:[]VAX_DECC_OPTIONS.OPT"
1026 $!
1027 $!  End DECC Check.
1028 $!
1029 $   ENDIF
1030 $!
1031 $!  Check To See If We Are To Use VAXC.
1032 $!
1033 $   IF (P3.EQS."VAXC")
1034 $   THEN
1035 $!
1036 $!    Looks Like VAXC, Set To Use VAXC.
1037 $!
1038 $     COMPILER = "VAXC"
1039 $!
1040 $!    Tell The User We Are Using VAX C.
1041 $!
1042 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1043 $!
1044 $!    Compile Using VAXC.
1045 $!
1046 $     CC = "CC"
1047 $     IF ARCH.EQS."AXP"
1048 $     THEN
1049 $       WRITE SYS$OUTPUT "There is no VAX C on Alpha!"
1050 $       EXIT
1051 $     ENDIF
1052 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1053 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1054            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1055            CCEXTRAFLAGS
1056 $     CCDEFS = """VAXC""," + CCDEFS
1057 $!
1058 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1059 $!
1060 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1061 $!
1062 $!    Define The Linker Options File Name.
1063 $!
1064 $     OPT_FILE = "SYS$DISK:[]VAX_VAXC_OPTIONS.OPT"
1065 $!
1066 $!  End VAXC Check
1067 $!
1068 $   ENDIF
1069 $!
1070 $!  Check To See If We Are To Use GNU C.
1071 $!
1072 $   IF (P3.EQS."GNUC")
1073 $   THEN
1074 $!
1075 $!    Looks Like GNUC, Set To Use GNUC.
1076 $!
1077 $     COMPILER = "GNUC"
1078 $!
1079 $!    Tell The User We Are Using GNUC.
1080 $!
1081 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1082 $!
1083 $!    Use GNU C...
1084 $!
1085 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1086            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1087            CCEXTRAFLAGS
1088 $!
1089 $!    Define The Linker Options File Name.
1090 $!
1091 $     OPT_FILE = "SYS$DISK:[]VAX_GNUC_OPTIONS.OPT"
1092 $!
1093 $!  End The GNU C Check.
1094 $!
1095 $   ENDIF
1096 $!
1097 $!  Set up default defines
1098 $!
1099 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1100 $!
1101 $!  Finish up the definition of CC.
1102 $!
1103 $   IF COMPILER .EQS. "DECC"
1104 $   THEN
1105 $     IF CCDISABLEWARNINGS .EQS. ""
1106 $     THEN
1107 $       CC4DISABLEWARNINGS = "DOLLARID"
1108 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
1109 $     ELSE
1110 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1111 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
1112 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1113 $     ENDIF
1114 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1115 $     CC6DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
1116 $   ELSE
1117 $     CCDISABLEWARNINGS = ""
1118 $     CC4DISABLEWARNINGS = ""
1119 $     CC6DISABLEWARNINGS = ""
1120 $   ENDIF
1121 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1122 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1123 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1124 $   THEN
1125 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1126 $   ELSE
1127 $     CC5 = CC + "/NOOPTIMIZE"
1128 $   ENDIF
1129 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1130 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1131 $!
1132 $!  Show user the result
1133 $!
1134 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1135 $!
1136 $!  Else The User Entered An Invalid Arguement.
1137 $!
1138 $ ELSE
1139 $!
1140 $!  Tell The User We Don't Know What They Want.
1141 $!
1142 $   WRITE SYS$OUTPUT ""
1143 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1144 $   WRITE SYS$OUTPUT ""
1145 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1146 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1147 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1148 $   WRITE SYS$OUTPUT ""
1149 $!
1150 $!  Time To EXIT.
1151 $!
1152 $   EXIT
1153 $!
1154 $! End The Valid Arguement Check.
1155 $!
1156 $ ENDIF
1157 $!
1158 $! Build a MACRO command for the architecture at hand
1159 $!
1160 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1161 $ IF ARCH .EQS. "AXP" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1162 $!
1163 $!  Show user the result
1164 $!
1165 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1166 $!
1167 $! Time to check the contents, and to make sure we get the correct library.
1168 $!
1169 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1170      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1171 $ THEN
1172 $!
1173 $!  Check to see if SOCKETSHR was chosen
1174 $!
1175 $   IF P4.EQS."SOCKETSHR"
1176 $   THEN
1177 $!
1178 $!    Set the library to use SOCKETSHR
1179 $!
1180 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1181 $!
1182 $!    Done with SOCKETSHR
1183 $!
1184 $   ENDIF
1185 $!
1186 $!  Check to see if MULTINET was chosen
1187 $!
1188 $   IF P4.EQS."MULTINET"
1189 $   THEN
1190 $!
1191 $!    Set the library to use UCX emulation.
1192 $!
1193 $     P4 = "UCX"
1194 $!
1195 $!    Done with MULTINET
1196 $!
1197 $   ENDIF
1198 $!
1199 $!  Check to see if UCX was chosen
1200 $!
1201 $   IF P4.EQS."UCX"
1202 $   THEN
1203 $!
1204 $!    Set the library to use UCX.
1205 $!
1206 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1207 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1208 $     THEN
1209 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1210 $     ELSE
1211 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1212           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1213 $     ENDIF
1214 $!
1215 $!    Done with UCX
1216 $!
1217 $   ENDIF
1218 $!
1219 $!  Check to see if TCPIP was chosen
1220 $!
1221 $   IF P4.EQS."TCPIP"
1222 $   THEN
1223 $!
1224 $!    Set the library to use TCPIP (post UCX).
1225 $!
1226 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1227 $!
1228 $!    Done with TCPIP
1229 $!
1230 $   ENDIF
1231 $!
1232 $!  Check to see if NONE was chosen
1233 $!
1234 $   IF P4.EQS."NONE"
1235 $   THEN
1236 $!
1237 $!    Do not use a TCPIP library.
1238 $!
1239 $     TCPIP_LIB = ""
1240 $!
1241 $!    Done with TCPIP
1242 $!
1243 $   ENDIF
1244 $!
1245 $!  Print info
1246 $!
1247 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1248 $!
1249 $!  Else The User Entered An Invalid Arguement.
1250 $!
1251 $ ELSE
1252 $!
1253 $!  Tell The User We Don't Know What They Want.
1254 $!
1255 $   WRITE SYS$OUTPUT ""
1256 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1257 $   WRITE SYS$OUTPUT ""
1258 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1259 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1260 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1261 $   WRITE SYS$OUTPUT ""
1262 $!
1263 $!  Time To EXIT.
1264 $!
1265 $   EXIT
1266 $!
1267 $!  Done with TCP/IP libraries
1268 $!
1269 $ ENDIF
1270 $!
1271 $! Check if the user wanted to compile just a subset of all the encryption
1272 $! methods.
1273 $!
1274 $ IF P6 .NES. ""
1275 $ THEN
1276 $   ENCRYPT_TYPES = P6
1277 $ ENDIF
1278 $!
1279 $!  Time To RETURN...
1280 $!
1281 $ RETURN
1282 $!
1283 $ INITIALISE:
1284 $!
1285 $! Save old value of the logical name OPENSSL
1286 $!
1287 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1288 $!
1289 $! Save directory information
1290 $!
1291 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1292 $ __HERE = F$EDIT(__HERE,"UPCASE")
1293 $ __TOP = __HERE - "CRYPTO]"
1294 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1295 $!
1296 $! Set up the logical name OPENSSL to point at the include directory
1297 $!
1298 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1299 $!
1300 $! Done
1301 $!
1302 $ RETURN
1303 $!
1304 $ CLEANUP:
1305 $!
1306 $! Restore the logical name OPENSSL if it had a value
1307 $!
1308 $ IF __SAVE_OPENSSL .EQS. ""
1309 $ THEN
1310 $   DEASSIGN OPENSSL
1311 $ ELSE
1312 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1313 $ ENDIF
1314 $!
1315 $! Done
1316 $!
1317 $ RETURN