board/esteem192e/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37     net/libnet.o                        (.text*)
  38     board/esteem192e/libesteem192e.o    (.text*)
  39     *(.text.*printf)
  40
  41     . = env_offset;
  42     common/env_embedded.o               (.text*)
  43
  44     *(.text*)
  45   }
  46   _etext = .;
  47   PROVIDE (etext = .);
  48   .rodata    :
  49   {
  50     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  51   }
  52
  53   /* Read-write section, merged into data segment: */
  54   . = (. + 0x00FF) & 0xFFFFFF00;
  55   _erotext = .;
  56   PROVIDE (erotext = .);
  57   .reloc   :
  58   {
  59     _GOT2_TABLE_ = .;
  60     KEEP(*(.got2))
  61     KEEP(*(.got))
  62     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  63     _FIXUP_TABLE_ = .;
  64     KEEP(*(.fixup))
  65   }
  66   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  67   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  68
  69   .data    :
  70   {
  71     *(.data*)
  72     *(.sdata*)
  73   }
  74   _edata  =  .;
  75   PROVIDE (edata = .);
  76
  77   . = .;
  78   __u_boot_cmd_start = .;
  79   .u_boot_cmd : { *(.u_boot_cmd) }
  80   __u_boot_cmd_end = .;
  81
  82
  83   . = .;
  84   __start___ex_table = .;
  85   __ex_table : { *(__ex_table) }
  86   __stop___ex_table = .;
  87
  88   . = ALIGN(256);
  89   __init_begin = .;
  90   .text.init : { *(.text.init) }
  91   .data.init : { *(.data.init) }
  92   . = ALIGN(256);
  93   __init_end = .;
  94
  95   __bss_start = .;
  96   .bss (NOLOAD)       :
  97   {
  98    *(.bss*)
  99    *(.sbss*)
 100    *(COMMON)
 101    . = ALIGN(4);
 102   }
 103   __bss_end__ = . ;
 104   PROVIDE (end = .);
 105 }