crypto/crypto-lib.com

   1 $!
   2 $!  CRYPTO-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!             Zoltan Arpadffy <arpadffy@polarhome.com>
  10 $!
  11 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  12 $!  library for OpenSSL.  The "xxx" denotes the machine architecture, ALPHA,
  13 $!  IA64 or VAX.
  14 $!
  15 $!  It was re-written so it would try to determine what "C" compiler to use
  16 $!  or you can specify which "C" compiler to use.
  17 $!
  18 $!  Specify the following as P1 to build just that part or ALL to just
  19 $!  build everything.
  20 $!
  21 $!      LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  22 $!      ALL        To do both LIBRARY and APPS
  23 $!
  24 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  25 $!  information.
  26 $!
  27 $!  Specify which compiler at P3 to try to compile under.
  28 $!
  29 $!      VAXC       For VAX C.
  30 $!      DECC       For DEC C.
  31 $!      GNUC       For GNU C.
  32 $!
  33 $!  If you don't specify a compiler, it will try to determine which
  34 $!  "C" compiler to use.
  35 $!
  36 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  37 $!  keywords:
  38 $!
  39 $!      UCX        For UCX
  40 $!      TCPIP      For TCPIP (post UCX)
  41 $!      SOCKETSHR  For SOCKETSHR+NETLIB
  42 $!
  43 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  44 $!
  45 $!  P6, if defined, sets a choice of crypto methods to compile.
  46 $!  WARNING: this should only be done to recompile some part of an already
  47 $!  fully compiled library.
  48 $!
  49 $!  P7, if defined, specifies the C pointer size.  Ignored on VAX.
  50 $!      ("64=ARGV" gives more efficient code with HP C V7.3 or newer.)
  51 $!      Supported values are:
  52 $!
  53 $!      ""       Compile with default (/NOPOINTER_SIZE)
  54 $!      32       Compile with /POINTER_SIZE=32 (SHORT)
  55 $!      64       Compile with /POINTER_SIZE=64[=ARGV] (LONG[=ARGV]).
  56 $!               (Automatically select ARGV if compiler supports it.)
  57 $!      64=      Compile with /POINTER_SIZE=64 (LONG).
  58 $!      64=ARGV  Compile with /POINTER_SIZE=64=ARGV (LONG=ARGV).
  59 $!
  60 $!  P8, if defined, specifies a directory where ZLIB files (zlib.h,
  61 $!  libz.olb) may be found.  Optionally, a non-default object library
  62 $!  name may be included ("dev:[dir]libz_64.olb", for example).
  63 $!
  64 $!
  65 $! Announce/identify.
  66 $!
  67 $ proc = f$environment( "procedure")
  68 $ write sys$output "@@@ "+ -
  69    f$parse( proc, , , "name")+ f$parse( proc, , , "type")
  70 $!
  71 $! Define A TCP/IP Library That We Will Need To Link To.
  72 $! (That Is, If We Need To Link To One.)
  73 $!
  74 $ TCPIP_LIB = ""
  75 $ ZLIB_LIB = ""
  76 $!
  77 $! Check Which Architecture We Are Using.
  78 $!
  79 $ IF (F$GETSYI("CPU").LT.128)
  80 $ THEN
  81 $!
  82 $!  The Architecture Is VAX
  83 $!
  84 $   ARCH = "VAX"
  85 $!
  86 $! Else...
  87 $!
  88 $ ELSE
  89 $!
  90 $!  The Architecture Is Alpha, IA64 or whatever comes in the future.
  91 $!
  92 $   ARCH = F$EDIT( F$GETSYI( "ARCH_NAME"), "UPCASE")
  93 $   IF (ARCH .EQS. "") THEN ARCH = "UNK"
  94 $!
  95 $! End The Architecture Check.
  96 $!
  97 $ ENDIF
  98 $!
  99 $ ARCHD = ARCH
 100 $ LIB32 = "32"
 101 $ OPT_FILE = ""
 102 $ POINTER_SIZE = ""
 103 $!
 104 $! Check if there's a SDIRS variable defined
 105 $!
 106 $ IF "''SDIRS'" .NES. ""
 107 $ THEN
 108 $!
 109 $!   If SDIRS was defined, define ENCRYPT_TYPES from it
 110 $!
 111 $     ENCRYPT_TYPES = "Basic,''SDIRS'"
 112 $!
 113 $! Otherwise
 114 $!
 115 $ ELSE
 116 $!
 117 $!   Define The Different Encryption Types.
 118 $!   NOTE: Some might think this list ugly.  However, it's made this way to
 119 $!   reflect the SDIRS variable in [-]Makefile.org as closely as possible,
 120 $!   thereby making it fairly easy to verify that the lists are the same.
 121 $!
 122 $   ET_WHIRLPOOL = "WHRLPOOL"
 123 $   IF ARCH .EQS. "VAX" THEN ET_WHIRLPOOL = ""
 124 $   ENCRYPT_TYPES = "Basic,"+ -
 125                     "OBJECTS,"+ -
 126                     "MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ET_WHIRLPOOL+","+ -
 127                     "DES,AES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,MODES,"+ -
 128                     "BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,"+ -
 129                     "BUFFER,BIO,STACK,LHASH,RAND,ERR,"+ -
 130                     "EVP,ASN1,PEM,X509,X509V3,CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,"+ -
 131                     "CMS,PQUEUE,TS,JPAKE,SRP,STORE,CMAC"
 132 $ ENDIF
 133 $!
 134 $! Check To Make Sure We Have Valid Command Line Parameters.
 135 $!
 136 $ GOSUB CHECK_OPTIONS
 137 $!
 138 $! Define The OBJ and EXE Directories.
 139 $!
 140 $ OBJ_DIR := SYS$DISK:[-.'ARCHD'.OBJ.CRYPTO]
 141 $ EXE_DIR := SYS$DISK:[-.'ARCHD'.EXE.CRYPTO]
 142 $!
 143 $! Specify the destination directory in any /MAP option.
 144 $!
 145 $ if (LINKMAP .eqs. "MAP")
 146 $ then
 147 $   LINKMAP = LINKMAP+ "=''EXE_DIR'"
 148 $ endif
 149 $!
 150 $! Add the location prefix to the linker options file name.
 151 $!
 152 $ if (OPT_FILE .nes. "")
 153 $ then
 154 $   OPT_FILE = EXE_DIR+ OPT_FILE
 155 $ endif
 156 $!
 157 $! Initialise logical names and such
 158 $!
 159 $ GOSUB INITIALISE
 160 $!
 161 $! Tell The User What Kind of Machine We Run On.
 162 $!
 163 $ WRITE SYS$OUTPUT "Host system architecture: ''ARCHD'"
 164 $!
 165 $!
 166 $! Check To See If The Architecture Specific OBJ Directory Exists.
 167 $!
 168 $ IF (F$PARSE(OBJ_DIR).EQS."")
 169 $ THEN
 170 $!
 171 $!  It Dosen't Exist, So Create It.
 172 $!
 173 $   CREATE/DIR 'OBJ_DIR'
 174 $!
 175 $! End The Architecture Specific OBJ Directory Check.
 176 $!
 177 $ ENDIF
 178 $!
 179 $! Check To See If The Architecture Specific Directory Exists.
 180 $!
 181 $ IF (F$PARSE(EXE_DIR).EQS."")
 182 $ THEN
 183 $!
 184 $!  It Dosen't Exist, So Create It.
 185 $!
 186 $   CREATE/DIRECTORY 'EXE_DIR'
 187 $!
 188 $! End The Architecture Specific Directory Check.
 189 $!
 190 $ ENDIF
 191 $!
 192 $! Define The Library Name.
 193 $!
 194 $ LIB_NAME := 'EXE_DIR'SSL_LIBCRYPTO'LIB32'.OLB
 195 $!
 196 $! Define The CRYPTO-LIB We Are To Use.
 197 $!
 198 $ CRYPTO_LIB := 'EXE_DIR'SSL_LIBCRYPTO'LIB32'.OLB
 199 $!
 200 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 201 $!
 202 $ IF (F$SEARCH(LIB_NAME).EQS."")
 203 $ THEN
 204 $!
 205 $! Guess Not, Create The Library.
 206 $!
 207 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 208 $!
 209 $! End The Library Check.
 210 $!
 211 $ ENDIF
 212 $!
 213 $! Build our options file for the application
 214 $!
 215 $ GOSUB CHECK_OPT_FILE
 216 $!
 217 $! Define The Different Encryption "library" Strings.
 218 $!
 219 $ LIB_ = "cryptlib,mem,mem_clr,mem_dbg,cversion,ex_data,cpt_err,"+ -
 220         "ebcdic,uid,o_time,o_str,o_dir,thr_id,lock,fips_ers,"+ -
 221         "o_init,o_fips"
 222 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err,obj_xref"
 223 $ LIB_MD2 = "md2_dgst,md2_one"
 224 $ LIB_MD4 = "md4_dgst,md4_one"
 225 $ LIB_MD5 = "md5_dgst,md5_one"
 226 $ LIB_SHA = "sha1dgst,sha1_one,sha256,sha512"
 227 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
 228 $ LIB_HMAC = "hmac,hm_ameth,hm_pmeth"
 229 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
 230 $ LIB_WHRLPOOL = "wp_dgst,wp_block"
 231 $ LIB_DES = "set_key,ecb_enc,cbc_enc,"+ -
 232         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
 233         "enc_read,enc_writ,ofb64enc,"+ -
 234         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
 235         "des_enc,fcrypt_b,"+ -
 236         "fcrypt,xcbc_enc,rpc_enc,cbc_cksm,"+ -
 237         "read2pwd"
 238 $ LIB_AES = "aes_misc,aes_ecb,aes_cfb,aes_ofb,aes_ige,aes_wrap,"+ -
 239         "aes_core,aes_cbc"
 240 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
 241 $ LIB_RC4 = "rc4_enc,rc4_skey"
 242 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
 243 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
 244 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
 245 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
 246 $ LIB_CAMELLIA = "cmll_ecb,cmll_ofb,cmll_cfb,cmll_ctr,camellia,cmll_misc,cmll_cbc"
 247 $ LIB_SEED = "seed,seed_ecb,seed_cbc,seed_cfb,seed_ofb"
 248 $ LIB_MODES = "cbc128,ctr128,cts128,cfb128,ofb128,gcm128,"+ -
 249         "ccm128,xts128,wrap128,ocb128"
 250 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
 251 $ IF F$TRNLNM("OPENSSL_NO_ASM") .OR. ARCH .NES. "VAX" THEN -
 252      LIB_BN_ASM = "bn_asm"
 253 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,bn_mod,"+ -
 254         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
 255         "bn_kron,bn_sqrt,bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+","+ -
 256         "bn_recp,bn_mont,bn_mpi,bn_exp2,bn_gf2m,bn_nist,"+ -
 257         "bn_depr,bn_const,bn_x931p,bn_intern,bn_dh,bn_srp"
 258 $ LIB_EC = "ec_lib,ecp_smpl,ecp_mont,ecp_nist,ec_cvt,ec_mult,"+ -
 259         "ec_err,ec_curve,ec_check,ec_print,ec_asn1,ec_key,"+ -
 260         "ec2_smpl,ec2_mult,ec_ameth,ec_pmeth,eck_prn,"+ -
 261         "ecp_nistp224,ecp_nistp256,ecp_nistp521,ecp_nistputil,"+ -
 262         "ecp_oct,ec2_oct,ec_oct"
 263 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
 264         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null,"+ -
 265         "rsa_pss,rsa_x931,rsa_asn1,rsa_depr,rsa_ameth,rsa_prn,"+ -
 266         "rsa_pmeth,rsa_crpt,rsa_x931g"
 267 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,"+ -
 268         "dsa_err,dsa_ossl,dsa_depr,dsa_ameth,dsa_pmeth,dsa_prn"
 269 $ LIB_ECDSA = "ecs_lib,ecs_asn1,ecs_ossl,ecs_sign,ecs_vrf,ecs_err"
 270 $ LIB_DH = "dh_asn1,dh_gen,dh_key,dh_lib,dh_check,dh_err,dh_depr,"+ -
 271         "dh_ameth,dh_pmeth,dh_prn,dh_rfc5114,dh_kdf"
 272 $ LIB_ECDH = "ech_lib,ech_ossl,ech_key,ech_err,ech_kdf"
 273 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
 274         "dso_openssl,dso_win32,dso_vms"
 275 $ LIB_ENGINE = "eng_err,eng_lib,eng_list,eng_init,eng_ctrl,"+ -
 276         "eng_table,eng_pkey,eng_fat,eng_all,"+ -
 277         "tb_rsa,tb_dsa,tb_ecdsa,tb_dh,tb_ecdh,tb_rand,tb_store,"+ -
 278         "tb_cipher,tb_digest,tb_pkmeth,tb_asnmth,"+ -
 279         "eng_openssl,eng_cnf,eng_dyn,eng_cryptodev,"+ -
 280         "eng_rdrand"
 281 $ LIB_BUFFER = "buffer,buf_str,buf_err"
 282 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
 283         "bss_mem,bss_null,bss_fd,"+ -
 284         "bss_file,bss_sock,bss_conn,"+ -
 285         "bf_null,bf_buff,b_print,b_dump,"+ -
 286         "b_sock,bss_acpt,bf_nbio,bss_log,bss_bio,"+ -
 287         "bss_dgram,"+ -
 288         "bf_lbuf"       ! The last one is VMS specific
 289 $ LIB_STACK = "stack"
 290 $ LIB_LHASH = "lhash,lh_stats"
 291 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,"+ -
 292         "rand_win,rand_unix,rand_vms,rand_os2,rand_nw"
 293 $ LIB_ERR = "err,err_all,err_prn"
 294 $ LIB_EVP_1 = "encode,digest,evp_enc,evp_key,evp_acnf,evp_cnf,"+ -
 295         "e_des,e_bf,e_idea,e_des3,e_camellia,"+ -
 296         "e_rc4,e_aes,names,e_seed,"+ -
 297         "e_xcbc_d,e_rc2,e_cast,e_rc5"
 298 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha1,m_wp," + -
 299         "m_dss1,m_mdc2,m_ripemd,m_ecdsa,"+ -
 300         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
 301         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
 302         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
 303         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
 304 $ LIB_EVP_3 = "e_old,pmeth_lib,pmeth_fn,pmeth_gn,m_sigver,"+ -
 305         "e_aes_cbc_hmac_sha1,e_aes_cbc_hmac_sha256,e_rc4_hmac_md5"
 306 $ LIB_ASN1_1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
 307         "a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,"+ -
 308         "a_enum,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
 309         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,x_bignum,"+ -
 310         "x_long,x_name,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
 311         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
 312 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
 313         "tasn_new,tasn_fre,tasn_enc,tasn_dec,tasn_utl,tasn_typ,"+ -
 314         "tasn_prn,tasn_scn,ameth_lib,"+ -
 315         "f_int,f_string,n_pkey,"+ -
 316         "f_enum,x_pkey,a_bool,x_exten,bio_asn1,bio_ndef,asn_mime,"+ -
 317         "asn1_gen,asn1_par,asn1_lib,asn1_err,a_bytes,a_strnid,"+ -
 318         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey,asn_moid,"+ -
 319         "asn_mstbl"
 320 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err,"+ -
 321         "pem_x509,pem_xaux,pem_oth,pem_pk8,pem_pkey,pvkfmt"
 322 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
 323         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
 324         "x509_set,x509cset,x509rset,x509_err,"+ -
 325         "x509name,x509_v3,x509_ext,x509_att,"+ -
 326         "x509type,x509_lu,x_all,x509_txt,"+ -
 327         "x509_trs,by_file,by_dir,x509_vpm"
 328 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
 329         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
 330         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info,"+ -
 331         "v3_akeya,v3_pmaps,v3_pcons,v3_ncons,v3_pcia,v3_pci,"+ -
 332         "pcy_cache,pcy_node,pcy_data,pcy_map,pcy_tree,pcy_lib,"+ -
 333         "v3_asid,v3_addr,v3_scts"
 334 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def,conf_mod,conf_mall,conf_sap"
 335 $ LIB_TXT_DB = "txt_db"
 336 $ LIB_PKCS7 = "pk7_asn1,pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,"+ -
 337         "pk7_mime,bio_pk7"
 338 $ LIB_PKCS12 = "p12_add,p12_asn,p12_attr,p12_crpt,p12_crt,p12_decr,"+ -
 339         "p12_init,p12_key,p12_kiss,p12_mutl,"+ -
 340         "p12_utl,p12_npas,pk12err,p12_p8d,p12_p8e"
 341 $ LIB_COMP = "comp_lib,comp_err,"+ -
 342         "c_zlib"
 343 $ LIB_OCSP = "ocsp_asn,ocsp_ext,ocsp_ht,ocsp_lib,ocsp_cl,"+ -
 344         "ocsp_srv,ocsp_prn,ocsp_vfy,ocsp_err,v3_ocsp"
 345 $ LIB_UI = "ui_err,ui_lib,ui_openssl,ui_util"
 346 $ LIB_CMS = "cms_lib,cms_asn1,cms_att,cms_io,cms_smime,cms_err,"+ -
 347         "cms_sd,cms_dd,cms_cd,cms_env,cms_enc,cms_ess,"+ -
 348         "cms_pwri,cms_kari"
 349 $ LIB_PQUEUE = "pqueue"
 350 $ LIB_TS = "ts_err,ts_req_utils,ts_req_print,ts_rsp_utils,ts_rsp_print,"+ -
 351         "ts_rsp_sign,ts_rsp_verify,ts_verify_ctx,ts_lib,ts_conf,"+ -
 352         "ts_asn1"
 353 $ LIB_JPAKE = "jpake,jpake_err"
 354 $ LIB_SRP = "srp_lib,srp_vfy"
 355 $ LIB_STORE = "str_err,str_lib,str_meth,str_mem"
 356 $ LIB_CMAC = "cmac,cm_ameth,cm_pmeth"
 357 $!
 358 $! Setup exceptional compilations
 359 $!
 360 $ CC3_SHOWN = 0
 361 $ CC4_SHOWN = 0
 362 $ CC5_SHOWN = 0
 363 $ CC6_SHOWN = 0
 364 $!
 365 $! The following lists must have leading and trailing commas, and no
 366 $! embedded spaces.  (They are scanned for ",name,".)
 367 $!
 368 $ ! Add definitions for no threads on OpenVMS 7.1 and higher.
 369 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 370 $ ! Disable the DOLLARID warning.  Not needed with /STANDARD=RELAXED.
 371 $ COMPILEWITH_CC4 = "" !!! ",a_utctm,bss_log,o_time,o_dir,"
 372 $ ! Disable disjoint optimization on VAX with DECC.
 373 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 374                     "seed,sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 375 $ ! Disable the MIXLINKAGE warning.
 376 $ COMPILEWITH_CC6 = "" !!! ",enc_read,set_key,"
 377 $!
 378 $! Figure Out What Other Modules We Are To Build.
 379 $!
 380 $ BUILD_SET:
 381 $!
 382 $! Define A Module Counter.
 383 $!
 384 $ MODULE_COUNTER = 0
 385 $!
 386 $! Top Of The Loop.
 387 $!
 388 $ MODULE_NEXT:
 389 $!
 390 $! Extract The Module Name From The Encryption List.
 391 $!
 392 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 393 $!
 394 $! Check To See If We Are At The End Of The Module List.
 395 $!
 396 $ IF (MODULE_NAME.EQS.",")
 397 $ THEN
 398 $!
 399 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 400 $!
 401 $   GOTO MODULE_DONE
 402 $!
 403 $! End The Module List Check.
 404 $!
 405 $ ENDIF
 406 $!
 407 $! Increment The Moudle Counter.
 408 $!
 409 $ MODULE_COUNTER = MODULE_COUNTER + 1
 410 $
 411 $ IF MODULE_NAME.EQS."" THEN GOTO MODULE_NEXT
 412 $ MODULE_NAME1 = MODULE_NAME
 413 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 414 $!
 415 $! Check if the library module name actually is defined
 416 $!
 417 $ PART_COUNTER = -1
 418 $ IF F$TYPE(LIB_'MODULE_NAME'_1) .NES. ""
 419 $ THEN
 420 $   PART_COUNTER = 1
 421 $ ELSE
 422 $   IF F$TYPE(LIB_'MODULE_NAME') .EQS. ""
 423 $   THEN
 424 $     WRITE SYS$ERROR ""
 425 $     WRITE SYS$ERROR "The module ",MODULE_NAME1," does not exist.  Continuing..."
 426 $     WRITE SYS$ERROR ""
 427 $     GOTO MODULE_NEXT
 428 $   ENDIF
 429 $ ENDIF
 430 $!
 431 $! Tell The User What Module We Are Building.
 432 $!
 433 $ WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,")"
 434 $!
 435 $! Create The Library Module Names.
 436 $!
 437 $ PART_NEXT:
 438 $ IF PART_COUNTER .EQ. 0 THEN GOTO MODULE_NEXT
 439 $
 440 $ IF PART_COUNTER .LT. 0
 441 $ THEN
 442 $   LIB_MODULE = "LIB_" + MODULE_NAME
 443 $ ELSE
 444 $   LIB_MODULE = "LIB_" + MODULE_NAME + "_''PART_COUNTER'"
 445 $ ENDIF
 446 $!
 447 $! If there are no more parts, go to the next module
 448 $!
 449 $ IF F$TYPE('LIB_MODULE') .EQS. "" THEN GOTO MODULE_NEXT
 450 $!
 451 $! Increment The Counter.
 452 $!
 453 $ PART_COUNTER = PART_COUNTER + 1
 454 $!
 455 $!  Define A File Counter And Set It To "0".
 456 $!
 457 $ FILE_COUNTER = 0
 458 $!
 459 $! Top Of The File Loop.
 460 $!
 461 $ NEXT_FILE:
 462 $!
 463 $! Extract The File Name From The File List.
 464 $!
 465 $ FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 466 $!
 467 $! Check To See If We Are At The End Of The File List.
 468 $!
 469 $ IF (FILE_NAME.EQS.",")
 470 $ THEN
 471 $!
 472 $!  We Are At The End Of The File List, Goto FILE_DONE.
 473 $!
 474 $   GOTO FILE_DONE
 475 $!
 476 $! End The File List Check.
 477 $!
 478 $ ENDIF
 479 $!
 480 $! Increment The Counter.
 481 $!
 482 $ FILE_COUNTER = FILE_COUNTER + 1
 483 $!
 484 $! Create The Source File Name.
 485 $!
 486 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 487 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 488 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 489         FILE_NAME = FILE_NAME + ".c"
 490 $ IF (MODULE_NAME.NES."")
 491 $ THEN
 492 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 493 $ ELSE
 494 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 495 $ ENDIF
 496 $ SOURCE_FILE = SOURCE_FILE - "]["
 497 $!
 498 $! Create The Object File Name.
 499 $!
 500 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 501 $ ON WARNING THEN GOTO NEXT_FILE
 502 $!
 503 $! Check To See If The File We Want To Compile Is Actually There.
 504 $!
 505 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 506 $ THEN
 507 $!
 508 $!  Tell The User That The File Doesn't Exist.
 509 $!
 510 $   WRITE SYS$OUTPUT ""
 511 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 512 $   WRITE SYS$OUTPUT ""
 513 $!
 514 $!  Exit The Build.
 515 $!
 516 $   GOTO EXIT
 517 $!
 518 $! End The File Exist Check.
 519 $!
 520 $ ENDIF
 521 $!
 522 $! Tell The User We Are Compiling The File.
 523 $!
 524 $ WRITE SYS$OUTPUT "        ",FILE_NAME,""
 525 $!
 526 $! Compile The File.
 527 $!
 528 $ ON ERROR THEN GOTO NEXT_FILE
 529 $ FILE_NAME0 = ","+ F$ELEMENT(0,".",FILE_NAME)+ ","
 530 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 531 $ THEN
 532 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 533 $ ELSE
 534 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 535 $   THEN
 536 $     write sys$output "        \Using special rule (3)"
 537 $     if (.not. CC3_SHOWN)
 538 $     then
 539 $       CC3_SHOWN = 1
 540 $       x = "    "+ CC3
 541 $       write /symbol sys$output x
 542 $     endif
 543 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 544 $   ELSE
 545 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 546 $     THEN
 547 $       write /symbol sys$output "        \Using special rule (4)"
 548 $       if (.not. CC4_SHOWN)
 549 $       then
 550 $         CC4_SHOWN = 1
 551 $         x = "    "+ CC4
 552 $         write /symbol sys$output x
 553 $       endif
 554 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 555 $     ELSE
 556 $       IF CC5_DIFFERENT .AND. -
 557          (COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5)
 558 $       THEN
 559 $         write sys$output "        \Using special rule (5)"
 560 $         if (.not. CC5_SHOWN)
 561 $         then
 562 $           CC5_SHOWN = 1
 563 $           x = "    "+ CC5
 564 $           write /symbol sys$output x
 565 $         endif
 566 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 567 $       ELSE
 568 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 569 $         THEN
 570 $           write sys$output "        \Using special rule (6)"
 571 $           if (.not. CC6_SHOWN)
 572 $           then
 573 $             CC6_SHOWN = 1
 574 $             x = "    "+ CC6
 575 $             write /symbol sys$output x
 576 $           endif
 577 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 578 $         ELSE
 579 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 580 $         ENDIF
 581 $       ENDIF
 582 $     ENDIF
 583 $   ENDIF
 584 $ ENDIF
 585 $!
 586 $! Add It To The Library.
 587 $!
 588 $ LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 589 $!
 590 $! Time To Clean Up The Object File.
 591 $!
 592 $ DELETE 'OBJECT_FILE';*
 593 $!
 594 $! Go Back And Do It Again.
 595 $!
 596 $ GOTO NEXT_FILE
 597 $!
 598 $! All Done With This Library Part.
 599 $!
 600 $ FILE_DONE:
 601 $!
 602 $! Go Back And Get The Next Part.
 603 $!
 604 $ GOTO PART_NEXT
 605 $!
 606 $! All Done With This Module.
 607 $!
 608 $ MODULE_DONE:
 609 $!
 610 $! Tell The User That We Are All Done.
 611 $!
 612 $ WRITE SYS$OUTPUT "All Done..."
 613 $ EXIT:
 614 $ GOSUB CLEANUP
 615 $ EXIT
 616 $!
 617 $! Check For The Link Option FIle.
 618 $!
 619 $ CHECK_OPT_FILE:
 620 $!
 621 $! Check To See If We Need To Make A VAX C Option File.
 622 $!
 623 $ IF (COMPILER.EQS."VAXC")
 624 $ THEN
 625 $!
 626 $!  Check To See If We Already Have A VAX C Linker Option File.
 627 $!
 628 $   IF (F$SEARCH(OPT_FILE).EQS."")
 629 $   THEN
 630 $!
 631 $!    We Need A VAX C Linker Option File.
 632 $!
 633 $     CREATE 'OPT_FILE'
 634 $DECK
 635 !
 636 ! Default System Options File To Link Against
 637 ! The Sharable VAX C Runtime Library.
 638 !
 639 SYS$SHARE:VAXCRTL.EXE/SHARE
 640 $EOD
 641 $!
 642 $!  End The Option File Check.
 643 $!
 644 $   ENDIF
 645 $!
 646 $! End The VAXC Check.
 647 $!
 648 $ ENDIF
 649 $!
 650 $! Check To See If We Need A GNU C Option File.
 651 $!
 652 $ IF (COMPILER.EQS."GNUC")
 653 $ THEN
 654 $!
 655 $!  Check To See If We Already Have A GNU C Linker Option File.
 656 $!
 657 $   IF (F$SEARCH(OPT_FILE).EQS."")
 658 $   THEN
 659 $!
 660 $!    We Need A GNU C Linker Option File.
 661 $!
 662 $     CREATE 'OPT_FILE'
 663 $DECK
 664 !
 665 ! Default System Options File To Link Against
 666 ! The Sharable C Runtime Library.
 667 !
 668 GNU_CC:[000000]GCCLIB/LIBRARY
 669 SYS$SHARE:VAXCRTL/SHARE
 670 $EOD
 671 $!
 672 $!  End The Option File Check.
 673 $!
 674 $   ENDIF
 675 $!
 676 $! End The GNU C Check.
 677 $!
 678 $ ENDIF
 679 $!
 680 $! Check To See If We Need A DEC C Option File.
 681 $!
 682 $ IF (COMPILER.EQS."DECC")
 683 $ THEN
 684 $!
 685 $!  Check To See If We Already Have A DEC C Linker Option File.
 686 $!
 687 $   IF (F$SEARCH(OPT_FILE).EQS."")
 688 $   THEN
 689 $!
 690 $!    Figure Out If We Need A non-VAX Or A VAX Linker Option File.
 691 $!
 692 $     IF ARCH .EQS. "VAX"
 693 $     THEN
 694 $!
 695 $!      We Need A DEC C Linker Option File For VAX.
 696 $!
 697 $       CREATE 'OPT_FILE'
 698 $DECK
 699 !
 700 ! Default System Options File To Link Against
 701 ! The Sharable DEC C Runtime Library.
 702 !
 703 SYS$SHARE:DECC$SHR.EXE/SHARE
 704 $EOD
 705 $!
 706 $!    Else...
 707 $!
 708 $     ELSE
 709 $!
 710 $!      Create The non-VAX Linker Option File.
 711 $!
 712 $       CREATE 'OPT_FILE'
 713 $DECK
 714 !
 715 ! Default System Options File For non-VAX To Link Against
 716 ! The Sharable C Runtime Library.
 717 !
 718 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 719 SYS$SHARE:CMA$OPEN_RTL/SHARE
 720 $EOD
 721 $!
 722 $!    End The DEC C Option File Check.
 723 $!
 724 $     ENDIF
 725 $!
 726 $!  End The Option File Search.
 727 $!
 728 $   ENDIF
 729 $!
 730 $! End The DEC C Check.
 731 $!
 732 $ ENDIF
 733 $!
 734 $!  Tell The User What Linker Option File We Are Using.
 735 $!
 736 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 737 $!
 738 $! Time To RETURN.
 739 $!
 740 $ RETURN
 741 $!
 742 $! Check The User's Options.
 743 $!
 744 $ CHECK_OPTIONS:
 745 $!
 746 $! Check To See If P1 Is Blank.
 747 $!
 748 $ IF (P1.EQS."ALL")
 749 $ THEN
 750 $!
 751 $!   P1 Is Blank, So Build Everything.
 752 $!
 753 $    BUILDALL = "TRUE"
 754 $!
 755 $! Else...
 756 $!
 757 $ ELSE
 758 $!
 759 $!  Else, Check To See If P1 Has A Valid Argument.
 760 $!
 761 $   IF (P1.EQS."LIBRARY")
 762 $   THEN
 763 $!
 764 $!    A Valid Argument.
 765 $!
 766 $     BUILDALL = P1
 767 $!
 768 $!  Else...
 769 $!
 770 $   ELSE
 771 $!
 772 $!    Tell The User We Don't Know What They Want.
 773 $!
 774 $     WRITE SYS$OUTPUT ""
 775 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 776 $     WRITE SYS$OUTPUT ""
 777 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 778 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 779 $     WRITE SYS$OUTPUT ""
 780 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 781 $     WRITE SYS$OUTPUT ""
 782 $     WRITE SYS$OUTPUT "    ALPHA[64]:  Alpha Architecture."
 783 $     WRITE SYS$OUTPUT "    IA64[64] :  IA64 Architecture."
 784 $     WRITE SYS$OUTPUT "    VAX      :  VAX Architecture."
 785 $     WRITE SYS$OUTPUT ""
 786 $!
 787 $!    Time To EXIT.
 788 $!
 789 $     EXIT
 790 $!
 791 $!  End The Valid Argument Check.
 792 $!
 793 $   ENDIF
 794 $!
 795 $! End The P1 Check.
 796 $!
 797 $ ENDIF
 798 $!
 799 $! Check To See If P2 Is Blank.
 800 $!
 801 $ IF (P2.EQS."NODEBUG")
 802 $ THEN
 803 $!
 804 $!  P2 Is NODEBUG, So Compile Without The Debugger Information.
 805 $!
 806 $   DEBUGGER = "NODEBUG"
 807 $   LINKMAP = "NOMAP"
 808 $   TRACEBACK = "NOTRACEBACK"
 809 $   GCC_OPTIMIZE = "OPTIMIZE"
 810 $   CC_OPTIMIZE = "OPTIMIZE"
 811 $   MACRO_OPTIMIZE = "OPTIMIZE"
 812 $   WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 813 $   WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 814 $ ELSE
 815 $!
 816 $!  Check To See If We Are To Compile With Debugger Information.
 817 $!
 818 $   IF (P2.EQS."DEBUG")
 819 $   THEN
 820 $!
 821 $!    Compile With Debugger Information.
 822 $!
 823 $     DEBUGGER = "DEBUG"
 824 $     LINKMAP = "MAP"
 825 $     TRACEBACK = "TRACEBACK"
 826 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 827 $     CC_OPTIMIZE = "NOOPTIMIZE"
 828 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 829 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 830 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 831 $   ELSE
 832 $!
 833 $!    They Entered An Invalid Option.
 834 $!
 835 $     WRITE SYS$OUTPUT ""
 836 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 837 $     WRITE SYS$OUTPUT ""
 838 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 839 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 840 $     WRITE SYS$OUTPUT ""
 841 $!
 842 $!    Time To EXIT.
 843 $!
 844 $     EXIT
 845 $!
 846 $!  End The Valid Argument Check.
 847 $!
 848 $   ENDIF
 849 $!
 850 $! End The P2 Check.
 851 $!
 852 $ ENDIF
 853 $!
 854 $! Special Threads For OpenVMS v7.1 Or Later
 855 $!
 856 $! Written By:  Richard Levitte
 857 $!              richard@levitte.org
 858 $!
 859 $!
 860 $! Check To See If We Have A Option For P5.
 861 $!
 862 $ IF (P5.EQS."")
 863 $ THEN
 864 $!
 865 $!  Get The Version Of VMS We Are Using.
 866 $!
 867 $   ISSEVEN :=
 868 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 869 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 870 $!
 871 $!  Check To See If The VMS Version Is v7.1 Or Later.
 872 $!
 873 $   IF (TMP.GE.71)
 874 $   THEN
 875 $!
 876 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 877 $!
 878 $     ISSEVEN := ,PTHREAD_USE_D4
 879 $!
 880 $!  End The VMS Version Check.
 881 $!
 882 $   ENDIF
 883 $!
 884 $! End The P5 Check.
 885 $!
 886 $ ENDIF
 887 $!
 888 $! Check P7 (POINTER_SIZE).
 889 $!
 890 $ IF (P7 .NES. "") .AND. (ARCH .NES. "VAX")
 891 $ THEN
 892 $!
 893 $   IF (P7 .EQS. "32")
 894 $   THEN
 895 $     POINTER_SIZE = " /POINTER_SIZE=32"
 896 $   ELSE
 897 $     POINTER_SIZE = F$EDIT( P7, "COLLAPSE, UPCASE")
 898 $     IF ((POINTER_SIZE .EQS. "64") .OR. -
 899        (POINTER_SIZE .EQS. "64=") .OR. -
 900        (POINTER_SIZE .EQS. "64=ARGV"))
 901 $     THEN
 902 $       ARCHD = ARCH+ "_64"
 903 $       LIB32 = ""
 904 $       POINTER_SIZE = " /POINTER_SIZE=64"
 905 $     ELSE
 906 $!
 907 $!      Tell The User Entered An Invalid Option.
 908 $!
 909 $       WRITE SYS$OUTPUT ""
 910 $       WRITE SYS$OUTPUT "The Option ", P7, -
 911          " Is Invalid.  The Valid Options Are:"
 912 $       WRITE SYS$OUTPUT ""
 913 $       WRITE SYS$OUTPUT -
 914          "    """"       :  Compile with default (short) pointers."
 915 $       WRITE SYS$OUTPUT -
 916          "    32       :  Compile with 32-bit (short) pointers."
 917 $       WRITE SYS$OUTPUT -
 918          "    64       :  Compile with 64-bit (long) pointers (auto ARGV)."
 919 $       WRITE SYS$OUTPUT -
 920          "    64=      :  Compile with 64-bit (long) pointers (no ARGV)."
 921 $       WRITE SYS$OUTPUT -
 922          "    64=ARGV  :  Compile with 64-bit (long) pointers (ARGV)."
 923 $       WRITE SYS$OUTPUT ""
 924 $!
 925 $!      Time To EXIT.
 926 $!
 927 $       EXIT
 928 $!
 929 $     ENDIF
 930 $!
 931 $   ENDIF
 932 $!
 933 $! End The P7 (POINTER_SIZE) Check.
 934 $!
 935 $ ENDIF
 936 $!
 937 $! Set basic C compiler /INCLUDE directories.
 938 $!
 939 $ CC_INCLUDES = "SYS$DISK:[.''ARCHD'],SYS$DISK:[],SYS$DISK:[-],"+ -
 940    "SYS$DISK:[.ENGINE.VENDOR_DEFNS],SYS$DISK:[.EVP],SYS$DISK:[.ASN1],"+ -
 941    "SYS$DISK:[.MODES]"
 942 $!
 943 $! Check To See If P3 Is Blank.
 944 $!
 945 $ IF (P3.EQS."")
 946 $ THEN
 947 $!
 948 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 949 $!  Find Out Which One To Use.
 950 $!
 951 $!  Check To See If We Have GNU C.
 952 $!
 953 $   IF (F$TRNLNM("GNU_CC").NES."")
 954 $   THEN
 955 $!
 956 $!    Looks Like GNUC, Set To Use GNUC.
 957 $!
 958 $     P3 = "GNUC"
 959 $!
 960 $!  Else...
 961 $!
 962 $   ELSE
 963 $!
 964 $!    Check To See If We Have VAXC Or DECC.
 965 $!
 966 $     IF (ARCH.NES."VAX").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 967 $     THEN
 968 $!
 969 $!      Looks Like DECC, Set To Use DECC.
 970 $!
 971 $       P3 = "DECC"
 972 $!
 973 $!    Else...
 974 $!
 975 $     ELSE
 976 $!
 977 $!      Looks Like VAXC, Set To Use VAXC.
 978 $!
 979 $       P3 = "VAXC"
 980 $!
 981 $!    End The VAXC Compiler Check.
 982 $!
 983 $     ENDIF
 984 $!
 985 $!  End The DECC & VAXC Compiler Check.
 986 $!
 987 $   ENDIF
 988 $!
 989 $!  End The Compiler Check.
 990 $!
 991 $ ENDIF
 992 $!
 993 $! Check To See If We Have A Option For P4.
 994 $!
 995 $ IF (P4.EQS."")
 996 $ THEN
 997 $!
 998 $!  Find out what socket library we have available
 999 $!
1000 $   IF F$PARSE("SOCKETSHR:") .NES. ""
1001 $   THEN
1002 $!
1003 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
1004 $!
1005 $     P4 = "SOCKETSHR"
1006 $!
1007 $!    Tell the user
1008 $!
1009 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
1010 $!
1011 $!    Else, let's look for something else
1012 $!
1013 $   ELSE
1014 $!
1015 $!    Like UCX (the reason to do this before Multinet is that the UCX
1016 $!    emulation is easier to use...)
1017 $!
1018 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
1019          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
1020          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
1021 $     THEN
1022 $!
1023 $!      Last resort: a UCX or UCX-compatible library
1024 $!
1025 $       P4 = "UCX"
1026 $!
1027 $!      Tell the user
1028 $!
1029 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
1030 $!
1031 $!      That was all...
1032 $!
1033 $     ENDIF
1034 $   ENDIF
1035 $ ENDIF
1036 $!
1037 $! Set Up Initial CC Definitions, Possibly With User Ones
1038 $!
1039 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
1040 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
1041 $ CCEXTRAFLAGS = ""
1042 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
1043 $ CCDISABLEWARNINGS = "" !!! "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
1044 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
1045         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
1046 $!
1047 $! Check To See If We Have A ZLIB Option.
1048 $!
1049 $ ZLIB = P8
1050 $ IF (ZLIB .NES. "")
1051 $ THEN
1052 $!
1053 $!  Check for expected ZLIB files.
1054 $!
1055 $   err = 0
1056 $   file1 = f$parse( "zlib.h", ZLIB, , , "SYNTAX_ONLY")
1057 $   if (f$search( file1) .eqs. "")
1058 $   then
1059 $     WRITE SYS$OUTPUT ""
1060 $     WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
1061 $     WRITE SYS$OUTPUT "    Can't find header: ''file1'"
1062 $     err = 1
1063 $   endif
1064 $   file1 = f$parse( "A.;", ZLIB)- "A.;"
1065 $!
1066 $   file2 = f$parse( ZLIB, "libz.olb", , , "SYNTAX_ONLY")
1067 $   if (f$search( file2) .eqs. "")
1068 $   then
1069 $     if (err .eq. 0)
1070 $     then
1071 $       WRITE SYS$OUTPUT ""
1072 $       WRITE SYS$OUTPUT "The Option ", ZLIB, " Is Invalid."
1073 $     endif
1074 $     WRITE SYS$OUTPUT "    Can't find library: ''file2'"
1075 $     WRITE SYS$OUTPUT ""
1076 $     err = err+ 2
1077 $   endif
1078 $   if (err .eq. 1)
1079 $   then
1080 $     WRITE SYS$OUTPUT ""
1081 $   endif
1082 $!
1083 $   if (err .ne. 0)
1084 $   then
1085 $     EXIT
1086 $   endif
1087 $!
1088 $   CCDEFS = """ZLIB=1"", "+ CCDEFS
1089 $   CC_INCLUDES = CC_INCLUDES+ ", "+ file1
1090 $   ZLIB_LIB = ", ''file2' /library"
1091 $!
1092 $!  Print info
1093 $!
1094 $   WRITE SYS$OUTPUT "ZLIB library spec: ", file2
1095 $!
1096 $! End The ZLIB Check.
1097 $!
1098 $ ENDIF
1099 $!
1100 $!  Check To See If The User Entered A Valid Parameter.
1101 $!
1102 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
1103 $ THEN
1104 $!
1105 $!    Check To See If The User Wanted DECC.
1106 $!
1107 $   IF (P3.EQS."DECC")
1108 $   THEN
1109 $!
1110 $!    Looks Like DECC, Set To Use DECC.
1111 $!
1112 $     COMPILER = "DECC"
1113 $!
1114 $!    Tell The User We Are Using DECC.
1115 $!
1116 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1117 $!
1118 $!    Use DECC...
1119 $!
1120 $     CC = "CC"
1121 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1122          THEN CC = "CC/DECC"
1123 $     CC = CC + " /''CC_OPTIMIZE' /''DEBUGGER' /STANDARD=RELAXED"+ -
1124        "''POINTER_SIZE' /NOLIST /PREFIX=ALL" + -
1125        " /INCLUDE=(''CC_INCLUDES')"+ -
1126        CCEXTRAFLAGS
1127 $!
1128 $!    Define The Linker Options File Name.
1129 $!
1130 $     OPT_FILE = "VAX_DECC_OPTIONS.OPT"
1131 $!
1132 $!  End DECC Check.
1133 $!
1134 $   ENDIF
1135 $!
1136 $!  Check To See If We Are To Use VAXC.
1137 $!
1138 $   IF (P3.EQS."VAXC")
1139 $   THEN
1140 $!
1141 $!    Looks Like VAXC, Set To Use VAXC.
1142 $!
1143 $     COMPILER = "VAXC"
1144 $!
1145 $!    Tell The User We Are Using VAX C.
1146 $!
1147 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1148 $!
1149 $!    Compile Using VAXC.
1150 $!
1151 $     CC = "CC"
1152 $     IF ARCH.NES."VAX"
1153 $     THEN
1154 $       WRITE SYS$OUTPUT "There is no VAX C on ''ARCH'!"
1155 $       EXIT
1156 $     ENDIF
1157 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1158 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1159        "/INCLUDE=(''CC_INCLUDES')"+ -
1160            CCEXTRAFLAGS
1161 $     CCDEFS = """VAXC""," + CCDEFS
1162 $!
1163 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1164 $!
1165 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1166 $!
1167 $!    Define The Linker Options File Name.
1168 $!
1169 $     OPT_FILE = "VAX_VAXC_OPTIONS.OPT"
1170 $!
1171 $!  End VAXC Check
1172 $!
1173 $   ENDIF
1174 $!
1175 $!  Check To See If We Are To Use GNU C.
1176 $!
1177 $   IF (P3.EQS."GNUC")
1178 $   THEN
1179 $!
1180 $!    Looks Like GNUC, Set To Use GNUC.
1181 $!
1182 $     COMPILER = "GNUC"
1183 $!
1184 $!    Tell The User We Are Using GNUC.
1185 $!
1186 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1187 $!
1188 $!    Use GNU C...
1189 $!
1190 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1191        "/INCLUDE=(''CC_INCLUDES')"+ -
1192            CCEXTRAFLAGS
1193 $!
1194 $!    Define The Linker Options File Name.
1195 $!
1196 $     OPT_FILE = "VAX_GNUC_OPTIONS.OPT"
1197 $!
1198 $!  End The GNU C Check.
1199 $!
1200 $   ENDIF
1201 $!
1202 $!  Set up default defines
1203 $!
1204 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1205 $!
1206 $!  Finish up the definition of CC.
1207 $!
1208 $   IF COMPILER .EQS. "DECC"
1209 $   THEN
1210 $     IF CCDISABLEWARNINGS .EQS. ""
1211 $     THEN
1212 $       CC4DISABLEWARNINGS = "DOLLARID"
1213 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
1214 $     ELSE
1215 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1216 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
1217 $       CCDISABLEWARNINGS = " /WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1218 $     ENDIF
1219 $     CC4DISABLEWARNINGS = " /WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1220 $     CC6DISABLEWARNINGS = " /WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
1221 $   ELSE
1222 $     CCDISABLEWARNINGS = ""
1223 $     CC4DISABLEWARNINGS = ""
1224 $     CC6DISABLEWARNINGS = ""
1225 $   ENDIF
1226 $   CC3 = CC + " /DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1227 $   CC = CC + " /DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1228 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1229 $   THEN
1230 $     CC5 = CC + " /OPTIMIZE=NODISJOINT"
1231 $     CC5_DIFFERENT = 1
1232 $   ELSE
1233 $     CC5 = CC
1234 $     CC5_DIFFERENT = 0
1235 $   ENDIF
1236 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1237 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1238 $!
1239 $!  Show user the result
1240 $!
1241 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1242 $!
1243 $!  Else The User Entered An Invalid Argument.
1244 $!
1245 $ ELSE
1246 $!
1247 $!  Tell The User We Don't Know What They Want.
1248 $!
1249 $   WRITE SYS$OUTPUT ""
1250 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1251 $   WRITE SYS$OUTPUT ""
1252 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1253 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1254 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1255 $   WRITE SYS$OUTPUT ""
1256 $!
1257 $!  Time To EXIT.
1258 $!
1259 $   EXIT
1260 $!
1261 $! End The Valid Argument Check.
1262 $!
1263 $ ENDIF
1264 $!
1265 $! Build a MACRO command for the architecture at hand
1266 $!
1267 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1268 $ IF ARCH .NES. "VAX" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1269 $!
1270 $!  Show user the result
1271 $!
1272 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1273 $!
1274 $! Time to check the contents, and to make sure we get the correct library.
1275 $!
1276 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1277      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1278 $ THEN
1279 $!
1280 $!  Check to see if SOCKETSHR was chosen
1281 $!
1282 $   IF P4.EQS."SOCKETSHR"
1283 $   THEN
1284 $!
1285 $!    Set the library to use SOCKETSHR
1286 $!
1287 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT /OPTIONS"
1288 $!
1289 $!    Done with SOCKETSHR
1290 $!
1291 $   ENDIF
1292 $!
1293 $!  Check to see if MULTINET was chosen
1294 $!
1295 $   IF P4.EQS."MULTINET"
1296 $   THEN
1297 $!
1298 $!    Set the library to use UCX emulation.
1299 $!
1300 $     P4 = "UCX"
1301 $!
1302 $!    Done with MULTINET
1303 $!
1304 $   ENDIF
1305 $!
1306 $!  Check to see if UCX was chosen
1307 $!
1308 $   IF P4.EQS."UCX"
1309 $   THEN
1310 $!
1311 $!    Set the library to use UCX.
1312 $!
1313 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT /OPTIONS"
1314 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1315 $     THEN
1316 $       TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT /OPTIONS"
1317 $     ELSE
1318 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1319           TCPIP_LIB = ",SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT /OPTIONS"
1320 $     ENDIF
1321 $!
1322 $!    Done with UCX
1323 $!
1324 $   ENDIF
1325 $!
1326 $!  Check to see if TCPIP was chosen
1327 $!
1328 $   IF P4.EQS."TCPIP"
1329 $   THEN
1330 $!
1331 $!    Set the library to use TCPIP (post UCX).
1332 $!
1333 $     TCPIP_LIB = ",SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT /OPTIONS"
1334 $!
1335 $!    Done with TCPIP
1336 $!
1337 $   ENDIF
1338 $!
1339 $!  Check to see if NONE was chosen
1340 $!
1341 $   IF P4.EQS."NONE"
1342 $   THEN
1343 $!
1344 $!    Do not use a TCPIP library.
1345 $!
1346 $     TCPIP_LIB = ""
1347 $!
1348 $!    Done with TCPIP
1349 $!
1350 $   ENDIF
1351 $!
1352 $!  Print info
1353 $!
1354 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB- ","
1355 $!
1356 $!  Else The User Entered An Invalid Argument.
1357 $!
1358 $ ELSE
1359 $!
1360 $!  Tell The User We Don't Know What They Want.
1361 $!
1362 $   WRITE SYS$OUTPUT ""
1363 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1364 $   WRITE SYS$OUTPUT ""
1365 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1366 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1367 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1368 $   WRITE SYS$OUTPUT ""
1369 $!
1370 $!  Time To EXIT.
1371 $!
1372 $   EXIT
1373 $!
1374 $!  Done with TCP/IP libraries
1375 $!
1376 $ ENDIF
1377 $!
1378 $! Check if the user wanted to compile just a subset of all the encryption
1379 $! methods.
1380 $!
1381 $ IF P6 .NES. ""
1382 $ THEN
1383 $   ENCRYPT_TYPES = P6
1384 $ ENDIF
1385 $!
1386 $!  Time To RETURN...
1387 $!
1388 $ RETURN
1389 $!
1390 $ INITIALISE:
1391 $!
1392 $! Save old value of the logical name OPENSSL
1393 $!
1394 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1395 $!
1396 $! Save directory information
1397 $!
1398 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1399 $ __HERE = F$EDIT(__HERE,"UPCASE")
1400 $ __TOP = __HERE - "CRYPTO]"
1401 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1402 $ __INTERNAL = __TOP + "CRYPTO.INCLUDE.INTERNAL]"
1403 $!
1404 $! Set up the logical name OPENSSL to point at the include directory
1405 $!
1406 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1407 $ DEFINE INTERNAL/NOLOG '__INTERNAL'
1408 $!
1409 $! Done
1410 $!
1411 $ RETURN
1412 $!
1413 $ CLEANUP:
1414 $!
1415 $! Restore the logical name OPENSSL if it had a value
1416 $!
1417 $ IF __SAVE_OPENSSL .EQS. ""
1418 $ THEN
1419 $   DEASSIGN OPENSSL
1420 $   DEASSIGN INTERNAL
1421 $ ELSE
1422 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1423 $ ENDIF
1424 $!
1425 $! Done
1426 $!
1427 $ RETURN