configure.ac

   1 # This file is part of GNUnet.
   2 # (C) 2001--2010 Christian Grothoff (and other contributing authors)
   3 #
   4 # GNUnet is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published
   6 # by the Free Software Foundation; either version 2, or (at your
   7 # option) any later version.
   8 #
   9 # GNUnet is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with GNUnet; see the file COPYING.  If not, write to the
  16 # Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18 #
  19 #
  20 # Process this file with autoconf to produce a configure script.
  21 #
  22 #
  23 AC_PREREQ(2.61)
  24 # Checks for programs.
  25 AC_INIT([gnunet], [0.9.0pre3],[bug-gnunet@gnu.org])
  26
  27 AC_CANONICAL_TARGET
  28 AC_CANONICAL_HOST
  29 AC_CANONICAL_SYSTEM
  30
  31 AM_INIT_AUTOMAKE([gnunet], [0.9.0pre3])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33 AC_CONFIG_HEADERS([gnunet_config.h])
  34 AH_TOP([#define _GNU_SOURCE  1])
  35
  36 AC_PROG_AWK
  37 AC_PROG_CC
  38 AC_PROG_CPP
  39 AC_PROG_CXX
  40 AC_PROG_OBJC
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AM_PROG_CC_C_O
  45 LT_INIT([disable-static dlopen win32-dll])
  46 LTDL_INIT
  47 AC_SUBST(LTDLINCL)
  48 AC_SUBST(LIBLTDL)
  49 AC_SUBST(MKDIR_P)
  50
  51 # large file support
  52 AC_SYS_LARGEFILE
  53 AC_FUNC_FSEEKO
  54
  55
  56 if test "$enable_shared" = "no"
  57 then
  58  AC_MSG_ERROR([GNUnet only works with shared libraries. Sorry.])
  59 fi
  60
  61 CFLAGS="-Wall $CFLAGS"
  62 # use '-fno-strict-aliasing', but only if the compiler can take it
  63 if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
  64 then
  65  CFLAGS="-fno-strict-aliasing $CFLAGS"
  66 fi
  67
  68 # Use Linux interface name unless the OS has a different preference
  69 DEFAULT_INTERFACE="\"eth0\""
  70
  71 # Check system type
  72 case "$host_os" in
  73 *darwin* | *rhapsody* | *macosx*)
  74      AC_DEFINE_UNQUOTED(DARWIN,1,[This is an Apple Darwin system])
  75      CPPFLAGS="-D_APPLE_C_SOURCE $CPPFLAGS"
  76      CFLAGS="-no-cpp-precomp -fno-common $CFLAGS"
  77      AC_MSG_WARN([The VPN application cannot be compiled on your OS])
  78      build_target="darwin"
  79      DEFAULT_INTERFACE="\"en0\""
  80      LIBPREFIX=
  81      DLLDIR=lib
  82      ;;
  83 linux*)
  84      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux system])
  85      build_target="linux"
  86      LIBPREFIX=
  87      DLLDIR=lib
  88      AC_PATH_XTRA
  89      ;;
  90 freebsd*)
  91      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
  92      AC_DEFINE_UNQUOTED(FREEBSD,1,[This is a FreeBSD system])
  93      CFLAGS="-D_THREAD_SAFE $CFLAGS"
  94      build_target="freebsd"
  95      LIBPREFIX=
  96      DLLDIR=lib
  97      ;;
  98 openbsd*)
  99      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 100      AC_DEFINE_UNQUOTED(OPENBSD,1,[This is an OpenBSD system])
 101      LIBS=`echo $LIBS | sed -e "s/-ldl//"`
 102      build_target="openbsd"
 103      LIBPREFIX=
 104      DLLDIR=lib
 105      ;;
 106 netbsd*)
 107      AC_DEFINE_UNQUOTED(SOMEBSD,1,[This is a BSD system])
 108      AC_DEFINE_UNQUOTED(NETBSD,1,[This is a NetBSD system])
 109      LIBPREFIX=
 110      DLLDIR=lib
 111      ;;
 112 *solaris*)
 113      AC_DEFINE_UNQUOTED(SOLARIS,1,[This is a Solaris system])
 114      AC_DEFINE_UNQUOTED(_REENTRANT,1,[Need with solaris or errno doesnt work])
 115      AC_CHECK_LIB(resolv, res_init)
 116      AC_CHECK_LIB(rt, nanosleep)
 117      build_target="solaris"
 118      LIBPREFIX=
 119      DLLDIR=lib
 120      ;;
 121 *arm-linux*)
 122      AC_DEFINE_UNQUOTED(LINUX,1,[This is a Linux system])
 123      CFLAGS="-D_REENTRANT -fPIC -pipe $CFLAGS"
 124      build_target="linux"
 125      LIBPREFIX=
 126      DLLDIR=lib
 127      ;;
 128 *cygwin*)
 129      AC_DEFINE_UNQUOTED(CYGWIN,1,[This is a Cygwin system])
 130      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 131      AC_CHECK_LIB(intl, gettext)
 132      LDFLAGS="$LDFLAGS -no-undefined"
 133      CFLAGS="-mms-bitfields $CFLAGS"
 134      build_target="cygwin"
 135      LIBPREFIX=lib
 136      DLLDIR=bin
 137      AC_PROG_CXX
 138      ;;
 139 *mingw*)
 140      AC_DEFINE_UNQUOTED(MINGW,1,[This is a MinGW system])
 141      AC_DEFINE_UNQUOTED(WINDOWS,1,[This is a Windows system])
 142      AC_DEFINE_UNQUOTED(_WIN32,1,[This is a Windows system])
 143      AC_CHECK_LIB(intl, gettext)
 144      LDFLAGS="$LDFLAGS -no-undefined -Wl,--export-all-symbols"
 145      LIBS="$LIBS -lws2_32 -lplibc"
 146      CFLAGS="-mms-bitfields $CFLAGS"
 147      CPPFLAGS="-D_WIN32_WINNT=0x0501 $CPPFLAGS"
 148      build_target="mingw"
 149      AC_PROG_CXX
 150      LIBPREFIX=lib
 151      DLLDIR=bin
 152      ;;
 153 *)
 154      AC_MSG_RESULT(Unrecognised OS $host_os)
 155      AC_DEFINE_UNQUOTED(OTHEROS,1,[Some strange OS])
 156 ;;
 157 esac
 158 AC_DEFINE_UNQUOTED([GNUNET_DEFAULT_INTERFACE], $DEFAULT_INTERFACE, [This should be the default choice for the name of the first network interface])
 159 AC_SUBST(DEFAULT_INTERFACE)
 160
 161 AC_MSG_CHECKING([for build target])
 162 AM_CONDITIONAL(DARWIN,  test "$build_target" = "darwin")
 163 AM_CONDITIONAL(CYGWIN,  test "$build_target" = "cygwin")
 164 AM_CONDITIONAL(MINGW,   test "$build_target" = "mingw")
 165 AM_CONDITIONAL(SOLARIS, test "$build_target" = "solaris")
 166 AM_CONDITIONAL(XFREEBSD, test "$build_target" = "freebsd")
 167 AM_CONDITIONAL(OPENBSD, test "$build_target" = "openbsd")
 168 AM_CONDITIONAL(LINUX, test "$build_target" = "linux")
 169
 170 AC_MSG_RESULT([$build_target])
 171 AC_SUBST(build_target)
 172 AM_CONDITIONAL([am__fastdepOBJC], false)
 173 AC_UNALIGNED_64_ACCESS
 174
 175 # some other checks for standard libs
 176 AC_SEARCH_LIBS([gethostbyname], [nsl ws2_32])
 177 AC_CHECK_LIB(socket, socket)
 178 AC_CHECK_LIB(m, log)
 179 AC_CHECK_LIB(c, getloadavg, AC_DEFINE(HAVE_GETLOADAVG,1,[getloadavg supported]))
 180
 181 # 'save' libs; only those libs found so far will be
 182 # linked against _everywhere_.  For the others, we
 183 # will be more selective!
 184 SAVE_LIBS=$LIBS
 185
 186 # libgcrypt
 187 gcrypt=0
 188 AM_PATH_LIBGCRYPT(1.2.0, gcrypt=1)
 189 AC_CHECK_DECLS([gcry_mpi_lshift], [], [], [[#include <gcrypt.h>]])
 190
 191 if test $gcrypt = 0
 192 then
 193   AC_MSG_ERROR([GNUnet needs libgcrypt])
 194 fi
 195
 196 if test $build = $target
 197 then
 198 AC_MSG_CHECKING([for working HMAC])
 199 AC_LANG_PUSH(C)
 200 LIBS="$LIBS $LIBGCRYPT_LIBS"
 201 CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
 202 AC_RUN_IFELSE(
 203   [AC_LANG_PROGRAM([#include <gcrypt.h>], [[
 204         gcry_md_hd_t mac;
 205
 206         unsigned char data[] = { 0xbf, 0x16, 0x6e, 0x46, 0x3a, 0x6c, 0xf3, 0x93, 0xa7, 0x72,
 207             0x11, 0xa1, 0xdc, 0x0b, 0x07, 0xdb, 0x1a, 0x5e, 0xd9, 0xb9, 0x81, 0xbe,
 208             0xea, 0xe4, 0x31, 0x5f, 0x24, 0xff, 0xfe, 0x50, 0x8a, 0xde };
 209         unsigned char key[] = { 0xfc, 0x62, 0x76, 0x35 };
 210         unsigned char result[] = {0xa2, 0xb, 0x1, 0xd9, 0xc0, 0x8b, 0x5a, 0x12, 0x80,
 211             0xd5, 0x50, 0x12, 0x8e, 0xd0, 0x5b, 0xb6, 0x5c, 0x87, 0x24, 0xe2, 0xd0,
 212             0xd2, 0xaf, 0x63, 0xae, 0xd1, 0xd6, 0x64, 0x14, 0xe3, 0x6e, 0x61, 0x5b,
 213             0xd, 0xba, 0x17, 0x7d, 0xd3, 0x10, 0xb1, 0x37, 0x41, 0x91, 0x7d, 0xeb,
 214             0x1, 0x4d, 0x71, 0xe8, 0x59, 0x71, 0x42, 0x8e, 0xd6, 0xf3, 0x29, 0x3b,
 215             0x90, 0xf2, 0xd1, 0xaf, 0x65, 0x1e, 0xb3};
 216
 217         if (!gcry_check_version (GCRYPT_VERSION))
 218           return 1;
 219
 220         gcry_control (GCRYCTL_DISABLE_SECMEM, 0);
 221         gcry_control (GCRYCTL_INITIALIZATION_FINISHED, 0);
 222
 223         if (gcry_md_open(&mac, GCRY_MD_SHA512, GCRY_MD_FLAG_HMAC) != GPG_ERR_NO_ERROR)
 224           return 2;
 225
 226         gcry_md_setkey (mac, key, sizeof (key));
 227         gcry_md_write (mac, data, sizeof (data));
 228
 229         if (memcmp(gcry_md_read (mac, 0), result, gcry_md_get_algo_dlen (gcry_md_get_algo (mac))) != 0)
 230           return 3;
 231
 232         gcry_md_close (mac);
 233
 234         return 0;
 235     ]])],
 236   [AC_MSG_RESULT([yes])],
 237   [
 238    if test $? = 3
 239    then
 240      AC_MSG_FAILURE([HMAC test vector does not match. This is a known problem with libgcrypt 1.2.2 on Windows and fixed in 1.4.6.])
 241    else
 242      AC_MSG_FAILURE([HMAC test failed])
 243    fi
 244   ])
 245 AC_LANG_POP(C)
 246 fi      # $build = $target
 247
 248 # libcurl
 249 LIBCURL_CHECK_CONFIG(,7.20.1,,AC_MSG_ERROR([GNUnet requires libcurl >= 7.20.1]))
 250 # restore LIBS
 251 LIBS=$SAVE_LIBS
 252
 253
 254 glpk=true
 255 AC_CHECK_HEADERS(glpk.h, ,[gplk=false])
 256 AC_CHECK_LIB([glpk],[glp_create_prob], , [gplk=false])
 257 # GLPK must support atm MLP presolving, version >= 4.32
 258 AC_CHECK_MEMBERS(glp_iocp.presolve, ,[gplk=false],[[#include <glpk.h>]])
 259 if test x$gplk = xfalse
 260 then
 261         AM_CONDITIONAL(HAVE_GLPK, [test x$gplk = xtrue])
 262         AM_CONDITIONAL(HAVE_LIBGLPK, [test x$gplk != x$gplk])
 263         AC_MSG_WARN([GNUnet requires GLPK  >= 4.32])
 264 else
 265         AM_CONDITIONAL(HAVE_GLPK, [test x$gplk = xtrue])
 266         AM_CONDITIONAL(HAVE_LIBGLPK, [test x$gplk = x$gplk])
 267 fi
 268
 269 # test for kvm and kstat (for CPU stats under BSD/Solaris)
 270 AC_CHECK_LIB([kvm],[kvm_open])
 271 AC_CHECK_LIB([kstat],[kstat_open])
 272
 273 # test for libextractor
 274 extractor=0
 275 AC_MSG_CHECKING(for libextractor)
 276 AC_ARG_WITH(extractor,
 277    [  --with-extractor=PFX    base of libextractor installation],
 278    [AC_MSG_RESULT([$with_extractor])
 279     case $with_extractor in
 280       no)
 281         ;;
 282       yes)
 283         AC_CHECK_HEADERS(extractor.h,
 284           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 285             extractor=1))
 286         ;;
 287       *)
 288         LDFLAGS="-L$with_extractor/lib $LDFLAGS"
 289         CPPFLAGS="-I$with_extractor/include $CPPFLAGS"
 290         AC_CHECK_HEADERS(extractor.h,
 291           AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 292             EXT_LIB_PATH="-L$with_extractor/lib $EXT_LIB_PATH"
 293             extractor=1))
 294         ;;
 295     esac
 296    ],
 297    [AC_MSG_RESULT([--with-extractor not specified])
 298     AC_CHECK_HEADERS(extractor.h,
 299      AC_CHECK_LIB([extractor], [EXTRACTOR_plugin_add_defaults],
 300       extractor=1))])
 301 if test "$extractor" != 1
 302 then
 303  AC_MSG_ERROR([GNUnet requires libextractor])
 304 fi
 305 # restore LIBS
 306 LIBS=$SAVE_LIBS
 307
 308
 309 # Checks for standard header files.
 310 AC_HEADER_DIRENT
 311 AC_HEADER_STDC
 312
 313 # Check for headers that are ALWAYS required
 314 AC_CHECK_HEADERS([fcntl.h math.h errno.h ctype.h limits.h stdio.h stdlib.h string.h unistd.h stdarg.h signal.h locale.h sys/stat.h sys/types.h],,AC_MSG_ERROR([Compiling GNUnet requires standard UNIX headers files]))
 315
 316 # Checks for headers that are only required on some systems or opional (and where we do NOT abort if they are not there)
 317 AC_CHECK_HEADERS([langinfo.h sys/param.h sys/mount.h sys/statvfs.h sys/select.h sockLib.h sys/mman.h sys/msg.h sys/vfs.h arpa/inet.h fcntl.h libintl.h netdb.h netinet/in.h netinet/in_systm.h sys/ioctl.h sys/socket.h sys/time.h unistd.h kstat.h sys/sysinfo.h kvm.h sys/file.h sys/resource.h ifaddrs.h mach/mach.h stddef.h sys/timeb.h terminos.h argz.h ucred.h endian.h sys/endian.h])
 318
 319 SAVE_LDFLAGS=$LDFLAGS
 320 SAVE_CPPFLAGS=$CPPFLAGS
 321
 322 # test for sqlite
 323 sqlite=false
 324 AC_MSG_CHECKING(for SQLite)
 325 AC_ARG_WITH(sqlite,
 326   [  --with-sqlite=PFX       base of SQLite installation],
 327   [AC_MSG_RESULT("$with_sqlite")
 328    case $with_sqlite in
 329    no)
 330      ;;
 331    yes)
 332     AC_CHECK_HEADERS(sqlite3.h,
 333      sqlite=true)
 334      ;;
 335    *)
 336     LDFLAGS="-L$with_sqlite/lib $LDFLAGS"
 337     CPPFLAGS="-I$with_sqlite/include $CPPFLAGS"
 338     AC_CHECK_HEADERS(sqlite3.h,
 339      EXT_LIB_PATH="-L$with_sqlite/lib $EXT_LIB_PATH"
 340      SQLITE_LDFLAGS="-L$with_sqlite/lib"
 341      SQLITE_CPPFLAGS="-I$with_sqlite/include"
 342      sqlite=true)
 343     LDFLAGS=$SAVE_LDFLAGS
 344     CPPFLAGS=$SAVE_CPPFLAGS
 345     ;;
 346    esac
 347   ],
 348   [AC_MSG_RESULT([--with-sqlite not specified])
 349     AC_CHECK_HEADERS(sqlite3.h, sqlite=true)])
 350 AM_CONDITIONAL(HAVE_SQLITE, test x$sqlite = xtrue)
 351 AC_SUBST(SQLITE_CPPFLAGS)
 352 AC_SUBST(SQLITE_LDFLAGS)
 353
 354 # test for postgres
 355 postgres=false
 356 AC_MSG_CHECKING(for postgres)
 357 AC_ARG_WITH(postgres,
 358   [  --with-postgres=PFX       base of postgres installation],
 359   [AC_MSG_RESULT("$with_postgres")
 360    case $with_postgres in
 361    no)
 362      ;;
 363    yes)
 364     AC_CHECK_HEADERS(postgresql/libpq-fe.h,
 365      postgres=true)
 366      ;;
 367    *)
 368     LDFLAGS="-L$with_postgres/lib $LDFLAGS"
 369     CPPFLAGS="-I$with_postgres/include $CPPFLAGS"
 370     AC_CHECK_HEADERS(postgresql/libpq-fe.h,
 371      EXT_LIB_PATH="-L$with_postgres/lib $EXT_LIB_PATH"
 372      POSTGRES_LDFLAGS="-L$with_postgres/lib"
 373      POSTGRES_CPPFLAGS="-I$with_postgres/include"
 374      postgres=true)
 375     LDFLAGS=$SAVE_LDFLAGS
 376     CPPFLAGS=$SAVE_CPPFLAGS
 377     ;;
 378    esac
 379   ],
 380   [AC_MSG_RESULT([--with-postgres not specified])
 381     AC_CHECK_HEADERS(postgresql/libpq-fe.h, postgres=true)])
 382 AM_CONDITIONAL(HAVE_POSTGRES, test x$postgres = xtrue)
 383 AC_SUBST(POSTGRES_CPPFLAGS)
 384 AC_SUBST(POSTGRES_LDFLAGS)
 385
 386 # test for libz (maybe required for linking mysql)
 387 zlib=1
 388 AC_CHECK_LIB(z, compress,,zlib=0)
 389 AM_CONDITIONAL(HAVE_ZLIB, test x$zlib = x1)
 390 if test "$zlib" != 1
 391 then
 392  AC_MSG_ERROR([GNUnet requires zlib])
 393 fi
 394
 395 # mysql & windows
 396 AC_CHECK_TYPES([sigset_t, off_t], [], [], [#include <sys/types.h>])
 397 AC_CHECK_TYPES([size_t], [], [], [#include <stdio.h>])
 398
 399 if test "$build_target" = "mingw"
 400 then
 401   CYGWIN_MYSQL_MAGIC="#include <mysql/my_global.h>"
 402 fi
 403
 404 # test for mysql
 405 mysql=false
 406 mysqlfail=false
 407 SAVE_LDFLAGS=$LDFLAGS
 408 SAVE_CPPFLAGS=$CPPFLAGS
 409 AC_MSG_CHECKING(for mysql)
 410 AC_ARG_WITH(mysql,
 411   [  --with-mysql=PFX        base of MySQL installation],
 412   [AC_MSG_RESULT("$with_mysql")
 413    if test "$with_mysql" != "no"
 414    then
 415     if test "$with_mysql" != "yes"
 416     then
 417       LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql $LDFLAGS $ZLIBS"
 418       CPPFLAGS="-I$with_mysql/include $CPPFLAGS"
 419     fi
 420     AC_CHECK_HEADERS(mysql/mysql.h,
 421      AC_CHECK_LIB(mysqlclient, mysql_init,
 422       MYSQL_LDFLAGS="-L$with_mysql/lib -L$with_mysql/lib/mysql"
 423       MYSQL_CPPFLAGS="-I$with_mysql/include"
 424
 425       mysql=true), [], [$CYGWIN_MYSQL_MAGIC])
 426    fi
 427   ],
 428   [AC_MSG_RESULT([--with-mysql not specified])
 429    LDFLAGS="-L/usr/lib/mysql $LDFLAGS $ZLIBS"
 430    AC_CHECK_LIB(mysqlclient, mysql_init,
 431     [AC_CHECK_HEADERS(mysql/mysql.h,
 432       MYSQL_LDFLAGS="-L/usr/lib/mysql"
 433       mysql=true
 434
 435      , [], [$CYGWIN_MYSQL_MAGIC])])
 436   ])
 437
 438 AC_SUBST(MYSQL_LDFLAGS)
 439 AC_SUBST(MYSQL_CPPFLAGS)
 440
 441 # additional version check for mysql
 442 AC_ARG_ENABLE(mysql-version-check, [  --disable-mysql-version-check  do not check MySQL version],, enable_mysql_version_check=yes)
 443 if test "$mysql" = "true" -a "x$enable_mysql_version_check" = "xyes"
 444 then
 445   AC_MSG_CHECKING(mysql version)
 446   AC_RUN_IFELSE([AC_LANG_PROGRAM(
 447     [[$CYGWIN_MYSQL_MAGIC
 448       #include <mysql/mysql.h>]],
 449     [[if (MYSQL_VERSION_ID < 40100)
 450         return(-1);
 451       else
 452         return(0);
 453     ]])
 454     ],mysql=true,mysql=false)
 455   if test "$mysql" = "false"
 456   then
 457     mysqlfail=true
 458     AC_MSG_RESULT([fail, >= 4.1 required])
 459   else
 460     AC_MSG_RESULT(ok)
 461   fi
 462 fi
 463 AM_CONDITIONAL(HAVE_MYSQL, test x$mysql = xtrue)
 464 AM_CONDITIONAL(HAVE_MYSQLE, test "0" = "1")
 465 # restore LIBS
 466 LIBS=$SAVE_LIBS
 467 LDFLAGS=$SAVE_LDFLAGS
 468 CPPFLAGS=$SAVE_CPPFLAGS
 469
 470 if test "$sqlite" = 0 -a "$mysql" = 0
 471 then
 472  AC_MSG_ERROR([GNUnet requires SQLite or MySQL])
 473 fi
 474
 475 # libmicrohttpd
 476 lmhd=0
 477 AC_MSG_CHECKING([for libmicrohttpd])
 478 AC_ARG_WITH(microhttpd,
 479    [  --with-microhttpd=PFX   base of libmicrohttpd installation],
 480    [AC_MSG_RESULT([$with_microhttpd])
 481     case $with_microhttpd in
 482       no)
 483         ;;
 484       yes)
 485         AC_CHECK_HEADERS([microhttpd.h],
 486           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 487             AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 488               lmhd=1),
 489             [],[#include "src/include/platform.h"
 490                 #include <microhttpd.h>]),,
 491             [#include "src/include/platform.h"])
 492         ;;
 493       *)
 494         LDFLAGS="-L$with_microhttpd/lib $LDFLAGS"
 495         CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"
 496         AC_CHECK_HEADERS(microhttpd.h,
 497           AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 498             AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 499               EXT_LIB_PATH="-L$with_microhttpd/lib $EXT_LIB_PATH"
 500               lmhd=1),
 501             [],[#include "src/include/platform.h"
 502                 #include <microhttpd.h>]),,
 503             [#include "src/include/platform.h"])
 504         ;;
 505     esac
 506    ],
 507    [AC_MSG_RESULT([--with-microhttpd not specified])
 508     AC_CHECK_HEADERS([microhttpd.h],
 509       AC_CHECK_DECL(MHD_OPTION_PER_IP_CONNECTION_LIMIT,
 510         AC_CHECK_LIB([microhttpd], [MHD_start_daemon],
 511           lmhd=1),
 512         [],[#include "src/include/platform.h"
 513             #include <microhttpd.h>]),,
 514        [#include "src/include/platform.h"])])
 515 AM_CONDITIONAL(HAVE_MHD, test x$lmhd = x1)
 516 AC_DEFINE_UNQUOTED([HAVE_MHD], $lmhd, [We have libmicrohttpd])
 517
 518
 519 # openssl
 520 openssl=0
 521 AC_MSG_CHECKING([for openssl])
 522 AC_ARG_WITH(openssl,
 523    [  --with-openssl=PFX   base of openssl installation],
 524    [AC_MSG_RESULT([$with_openssl])
 525     case $with_openssl in
 526       no)
 527         ;;
 528       yes)
 529         AC_CHECK_HEADERS([openssl/ssl.h],
 530             AC_CHECK_LIB([ssl], [SSL_new],
 531              openssl=1))
 532         ;;
 533       *)
 534         LDFLAGS="-L$with_openssl/lib $LDFLAGS"
 535         CPPFLAGS="-I$with_openssl/include $CPPFLAGS"
 536         AC_CHECK_HEADERS([openssl/ssl.h],
 537             AC_CHECK_LIB([ssl], [SSL_new],
 538               EXT_LIB_PATH="-L$with_openssl/lib $EXT_LIB_PATH"
 539               openssl=1))
 540         ;;
 541     esac
 542    ],
 543    [AC_MSG_RESULT([--with-openssl not specified])
 544     AC_CHECK_HEADERS([openssl/ssl.h],
 545         AC_CHECK_LIB([ssl], [SSL_new],
 546           openssl=1))])
 547 AM_CONDITIONAL(HAVE_OPENSSL, test x$openssl = x1)
 548 AC_DEFINE_UNQUOTED([HAVE_OPENSSL], $openssl, [We have openssl])
 549
 550
 551
 552
 553
 554
 555 # restore LIBS
 556 LIBS=$SAVE_LIBS
 557
 558 # check for python & pexpect (used for some testcases only)
 559 AM_PATH_PYTHON([2.5],, [:])
 560 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
 561
 562 if test "$PYTHON" != :
 563 then
 564   AC_MSG_CHECKING([for pexpect])
 565   $PYTHON -c "import pexpect" > /dev/null 2> /dev/null
 566   PYEX=$?
 567   AM_CONDITIONAL(HAVE_PYTHON_PEXPECT, test $PYEX -eq 0)
 568   if test $PYEX -eq 0
 569   then
 570     AC_MSG_RESULT([yes])
 571   else
 572     AC_MSG_RESULT([not found])
 573   fi
 574 else
 575   AM_CONDITIONAL(HAVE_PYTHON_PEXPECT, 0)
 576 fi
 577
 578 # libesmtp
 579 esmtp=0
 580 AC_MSG_CHECKING([for libesmtp])
 581 AC_ARG_WITH(esmtp,
 582    [  --with-esmtp=PFX        base of libesmtp installation],
 583    [AC_MSG_RESULT([$with_esmtp])
 584     case $with_esmtp in
 585       no)
 586         ;;
 587       yes)
 588         AC_CHECK_HEADERS(libesmtp.h,
 589           AC_CHECK_LIB([esmtp], [smtp_start_session],
 590             esmtp=1))
 591         ;;
 592       *)
 593         LDFLAGS="-L$with_esmtp/lib $LDFLAGS"
 594         CPPFLAGS="-I$with_esmtp/include $CPPFLAGS"
 595         AC_CHECK_HEADERS(libesmtp.h,
 596           AC_CHECK_LIB([esmtp], [smtp_start_session],
 597             EXT_LIB_PATH="-L$with_esmtp/lib $EXT_LIB_PATH"
 598               esmtp=1))
 599         ;;
 600     esac
 601    ],
 602    [AC_MSG_RESULT([--with-esmtp not specified])
 603     AC_CHECK_HEADERS(libesmtp.h,
 604       AC_CHECK_LIB([esmtp], [smtp_start_session],
 605           esmtp=1))])
 606 AM_CONDITIONAL(HAVE_ESMTP, test x$esmtp = x1)
 607 AC_DEFINE_UNQUOTED([HAVE_ESMTP], $esmtp, [We have libesmtp])
 608 # restore LIBS
 609 LIBS=$SAVE_LIBS
 610
 611
 612
 613 # check for gettext
 614 AM_GNU_GETTEXT([external])
 615 AM_GNU_GETTEXT_VERSION([0.16.1])
 616
 617 # check for iconv
 618 AM_ICONV
 619
 620 # Checks for standard typedefs, structures, and compiler characteristics.
 621 AC_TYPE_PID_T
 622 AC_TYPE_SIZE_T
 623 AC_TYPE_MODE_T
 624 AC_HEADER_TIME
 625 AC_HEADER_STAT
 626 AC_HEADER_STDBOOL
 627 AC_STRUCT_TM
 628
 629 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 630    [ AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [Do we have sockaddr_in.sin_len?])
 631    ],
 632    [],
 633    [
 634       #include <sys/types.h>
 635       #include <sys/socket.h>
 636       #include <netinet/in.h>
 637    ])
 638
 639
 640
 641 # Checks for library functions.
 642 AC_FUNC_CLOSEDIR_VOID
 643 AC_FUNC_FORK
 644 AC_FUNC_VFORK
 645 AC_PROG_GCC_TRADITIONAL
 646 AC_FUNC_MEMCMP
 647 AC_FUNC_SELECT_ARGTYPES
 648 AC_FUNC_CHOWN
 649
 650 AC_TYPE_SIGNAL
 651 AC_FUNC_STAT
 652 AC_FUNC_STRFTIME
 653 AC_FUNC_VPRINTF
 654 AC_HEADER_SYS_WAIT
 655 AC_TYPE_OFF_T
 656 AC_TYPE_UID_T
 657 AC_CHECK_FUNCS([floor gethostname memmove rmdir strncasecmp strrchr strtol atoll dup2 fdatasync ftruncate gettimeofday memset mkdir mkfifo select socket strcasecmp strchr strdup strerror strstr clock_gettime getrusage rand uname setlocale getcwd mktime gmtime_r gmtime strlcpy strlcat ftruncate stat64 sbrk mmap mremap setrlimit sysconf gethostbyaddr initgroups getifaddrs freeifaddrs getnameinfo getaddrinfo inet_ntoa localtime_r nl_langinfo putenv realpath strndup gethostbyname2 gethostbyname getpeerucred getpeereid])
 658
 659 # restore LIBS
 660 LIBS=$SAVE_LIBS
 661
 662 gn_user_home_dir="~/.gnunet"
 663 AC_ARG_WITH(user-home-dir,
 664         AC_HELP_STRING(
 665                 [--with-user-home-dir=DIR],
 666                 [default user home directory (~/.gnunet)]),
 667         [gn_user_home_dir=$withval])
 668 AC_SUBST(GN_USER_HOME_DIR, $gn_user_home_dir)
 669 gn_daemon_home_dir="/var/lib/gnunet"
 670 AC_ARG_WITH(daemon-home-dir,
 671         AC_HELP_STRING(
 672                 [--with-daemon-home-dir=DIR],
 673                 [default daemon home directory (/var/lib/gnunet)]),
 674         [gn_daemon_home_dir=$withval])
 675 AC_SUBST(GN_DAEMON_HOME_DIR, $gn_daemon_home_dir)
 676 gn_daemon_config_dir="/etc"
 677 AC_ARG_WITH(daemon-config-dir,
 678         AC_HELP_STRING(
 679                 [--with-daemon-config-dir=DIR],
 680                 [default daemon config directory (/etc)]),
 681         [gn_daemon_config_dir=$withval])
 682 AC_SUBST(GN_DAEMON_CONFIG_DIR, $gn_daemon_config_dir)
 683
 684 GN_INTLINCL=""
 685 GN_LIBINTL="$LTLIBINTL"
 686 AC_ARG_ENABLE(framework, [  --enable-framework      enable Mac OS X framework build helpers],enable_framework_build=$enableval)
 687 AM_CONDITIONAL(WANT_FRAMEWORK, test x$enable_framework_build = xyes)
 688 if test x$enable_framework_build = xyes
 689 then
 690   AC_DEFINE([FRAMEWORK_BUILD], 1, [Build a Mac OS X Framework])
 691   GN_INTLINCL='-I$(top_srcdir)/src/intlemu'
 692   GN_LIBINTL='$(top_builddir)/src/intlemu/libintlemu.la -framework CoreFoundation'
 693   AC_LIB_APPENDTOVAR([CPPFLAGS], [$GN_INTLINCL])
 694 fi
 695
 696 GN_LIB_LDFLAGS="-export-dynamic -no-undefined"
 697 GN_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
 698
 699 AC_SUBST(GN_LIB_LDFLAGS)
 700 AC_SUBST(GN_PLUGIN_LDFLAGS)
 701 AC_SUBST(GN_INTLINCL)
 702 AC_SUBST(GN_LIBINTL)
 703
 704 AC_SUBST(CPPFLAGS)
 705 AC_SUBST(LIBS)
 706 AC_SUBST(LDFLAGS)
 707 AC_SUBST(EXT_LIB_PATH)
 708 AC_SUBST(EXT_LIBS)
 709
 710 AC_SUBST(LIBPREFIX)
 711 AC_SUBST(DLLDIR)
 712 AC_SUBST(EXT_LIB_PATH)
 713
 714
 715 # should 'make check' run tests?
 716 AC_MSG_CHECKING(whether to run tests)
 717 AC_ARG_ENABLE([testruns],
 718    [AS_HELP_STRING([--disable-testruns], [disable running tests on make check (default is YES)])],
 719    [enable_tests_run=${enableval}],
 720    [enable_tests_run=yes])
 721 AC_MSG_RESULT($enable_test_run)
 722 AM_CONDITIONAL([ENABLE_TEST_RUN], [test "x$enable_tests_run" = "xyes"])
 723
 724 # should expensive tests be run?
 725 AC_MSG_CHECKING(whether to run expensive tests)
 726 AC_ARG_ENABLE([expensivetests],
 727    [AS_HELP_STRING([--enable-expensive-tests], [enable running expensive testcases])],
 728    [enable_expensive=${enableval}],
 729    [enable_expensive=no])
 730 AC_MSG_RESULT($enable_expensive)
 731 AM_CONDITIONAL([HAVE_EXPENSIVE_TESTS], [test "x$enable_expensive" = "xyes"])
 732
 733 # should benchmarks be run?
 734 AC_MSG_CHECKING(whether to run benchmarks during make check)
 735 AC_ARG_ENABLE([benchmarks],
 736    [AS_HELP_STRING([--enable-benchmarks], [enable running benchmarks during make check])],
 737    [enable_benchmarks=${enableval}],
 738    [enable_benchmarks=no])
 739 AC_MSG_RESULT($enable_benchmarks)
 740 AM_CONDITIONAL([HAVE_BENCHMARKS], [test "x$enable_benchmarks" = "xyes"])
 741
 742 # should experimental code be compiled (code that may not yet compile)?
 743 AC_MSG_CHECKING(whether to compile experimental code)
 744 AC_ARG_ENABLE([experimental],
 745    [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
 746    [enable_experimental=${enableval}],
 747    [enable_experimental=no])
 748 AC_MSG_RESULT($enable_experimental)
 749 AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
 750
 751 # should malicious code be compiled (code used for testing with malicious peers)
 752 AC_MSG_CHECKING(whether to compile malicious code)
 753 AC_ARG_ENABLE([malicious],
 754    [AS_HELP_STRING([--enable-malicious], [enable compiling malicious code (only for developers for testing)])],
 755    [enable_malicious=${enableval}],
 756    [enable_malicious=no])
 757 AC_MSG_RESULT($enable_malicious)
 758 AM_CONDITIONAL([HAVE_MALICIOUS], [test "x$enable_malicious" = "xyes"])
 759 if test "$enable_malicious" = "yes"
 760 then
 761  AC_DEFINE([HAVE_MALICIOUS],[1],[include malicious code])
 762 else
 763  AC_DEFINE([HAVE_MALICIOUS],[0],[disable malicious code])
 764 fi
 765
 766 # should code be enabled that works around missing OS functionality on Windows?
 767 # used for test cases
 768 if test $build_target = "mingw"
 769 then
 770         workarounds=1
 771 else
 772   AC_MSG_CHECKING(whether to enable windows workarounds)
 773   AC_ARG_ENABLE([windows_workarounds],
 774      [AS_HELP_STRING([--enable-windows_workarounds], [enable workarounds used on Windows (only useful for test cases)])],
 775      [enable_workarounds=${enableval}],
 776      [enable_workarounds=no])
 777   AC_MSG_RESULT($enable_workarounds)
 778   if test x$enable_windows_workarounds = "xyes"
 779   then
 780      workarounds=1
 781   else
 782      workarounds=0
 783    fi
 784 fi
 785 AC_DEFINE_UNQUOTED([ENABLE_WINDOWS_WORKAROUNDS], $workarounds, [enable workarounds used on Windows (only useful for test cases)])
 786
 787 # gcov compilation
 788 AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
 789 AC_ARG_ENABLE([coverage],
 790               AS_HELP_STRING([--enable-coverage],
 791                              [compile the library with code coverage support]),
 792               [use_gcov=${enableval}],
 793               [use_gcov=no])
 794 AC_MSG_RESULT($use_gcov)
 795 AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
 796
 797
 798 AC_CONFIG_FILES([
 799 Makefile
 800 contrib/Makefile
 801 doc/Makefile
 802 doc/man/Makefile
 803 m4/Makefile
 804 po/Makefile.in
 805 src/Makefile
 806 src/arm/Makefile
 807 src/block/Makefile
 808 src/core/Makefile
 809 src/datacache/Makefile
 810 src/datastore/Makefile
 811 src/dht/Makefile
 812 src/dv/Makefile
 813 src/fragmentation/Makefile
 814 src/fs/Makefile
 815 src/hello/Makefile
 816 src/include/Makefile
 817 src/include/gnunet_directories.h
 818 src/hostlist/Makefile
 819 src/mesh/Makefile
 820 src/monkey/Makefile
 821 src/nat/Makefile
 822 src/peerinfo/Makefile
 823 src/peerinfo-tool/Makefile
 824 src/statistics/Makefile
 825 src/template/Makefile
 826 src/testing/Makefile
 827 src/topology/Makefile
 828 src/transport/Makefile
 829 src/util/Makefile
 830 src/vpn/Makefile
 831 src/chat/Makefile
 832 pkgconfig/Makefile
 833 pkgconfig/gnunetarm.pc
 834 pkgconfig/gnunetblock.pc
 835 pkgconfig/gnunetcore.pc
 836 pkgconfig/gnunetdatacache.pc
 837 pkgconfig/gnunetdatastore.pc
 838 pkgconfig/gnunetdht.pc
 839 pkgconfig/gnunetdhtlog.pc
 840 pkgconfig/gnunetdv.pc
 841 pkgconfig/gnunetfragmentation.pc
 842 pkgconfig/gnunetfs.pc
 843 pkgconfig/gnunethello.pc
 844 pkgconfig/gnunetpeerinfo.pc
 845 pkgconfig/gnunetstatistics.pc
 846 pkgconfig/gnunettesting.pc
 847 pkgconfig/gnunettransport.pc
 848 pkgconfig/gnunetutil.pc
 849 ])
 850 AC_OUTPUT
 851
 852 # Finally: summary!
 853
 854 # warn user if mysql found but not used due to version
 855 if test "$mysqlfail" = "true"
 856 then
 857   AC_MSG_NOTICE([NOTICE: MySQL found, but too old. MySQL support will not be compiled.])
 858 fi
 859
 860 # sqlite
 861 if test "x$sqlite" = "x0"
 862 then
 863   AC_MSG_NOTICE([NOTICE: sqlite not found.  sqLite support will not be compiled.])
 864 fi
 865
 866 if test "x$lmhd" != "x1"
 867 then
 868  AC_MSG_NOTICE([NOTICE: libmicrohttpd not found, http transport will not be installed.])
 869 fi
 870
 871 if test "x$esmtp" != "x1"
 872 then
 873  AC_MSG_NOTICE([NOTICE: libesmtp not found, monkey will not be installed.])
 874 fi
 875
 876 if test "x$openssl" != "x1"
 877 then
 878  AC_MSG_NOTICE([NOTICE: OpenSSL not found, monkey will not be installed.])
 879 fi
 880
 881 AC_MSG_NOTICE([NOTICE: Database support is set to MySQL: $mysql, SQLite: $sqlite, Postgres: $postgres])
 882
 883 if test "$enable_framework_build" = "yes"
 884 then
 885   AC_MSG_NOTICE([NOTICE: Mac OS X framework build enabled.])
 886 fi
 887
 888 AC_MSG_NOTICE([********************************************
 889 You can compile GNUnet with
 890         make
 891 now. After that, run (if necessary as 'root')
 892         make install
 893 to install everything. You may want to create a new user account
 894 to run the GNUnet service:
 895         adduser gnunet
 896 You also need to create an configuration file that should
 897 specify the path where GNUnet should store data.  For example,
 898 you could store in "/etc/gnunet.conf" the following lines:
 899
 900 [[PATHS]]
 901 SERVICEHOME = /var/lib/gnunet
 902 DEFAULTCONFIG = /etc/gnunet.conf
 903
 904 Now, in order to start your peer, run as the 'gnunet' user
 905         gnunet-arm -s
 906
 907 Each GNUnet user should also create an (at least initially) empty
 908 configuration file:
 909         mkdir $HOME/.gnunet/
 910         touch $HOME/.gnunet/gnunet.conf
 911
 912 Optionally, download and compile gnunet-gtk to get a GUI.
 913 ********************************************])