crypto/crypto-lib.com

   1 $!
   2 $!  CRYPTO-LIB.COM
   3 $!  Written By:  Robert Byer
   4 $!               Vice-President
   5 $!               A-Com Computing, Inc.
   6 $!               byer@mail.all-net.net
   7 $!
   8 $!  Changes by Richard Levitte <richard@levitte.org>
   9 $!
  10 $!  This command files compiles and creates the "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB"
  11 $!  library for OpenSSL.  The "xxx" denotes the machine architecture, ALPHA,
  12 $!  IA64 or VAX.
  13 $!
  14 $!  It was re-written so it would try to determine what "C" compiler to use
  15 $!  or you can specify which "C" compiler to use.
  16 $!
  17 $!  Specify the following as P1 to build just that part or ALL to just
  18 $!  build everything.
  19 $!
  20 $!      LIBRARY    To just compile the [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library.
  21 $!      APPS       To just compile the [.xxx.EXE.CRYPTO]*.EXE
  22 $!      ALL        To do both LIBRARY and APPS
  23 $!
  24 $!  Specify DEBUG or NODEBUG as P2 to compile with or without debugger
  25 $!  information.
  26 $!
  27 $!  Specify which compiler at P3 to try to compile under.
  28 $!
  29 $!      VAXC       For VAX C.
  30 $!      DECC       For DEC C.
  31 $!      GNUC       For GNU C.
  32 $!
  33 $!  If you don't specify a compiler, it will try to determine which
  34 $!  "C" compiler to use.
  35 $!
  36 $!  P4, if defined, sets a TCP/IP library to use, through one of the following
  37 $!  keywords:
  38 $!
  39 $!      UCX        For UCX
  40 $!      TCPIP      For TCPIP (post UCX)
  41 $!      SOCKETSHR  For SOCKETSHR+NETLIB
  42 $!
  43 $!  P5, if defined, sets a compiler thread NOT needed on OpenVMS 7.1 (and up)
  44 $!
  45 $!  P6, if defined, sets a choice of crypto methods to compile.
  46 $!  WARNING: this should only be done to recompile some part of an already
  47 $!  fully compiled library.
  48 $!
  49 $!
  50 $! Define A TCP/IP Library That We Will Need To Link To.
  51 $! (That Is, If We Need To Link To One.)
  52 $!
  53 $ TCPIP_LIB = ""
  54 $!
  55 $! Check Which Architecture We Are Using.
  56 $!
  57 $ IF (F$GETSYI("CPU").LT.128)
  58 $ THEN
  59 $!
  60 $!  The Architecture Is VAX
  61 $!
  62 $   ARCH := VAX
  63 $!
  64 $! Else...
  65 $!
  66 $ ELSE
  67 $!
  68 $!  The Architecture Is Alpha, IA64 or whatever comes in the future.
  69 $!
  70 $   ARCH = F$EDIT( F$GETSYI( "ARCH_NAME"), "UPCASE")
  71 $   IF (ARCH .EQS. "") THEN ARCH = "UNK"
  72 $!
  73 $! End The Architecture Check.
  74 $!
  75 $ ENDIF
  76 $!
  77 $! Define The Different Encryption Types.
  78 $! NOTE: Some might think this list ugly.  However, it's made this way to
  79 $! reflect the SDIRS variable in [-]Makefile.org as closely as possible,
  80 $! thereby making it fairly easy to verify that the lists are the same.
  81 $!
  82 $ ENCRYPT_TYPES = "Basic,"+ -
  83                   "OBJECTS,"+ -
  84                   "MD2,MD4,MD5,SHA,MDC2,HMAC,RIPEMD,"+ -
  85                   "DES,RC2,RC4,RC5,IDEA,BF,CAST,CAMELLIA,SEED,"+ -
  86                   "BN,EC,RSA,DSA,ECDSA,DH,ECDH,DSO,ENGINE,AES,"+ -
  87                   "BUFFER,BIO,STACK,LHASH,RAND,ERR,"+ -
  88                   "EVP,EVP_2,ASN1,ASN1_2,PEM,X509,X509V3,"+ -
  89                   "CONF,TXT_DB,PKCS7,PKCS12,COMP,OCSP,UI,KRB5,"+ -
  90                   "STORE,CMS,PQUEUE,JPAKE"
  91 $! Define The OBJ Directory.
  92 $!
  93 $ OBJ_DIR := SYS$DISK:[-.'ARCH'.OBJ.CRYPTO]
  94 $!
  95 $! Define The EXE Directory.
  96 $!
  97 $ EXE_DIR := SYS$DISK:[-.'ARCH'.EXE.CRYPTO]
  98 $!
  99 $! Check To Make Sure We Have Valid Command Line Parameters.
 100 $!
 101 $ GOSUB CHECK_OPTIONS
 102 $!
 103 $! Initialise logical names and such
 104 $!
 105 $ GOSUB INITIALISE
 106 $!
 107 $! Tell The User What Kind of Machine We Run On.
 108 $!
 109 $ WRITE SYS$OUTPUT "Compiling On A ",ARCH," Machine."
 110 $!
 111 $!
 112 $! Check To See If The Architecture Specific OBJ Directory Exists.
 113 $!
 114 $ IF (F$PARSE(OBJ_DIR).EQS."")
 115 $ THEN
 116 $!
 117 $!  It Dosen't Exist, So Create It.
 118 $!
 119 $   CREATE/DIR 'OBJ_DIR'
 120 $!
 121 $! End The Architecture Specific OBJ Directory Check.
 122 $!
 123 $ ENDIF
 124 $!
 125 $! Check To See If The Architecture Specific Directory Exists.
 126 $!
 127 $ IF (F$PARSE(EXE_DIR).EQS."")
 128 $ THEN
 129 $!
 130 $!  It Dosen't Exist, So Create It.
 131 $!
 132 $   CREATE/DIRECTORY 'EXE_DIR'
 133 $!
 134 $! End The Architecture Specific Directory Check.
 135 $!
 136 $ ENDIF
 137 $!
 138 $! Define The Library Name.
 139 $!
 140 $ LIB_NAME := 'EXE_DIR'LIBCRYPTO.OLB
 141 $!
 142 $! Define The CRYPTO-LIB We Are To Use.
 143 $!
 144 $ CRYPTO_LIB := 'EXE_DIR'LIBCRYPTO.OLB
 145 $!
 146 $! Check To See If We Already Have A "[.xxx.EXE.CRYPTO]LIBCRYPTO.OLB" Library...
 147 $!
 148 $ IF (F$SEARCH(LIB_NAME).EQS."")
 149 $ THEN
 150 $!
 151 $! Guess Not, Create The Library.
 152 $!
 153 $   LIBRARY/CREATE/OBJECT 'LIB_NAME'
 154 $!
 155 $! End The Library Check.
 156 $!
 157 $ ENDIF
 158 $!
 159 $! Build our options file for the application
 160 $!
 161 $ GOSUB CHECK_OPT_FILE
 162 $!
 163 $! Define The Different Encryption "library" Strings.
 164 $!
 165 $ APPS_DES = "DES/DES,CBC3_ENC"
 166 $ APPS_PKCS7 = "ENC/ENC;DEC/DEC;SIGN/SIGN;VERIFY/VERIFY,EXAMPLE"
 167 $
 168 $ LIB_ = "cryptlib,dyn_lck,mem,mem_clr,mem_dbg,cversion,ex_data,tmdiff,cpt_err,ebcdic,uid,o_time,o_str,o_dir,o_init,fips_err"
 169 $ LIB_MD2 = "md2_dgst,md2_one"
 170 $ LIB_MD4 = "md4_dgst,md4_one"
 171 $ LIB_MD5 = "md5_dgst,md5_one"
 172 $ LIB_SHA = "sha_dgst,sha1dgst,sha_one,sha1_one,sha256,sha512"
 173 $ LIB_MDC2 = "mdc2dgst,mdc2_one"
 174 $ LIB_HMAC = "hmac"
 175 $ LIB_RIPEMD = "rmd_dgst,rmd_one"
 176 $ LIB_DES = "des_lib,set_key,ecb_enc,cbc_enc,"+ -
 177         "ecb3_enc,cfb64enc,cfb64ede,cfb_enc,ofb64ede,"+ -
 178         "enc_read,enc_writ,ofb64enc,"+ -
 179         "ofb_enc,str2key,pcbc_enc,qud_cksm,rand_key,"+ -
 180         "des_enc,fcrypt_b,"+ -
 181         "fcrypt,xcbc_enc,rpc_enc,cbc_cksm,"+ -
 182         "ede_cbcm_enc,des_old,des_old2,read2pwd"
 183 $ LIB_RC2 = "rc2_ecb,rc2_skey,rc2_cbc,rc2cfb64,rc2ofb64"
 184 $ LIB_RC4 = "rc4_skey,rc4_enc"
 185 $ LIB_RC5 = "rc5_skey,rc5_ecb,rc5_enc,rc5cfb64,rc5ofb64"
 186 $ LIB_IDEA = "i_cbc,i_cfb64,i_ofb64,i_ecb,i_skey"
 187 $ LIB_BF = "bf_skey,bf_ecb,bf_enc,bf_cfb64,bf_ofb64"
 188 $ LIB_CAST = "c_skey,c_ecb,c_enc,c_cfb64,c_ofb64"
 189 $ LIB_CAMELLIA = "camellia,cmll_misc,cmll_ecb,cmll_cbc,cmll_ofb,"+ -
 190         "cmll_cfb,cmll_ctr"
 191 $ LIB_SEED = "seed,seed_cbc,seed_ecb,seed_cfb,seed_ofb"
 192 $ LIB_BN_ASM = "[.asm]vms.mar,vms-helper"
 193 $ IF F$TRNLNM("OPENSSL_NO_ASM").OR.ARCH.EQS."AXP" THEN LIB_BN_ASM = "bn_asm"
 194 $ LIB_BN = "bn_add,bn_div,bn_exp,bn_lib,bn_ctx,bn_mul,bn_mod,"+ -
 195         "bn_print,bn_rand,bn_shift,bn_word,bn_blind,"+ -
 196         "bn_kron,bn_sqrt,bn_gcd,bn_prime,bn_err,bn_sqr,"+LIB_BN_ASM+","+ -
 197         "bn_recp,bn_mont,bn_mpi,bn_exp2,bn_gf2m,bn_nist,"+ -
 198         "bn_depr,bn_x931p,bn_const,bn_opt"
 199 $ LIB_EC = "ec_lib,ecp_smpl,ecp_mont,ecp_nist,ec_cvt,ec_mult,"+ -
 200         "ec_err,ec_curve,ec_check,ec_print,ec_asn1,ec_key,"+ -
 201         "ec2_smpl,ec2_mult"
 202 $ LIB_RSA = "rsa_eay,rsa_gen,rsa_lib,rsa_sign,rsa_saos,rsa_err,"+ -
 203         "rsa_pk1,rsa_ssl,rsa_none,rsa_oaep,rsa_chk,rsa_null,"+ -
 204         "rsa_pss,rsa_x931,rsa_x931g,rsa_asn1,rsa_depr,rsa_eng"
 205 $ LIB_DSA = "dsa_gen,dsa_key,dsa_lib,dsa_asn1,dsa_vrf,dsa_sign,"+ -
 206         "dsa_err,dsa_ossl,dsa_depr,dsa_utl"
 207 $ LIB_ECDSA = "ecs_lib,ecs_asn1,ecs_ossl,ecs_sign,ecs_vrf,ecs_err"
 208 $ LIB_DH = "dh_asn1,dh_gen,dh_key,dh_lib,dh_check,dh_err,dh_depr"
 209 $ LIB_ECDH = "ech_lib,ech_ossl,ech_key,ech_err"
 210 $ LIB_DSO = "dso_dl,dso_dlfcn,dso_err,dso_lib,dso_null,"+ -
 211         "dso_openssl,dso_win32,dso_vms"
 212 $ LIB_ENGINE = "eng_err,eng_lib,eng_list,eng_init,eng_ctrl,"+ -
 213         "eng_table,eng_pkey,eng_fat,eng_all,"+ -
 214         "tb_rsa,tb_dsa,tb_ecdsa,tb_dh,tb_ecdh,tb_rand,tb_store,"+ -
 215         "tb_cipher,tb_digest,"+ -
 216         "eng_openssl,eng_dyn,eng_cnf,eng_cryptodev,eng_padlock"
 217 $ LIB_AES = "aes_core,aes_misc,aes_ecb,aes_cbc,aes_cfb,aes_ofb,"+ -
 218         "aes_ctr,aes_ige,aes_wrap"
 219 $ LIB_BUFFER = "buffer,buf_str,buf_err"
 220 $ LIB_BIO = "bio_lib,bio_cb,bio_err,"+ -
 221         "bss_mem,bss_null,bss_fd,"+ -
 222         "bss_file,bss_sock,bss_conn,"+ -
 223         "bf_null,bf_buff,b_print,b_dump,"+ -
 224         "b_sock,bss_acpt,bf_nbio,bss_rtcp,bss_bio,bss_log,"+ -
 225         "bss_dgram,"+ -
 226         "bf_lbuf"
 227 $ LIB_STACK = "stack"
 228 $ LIB_LHASH = "lhash,lh_stats"
 229 $ LIB_RAND = "md_rand,randfile,rand_lib,rand_err,rand_egd,"+ -
 230         "rand_vms"
 231 $ LIB_ERR = "err,err_def,err_all,err_prn,err_str,err_bio"
 232 $ LIB_OBJECTS = "o_names,obj_dat,obj_lib,obj_err"
 233 $ LIB_EVP = "encode,digest,dig_eng,evp_enc,evp_key,evp_acnf,evp_cnf,"+ -
 234         "e_des,e_bf,e_idea,e_des3,e_camellia,"+ -
 235         "e_rc4,e_aes,names,e_seed,"+ -
 236         "e_xcbc_d,e_rc2,e_cast,e_rc5,enc_min"
 237 $ LIB_EVP_2 = "m_null,m_md2,m_md4,m_md5,m_sha,m_sha1," + -
 238         "m_dss,m_dss1,m_mdc2,m_ripemd,m_ecdsa,"+ -
 239         "p_open,p_seal,p_sign,p_verify,p_lib,p_enc,p_dec,"+ -
 240         "bio_md,bio_b64,bio_enc,evp_err,e_null,"+ -
 241         "c_all,c_allc,c_alld,evp_lib,bio_ok,"+-
 242         "evp_pkey,evp_pbe,p5_crpt,p5_crpt2"
 243 $ LIB_EVP_3 = "e_old"
 244 $ LIB_ASN1 = "a_object,a_bitstr,a_utctm,a_gentm,a_time,a_int,a_octet,"+ -
 245         "a_print,a_type,a_set,a_dup,a_d2i_fp,a_i2d_fp,"+ -
 246         "a_enum,a_utf8,a_sign,a_digest,a_verify,a_mbstr,a_strex,"+ -
 247         "x_algor,x_val,x_pubkey,x_sig,x_req,x_attrib,x_bignum,"+ -
 248         "x_long,x_name,x_x509,x_x509a,x_crl,x_info,x_spki,nsseq,"+ -
 249         "d2i_pu,d2i_pr,i2d_pu,i2d_pr"
 250 $ LIB_ASN1_2 = "t_req,t_x509,t_x509a,t_crl,t_pkey,t_spki,t_bitst,"+ -
 251         "tasn_new,tasn_fre,tasn_enc,tasn_dec,tasn_utl,tasn_typ,"+ -
 252         "f_int,f_string,n_pkey,"+ -
 253         "f_enum,a_hdr,x_pkey,a_bool,x_exten,asn_mime,"+ -
 254         "asn1_gen,asn1_par,asn1_lib,asn1_err,a_meth,a_bytes,a_strnid,"+ -
 255         "evp_asn1,asn_pack,p5_pbe,p5_pbev2,p8_pkey,asn_moid"
 256 $ LIB_PEM = "pem_sign,pem_seal,pem_info,pem_lib,pem_all,pem_err,"+ -
 257         "pem_x509,pem_xaux,pem_oth,pem_pk8,pem_pkey"
 258 $ LIB_X509 = "x509_def,x509_d2,x509_r2x,x509_cmp,"+ -
 259         "x509_obj,x509_req,x509spki,x509_vfy,"+ -
 260         "x509_set,x509cset,x509rset,x509_err,"+ -
 261         "x509name,x509_v3,x509_ext,x509_att,"+ -
 262         "x509type,x509_lu,x_all,x509_txt,"+ -
 263         "x509_trs,by_file,by_dir,x509_vpm"
 264 $ LIB_X509V3 = "v3_bcons,v3_bitst,v3_conf,v3_extku,v3_ia5,v3_lib,"+ -
 265         "v3_prn,v3_utl,v3err,v3_genn,v3_alt,v3_skey,v3_akey,v3_pku,"+ -
 266         "v3_int,v3_enum,v3_sxnet,v3_cpols,v3_crld,v3_purp,v3_info,"+ -
 267         "v3_ocsp,v3_akeya,v3_pmaps,v3_pcons,v3_ncons,v3_pcia,v3_pci,"+ -
 268         "pcy_cache,pcy_node,pcy_data,pcy_map,pcy_tree,pcy_lib,"+ -
 269         "v3_asid,v3_addr"
 270 $ LIB_CONF = "conf_err,conf_lib,conf_api,conf_def,conf_mod,conf_mall,conf_sap"
 271 $ LIB_TXT_DB = "txt_db"
 272 $ LIB_PKCS7 = "pk7_asn1,pk7_lib,pkcs7err,pk7_doit,pk7_smime,pk7_attr,"+ -
 273         "pk7_mime"
 274 $ LIB_PKCS12 = "p12_add,p12_asn,p12_attr,p12_crpt,p12_crt,p12_decr,"+ -
 275         "p12_init,p12_key,p12_kiss,p12_mutl,"+ -
 276         "p12_utl,p12_npas,pk12err,p12_p8d,p12_p8e"
 277 $ LIB_COMP = "comp_lib,comp_err,"+ -
 278         "c_rle,c_zlib"
 279 $ LIB_OCSP = "ocsp_asn,ocsp_ext,ocsp_ht,ocsp_lib,ocsp_cl,"+ -
 280         "ocsp_srv,ocsp_prn,ocsp_vfy,ocsp_err"
 281 $ LIB_UI_COMPAT = ",ui_compat"
 282 $ LIB_UI = "ui_err,ui_lib,ui_openssl,ui_util"+LIB_UI_COMPAT
 283 $ LIB_KRB5 = "krb5_asn"
 284 $ LIB_STORE = "str_err,str_lib,str_meth,str_mem"
 285 $ LIB_CMS = "cms_lib,cms_asn1,cms_att,cms_io,cms_smime,cms_err,"+ -
 286         "cms_sd,cms_dd,cms_cd,cms_env,cms_enc,cms_ess"
 287 $ LIB_PQUEUE = "pqueue"
 288 $ LIB_JPAKE = "jpake,jpake_err"
 289 $!
 290 $! Setup exceptional compilations
 291 $!
 292 $ ! Add definitions for no threads on OpenVMS 7.1 and higher
 293 $ COMPILEWITH_CC3 = ",bss_rtcp,"
 294 $ ! Disable the DOLLARID warning
 295 $ COMPILEWITH_CC4 = ",a_utctm,bss_log,o_time,o_dir"
 296 $ ! Disable disjoint optimization
 297 $ COMPILEWITH_CC5 = ",md2_dgst,md4_dgst,md5_dgst,mdc2dgst," + -
 298                     "seed,sha_dgst,sha1dgst,rmd_dgst,bf_enc,"
 299 $ ! Disable the MIXLINKAGE warning
 300 $ COMPILEWITH_CC6 = ",enc_read,set_key,"
 301 $!
 302 $! Figure Out What Other Modules We Are To Build.
 303 $!
 304 $ BUILD_SET:
 305 $!
 306 $! Define A Module Counter.
 307 $!
 308 $ MODULE_COUNTER = 0
 309 $!
 310 $! Top Of The Loop.
 311 $!
 312 $ MODULE_NEXT:
 313 $!
 314 $! Extract The Module Name From The Encryption List.
 315 $!
 316 $ MODULE_NAME = F$ELEMENT(MODULE_COUNTER,",",ENCRYPT_TYPES)
 317 $ IF MODULE_NAME.EQS."Basic" THEN MODULE_NAME = ""
 318 $ MODULE_NAME1 = MODULE_NAME
 319 $!
 320 $! Check To See If We Are At The End Of The Module List.
 321 $!
 322 $ IF (MODULE_NAME.EQS.",")
 323 $ THEN
 324 $!
 325 $!  We Are At The End Of The Module List, Go To MODULE_DONE.
 326 $!
 327 $   GOTO MODULE_DONE
 328 $!
 329 $! End The Module List Check.
 330 $!
 331 $ ENDIF
 332 $!
 333 $! Increment The Moudle Counter.
 334 $!
 335 $ MODULE_COUNTER = MODULE_COUNTER + 1
 336 $!
 337 $! Create The Library and Apps Module Names.
 338 $!
 339 $ LIB_MODULE = "LIB_" + MODULE_NAME
 340 $ APPS_MODULE = "APPS_" + MODULE_NAME
 341 $ IF (F$EXTRACT(0,5,MODULE_NAME).EQS."ASN1_")
 342 $ THEN
 343 $   MODULE_NAME = "ASN1"
 344 $ ENDIF
 345 $ IF (F$EXTRACT(0,4,MODULE_NAME).EQS."EVP_")
 346 $ THEN
 347 $   MODULE_NAME = "EVP"
 348 $ ENDIF
 349 $!
 350 $! Set state (can be LIB and APPS)
 351 $!
 352 $ STATE = "LIB"
 353 $ IF BUILDALL .EQS. "APPS" THEN STATE = "APPS"
 354 $!
 355 $! Check if the library module name actually is defined
 356 $!
 357 $ IF F$TYPE('LIB_MODULE') .EQS. ""
 358 $ THEN
 359 $   WRITE SYS$ERROR ""
 360 $   WRITE SYS$ERROR "The module ",MODULE_NAME," does not exist.  Continuing..."
 361 $   WRITE SYS$ERROR ""
 362 $   GOTO MODULE_NEXT
 363 $ ENDIF
 364 $!
 365 $! Top Of The Module Loop.
 366 $!
 367 $ MODULE_AGAIN:
 368 $!
 369 $! Tell The User What Module We Are Building.
 370 $!
 371 $ IF (MODULE_NAME1.NES."")
 372 $ THEN
 373 $   IF STATE .EQS. "LIB"
 374 $   THEN
 375 $     WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Library Files. (",BUILDALL,",",STATE,")"
 376 $   ELSE IF F$TYPE('APPS_MODULE') .NES. ""
 377 $     THEN
 378 $       WRITE SYS$OUTPUT "Compiling The ",MODULE_NAME1," Applications. (",BUILDALL,",",STATE,")"
 379 $     ENDIF
 380 $   ENDIF
 381 $ ENDIF
 382 $!
 383 $!  Define A File Counter And Set It To "0".
 384 $!
 385 $ FILE_COUNTER = 0
 386 $ APPLICATION = ""
 387 $ APPLICATION_COUNTER = 0
 388 $!
 389 $! Top Of The File Loop.
 390 $!
 391 $ NEXT_FILE:
 392 $!
 393 $! Look in the LIB_MODULE is we're in state LIB
 394 $!
 395 $ IF STATE .EQS. "LIB"
 396 $ THEN
 397 $!
 398 $!   O.K, Extract The File Name From The File List.
 399 $!
 400 $   FILE_NAME = F$ELEMENT(FILE_COUNTER,",",'LIB_MODULE')
 401 $!
 402 $!   else
 403 $!
 404 $ ELSE
 405 $   FILE_NAME = ","
 406 $!
 407 $   IF F$TYPE('APPS_MODULE') .NES. ""
 408 $   THEN
 409 $!
 410 $!     Extract The File Name From The File List.
 411 $!     This part is a bit more complicated.
 412 $!
 413 $     IF APPLICATION .EQS. ""
 414 $     THEN
 415 $       APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 416 $       APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 417 $       APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 418 $       APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 419 $       FILE_COUNTER = 0
 420 $     ENDIF
 421 $
 422 $!     WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 423 $!     SHOW SYMBOL APPLICATION*
 424 $!
 425 $     IF APPLICATION .NES. ";"
 426 $     THEN
 427 $       FILE_NAME = F$ELEMENT(FILE_COUNTER,",",APPLICATION_OBJECTS)
 428 $       IF FILE_NAME .EQS. ","
 429 $       THEN
 430 $         APPLICATION = ""
 431 $         GOTO NEXT_FILE
 432 $       ENDIF
 433 $     ENDIF
 434 $   ENDIF
 435 $ ENDIF
 436 $!
 437 $! Check To See If We Are At The End Of The File List.
 438 $!
 439 $ IF (FILE_NAME.EQS.",")
 440 $ THEN
 441 $!
 442 $!  We Are At The End Of The File List, Change State Or Goto FILE_DONE.
 443 $!
 444 $   IF STATE .EQS. "LIB" .AND. BUILDALL .NES. "LIBRARY"
 445 $   THEN
 446 $     STATE = "APPS"
 447 $     GOTO MODULE_AGAIN
 448 $   ELSE
 449 $     GOTO FILE_DONE
 450 $   ENDIF
 451 $!
 452 $! End The File List Check.
 453 $!
 454 $ ENDIF
 455 $!
 456 $! Increment The Counter.
 457 $!
 458 $ FILE_COUNTER = FILE_COUNTER + 1
 459 $!
 460 $! Create The Source File Name.
 461 $!
 462 $ TMP_FILE_NAME = F$ELEMENT(1,"]",FILE_NAME)
 463 $ IF TMP_FILE_NAME .EQS. "]" THEN TMP_FILE_NAME = FILE_NAME
 464 $ IF F$ELEMENT(0,".",TMP_FILE_NAME) .EQS. TMP_FILE_NAME THEN -
 465         FILE_NAME = FILE_NAME + ".c"
 466 $ IF (MODULE_NAME.NES."")
 467 $ THEN
 468 $   SOURCE_FILE = "SYS$DISK:[." + MODULE_NAME+ "]" + FILE_NAME
 469 $ ELSE
 470 $   SOURCE_FILE = "SYS$DISK:[]" + FILE_NAME
 471 $ ENDIF
 472 $ SOURCE_FILE = SOURCE_FILE - "]["
 473 $!
 474 $! Create The Object File Name.
 475 $!
 476 $ OBJECT_FILE = OBJ_DIR + F$PARSE(FILE_NAME,,,"NAME","SYNTAX_ONLY") + ".OBJ"
 477 $ ON WARNING THEN GOTO NEXT_FILE
 478 $!
 479 $! Check To See If The File We Want To Compile Is Actually There.
 480 $!
 481 $ IF (F$SEARCH(SOURCE_FILE).EQS."")
 482 $ THEN
 483 $!
 484 $!  Tell The User That The File Doesn't Exist.
 485 $!
 486 $   WRITE SYS$OUTPUT ""
 487 $   WRITE SYS$OUTPUT "The File ",SOURCE_FILE," Doesn't Exist."
 488 $   WRITE SYS$OUTPUT ""
 489 $!
 490 $!  Exit The Build.
 491 $!
 492 $   GOTO EXIT
 493 $!
 494 $! End The File Exist Check.
 495 $!
 496 $ ENDIF
 497 $!
 498 $! Tell The User We Are Compiling The File.
 499 $!
 500 $ IF (MODULE_NAME.EQS."")
 501 $ THEN
 502 $   WRITE SYS$OUTPUT "Compiling The ",FILE_NAME," File.  (",BUILDALL,",",STATE,")"
 503 $ ENDIF
 504 $ IF (MODULE_NAME.NES."")
 505 $ THEN
 506 $   WRITE SYS$OUTPUT "  ",FILE_NAME,""
 507 $ ENDIF
 508 $!
 509 $! Compile The File.
 510 $!
 511 $ ON ERROR THEN GOTO NEXT_FILE
 512 $ FILE_NAME0 = F$ELEMENT(0,".",FILE_NAME)
 513 $ IF FILE_NAME - ".mar" .NES. FILE_NAME
 514 $ THEN
 515 $   MACRO/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 516 $ ELSE
 517 $   IF COMPILEWITH_CC3 - FILE_NAME0 .NES. COMPILEWITH_CC3
 518 $   THEN
 519 $     CC3/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 520 $   ELSE
 521 $     IF COMPILEWITH_CC4 - FILE_NAME0 .NES. COMPILEWITH_CC4
 522 $     THEN
 523 $       CC4/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 524 $     ELSE
 525 $       IF COMPILEWITH_CC5 - FILE_NAME0 .NES. COMPILEWITH_CC5
 526 $       THEN
 527 $         CC5/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 528 $       ELSE
 529 $         IF COMPILEWITH_CC6 - FILE_NAME0 .NES. COMPILEWITH_CC6
 530 $         THEN
 531 $           CC6/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 532 $         ELSE
 533 $           CC/OBJECT='OBJECT_FILE' 'SOURCE_FILE'
 534 $         ENDIF
 535 $       ENDIF
 536 $     ENDIF
 537 $   ENDIF
 538 $ ENDIF
 539 $ IF STATE .EQS. "LIB"
 540 $ THEN
 541 $!
 542 $!   Add It To The Library.
 543 $!
 544 $   LIBRARY/REPLACE 'LIB_NAME' 'OBJECT_FILE'
 545 $!
 546 $!   Time To Clean Up The Object File.
 547 $!
 548 $   DELETE 'OBJECT_FILE';*
 549 $ ENDIF
 550 $!
 551 $! Go Back And Do It Again.
 552 $!
 553 $ GOTO NEXT_FILE
 554 $!
 555 $! All Done With This Library Part.
 556 $!
 557 $ FILE_DONE:
 558 $!
 559 $! Time To Build Some Applications
 560 $!
 561 $ IF F$TYPE('APPS_MODULE') .NES. "" .AND. BUILDALL .NES. "LIBRARY"
 562 $ THEN
 563 $   APPLICATION_COUNTER = 0
 564 $ NEXT_APPLICATION:
 565 $   APPLICATION = F$ELEMENT(APPLICATION_COUNTER,";",'APPS_MODULE')
 566 $   IF APPLICATION .EQS. ";" THEN GOTO APPLICATION_DONE
 567 $
 568 $   APPLICATION_COUNTER = APPLICATION_COUNTER + 1
 569 $   APPLICATION_OBJECTS = F$ELEMENT(1,"/",APPLICATION)
 570 $   APPLICATION = F$ELEMENT(0,"/",APPLICATION)
 571 $
 572 $!   WRITE SYS$OUTPUT "DEBUG: SHOW SYMBOL APPLICATION*"
 573 $!   SHOW SYMBOL APPLICATION*
 574 $!
 575 $! Tell the user what happens
 576 $!
 577 $   WRITE SYS$OUTPUT "  ",APPLICATION,".exe"
 578 $!
 579 $! Link The Program.
 580 $!
 581 $   ON ERROR THEN GOTO NEXT_APPLICATION
 582 $!
 583 $! Check To See If We Are To Link With A Specific TCP/IP Library.
 584 $!
 585 $   IF (TCPIP_LIB.NES."")
 586 $   THEN
 587 $!
 588 $!    Link With A TCP/IP Library.
 589 $!
 590 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 591           'OBJ_DIR''APPLICATION_OBJECTS', -
 592           'CRYPTO_LIB'/LIBRARY, -
 593           'TCPIP_LIB','OPT_FILE'/OPTION
 594 $!
 595 $! Else...
 596 $!
 597 $   ELSE
 598 $!
 599 $!    Don't Link With A TCP/IP Library.
 600 $!
 601 $     LINK/'DEBUGGER'/'TRACEBACK'/EXE='EXE_DIR''APPLICATION'.EXE -
 602           'OBJ_DIR''APPLICATION_OBJECTS',-
 603           'CRYPTO_LIB'/LIBRARY, -
 604           'OPT_FILE'/OPTION
 605 $!
 606 $! End The TCP/IP Library Check.
 607 $!
 608 $   ENDIF
 609 $   GOTO NEXT_APPLICATION
 610 $  APPLICATION_DONE:
 611 $ ENDIF
 612 $!
 613 $! Go Back And Get The Next Module.
 614 $!
 615 $ GOTO MODULE_NEXT
 616 $!
 617 $! All Done With This Module.
 618 $!
 619 $ MODULE_DONE:
 620 $!
 621 $! Tell The User That We Are All Done.
 622 $!
 623 $ WRITE SYS$OUTPUT "All Done..."
 624 $ EXIT:
 625 $ GOSUB CLEANUP
 626 $ EXIT
 627 $!
 628 $! Check For The Link Option FIle.
 629 $!
 630 $ CHECK_OPT_FILE:
 631 $!
 632 $! Check To See If We Need To Make A VAX C Option File.
 633 $!
 634 $ IF (COMPILER.EQS."VAXC")
 635 $ THEN
 636 $!
 637 $!  Check To See If We Already Have A VAX C Linker Option File.
 638 $!
 639 $   IF (F$SEARCH(OPT_FILE).EQS."")
 640 $   THEN
 641 $!
 642 $!    We Need A VAX C Linker Option File.
 643 $!
 644 $     CREATE 'OPT_FILE'
 645 $DECK
 646 !
 647 ! Default System Options File To Link Agianst
 648 ! The Sharable VAX C Runtime Library.
 649 !
 650 SYS$SHARE:VAXCRTL.EXE/SHARE
 651 $EOD
 652 $!
 653 $!  End The Option File Check.
 654 $!
 655 $   ENDIF
 656 $!
 657 $! End The VAXC Check.
 658 $!
 659 $ ENDIF
 660 $!
 661 $! Check To See If We Need A GNU C Option File.
 662 $!
 663 $ IF (COMPILER.EQS."GNUC")
 664 $ THEN
 665 $!
 666 $!  Check To See If We Already Have A GNU C Linker Option File.
 667 $!
 668 $   IF (F$SEARCH(OPT_FILE).EQS."")
 669 $   THEN
 670 $!
 671 $!    We Need A GNU C Linker Option File.
 672 $!
 673 $     CREATE 'OPT_FILE'
 674 $DECK
 675 !
 676 ! Default System Options File To Link Agianst
 677 ! The Sharable C Runtime Library.
 678 !
 679 GNU_CC:[000000]GCCLIB/LIBRARY
 680 SYS$SHARE:VAXCRTL/SHARE
 681 $EOD
 682 $!
 683 $!  End The Option File Check.
 684 $!
 685 $   ENDIF
 686 $!
 687 $! End The GNU C Check.
 688 $!
 689 $ ENDIF
 690 $!
 691 $! Check To See If We Need A DEC C Option File.
 692 $!
 693 $ IF (COMPILER.EQS."DECC")
 694 $ THEN
 695 $!
 696 $!  Check To See If We Already Have A DEC C Linker Option File.
 697 $!
 698 $   IF (F$SEARCH(OPT_FILE).EQS."")
 699 $   THEN
 700 $!
 701 $!    Figure Out If We Need A non-VAX Or A VAX Linker Option File.
 702 $!
 703 $     IF ARCH .EQS. "VAX"
 704 $     THEN
 705 $!
 706 $!      We Need A DEC C Linker Option File For VAX.
 707 $!
 708 $       CREATE 'OPT_FILE'
 709 $DECK
 710 !
 711 ! Default System Options File To Link Agianst
 712 ! The Sharable DEC C Runtime Library.
 713 !
 714 SYS$SHARE:DECC$SHR.EXE/SHARE
 715 $EOD
 716 $!
 717 $!    Else...
 718 $!
 719 $     ELSE
 720 $!
 721 $!      Create The non-VAX Linker Option File.
 722 $!
 723 $       CREATE 'OPT_FILE'
 724 $DECK
 725 !
 726 ! Default System Options File For non-VAX To Link Agianst
 727 ! The Sharable C Runtime Library.
 728 !
 729 SYS$SHARE:CMA$OPEN_LIB_SHR/SHARE
 730 SYS$SHARE:CMA$OPEN_RTL/SHARE
 731 $EOD
 732 $!
 733 $!    End The DEC C Option File Check.
 734 $!
 735 $     ENDIF
 736 $!
 737 $!  End The Option File Search.
 738 $!
 739 $   ENDIF
 740 $!
 741 $! End The DEC C Check.
 742 $!
 743 $ ENDIF
 744 $!
 745 $!  Tell The User What Linker Option File We Are Using.
 746 $!
 747 $ WRITE SYS$OUTPUT "Using Linker Option File ",OPT_FILE,"."
 748 $!
 749 $! Time To RETURN.
 750 $!
 751 $ RETURN
 752 $!
 753 $! Check The User's Options.
 754 $!
 755 $ CHECK_OPTIONS:
 756 $!
 757 $! Check To See If P1 Is Blank.
 758 $!
 759 $ IF (P1.EQS."ALL")
 760 $ THEN
 761 $!
 762 $!   P1 Is Blank, So Build Everything.
 763 $!
 764 $    BUILDALL = "TRUE"
 765 $!
 766 $! Else...
 767 $!
 768 $ ELSE
 769 $!
 770 $!  Else, Check To See If P1 Has A Valid Arguement.
 771 $!
 772 $   IF (P1.EQS."LIBRARY").OR.(P1.EQS."APPS")
 773 $   THEN
 774 $!
 775 $!    A Valid Arguement.
 776 $!
 777 $     BUILDALL = P1
 778 $!
 779 $!  Else...
 780 $!
 781 $   ELSE
 782 $!
 783 $!    Tell The User We Don't Know What They Want.
 784 $!
 785 $     WRITE SYS$OUTPUT ""
 786 $     WRITE SYS$OUTPUT "The Option ",P1," Is Invalid.  The Valid Options Are:"
 787 $     WRITE SYS$OUTPUT ""
 788 $     WRITE SYS$OUTPUT "    ALL      :  Just Build Everything."
 789 $     WRITE SYS$OUTPUT "    LIBRARY  :  To Compile Just The [.xxx.EXE.CRYPTO]LIBCRYPTO.OLB Library."
 790 $     WRITE SYS$OUTPUT "    APPS     :  To Compile Just The [.xxx.EXE.CRYPTO]*.EXE Programs."
 791 $     WRITE SYS$OUTPUT ""
 792 $     WRITE SYS$OUTPUT " Where 'xxx' Stands For:"
 793 $     WRITE SYS$OUTPUT ""
 794 $     WRITE SYS$OUTPUT "    ALPHA    :  Alpha Architecture."
 795 $     WRITE SYS$OUTPUT "    IA64     :  IA64 Architecture."
 796 $     WRITE SYS$OUTPUT "    VAX      :  VAX Architecture."
 797 $     WRITE SYS$OUTPUT ""
 798 $!
 799 $!    Time To EXIT.
 800 $!
 801 $     EXIT
 802 $!
 803 $!  End The Valid Arguement Check.
 804 $!
 805 $   ENDIF
 806 $!
 807 $! End The P1 Check.
 808 $!
 809 $ ENDIF
 810 $!
 811 $! Check To See If P2 Is Blank.
 812 $!
 813 $ IF (P2.EQS."NODEBUG")
 814 $ THEN
 815 $!
 816 $!   P2 Is NODEBUG, So Compile Without The Debugger Information.
 817 $!
 818 $    DEBUGGER = "NODEBUG"
 819 $    TRACEBACK = "NOTRACEBACK"
 820 $    GCC_OPTIMIZE = "OPTIMIZE"
 821 $    CC_OPTIMIZE = "OPTIMIZE"
 822 $    MACRO_OPTIMIZE = "OPTIMIZE"
 823 $    WRITE SYS$OUTPUT "No Debugger Information Will Be Produced During Compile."
 824 $    WRITE SYS$OUTPUT "Compiling With Compiler Optimization."
 825 $ ELSE
 826 $!
 827 $!  Check To See If We Are To Compile With Debugger Information.
 828 $!
 829 $   IF (P2.EQS."DEBUG")
 830 $   THEN
 831 $!
 832 $!    Compile With Debugger Information.
 833 $!
 834 $     DEBUGGER = "DEBUG"
 835 $     TRACEBACK = "TRACEBACK"
 836 $     GCC_OPTIMIZE = "NOOPTIMIZE"
 837 $     CC_OPTIMIZE = "NOOPTIMIZE"
 838 $     MACRO_OPTIMIZE = "NOOPTIMIZE"
 839 $     WRITE SYS$OUTPUT "Debugger Information Will Be Produced During Compile."
 840 $     WRITE SYS$OUTPUT "Compiling Without Compiler Optimization."
 841 $   ELSE
 842 $!
 843 $!    They Entered An Invalid Option..
 844 $!
 845 $     WRITE SYS$OUTPUT ""
 846 $     WRITE SYS$OUTPUT "The Option ",P2," Is Invalid.  The Valid Options Are:"
 847 $     WRITE SYS$OUTPUT ""
 848 $     WRITE SYS$OUTPUT "     DEBUG   :  Compile With The Debugger Information."
 849 $     WRITE SYS$OUTPUT "     NODEBUG :  Compile Without The Debugger Information."
 850 $     WRITE SYS$OUTPUT ""
 851 $!
 852 $!    Time To EXIT.
 853 $!
 854 $     EXIT
 855 $!
 856 $!  End The Valid Arguement Check.
 857 $!
 858 $   ENDIF
 859 $!
 860 $! End The P2 Check.
 861 $!
 862 $ ENDIF
 863 $!
 864 $! Special Threads For OpenVMS v7.1 Or Later
 865 $!
 866 $! Written By:  Richard Levitte
 867 $!              richard@levitte.org
 868 $!
 869 $!
 870 $! Check To See If We Have A Option For P5.
 871 $!
 872 $ IF (P5.EQS."")
 873 $ THEN
 874 $!
 875 $!  Get The Version Of VMS We Are Using.
 876 $!
 877 $   ISSEVEN :=
 878 $   TMP = F$ELEMENT(0,"-",F$EXTRACT(1,4,F$GETSYI("VERSION")))
 879 $   TMP = F$INTEGER(F$ELEMENT(0,".",TMP)+F$ELEMENT(1,".",TMP))
 880 $!
 881 $!  Check To See If The VMS Version Is v7.1 Or Later.
 882 $!
 883 $   IF (TMP.GE.71)
 884 $   THEN
 885 $!
 886 $!    We Have OpenVMS v7.1 Or Later, So Use The Special Threads.
 887 $!
 888 $     ISSEVEN := ,PTHREAD_USE_D4
 889 $!
 890 $!  End The VMS Version Check.
 891 $!
 892 $   ENDIF
 893 $!
 894 $! End The P5 Check.
 895 $!
 896 $ ENDIF
 897 $!
 898 $! Check To See If P3 Is Blank.
 899 $!
 900 $ IF (P3.EQS."")
 901 $ THEN
 902 $!
 903 $!  O.K., The User Didn't Specify A Compiler, Let's Try To
 904 $!  Find Out Which One To Use.
 905 $!
 906 $!  Check To See If We Have GNU C.
 907 $!
 908 $   IF (F$TRNLNM("GNU_CC").NES."")
 909 $   THEN
 910 $!
 911 $!    Looks Like GNUC, Set To Use GNUC.
 912 $!
 913 $     P3 = "GNUC"
 914 $!
 915 $!  Else...
 916 $!
 917 $   ELSE
 918 $!
 919 $!    Check To See If We Have VAXC Or DECC.
 920 $!
 921 $     IF (ARCH.NES."VAX").OR.(F$TRNLNM("DECC$CC_DEFAULT").NES."")
 922 $     THEN
 923 $!
 924 $!      Looks Like DECC, Set To Use DECC.
 925 $!
 926 $       P3 = "DECC"
 927 $!
 928 $!    Else...
 929 $!
 930 $     ELSE
 931 $!
 932 $!      Looks Like VAXC, Set To Use VAXC.
 933 $!
 934 $       P3 = "VAXC"
 935 $!
 936 $!    End The VAXC Compiler Check.
 937 $!
 938 $     ENDIF
 939 $!
 940 $!  End The DECC & VAXC Compiler Check.
 941 $!
 942 $   ENDIF
 943 $!
 944 $!  End The Compiler Check.
 945 $!
 946 $ ENDIF
 947 $!
 948 $! Check To See If We Have A Option For P4.
 949 $!
 950 $ IF (P4.EQS."")
 951 $ THEN
 952 $!
 953 $!  Find out what socket library we have available
 954 $!
 955 $   IF F$PARSE("SOCKETSHR:") .NES. ""
 956 $   THEN
 957 $!
 958 $!    We have SOCKETSHR, and it is my opinion that it's the best to use.
 959 $!
 960 $     P4 = "SOCKETSHR"
 961 $!
 962 $!    Tell the user
 963 $!
 964 $     WRITE SYS$OUTPUT "Using SOCKETSHR for TCP/IP"
 965 $!
 966 $!    Else, let's look for something else
 967 $!
 968 $   ELSE
 969 $!
 970 $!    Like UCX (the reason to do this before Multinet is that the UCX
 971 $!    emulation is easier to use...)
 972 $!
 973 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. "" -
 974          .OR. F$PARSE("SYS$SHARE:UCX$IPC_SHR.EXE") .NES. "" -
 975          .OR. F$PARSE("SYS$LIBRARY:UCX$IPC.OLB") .NES. ""
 976 $     THEN
 977 $!
 978 $!      Last resort: a UCX or UCX-compatible library
 979 $!
 980 $       P4 = "UCX"
 981 $!
 982 $!      Tell the user
 983 $!
 984 $       WRITE SYS$OUTPUT "Using UCX or an emulation thereof for TCP/IP"
 985 $!
 986 $!      That was all...
 987 $!
 988 $     ENDIF
 989 $   ENDIF
 990 $ ENDIF
 991 $!
 992 $! Set Up Initial CC Definitions, Possibly With User Ones
 993 $!
 994 $ CCDEFS = "TCPIP_TYPE_''P4',DSO_VMS"
 995 $ IF F$TYPE(USER_CCDEFS) .NES. "" THEN CCDEFS = CCDEFS + "," + USER_CCDEFS
 996 $ CCEXTRAFLAGS = ""
 997 $ IF F$TYPE(USER_CCFLAGS) .NES. "" THEN CCEXTRAFLAGS = USER_CCFLAGS
 998 $ CCDISABLEWARNINGS = "LONGLONGTYPE,LONGLONGSUFX,FOUNDCR"
 999 $ IF F$TYPE(USER_CCDISABLEWARNINGS) .NES. "" THEN -
1000         CCDISABLEWARNINGS = CCDISABLEWARNINGS + "," + USER_CCDISABLEWARNINGS
1001 $!
1002 $!  Check To See If The User Entered A Valid Paramter.
1003 $!
1004 $ IF (P3.EQS."VAXC").OR.(P3.EQS."DECC").OR.(P3.EQS."GNUC")
1005 $ THEN
1006 $!
1007 $!    Check To See If The User Wanted DECC.
1008 $!
1009 $   IF (P3.EQS."DECC")
1010 $   THEN
1011 $!
1012 $!    Looks Like DECC, Set To Use DECC.
1013 $!
1014 $     COMPILER = "DECC"
1015 $!
1016 $!    Tell The User We Are Using DECC.
1017 $!
1018 $     WRITE SYS$OUTPUT "Using DECC 'C' Compiler."
1019 $!
1020 $!    Use DECC...
1021 $!
1022 $     CC = "CC"
1023 $     IF ARCH.EQS."VAX" .AND. F$TRNLNM("DECC$CC_DEFAULT").NES."/DECC" -
1024          THEN CC = "CC/DECC"
1025 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/STANDARD=ANSI89" + -
1026            "/NOLIST/PREFIX=ALL" + -
1027            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS],SYS$DISK:[.EVP])" + -
1028            CCEXTRAFLAGS
1029 $!
1030 $!    Define The Linker Options File Name.
1031 $!
1032 $     OPT_FILE = "''EXE_DIR'VAX_DECC_OPTIONS.OPT"
1033 $!
1034 $!  End DECC Check.
1035 $!
1036 $   ENDIF
1037 $!
1038 $!  Check To See If We Are To Use VAXC.
1039 $!
1040 $   IF (P3.EQS."VAXC")
1041 $   THEN
1042 $!
1043 $!    Looks Like VAXC, Set To Use VAXC.
1044 $!
1045 $     COMPILER = "VAXC"
1046 $!
1047 $!    Tell The User We Are Using VAX C.
1048 $!
1049 $     WRITE SYS$OUTPUT "Using VAXC 'C' Compiler."
1050 $!
1051 $!    Compile Using VAXC.
1052 $!
1053 $     CC = "CC"
1054 $     IF ARCH.NES."VAX"
1055 $     THEN
1056 $       WRITE SYS$OUTPUT "There is no VAX C on ''ARCH'!"
1057 $       EXIT
1058 $     ENDIF
1059 $     IF F$TRNLNM("DECC$CC_DEFAULT").EQS."/DECC" THEN CC = "CC/VAXC"
1060 $     CC = CC + "/''CC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1061            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1062            CCEXTRAFLAGS
1063 $     CCDEFS = """VAXC""," + CCDEFS
1064 $!
1065 $!    Define <sys> As SYS$COMMON:[SYSLIB]
1066 $!
1067 $     DEFINE/NOLOG SYS SYS$COMMON:[SYSLIB]
1068 $!
1069 $!    Define The Linker Options File Name.
1070 $!
1071 $     OPT_FILE = "''EXE_DIR'VAX_VAXC_OPTIONS.OPT"
1072 $!
1073 $!  End VAXC Check
1074 $!
1075 $   ENDIF
1076 $!
1077 $!  Check To See If We Are To Use GNU C.
1078 $!
1079 $   IF (P3.EQS."GNUC")
1080 $   THEN
1081 $!
1082 $!    Looks Like GNUC, Set To Use GNUC.
1083 $!
1084 $     COMPILER = "GNUC"
1085 $!
1086 $!    Tell The User We Are Using GNUC.
1087 $!
1088 $     WRITE SYS$OUTPUT "Using GNU 'C' Compiler."
1089 $!
1090 $!    Use GNU C...
1091 $!
1092 $     CC = "GCC/NOCASE_HACK/''GCC_OPTIMIZE'/''DEBUGGER'/NOLIST" + -
1093            "/INCLUDE=(SYS$DISK:[],SYS$DISK:[.''ARCH'],SYS$DISK:[-],SYS$DISK:[.ENGINE.VENDOR_DEFNS])" + -
1094            CCEXTRAFLAGS
1095 $!
1096 $!    Define The Linker Options File Name.
1097 $!
1098 $     OPT_FILE = "''EXE_DIR'VAX_GNUC_OPTIONS.OPT"
1099 $!
1100 $!  End The GNU C Check.
1101 $!
1102 $   ENDIF
1103 $!
1104 $!  Set up default defines
1105 $!
1106 $   CCDEFS = """FLAT_INC=1""," + CCDEFS
1107 $!
1108 $!  Finish up the definition of CC.
1109 $!
1110 $   IF COMPILER .EQS. "DECC"
1111 $   THEN
1112 $     IF CCDISABLEWARNINGS .EQS. ""
1113 $     THEN
1114 $       CC4DISABLEWARNINGS = "DOLLARID"
1115 $       CC6DISABLEWARNINGS = "MIXLINKAGE"
1116 $     ELSE
1117 $       CC4DISABLEWARNINGS = CCDISABLEWARNINGS + ",DOLLARID"
1118 $       CC6DISABLEWARNINGS = CCDISABLEWARNINGS + ",MIXLINKAGE"
1119 $       CCDISABLEWARNINGS = "/WARNING=(DISABLE=(" + CCDISABLEWARNINGS + "))"
1120 $     ENDIF
1121 $     CC4DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC4DISABLEWARNINGS + "))"
1122 $     CC6DISABLEWARNINGS = "/WARNING=(DISABLE=(" + CC6DISABLEWARNINGS + "))"
1123 $   ELSE
1124 $     CCDISABLEWARNINGS = ""
1125 $     CC4DISABLEWARNINGS = ""
1126 $     CC6DISABLEWARNINGS = ""
1127 $   ENDIF
1128 $   CC3 = CC + "/DEFINE=(" + CCDEFS + ISSEVEN + ")" + CCDISABLEWARNINGS
1129 $   CC = CC + "/DEFINE=(" + CCDEFS + ")" + CCDISABLEWARNINGS
1130 $   IF ARCH .EQS. "VAX" .AND. COMPILER .EQS. "DECC" .AND. P2 .NES. "DEBUG"
1131 $   THEN
1132 $     CC5 = CC + "/OPTIMIZE=NODISJOINT"
1133 $   ELSE
1134 $     CC5 = CC + "/NOOPTIMIZE"
1135 $   ENDIF
1136 $   CC4 = CC - CCDISABLEWARNINGS + CC4DISABLEWARNINGS
1137 $   CC6 = CC - CCDISABLEWARNINGS + CC6DISABLEWARNINGS
1138 $!
1139 $!  Show user the result
1140 $!
1141 $   WRITE/SYMBOL SYS$OUTPUT "Main C Compiling Command: ",CC
1142 $!
1143 $!  Else The User Entered An Invalid Arguement.
1144 $!
1145 $ ELSE
1146 $!
1147 $!  Tell The User We Don't Know What They Want.
1148 $!
1149 $   WRITE SYS$OUTPUT ""
1150 $   WRITE SYS$OUTPUT "The Option ",P3," Is Invalid.  The Valid Options Are:"
1151 $   WRITE SYS$OUTPUT ""
1152 $   WRITE SYS$OUTPUT "    VAXC  :  To Compile With VAX C."
1153 $   WRITE SYS$OUTPUT "    DECC  :  To Compile With DEC C."
1154 $   WRITE SYS$OUTPUT "    GNUC  :  To Compile With GNU C."
1155 $   WRITE SYS$OUTPUT ""
1156 $!
1157 $!  Time To EXIT.
1158 $!
1159 $   EXIT
1160 $!
1161 $! End The Valid Arguement Check.
1162 $!
1163 $ ENDIF
1164 $!
1165 $! Build a MACRO command for the architecture at hand
1166 $!
1167 $ IF ARCH .EQS. "VAX" THEN MACRO = "MACRO/''DEBUGGER'"
1168 $ IF ARCH .NES. "VAX" THEN MACRO = "MACRO/MIGRATION/''DEBUGGER'/''MACRO_OPTIMIZE'"
1169 $!
1170 $!  Show user the result
1171 $!
1172 $   WRITE/SYMBOL SYS$OUTPUT "Main MACRO Compiling Command: ",MACRO
1173 $!
1174 $! Time to check the contents, and to make sure we get the correct library.
1175 $!
1176 $ IF P4.EQS."SOCKETSHR" .OR. P4.EQS."MULTINET" .OR. P4.EQS."UCX" -
1177      .OR. P4.EQS."TCPIP" .OR. P4.EQS."NONE"
1178 $ THEN
1179 $!
1180 $!  Check to see if SOCKETSHR was chosen
1181 $!
1182 $   IF P4.EQS."SOCKETSHR"
1183 $   THEN
1184 $!
1185 $!    Set the library to use SOCKETSHR
1186 $!
1187 $     TCPIP_LIB = "SYS$DISK:[-.VMS]SOCKETSHR_SHR.OPT/OPT"
1188 $!
1189 $!    Done with SOCKETSHR
1190 $!
1191 $   ENDIF
1192 $!
1193 $!  Check to see if MULTINET was chosen
1194 $!
1195 $   IF P4.EQS."MULTINET"
1196 $   THEN
1197 $!
1198 $!    Set the library to use UCX emulation.
1199 $!
1200 $     P4 = "UCX"
1201 $!
1202 $!    Done with MULTINET
1203 $!
1204 $   ENDIF
1205 $!
1206 $!  Check to see if UCX was chosen
1207 $!
1208 $   IF P4.EQS."UCX"
1209 $   THEN
1210 $!
1211 $!    Set the library to use UCX.
1212 $!
1213 $     TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC.OPT/OPT"
1214 $     IF F$TRNLNM("UCX$IPC_SHR") .NES. ""
1215 $     THEN
1216 $       TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_DECC_LOG.OPT/OPT"
1217 $     ELSE
1218 $       IF COMPILER .NES. "DECC" .AND. ARCH .EQS. "VAX" THEN -
1219           TCPIP_LIB = "SYS$DISK:[-.VMS]UCX_SHR_VAXC.OPT/OPT"
1220 $     ENDIF
1221 $!
1222 $!    Done with UCX
1223 $!
1224 $   ENDIF
1225 $!
1226 $!  Check to see if TCPIP was chosen
1227 $!
1228 $   IF P4.EQS."TCPIP"
1229 $   THEN
1230 $!
1231 $!    Set the library to use TCPIP (post UCX).
1232 $!
1233 $     TCPIP_LIB = "SYS$DISK:[-.VMS]TCPIP_SHR_DECC.OPT/OPT"
1234 $!
1235 $!    Done with TCPIP
1236 $!
1237 $   ENDIF
1238 $!
1239 $!  Check to see if NONE was chosen
1240 $!
1241 $   IF P4.EQS."NONE"
1242 $   THEN
1243 $!
1244 $!    Do not use a TCPIP library.
1245 $!
1246 $     TCPIP_LIB = ""
1247 $!
1248 $!    Done with TCPIP
1249 $!
1250 $   ENDIF
1251 $!
1252 $!  Print info
1253 $!
1254 $   WRITE SYS$OUTPUT "TCP/IP library spec: ", TCPIP_LIB
1255 $!
1256 $!  Else The User Entered An Invalid Arguement.
1257 $!
1258 $ ELSE
1259 $!
1260 $!  Tell The User We Don't Know What They Want.
1261 $!
1262 $   WRITE SYS$OUTPUT ""
1263 $   WRITE SYS$OUTPUT "The Option ",P4," Is Invalid.  The Valid Options Are:"
1264 $   WRITE SYS$OUTPUT ""
1265 $   WRITE SYS$OUTPUT "    SOCKETSHR  :  To link with SOCKETSHR TCP/IP library."
1266 $   WRITE SYS$OUTPUT "    UCX        :  To link with UCX TCP/IP library."
1267 $   WRITE SYS$OUTPUT "    TCPIP      :  To link with TCPIP (post UCX) TCP/IP library."
1268 $   WRITE SYS$OUTPUT ""
1269 $!
1270 $!  Time To EXIT.
1271 $!
1272 $   EXIT
1273 $!
1274 $!  Done with TCP/IP libraries
1275 $!
1276 $ ENDIF
1277 $!
1278 $! Check if the user wanted to compile just a subset of all the encryption
1279 $! methods.
1280 $!
1281 $ IF P6 .NES. ""
1282 $ THEN
1283 $   ENCRYPT_TYPES = P6
1284 $ ENDIF
1285 $!
1286 $!  Time To RETURN...
1287 $!
1288 $ RETURN
1289 $!
1290 $ INITIALISE:
1291 $!
1292 $! Save old value of the logical name OPENSSL
1293 $!
1294 $ __SAVE_OPENSSL = F$TRNLNM("OPENSSL","LNM$PROCESS_TABLE")
1295 $!
1296 $! Save directory information
1297 $!
1298 $ __HERE = F$PARSE(F$PARSE("A.;",F$ENVIRONMENT("PROCEDURE"))-"A.;","[]A.;") - "A.;"
1299 $ __HERE = F$EDIT(__HERE,"UPCASE")
1300 $ __TOP = __HERE - "CRYPTO]"
1301 $ __INCLUDE = __TOP + "INCLUDE.OPENSSL]"
1302 $!
1303 $! Set up the logical name OPENSSL to point at the include directory
1304 $!
1305 $ DEFINE OPENSSL/NOLOG '__INCLUDE'
1306 $!
1307 $! Done
1308 $!
1309 $ RETURN
1310 $!
1311 $ CLEANUP:
1312 $!
1313 $! Restore the logical name OPENSSL if it had a value
1314 $!
1315 $ IF __SAVE_OPENSSL .EQS. ""
1316 $ THEN
1317 $   DEASSIGN OPENSSL
1318 $ ELSE
1319 $   DEFINE/NOLOG OPENSSL '__SAVE_OPENSSL'
1320 $ ENDIF
1321 $!
1322 $! Done
1323 $!
1324 $ RETURN