crypto/crypto-lib.com

   1 $!
   2 $!  CRYPTO-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!             Zoltan Arpadffy <arpadffy@polarhome.com>
  10 $!
  11 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  12 $!  library for OpenSSL.  The "xxx" denotes the machine architecture, ALPHA,
  13 $!  IA64 or VAX.
  14 $!
  15 $!  It was re-written so it would try to determine what "C" compiler to use
  16 $!  or you can specify which "C" compiler to use.
  17 $!
  18 $!  Specify the following as P1 to build just that part or ALL to just
  19 $!  build everything.
  20 $!
  21 $!      LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  22 $!      APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
  23 $!      ALL        To do both LIBRARY and APPS
  24 $!
  25 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  26 $!  information.
  27 $!
  28 $!  Specify which compiler at P3 to try to compile under.
  29 $!
  30 $!      VAXC       For VAX C.
  31 $!      DECC       For DEC C.
  32 $!      GNUC       For GNU C.
  33 $!
  34 $!  If you don't specify a compiler, it will try to determine which
  35 $!  "C" compiler to use.
  36 $!
  37 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  38 $!  keywords:
  39 $!
  40 $!      UCX        For UCX
  41 $!      TCPIP      For TCPIP (post UCX)
  42 $!      SOCKETSHR  For SOCKETSHR+NETLIB
  43 $!
  44 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  45 $!
  46 $!  P6, if defined, sets a choice of crypto methods to compile.
  47 $!  WARNING: this should only be done to recompile some part of an already
  48 $!  fully compiled library.
  49 $!
  50 $!
  51 $! Define A TCP/IP Library That We Will Need To Link To.
  52 $! (That Is, If We Need To Link To One.)
  53 $!
  54 $ TCPIP_LIB = ""
  55 $!
  56 $! Check Which Architecture We Are Using.
  57 $!
  58 $ IF (F$GETSYI("CPU").LT.128)
  59 $ THEN
  60 $!
  61 $!  The Architecture Is VAX
  62 $!
  63 $   ARCH := VAX
  64 $!
  65 $! Else...
  66 $!
  67 $ ELSE
  68 $!
  69 $!  The Architecture Is Alpha, IA64 or whatever comes in the future.
  70 $!
  71 $   ARCH = F$EDIT( F$GETSYI( "ARCH_NAME"), "UPCASE")
  72 $   IF (ARCH .EQS. "") THEN ARCH = "UNK"
  73 $!
  74 $! End The Architecture Check.
  75 $!
  76 $ ENDIF
  77 $!
  78 $! Define The Different Encryption Types.
  79 $! NOTE: Some might think this list ugly.  However, it's made this way to
  80 $! reflect the SDIRS variable in [-]Makefile.org as closely as possible,
  81 $! thereby making it fairly easy to verify that the lists are the same.
  82 $!
  83 $ ENCRYPT_TYPES = "Basic,"+ -
  84                   "OBJECTS,"+ -
  85                   "MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ -
  86                   "DES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,"+ -
  87                   "BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,AES,"+ -
  88                   "BUFFER,BIO,STACK,LHASH,RAND,ERR,"+ -
  89                   "EVP,EVP_2,ASN1,ASN1_2,PEM,X509,X509V3,"+ -
  90                   "CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5,"+ -
  91                   "STORE,CMS,PQUEUE,JPAKE"
  92 $! Define The OBJ Directory.
  93 $!
  94 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
  95 $!
  96 $! Define The EXE Directory.
  97 $!
  98 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
  99 $!
 100 $! Check To Make Sure We Have Valid Command Line Parameters.
 101 $!
 102 $ GOSUB CHECK_OPTIONS
 103 $!
 104 $! Initialise logical names and such
 105 $!
 106 $ GOSUB INITIALISE
 107 $!
 108 $! Tell The User What Kind of Machine We Run On.
 109 $!
 110 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
 111 $!
 112 $!
 113 $! Check To See If The Architecture Specific OBJ Directory Exists.
 114 $!
 115 $ IF (F$PARSE(OBJ_DIR).EQS."")
 116 $ THEN
 117 $!
 118 $!  It Dosen't Exist, So Create It.
 119 $!
 120 $   CREATE/DIR 'OBJ_DIR'
 121 $!
 122 $! End The Architecture Specific OBJ Directory Check.
 123 $!
 124 $ ENDIF
 125 $!
 126 $! Check To See If The Architecture Specific Directory Exists.
 127 $!
 128 $ IF (F$PARSE(EXE_DIR).EQS."")
 129 $ THEN
 130 $!
 131 $!  It Dosen't Exist, So Create It.
 132 $!
 133 $   CREATE/DIRECTORY 'EXE_DIR'
 134 $!
 135 $! End The Architecture Specific Directory Check.
 136 $!
 137 $ ENDIF
 138 $!
 139 $! Define The Library Name.
 140 $!
 141 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
 142 $!
 143 $! Define The CRYPTO-LIB We Are To Use.
 144 $!
 145 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
 146 $!
 147 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 148 $!
 149 $ IF (F$SEARCH(LIB_NAME).EQS."")
 150 $ THEN
 151 $!
 152 $! Guess Not, Create The Library.
 153 $!
 154 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 155 $!
 156 $! End The Library Check.
 157 $!
 158 $ ENDIF
 159 $!
 160 $! Build our options file for the application
 161 $!
 162 $ GOSUB CHECK_OPT_FILE
 163 $!
 164 $! Define The Different Encryption "library" Strings.
 165 $!
 166 $ APPS_DES = "DES/DES,CBC3_ENC"
 167 $ APPS_PKCS7 = "ENC/ENC;DEC/DEC;SIGN/SIGN;VERIFY/VERIFY,EXAMPLE"
 168 $
 169 $ LIB_ = "cryptlib,dyn_lck,mem,mem_clr,mem_dbg,cversion,ex_data,tmdiff,cpt_err,ebcdic,uid,o_time,o_str,o_dir,o_init,fips_err"
 170 $ LIB_MD2 = "md2_dgst,md2_one"
 171 $ LIB_MD4 = "md4_dgst,md4_one"
 172 $ LIB_MD5 = "md5_dgst,md5_one"
 173 $ LIB_SHA = "sha_dgst,sha1dgst,sha_one,sha1_one,sha256,sha512"
 174 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
 175 $ LIB_HMAC = "hmac"
 176 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
 177 $ LIB_DES = "des_lib,set_key,ecb_enc,cbc_enc,"+ -
 178         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
 179         "enc_read,enc_writ,ofb64enc,"+ -
 180         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
 181         "des_enc,fcrypt_b,"+ -
 182         "fcrypt,xcbc_enc,rpc_enc,cbc_cksm,"+ -
 183         "ede_cbcm_enc,des_old,des_old2,read2pwd"
 184 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
 185 $ LIB_RC4 = "rc4_skey,rc4_enc"
 186 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
 187 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
 188 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
 189 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
 190 $ LIB_CAMELLIA = "camellia,cmll_misc,cmll_ecb,cmll_cbc,cmll_ofb,"+ -
 191         "cmll_cfb,cmll_ctr"
 192 $ LIB_SEED = "seed,seed_cbc,seed_ecb,seed_cfb,seed_ofb"
 193 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
 194 $ IF F$TRNLNM("OPENSSL_NO_ASM") THEN LIB_BN_ASM = "bn_asm"
 195 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,bn_mod,"+ -
 196         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
 197         "bn_kron,bn_sqrt,bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+","+ -
 198         "bn_recp,bn_mont,bn_mpi,bn_exp2,bn_gf2m,bn_nist,"+ -
 199         "bn_depr,bn_x931p,bn_const,bn_opt"
 200 $ LIB_EC = "ec_lib,ecp_smpl,ecp_mont,ecp_nist,ec_cvt,ec_mult,"+ -
 201         "ec_err,ec_curve,ec_check,ec_print,ec_asn1,ec_key,"+ -
 202         "ec2_smpl,ec2_mult"
 203 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
 204         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null,"+ -
 205         "rsa_pss,rsa_x931,rsa_x931g,rsa_asn1,rsa_depr,rsa_eng"
 206 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,"+ -
 207         "dsa_err,dsa_ossl,dsa_depr,dsa_utl"
 208 $ LIB_ECDSA = "ecs_lib,ecs_asn1,ecs_ossl,ecs_sign,ecs_vrf,ecs_err"
 209 $ LIB_DH = "dh_asn1,dh_gen,dh_key,dh_lib,dh_check,dh_err,dh_depr"
 210 $ LIB_ECDH = "ech_lib,ech_ossl,ech_key,ech_err"
 211 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
 212         "dso_openssl,dso_win32,dso_vms"
 213 $ LIB_ENGINE = "eng_err,eng_lib,eng_list,eng_init,eng_ctrl,"+ -
 214         "eng_table,eng_pkey,eng_fat,eng_all,"+ -
 215         "tb_rsa,tb_dsa,tb_ecdsa,tb_dh,tb_ecdh,tb_rand,tb_store,"+ -
 216         "tb_cipher,tb_digest,"+ -
 217         "eng_openssl,eng_dyn,eng_cnf,eng_cryptodev,eng_padlock"
 218 $ LIB_AES = "aes_core,aes_misc,aes_ecb,aes_cbc,aes_cfb,aes_ofb,"+ -
 219         "aes_ctr,aes_ige,aes_wrap"
 220 $ LIB_BUFFER = "buffer,buf_str,buf_err"
 221 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
 222         "bss_mem,bss_null,bss_fd,"+ -
 223         "bss_file,bss_sock,bss_conn,"+ -
 224         "bf_null,bf_buff,b_print,b_dump,"+ -
 225         "b_sock,bss_acpt,bf_nbio,bss_rtcp,bss_bio,bss_log,"+ -
 226         "bss_dgram,"+ -
 227         "bf_lbuf"
 228 $ LIB_STACK = "stack"
 229 $ LIB_LHASH = "lhash,lh_stats"
 230 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,"+ -
 231         "rand_vms"
 232 $ LIB_ERR = "err,err_def,err_all,err_prn,err_str,err_bio"
 233 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err"
 234 $ LIB_EVP = "encode,digest,dig_eng,evp_enc,evp_key,evp_acnf,evp_cnf,"+ -
 235         "e_des,e_bf,e_idea,e_des3,e_camellia,"+ -
 236         "e_rc4,e_aes,names,e_seed,"+ -
 237         "e_xcbc_d,e_rc2,e_cast,e_rc5,enc_min"
 238 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha,m_sha1," + -
 239         "m_dss,m_dss1,m_mdc2,m_ripemd,m_ecdsa,"+ -
 240         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
 241         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
 242         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
 243         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
 244 $ LIB_EVP_3 = "e_old"
 245 $ LIB_ASN1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
 246         "a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,"+ -
 247         "a_enum,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
 248         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,x_bignum,"+ -
 249         "x_long,x_name,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
 250         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
 251 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
 252         "tasn_new,tasn_fre,tasn_enc,tasn_dec,tasn_utl,tasn_typ,"+ -
 253         "f_int,f_string,n_pkey,"+ -
 254         "f_enum,a_hdr,x_pkey,a_bool,x_exten,asn_mime,"+ -
 255         "asn1_gen,asn1_par,asn1_lib,asn1_err,a_meth,a_bytes,a_strnid,"+ -
 256         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey,asn_moid"
 257 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err,"+ -
 258         "pem_x509,pem_xaux,pem_oth,pem_pk8,pem_pkey"
 259 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
 260         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
 261         "x509_set,x509cset,x509rset,x509_err,"+ -
 262         "x509name,x509_v3,x509_ext,x509_att,"+ -
 263         "x509type,x509_lu,x_all,x509_txt,"+ -
 264         "x509_trs,by_file,by_dir,x509_vpm"
 265 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
 266         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
 267         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info,"+ -
 268         "v3_ocsp,v3_akeya,v3_pmaps,v3_pcons,v3_ncons,v3_pcia,v3_pci,"+ -
 269         "pcy_cache,pcy_node,pcy_data,pcy_map,pcy_tree,pcy_lib,"+ -
 270         "v3_asid,v3_addr"
 271 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def,conf_mod,conf_mall,conf_sap"
 272 $ LIB_TXT_DB = "txt_db"
 273 $ LIB_PKCS7 = "pk7_asn1,pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,"+ -
 274         "pk7_mime"
 275 $ LIB_PKCS12 = "p12_add,p12_asn,p12_attr,p12_crpt,p12_crt,p12_decr,"+ -
 276         "p12_init,p12_key,p12_kiss,p12_mutl,"+ -
 277         "p12_utl,p12_npas,pk12err,p12_p8d,p12_p8e"
 278 $ LIB_COMP = "comp_lib,comp_err,"+ -
 279         "c_rle,c_zlib"
 280 $ LIB_OCSP = "ocsp_asn,ocsp_ext,ocsp_ht,ocsp_lib,ocsp_cl,"+ -
 281         "ocsp_srv,ocsp_prn,ocsp_vfy,ocsp_err"
 282 $ LIB_UI_COMPAT = ",ui_compat"
 283 $ LIB_UI = "ui_err,ui_lib,ui_openssl,ui_util"+LIB_UI_COMPAT
 284 $ LIB_KRB5 = "krb5_asn"
 285 $ LIB_STORE = "str_err,str_lib,str_meth,str_mem"
 286 $ LIB_CMS = "cms_lib,cms_asn1,cms_att,cms_io,cms_smime,cms_err,"+ -
 287         "cms_sd,cms_dd,cms_cd,cms_env,cms_enc,cms_ess"
 288 $ LIB_PQUEUE = "pqueue"
 289 $ LIB_JPAKE = "jpake,jpake_err"
 290 $!
 291 $! Setup exceptional compilations
 292 $!
 293 $ ! Add definitions for no threads on OpenVMS 7.1 and higher
 294 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 295 $ ! Disable the DOLLARID warning
 296 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,o_time,o_dir"
 297 $ ! Disable disjoint optimization
 298 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 299                     "seed,sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 300 $ ! Disable the MIXLINKAGE warning
 301 $ COMPILEWITH_CC6 = ",enc_read,set_key,"
 302 $!
 303 $! Figure Out What Other Modules We Are To Build.
 304 $!
 305 $ BUILD_SET:
 306 $!
 307 $! Define A Module Counter.
 308 $!
 309 $ MODULE_COUNTER = 0
 310 $!
 311 $! Top Of The Loop.
 312 $!
 313 $ MODULE_NEXT:
 314 $!
 315 $! Extract The Module Name From The Encryption List.
 316 $!
 317 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 318 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 319 $ MODULE_NAME1 = MODULE_NAME
 320 $!
 321 $! Check To See If We Are At The End Of The Module List.
 322 $!
 323 $ IF (MODULE_NAME.EQS.",")
 324 $ THEN
 325 $!
 326 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 327 $!
 328 $   GOTO MODULE_DONE
 329 $!
 330 $! End The Module List Check.
 331 $!
 332 $ ENDIF
 333 $!
 334 $! Increment The Moudle Counter.
 335 $!
 336 $ MODULE_COUNTER = MODULE_COUNTER + 1
 337 $!
 338 $! Create The Library and Apps Module Names.
 339 $!
 340 $ LIB_MODULE = "LIB_" + MODULE_NAME
 341 $ APPS_MODULE = "APPS_" + MODULE_NAME
 342 $ IF (F$EXTRACT(0,5,MODULE_NAME).EQS."ASN1_")
 343 $ THEN
 344 $   MODULE_NAME = "ASN1"
 345 $ ENDIF
 346 $ IF (F$EXTRACT(0,4,MODULE_NAME).EQS."EVP_")
 347 $ THEN
 348 $   MODULE_NAME = "EVP"
 349 $ ENDIF
 350 $!
 351 $! Set state (can be LIB and APPS)
 352 $!
 353 $ STATE = "LIB"
 354 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
 355 $!
 356 $! Check if the library module name actually is defined
 357 $!
 358 $ IF F$TYPE('LIB_MODULE') .EQS. ""
 359 $ THEN
 360 $   WRITE SYS$ERROR ""
 361 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
 362 $   WRITE SYS$ERROR ""
 363 $   GOTO MODULE_NEXT
 364 $ ENDIF
 365 $!
 366 $! Top Of The Module Loop.
 367 $!
 368 $ MODULE_AGAIN:
 369 $!
 370 $! Tell The User What Module We Are Building.
 371 $!
 372 $ IF (MODULE_NAME1.NES."")
 373 $ THEN
 374 $   IF STATE .EQS. "LIB"
 375 $   THEN
 376 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
 377 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
 378 $     THEN
 379 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
 380 $     ENDIF
 381 $   ENDIF
 382 $ ENDIF
 383 $!
 384 $!  Define A File Counter And Set It To "0".
 385 $!
 386 $ FILE_COUNTER = 0
 387 $ APPLICATION = ""
 388 $ APPLICATION_COUNTER = 0
 389 $!
 390 $! Top Of The File Loop.
 391 $!
 392 $ NEXT_FILE:
 393 $!
 394 $! Look in the LIB_MODULE is we're in state LIB
 395 $!
 396 $ IF STATE .EQS. "LIB"
 397 $ THEN
 398 $!
 399 $!   O.K, Extract The File Name From The File List.
 400 $!
 401 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 402 $!
 403 $!   else
 404 $!
 405 $ ELSE
 406 $   FILE_NAME = ","
 407 $!
 408 $   IF F$TYPE('APPS_MODULE') .NES. ""
 409 $   THEN
 410 $!
 411 $!     Extract The File Name From The File List.
 412 $!     This part is a bit more complicated.
 413 $!
 414 $     IF APPLICATION .EQS. ""
 415 $     THEN
 416 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 417 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 418 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 419 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 420 $       FILE_COUNTER = 0
 421 $     ENDIF
 422 $
 423 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 424 $!     SHOW SYMBOL APPLICATION*
 425 $!
 426 $     IF APPLICATION .NES. ";"
 427 $     THEN
 428 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
 429 $       IF FILE_NAME .EQS. ","
 430 $       THEN
 431 $         APPLICATION = ""
 432 $         GOTO NEXT_FILE
 433 $       ENDIF
 434 $     ENDIF
 435 $   ENDIF
 436 $ ENDIF
 437 $!
 438 $! Check To See If We Are At The End Of The File List.
 439 $!
 440 $ IF (FILE_NAME.EQS.",")
 441 $ THEN
 442 $!
 443 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
 444 $!
 445 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
 446 $   THEN
 447 $     STATE = "APPS"
 448 $     GOTO MODULE_AGAIN
 449 $   ELSE
 450 $     GOTO FILE_DONE
 451 $   ENDIF
 452 $!
 453 $! End The File List Check.
 454 $!
 455 $ ENDIF
 456 $!
 457 $! Increment The Counter.
 458 $!
 459 $ FILE_COUNTER = FILE_COUNTER + 1
 460 $!
 461 $! Create The Source File Name.
 462 $!
 463 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 464 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 465 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 466         FILE_NAME = FILE_NAME + ".c"
 467 $ IF (MODULE_NAME.NES."")
 468 $ THEN
 469 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 470 $ ELSE
 471 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 472 $ ENDIF
 473 $ SOURCE_FILE = SOURCE_FILE - "]["
 474 $!
 475 $! Create The Object File Name.
 476 $!
 477 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 478 $ ON WARNING THEN GOTO NEXT_FILE
 479 $!
 480 $! Check To See If The File We Want To Compile Is Actually There.
 481 $!
 482 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 483 $ THEN
 484 $!
 485 $!  Tell The User That The File Doesn't Exist.
 486 $!
 487 $   WRITE SYS$OUTPUT ""
 488 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 489 $   WRITE SYS$OUTPUT ""
 490 $!
 491 $!  Exit The Build.
 492 $!
 493 $   GOTO EXIT
 494 $!
 495 $! End The File Exist Check.
 496 $!
 497 $ ENDIF
 498 $!
 499 $! Tell The User We Are Compiling The File.
 500 $!
 501 $ IF (MODULE_NAME.EQS."")
 502 $ THEN
 503 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
 504 $ ENDIF
 505 $ IF (MODULE_NAME.NES."")
 506 $ THEN
 507 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
 508 $ ENDIF
 509 $!
 510 $! Compile The File.
 511 $!
 512 $ ON ERROR THEN GOTO NEXT_FILE
 513 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
 514 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 515 $ THEN
 516 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 517 $ ELSE
 518 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 519 $   THEN
 520 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 521 $   ELSE
 522 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 523 $     THEN
 524 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 525 $     ELSE
 526 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
 527 $       THEN
 528 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 529 $       ELSE
 530 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 531 $         THEN
 532 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 533 $         ELSE
 534 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 535 $         ENDIF
 536 $       ENDIF
 537 $     ENDIF
 538 $   ENDIF
 539 $ ENDIF
 540 $ IF STATE .EQS. "LIB"
 541 $ THEN
 542 $!
 543 $!   Add It To The Library.
 544 $!
 545 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 546 $!
 547 $!   Time To Clean Up The Object File.
 548 $!
 549 $   DELETE 'OBJECT_FILE';*
 550 $ ENDIF
 551 $!
 552 $! Go Back And Do It Again.
 553 $!
 554 $ GOTO NEXT_FILE
 555 $!
 556 $! All Done With This Library Part.
 557 $!
 558 $ FILE_DONE:
 559 $!
 560 $! Time To Build Some Applications
 561 $!
 562 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
 563 $ THEN
 564 $   APPLICATION_COUNTER = 0
 565 $ NEXT_APPLICATION:
 566 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 567 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
 568 $
 569 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 570 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 571 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 572 $
 573 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 574 $!   SHOW SYMBOL APPLICATION*
 575 $!
 576 $! Tell the user what happens
 577 $!
 578 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
 579 $!
 580 $! Link The Program.
 581 $!
 582 $   ON ERROR THEN GOTO NEXT_APPLICATION
 583 $!
 584 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 585 $!
 586 $   IF (TCPIP_LIB.NES."")
 587 $   THEN
 588 $!
 589 $!    Link With A TCP/IP Library.
 590 $!
 591 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 592           'OBJ_DIR''APPLICATION_OBJECTS', -
 593           'CRYPTO_LIB'/LIBRARY, -
 594           'TCPIP_LIB','OPT_FILE'/OPTION
 595 $!
 596 $! Else...
 597 $!
 598 $   ELSE
 599 $!
 600 $!    Don't Link With A TCP/IP Library.
 601 $!
 602 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 603           'OBJ_DIR''APPLICATION_OBJECTS',-
 604           'CRYPTO_LIB'/LIBRARY, -
 605           'OPT_FILE'/OPTION
 606 $!
 607 $! End The TCP/IP Library Check.
 608 $!
 609 $   ENDIF
 610 $   GOTO NEXT_APPLICATION
 611 $  APPLICATION_DONE:
 612 $ ENDIF
 613 $!
 614 $! Go Back And Get The Next Module.
 615 $!
 616 $ GOTO MODULE_NEXT
 617 $!
 618 $! All Done With This Module.
 619 $!
 620 $ MODULE_DONE:
 621 $!
 622 $! Tell The User That We Are All Done.
 623 $!
 624 $ WRITE SYS$OUTPUT "All Done..."
 625 $ EXIT:
 626 $ GOSUB CLEANUP
 627 $ EXIT
 628 $!
 629 $! Check For The Link Option FIle.
 630 $!
 631 $ CHECK_OPT_FILE:
 632 $!
 633 $! Check To See If We Need To Make A VAX C Option File.
 634 $!
 635 $ IF (COMPILER.EQS."VAXC")
 636 $ THEN
 637 $!
 638 $!  Check To See If We Already Have A VAX C Linker Option File.
 639 $!
 640 $   IF (F$SEARCH(OPT_FILE).EQS."")
 641 $   THEN
 642 $!
 643 $!    We Need A VAX C Linker Option File.
 644 $!
 645 $     CREATE 'OPT_FILE'
 646 $DECK
 647 !
 648 ! Default System Options File To Link Agianst
 649 ! The Sharable VAX C Runtime Library.
 650 !
 651 SYS$SHARE:VAXCRTL.EXE/SHARE
 652 $EOD
 653 $!
 654 $!  End The Option File Check.
 655 $!
 656 $   ENDIF
 657 $!
 658 $! End The VAXC Check.
 659 $!
 660 $ ENDIF
 661 $!
 662 $! Check To See If We Need A GNU C Option File.
 663 $!
 664 $ IF (COMPILER.EQS."GNUC")
 665 $ THEN
 666 $!
 667 $!  Check To See If We Already Have A GNU C Linker Option File.
 668 $!
 669 $   IF (F$SEARCH(OPT_FILE).EQS."")
 670 $   THEN
 671 $!
 672 $!    We Need A GNU C Linker Option File.
 673 $!
 674 $     CREATE 'OPT_FILE'
 675 $DECK
 676 !
 677 ! Default System Options File To Link Agianst
 678 ! The Sharable C Runtime Library.
 679 !
 680 GNU_CC:[000000]GCCLIB/LIBRARY
 681 SYS$SHARE:VAXCRTL/SHARE
 682 $EOD
 683 $!
 684 $!  End The Option File Check.
 685 $!
 686 $   ENDIF
 687 $!
 688 $! End The GNU C Check.
 689 $!
 690 $ ENDIF
 691 $!
 692 $! Check To See If We Need A DEC C Option File.
 693 $!
 694 $ IF (COMPILER.EQS."DECC")
 695 $ THEN
 696 $!
 697 $!  Check To See If We Already Have A DEC C Linker Option File.
 698 $!
 699 $   IF (F$SEARCH(OPT_FILE).EQS."")
 700 $   THEN
 701 $!
 702 $!    Figure Out If We Need A non-VAX Or A VAX Linker Option File.
 703 $!
 704 $     IF ARCH .EQS. "VAX"
 705 $     THEN
 706 $!
 707 $!      We Need A DEC C Linker Option File For VAX.
 708 $!
 709 $       CREATE 'OPT_FILE'
 710 $DECK
 711 !
 712 ! Default System Options File To Link Agianst
 713 ! The Sharable DEC C Runtime Library.
 714 !
 715 SYS$SHARE:DECC$SHR.EXE/SHARE
 716 $EOD
 717 $!
 718 $!    Else...
 719 $!
 720 $     ELSE
 721 $!
 722 $!      Create The non-VAX Linker Option File.
 723 $!
 724 $       CREATE 'OPT_FILE'
 725 $DECK
 726 !
 727 ! Default System Options File For non-VAX To Link Agianst
 728 ! The Sharable C Runtime Library.
 729 !
 730 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 731 SYS$SHARE:CMA$OPEN_RTL/SHARE
 732 $EOD
 733 $!
 734 $!    End The DEC C Option File Check.
 735 $!
 736 $     ENDIF
 737 $!
 738 $!  End The Option File Search.
 739 $!
 740 $   ENDIF
 741 $!
 742 $! End The DEC C Check.
 743 $!
 744 $ ENDIF
 745 $!
 746 $!  Tell The User What Linker Option File We Are Using.
 747 $!
 748 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 749 $!
 750 $! Time To RETURN.
 751 $!
 752 $ RETURN
 753 $!
 754 $! Check The User's Options.
 755 $!
 756 $ CHECK_OPTIONS:
 757 $!
 758 $! Check To See If P1 Is Blank.
 759 $!
 760 $ IF (P1.EQS."ALL")
 761 $ THEN
 762 $!
 763 $!   P1 Is Blank, So Build Everything.
 764 $!
 765 $    BUILDALL = "TRUE"
 766 $!
 767 $! Else...
 768 $!
 769 $ ELSE
 770 $!
 771 $!  Else, Check To See If P1 Has A Valid Arguement.
 772 $!
 773 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
 774 $   THEN
 775 $!
 776 $!    A Valid Arguement.
 777 $!
 778 $     BUILDALL = P1
 779 $!
 780 $!  Else...
 781 $!
 782 $   ELSE
 783 $!
 784 $!    Tell The User We Don't Know What They Want.
 785 $!
 786 $     WRITE SYS$OUTPUT ""
 787 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 788 $     WRITE SYS$OUTPUT ""
 789 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 790 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 791 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.CRYPTO]*.EXE Programs."
 792 $     WRITE SYS$OUTPUT ""
 793 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 794 $     WRITE SYS$OUTPUT ""
 795 $     WRITE SYS$OUTPUT "    ALPHA    :  Alpha Architecture."
 796 $     WRITE SYS$OUTPUT "    IA64     :  IA64 Architecture."
 797 $     WRITE SYS$OUTPUT "    VAX      :  VAX Architecture."
 798 $     WRITE SYS$OUTPUT ""
 799 $!
 800 $!    Time To EXIT.
 801 $!
 802 $     EXIT
 803 $!
 804 $!  End The Valid Arguement Check.
 805 $!
 806 $   ENDIF
 807 $!
 808 $! End The P1 Check.
 809 $!
 810 $ ENDIF
 811 $!
 812 $! Check To See If P2 Is Blank.
 813 $!
 814 $ IF (P2.EQS."NODEBUG")
 815 $ THEN
 816 $!
 817 $!   P2 Is NODEBUG, So Compile Without The Debugger Information.
 818 $!
 819 $    DEBUGGER = "NODEBUG"
 820 $    TRACEBACK = "NOTRACEBACK"
 821 $    GCC_OPTIMIZE = "OPTIMIZE"
 822 $    CC_OPTIMIZE = "OPTIMIZE"
 823 $    MACRO_OPTIMIZE = "OPTIMIZE"
 824 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 825 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 826 $ ELSE
 827 $!
 828 $!  Check To See If We Are To Compile With Debugger Information.
 829 $!
 830 $   IF (P2.EQS."DEBUG")
 831 $   THEN
 832 $!
 833 $!    Compile With Debugger Information.
 834 $!
 835 $     DEBUGGER = "DEBUG"
 836 $     TRACEBACK = "TRACEBACK"
 837 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 838 $     CC_OPTIMIZE = "NOOPTIMIZE"
 839 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 840 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 841 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 842 $   ELSE
 843 $!
 844 $!    They Entered An Invalid Option..
 845 $!
 846 $     WRITE SYS$OUTPUT ""
 847 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 848 $     WRITE SYS$OUTPUT ""
 849 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 850 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 851 $     WRITE SYS$OUTPUT ""
 852 $!
 853 $!    Time To EXIT.
 854 $!
 855 $     EXIT
 856 $!
 857 $!  End The Valid Arguement Check.
 858 $!
 859 $   ENDIF
 860 $!
 861 $! End The P2 Check.
 862 $!
 863 $ ENDIF
 864 $!
 865 $! Special Threads For OpenVMS v7.1 Or Later
 866 $!
 867 $! Written By:  Richard Levitte
 868 $!              richard@levitte.org
 869 $!
 870 $!
 871 $! Check To See If We Have A Option For P5.
 872 $!
 873 $ IF (P5.EQS."")
 874 $ THEN
 875 $!
 876 $!  Get The Version Of VMS We Are Using.
 877 $!
 878 $   ISSEVEN :=
 879 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 880 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 881 $!
 882 $!  Check To See If The VMS Version Is v7.1 Or Later.
 883 $!
 884 $   IF (TMP.GE.71)
 885 $   THEN
 886 $!
 887 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 888 $!
 889 $     ISSEVEN := ,PTHREAD_USE_D4
 890 $!
 891 $!  End The VMS Version Check.
 892 $!
 893 $   ENDIF
 894 $!
 895 $! End The P5 Check.
 896 $!
 897 $ ENDIF
 898 $!
 899 $! Check To See If P3 Is Blank.
 900 $!
 901 $ IF (P3.EQS."")
 902 $ THEN
 903 $!
 904 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 905 $!  Find Out Which One To Use.
 906 $!
 907 $!  Check To See If We Have GNU C.
 908 $!
 909 $   IF (F$TRNLNM("GNU_CC").NES."")
 910 $   THEN
 911 $!
 912 $!    Looks Like GNUC, Set To Use GNUC.
 913 $!
 914 $     P3 = "GNUC"
 915 $!
 916 $!  Else...
 917 $!
 918 $   ELSE
 919 $!
 920 $!    Check To See If We Have VAXC Or DECC.
 921 $!
 922 $     IF (ARCH.NES."VAX").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 923 $     THEN
 924 $!
 925 $!      Looks Like DECC, Set To Use DECC.
 926 $!
 927 $       P3 = "DECC"
 928 $!
 929 $!    Else...
 930 $!
 931 $     ELSE
 932 $!
 933 $!      Looks Like VAXC, Set To Use VAXC.
 934 $!
 935 $       P3 = "VAXC"
 936 $!
 937 $!    End The VAXC Compiler Check.
 938 $!
 939 $     ENDIF
 940 $!
 941 $!  End The DECC & VAXC Compiler Check.
 942 $!
 943 $   ENDIF
 944 $!
 945 $!  End The Compiler Check.
 946 $!
 947 $ ENDIF
 948 $!
 949 $! Check To See If We Have A Option For P4.
 950 $!
 951 $ IF (P4.EQS."")
 952 $ THEN
 953 $!
 954 $!  Find out what socket library we have available
 955 $!
 956 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 957 $   THEN
 958 $!
 959 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 960 $!
 961 $     P4 = "SOCKETSHR"
 962 $!
 963 $!    Tell the user
 964 $!
 965 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 966 $!
 967 $!    Else, let's look for something else
 968 $!
 969 $   ELSE
 970 $!
 971 $!    Like UCX (the reason to do this before Multinet is that the UCX
 972 $!    emulation is easier to use...)
 973 $!
 974 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 975          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 976          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 977 $     THEN
 978 $!
 979 $!      Last resort: a UCX or UCX-compatible library
 980 $!
 981 $       P4 = "UCX"
 982 $!
 983 $!      Tell the user
 984 $!
 985 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 986 $!
 987 $!      That was all...
 988 $!
 989 $     ENDIF
 990 $   ENDIF
 991 $ ENDIF
 992 $!
 993 $! Set Up Initial CC Definitions, Possibly With User Ones
 994 $!
 995 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
 996 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 997 $ CCEXTRAFLAGS = ""
 998 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 999 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
1000 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
1001         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
1002 $!
1003 $!  Check To See If The User Entered A Valid Paramter.
1004 $!
1005 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
1006 $ THEN
1007 $!
1008 $!    Check To See If The User Wanted DECC.
1009 $!
1010 $   IF (P3.EQS."DECC")
1011 $   THEN
1012 $!
1013 $!    Looks Like DECC, Set To Use DECC.
1014 $!
1015 $     COMPILER = "DECC"
1016 $!
1017 $!    Tell The User We Are Using DECC.
1018 $!
1019 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1020 $!
1021 $!    Use DECC...
1022 $!
1023 $     CC = "CC"
1024 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1025          THEN CC = "CC/DECC"
1026 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
1027            "/NOLIST/PREFIX=ALL" + -
1028            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS],SYS$DISK:[.EVP])" + -
1029            CCEXTRAFLAGS
1030 $!
1031 $!    Define The Linker Options File Name.
1032 $!
1033 $     OPT_FILE = "''EXE_DIR'VAX_DECC_OPTIONS.OPT"
1034 $!
1035 $!  End DECC Check.
1036 $!
1037 $   ENDIF
1038 $!
1039 $!  Check To See If We Are To Use VAXC.
1040 $!
1041 $   IF (P3.EQS."VAXC")
1042 $   THEN
1043 $!
1044 $!    Looks Like VAXC, Set To Use VAXC.
1045 $!
1046 $     COMPILER = "VAXC"
1047 $!
1048 $!    Tell The User We Are Using VAX C.
1049 $!
1050 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1051 $!
1052 $!    Compile Using VAXC.
1053 $!
1054 $     CC = "CC"
1055 $     IF ARCH.NES."VAX"
1056 $     THEN
1057 $       WRITE SYS$OUTPUT "There is no VAX C on ''ARCH'!"
1058 $       EXIT
1059 $     ENDIF
1060 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1061 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1062            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1063            CCEXTRAFLAGS
1064 $     CCDEFS = """VAXC""," + CCDEFS
1065 $!
1066 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1067 $!
1068 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1069 $!
1070 $!    Define The Linker Options File Name.
1071 $!
1072 $     OPT_FILE = "''EXE_DIR'VAX_VAXC_OPTIONS.OPT"
1073 $!
1074 $!  End VAXC Check
1075 $!
1076 $   ENDIF
1077 $!
1078 $!  Check To See If We Are To Use GNU C.
1079 $!
1080 $   IF (P3.EQS."GNUC")
1081 $   THEN
1082 $!
1083 $!    Looks Like GNUC, Set To Use GNUC.
1084 $!
1085 $     COMPILER = "GNUC"
1086 $!
1087 $!    Tell The User We Are Using GNUC.
1088 $!
1089 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1090 $!
1091 $!    Use GNU C...
1092 $!
1093 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1094            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1095            CCEXTRAFLAGS
1096 $!
1097 $!    Define The Linker Options File Name.
1098 $!
1099 $     OPT_FILE = "''EXE_DIR'VAX_GNUC_OPTIONS.OPT"
1100 $!
1101 $!  End The GNU C Check.
1102 $!
1103 $   ENDIF
1104 $!
1105 $!  Set up default defines
1106 $!
1107 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1108 $!
1109 $!  Finish up the definition of CC.
1110 $!
1111 $   IF COMPILER .EQS. "DECC"
1112 $   THEN
1113 $     IF CCDISABLEWARNINGS .EQS. ""
1114 $     THEN
1115 $       CC4DISABLEWARNINGS = "DOLLARID"
1116 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
1117 $     ELSE
1118 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1119 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
1120 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1121 $     ENDIF
1122 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1123 $     CC6DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
1124 $   ELSE
1125 $     CCDISABLEWARNINGS = ""
1126 $     CC4DISABLEWARNINGS = ""
1127 $     CC6DISABLEWARNINGS = ""
1128 $   ENDIF
1129 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1130 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1131 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1132 $   THEN
1133 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1134 $   ELSE
1135 $     CC5 = CC + "/NOOPTIMIZE"
1136 $   ENDIF
1137 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1138 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1139 $!
1140 $!  Show user the result
1141 $!
1142 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1143 $!
1144 $!  Else The User Entered An Invalid Arguement.
1145 $!
1146 $ ELSE
1147 $!
1148 $!  Tell The User We Don't Know What They Want.
1149 $!
1150 $   WRITE SYS$OUTPUT ""
1151 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1152 $   WRITE SYS$OUTPUT ""
1153 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1154 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1155 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1156 $   WRITE SYS$OUTPUT ""
1157 $!
1158 $!  Time To EXIT.
1159 $!
1160 $   EXIT
1161 $!
1162 $! End The Valid Arguement Check.
1163 $!
1164 $ ENDIF
1165 $!
1166 $! Build a MACRO command for the architecture at hand
1167 $!
1168 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1169 $ IF ARCH .NES. "VAX" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1170 $!
1171 $!  Show user the result
1172 $!
1173 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1174 $!
1175 $! Time to check the contents, and to make sure we get the correct library.
1176 $!
1177 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1178      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1179 $ THEN
1180 $!
1181 $!  Check to see if SOCKETSHR was chosen
1182 $!
1183 $   IF P4.EQS."SOCKETSHR"
1184 $   THEN
1185 $!
1186 $!    Set the library to use SOCKETSHR
1187 $!
1188 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1189 $!
1190 $!    Done with SOCKETSHR
1191 $!
1192 $   ENDIF
1193 $!
1194 $!  Check to see if MULTINET was chosen
1195 $!
1196 $   IF P4.EQS."MULTINET"
1197 $   THEN
1198 $!
1199 $!    Set the library to use UCX emulation.
1200 $!
1201 $     P4 = "UCX"
1202 $!
1203 $!    Done with MULTINET
1204 $!
1205 $   ENDIF
1206 $!
1207 $!  Check to see if UCX was chosen
1208 $!
1209 $   IF P4.EQS."UCX"
1210 $   THEN
1211 $!
1212 $!    Set the library to use UCX.
1213 $!
1214 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1215 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1216 $     THEN
1217 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1218 $     ELSE
1219 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1220           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1221 $     ENDIF
1222 $!
1223 $!    Done with UCX
1224 $!
1225 $   ENDIF
1226 $!
1227 $!  Check to see if TCPIP was chosen
1228 $!
1229 $   IF P4.EQS."TCPIP"
1230 $   THEN
1231 $!
1232 $!    Set the library to use TCPIP (post UCX).
1233 $!
1234 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1235 $!
1236 $!    Done with TCPIP
1237 $!
1238 $   ENDIF
1239 $!
1240 $!  Check to see if NONE was chosen
1241 $!
1242 $   IF P4.EQS."NONE"
1243 $   THEN
1244 $!
1245 $!    Do not use a TCPIP library.
1246 $!
1247 $     TCPIP_LIB = ""
1248 $!
1249 $!    Done with TCPIP
1250 $!
1251 $   ENDIF
1252 $!
1253 $!  Print info
1254 $!
1255 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1256 $!
1257 $!  Else The User Entered An Invalid Arguement.
1258 $!
1259 $ ELSE
1260 $!
1261 $!  Tell The User We Don't Know What They Want.
1262 $!
1263 $   WRITE SYS$OUTPUT ""
1264 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1265 $   WRITE SYS$OUTPUT ""
1266 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1267 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1268 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1269 $   WRITE SYS$OUTPUT ""
1270 $!
1271 $!  Time To EXIT.
1272 $!
1273 $   EXIT
1274 $!
1275 $!  Done with TCP/IP libraries
1276 $!
1277 $ ENDIF
1278 $!
1279 $! Check if the user wanted to compile just a subset of all the encryption
1280 $! methods.
1281 $!
1282 $ IF P6 .NES. ""
1283 $ THEN
1284 $   ENCRYPT_TYPES = P6
1285 $ ENDIF
1286 $!
1287 $!  Time To RETURN...
1288 $!
1289 $ RETURN
1290 $!
1291 $ INITIALISE:
1292 $!
1293 $! Save old value of the logical name OPENSSL
1294 $!
1295 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1296 $!
1297 $! Save directory information
1298 $!
1299 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1300 $ __HERE = F$EDIT(__HERE,"UPCASE")
1301 $ __TOP = __HERE - "CRYPTO]"
1302 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1303 $!
1304 $! Set up the logical name OPENSSL to point at the include directory
1305 $!
1306 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1307 $!
1308 $! Done
1309 $!
1310 $ RETURN
1311 $!
1312 $ CLEANUP:
1313 $!
1314 $! Restore the logical name OPENSSL if it had a value
1315 $!
1316 $ IF __SAVE_OPENSSL .EQS. ""
1317 $ THEN
1318 $   DEASSIGN OPENSSL
1319 $ ELSE
1320 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1321 $ ENDIF
1322 $!
1323 $! Done
1324 $!
1325 $ RETURN