cpu/arm_intcm/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33
  34 #include <config.h>
  35 #include <version.h>
  36
  37 /*
  38  *************************************************************************
  39  *
  40  * Jump vector table
  41  *
  42  *************************************************************************
  43  */
  44
  45 .globl _start
  46 _start:
  47         b       reset
  48         ldr     pc, _undefined_instruction
  49         ldr     pc, _software_interrupt
  50         ldr     pc, _prefetch_abort
  51         ldr     pc, _data_abort
  52         ldr     pc, _not_used
  53         ldr     pc, _irq
  54         ldr     pc, _fiq
  55
  56 _undefined_instruction:
  57         .word undefined_instruction
  58 _software_interrupt:
  59         .word software_interrupt
  60 _prefetch_abort:
  61         .word prefetch_abort
  62 _data_abort:
  63         .word data_abort
  64 _not_used:
  65         .word not_used
  66 _irq:
  67         .word irq
  68 _fiq:
  69         .word fiq
  70
  71         .balignl 16,0xdeadbeef
  72
  73 /*
  74  *************************************************************************
  75  *
  76  * Startup Code (reset vector)
  77  *
  78  * do important init only if we don't start from memory!
  79  * setup memory and board specific bits prior to relocation.
  80  * relocate armboot to ram
  81  * setup stack
  82  *
  83  *************************************************************************
  84  */
  85
  86 _TEXT_BASE:
  87         .word   TEXT_BASE /* address of _start in the linked image */
  88
  89 .globl _armboot_start
  90 _armboot_start:
  91         .word _start
  92
  93 /*
  94  * These are defined in the board-specific linker script.
  95  */
  96 .globl _bss_start
  97 _bss_start:
  98         .word __bss_start
  99
 100 .globl _bss_end
 101 _bss_end:
 102         .word _end
 103
 104 #ifdef CONFIG_USE_IRQ
 105 /* IRQ stack memory (calculated at run-time) */
 106 .globl IRQ_STACK_START
 107 IRQ_STACK_START:
 108         .word   0x0badc0de
 109
 110 /* IRQ stack memory (calculated at run-time) */
 111 .globl FIQ_STACK_START
 112 FIQ_STACK_START:
 113         .word 0x0badc0de
 114 #endif
 115
 116
 117 /*
 118  * the actual reset code
 119  */
 120 .globl reset
 121 reset:
 122         /*
 123          * set the cpu to SVC32 mode
 124          */
 125         mrs     r0,cpsr
 126         bic     r0,r0,#0x1f
 127         orr     r0,r0,#0xd3
 128         msr     cpsr,r0
 129
 130         /*
 131          * we do sys-critical inits only at reboot,
 132          * not when booting from ram!
 133          */
 134 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 135         bl      cpu_init_crit
 136 #endif
 137
 138 relocate:                               /* relocate U-Boot to RAM           */
 139         adr     r0, _start              /* pc relative  address of label    */
 140         ldr     r1, _TEXT_BASE          /* linked image address of label    */
 141         cmp     r0, r1                  /* test if we run from flash or RAM */
 142         beq     stack_setup             /* ifeq we are in the RAM copy      */
 143
 144         ldr     r2, _armboot_start
 145         ldr     r3, _bss_start
 146         sub     r2, r3, r2              /* r2 <- size of armboot            */
 147         add     r2, r0, r2              /* r2 <- source end address         */
 148
 149 copy_loop:
 150         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 151         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 152         cmp     r0, r2                  /* until source end addreee [r2]    */
 153         ble     copy_loop
 154
 155         /* Set up the stack                                                 */
 156 stack_setup:
 157         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 158         sub     r0, r0, #CONFIG_SYS_MALLOC_LEN  /* malloc area                      */
 159         sub     r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo                        */
 160 #ifdef CONFIG_USE_IRQ
 161         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 162 #endif
 163         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 164
 165 clear_bss:
 166         ldr     r0, _bss_start          /* find start of bss segment        */
 167         ldr     r1, _bss_end            /* stop here                        */
 168         mov     r2, #0x00000000         /* clear                            */
 169
 170 clbss_l:str     r2, [r0]                /* clear loop...                    */
 171         add     r0, r0, #4
 172         cmp     r0, r1
 173         ble     clbss_l
 174
 175         ldr     pc, _start_armboot
 176
 177 _start_armboot:
 178         .word start_armboot
 179
 180 /*
 181  *************************************************************************
 182  *
 183  * CPU_init_critical registers
 184  *
 185  * setup important registers
 186  * setup memory timing
 187  *
 188  *************************************************************************
 189  */
 190
 191 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 192 cpu_init_crit:
 193         /*  arm_int_generic assumes the ARM boot monitor, or user software,
 194          * has initialized the platform
 195          */
 196         mov     pc, lr          /* back to my caller */
 197 #endif
 198 /*
 199  *************************************************************************
 200  *
 201  * Interrupt handling
 202  *
 203  *************************************************************************
 204  */
 205
 206 @
 207 @ IRQ stack frame.
 208 @
 209 #define S_FRAME_SIZE    72
 210
 211 #define S_OLD_R0        68
 212 #define S_PSR           64
 213 #define S_PC            60
 214 #define S_LR            56
 215 #define S_SP            52
 216
 217 #define S_IP            48
 218 #define S_FP            44
 219 #define S_R10           40
 220 #define S_R9            36
 221 #define S_R8            32
 222 #define S_R7            28
 223 #define S_R6            24
 224 #define S_R5            20
 225 #define S_R4            16
 226 #define S_R3            12
 227 #define S_R2            8
 228 #define S_R1            4
 229 #define S_R0            0
 230
 231 #define MODE_SVC 0x13
 232 #define I_BIT    0x80
 233
 234 /*
 235  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 236  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 237  */
 238
 239         .macro  bad_save_user_regs
 240         @ carve out a frame on current user stack
 241         sub     sp, sp, #S_FRAME_SIZE
 242         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 243
 244         ldr     r2, _armboot_start
 245         sub     r2, r2, #(CONFIG_STACKSIZE+CONFIG_SYS_MALLOC_LEN)
 246         sub     r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 247         @ get values for "aborted" pc and cpsr (into parm regs)
 248         ldmia   r2, {r2 - r3}
 249         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 250         add     r5, sp, #S_SP
 251         mov     r1, lr
 252         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 253         mov     r0, sp          @ save current stack into r0 (param register)
 254         .endm
 255
 256         .macro  irq_save_user_regs
 257         sub     sp, sp, #S_FRAME_SIZE
 258         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 259         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 260         add     r8, sp, #S_PC
 261         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 262         str     lr, [r8, #0]            @ Save calling PC
 263         mrs     r6, spsr
 264         str     r6, [r8, #4]            @ Save CPSR
 265         str     r0, [r8, #8]            @ Save OLD_R0
 266         mov     r0, sp
 267         .endm
 268
 269         .macro  irq_restore_user_regs
 270         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 271         mov     r0, r0
 272         ldr     lr, [sp, #S_PC]                 @ Get PC
 273         add     sp, sp, #S_FRAME_SIZE
 274         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 275         .endm
 276
 277         .macro get_bad_stack
 278         ldr     r13, _armboot_start             @ setup our mode stack
 279         sub     r13, r13, #(CONFIG_STACKSIZE+CONFIG_SYS_MALLOC_LEN)
 280         sub     r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 281
 282         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 283         mrs     lr, spsr        @ get the spsr
 284         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 285         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 286         @ msr   spsr_c, r13
 287         msr     spsr, r13       @ switch modes, make sure moves will execute
 288         mov     lr, pc          @ capture return pc
 289         movs    pc, lr          @ jump to next instruction & switch modes.
 290         .endm
 291
 292         .macro get_irq_stack                    @ setup IRQ stack
 293         ldr     sp, IRQ_STACK_START
 294         .endm
 295
 296         .macro get_fiq_stack                    @ setup FIQ stack
 297         ldr     sp, FIQ_STACK_START
 298         .endm
 299
 300 /*
 301  * exception handlers
 302  */
 303         .align  5
 304 .globl undefined_instruction
 305 undefined_instruction:
 306         get_bad_stack
 307         bad_save_user_regs
 308         bl      do_undefined_instruction
 309
 310         .align  5
 311 .globl software_interrupt
 312 software_interrupt:
 313         get_bad_stack
 314         bad_save_user_regs
 315         bl      do_software_interrupt
 316
 317         .align  5
 318 .globl prefetch_abort
 319 prefetch_abort:
 320         get_bad_stack
 321         bad_save_user_regs
 322         bl      do_prefetch_abort
 323
 324         .align  5
 325 .globl data_abort
 326 data_abort:
 327         get_bad_stack
 328         bad_save_user_regs
 329         bl      do_data_abort
 330
 331         .align  5
 332 .globl not_used
 333 not_used:
 334         get_bad_stack
 335         bad_save_user_regs
 336         bl      do_not_used
 337
 338 #ifdef CONFIG_USE_IRQ
 339         .align  5
 340 .globl irq
 341 irq:
 342         get_irq_stack
 343         irq_save_user_regs
 344         bl      do_irq
 345         irq_restore_user_regs
 346
 347         .align  5
 348 .globl fiq
 349 fiq:
 350         get_fiq_stack
 351         /* someone ought to write a more effiction fiq_save_user_regs */
 352         irq_save_user_regs
 353         bl      do_fiq
 354         irq_restore_user_regs
 355
 356 #else
 357
 358         .align  5
 359 .globl irq
 360 irq:
 361         get_bad_stack
 362         bad_save_user_regs
 363         bl      do_irq
 364
 365         .align  5
 366 .globl fiq
 367 fiq:
 368         get_bad_stack
 369         bad_save_user_regs
 370         bl      do_fiq
 371
 372 #endif