arch/x86/cpu/start.S

   1 /*
   2  *  U-Boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm/global_data.h>
  15 #include <asm/post.h>
  16 #include <asm/processor.h>
  17 #include <asm/processor-flags.h>
  18 #include <generated/generic-asm-offsets.h>
  19 #include <generated/asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail-safe 32-bit bootstrap entry point.
  29          *
  30          * This code is used when booting from another boot loader like
  31          * coreboot or EFI. So we repeat some of the same init found in
  32          * start16.
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movl    $GD_FLG_WARM_BOOT, %ebx
  45
  46         /*
  47          * Zero the BIST (Built-In Self Test) value since we don't have it.
  48          * It must be 0 or the previous loader would have reported an error.
  49          */
  50         movl    $0, %ebp
  51
  52         jmp     1f
  53
  54         /* Add a way for tools to discover the _start entry point */
  55         .align  4
  56         .long   0x12345678
  57 _start:
  58         /*
  59          * This is the 32-bit cold-reset entry point, coming from start16.
  60          * Set %ebx to GD_FLG_COLD_BOOT to indicate this.
  61          */
  62         movl    $GD_FLG_COLD_BOOT, %ebx
  63
  64         /* Save BIST */
  65         movl    %eax, %ebp
  66 1:
  67
  68         /* Save table pointer */
  69         movl    %ecx, %esi
  70
  71         /* Load the segement registers to match the GDT loaded in start16.S */
  72         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  73         movw    %ax, %fs
  74         movw    %ax, %ds
  75         movw    %ax, %gs
  76         movw    %ax, %es
  77         movw    %ax, %ss
  78
  79         /* Clear the interrupt vectors */
  80         lidt    blank_idt_ptr
  81
  82         /*
  83          * Critical early platform init - generally not used, we prefer init
  84          * to happen later when we have a console, in case something goes
  85          * wrong.
  86          */
  87         jmp     early_board_init
  88 .globl early_board_init_ret
  89 early_board_init_ret:
  90         post_code(POST_START)
  91
  92         /* Initialise Cache-As-RAM */
  93         jmp     car_init
  94 .globl car_init_ret
  95 car_init_ret:
  96 #ifndef CONFIG_HAVE_FSP
  97         /*
  98          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  99          * or fully initialised SDRAM - we really don't care which)
 100          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
 101          * and early malloc() area. The MRC requires some space at the top.
 102          *
 103          * Stack grows down from top of CAR. We have:
 104          *
 105          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
 106          *      MRC area
 107          *      global_data
 108          *      x86 global descriptor table
 109          *      early malloc area
 110          *      stack
 111          * bottom-> CONFIG_SYS_CAR_ADDR
 112          */
 113         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE - 4), %esp
 114 #ifdef CONFIG_DCACHE_RAM_MRC_VAR_SIZE
 115         subl    $CONFIG_DCACHE_RAM_MRC_VAR_SIZE, %esp
 116 #endif
 117 #else
 118         /*
 119          * When we get here after car_init(), esp points to a temporary stack
 120          * and esi holds the HOB list address returned by the FSP.
 121          */
 122 #endif
 123
 124         /* Reserve space on stack for global data */
 125         subl    $GENERATED_GBL_DATA_SIZE, %esp
 126
 127         /* Align global data to 16-byte boundary */
 128         andl    $0xfffffff0, %esp
 129         post_code(POST_START_STACK)
 130
 131         /*
 132          * Debug UART is available here although it may not be plumbed out
 133          * to pins depending on the board. To use it:
 134          *
 135          * call  debug_uart_init
 136          * mov   $'a', %eax
 137          * call  printch
 138          */
 139
 140         /* Zero the global data since it won't happen later */
 141         xorl    %eax, %eax
 142         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 143         movl    %esp, %edi
 144         rep     stosb
 145
 146 #ifdef CONFIG_HAVE_FSP
 147         test    %esi, %esi
 148         jz      skip_hob
 149
 150         /* Store HOB list */
 151         movl    %esp, %edx
 152         addl    $GD_HOB_LIST, %edx
 153         movl    %esi, (%edx)
 154
 155 skip_hob:
 156 #else
 157         /* Store table pointer */
 158         movl    %esp, %edx
 159         addl    $GD_TABLE, %edx
 160         movl    %esi, (%edx)
 161 #endif
 162
 163         /* Setup first parameter to setup_gdt, pointer to global_data */
 164         movl    %esp, %eax
 165
 166         /* Reserve space for global descriptor table */
 167         subl    $X86_GDT_SIZE, %esp
 168
 169         /* Align temporary global descriptor table to 16-byte boundary */
 170         andl    $0xfffffff0, %esp
 171         movl    %esp, %ecx
 172
 173 #if defined(CONFIG_SYS_MALLOC_F_LEN)
 174         /* Set up the pre-relocation malloc pool */
 175         subl    $CONFIG_SYS_MALLOC_F_LEN, %esp
 176         movl    %eax, %edx
 177         addl    $GD_MALLOC_BASE, %edx
 178         movl    %esp, (%edx)
 179 #endif
 180         /* Store BIST into global_data */
 181         movl    %eax, %edx
 182         addl    $GD_BIST, %edx
 183         movl    %ebp, (%edx)
 184
 185         /* Set second parameter to setup_gdt() */
 186         movl    %ecx, %edx
 187
 188         /* Setup global descriptor table so gd->xyz works */
 189         call    setup_gdt
 190
 191         /* Set parameter to board_init_f() to boot flags */
 192         post_code(POST_START_DONE)
 193         xorl    %eax, %eax
 194
 195         /* Enter, U-Boot! */
 196         call    board_init_f
 197
 198         /* indicate (lack of) progress */
 199         movw    $0x85, %ax
 200         jmp     die
 201
 202 .globl board_init_f_r_trampoline
 203 .type board_init_f_r_trampoline, @function
 204 board_init_f_r_trampoline:
 205         /*
 206          * SDRAM has been initialised, U-Boot code has been copied into
 207          * RAM, BSS has been cleared and relocation adjustments have been
 208          * made. It is now time to jump into the in-RAM copy of U-Boot
 209          *
 210          * %eax = Address of top of new stack
 211          */
 212
 213         /* Stack grows down from top of SDRAM */
 214         movl    %eax, %esp
 215
 216         /* Reserve space on stack for global data */
 217         subl    $GENERATED_GBL_DATA_SIZE, %esp
 218
 219         /* Align global data to 16-byte boundary */
 220         andl    $0xfffffff0, %esp
 221
 222         /* Setup first parameter to memcpy() and setup_gdt() */
 223         movl    %esp, %eax
 224
 225         /* Setup second parameter to memcpy() */
 226         fs movl 0, %edx
 227
 228         /* Set third parameter to memcpy() */
 229         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 230
 231         /* Copy global data from CAR to SDRAM stack */
 232         call    memcpy
 233
 234         /* Reserve space for global descriptor table */
 235         subl    $X86_GDT_SIZE, %esp
 236
 237         /* Align global descriptor table to 16-byte boundary */
 238         andl    $0xfffffff0, %esp
 239
 240         /* Set second parameter to setup_gdt() */
 241         movl    %esp, %edx
 242
 243         /* Setup global descriptor table so gd->xyz works */
 244         call    setup_gdt
 245
 246         /* Set if we need to disable CAR */
 247 .weak   car_uninit
 248         movl    $car_uninit, %eax
 249         cmpl    $0, %eax
 250         jz      1f
 251
 252         call    car_uninit
 253 1:
 254         /* Re-enter U-Boot by calling board_init_f_r() */
 255         call    board_init_f_r
 256
 257 die:
 258         hlt
 259         jmp     die
 260         hlt
 261
 262 blank_idt_ptr:
 263         .word   0               /* limit */
 264         .long   0               /* base */
 265
 266         .p2align        2       /* force 4-byte alignment */
 267
 268         /* Add a multiboot header so U-Boot can be loaded by GRUB2 */
 269 multiboot_header:
 270         /* magic */
 271         .long   0x1badb002
 272         /* flags */
 273         .long   (1 << 16)
 274         /* checksum */
 275         .long   -0x1BADB002 - (1 << 16)
 276         /* header addr */
 277         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 278         /* load addr */
 279         .long   CONFIG_SYS_TEXT_BASE
 280         /* load end addr */
 281         .long   0
 282         /* bss end addr */
 283         .long   0
 284         /* entry addr */
 285         .long   CONFIG_SYS_TEXT_BASE