board/ml2/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     /* WARNING - the following is hand-optimized to fit within  */
  56     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  57
  58     arch/powerpc/cpu/ppc4xx/start.o     (.text)
  59     board/ml2/init.o    (.text)
  60     arch/powerpc/cpu/ppc4xx/kgdb.o      (.text)
  61     arch/powerpc/cpu/ppc4xx/traps.o     (.text)
  62     arch/powerpc/cpu/ppc4xx/interrupts.o        (.text)
  63     arch/powerpc/cpu/ppc4xx/4xx_uart.o  (.text)
  64     arch/powerpc/cpu/ppc4xx/cpu_init.o  (.text)
  65     arch/powerpc/cpu/ppc4xx/speed.o     (.text)
  66     common/dlmalloc.o   (.text)
  67     lib/crc32.o         (.text)
  68     arch/powerpc/lib/extable.o  (.text)
  69     lib/zlib.o          (.text)
  70
  71 /*    . = env_offset;*/
  72 /*    common/env_embedded.o(.text)*/
  73
  74     *(.text)
  75     *(.got1)
  76   }
  77   _etext = .;
  78   PROVIDE (etext = .);
  79   .rodata    :
  80   {
  81     *(.eh_frame)
  82     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  83   }
  84   .fini      : { *(.fini)    } =0
  85   .ctors     : { *(.ctors)   }
  86   .dtors     : { *(.dtors)   }
  87
  88   /* Read-write section, merged into data segment: */
  89   . = (. + 0x00FF) & 0xFFFFFF00;
  90   _erotext = .;
  91   PROVIDE (erotext = .);
  92   .reloc   :
  93   {
  94     *(.got)
  95     _GOT2_TABLE_ = .;
  96     *(.got2)
  97     _FIXUP_TABLE_ = .;
  98     *(.fixup)
  99   }
 100   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 101   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 102
 103   .data    :
 104   {
 105     *(.data)
 106     *(.data1)
 107     *(.sdata)
 108     *(.sdata2)
 109     *(.dynamic)
 110     CONSTRUCTORS
 111   }
 112   _edata  =  .;
 113   PROVIDE (edata = .);
 114
 115   . = .;
 116   __u_boot_cmd_start = .;
 117   .u_boot_cmd : { *(.u_boot_cmd) }
 118   __u_boot_cmd_end = .;
 119
 120
 121   . = .;
 122   __start___ex_table = .;
 123   __ex_table : { *(__ex_table) }
 124   __stop___ex_table = .;
 125
 126   . = ALIGN(256);
 127   __init_begin = .;
 128   .text.init : { *(.text.init) }
 129   .data.init : { *(.data.init) }
 130   . = ALIGN(256);
 131   __init_end = .;
 132
 133   __bss_start = .;
 134   .bss (NOLOAD)       :
 135   {
 136    *(.sbss) *(.scommon)
 137    *(.dynbss)
 138    *(.bss)
 139    *(COMMON)
 140    . = ALIGN(4);
 141   }
 142   _end = . ;
 143   PROVIDE (end = .);
 144 }