cmake/Modules/FindIrrlicht.cmake

   1
   2 mark_as_advanced(IRRLICHT_LIBRARY IRRLICHT_INCLUDE_DIR IRRLICHT_DLL)
   3 set(IRRLICHT_SOURCE_DIR "" CACHE PATH "Path to irrlicht source directory (optional)")
   4
   5
   6 # Find include directory
   7
   8 if(NOT IRRLICHT_SOURCE_DIR STREQUAL "")
   9         set(IRRLICHT_SOURCE_DIR_INCLUDE
  10                 "${IRRLICHT_SOURCE_DIR}/include"
  11         )
  12
  13         set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a Irrlicht Irrlicht.lib)
  14
  15         if(WIN32)
  16                 if(MSVC)
  17                         set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Win32-visualstudio")
  18                         set(IRRLICHT_LIBRARY_NAMES Irrlicht.lib)
  19                 else()
  20                         set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Win32-gcc")
  21                         set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a libIrrlicht.dll.a)
  22                 endif()
  23         else()
  24                 set(IRRLICHT_SOURCE_DIR_LIBS "${IRRLICHT_SOURCE_DIR}/lib/Linux")
  25                 set(IRRLICHT_LIBRARY_NAMES libIrrlicht.a)
  26         endif()
  27
  28         find_path(IRRLICHT_INCLUDE_DIR NAMES irrlicht.h
  29                 PATHS
  30                 ${IRRLICHT_SOURCE_DIR_INCLUDE}
  31                 NO_DEFAULT_PATH
  32         )
  33
  34         find_library(IRRLICHT_LIBRARY NAMES ${IRRLICHT_LIBRARY_NAMES}
  35                 PATHS
  36                 ${IRRLICHT_SOURCE_DIR_LIBS}
  37                 NO_DEFAULT_PATH
  38         )
  39
  40 else()
  41         find_path(IRRLICHT_INCLUDE_DIR NAMES irrlicht.h
  42                 PATHS
  43                 /usr/local/include/irrlicht
  44                 /usr/include/irrlicht
  45         )
  46
  47         find_library(IRRLICHT_LIBRARY NAMES libIrrlicht.so libIrrlicht.a Irrlicht
  48                 PATHS
  49                 /usr/local/lib
  50                 /usr/lib
  51         )
  52 endif()
  53
  54
  55 # On Windows, find the DLL for installation
  56 if(WIN32)
  57         if(MSVC)
  58                 set(IRRLICHT_COMPILER "VisualStudio")
  59         else()
  60                 set(IRRLICHT_COMPILER "gcc")
  61         endif()
  62         find_file(IRRLICHT_DLL NAMES Irrlicht.dll
  63                 PATHS
  64                 "${IRRLICHT_SOURCE_DIR}/bin/Win32-${IRRLICHT_COMPILER}"
  65                 DOC "Path of the Irrlicht dll (for installation)"
  66         )
  67 endif(WIN32)
  68
  69 include(FindPackageHandleStandardArgs)
  70 find_package_handle_standard_args(Irrlicht DEFAULT_MSG IRRLICHT_LIBRARY IRRLICHT_INCLUDE_DIR)
  71