arch/x86/cpu/start.S

   1 /* SPDX-License-Identifier: GPL-2.0+ */
   2 /*
   3  *  U-Boot - x86 Startup Code
   4  *
   5  * (C) Copyright 2008-2011
   6  * Graeme Russ, <graeme.russ@gmail.com>
   7  *
   8  * (C) Copyright 2002
   9  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
  10  */
  11
  12 #include <config.h>
  13 #include <asm/global_data.h>
  14 #include <asm/post.h>
  15 #include <asm/processor.h>
  16 #include <asm/processor-flags.h>
  17 #include <generated/generic-asm-offsets.h>
  18 #include <generated/asm-offsets.h>
  19 #include <linux/linkage.h>
  20
  21 .section .text.start
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail-safe 32-bit bootstrap entry point.
  29          *
  30          * This code is used when booting from another boot loader like
  31          * coreboot or EFI. So we repeat some of the same init found in
  32          * start16.
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /*
  44          * Zero the BIST (Built-In Self Test) value since we don't have it.
  45          * It must be 0 or the previous loader would have reported an error.
  46          */
  47         movl    $0, %ebp
  48
  49         jmp     1f
  50
  51         /* Add a way for tools to discover the _start entry point */
  52         .align  4
  53         .long   0x12345678
  54 _start:
  55         /* This is the 32-bit cold-reset entry point, coming from start16 */
  56
  57         /* Save BIST */
  58         movl    %eax, %ebp
  59 1:
  60
  61         /* Save table pointer */
  62         movl    %ecx, %esi
  63
  64 #ifdef CONFIG_X86_LOAD_FROM_32_BIT
  65         lgdt    gdt_ptr2
  66 #endif
  67
  68         /* Load the segement registers to match the GDT loaded in start16.S */
  69         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  70         movw    %ax, %fs
  71         movw    %ax, %ds
  72         movw    %ax, %gs
  73         movw    %ax, %es
  74         movw    %ax, %ss
  75
  76         /* Clear the interrupt vectors */
  77         lidt    blank_idt_ptr
  78
  79         /*
  80          * Critical early platform init - generally not used, we prefer init
  81          * to happen later when we have a console, in case something goes
  82          * wrong.
  83          */
  84         jmp     early_board_init
  85 .globl early_board_init_ret
  86 early_board_init_ret:
  87         post_code(POST_START)
  88
  89         /* Initialise Cache-As-RAM */
  90         jmp     car_init
  91 .globl car_init_ret
  92 car_init_ret:
  93 #ifndef CONFIG_USE_HOB
  94         /*
  95          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  96          * or fully initialised SDRAM - we really don't care which)
  97          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  98          * and early malloc() area. The MRC requires some space at the top.
  99          *
 100          * Stack grows down from top of CAR. We have:
 101          *
 102          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
 103          *      MRC area
 104          *      global_data with x86 global descriptor table
 105          *      early malloc area
 106          *      stack
 107          * bottom-> CONFIG_SYS_CAR_ADDR
 108          */
 109         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
 110 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
 111         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
 112 #endif
 113 #else
 114         /*
 115          * U-Boot enters here twice. For the first time it comes from
 116          * car_init_done() with esp points to a temporary stack and esi
 117          * set to zero. For the second time it comes from fsp_init_done()
 118          * with esi holding the HOB list address returned by the FSP.
 119          */
 120 #endif
 121         /* Set up global data */
 122         mov     %esp, %eax
 123         call    board_init_f_alloc_reserve
 124         mov     %eax, %esp
 125         call    board_init_f_init_reserve
 126
 127 #ifdef CONFIG_DEBUG_UART
 128         call    debug_uart_init
 129 #endif
 130
 131         /* Get address of global_data */
 132         mov     %fs:0, %edx
 133 #ifdef CONFIG_USE_HOB
 134         /* Store the HOB list if we have one */
 135         test    %esi, %esi
 136         jz      skip_hob
 137         movl    %esi, GD_HOB_LIST(%edx)
 138
 139 #ifdef CONFIG_HAVE_FSP
 140         /*
 141          * After fsp_init() returns, the stack has already been switched to a
 142          * place within system memory as defined by CONFIG_FSP_TEMP_RAM_ADDR.
 143          * Enlarge the size of malloc() pool before relocation since we have
 144          * plenty of memory now.
 145          */
 146         subl    $CONFIG_FSP_SYS_MALLOC_F_LEN, %esp
 147         movl    %esp, GD_MALLOC_BASE(%edx)
 148 #endif
 149 skip_hob:
 150 #else
 151         /* Store table pointer */
 152         movl    %esi, GD_TABLE(%edx)
 153 #endif
 154         /* Store BIST */
 155         movl    %ebp, GD_BIST(%edx)
 156
 157         /* Set parameter to board_init_f() to boot flags */
 158         post_code(POST_START_DONE)
 159         xorl    %eax, %eax
 160
 161         /* Enter, U-Boot! */
 162         call    board_init_f
 163
 164         /* indicate (lack of) progress */
 165         movw    $0x85, %ax
 166         jmp     die
 167
 168 .globl board_init_f_r_trampoline
 169 .type board_init_f_r_trampoline, @function
 170 board_init_f_r_trampoline:
 171         /*
 172          * SDRAM has been initialised, U-Boot code has been copied into
 173          * RAM, BSS has been cleared and relocation adjustments have been
 174          * made. It is now time to jump into the in-RAM copy of U-Boot
 175          *
 176          * %eax = Address of top of new stack
 177          */
 178
 179         /* Stack grows down from top of SDRAM */
 180         movl    %eax, %esp
 181
 182         /* See if we need to disable CAR */
 183         call    car_uninit
 184
 185         /* Re-enter U-Boot by calling board_init_f_r() */
 186         call    board_init_f_r
 187
 188 #ifdef CONFIG_TPL
 189 .globl jump_to_spl
 190 .type jump_to_spl, @function
 191 jump_to_spl:
 192         /* Reset stack to the top of CAR space */
 193         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
 194 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
 195         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
 196 #endif
 197
 198         jmp     *%eax
 199 #endif
 200
 201 die:
 202         hlt
 203         jmp     die
 204         hlt
 205
 206 WEAK(car_uninit)
 207         ret
 208 ENDPROC(car_uninit)
 209
 210 blank_idt_ptr:
 211         .word   0               /* limit */
 212         .long   0               /* base */
 213
 214         .p2align        2       /* force 4-byte alignment */
 215
 216         /* Add a multiboot header so U-Boot can be loaded by GRUB2 */
 217 multiboot_header:
 218         /* magic */
 219         .long   0x1badb002
 220         /* flags */
 221         .long   (1 << 16)
 222         /* checksum */
 223         .long   -0x1BADB002 - (1 << 16)
 224         /* header addr */
 225         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 226         /* load addr */
 227         .long   CONFIG_SYS_TEXT_BASE
 228         /* load end addr */
 229         .long   0
 230         /* bss end addr */
 231         .long   0
 232         /* entry addr */
 233         .long   CONFIG_SYS_TEXT_BASE
 234
 235 #ifdef CONFIG_X86_LOAD_FROM_32_BIT
 236         /*
 237          * The following Global Descriptor Table is just enough to get us into
 238          * 'Flat Protected Mode' - It will be discarded as soon as the final
 239          * GDT is setup in a safe location in RAM
 240          */
 241 gdt_ptr2:
 242         .word   0x1f            /* limit (31 bytes = 4 GDT entries - 1) */
 243         .long   gdt_rom2        /* base */
 244
 245         /* Some CPUs are picky about GDT alignment... */
 246         .align  16
 247 .globl gdt_rom2
 248 gdt_rom2:
 249         /*
 250          * The GDT table ...
 251          *
 252          *       Selector       Type
 253          *       0x00           NULL
 254          *       0x08           Unused
 255          *       0x10           32bit code
 256          *       0x18           32bit data/stack
 257          */
 258         /* The NULL Desciptor - Mandatory */
 259         .word   0x0000          /* limit_low */
 260         .word   0x0000          /* base_low */
 261         .byte   0x00            /* base_middle */
 262         .byte   0x00            /* access */
 263         .byte   0x00            /* flags + limit_high */
 264         .byte   0x00            /* base_high */
 265
 266         /* Unused Desciptor - (matches Linux) */
 267         .word   0x0000          /* limit_low */
 268         .word   0x0000          /* base_low */
 269         .byte   0x00            /* base_middle */
 270         .byte   0x00            /* access */
 271         .byte   0x00            /* flags + limit_high */
 272         .byte   0x00            /* base_high */
 273
 274         /*
 275          * The Code Segment Descriptor:
 276          * - Base   = 0x00000000
 277          * - Size   = 4GB
 278          * - Access = Present, Ring 0, Exec (Code), Readable
 279          * - Flags  = 4kB Granularity, 32-bit
 280          */
 281         .word   0xffff          /* limit_low */
 282         .word   0x0000          /* base_low */
 283         .byte   0x00            /* base_middle */
 284         .byte   0x9b            /* access */
 285         .byte   0xcf            /* flags + limit_high */
 286         .byte   0x00            /* base_high */
 287
 288         /*
 289          * The Data Segment Descriptor:
 290          * - Base   = 0x00000000
 291          * - Size   = 4GB
 292          * - Access = Present, Ring 0, Non-Exec (Data), Writable
 293          * - Flags  = 4kB Granularity, 32-bit
 294          */
 295         .word   0xffff          /* limit_low */
 296         .word   0x0000          /* base_low */
 297         .byte   0x00            /* base_middle */
 298         .byte   0x93            /* access */
 299         .byte   0xcf            /* flags + limit_high */
 300         .byte   0x00            /* base_high */
 301 #endif