board/flagadm/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  33     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  34
  35     *(.text*)
  36   }
  37   _etext = .;
  38   PROVIDE (etext = .);
  39   .rodata    :
  40   {
  41     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  42   }
  43
  44   /* Read-write section, merged into data segment: */
  45   . = (. + 0x00FF) & 0xFFFFFF00;
  46   _erotext = .;
  47   PROVIDE (erotext = .);
  48   .reloc   :
  49   {
  50     _GOT2_TABLE_ = .;
  51     KEEP(*(.got2))
  52     KEEP(*(.got))
  53     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  54     _FIXUP_TABLE_ = .;
  55     KEEP(*(.fixup))
  56   }
  57   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  58   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  59
  60   .data    :
  61   {
  62     *(.data*)
  63     *(.sdata*)
  64   }
  65   _edata  =  .;
  66   PROVIDE (edata = .);
  67
  68   . = .;
  69   __u_boot_cmd_start = .;
  70   .u_boot_cmd : { *(.u_boot_cmd) }
  71   __u_boot_cmd_end = .;
  72
  73
  74   . = .;
  75   __start___ex_table = .;
  76   __ex_table : { *(__ex_table) }
  77   __stop___ex_table = .;
  78
  79   . = ALIGN(256);
  80   __init_begin = .;
  81   .text.init : { *(.text.init) }
  82   .data.init : { *(.data.init) }
  83   . = ALIGN(256);
  84   __init_end = .;
  85
  86   __bss_start = .;
  87   .bss (NOLOAD)       :
  88   {
  89    *(.bss*)
  90    *(.sbss*)
  91    *(COMMON)
  92    . = ALIGN(4);
  93   }
  94   __bss_end__ = . ;
  95   PROVIDE (end = .);
  96 }