configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE(tinc, 1.1pre1+git)
   8 AC_CONFIG_HEADERS([config.h])
   9 AM_MAINTAINER_MODE
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22 AC_PROG_RANLIB
  23
  24 dnl Check and set OS
  25
  26 AC_CANONICAL_HOST
  27
  28 case $host_os in
  29   *linux*)
  30     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  31     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  32   ;;
  33   *freebsd*)
  34     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  35     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  36   ;;
  37   *darwin*)
  38     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  39     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  40   ;;
  41   *solaris*)
  42     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  43     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  44   ;;
  45   *openbsd*)
  46     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  47     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  48   ;;
  49   *netbsd*)
  50     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  51     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  52   ;;
  53   *dragonfly*)
  54     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  55     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  56   ;;
  57   *bsd*)
  58     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  59     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  60     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  61   ;;
  62   *cygwin*)
  63     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  64     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  65   ;;
  66   *mingw*)
  67     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  68     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  69     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  70   ;;
  71   *)
  72     AC_MSG_ERROR("Unknown operating system.")
  73   ;;
  74 esac
  75
  76 AC_ARG_ENABLE(tunemu,
  77   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
  78   [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
  79     tunemu=true
  80   ]
  81 )
  82
  83 AC_ARG_WITH(windows2000,
  84   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
  85   [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])]
  86 )
  87
  88 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  89
  90 AC_CACHE_SAVE
  91
  92 if test -d /sw/include ; then
  93   CPPFLAGS="$CPPFLAGS -I/sw/include"
  94 fi
  95 if test -d /sw/lib ; then
  96   LIBS="$LIBS -L/sw/lib"
  97 fi
  98
  99 dnl Checks for header files.
 100 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 101
 102 AC_HEADER_STDC
 103 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 104 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h],
 105   [], [], [#include "have.h"]
 106 )
 107 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 108   [], [], [#include "have.h"]
 109 )
 110 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 111   [], [], [#include "have.h"]
 112 )
 113
 114 dnl Checks for typedefs, structures, and compiler characteristics.
 115 AC_C_CONST
 116 AC_C_VOLATILE
 117 AC_TYPE_PID_T
 118 AC_TYPE_SIZE_T
 119 AC_HEADER_TIME
 120 AC_STRUCT_TM
 121
 122 tinc_ATTRIBUTE(__malloc__)
 123
 124 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 125   [#include "have.h"]
 126 )
 127
 128 dnl Checks for library functions.
 129 AC_TYPE_SIGNAL
 130 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 131   [], [], [#include "have.h"]
 132 )
 133
 134 dnl Support for SunOS
 135
 136 AC_CHECK_FUNC(socket, [], [
 137   AC_CHECK_LIB(socket, connect)
 138 ])
 139 AC_CHECK_FUNC(gethostbyname, [], [
 140   AC_CHECK_LIB(nsl, gethostbyname)
 141 ])
 142
 143 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 144   [], [], [#include "have.h"]
 145 )
 146
 147 AC_CACHE_SAVE
 148
 149 dnl These are defined in files in m4/
 150
 151 AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 152
 153 tinc_CURSES
 154 tinc_LIBEVENT
 155 tinc_ZLIB
 156 tinc_LZO
 157
 158 if test "$with_libgcrypt" = yes; then
 159         AM_PATH_LIBGCRYPT([1.4.0], [], [])
 160         ln -sf gcrypt/cipher.c gcrypt/cipher.h gcrypt/crypto.c gcrypt/crypto.h gcrypt/digest.c gcrypt/digest.h gcrypt/ecdh.c gcrypt/ecdh.h gcrypt/ecdsa.c gcrypt/ecdsa.h gcrypt/ecdsagen.c gcrypt/ecdsagen.h gcrypt/prf.c gcrypt/prf.h gcrypt/rsa.c gcrypt/rsa.h gcrypt/rsagen.c gcrypt/rsagen.h src/
 161 else
 162         tinc_OPENSSL
 163         ln -sf openssl/cipher.c openssl/cipher.h openssl/crypto.c openssl/crypto.h openssl/digest.c openssl/digest.h openssl/ecdh.c openssl/ecdh.h openssl/ecdsa.c openssl/ecdsa.h openssl/ecdsagen.c openssl/ecdsagen.h openssl/prf.c openssl/prf.h openssl/rsa.c openssl/rsa.h openssl/rsagen.c openssl/rsagen.h src/
 164 fi
 165
 166
 167 dnl Check if support for jumbograms is requested
 168 AC_ARG_ENABLE(jumbograms,
 169   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 170   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 171 )
 172
 173 AC_SUBST(INCLUDES)
 174
 175 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile gui/Makefile])
 176
 177 AC_OUTPUT