crypto/aes/asm/vpaes-ppc.pl

   1 #!/usr/bin/env perl
   2
   3 ######################################################################
   4 ## Constant-time SSSE3 AES core implementation.
   5 ## version 0.1
   6 ##
   7 ## By Mike Hamburg (Stanford University), 2009
   8 ## Public domain.
   9 ##
  10 ## For details see http://shiftleft.org/papers/vector_aes/ and
  11 ## http://crypto.stanford.edu/vpaes/.
  12
  13 # CBC encrypt/decrypt performance in cycles per byte processed with
  14 # 128-bit key.
  15 #
  16 #               aes-ppc.pl              this
  17 # G4e           35.5/52.1/(23.8)        11.9(*)/15.4
  18 # POWER6        42.7/54.3/(28.2)        63.0/92.8(**)
  19 # POWER7        32.3/42.9/(18.4)        18.5/23.3
  20 #
  21 # (*)   This is ~10% worse than reported in paper. The reason is
  22 #       twofold. This module doesn't make any assumption about
  23 #       key schedule (or data for that matter) alignment and handles
  24 #       it in-line. Secondly it, being transliterated from
  25 #       vpaes-x86_64.pl, relies on "nested inversion" better suited
  26 #       for Intel CPUs.
  27 # (**)  Inadequate POWER6 performance is due to astronomic AltiVec
  28 #       latency, 9 cycles per simple logical operation.
  29
  30 $flavour = shift;
  31
  32 if ($flavour =~ /64/) {
  33         $SIZE_T =8;
  34         $LRSAVE =2*$SIZE_T;
  35         $STU    ="stdu";
  36         $POP    ="ld";
  37         $PUSH   ="std";
  38 } elsif ($flavour =~ /32/) {
  39         $SIZE_T =4;
  40         $LRSAVE =$SIZE_T;
  41         $STU    ="stwu";
  42         $POP    ="lwz";
  43         $PUSH   ="stw";
  44 } else { die "nonsense $flavour"; }
  45
  46 $sp="r1";
  47 $FRAME=8*$SIZE_T;
  48
  49 $0 =~ m/(.*[\/\\])[^\/\\]+$/; $dir=$1;
  50 ( $xlate="${dir}ppc-xlate.pl" and -f $xlate ) or
  51 ( $xlate="${dir}../../perlasm/ppc-xlate.pl" and -f $xlate) or
  52 die "can't locate ppc-xlate.pl";
  53
  54 open STDOUT,"| $^X $xlate $flavour ".shift || die "can't call $xlate: $!";
  55
  56 $code.=<<___;
  57 .machine        "any"
  58
  59 .text
  60
  61 .align  7       # totally strategic alignment
  62 _vpaes_consts:
  63 Lk_mc_forward:  # mc_forward
  64         .long   0x01020300, 0x05060704, 0x090a0b08, 0x0d0e0f0c
  65         .long   0x05060704, 0x090a0b08, 0x0d0e0f0c, 0x01020300
  66         .long   0x090a0b08, 0x0d0e0f0c, 0x01020300, 0x05060704
  67         .long   0x0d0e0f0c, 0x01020300, 0x05060704, 0x090a0b08
  68 Lk_mc_backward: # mc_backward
  69         .long   0x03000102, 0x07040506, 0x0b08090a, 0x0f0c0d0e
  70         .long   0x0f0c0d0e, 0x03000102, 0x07040506, 0x0b08090a
  71         .long   0x0b08090a, 0x0f0c0d0e, 0x03000102, 0x07040506
  72         .long   0x07040506, 0x0b08090a, 0x0f0c0d0e, 0x03000102
  73 Lk_sr:          # sr
  74         .long   0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
  75         .long   0x00050a0f, 0x04090e03, 0x080d0207, 0x0c01060b
  76         .long   0x0009020b, 0x040d060f, 0x08010a03, 0x0c050e07
  77         .long   0x000d0a07, 0x04010e0b, 0x0805020f, 0x0c090603
  78
  79 ##
  80 ## "Hot" constants
  81 ##
  82 Lk_inv:         # inv, inva
  83         .long   0xf001080d, 0x0f06050e, 0x020c0b0a, 0x09030704
  84         .long   0xf0070b0f, 0x060a0401, 0x09080502, 0x0c0e0d03
  85 Lk_ipt:         # input transform (lo, hi)
  86         .long   0x00702a5a, 0x98e8b2c2, 0x08782252, 0x90e0baca
  87         .long   0x004d7c31, 0x7d30014c, 0x81ccfdb0, 0xfcb180cd
  88 Lk_sbo:         # sbou, sbot
  89         .long   0x00c7bd6f, 0x176dd2d0, 0x78a802c5, 0x7abfaa15
  90         .long   0x006abb5f, 0xa574e4cf, 0xfa352b41, 0xd1901e8e
  91 Lk_sb1:         # sb1u, sb1t
  92         .long   0x0023e2fa, 0x15d41836, 0xefd92e0d, 0xc1ccf73b
  93         .long   0x003e50cb, 0x8fe19bb1, 0x44f52a14, 0x6e7adfa5
  94 Lk_sb2:         # sb2u, sb2t
  95         .long   0x0029e10a, 0x4088eb69, 0x4a2382ab, 0xc863a1c2
  96         .long   0x0024710b, 0xc6937ae2, 0xcd2f98bc, 0x55e9b75e
  97
  98 ##
  99 ##  Decryption stuff
 100 ##
 101 Lk_dipt:        # decryption input transform
 102         .long   0x005f540b, 0x045b500f, 0x1a454e11, 0x1e414a15
 103         .long   0x00650560, 0xe683e386, 0x94f191f4, 0x72177712
 104 Lk_dsbo:        # decryption sbox final output
 105         .long   0x0040f97e, 0x53ea8713, 0x2d3e94d4, 0xb96daac7
 106         .long   0x001d4493, 0x0f56d712, 0x9c8ec5d8, 0x59814bca
 107 Lk_dsb9:        # decryption sbox output *9*u, *9*t
 108         .long   0x00d6869a, 0x53031c85, 0xc94c994f, 0x501fd5ca
 109         .long   0x0049d7ec, 0x89173bc0, 0x65a5fbb2, 0x9e2c5e72
 110 Lk_dsbd:        # decryption sbox output *D*u, *D*t
 111         .long   0x00a2b1e6, 0xdfcc577d, 0x39442a88, 0x139b6ef5
 112         .long   0x00cbc624, 0xf7fae23c, 0xd3efde15, 0x0d183129
 113 Lk_dsbb:        # decryption sbox output *B*u, *B*t
 114         .long   0x0042b496, 0x926422d0, 0x04d4f2b0, 0xf6462660
 115         .long   0x006759cd, 0xa69894c1, 0x6baa5532, 0x3e0cfff3
 116 Lk_dsbe:        # decryption sbox output *E*u, *E*t
 117         .long   0x00d0d426, 0x9692f246, 0xb0f6b464, 0x04604222
 118         .long   0x00c1aaff, 0xcda6550c, 0x323e5998, 0x6bf36794
 119
 120 ##
 121 ##  Key schedule constants
 122 ##
 123 Lk_dksd:        # decryption key schedule: invskew x*D
 124         .long   0x0047e4a3, 0x5d1ab9fe, 0xf9be1d5a, 0xa4e34007
 125         .long   0x008336b5, 0xf477c241, 0x1e9d28ab, 0xea69dc5f
 126 Lk_dksb:        # decryption key schedule: invskew x*B
 127         .long   0x00d55085, 0x1fca4f9a, 0x994cc91c, 0x8653d603
 128         .long   0x004afcb6, 0xa7ed5b11, 0xc882347e, 0x6f2593d9
 129 Lk_dkse:        # decryption key schedule: invskew x*E + 0x63
 130         .long   0x00d6c91f, 0xca1c03d5, 0x86504f99, 0x4c9a8553
 131         .long   0xe87bdc4f, 0x059631a2, 0x8714b320, 0x6af95ecd
 132 Lk_dks9:        # decryption key schedule: invskew x*9
 133         .long   0x00a7d97e, 0xc86f11b6, 0xfc5b2582, 0x3493ed4a
 134         .long   0x00331427, 0x62517645, 0xcefddae9, 0xac9fb88b
 135
 136 Lk_rcon:        # rcon
 137         .long   0xb6ee9daf, 0xb991831f, 0x817d7c4d, 0x08982a70
 138 Lk_s63:
 139         .long   0x5b5b5b5b, 0x5b5b5b5b, 0x5b5b5b5b, 0x5b5b5b5b
 140
 141 Lk_opt:         # output transform
 142         .long   0x0060b6d6, 0x29499fff, 0x0868bede, 0x214197f7
 143         .long   0x00ecbc50, 0x51bded01, 0xe00c5cb0, 0xb15d0de1
 144 Lk_deskew:      # deskew tables: inverts the sbox's "skew"
 145         .long   0x00e3a447, 0x40a3e407, 0x1af9be5d, 0x5ab9fe1d
 146         .long   0x0069ea83, 0xdcb5365f, 0x771e9df4, 0xabc24128
 147 .align  5
 148 Lconsts:
 149         mflr    r0
 150         bcl     20,31,\$+4
 151         mflr    r12     #vvvvv "distance between . and _vpaes_consts
 152         addi    r12,r12,-0x308
 153         mtlr    r0
 154         blr
 155         .long   0
 156         .byte   0,12,0x14,0,0,0,0,0
 157 .asciz  "Vector Permutaion AES for AltiVec, Mike Hamburg (Stanford University)"
 158 .align  6
 159 ___
 160 \f
 161 my ($inptail,$inpperm,$outhead,$outperm,$outmask,$keyperm) = map("v$_",(26..31));
 162 {
 163 my ($inp,$out,$key) = map("r$_",(3..5));
 164
 165 my ($invlo,$invhi,$iptlo,$ipthi,$sbou,$sbot) = map("v$_",(10..15));
 166 my ($sb1u,$sb1t,$sb2u,$sb2t) = map("v$_",(16..19));
 167 my ($sb9u,$sb9t,$sbdu,$sbdt,$sbbu,$sbbt,$sbeu,$sbet)=map("v$_",(16..23));
 168
 169 $code.=<<___;
 170 ##
 171 ##  _aes_preheat
 172 ##
 173 ##  Fills register %r10 -> .aes_consts (so you can -fPIC)
 174 ##  and %xmm9-%xmm15 as specified below.
 175 ##
 176 .align  4
 177 _vpaes_encrypt_preheat:
 178         mflr    r8
 179         bl      Lconsts
 180         mtlr    r8
 181         li      r11, 0xc0               # Lk_inv
 182         li      r10, 0xd0
 183         li      r9,  0xe0               # Lk_ipt
 184         li      r8,  0xf0
 185         vxor    v7, v7, v7              # 0x00..00
 186         vspltisb        v8,4            # 0x04..04
 187         vspltisb        v9,0x0f         # 0x0f..0f
 188         lvx     $invlo, r12, r11
 189         li      r11, 0x100
 190         lvx     $invhi, r12, r10
 191         li      r10, 0x110
 192         lvx     $iptlo, r12, r9
 193         li      r9,  0x120
 194         lvx     $ipthi, r12, r8
 195         li      r8,  0x130
 196         lvx     $sbou, r12, r11
 197         li      r11, 0x140
 198         lvx     $sbot, r12, r10
 199         li      r10, 0x150
 200         lvx     $sb1u, r12, r9
 201         lvx     $sb1t, r12, r8
 202         lvx     $sb2u, r12, r11
 203         lvx     $sb2t, r12, r10
 204         blr
 205         .long   0
 206         .byte   0,12,0x14,0,0,0,0,0
 207
 208 ##
 209 ##  _aes_encrypt_core
 210 ##
 211 ##  AES-encrypt %xmm0.
 212 ##
 213 ##  Inputs:
 214 ##     %xmm0 = input
 215 ##     %xmm9-%xmm15 as in _vpaes_preheat
 216 ##    (%rdx) = scheduled keys
 217 ##
 218 ##  Output in %xmm0
 219 ##  Clobbers  %xmm1-%xmm6, %r9, %r10, %r11, %rax
 220 ##
 221 ##
 222 .align 5
 223 _vpaes_encrypt_core:
 224         lwz     r8, 240($key)           # pull rounds
 225         li      r9, 16
 226         lvx     v5, 0, $key             # vmovdqu       (%r9),  %xmm5           # round0 key
 227         li      r11, 0x10
 228         lvx     v6, r9, $key
 229         addi    r9, r9, 16
 230         vperm   v5, v5, v6, $keyperm    # align round key
 231         addi    r10, r11, 0x40
 232         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
 233         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm1
 234         vperm   v1, $ipthi, $ipthi, v1  # vpshufb       %xmm0,  %xmm3,  %xmm2
 235         vxor    v0, v0, v5              # vpxor %xmm5,  %xmm1,  %xmm0
 236         vxor    v0, v0, v1              # vpxor %xmm2,  %xmm0,  %xmm0
 237         mtctr   r8
 238         b       Lenc_entry
 239
 240 .align 4
 241 Lenc_loop:
 242         # middle of middle round
 243         vperm   v4, $sb1t, v7, v2       # vpshufb       %xmm2,  %xmm13, %xmm4   # 4 = sb1u
 244         lvx     v1, r12, r11            # vmovdqa       -0x40(%r11,%r10), %xmm1 # .Lk_mc_forward[]
 245         addi    r11, r11, 16
 246         vperm   v0, $sb1u, v7, v3       # vpshufb       %xmm3,  %xmm12, %xmm0   # 0 = sb1t
 247         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = sb1u + k
 248         andi.   r11, r11, 0x30          # and           \$0x30, %r11    # ... mod 4
 249         vperm   v5, $sb2t, v7, v2       # vpshufb       %xmm2,  %xmm15, %xmm5   # 4 = sb2u
 250         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0,  %xmm0   # 0 = A
 251         vperm   v2, $sb2u, v7, v3       # vpshufb       %xmm3,  %xmm14, %xmm2   # 2 = sb2t
 252         lvx     v4, r12, r10            # vmovdqa       (%r11,%r10), %xmm4      # .Lk_mc_backward[]
 253         addi    r10, r11, 0x40
 254         vperm   v3, v0, v7, v1          # vpshufb       %xmm1,  %xmm0,  %xmm3   # 0 = B
 255         vxor    v2, v2, v5              # vpxor         %xmm5,  %xmm2,  %xmm2   # 2 = 2A
 256         vperm   v0, v0, v7, v4          # vpshufb       %xmm4,  %xmm0,  %xmm0   # 3 = D
 257         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3   # 0 = 2A+B
 258         vperm   v4, v3, v7, v1          # vpshufb       %xmm1,  %xmm3,  %xmm4   # 0 = 2B+C
 259         vxor    v0, v0, v3              # vpxor         %xmm3,  %xmm0,  %xmm0   # 3 = 2A+B+D
 260         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0, %xmm0    # 0 = 2A+3B+C+D
 261
 262 Lenc_entry:
 263         # top of round
 264         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0   # 1 = i
 265         vperm   v5, $invhi, $invhi, v0  # vpshufb       %xmm1,  %xmm11, %xmm5   # 2 = a/k
 266         vxor    v0, v0, v1              # vpxor         %xmm0,  %xmm1,  %xmm1   # 0 = j
 267         vperm   v3, $invlo, $invlo, v1  # vpshufb       %xmm0,  %xmm10, %xmm3   # 3 = 1/i
 268         vperm   v4, $invlo, $invlo, v0  # vpshufb       %xmm1,  %xmm10, %xmm4   # 4 = 1/j
 269         vand    v0, v0, v9
 270         vxor    v3, v3, v5              # vpxor         %xmm5,  %xmm3,  %xmm3   # 3 = iak = 1/i + a/k
 271         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = jak = 1/j + a/k
 272         vperm   v2, $invlo, v7, v3      # vpshufb       %xmm3,  %xmm10, %xmm2   # 2 = 1/iak
 273         vmr     v5, v6
 274         lvx     v6, r9, $key            # vmovdqu       (%r9), %xmm5
 275         vperm   v3, $invlo, v7, v4      # vpshufb       %xmm4,  %xmm10, %xmm3   # 3 = 1/jak
 276         addi    r9, r9, 16
 277         vxor    v2, v2, v0              # vpxor         %xmm1,  %xmm2,  %xmm2   # 2 = io
 278         vperm   v5, v5, v6, $keyperm    # align round key
 279         vxor    v3, v3, v1              # vpxor         %xmm0,  %xmm3,  %xmm3   # 3 = jo
 280         bdnz    Lenc_loop
 281
 282         # middle of last round
 283         addi    r10, r11, 0x80
 284                                         # vmovdqa       -0x60(%r10), %xmm4      # 3 : sbou      .Lk_sbo
 285                                         # vmovdqa       -0x50(%r10), %xmm0      # 0 : sbot      .Lk_sbo+16
 286         vperm   v4, $sbou, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4   # 4 = sbou
 287         lvx     v1, r12, r10            # vmovdqa       0x40(%r11,%r10), %xmm1  # .Lk_sr[]
 288         vperm   v0, $sbot, v7, v3       # vpshufb       %xmm3,  %xmm0,  %xmm0   # 0 = sb1t
 289         vxor    v4, v4, v5              # vpxor         %xmm5,  %xmm4,  %xmm4   # 4 = sb1u + k
 290         vxor    v0, v0, v4              # vpxor         %xmm4,  %xmm0,  %xmm0   # 0 = A
 291         vperm   v0, v0, v7, v1          # vpshufb       %xmm1,  %xmm0,  %xmm0
 292         blr
 293         .long   0
 294         .byte   0,12,0x14,0,0,0,0,0
 295
 296 .globl  .vpaes_encrypt
 297 .align  5
 298 .vpaes_encrypt:
 299         mflr    r6
 300         mfspr   r7, 256                 # save vrsave
 301         li      r0, -1
 302         $PUSH   r6,$LRSAVE($sp)
 303         mtspr   256, r0                 # preserve all AltiVec registers
 304
 305         bl      _vpaes_encrypt_preheat
 306
 307         lvx     v0, 0, $inp
 308         neg     r8, $inp                # prepare for unaligned access
 309         lvsl    $keyperm, 0, $key
 310          lvsr   $outperm, 0, $out
 311         lvsr    $inpperm, 0, r8         # -$inp
 312          vnor   $outmask, v7, v7        # 0xff..ff
 313         lvx     $inptail, 0, $inp
 314          vperm  $outmask, v7, $outmask, $outperm
 315         addi    $inp, $inp, 15          # 15 is not a typo
 316          lvx    $outhead, 0, $out
 317
 318         ########
 319         vmr     v0, $inptail
 320         lvx     $inptail, 0, $inp       # redundant in aligned case
 321         addi    $inp, $inp, 16
 322         vperm   v0, v0, $inptail, $inpperm
 323
 324         bl      _vpaes_encrypt_core
 325
 326         vperm   v0, v0, v0, $outperm    # rotate left
 327         vsel    v1, $outhead, v0, $outmask
 328         vmr     $outhead, v0
 329         stvx    v1, 0, $out
 330         addi    $out, $out, 15          # 15 is not a typo
 331         ########
 332
 333         lvx     v1, 0, $out             # redundant in aligned case
 334         vsel    v1, $outhead, v1, $outmask
 335         stvx    v1, 0, $out
 336
 337         mtlr    r6
 338         mtspr   256, r7                 # restore vrsave
 339         blr
 340         .long   0
 341         .byte   0,12,0x14,1,0,0,3,0
 342         .long   0
 343 .size   .vpaes_encrypt,.-.vpaes_encrypt
 344
 345 .align  4
 346 _vpaes_decrypt_preheat:
 347         mflr    r8
 348         bl      Lconsts
 349         mtlr    r8
 350         li      r11, 0xc0               # Lk_inv
 351         li      r10, 0xd0
 352         li      r9,  0x160              # Ldipt
 353         li      r8,  0x170
 354         vxor    v7, v7, v7              # 0x00..00
 355         vspltisb        v8,4            # 0x04..04
 356         vspltisb        v9,0x0f         # 0x0f..0f
 357         lvx     $invlo, r12, r11
 358         li      r11, 0x180
 359         lvx     $invhi, r12, r10
 360         li      r10, 0x190
 361         lvx     $iptlo, r12, r9
 362         li      r9,  0x1a0
 363         lvx     $ipthi, r12, r8
 364         li      r8,  0x1b0
 365         lvx     $sbou, r12, r11
 366         li      r11, 0x1c0
 367         lvx     $sbot, r12, r10
 368         li      r10, 0x1d0
 369         lvx     $sb9u, r12, r9
 370         li      r9,  0x1e0
 371         lvx     $sb9t, r12, r8
 372         li      r8,  0x1f0
 373         lvx     $sbdu, r12, r11
 374         li      r11, 0x200
 375         lvx     $sbdt, r12, r10
 376         li      r10, 0x210
 377         lvx     $sbbu, r12, r9
 378         lvx     $sbbt, r12, r8
 379         lvx     $sbeu, r12, r11
 380         lvx     $sbet, r12, r10
 381         blr
 382         .long   0
 383         .byte   0,12,0x14,0,0,0,0,0
 384
 385 ##
 386 ##  Decryption core
 387 ##
 388 ##  Same API as encryption core.
 389 ##
 390 .align  4
 391 _vpaes_decrypt_core:
 392         lwz     r8, 240($key)           # pull rounds
 393         li      r9, 16
 394         lvx     v5, 0, $key             # vmovdqu       (%r9),  %xmm4           # round0 key
 395         li      r11, 0x30
 396         lvx     v6, r9, $key
 397         addi    r9, r9, 16
 398         vperm   v5, v5, v6, $keyperm    # align round key
 399         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
 400         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm2
 401         vperm   v1, $ipthi, $ipthi, v1  # vpshufb       %xmm0,  %xmm1,  %xmm0
 402         vxor    v0, v0, v5              # vpxor %xmm4,  %xmm2,  %xmm2
 403         vxor    v0, v0, v1              # vpxor %xmm2,  %xmm0,  %xmm0
 404         mtctr   r8
 405         b       Ldec_entry
 406
 407 .align 4
 408 Ldec_loop:
 409 #
 410 #  Inverse mix columns
 411 #
 412         lvx     v0, r12, r11            # v5 and v0 are flipped
 413                                         # vmovdqa       -0x20(%r10),%xmm4               # 4 : sb9u
 414                                         # vmovdqa       -0x10(%r10),%xmm1               # 0 : sb9t
 415         vperm   v4, $sb9u, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sb9u
 416         subi    r11, r11, 16
 417         vperm   v1, $sb9t, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sb9t
 418         andi.   r11, r11, 0x30
 419         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0
 420                                         # vmovdqa       0x00(%r10),%xmm4                # 4 : sbdu
 421         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
 422                                         # vmovdqa       0x10(%r10),%xmm1                # 0 : sbdt
 423
 424         vperm   v4, $sbdu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbdu
 425         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
 426         vperm   v1, $sbdt, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbdt
 427         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
 428                                         # vmovdqa       0x20(%r10),     %xmm4           # 4 : sbbu
 429         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
 430                                         # vmovdqa       0x30(%r10),     %xmm1           # 0 : sbbt
 431
 432         vperm   v4, $sbbu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbbu
 433         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
 434         vperm   v1, $sbbt, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbbt
 435         vxor    v5, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
 436                                         # vmovdqa       0x40(%r10),     %xmm4           # 4 : sbeu
 437         vxor    v5, v5, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
 438                                         # vmovdqa       0x50(%r10),     %xmm1           # 0 : sbet
 439
 440         vperm   v4, $sbeu, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4           # 4 = sbeu
 441         vperm   v5, v5, v7, v0          # vpshufb       %xmm5,  %xmm0,  %xmm0           # MC ch
 442         vperm   v1, $sbet, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1           # 0 = sbet
 443         vxor    v0, v5, v4              # vpxor         %xmm4,  %xmm0,  %xmm0           # 4 = ch
 444         vxor    v0, v0, v1              # vpxor         %xmm1,  %xmm0,  %xmm0           # 0 = ch
 445
 446 Ldec_entry:
 447         # top of round
 448         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0   # 1 = i
 449         vperm   v2, $invhi, $invhi, v0  # vpshufb       %xmm1,  %xmm11, %xmm2   # 2 = a/k
 450         vxor    v0, v0, v1              # vpxor         %xmm0,  %xmm1,  %xmm1   # 0 = j
 451         vperm   v3, $invlo, $invlo, v1  # vpshufb       %xmm0,  %xmm10, %xmm3   # 3 = 1/i
 452         vperm   v4, $invlo, $invlo, v0  # vpshufb       %xmm1,  %xmm10, %xmm4   # 4 = 1/j
 453         vand    v0, v0, v9
 454         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3   # 3 = iak = 1/i + a/k
 455         vxor    v4, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm4   # 4 = jak = 1/j + a/k
 456         vperm   v2, $invlo, v7, v3      # vpshufb       %xmm3,  %xmm10, %xmm2   # 2 = 1/iak
 457         vmr     v5, v6
 458         lvx     v6, r9, $key            # vmovdqu       (%r9),  %xmm0
 459         vperm   v3, $invlo, v7, v4      # vpshufb       %xmm4,  %xmm10, %xmm3   # 3 = 1/jak
 460         addi    r9, r9, 16
 461         vxor    v2, v2, v0              # vpxor         %xmm1,  %xmm2,  %xmm2   # 2 = io
 462         vperm   v5, v5, v6, $keyperm    # align round key
 463         vxor    v3, v3, v1              # vpxor         %xmm0,  %xmm3,  %xmm3   # 3 = jo
 464         bdnz    Ldec_loop
 465
 466         # middle of last round
 467         addi    r10, r11, 0x80
 468                                         # vmovdqa       0x60(%r10),     %xmm4   # 3 : sbou
 469         vperm   v4, $sbou, v7, v2       # vpshufb       %xmm2,  %xmm4,  %xmm4   # 4 = sbou
 470                                         # vmovdqa       0x70(%r10),     %xmm1   # 0 : sbot
 471         lvx     v2, r12, r10            # vmovdqa       -0x160(%r11),   %xmm2   # .Lk_sr-.Lk_dsbd=-0x160
 472         vperm   v1, $sbot, v7, v3       # vpshufb       %xmm3,  %xmm1,  %xmm1   # 0 = sb1t
 473         vxor    v4, v4, v5              # vpxor         %xmm0,  %xmm4,  %xmm4   # 4 = sb1u + k
 474         vxor    v0, v1, v4              # vpxor         %xmm4,  %xmm1,  %xmm0   # 0 = A
 475         vperm   v0, v0, v7, v2          # vpshufb       %xmm2,  %xmm0,  %xmm0
 476         blr
 477         .long   0
 478         .byte   0,12,0x14,0,0,0,0,0
 479
 480 .globl  .vpaes_decrypt
 481 .align  5
 482 .vpaes_decrypt:
 483         mflr    r6
 484         mfspr   r7, 256                 # save vrsave
 485         li      r0, -1
 486         $PUSH   r6,$LRSAVE($sp)
 487         mtspr   256, r0                 # preserve all AltiVec registers
 488
 489         bl      _vpaes_decrypt_preheat
 490
 491         lvx     v0, 0, $inp
 492         neg     r8, $inp                # prepare for unaligned access
 493         lvsl    $keyperm, 0, $key
 494          lvsr   $outperm, 0, $out
 495         lvsr    $inpperm, 0, r8         # -$inp
 496          vnor   $outmask, v7, v7        # 0xff..ff
 497         lvx     $inptail, 0, $inp
 498          vperm  $outmask, v7, $outmask, $outperm
 499         addi    $inp, $inp, 15          # 15 is not a typo
 500          lvx    $outhead, 0, $out
 501
 502         ########
 503         vmr     v0, $inptail
 504         lvx     $inptail, 0, $inp       # redundant in aligned case
 505         addi    $inp, $inp, 16
 506         vperm   v0, v0, $inptail, $inpperm
 507
 508         bl      _vpaes_decrypt_core
 509
 510         vperm   v0, v0, v0, $outperm    # rotate left
 511         vsel    v1, $outhead, v0, $outmask
 512         vmr     $outhead, v0
 513         stvx    v1, 0, $out
 514         addi    $out, $out, 15          # 15 is not a typo
 515         ########
 516
 517         lvx     v1, 0, $out             # redundant in aligned case
 518         vsel    v1, $outhead, v1, $outmask
 519         stvx    v1, 0, $out
 520
 521         mtlr    r6
 522         mtspr   256, r7                 # restore vrsave
 523         blr
 524         .long   0
 525         .byte   0,12,0x14,1,0,0,3,0
 526         .long   0
 527 .size   .vpaes_decrypt,.-.vpaes_decrypt
 528
 529 .globl  .vpaes_cbc_encrypt
 530 .align  5
 531 .vpaes_cbc_encrypt:
 532         $STU    $sp,-$FRAME($sp)
 533         mflr    r0
 534         $PUSH   r30,$FRAME-$SIZE_T*2($sp)
 535         li      r9, 16
 536         $PUSH   r31,$FRAME-$SIZE_T*1($sp)
 537         $PUSH   r0, $FRAME+$LRSAVE($sp)
 538
 539         sub.    r30, r5, r9             # copy length-16
 540         mr      r5, r6                  # copy pointer to key
 541         mr      r31, r7                 # copy pointer to iv
 542         blt     Lcbc_abort
 543         cmpwi   r8, 0                   # test direction
 544         li      r6, -1
 545         mfspr   r7, 256
 546         mtspr   256, r6                 # preserve all AltiVec registers
 547
 548         neg     r8, r31                 # load [potentially unaligned] iv
 549         li      r9, 15
 550         lvx     v24, 0, r31
 551         lvsr    $inpperm, 0, r8         # -ivp
 552         lvx     v25, r9, r31
 553         vperm   v24, v24, v25, $inpperm
 554
 555         lvx     v0, 0, $inp
 556         neg     r8, $inp                # prepare for unaligned access
 557          vxor   v7, v7, v7
 558         lvsl    $keyperm, 0, $key
 559          lvsr   $outperm, 0, $out
 560         lvsr    $inpperm, 0, r8         # -$inp
 561          vnor   $outmask, v7, v7        # 0xff..ff
 562         lvx     $inptail, 0, $inp
 563          vperm  $outmask, v7, $outmask, $outperm
 564         addi    $inp, $inp, 15          # 15 is not a typo
 565          lvx    $outhead, 0, $out
 566
 567         beq     Lcbc_decrypt
 568
 569         bl      _vpaes_encrypt_preheat
 570         li      r0, 16
 571
 572 Lcbc_enc_loop:
 573         vmr     v0, $inptail
 574         lvx     $inptail, 0, $inp
 575         addi    $inp, $inp, 16
 576         vperm   v0, v0, $inptail, $inpperm
 577         vxor    v0, v0, v24             # ^= iv
 578
 579         bl      _vpaes_encrypt_core
 580
 581         vmr     v24, v0                 # put aside iv
 582         sub.    r30, r30, r0            # len -= 16
 583         vperm   v0, v0, v0, $outperm    # rotate left
 584         vsel    v1, $outhead, v0, $outmask
 585         vmr     $outhead, v0
 586         stvx    v1, 0, $out
 587         addi    $out, $out, 16
 588         bge     Lcbc_enc_loop
 589
 590         b       Lcbc_done
 591
 592 .align  5
 593 Lcbc_decrypt:
 594         bl      _vpaes_decrypt_preheat
 595         li      r0, 16
 596
 597 Lcbc_dec_loop:
 598         vmr     v0, $inptail
 599         lvx     $inptail, 0, $inp
 600         addi    $inp, $inp, 16
 601         vperm   v0, v0, $inptail, $inpperm
 602         vmr     v25, v0                 # put aside input
 603
 604         bl      _vpaes_decrypt_core
 605
 606         vxor    v0, v0, v24             # ^= iv
 607         vmr     v24, v25
 608         sub.    r30, r30, r0            # len -= 16
 609         vperm   v0, v0, v0, $outperm    # rotate left
 610         vsel    v1, $outhead, v0, $outmask
 611         vmr     $outhead, v0
 612         stvx    v1, 0, $out
 613         addi    $out, $out, 16
 614         bge     Lcbc_dec_loop
 615
 616 Lcbc_done:
 617         addi    $out, $out, -1
 618         lvx     v1, 0, $out             # redundant in aligned case
 619         vsel    v1, $outhead, v1, $outmask
 620         stvx    v1, 0, $out
 621
 622         lvsr    $outperm, 0, r31        # write [potentially unaligned] iv
 623         li      r6, 15
 624         vnor    $outmask, v7, v7        # 0xff..ff
 625         vperm   $outmask, v7, $outmask, $outperm
 626         lvx     $outhead, 0, $out
 627         vperm   v24, v24, v24, $outperm # rotate
 628         vsel    v0, $outhead, v24, $outmask
 629         lvx     v1, r6, r31
 630         stvx    v0, 0, r31
 631         vsel    v1, v24, v1, $outmask
 632         stvx    v1, r6, r31
 633
 634         mtspr   256, r7                 # restore vrsave
 635 Lcbc_abort:
 636         $POP    r0, $FRAME+$LRSAVE($sp)
 637         $POP    r30,$FRAME-$SIZE_T*2($sp)
 638         $POP    r31,$FRAME-$SIZE_T*1($sp)
 639         mtlr    r0
 640         addi    $sp,$sp,$FRAME
 641         blr
 642         .long   0
 643         .byte   0,12,0x04,1,0x80,2,6,0
 644         .long   0
 645 .size   .vpaes_cbc_encrypt,.-.vpaes_cbc_encrypt
 646 ___
 647 }\f
 648 {
 649 my ($inp,$bits,$out)=map("r$_",(3..5));
 650 my $dir="cr3";
 651 my ($invlo,$invhi,$iptlo,$ipthi,$rcon) = map("v$_",(10..13,24));
 652
 653 $code.=<<___;
 654 ########################################################
 655 ##                                                    ##
 656 ##                  AES key schedule                  ##
 657 ##                                                    ##
 658 ########################################################
 659 .align  4
 660 _vpaes_key_preheat:
 661         mflr    r8
 662         bl      Lconsts
 663         mtlr    r8
 664         li      r11, 0xc0               # Lk_inv
 665         li      r10, 0xd0
 666         li      r9,  0xe0               # L_ipt
 667         li      r8,  0xf0
 668
 669         vspltisb        v8,4            # 0x04..04
 670         vxor    v9,v9,v9                # 0x00..00
 671         lvx     $invlo, r12, r11        # Lk_inv
 672         li      r11, 0x120
 673         lvx     $invhi, r12, r10
 674         li      r10, 0x130
 675         lvx     $iptlo, r12, r9         # Lk_ipt
 676         li      r9, 0x220
 677         lvx     $ipthi, r12, r8
 678         li      r8, 0x230
 679
 680         lvx     v14, r12, r11           # Lk_sb1
 681         li      r11, 0x240
 682         lvx     v15, r12, r10
 683         li      r10, 0x250
 684
 685         lvx     v16, r12, r9            # Lk_dksd
 686         li      r9, 0x260
 687         lvx     v17, r12, r8
 688         li      r8, 0x270
 689         lvx     v18, r12, r11           # Lk_dksb
 690         li      r11, 0x280
 691         lvx     v19, r12, r10
 692         li      r10, 0x290
 693         lvx     v20, r12, r9            # Lk_dkse
 694         li      r9, 0x2a0
 695         lvx     v21, r12, r8
 696         li      r8, 0x2b0
 697         lvx     v22, r12, r11           # Lk_dks9
 698         lvx     v23, r12, r10
 699
 700         lvx     v24, r12, r9            # Lk_rcon
 701         lvx     v25, 0, r12             # Lk_mc_forward[0]
 702         lvx     v26, r12, r8            # Lks63
 703         blr
 704         .long   0
 705         .byte   0,12,0x14,0,0,0,0,0
 706
 707 .align  4
 708 _vpaes_schedule_core:
 709         mflr    r7
 710
 711         bl      _vpaes_key_preheat      # load the tables
 712
 713         #lvx    v0, 0, $inp             # vmovdqu       (%rdi), %xmm0           # load key (unaligned)
 714         neg     r8, $inp                # prepare for unaligned access
 715         lvx     v0, 0, $inp
 716         addi    $inp, $inp, 15          # 15 is not typo
 717         lvsr    $inpperm, 0, r8         # -$inp
 718         lvx     v6, 0, $inp             # v6 serves as inptail
 719         addi    $inp, $inp, 8
 720         vperm   v0, v0, v6, $inpperm
 721
 722         # input transform
 723         vmr     v3, v0                  # vmovdqa       %xmm0,  %xmm3
 724         bl      _vpaes_schedule_transform
 725         vmr     v7, v0                  # vmovdqa       %xmm0,  %xmm7
 726
 727         bne     $dir, Lschedule_am_decrypting
 728
 729         # encrypting, output zeroth round key after transform
 730         li      r8, 0x30                # mov   \$0x30,%r8d
 731         addi    r10, r12, 0x80          # lea   .Lk_sr(%rip),%r10
 732
 733         lvsr    $outperm, 0, $out       # prepare for unaligned access
 734         vspltisb        $outmask, -1    # 0xff..ff
 735         lvx     $outhead, 0, $out
 736         vperm   $outmask, v9, $outmask, $outperm
 737
 738         #stvx   v0, 0, $out             # vmovdqu       %xmm0,  (%rdx)
 739         vperm   v1, v0, v0, $outperm    # rotate left
 740         vsel    v2, $outhead, v1, $outmask
 741         vmr     $outhead, v1
 742         stvx    v2, 0, $out
 743         b       Lschedule_go
 744
 745 Lschedule_am_decrypting:
 746         srwi    r8, $bits, 1            # shr   \$1,%r8d
 747         andi.   r8, r8, 32              # and   \$32,%r8d
 748         xori    r8, r8, 32              # xor   \$32,%r8d       # nbits==192?0:32
 749         addi    r10, r12, 0x80          # lea   .Lk_sr(%rip),%r10
 750         # decrypting, output zeroth round key after shiftrows
 751         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
 752         vperm   v4, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
 753
 754         neg     r0, $out                # prepare for unaligned access
 755         lvsl    $outperm, 0, r0
 756         addi    $out, $out, 15          # 15 is not typo
 757         vspltisb        $outmask, -1    # 0xff..ff
 758         lvx     $outhead, 0, $out
 759         vperm   $outmask, $outmask, v9, $outperm
 760
 761         #stvx   v4, 0, $out             # vmovdqu       %xmm3,  (%rdx)
 762         vperm   v4, v4, v4, $outperm    # rotate left
 763         vsel    v2, $outhead, v4, $outmask
 764         vmr     $outhead, v4
 765         stvx    v2, 0, $out
 766         xori    r8, r8, 0x30            # xor   \$0x30, %r8
 767
 768 Lschedule_go:
 769         cmplwi  $bits, 192              # cmp   \$192,  %esi
 770         bgt     Lschedule_256
 771         beq     Lschedule_192
 772         # 128: fall though
 773
 774 ##
 775 ##  .schedule_128
 776 ##
 777 ##  128-bit specific part of key schedule.
 778 ##
 779 ##  This schedule is really simple, because all its parts
 780 ##  are accomplished by the subroutines.
 781 ##
 782 Lschedule_128:
 783         li      r0, 10                  # mov   \$10, %esi
 784         mtctr   r0
 785
 786 Loop_schedule_128:
 787         bl      _vpaes_schedule_round
 788         bdz     Lschedule_mangle_last   # dec   %esi
 789         bl      _vpaes_schedule_mangle  # write output
 790         b       Loop_schedule_128
 791
 792 ##
 793 ##  .aes_schedule_192
 794 ##
 795 ##  192-bit specific part of key schedule.
 796 ##
 797 ##  The main body of this schedule is the same as the 128-bit
 798 ##  schedule, but with more smearing.  The long, high side is
 799 ##  stored in %xmm7 as before, and the short, low side is in
 800 ##  the high bits of %xmm6.
 801 ##
 802 ##  This schedule is somewhat nastier, however, because each
 803 ##  round produces 192 bits of key material, or 1.5 round keys.
 804 ##  Therefore, on each cycle we do 2 rounds and produce 3 round
 805 ##  keys.
 806 ##
 807 .align  4
 808 Lschedule_192:
 809         li      r0, 4                   # mov   \$4,    %esi
 810         lvx     v0, 0, $inp
 811         vperm   v0, v6, v0, $inpperm
 812         vsldoi  v0, v3, v0, 8           # vmovdqu       8(%rdi),%xmm0           # load key part 2 (very unaligned)
 813         bl      _vpaes_schedule_transform       # input transform
 814         vsldoi  v6, v0, v9, 8
 815         vsldoi  v6, v9, v6, 8           # clobber "low" side with zeros
 816         mtctr   r0
 817
 818 Loop_schedule_192:
 819         bl      _vpaes_schedule_round
 820         vsldoi  v0, v6, v0, 8           # vpalignr      \$8,%xmm6,%xmm0,%xmm0
 821         bl      _vpaes_schedule_mangle  # save key n
 822         bl      _vpaes_schedule_192_smear
 823         bl      _vpaes_schedule_mangle  # save key n+1
 824         bl      _vpaes_schedule_round
 825         bdz     Lschedule_mangle_last   # dec   %esi
 826         bl      _vpaes_schedule_mangle  # save key n+2
 827         bl      _vpaes_schedule_192_smear
 828         b       Loop_schedule_192
 829
 830 ##
 831 ##  .aes_schedule_256
 832 ##
 833 ##  256-bit specific part of key schedule.
 834 ##
 835 ##  The structure here is very similar to the 128-bit
 836 ##  schedule, but with an additional "low side" in
 837 ##  %xmm6.  The low side's rounds are the same as the
 838 ##  high side's, except no rcon and no rotation.
 839 ##
 840 .align  4
 841 Lschedule_256:
 842         li      r0, 7                   # mov   \$7, %esi
 843         addi    $inp, $inp, 8
 844         lvx     v0, 0, $inp             # vmovdqu       16(%rdi),%xmm0          # load key part 2 (unaligned)
 845         vperm   v0, v6, v0, $inpperm
 846         bl      _vpaes_schedule_transform       # input transform
 847         mtctr   r0
 848
 849 Loop_schedule_256:
 850         bl      _vpaes_schedule_mangle  # output low result
 851         vmr     v6, v0                  # vmovdqa       %xmm0,  %xmm6           # save cur_lo in xmm6
 852
 853         # high round
 854         bl      _vpaes_schedule_round
 855         bdz     Lschedule_mangle_last   # dec   %esi
 856         bl      _vpaes_schedule_mangle
 857
 858         # low round. swap xmm7 and xmm6
 859         vspltw  v0, v0, 3               # vpshufd       \$0xFF, %xmm0,  %xmm0
 860         vmr     v5, v7                  # vmovdqa       %xmm7,  %xmm5
 861         vmr     v7, v6                  # vmovdqa       %xmm6,  %xmm7
 862         bl      _vpaes_schedule_low_round
 863         vmr     v7, v5                  # vmovdqa       %xmm5,  %xmm7
 864
 865         b       Loop_schedule_256
 866 ##
 867 ##  .aes_schedule_mangle_last
 868 ##
 869 ##  Mangler for last round of key schedule
 870 ##  Mangles %xmm0
 871 ##    when encrypting, outputs out(%xmm0) ^ 63
 872 ##    when decrypting, outputs unskew(%xmm0)
 873 ##
 874 ##  Always called right before return... jumps to cleanup and exits
 875 ##
 876 .align  4
 877 Lschedule_mangle_last:
 878         # schedule last round key from xmm0
 879         li      r11, 0x2e0              # lea   .Lk_deskew(%rip),%r11
 880         li      r9,  0x2f0
 881         bne     $dir, Lschedule_mangle_last_dec
 882
 883         # encrypting
 884         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),%xmm1
 885         li      r11, 0x2c0              # lea           .Lk_opt(%rip),  %r11    # prepare to output transform
 886         li      r9,  0x2d0              # prepare to output transform
 887         vperm   v0, v0, v0, v1          # vpshufb       %xmm1,  %xmm0,  %xmm0   # output permute
 888
 889         lvx     $iptlo, r11, r12        # reload $ipt
 890         lvx     $ipthi, r9, r12
 891         addi    $out, $out, 16          # add   \$16,   %rdx
 892         vxor    v0, v0, v26             # vpxor         .Lk_s63(%rip),  %xmm0,  %xmm0
 893         bl      _vpaes_schedule_transform       # output transform
 894
 895         #stvx   v0, r0, $out            # vmovdqu       %xmm0,  (%rdx)          # save last key
 896         vperm   v0, v0, v0, $outperm    # rotate left
 897         vsel    v2, $outhead, v0, $outmask
 898         vmr     $outhead, v0
 899         stvx    v2, 0, $out
 900
 901         addi    $out, $out, 15          # 15 is not typo
 902         lvx     v1, 0, $out             # redundant in aligned case
 903         vsel    v1, $outhead, v1, $outmask
 904         stvx    v1, 0, $out
 905         b       Lschedule_mangle_done
 906
 907 .align  4
 908 Lschedule_mangle_last_dec:
 909         lvx     $iptlo, r11, r12        # reload $ipt
 910         lvx     $ipthi, r9,  r12
 911         addi    $out, $out, -16         # add   \$-16,  %rdx
 912         vxor    v0, v0, v26             # vpxor .Lk_s63(%rip),  %xmm0,  %xmm0
 913         bl      _vpaes_schedule_transform       # output transform
 914
 915         #stvx   v0, r0, $out            # vmovdqu       %xmm0,  (%rdx)          # save last key
 916         vperm   v0, v0, v0, $outperm    # rotate left
 917         vsel    v2, $outhead, v0, $outmask
 918         vmr     $outhead, v0
 919         stvx    v2, 0, $out
 920
 921         addi    $out, $out, -15         # -15 is not typo
 922         lvx     v1, 0, $out             # redundant in aligned case
 923         vsel    v1, $outhead, v1, $outmask
 924         stvx    v1, 0, $out
 925
 926 Lschedule_mangle_done:
 927         mtlr    r7
 928         # cleanup
 929         vxor    v0, v0, v0              # vpxor         %xmm0,  %xmm0,  %xmm0
 930         vxor    v1, v1, v1              # vpxor         %xmm1,  %xmm1,  %xmm1
 931         vxor    v2, v2, v2              # vpxor         %xmm2,  %xmm2,  %xmm2
 932         vxor    v3, v3, v3              # vpxor         %xmm3,  %xmm3,  %xmm3
 933         vxor    v4, v4, v4              # vpxor         %xmm4,  %xmm4,  %xmm4
 934         vxor    v5, v5, v5              # vpxor         %xmm5,  %xmm5,  %xmm5
 935         vxor    v6, v6, v6              # vpxor         %xmm6,  %xmm6,  %xmm6
 936         vxor    v7, v7, v7              # vpxor         %xmm7,  %xmm7,  %xmm7
 937
 938         blr
 939         .long   0
 940         .byte   0,12,0x14,0,0,0,0,0
 941
 942 ##
 943 ##  .aes_schedule_192_smear
 944 ##
 945 ##  Smear the short, low side in the 192-bit key schedule.
 946 ##
 947 ##  Inputs:
 948 ##    %xmm7: high side, b  a  x  y
 949 ##    %xmm6:  low side, d  c  0  0
 950 ##    %xmm13: 0
 951 ##
 952 ##  Outputs:
 953 ##    %xmm6: b+c+d  b+c  0  0
 954 ##    %xmm0: b+c+d  b+c  b  a
 955 ##
 956 .align  4
 957 _vpaes_schedule_192_smear:
 958         vspltw  v0, v7, 3
 959         vsldoi  v1, v9, v6, 12          # vpshufd       \$0x80, %xmm6,  %xmm1   # d c 0 0 -> c 0 0 0
 960         vsldoi  v0, v7, v0, 8           # vpshufd       \$0xFE, %xmm7,  %xmm0   # b a _ _ -> b b b a
 961         vxor    v6, v6, v1              # vpxor         %xmm1,  %xmm6,  %xmm6   # -> c+d c 0 0
 962         vxor    v6, v6, v0              # vpxor         %xmm0,  %xmm6,  %xmm6   # -> b+c+d b+c b a
 963         vmr     v0, v6
 964         vsldoi  v6, v6, v9, 8
 965         vsldoi  v6, v9, v6, 8           # clobber low side with zeros
 966         blr
 967         .long   0
 968         .byte   0,12,0x14,0,0,0,0,0
 969
 970 ##
 971 ##  .aes_schedule_round
 972 ##
 973 ##  Runs one main round of the key schedule on %xmm0, %xmm7
 974 ##
 975 ##  Specifically, runs subbytes on the high dword of %xmm0
 976 ##  then rotates it by one byte and xors into the low dword of
 977 ##  %xmm7.
 978 ##
 979 ##  Adds rcon from low byte of %xmm8, then rotates %xmm8 for
 980 ##  next rcon.
 981 ##
 982 ##  Smears the dwords of %xmm7 by xoring the low into the
 983 ##  second low, result into third, result into highest.
 984 ##
 985 ##  Returns results in %xmm7 = %xmm0.
 986 ##  Clobbers %xmm1-%xmm4, %r11.
 987 ##
 988 .align  4
 989 _vpaes_schedule_round:
 990         # extract rcon from xmm8
 991         #vxor   v4, v4, v4              # vpxor         %xmm4,  %xmm4,  %xmm4
 992         vsldoi  v1, $rcon, v9, 15       # vpalignr      \$15,   %xmm8,  %xmm4,  %xmm1
 993         vsldoi  $rcon, $rcon, $rcon, 15 # vpalignr      \$15,   %xmm8,  %xmm8,  %xmm8
 994         vxor    v7, v7, v1              # vpxor         %xmm1,  %xmm7,  %xmm7
 995
 996         # rotate
 997         vspltw  v0, v0, 3               # vpshufd       \$0xFF, %xmm0,  %xmm0
 998         vsldoi  v0, v0, v0, 1           # vpalignr      \$1,    %xmm0,  %xmm0,  %xmm0
 999
1000         # fall through...
1001
1002         # low round: same as high round, but no rotation and no rcon.
1003 _vpaes_schedule_low_round:
1004         # smear xmm7
1005         vsldoi  v1, v9, v7, 12          # vpslldq       \$4,    %xmm7,  %xmm1
1006         vxor    v7, v7, v1              # vpxor         %xmm1,  %xmm7,  %xmm7
1007         vspltisb        v1, 0x0f        # 0x0f..0f
1008         vsldoi  v4, v9, v7, 8           # vpslldq       \$8,    %xmm7,  %xmm4
1009
1010         # subbytes
1011         vand    v1, v1, v0              # vpand         %xmm9,  %xmm0,  %xmm1           # 0 = k
1012         vsrb    v0, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0           # 1 = i
1013          vxor   v7, v7, v4              # vpxor         %xmm4,  %xmm7,  %xmm7
1014         vperm   v2, $invhi, v9, v1      # vpshufb       %xmm1,  %xmm11, %xmm2           # 2 = a/k
1015         vxor    v1, v1, v0              # vpxor         %xmm0,  %xmm1,  %xmm1           # 0 = j
1016         vperm   v3, $invlo, v9, v0      # vpshufb       %xmm0,  %xmm10, %xmm3           # 3 = 1/i
1017         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3           # 3 = iak = 1/i + a/k
1018         vperm   v4, $invlo, v9, v1      # vpshufb       %xmm1,  %xmm10, %xmm4           # 4 = 1/j
1019          vxor   v7, v7, v26             # vpxor         .Lk_s63(%rip),  %xmm7,  %xmm7
1020         vperm   v3, $invlo, v9, v3      # vpshufb       %xmm3,  %xmm10, %xmm3           # 2 = 1/iak
1021         vxor    v4, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm4           # 4 = jak = 1/j + a/k
1022         vperm   v2, $invlo, v9, v4      # vpshufb       %xmm4,  %xmm10, %xmm2           # 3 = 1/jak
1023         vxor    v3, v3, v1              # vpxor         %xmm1,  %xmm3,  %xmm3           # 2 = io
1024         vxor    v2, v2, v0              # vpxor         %xmm0,  %xmm2,  %xmm2           # 3 = jo
1025         vperm   v4, v15, v9, v3         # vpshufb       %xmm3,  %xmm13, %xmm4           # 4 = sbou
1026         vperm   v1, v14, v9, v2         # vpshufb       %xmm2,  %xmm12, %xmm1           # 0 = sb1t
1027         vxor    v1, v1, v4              # vpxor         %xmm4,  %xmm1,  %xmm1           # 0 = sbox output
1028
1029         # add in smeared stuff
1030         vxor    v0, v1, v7              # vpxor         %xmm7,  %xmm1,  %xmm0
1031         vxor    v7, v1, v7              # vmovdqa       %xmm0,  %xmm7
1032         blr
1033         .long   0
1034         .byte   0,12,0x14,0,0,0,0,0
1035
1036 ##
1037 ##  .aes_schedule_transform
1038 ##
1039 ##  Linear-transform %xmm0 according to tables at (%r11)
1040 ##
1041 ##  Requires that %xmm9 = 0x0F0F... as in preheat
1042 ##  Output in %xmm0
1043 ##  Clobbers %xmm2
1044 ##
1045 .align  4
1046 _vpaes_schedule_transform:
1047         #vand   v1, v0, v9              # vpand         %xmm9,  %xmm0,  %xmm1
1048         vsrb    v2, v0, v8              # vpsrlb        \$4,    %xmm0,  %xmm0
1049                                         # vmovdqa       (%r11), %xmm2   # lo
1050         vperm   v0, $iptlo, $iptlo, v0  # vpshufb       %xmm1,  %xmm2,  %xmm2
1051                                         # vmovdqa       16(%r11),       %xmm1 # hi
1052         vperm   v2, $ipthi, $ipthi, v2  # vpshufb       %xmm0,  %xmm1,  %xmm0
1053         vxor    v0, v0, v2              # vpxor         %xmm2,  %xmm0,  %xmm0
1054         blr
1055         .long   0
1056         .byte   0,12,0x14,0,0,0,0,0
1057
1058 ##
1059 ##  .aes_schedule_mangle
1060 ##
1061 ##  Mangle xmm0 from (basis-transformed) standard version
1062 ##  to our version.
1063 ##
1064 ##  On encrypt,
1065 ##    xor with 0x63
1066 ##    multiply by circulant 0,1,1,1
1067 ##    apply shiftrows transform
1068 ##
1069 ##  On decrypt,
1070 ##    xor with 0x63
1071 ##    multiply by "inverse mixcolumns" circulant E,B,D,9
1072 ##    deskew
1073 ##    apply shiftrows transform
1074 ##
1075 ##
1076 ##  Writes out to (%rdx), and increments or decrements it
1077 ##  Keeps track of round number mod 4 in %r8
1078 ##  Preserves xmm0
1079 ##  Clobbers xmm1-xmm5
1080 ##
1081 .align  4
1082 _vpaes_schedule_mangle:
1083         #vmr    v4, v0                  # vmovdqa       %xmm0,  %xmm4   # save xmm0 for later
1084                                         # vmovdqa       .Lk_mc_forward(%rip),%xmm5
1085         bne     $dir, Lschedule_mangle_dec
1086
1087         # encrypting
1088         vxor    v4, v0, v26             # vpxor .Lk_s63(%rip),  %xmm0,  %xmm4
1089         addi    $out, $out, 16          # add   \$16,   %rdx
1090         vperm   v4, v4, v4, v25         # vpshufb       %xmm5,  %xmm4,  %xmm4
1091         vperm   v1, v4, v4, v25         # vpshufb       %xmm5,  %xmm4,  %xmm1
1092         vperm   v3, v1, v1, v25         # vpshufb       %xmm5,  %xmm1,  %xmm3
1093         vxor    v4, v4, v1              # vpxor         %xmm1,  %xmm4,  %xmm4
1094         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
1095         vxor    v3, v3, v4              # vpxor         %xmm4,  %xmm3,  %xmm3
1096
1097         vperm   v3, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
1098         addi    r8, r8, -16             # add   \$-16,  %r8
1099         andi.   r8, r8, 0x30            # and   \$0x30, %r8
1100
1101         #stvx   v3, 0, $out             # vmovdqu       %xmm3,  (%rdx)
1102         vperm   v1, v3, v3, $outperm    # rotate left
1103         vsel    v2, $outhead, v1, $outmask
1104         vmr     $outhead, v1
1105         stvx    v2, 0, $out
1106         blr
1107
1108 .align  4
1109 Lschedule_mangle_dec:
1110         # inverse mix columns
1111                                         # lea   .Lk_dksd(%rip),%r11
1112         vsrb    v1, v0, v8              # vpsrlb        \$4,    %xmm4,  %xmm1   # 1 = hi
1113         #and    v4, v0, v9              # vpand         %xmm9,  %xmm4,  %xmm4   # 4 = lo
1114
1115                                         # vmovdqa       0x00(%r11),     %xmm2
1116         vperm   v2, v16, v16, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1117                                         # vmovdqa       0x10(%r11),     %xmm3
1118         vperm   v3, v17, v17, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1119         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1120         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1121
1122                                         # vmovdqa       0x20(%r11),     %xmm2
1123         vperm   v2, v18, v18, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1124         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1125                                         # vmovdqa       0x30(%r11),     %xmm3
1126         vperm   v3, v19, v19, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1127         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1128         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1129
1130                                         # vmovdqa       0x40(%r11),     %xmm2
1131         vperm   v2, v20, v20, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1132         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1133                                         # vmovdqa       0x50(%r11),     %xmm3
1134         vperm   v3, v21, v21, v1        # vpshufb       %xmm1,  %xmm3,  %xmm3
1135         vxor    v3, v3, v2              # vpxor         %xmm2,  %xmm3,  %xmm3
1136
1137                                         # vmovdqa       0x60(%r11),     %xmm2
1138         vperm   v2, v22, v22, v0        # vpshufb       %xmm4,  %xmm2,  %xmm2
1139         vperm   v3, v3, v9, v25         # vpshufb       %xmm5,  %xmm3,  %xmm3
1140                                         # vmovdqa       0x70(%r11),     %xmm4
1141         vperm   v4, v23, v23, v1        # vpshufb       %xmm1,  %xmm4,  %xmm4
1142         lvx     v1, r8, r10             # vmovdqa       (%r8,%r10),     %xmm1
1143         vxor    v2, v2, v3              # vpxor         %xmm3,  %xmm2,  %xmm2
1144         vxor    v3, v4, v2              # vpxor         %xmm2,  %xmm4,  %xmm3
1145
1146         addi    $out, $out, -16         # add   \$-16,  %rdx
1147
1148         vperm   v3, v3, v3, v1          # vpshufb       %xmm1,  %xmm3,  %xmm3
1149         addi    r8, r8, -16             # add   \$-16,  %r8
1150         andi.   r8, r8, 0x30            # and   \$0x30, %r8
1151
1152         #stvx   v3, 0, $out             # vmovdqu       %xmm3,  (%rdx)
1153         vperm   v1, v3, v3, $outperm    # rotate left
1154         vsel    v2, $outhead, v1, $outmask
1155         vmr     $outhead, v1
1156         stvx    v2, 0, $out
1157         blr
1158         .long   0
1159         .byte   0,12,0x14,0,0,0,0,0
1160
1161 .globl  .vpaes_set_encrypt_key
1162 .align  5
1163 .vpaes_set_encrypt_key:
1164         mflr    r0
1165         mfspr   r6, 256                 # save vrsave
1166         li      r7, -1
1167         $PUSH   r0, $LRSAVE($sp)
1168         mtspr   256, r7                 # preserve all AltiVec registers
1169
1170         srwi    r9, $bits, 5            # shr   \$5,%eax
1171         addi    r9, r9, 6               # add   \$5,%eax
1172         stw     r9, 240($out)           # mov   %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
1173
1174         cmplw   $dir, $bits, $bits
1175         li      r8, 0x30                # mov   \$0x30,%r8d
1176         bl      _vpaes_schedule_core
1177
1178         $POP    r0, $LRSAVE($sp)
1179         mtspr   256, r6                 # restore vrsave
1180         mtlr    r0
1181         xor     r3, r3, r3
1182         blr
1183         .long   0
1184         .byte   0,12,0x14,1,0,3,0
1185         .long   0
1186 .size   .vpaes_set_encrypt_key,.-.vpaes_set_encrypt_key
1187
1188 .globl  .vpaes_set_decrypt_key
1189 .align  4
1190 .vpaes_set_decrypt_key:
1191         mflr    r0
1192         mfspr   r6, 256                 # save vrsave
1193         li      r7, -1
1194         $PUSH   r0, $LRSAVE($sp)
1195         mtspr   256, r7                 # preserve all AltiVec registers
1196
1197         srwi    r9, $bits, 5            # shr   \$5,%eax
1198         addi    r9, r9, 6               # add   \$5,%eax
1199         stw     r9, 240($out)           # mov   %eax,240(%rdx)  # AES_KEY->rounds = nbits/32+5;
1200
1201         slwi    r9, r9, 4               # shl   \$4,%eax
1202         add     $out, $out, r9          # lea   (%rdx,%rax),%rdx
1203
1204         cmplwi  $dir, $bits, 0
1205         srwi    r8, $bits, 1            # shr   \$1,%r8d
1206         andi.   r8, r8, 32              # and   \$32,%r8d
1207         xori    r8, r8, 32              # xor   \$32,%r8d       # nbits==192?0:32
1208         bl      _vpaes_schedule_core
1209
1210         $POP    r0,  $LRSAVE($sp)
1211         mtspr   256, r6                 # restore vrsave
1212         mtlr    r0
1213         xor     r3, r3, r3
1214         blr
1215         .long   0
1216         .byte   0,12,0x14,1,0,3,0
1217         .long   0
1218 .size   .vpaes_set_decrypt_key,.-.vpaes_set_decrypt_key
1219 ___
1220 }
1221
1222 print $code;
1223
1224 close STDOUT;