crypto/crypto-lib.com

   1 $!
   2 $!  CRYPTO-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  11 $!  library for OpenSSL.  The "xxx" denotes the machine architecture of AXP
  12 $!  or VAX.
  13 $!
  14 $!  It was re-written so it would try to determine what "C" compiler to use
  15 $!  or you can specify which "C" compiler to use.
  16 $!
  17 $!  Specify the following as P1 to build just that part or ALL to just
  18 $!  build everything.
  19 $!
  20 $!              LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  21 $!              APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
  22 $!              ALL        To do both LIBRARY and APPS
  23 $!
  24 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  25 $!  information.
  26 $!
  27 $!  Specify which compiler at P3 to try to compile under.
  28 $!
  29 $!         VAXC  For VAX C.
  30 $!         DECC  For DEC C.
  31 $!         GNUC  For GNU C.
  32 $!
  33 $!  If you don't speficy a compiler, it will try to determine which
  34 $!  "C" compiler to use.
  35 $!
  36 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  37 $!  keywords:
  38 $!
  39 $!      UCX             for UCX
  40 $!      TCPIP           for TCPIP (post UCX)
  41 $!      SOCKETSHR       for SOCKETSHR+NETLIB
  42 $!
  43 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  44 $!
  45 $!  P6, if defined, sets a choice of crypto methods to compile.
  46 $!  WARNING: this should only be done to recompile some part of an already
  47 $!  fully compiled library.
  48 $!
  49 $!
  50 $! Define A TCP/IP Library That We Will Need To Link To.
  51 $! (That Is, If We Need To Link To One.)
  52 $!
  53 $ TCPIP_LIB = ""
  54 $!
  55 $! Check Which Architecture We Are Using.
  56 $!
  57 $ IF (F$GETSYI("CPU").GE.128)
  58 $ THEN
  59 $!
  60 $!  The Architecture Is AXP
  61 $!
  62 $   ARCH := AXP
  63 $!
  64 $! Else...
  65 $!
  66 $ ELSE
  67 $!
  68 $!  The Architecture Is VAX.
  69 $!
  70 $   ARCH := VAX
  71 $!
  72 $! End The Architecture Check.
  73 $!
  74 $ ENDIF
  75 $!
  76 $! Define The Different Encryption Types.
  77 $!
  78 $ ENCRYPT_TYPES = "Basic,"+ -
  79                   "OBJECTS,"+ -
  80                   "MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ -
  81                   "DES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,"+ -
  82                   "BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,AES,"+ -
  83                   "BUFFER,BIO,STACK,LHASH,RAND,ERR,"+ -
  84                   "EVP,EVP_2,ASN1,ASN1_2,PEM,X509,X509V3,"+ -
  85                   "CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5,"+ -
  86                   "STORE,CMS,PQUEUE,JPAKE"
  87 $!
  88 $! Check To Make Sure We Have Valid Command Line Parameters.
  89 $!
  90 $ GOSUB CHECK_OPTIONS
  91 $!
  92 $! Initialise logical names and such
  93 $!
  94 $ GOSUB INITIALISE
  95 $!
  96 $! Tell The User What Kind of Machine We Run On.
  97 $!
  98 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
  99 $!
 100 $! Define The OBJ Directory.
 101 $!
 102 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
 103 $!
 104 $! Check To See If The Architecture Specific OBJ Directory Exists.
 105 $!
 106 $ IF (F$PARSE(OBJ_DIR).EQS."")
 107 $ THEN
 108 $!
 109 $!  It Dosen't Exist, So Create It.
 110 $!
 111 $   CREATE/DIR 'OBJ_DIR'
 112 $!
 113 $! End The Architecture Specific OBJ Directory Check.
 114 $!
 115 $ ENDIF
 116 $!
 117 $! Define The EXE Directory.
 118 $!
 119 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
 120 $!
 121 $! Check To See If The Architecture Specific Directory Exists.
 122 $!
 123 $ IF (F$PARSE(EXE_DIR).EQS."")
 124 $ THEN
 125 $!
 126 $!  It Dosen't Exist, So Create It.
 127 $!
 128 $   CREATE/DIRECTORY 'EXE_DIR'
 129 $!
 130 $! End The Architecture Specific Directory Check.
 131 $!
 132 $ ENDIF
 133 $!
 134 $! Define The Library Name.
 135 $!
 136 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
 137 $!
 138 $! Define The CRYPTO-LIB We Are To Use.
 139 $!
 140 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
 141 $!
 142 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 143 $!
 144 $ IF (F$SEARCH(LIB_NAME).EQS."")
 145 $ THEN
 146 $!
 147 $! Guess Not, Create The Library.
 148 $!
 149 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 150 $!
 151 $! End The Library Check.
 152 $!
 153 $ ENDIF
 154 $!
 155 $! Build our options file for the application
 156 $!
 157 $ GOSUB CHECK_OPT_FILE
 158 $!
 159 $! Define The Different Encryption "library" Strings.
 160 $!
 161 $ APPS_DES = "DES/DES,CBC3_ENC"
 162 $ APPS_PKCS7 = "ENC/ENC;DEC/DEC;SIGN/SIGN;VERIFY/VERIFY,EXAMPLE"
 163 $
 164 $ LIB_ = "cryptlib,dyn_lck,mem,mem_clr,mem_dbg,cversion,ex_data,tmdiff,cpt_err,ebcdic,uid,o_time,o_str,o_dir,o_init,fips_err"
 165 $ LIB_MD2 = "md2_dgst,md2_one"
 166 $ LIB_MD4 = "md4_dgst,md4_one"
 167 $ LIB_MD5 = "md5_dgst,md5_one"
 168 $ LIB_SHA = "sha_dgst,sha1dgst,sha_one,sha1_one,sha256,sha512"
 169 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
 170 $ LIB_HMAC = "hmac"
 171 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
 172 $ LIB_DES = "set_key,ecb_enc,cbc_enc,"+ -
 173         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
 174         "enc_read,enc_writ,ofb64enc,"+ -
 175         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
 176         "des_enc,fcrypt_b,"+ -
 177         "fcrypt,xcbc_enc,rpc_enc,cbc_cksm,"+ -
 178         "ede_cbcm_enc,des_old,des_old2,read2pwd"
 179 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
 180 $ LIB_RC4 = "rc4_skey,rc4_enc"
 181 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
 182 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
 183 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
 184 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
 185 $ LIB_CAMELLIA = "camellia,cmll_misc,cmll_ecb,cmll_cbc,cmll_ofb,"+ -
 186         "cmll_cfb,cmll_ctr"
 187 $ LIB_SEED = "seed,seed_cbc,seed_ecb,seed_cfb,seed_ofb"
 188 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
 189 $ IF F$TRNLNM("OPENSSL_NO_ASM").OR.ARCH.EQS."AXP" THEN LIB_BN_ASM = "bn_asm"
 190 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,bn_mod,"+ -
 191         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
 192         "bn_kron,bn_sqrt,bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+","+ -
 193         "bn_recp,bn_mont,bn_mpi,bn_exp2,bn_gf2m,bn_nist,"+ -
 194         "bn_depr,bn_const"
 195 $ LIB_EC = "ec_lib,ecp_smpl,ecp_mont,ecp_nist,ec_cvt,ec_mult,"+ -
 196         "ec_err,ec_curve,ec_check,ec_print,ec_asn1,ec_key,"+ -
 197         "ec2_smpl,ec2_mult"
 198 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
 199         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null,"+ -
 200         "rsa_pss,rsa_x931,rsa_x931g,rsa_asn1,rsa_depr,rsa_eng"
 201 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,"+ -
 202         "dsa_err,dsa_ossl,dsa_depr,dsa_utl"
 203 $ LIB_ECDSA = "ecs_lib,ecs_asn1,ecs_ossl,ecs_sign,ecs_vrf,ecs_err"
 204 $ LIB_DH = "dh_asn1,dh_gen,dh_key,dh_lib,dh_check,dh_err,dh_depr"
 205 $ LIB_ECDH = "ech_lib,ech_ossl,ech_key,ech_err"
 206 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
 207         "dso_openssl,dso_win32,dso_vms"
 208 $ LIB_ENGINE = "eng_err,eng_lib,eng_list,eng_init,eng_ctrl,"+ -
 209         "eng_table,eng_pkey,eng_fat,eng_all,"+ -
 210         "tb_rsa,tb_dsa,tb_ecdsa,tb_dh,tb_ecdh,tb_rand,tb_store,"+ -
 211         "tb_cipher,tb_digest,"+ -
 212         "eng_openssl,eng_dyn,eng_cnf,eng_cryptodev,eng_padlock"
 213 $ LIB_AES = "aes_core,aes_misc,aes_ecb,aes_cbc,aes_cfb,aes_ofb,"+ -
 214         "aes_ctr,aes_ige"
 215 $ LIB_BUFFER = "buffer,buf_str,buf_err"
 216 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
 217         "bss_mem,bss_null,bss_fd,"+ -
 218         "bss_file,bss_sock,bss_conn,"+ -
 219         "bf_null,bf_buff,b_print,b_dump,"+ -
 220         "b_sock,bss_acpt,bf_nbio,bss_rtcp,bss_bio,bss_log,"+ -
 221         "bss_dgram,"+ -
 222         "bf_lbuf"
 223 $ LIB_STACK = "stack"
 224 $ LIB_LHASH = "lhash,lh_stats"
 225 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,"+ -
 226         "rand_vms"
 227 $ LIB_ERR = "err,err_def,err_all,err_prn,err_str,err_bio"
 228 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err"
 229 $ LIB_EVP = "encode,digest,dig_eng,evp_enc,evp_key,evp_acnf,evp_cnf,"+ -
 230         "e_des,e_bf,e_idea,e_des3,e_camellia,"+ -
 231         "e_rc4,e_aes,names,e_seed,"+ -
 232         "e_xcbc_d,e_rc2,e_cast,e_rc5,enc_min"
 233 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha,m_sha1," + -
 234         "m_dss,m_dss1,m_mdc2,m_ripemd,m_ecdsa,"+ -
 235         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
 236         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
 237         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
 238         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
 239 $ LIB_EVP_3 = "e_old"
 240 $ LIB_ASN1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
 241         "a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,"+ -
 242         "a_enum,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
 243         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,x_bignum,"+ -
 244         "x_long,x_name,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
 245         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
 246 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
 247         "tasn_new,tasn_fre,tasn_enc,tasn_dec,tasn_utl,tasn_typ,"+ -
 248         "f_int,f_string,n_pkey,"+ -
 249         "f_enum,a_hdr,x_pkey,a_bool,x_exten,"+ -
 250         "asn1_gen,asn1_par,asn1_lib,asn1_err,a_meth,a_bytes,a_strnid,"+ -
 251         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey,asn_moid"
 252 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err,"+ -
 253         "pem_x509,pem_xaux,pem_oth,pem_pk8,pem_pkey"
 254 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
 255         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
 256         "x509_set,x509cset,x509rset,x509_err,"+ -
 257         "x509name,x509_v3,x509_ext,x509_att,"+ -
 258         "x509type,x509_lu,x_all,x509_txt,"+ -
 259         "x509_trs,by_file,by_dir,x509_vpm"
 260 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
 261         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
 262         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info,"+ -
 263         "v3_ocsp,v3_akeya,v3_pmaps,v3_pcons,v3_ncons,v3_pcia,v3_pci,"+ -
 264         "pcy_cache,pcy_node,pcy_data,pcy_map,pcy_tree,pcy_lib,"+ -
 265         "v3_asid,v3_addr"
 266 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def,conf_mod,conf_mall,conf_sap"
 267 $ LIB_TXT_DB = "txt_db"
 268 $ LIB_PKCS7 = "pk7_asn1,pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,"+ -
 269         "pk7_mime"
 270 $ LIB_PKCS12 = "p12_add,p12_asn,p12_attr,p12_crpt,p12_crt,p12_decr,"+ -
 271         "p12_init,p12_key,p12_kiss,p12_mutl,"+ -
 272         "p12_utl,p12_npas,pk12err,p12_p8d,p12_p8e"
 273 $ LIB_COMP = "comp_lib,comp_err,"+ -
 274         "c_rle,c_zlib"
 275 $ LIB_OCSP = "ocsp_asn,ocsp_ext,ocsp_ht,ocsp_lib,ocsp_cl,"+ -
 276         "ocsp_srv,ocsp_prn,ocsp_vfy,ocsp_err"
 277 $ LIB_UI_COMPAT = ",ui_compat"
 278 $ LIB_UI = "ui_err,ui_lib,ui_openssl,ui_util"+LIB_UI_COMPAT
 279 $ LIB_KRB5 = "krb5_asn"
 280 $ LIB_STORE = "str_err,str_lib,str_meth,str_mem"
 281 $ LIB_CMS = "cms_lib,cms_asn1,cms_att,cms_io,cms_smime,cms_err,"+ -
 282         "cms_sd,cms_dd,cms_cd,cms_env,cms_enc,cms_ess"
 283 $ LIB_PQUEUE = "pqueue"
 284 $ LIB_JPAKE = "jpake,jpake_err"
 285 $!
 286 $! Setup exceptional compilations
 287 $!
 288 $ ! Add definitions for no threads on OpenVMS 7.1 and higher
 289 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 290 $ ! Disable the DOLLARID warning
 291 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,o_time,o_dir"
 292 $ ! Disable disjoint optimization
 293 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 294                     "sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 295 $ ! Disable the MIXLINKAGE warning
 296 $ COMPILEWITH_CC6 = ",enc_read,set_key,"
 297 $!
 298 $! Figure Out What Other Modules We Are To Build.
 299 $!
 300 $ BUILD_SET:
 301 $!
 302 $! Define A Module Counter.
 303 $!
 304 $ MODULE_COUNTER = 0
 305 $!
 306 $! Top Of The Loop.
 307 $!
 308 $ MODULE_NEXT:
 309 $!
 310 $! Extract The Module Name From The Encryption List.
 311 $!
 312 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 313 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 314 $ MODULE_NAME1 = MODULE_NAME
 315 $!
 316 $! Check To See If We Are At The End Of The Module List.
 317 $!
 318 $ IF (MODULE_NAME.EQS.",")
 319 $ THEN
 320 $!
 321 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 322 $!
 323 $   GOTO MODULE_DONE
 324 $!
 325 $! End The Module List Check.
 326 $!
 327 $ ENDIF
 328 $!
 329 $! Increment The Moudle Counter.
 330 $!
 331 $ MODULE_COUNTER = MODULE_COUNTER + 1
 332 $!
 333 $! Create The Library and Apps Module Names.
 334 $!
 335 $ LIB_MODULE = "LIB_" + MODULE_NAME
 336 $ APPS_MODULE = "APPS_" + MODULE_NAME
 337 $ IF (MODULE_NAME.EQS."ASN1_2")
 338 $ THEN
 339 $   MODULE_NAME = "ASN1"
 340 $ ENDIF
 341 $ IF (MODULE_NAME.EQS."EVP_2")
 342 $ THEN
 343 $   MODULE_NAME = "EVP"
 344 $ ENDIF
 345 $!
 346 $! Set state (can be LIB and APPS)
 347 $!
 348 $ STATE = "LIB"
 349 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
 350 $!
 351 $! Check if the library module name actually is defined
 352 $!
 353 $ IF F$TYPE('LIB_MODULE') .EQS. ""
 354 $ THEN
 355 $   WRITE SYS$ERROR ""
 356 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
 357 $   WRITE SYS$ERROR ""
 358 $   GOTO MODULE_NEXT
 359 $ ENDIF
 360 $!
 361 $! Top Of The Module Loop.
 362 $!
 363 $ MODULE_AGAIN:
 364 $!
 365 $! Tell The User What Module We Are Building.
 366 $!
 367 $ IF (MODULE_NAME1.NES."")
 368 $ THEN
 369 $   IF STATE .EQS. "LIB"
 370 $   THEN
 371 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
 372 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
 373 $     THEN
 374 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
 375 $     ENDIF
 376 $   ENDIF
 377 $ ENDIF
 378 $!
 379 $!  Define A File Counter And Set It To "0".
 380 $!
 381 $ FILE_COUNTER = 0
 382 $ APPLICATION = ""
 383 $ APPLICATION_COUNTER = 0
 384 $!
 385 $! Top Of The File Loop.
 386 $!
 387 $ NEXT_FILE:
 388 $!
 389 $! Look in the LIB_MODULE is we're in state LIB
 390 $!
 391 $ IF STATE .EQS. "LIB"
 392 $ THEN
 393 $!
 394 $!   O.K, Extract The File Name From The File List.
 395 $!
 396 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 397 $!
 398 $!   else
 399 $!
 400 $ ELSE
 401 $   FILE_NAME = ","
 402 $!
 403 $   IF F$TYPE('APPS_MODULE') .NES. ""
 404 $   THEN
 405 $!
 406 $!     Extract The File Name From The File List.
 407 $!     This part is a bit more complicated.
 408 $!
 409 $     IF APPLICATION .EQS. ""
 410 $     THEN
 411 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 412 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 413 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 414 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 415 $       FILE_COUNTER = 0
 416 $     ENDIF
 417 $
 418 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 419 $!     SHOW SYMBOL APPLICATION*
 420 $!
 421 $     IF APPLICATION .NES. ";"
 422 $     THEN
 423 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
 424 $       IF FILE_NAME .EQS. ","
 425 $       THEN
 426 $         APPLICATION = ""
 427 $         GOTO NEXT_FILE
 428 $       ENDIF
 429 $     ENDIF
 430 $   ENDIF
 431 $ ENDIF
 432 $!
 433 $! Check To See If We Are At The End Of The File List.
 434 $!
 435 $ IF (FILE_NAME.EQS.",")
 436 $ THEN
 437 $!
 438 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
 439 $!
 440 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
 441 $   THEN
 442 $     STATE = "APPS"
 443 $     GOTO MODULE_AGAIN
 444 $   ELSE
 445 $     GOTO FILE_DONE
 446 $   ENDIF
 447 $!
 448 $! End The File List Check.
 449 $!
 450 $ ENDIF
 451 $!
 452 $! Increment The Counter.
 453 $!
 454 $ FILE_COUNTER = FILE_COUNTER + 1
 455 $!
 456 $! Create The Source File Name.
 457 $!
 458 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 459 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 460 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 461         FILE_NAME = FILE_NAME + ".c"
 462 $ IF (MODULE_NAME.NES."")
 463 $ THEN
 464 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 465 $ ELSE
 466 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 467 $ ENDIF
 468 $ SOURCE_FILE = SOURCE_FILE - "]["
 469 $!
 470 $! Create The Object File Name.
 471 $!
 472 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 473 $ ON WARNING THEN GOTO NEXT_FILE
 474 $!
 475 $! Check To See If The File We Want To Compile Is Actually There.
 476 $!
 477 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 478 $ THEN
 479 $!
 480 $!  Tell The User That The File Doesn't Exist.
 481 $!
 482 $   WRITE SYS$OUTPUT ""
 483 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 484 $   WRITE SYS$OUTPUT ""
 485 $!
 486 $!  Exit The Build.
 487 $!
 488 $   GOTO EXIT
 489 $!
 490 $! End The File Exist Check.
 491 $!
 492 $ ENDIF
 493 $!
 494 $! Tell The User We Are Compiling The File.
 495 $!
 496 $ IF (MODULE_NAME.EQS."")
 497 $ THEN
 498 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
 499 $ ENDIF
 500 $ IF (MODULE_NAME.NES."")
 501 $ THEN
 502 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
 503 $ ENDIF
 504 $!
 505 $! Compile The File.
 506 $!
 507 $ ON ERROR THEN GOTO NEXT_FILE
 508 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
 509 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 510 $ THEN
 511 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 512 $ ELSE
 513 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 514 $   THEN
 515 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 516 $   ELSE
 517 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 518 $     THEN
 519 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 520 $     ELSE
 521 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
 522 $       THEN
 523 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 524 $       ELSE
 525 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 526 $         THEN
 527 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 528 $         ELSE
 529 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 530 $         ENDIF
 531 $       ENDIF
 532 $     ENDIF
 533 $   ENDIF
 534 $ ENDIF
 535 $ IF STATE .EQS. "LIB"
 536 $ THEN
 537 $!
 538 $!   Add It To The Library.
 539 $!
 540 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 541 $!
 542 $!   Time To Clean Up The Object File.
 543 $!
 544 $   DELETE 'OBJECT_FILE';*
 545 $ ENDIF
 546 $!
 547 $! Go Back And Do It Again.
 548 $!
 549 $ GOTO NEXT_FILE
 550 $!
 551 $! All Done With This Library Part.
 552 $!
 553 $ FILE_DONE:
 554 $!
 555 $! Time To Build Some Applications
 556 $!
 557 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
 558 $ THEN
 559 $   APPLICATION_COUNTER = 0
 560 $ NEXT_APPLICATION:
 561 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 562 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
 563 $
 564 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 565 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 566 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 567 $
 568 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 569 $!   SHOW SYMBOL APPLICATION*
 570 $!
 571 $! Tell the user what happens
 572 $!
 573 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
 574 $!
 575 $! Link The Program.
 576 $!
 577 $   ON ERROR THEN GOTO NEXT_APPLICATION
 578 $!
 579 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 580 $!
 581 $   IF (TCPIP_LIB.NES."")
 582 $   THEN
 583 $!
 584 $!    Link With A TCP/IP Library.
 585 $!
 586 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 587           'OBJ_DIR''APPLICATION_OBJECTS', -
 588           'CRYPTO_LIB'/LIBRARY, -
 589           'TCPIP_LIB','OPT_FILE'/OPTION
 590 $!
 591 $! Else...
 592 $!
 593 $   ELSE
 594 $!
 595 $!    Don't Link With A TCP/IP Library.
 596 $!
 597 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 598           'OBJ_DIR''APPLICATION_OBJECTS',-
 599           'CRYPTO_LIB'/LIBRARY, -
 600           'OPT_FILE'/OPTION
 601 $!
 602 $! End The TCP/IP Library Check.
 603 $!
 604 $   ENDIF
 605 $   GOTO NEXT_APPLICATION
 606 $  APPLICATION_DONE:
 607 $ ENDIF
 608 $!
 609 $! Go Back And Get The Next Module.
 610 $!
 611 $ GOTO MODULE_NEXT
 612 $!
 613 $! All Done With This Module.
 614 $!
 615 $ MODULE_DONE:
 616 $!
 617 $! Tell The User That We Are All Done.
 618 $!
 619 $ WRITE SYS$OUTPUT "All Done..."
 620 $ EXIT:
 621 $ GOSUB CLEANUP
 622 $ EXIT
 623 $!
 624 $! Check For The Link Option FIle.
 625 $!
 626 $ CHECK_OPT_FILE:
 627 $!
 628 $! Check To See If We Need To Make A VAX C Option File.
 629 $!
 630 $ IF (COMPILER.EQS."VAXC")
 631 $ THEN
 632 $!
 633 $!  Check To See If We Already Have A VAX C Linker Option File.
 634 $!
 635 $   IF (F$SEARCH(OPT_FILE).EQS."")
 636 $   THEN
 637 $!
 638 $!    We Need A VAX C Linker Option File.
 639 $!
 640 $     CREATE 'OPT_FILE'
 641 $DECK
 642 !
 643 ! Default System Options File To Link Agianst
 644 ! The Sharable VAX C Runtime Library.
 645 !
 646 SYS$SHARE:VAXCRTL.EXE/SHARE
 647 $EOD
 648 $!
 649 $!  End The Option File Check.
 650 $!
 651 $   ENDIF
 652 $!
 653 $! End The VAXC Check.
 654 $!
 655 $ ENDIF
 656 $!
 657 $! Check To See If We Need A GNU C Option File.
 658 $!
 659 $ IF (COMPILER.EQS."GNUC")
 660 $ THEN
 661 $!
 662 $!  Check To See If We Already Have A GNU C Linker Option File.
 663 $!
 664 $   IF (F$SEARCH(OPT_FILE).EQS."")
 665 $   THEN
 666 $!
 667 $!    We Need A GNU C Linker Option File.
 668 $!
 669 $     CREATE 'OPT_FILE'
 670 $DECK
 671 !
 672 ! Default System Options File To Link Agianst
 673 ! The Sharable C Runtime Library.
 674 !
 675 GNU_CC:[000000]GCCLIB/LIBRARY
 676 SYS$SHARE:VAXCRTL/SHARE
 677 $EOD
 678 $!
 679 $!  End The Option File Check.
 680 $!
 681 $   ENDIF
 682 $!
 683 $! End The GNU C Check.
 684 $!
 685 $ ENDIF
 686 $!
 687 $! Check To See If We Need A DEC C Option File.
 688 $!
 689 $ IF (COMPILER.EQS."DECC")
 690 $ THEN
 691 $!
 692 $!  Check To See If We Already Have A DEC C Linker Option File.
 693 $!
 694 $   IF (F$SEARCH(OPT_FILE).EQS."")
 695 $   THEN
 696 $!
 697 $!    Figure Out If We Need An AXP Or A VAX Linker Option File.
 698 $!
 699 $     IF ARCH .EQS. "VAX"
 700 $     THEN
 701 $!
 702 $!      We Need A DEC C Linker Option File For VAX.
 703 $!
 704 $       CREATE 'OPT_FILE'
 705 $DECK
 706 !
 707 ! Default System Options File To Link Agianst
 708 ! The Sharable DEC C Runtime Library.
 709 !
 710 SYS$SHARE:DECC$SHR.EXE/SHARE
 711 $EOD
 712 $!
 713 $!    Else...
 714 $!
 715 $     ELSE
 716 $!
 717 $!      Create The AXP Linker Option File.
 718 $!
 719 $       CREATE 'OPT_FILE'
 720 $DECK
 721 !
 722 ! Default System Options File For AXP To Link Agianst
 723 ! The Sharable C Runtime Library.
 724 !
 725 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 726 SYS$SHARE:CMA$OPEN_RTL/SHARE
 727 $EOD
 728 $!
 729 $!    End The VAX/AXP DEC C Option File Check.
 730 $!
 731 $     ENDIF
 732 $!
 733 $!  End The Option File Search.
 734 $!
 735 $   ENDIF
 736 $!
 737 $! End The DEC C Check.
 738 $!
 739 $ ENDIF
 740 $!
 741 $!  Tell The User What Linker Option File We Are Using.
 742 $!
 743 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 744 $!
 745 $! Time To RETURN.
 746 $!
 747 $ RETURN
 748 $!
 749 $! Check The User's Options.
 750 $!
 751 $ CHECK_OPTIONS:
 752 $!
 753 $! Check To See If P1 Is Blank.
 754 $!
 755 $ IF (P1.EQS."ALL")
 756 $ THEN
 757 $!
 758 $!   P1 Is Blank, So Build Everything.
 759 $!
 760 $    BUILDALL = "TRUE"
 761 $!
 762 $! Else...
 763 $!
 764 $ ELSE
 765 $!
 766 $!  Else, Check To See If P1 Has A Valid Arguement.
 767 $!
 768 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
 769 $   THEN
 770 $!
 771 $!    A Valid Arguement.
 772 $!
 773 $     BUILDALL = P1
 774 $!
 775 $!  Else...
 776 $!
 777 $   ELSE
 778 $!
 779 $!    Tell The User We Don't Know What They Want.
 780 $!
 781 $     WRITE SYS$OUTPUT ""
 782 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 783 $     WRITE SYS$OUTPUT ""
 784 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 785 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 786 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.CRYPTO]*.EXE Programs."
 787 $     WRITE SYS$OUTPUT ""
 788 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 789 $     WRITE SYS$OUTPUT ""
 790 $     WRITE SYS$OUTPUT "        AXP  :  Alpha Architecture."
 791 $     WRITE SYS$OUTPUT "        VAX  :  VAX Architecture."
 792 $     WRITE SYS$OUTPUT ""
 793 $!
 794 $!    Time To EXIT.
 795 $!
 796 $     EXIT
 797 $!
 798 $!  End The Valid Arguement Check.
 799 $!
 800 $   ENDIF
 801 $!
 802 $! End The P1 Check.
 803 $!
 804 $ ENDIF
 805 $!
 806 $! Check To See If P2 Is Blank.
 807 $!
 808 $ IF (P2.EQS."NODEBUG")
 809 $ THEN
 810 $!
 811 $!   P2 Is NODEBUG, So Compile Without The Debugger Information.
 812 $!
 813 $    DEBUGGER = "NODEBUG"
 814 $    TRACEBACK = "NOTRACEBACK"
 815 $    GCC_OPTIMIZE = "OPTIMIZE"
 816 $    CC_OPTIMIZE = "OPTIMIZE"
 817 $    MACRO_OPTIMIZE = "OPTIMIZE"
 818 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 819 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 820 $ ELSE
 821 $!
 822 $!  Check To See If We Are To Compile With Debugger Information.
 823 $!
 824 $   IF (P2.EQS."DEBUG")
 825 $   THEN
 826 $!
 827 $!    Compile With Debugger Information.
 828 $!
 829 $     DEBUGGER = "DEBUG"
 830 $     TRACEBACK = "TRACEBACK"
 831 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 832 $     CC_OPTIMIZE = "NOOPTIMIZE"
 833 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 834 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 835 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 836 $   ELSE
 837 $!
 838 $!    They Entered An Invalid Option..
 839 $!
 840 $     WRITE SYS$OUTPUT ""
 841 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 842 $     WRITE SYS$OUTPUT ""
 843 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 844 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 845 $     WRITE SYS$OUTPUT ""
 846 $!
 847 $!    Time To EXIT.
 848 $!
 849 $     EXIT
 850 $!
 851 $!  End The Valid Arguement Check.
 852 $!
 853 $   ENDIF
 854 $!
 855 $! End The P2 Check.
 856 $!
 857 $ ENDIF
 858 $!
 859 $! Special Threads For OpenVMS v7.1 Or Later
 860 $!
 861 $! Written By:  Richard Levitte
 862 $!              richard@levitte.org
 863 $!
 864 $!
 865 $! Check To See If We Have A Option For P5.
 866 $!
 867 $ IF (P5.EQS."")
 868 $ THEN
 869 $!
 870 $!  Get The Version Of VMS We Are Using.
 871 $!
 872 $   ISSEVEN :=
 873 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 874 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 875 $!
 876 $!  Check To See If The VMS Version Is v7.1 Or Later.
 877 $!
 878 $   IF (TMP.GE.71)
 879 $   THEN
 880 $!
 881 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 882 $!
 883 $     ISSEVEN := ,PTHREAD_USE_D4
 884 $!
 885 $!  End The VMS Version Check.
 886 $!
 887 $   ENDIF
 888 $!
 889 $! End The P5 Check.
 890 $!
 891 $ ENDIF
 892 $!
 893 $! Check To See If P3 Is Blank.
 894 $!
 895 $ IF (P3.EQS."")
 896 $ THEN
 897 $!
 898 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 899 $!  Find Out Which One To Use.
 900 $!
 901 $!  Check To See If We Have GNU C.
 902 $!
 903 $   IF (F$TRNLNM("GNU_CC").NES."")
 904 $   THEN
 905 $!
 906 $!    Looks Like GNUC, Set To Use GNUC.
 907 $!
 908 $     P3 = "GNUC"
 909 $!
 910 $!  Else...
 911 $!
 912 $   ELSE
 913 $!
 914 $!    Check To See If We Have VAXC Or DECC.
 915 $!
 916 $     IF (ARCH.EQS."AXP").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 917 $     THEN
 918 $!
 919 $!      Looks Like DECC, Set To Use DECC.
 920 $!
 921 $       P3 = "DECC"
 922 $!
 923 $!    Else...
 924 $!
 925 $     ELSE
 926 $!
 927 $!      Looks Like VAXC, Set To Use VAXC.
 928 $!
 929 $       P3 = "VAXC"
 930 $!
 931 $!    End The VAXC Compiler Check.
 932 $!
 933 $     ENDIF
 934 $!
 935 $!  End The DECC & VAXC Compiler Check.
 936 $!
 937 $   ENDIF
 938 $!
 939 $!  End The Compiler Check.
 940 $!
 941 $ ENDIF
 942 $!
 943 $! Check To See If We Have A Option For P4.
 944 $!
 945 $ IF (P4.EQS."")
 946 $ THEN
 947 $!
 948 $!  Find out what socket library we have available
 949 $!
 950 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 951 $   THEN
 952 $!
 953 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 954 $!
 955 $     P4 = "SOCKETSHR"
 956 $!
 957 $!    Tell the user
 958 $!
 959 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 960 $!
 961 $!    Else, let's look for something else
 962 $!
 963 $   ELSE
 964 $!
 965 $!    Like UCX (the reason to do this before Multinet is that the UCX
 966 $!    emulation is easier to use...)
 967 $!
 968 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 969          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 970          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 971 $     THEN
 972 $!
 973 $!      Last resort: a UCX or UCX-compatible library
 974 $!
 975 $       P4 = "UCX"
 976 $!
 977 $!      Tell the user
 978 $!
 979 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 980 $!
 981 $!      That was all...
 982 $!
 983 $     ENDIF
 984 $   ENDIF
 985 $ ENDIF
 986 $!
 987 $! Set Up Initial CC Definitions, Possibly With User Ones
 988 $!
 989 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
 990 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 991 $ CCEXTRAFLAGS = ""
 992 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 993 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 994 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
 995         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
 996 $!
 997 $!  Check To See If The User Entered A Valid Paramter.
 998 $!
 999 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
1000 $ THEN
1001 $!
1002 $!    Check To See If The User Wanted DECC.
1003 $!
1004 $   IF (P3.EQS."DECC")
1005 $   THEN
1006 $!
1007 $!    Looks Like DECC, Set To Use DECC.
1008 $!
1009 $     COMPILER = "DECC"
1010 $!
1011 $!    Tell The User We Are Using DECC.
1012 $!
1013 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1014 $!
1015 $!    Use DECC...
1016 $!
1017 $     CC = "CC"
1018 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1019          THEN CC = "CC/DECC"
1020 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
1021            "/NOLIST/PREFIX=ALL" + -
1022            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS],SYS$DISK:[.EVP])" + -
1023            CCEXTRAFLAGS
1024 $!
1025 $!    Define The Linker Options File Name.
1026 $!
1027 $     OPT_FILE = "SYS$DISK:[]VAX_DECC_OPTIONS.OPT"
1028 $!
1029 $!  End DECC Check.
1030 $!
1031 $   ENDIF
1032 $!
1033 $!  Check To See If We Are To Use VAXC.
1034 $!
1035 $   IF (P3.EQS."VAXC")
1036 $   THEN
1037 $!
1038 $!    Looks Like VAXC, Set To Use VAXC.
1039 $!
1040 $     COMPILER = "VAXC"
1041 $!
1042 $!    Tell The User We Are Using VAX C.
1043 $!
1044 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1045 $!
1046 $!    Compile Using VAXC.
1047 $!
1048 $     CC = "CC"
1049 $     IF ARCH.EQS."AXP"
1050 $     THEN
1051 $       WRITE SYS$OUTPUT "There is no VAX C on Alpha!"
1052 $       EXIT
1053 $     ENDIF
1054 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1055 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1056            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1057            CCEXTRAFLAGS
1058 $     CCDEFS = """VAXC""," + CCDEFS
1059 $!
1060 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1061 $!
1062 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1063 $!
1064 $!    Define The Linker Options File Name.
1065 $!
1066 $     OPT_FILE = "SYS$DISK:[]VAX_VAXC_OPTIONS.OPT"
1067 $!
1068 $!  End VAXC Check
1069 $!
1070 $   ENDIF
1071 $!
1072 $!  Check To See If We Are To Use GNU C.
1073 $!
1074 $   IF (P3.EQS."GNUC")
1075 $   THEN
1076 $!
1077 $!    Looks Like GNUC, Set To Use GNUC.
1078 $!
1079 $     COMPILER = "GNUC"
1080 $!
1081 $!    Tell The User We Are Using GNUC.
1082 $!
1083 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1084 $!
1085 $!    Use GNU C...
1086 $!
1087 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1088            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1089            CCEXTRAFLAGS
1090 $!
1091 $!    Define The Linker Options File Name.
1092 $!
1093 $     OPT_FILE = "SYS$DISK:[]VAX_GNUC_OPTIONS.OPT"
1094 $!
1095 $!  End The GNU C Check.
1096 $!
1097 $   ENDIF
1098 $!
1099 $!  Set up default defines
1100 $!
1101 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1102 $!
1103 $!  Finish up the definition of CC.
1104 $!
1105 $   IF COMPILER .EQS. "DECC"
1106 $   THEN
1107 $     IF CCDISABLEWARNINGS .EQS. ""
1108 $     THEN
1109 $       CC4DISABLEWARNINGS = "DOLLARID"
1110 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
1111 $     ELSE
1112 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1113 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
1114 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1115 $     ENDIF
1116 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1117 $     CC6DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
1118 $   ELSE
1119 $     CCDISABLEWARNINGS = ""
1120 $     CC4DISABLEWARNINGS = ""
1121 $     CC6DISABLEWARNINGS = ""
1122 $   ENDIF
1123 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1124 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1125 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1126 $   THEN
1127 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1128 $   ELSE
1129 $     CC5 = CC + "/NOOPTIMIZE"
1130 $   ENDIF
1131 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1132 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1133 $!
1134 $!  Show user the result
1135 $!
1136 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1137 $!
1138 $!  Else The User Entered An Invalid Arguement.
1139 $!
1140 $ ELSE
1141 $!
1142 $!  Tell The User We Don't Know What They Want.
1143 $!
1144 $   WRITE SYS$OUTPUT ""
1145 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1146 $   WRITE SYS$OUTPUT ""
1147 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1148 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1149 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1150 $   WRITE SYS$OUTPUT ""
1151 $!
1152 $!  Time To EXIT.
1153 $!
1154 $   EXIT
1155 $!
1156 $! End The Valid Arguement Check.
1157 $!
1158 $ ENDIF
1159 $!
1160 $! Build a MACRO command for the architecture at hand
1161 $!
1162 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1163 $ IF ARCH .EQS. "AXP" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1164 $!
1165 $!  Show user the result
1166 $!
1167 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1168 $!
1169 $! Time to check the contents, and to make sure we get the correct library.
1170 $!
1171 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1172      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1173 $ THEN
1174 $!
1175 $!  Check to see if SOCKETSHR was chosen
1176 $!
1177 $   IF P4.EQS."SOCKETSHR"
1178 $   THEN
1179 $!
1180 $!    Set the library to use SOCKETSHR
1181 $!
1182 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1183 $!
1184 $!    Done with SOCKETSHR
1185 $!
1186 $   ENDIF
1187 $!
1188 $!  Check to see if MULTINET was chosen
1189 $!
1190 $   IF P4.EQS."MULTINET"
1191 $   THEN
1192 $!
1193 $!    Set the library to use UCX emulation.
1194 $!
1195 $     P4 = "UCX"
1196 $!
1197 $!    Done with MULTINET
1198 $!
1199 $   ENDIF
1200 $!
1201 $!  Check to see if UCX was chosen
1202 $!
1203 $   IF P4.EQS."UCX"
1204 $   THEN
1205 $!
1206 $!    Set the library to use UCX.
1207 $!
1208 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1209 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1210 $     THEN
1211 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1212 $     ELSE
1213 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1214           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1215 $     ENDIF
1216 $!
1217 $!    Done with UCX
1218 $!
1219 $   ENDIF
1220 $!
1221 $!  Check to see if TCPIP was chosen
1222 $!
1223 $   IF P4.EQS."TCPIP"
1224 $   THEN
1225 $!
1226 $!    Set the library to use TCPIP (post UCX).
1227 $!
1228 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1229 $!
1230 $!    Done with TCPIP
1231 $!
1232 $   ENDIF
1233 $!
1234 $!  Check to see if NONE was chosen
1235 $!
1236 $   IF P4.EQS."NONE"
1237 $   THEN
1238 $!
1239 $!    Do not use a TCPIP library.
1240 $!
1241 $     TCPIP_LIB = ""
1242 $!
1243 $!    Done with TCPIP
1244 $!
1245 $   ENDIF
1246 $!
1247 $!  Print info
1248 $!
1249 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1250 $!
1251 $!  Else The User Entered An Invalid Arguement.
1252 $!
1253 $ ELSE
1254 $!
1255 $!  Tell The User We Don't Know What They Want.
1256 $!
1257 $   WRITE SYS$OUTPUT ""
1258 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1259 $   WRITE SYS$OUTPUT ""
1260 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1261 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1262 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1263 $   WRITE SYS$OUTPUT ""
1264 $!
1265 $!  Time To EXIT.
1266 $!
1267 $   EXIT
1268 $!
1269 $!  Done with TCP/IP libraries
1270 $!
1271 $ ENDIF
1272 $!
1273 $! Check if the user wanted to compile just a subset of all the encryption
1274 $! methods.
1275 $!
1276 $ IF P6 .NES. ""
1277 $ THEN
1278 $   ENCRYPT_TYPES = P6
1279 $ ENDIF
1280 $!
1281 $!  Time To RETURN...
1282 $!
1283 $ RETURN
1284 $!
1285 $ INITIALISE:
1286 $!
1287 $! Save old value of the logical name OPENSSL
1288 $!
1289 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1290 $!
1291 $! Save directory information
1292 $!
1293 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1294 $ __HERE = F$EDIT(__HERE,"UPCASE")
1295 $ __TOP = __HERE - "CRYPTO]"
1296 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1297 $!
1298 $! Set up the logical name OPENSSL to point at the include directory
1299 $!
1300 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1301 $!
1302 $! Done
1303 $!
1304 $ RETURN
1305 $!
1306 $ CLEANUP:
1307 $!
1308 $! Restore the logical name OPENSSL if it had a value
1309 $!
1310 $ IF __SAVE_OPENSSL .EQS. ""
1311 $ THEN
1312 $   DEASSIGN OPENSSL
1313 $ ELSE
1314 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1315 $ ENDIF
1316 $!
1317 $! Done
1318 $!
1319 $ RETURN