cpu/arm925t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM925 CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1510 from ARM920 code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij          <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33
  34 #include <config.h>
  35 #include <version.h>
  36
  37 #if defined(CONFIG_OMAP1510)
  38 #include <./configs/omap1510.h>
  39 #endif
  40
  41 /*
  42  *************************************************************************
  43  *
  44  * Jump vector table as in table 3.1 in [1]
  45  *
  46  *************************************************************************
  47  */
  48
  49
  50 .globl _start
  51 _start: b       reset
  52         ldr     pc, _undefined_instruction
  53         ldr     pc, _software_interrupt
  54         ldr     pc, _prefetch_abort
  55         ldr     pc, _data_abort
  56         ldr     pc, _not_used
  57         ldr     pc, _irq
  58         ldr     pc, _fiq
  59
  60 _undefined_instruction: .word undefined_instruction
  61 _software_interrupt:    .word software_interrupt
  62 _prefetch_abort:        .word prefetch_abort
  63 _data_abort:            .word data_abort
  64 _not_used:              .word not_used
  65 _irq:                   .word irq
  66 _fiq:                   .word fiq
  67
  68         .balignl 16,0xdeadbeef
  69
  70
  71 /*
  72  *************************************************************************
  73  *
  74  * Startup Code (reset vector)
  75  *
  76  * do important init only if we don't start from memory!
  77  * setup Memory and board specific bits prior to relocation.
  78  * relocate armboot to ram
  79  * setup stack
  80  *
  81  *************************************************************************
  82  */
  83
  84 _TEXT_BASE:
  85         .word   TEXT_BASE
  86
  87 .globl _armboot_start
  88 _armboot_start:
  89         .word _start
  90
  91 /*
  92  * Note: _armboot_end_data and _armboot_end are defined
  93  * by the (board-dependent) linker script.
  94  * _armboot_end_data is the first usable FLASH address after armboot
  95  */
  96 .globl _armboot_end_data
  97 _armboot_end_data:
  98         .word armboot_end_data
  99 .globl _armboot_end
 100 _armboot_end:
 101         .word armboot_end
 102
 103 #ifdef CONFIG_USE_IRQ
 104 /* IRQ stack memory (calculated at run-time) */
 105 .globl IRQ_STACK_START
 106 IRQ_STACK_START:
 107         .word   0x0badc0de
 108
 109 /* IRQ stack memory (calculated at run-time) */
 110 .globl FIQ_STACK_START
 111 FIQ_STACK_START:
 112         .word 0x0badc0de
 113 #endif
 114
 115
 116 /*
 117  * the actual reset code
 118  */
 119
 120 reset:
 121         /*
 122          * set the cpu to SVC32 mode
 123          */
 124         mrs     r0,cpsr
 125         bic     r0,r0,#0x1f
 126         orr     r0,r0,#0xd3
 127         msr     cpsr,r0
 128
 129         /*
 130          * Set up 925T mode
 131          */
 132         mov r1, #0x81               /* Set ARM925T configuration. */
 133         mcr p15, 0, r1, c15, c1, 0  /* Write ARM925T configuration register. */
 134
 135         /*
 136          * turn off the watchdog, unlock/diable sequence
 137          */
 138         mov  r1, #0xF5
 139         ldr  r0, =WDTIM_MODE
 140         strh r1, [r0]
 141         mov  r1, #0xA0
 142         strh r1, [r0]
 143
 144         /*
 145          * mask all IRQs by setting all bits in the INTMR - default
 146          */
 147         mov r1, #0xffffffff
 148         ldr r0, =REG_IHL1_MIR
 149         str r1, [r0]
 150         ldr r0, =REG_IHL2_MIR
 151         str r1, [r0]
 152
 153         /*
 154          * wait for dpll to lock
 155          */
 156         ldr  r0, =CK_DPLL1
 157         mov  r1, #0x10
 158         strh r1, [r0]
 159 poll1:
 160         ldrh r1, [r0]
 161         ands r1, r1, #0x01
 162         beq poll1
 163
 164         /*
 165          * we do sys-critical inits only at reboot,
 166          * not when booting from ram!
 167          */
 168 #ifdef CONFIG_INIT_CRITICAL
 169         bl  cpu_init_crit
 170 #endif
 171
 172 relocate:                               /* relocate U-Boot to RAM           */
 173         adr     r0, _start              /* r0 <- current position of code   */
 174         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 175         cmp     r0, r1                  /* don't reloc during debug         */
 176         beq     stack_setup
 177
 178         ldr     r2, _armboot_start
 179         ldr     r3, _armboot_end
 180         sub     r2, r3, r2              /* r2 <- size of armboot            */
 181         add     r2, r0, r2              /* r2 <- source end address         */
 182
 183 copy_loop:
 184         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 185         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 186         cmp     r0, r2                  /* until source end addreee [r2]    */
 187         ble     copy_loop
 188
 189         /* Set up the stack                                                 */
 190 stack_setup:
 191         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 192         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 193         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 194 #ifdef CONFIG_USE_IRQ
 195         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 196 #endif
 197         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 198
 199         ldr     pc, _start_armboot
 200
 201 _start_armboot: .word start_armboot
 202
 203
 204 /*
 205  *************************************************************************
 206  *
 207  * CPU_init_critical registers
 208  *
 209  * setup important registers
 210  * setup memory timing
 211  *
 212  *************************************************************************
 213  */
 214
 215
 216 cpu_init_crit:
 217         /*
 218          * flush v4 I/D caches
 219          */
 220         mov     r0, #0
 221         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 222         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 223
 224         /*
 225          * disable MMU stuff and caches
 226          */
 227         mrc     p15, 0, r0, c1, c0, 0
 228         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 229         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 230         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 231         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 232         mcr     p15, 0, r0, c1, c0, 0
 233
 234         /*
 235          * Go setup Memory and board specific bits prior to relocation.
 236          */
 237         mov     ip, lr          /* perserve link reg across call */
 238         bl      platformsetup   /* go setup pll,mux,memory */
 239         mov     lr, ip          /* restore link */
 240         mov     pc, lr          /* back to my caller */
 241 /*
 242  *************************************************************************
 243  *
 244  * Interrupt handling
 245  *
 246  *************************************************************************
 247  */
 248
 249 @
 250 @ IRQ stack frame.
 251 @
 252 #define S_FRAME_SIZE    72
 253
 254 #define S_OLD_R0        68
 255 #define S_PSR           64
 256 #define S_PC            60
 257 #define S_LR            56
 258 #define S_SP            52
 259
 260 #define S_IP            48
 261 #define S_FP            44
 262 #define S_R10           40
 263 #define S_R9            36
 264 #define S_R8            32
 265 #define S_R7            28
 266 #define S_R6            24
 267 #define S_R5            20
 268 #define S_R4            16
 269 #define S_R3            12
 270 #define S_R2            8
 271 #define S_R1            4
 272 #define S_R0            0
 273
 274 #define MODE_SVC 0x13
 275 #define I_BIT    0x80
 276
 277 /*
 278  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 279  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 280  */
 281
 282         .macro  bad_save_user_regs
 283         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 284         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 285
 286         ldr     r2, _armboot_end                @ find top of stack
 287         add     r2, r2, #CONFIG_STACKSIZE       @ find base of normal stack
 288         sub     r2, r2, #8                      @ set base 2 words into abort stack
 289         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 290         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 291
 292         add     r5, sp, #S_SP
 293         mov     r1, lr
 294         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 295         mov     r0, sp                          @ save current stack into r0 (param register)
 296         .endm
 297
 298         .macro  irq_save_user_regs
 299         sub     sp, sp, #S_FRAME_SIZE
 300         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 301         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 302         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 303         str     lr, [r8, #0]                    @ Save calling PC
 304         mrs     r6, spsr
 305         str     r6, [r8, #4]                    @ Save CPSR
 306         str     r0, [r8, #8]                    @ Save OLD_R0
 307         mov     r0, sp
 308         .endm
 309
 310         .macro  irq_restore_user_regs
 311         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 312         mov     r0, r0
 313         ldr     lr, [sp, #S_PC]                 @ Get PC
 314         add     sp, sp, #S_FRAME_SIZE
 315         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 316         .endm
 317
 318         .macro get_bad_stack
 319         ldr     r13, _armboot_end               @ get bottom of stack (into sp by by user stack pointer).
 320         add     r13, r13, #CONFIG_STACKSIZE     @ head to reserved words at the top of the stack
 321         sub     r13, r13, #8                    @ reserved a couple spots in abort stack
 322
 323         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 324         mrs     lr, spsr                        @ get the spsr
 325         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 326
 327         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 328         @ msr   spsr_c, r13
 329         msr     spsr, r13                       @ switch modes, make sure moves will execute
 330         mov     lr, pc                          @ capture return pc
 331         movs    pc, lr                          @ jump to next instruction & switch modes.
 332         .endm
 333
 334         .macro get_irq_stack                    @ setup IRQ stack
 335         ldr     sp, IRQ_STACK_START
 336         .endm
 337
 338         .macro get_fiq_stack                    @ setup FIQ stack
 339         ldr     sp, FIQ_STACK_START
 340         .endm
 341
 342 /*
 343  * exception handlers
 344  */
 345         .align  5
 346 undefined_instruction:
 347         get_bad_stack
 348         bad_save_user_regs
 349         bl      do_undefined_instruction
 350
 351         .align  5
 352 software_interrupt:
 353         get_bad_stack
 354         bad_save_user_regs
 355         bl      do_software_interrupt
 356
 357         .align  5
 358 prefetch_abort:
 359         get_bad_stack
 360         bad_save_user_regs
 361         bl      do_prefetch_abort
 362
 363         .align  5
 364 data_abort:
 365         get_bad_stack
 366         bad_save_user_regs
 367         bl      do_data_abort
 368
 369         .align  5
 370 not_used:
 371         get_bad_stack
 372         bad_save_user_regs
 373         bl      do_not_used
 374
 375 #ifdef CONFIG_USE_IRQ
 376
 377         .align  5
 378 irq:
 379         get_irq_stack
 380         irq_save_user_regs
 381         bl      do_irq
 382         irq_restore_user_regs
 383
 384         .align  5
 385 fiq:
 386         get_fiq_stack
 387         /* someone ought to write a more effiction fiq_save_user_regs */
 388         irq_save_user_regs
 389         bl      do_fiq
 390         irq_restore_user_regs
 391
 392 #else
 393
 394         .align  5
 395 irq:
 396         get_bad_stack
 397         bad_save_user_regs
 398         bl      do_irq
 399
 400         .align  5
 401 fiq:
 402         get_bad_stack
 403         bad_save_user_regs
 404         bl      do_fiq
 405
 406 #endif
 407
 408         .align  5
 409 .globl reset_cpu
 410 reset_cpu:
 411         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 412         mov     r3, #0x3        /* dsp_en + arm_rst = global reset */
 413         strh    r3, [r1]        /* force reset */
 414         mov     r0, r0
 415 _loop_forever:
 416         b       _loop_forever
 417 rstctl1:
 418         .word   0xfffece10