board/matrix_vision/mvsmr/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  * (C) Copyright 2010
   5  * André Schwarz, Matrix Vision GmbH, as@matrix-vision.de
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the first two sectors (=8KB) of our S29GL flash chip */
  58     arch/powerpc/cpu/mpc5xxx/start.o          (.text)
  59     arch/powerpc/cpu/mpc5xxx/traps.o          (.text)
  60     lib/crc32.o         (.text)
  61     arch/powerpc/lib/cache.o             (.text)
  62     arch/powerpc/lib/time.o              (.text)
  63
  64     /* This is only needed to force failure if size of above code will ever */
  65     /* increase and grow into reserved space. */
  66     . = ALIGN(0x2000);  /* location counter has to be 0x4000 now */
  67     . += 0x4000;        /* ->0x8000, i.e. move to env_offset */
  68
  69     . = env_offset;     /* ld error as soon as above ALIGN misplaces lc */
  70     common/env_embedded.o        (.ppcenv)
  71
  72     *(.text)
  73     *(.got1)
  74     . = ALIGN(16);
  75     *(.eh_frame)
  76     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  77   }
  78   .fini      : { *(.fini)    } =0
  79   .ctors     : { *(.ctors)   }
  80   .dtors     : { *(.dtors)   }
  81
  82   /* Read-write section, merged into data segment: */
  83   . = (. + 0x0FFF) & 0xFFFFF000;
  84   _erotext = .;
  85   PROVIDE (erotext = .);
  86   .reloc   :
  87   {
  88     *(.got)
  89     _GOT2_TABLE_ = .;
  90     *(.got2)
  91     _FIXUP_TABLE_ = .;
  92     *(.fixup)
  93   }
  94   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  95   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  96
  97   .data    :
  98   {
  99     *(.data)
 100     *(.data1)
 101     *(.sdata)
 102     *(.sdata2)
 103     *(.dynamic)
 104     CONSTRUCTORS
 105   }
 106   _edata  =  .;
 107   PROVIDE (edata = .);
 108
 109   . = .;
 110   __u_boot_cmd_start = .;
 111   .u_boot_cmd : { *(.u_boot_cmd) }
 112   __u_boot_cmd_end = .;
 113
 114
 115   . = .;
 116   __start___ex_table = .;
 117   __ex_table : { *(__ex_table) }
 118   __stop___ex_table = .;
 119
 120   . = ALIGN(4096);
 121   __init_begin = .;
 122   .text.init : { *(.text.init) }
 123   .data.init : { *(.data.init) }
 124   . = ALIGN(4096);
 125   __init_end = .;
 126
 127   __bss_start = .;
 128   .bss (NOLOAD)       :
 129   {
 130    *(.sbss) *(.scommon)
 131    *(.dynbss)
 132    *(.bss)
 133    *(COMMON)
 134    . = ALIGN(4);
 135   }
 136   _end = . ;
 137   PROVIDE (end = .);
 138 }